lnet/autoconf/lustre-lnet.m4

   1 #
   2 # LN_CONFIG_MAX_PAYLOAD
   3 #
   4 # configure maximum payload
   5 #
   6 AC_DEFUN([LN_CONFIG_MAX_PAYLOAD],
   7 [AC_MSG_CHECKING([for non-default maximum LNET payload])
   8 AC_ARG_WITH([max-payload-mb],
   9         AC_HELP_STRING([--with-max-payload-mb=MBytes],
  10                        [set maximum lnet payload in MBytes]),
  11         [
  12                 AC_MSG_RESULT([$with_max_payload_mb])
  13                 CONFIG_LNET_MAX_PAYLOAD_MB=$with_max_payload_mb
  14                 CONFIG_LNET_MAX_PAYLOAD="(($with_max_payload_mb)<<20)"
  15         ], [
  16                 AC_MSG_RESULT([no])
  17                 CONFIG_LNET_MAX_PAYLOAD="LNET_MTU"
  18         ])
  19         AC_DEFINE_UNQUOTED(CONFIG_LNET_MAX_PAYLOAD, $CONFIG_LNET_MAX_PAYLOAD,
  20                            [Max LNET payload])
  21 ])
  22
  23 #
  24 # LN_CHECK_GCC_VERSION
  25 #
  26 # Check compiler version
  27 #
  28 AC_DEFUN([LN_CHECK_GCC_VERSION],
  29 [AC_MSG_CHECKING([compiler version])
  30 PTL_CC_VERSION=`$CC --version | awk '/^gcc/{print $ 3}'`
  31 PTL_MIN_CC_VERSION="3.2.2"
  32 v2n() {
  33         awk -F. '{printf "%d\n", (($ 1)*100+($ 2))*100+($ 3)}'
  34 }
  35 if test -z "$PTL_CC_VERSION" -o \
  36         `echo $PTL_CC_VERSION | v2n` -ge `echo $PTL_MIN_CC_VERSION | v2n`; then
  37         AC_MSG_RESULT([ok])
  38 else
  39         AC_MSG_RESULT([Buggy compiler found])
  40         AC_MSG_ERROR([Need gcc version >= $PTL_MIN_CC_VERSION])
  41 fi
  42 ])
  43
  44 #
  45 # LN_FUNC_DEV_GET_BY_NAME_2ARG
  46 #
  47 AC_DEFUN([LN_FUNC_DEV_GET_BY_NAME_2ARG],
  48 [AC_MSG_CHECKING([if dev_get_by_name has two args])
  49 LB_LINUX_TRY_COMPILE([
  50         #include <linux/netdevice.h>
  51 ],[
  52         dev_get_by_name(NULL, NULL);
  53 ],[
  54         AC_MSG_RESULT([yes])
  55         AC_DEFINE(HAVE_DEV_GET_BY_NAME_2ARG, 1, [dev_get_by_name has 2 args])
  56 ],[
  57         AC_MSG_RESULT([no])
  58 ])
  59 ])
  60
  61 #
  62 # LN_CONFIG_AFFINITY
  63 #
  64 # check if cpu affinity is available/wanted
  65 #
  66 AC_DEFUN([LN_CONFIG_AFFINITY],
  67 [AC_ARG_ENABLE([affinity],
  68         AC_HELP_STRING([--disable-affinity],
  69                        [disable process/irq affinity]),
  70         [],[enable_affinity='yes'])
  71
  72 AC_MSG_CHECKING([for CPU affinity support])
  73 if test x$enable_affinity = xno ; then
  74         AC_MSG_RESULT([no (by request)])
  75 else
  76         LB_LINUX_TRY_COMPILE([
  77                 #include <linux/sched.h>
  78         ],[
  79                 struct task_struct *t;
  80                 #if HAVE_CPUMASK_T
  81                 cpumask_t     m;
  82                 #else
  83                 unsigned long m;
  84                 #endif
  85                 set_cpus_allowed_ptr(t, &m);
  86         ],[
  87                 AC_DEFINE(CPU_AFFINITY, 1, [kernel has cpu affinity support])
  88                 AC_MSG_RESULT([yes])
  89         ],[
  90                 AC_MSG_RESULT([no (no kernel support)])
  91         ])
  92 fi
  93 ])
  94
  95 #
  96 # LN_CONFIG_PORTALS
  97 #
  98 # configure support for Portals
  99 #
 100 AC_DEFUN([LN_CONFIG_PORTALS],
 101 [AC_MSG_CHECKING([for portals])
 102 AC_ARG_WITH([portals],
 103         AC_HELP_STRING([--with-portals=path],
 104                        [set path to portals]),
 105         [
 106                 case $with_portals in
 107                         no)     ENABLEPORTALS=0
 108                                 ;;
 109                         *)      PORTALS="${with_portals}"
 110                                 ENABLEPORTALS=1
 111                                 ;;
 112                 esac
 113         ], [
 114                 ENABLEPORTALS=0
 115         ])
 116 PTLLNDCPPFLAGS=""
 117 if test $ENABLEPORTALS -eq 0; then
 118         AC_MSG_RESULT([no])
 119 elif test ! \( -f ${PORTALS}/include/portals/p30.h \); then
 120         AC_MSG_RESULT([no])
 121         AC_MSG_ERROR([bad --with-portals path])
 122 else
 123         PORTALS=$(readlink --canonicalize $PORTALS)
 124         AC_MSG_RESULT([$PORTALS])
 125         PTLLNDCPPFLAGS="-I${PORTALS}/include"
 126 fi
 127 AC_SUBST(PTLLNDCPPFLAGS)
 128 ])
 129
 130 #
 131 # LN_CONFIG_BACKOFF
 132 #
 133 # check if tunable tcp backoff is available/wanted
 134 #
 135 AC_DEFUN([LN_CONFIG_BACKOFF],
 136 [AC_MSG_CHECKING([for tunable backoff TCP support])
 137 AC_ARG_ENABLE([backoff],
 138        AC_HELP_STRING([--disable-backoff],
 139                       [disable socknal tunable backoff]),
 140        [],[enable_backoff='yes'])
 141 if test x$enable_backoff = xno ; then
 142        AC_MSG_RESULT([no (by request)])
 143 else
 144        BOCD="`grep -c TCP_BACKOFF $LINUX/include/linux/tcp.h`"
 145        if test "$BOCD" != 0 ; then
 146                AC_DEFINE(SOCKNAL_BACKOFF, 1, [use tunable backoff TCP])
 147                AC_MSG_RESULT(yes)
 148                if grep rto_max $LINUX/include/linux/tcp.h|grep -q __u16; then
 149                    AC_DEFINE(SOCKNAL_BACKOFF_MS, 1, [tunable backoff TCP in ms])
 150                fi
 151        else
 152                AC_MSG_RESULT([no (no kernel support)])
 153        fi
 154 fi
 155 ])
 156
 157
 158 #
 159 # LN_CONFIG_PTLLND
 160 #
 161 # configure support for Portals LND
 162 #
 163 AC_DEFUN([LN_CONFIG_PTLLND],
 164 [
 165 if test -z "$ENABLEPORTALS"; then
 166         LN_CONFIG_PORTALS
 167 fi
 168
 169 AC_MSG_CHECKING([whether to build the kernel portals LND])
 170
 171 PTLLND=""
 172 if test $ENABLEPORTALS -ne 0; then
 173         AC_MSG_RESULT([yes])
 174         PTLLND="ptllnd"
 175 else
 176         AC_MSG_RESULT([no])
 177 fi
 178 AC_SUBST(PTLLND)
 179 ])
 180
 181 #
 182 # LN_CONFIG_UPTLLND
 183 #
 184 # configure support for Portals LND
 185 #
 186 AC_DEFUN([LN_CONFIG_UPTLLND],
 187 [
 188 if test -z "$ENABLEPORTALS"; then
 189         LN_CONFIG_PORTALS
 190 fi
 191
 192 AC_MSG_CHECKING([whether to build the userspace portals LND])
 193
 194 UPTLLND=""
 195 if test $ENABLEPORTALS -ne 0; then
 196         AC_MSG_RESULT([yes])
 197         UPTLLND="ptllnd"
 198 else
 199         AC_MSG_RESULT([no])
 200 fi
 201 AC_SUBST(UPTLLND)
 202 ])
 203
 204 #
 205 # LN_CONFIG_USOCKLND
 206 #
 207 # configure support for userspace TCP/IP LND
 208 #
 209 AC_DEFUN([LN_CONFIG_USOCKLND],
 210 [AC_MSG_CHECKING([whether to build usocklnd])
 211 AC_ARG_ENABLE([usocklnd],
 212         AC_HELP_STRING([--disable-usocklnd],
 213                         [disable usocklnd]),
 214         [],[enable_usocklnd='yes'])
 215
 216 if test x$enable_usocklnd = xyes ; then
 217         if test "$ENABLE_LIBPTHREAD" = "yes" ; then
 218                 AC_MSG_RESULT([yes])
 219                 USOCKLND="usocklnd"
 220         else
 221                 AC_MSG_RESULT([no (libpthread not present or disabled)])
 222                 USOCKLND=""
 223         fi
 224 else
 225         AC_MSG_RESULT([no (disabled explicitly)])
 226         USOCKLND=""
 227 fi
 228 AC_SUBST(USOCKLND)
 229 ])
 230
 231 #
 232 # LN_CONFIG_QUADRICS
 233 #
 234 # check if quadrics support is in this kernel
 235 #
 236 AC_DEFUN([LN_CONFIG_QUADRICS],
 237 [AC_MSG_CHECKING([for QsNet sources])
 238 AC_ARG_WITH([qsnet],
 239         AC_HELP_STRING([--with-qsnet=path],
 240                        [set path to qsnet source (default=$LINUX)]),
 241         [QSNET=$with_qsnet],
 242         [QSNET=$LINUX])
 243 AC_MSG_RESULT([$QSNET])
 244
 245 AC_MSG_CHECKING([if quadrics kernel headers are present])
 246 if test -d $QSNET/drivers/net/qsnet ; then
 247         AC_MSG_RESULT([yes])
 248         QSWLND="qswlnd"
 249         AC_MSG_CHECKING([for multirail EKC])
 250         if test -f $QSNET/include/elan/epcomms.h; then
 251                 QSNET=$(readlink --canonicalize $QSNET)
 252                 AC_MSG_RESULT([supported])
 253                 QSWCPPFLAGS="-I$QSNET/include -DMULTIRAIL_EKC=1"
 254         else
 255                 AC_MSG_RESULT([not supported])
 256                 AC_MSG_ERROR([Need multirail EKC])
 257         fi
 258
 259         if test x$QSNET = x$LINUX ; then
 260                 LB_LINUX_CONFIG([QSNET],[],[
 261                         LB_LINUX_CONFIG([QSNET_MODULE],[],[
 262                                 AC_MSG_WARN([QSNET is not enabled in this kernel; not building qswlnd.])
 263                                 QSWLND=""
 264                                 QSWCPPFLAGS=""
 265                         ])
 266                 ])
 267         fi
 268 else
 269         AC_MSG_RESULT([no])
 270         QSWLND=""
 271         QSWCPPFLAGS=""
 272 fi
 273 AC_SUBST(QSWCPPFLAGS)
 274 AC_SUBST(QSWLND)
 275 ])
 276
 277
 278 #
 279 # LN_CONFIG_MX
 280 #
 281 AC_DEFUN([LN_CONFIG_MX],
 282 [AC_MSG_CHECKING([whether to enable Myrinet MX support])
 283 # set default
 284 MXPATH="/opt/mx"
 285 AC_ARG_WITH([mx],
 286        AC_HELP_STRING([--with-mx=path],
 287                       [build mxlnd against path]),
 288        [
 289                case $with_mx in
 290                yes)    ENABLEMX=2
 291                        ;;
 292                no)     ENABLEMX=0
 293                        ;;
 294                *)      MXPATH=$with_mx
 295                        ENABLEMX=3
 296                        ;;
 297                esac
 298        ],[
 299                ENABLEMX=1
 300        ])
 301 if test $ENABLEMX -eq 0; then
 302        AC_MSG_RESULT([disabled])
 303 elif test ! \( -f ${MXPATH}/include/myriexpress.h -a \
 304               -f ${MXPATH}/include/mx_kernel_api.h -a \
 305               -f ${MXPATH}/include/mx_pin.h \); then
 306        AC_MSG_RESULT([no])
 307        case $ENABLEMX in
 308        1) ;;
 309        2) AC_MSG_ERROR([Myrinet MX kernel headers not present]);;
 310        3) AC_MSG_ERROR([bad --with-mx path]);;
 311        *) AC_MSG_ERROR([internal error]);;
 312        esac
 313 else
 314        MXPATH=$(readlink --canonicalize $MXPATH)
 315        MXCPPFLAGS="-I$MXPATH/include"
 316        EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 317        EXTRA_KCFLAGS="$EXTRA_KCFLAGS $MXCPPFLAGS"
 318        MXLIBS="-L$MXPATH/lib"
 319        LB_LINUX_TRY_COMPILE([
 320                #define MX_KERNEL 1
 321                #include <mx_extensions.h>
 322                #include <myriexpress.h>
 323        ],[
 324                mx_endpoint_t   end;
 325                mx_status_t     status;
 326                mx_request_t    request;
 327                int             result;
 328
 329                mx_init();
 330                mx_open_endpoint(MX_ANY_NIC, MX_ANY_ENDPOINT, 0, NULL, 0, &end);
 331                mx_register_unexp_handler(end, (mx_unexp_handler_t) NULL, NULL);
 332                mx_wait_any(end, MX_INFINITE, 0LL, 0LL, &status, &result);
 333                mx_iconnect(end, 0LL, 0, 0, 0, NULL, &request);
 334                return 0;
 335        ],[
 336                AC_MSG_RESULT([yes])
 337                MXLND="mxlnd"
 338        ],[
 339                AC_MSG_RESULT([no])
 340                case $ENABLEMX in
 341                1) ;;
 342                2) AC_MSG_ERROR([can't compile with Myrinet MX kernel headers]);;
 343                3) AC_MSG_ERROR([can't compile with Myrinet MX headers under $MXPATH]);;
 344                *) AC_MSG_ERROR([internal error]);;
 345                esac
 346                MXLND=""
 347                MXCPPFLAGS=""
 348        ])
 349        EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 350 fi
 351 AC_SUBST(MXCPPFLAGS)
 352 AC_SUBST(MXLIBS)
 353 AC_SUBST(MXLND)
 354 ])
 355
 356
 357
 358 #
 359 # LN_CONFIG_O2IB
 360 #
 361 AC_DEFUN([LN_CONFIG_O2IB],[
 362
 363 AC_MSG_CHECKING([whether to enable OpenIB gen2 support])
 364 # set default
 365 AC_ARG_WITH([o2ib],
 366         AC_HELP_STRING([--with-o2ib=path],
 367                        [build o2iblnd against path]),
 368         [
 369                 case $with_o2ib in
 370                 yes)    O2IBPATHS="$LINUX $LINUX/drivers/infiniband"
 371                         ENABLEO2IB=2
 372                         ;;
 373                 no)     ENABLEO2IB=0
 374                         ;;
 375                 *)      O2IBPATHS=$with_o2ib
 376                         ENABLEO2IB=3
 377                         ;;
 378                 esac
 379         ],[
 380                 O2IBPATHS="$LINUX $LINUX/drivers/infiniband"
 381                 ENABLEO2IB=1
 382         ])
 383 if test $ENABLEO2IB -eq 0; then
 384         AC_MSG_RESULT([disabled])
 385 else
 386         o2ib_found=false
 387         for O2IBPATH in $O2IBPATHS; do
 388                 if test \( -f ${O2IBPATH}/include/rdma/rdma_cm.h -a \
 389                            -f ${O2IBPATH}/include/rdma/ib_cm.h -a \
 390                            -f ${O2IBPATH}/include/rdma/ib_verbs.h -a \
 391                            -f ${O2IBPATH}/include/rdma/ib_fmr_pool.h \); then
 392                         if test \( -d ${O2IBPATH}/kernel_patches -a \
 393                                    -f ${O2IBPATH}/Makefile \); then
 394                                 AC_MSG_RESULT([no])
 395                                 AC_MSG_ERROR([you appear to be trying to use the OFED distribution's source directory (${O2IBPATH}) rather than the "development/headers" directory which is likely in ${O2IBPATH%-*}])
 396                         fi
 397                         o2ib_found=true
 398                         break
 399                 fi
 400         done
 401         if ! $o2ib_found; then
 402                 AC_MSG_RESULT([no])
 403                 case $ENABLEO2IB in
 404                         1) ;;
 405                         2) AC_MSG_ERROR([kernel OpenIB gen2 headers not present]);;
 406                         3) AC_MSG_ERROR([bad --with-o2ib path]);;
 407                         *) AC_MSG_ERROR([internal error]);;
 408                 esac
 409         else
 410                 O2IBPATH=$(readlink --canonicalize $O2IBPATH)
 411                 O2IBCPPFLAGS="-I$O2IBPATH/include"
 412                 EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 413                 EXTRA_KCFLAGS="$EXTRA_KCFLAGS $O2IBCPPFLAGS"
 414                 EXTRA_LNET_INCLUDE="$EXTRA_LNET_INCLUDE $O2IBCPPFLAGS"
 415
 416                 LB_LINUX_TRY_COMPILE([
 417                         #include <linux/version.h>
 418                         #include <linux/pci.h>
 419                         #include <linux/gfp.h>
 420                         #ifdef HAVE_COMPAT_RDMA
 421                         #include <linux/compat-2.6.h>
 422                         #endif
 423                         #include <rdma/rdma_cm.h>
 424                         #include <rdma/ib_cm.h>
 425                         #include <rdma/ib_verbs.h>
 426                         #include <rdma/ib_fmr_pool.h>
 427                 ],[
 428                         struct rdma_cm_id      *cm_idi __attribute__ ((unused));
 429                         struct rdma_conn_param  conn_param __attribute__ ((unused));
 430                         struct ib_device_attr   device_attr __attribute__ ((unused));
 431                         struct ib_qp_attr       qp_attr __attribute__ ((unused));
 432                         struct ib_pool_fmr      pool_fmr __attribute__ ((unused));
 433                         enum   ib_cm_rej_reason rej_reason __attribute__ ((unused));
 434
 435                         rdma_destroy_id(NULL);
 436                 ],[
 437                         AC_MSG_RESULT([yes])
 438                         O2IBLND="o2iblnd"
 439                 ],[
 440                         AC_MSG_RESULT([no])
 441                         case $ENABLEO2IB in
 442                         1) ;;
 443                         2) AC_MSG_ERROR([can't compile with kernel OpenIB gen2 headers]);;
 444                         3) AC_MSG_ERROR([can't compile with OpenIB gen2 headers under $O2IBPATH]);;
 445                         *) AC_MSG_ERROR([internal error]);;
 446                         esac
 447                         O2IBLND=""
 448                         O2IBCPPFLAGS=""
 449                 ])
 450                 # we know at this point that the found OFED source is good
 451                 O2IB_SYMVER=""
 452                 if test $ENABLEO2IB -eq 3 ; then
 453                         # OFED default rpm not handle sles10 Modules.symvers name
 454                         for name in Module.symvers Modules.symvers; do
 455                                 if test -f $O2IBPATH/$name; then
 456                                         O2IB_SYMVER=$name;
 457                                         break;
 458                                 fi
 459                         done
 460                         if test -n "$O2IB_SYMVER"; then
 461                                 AC_MSG_NOTICE([adding $O2IBPATH/$O2IB_SYMVER to $PWD/$SYMVERFILE])
 462                                 # strip out the existing symbols versions first
 463                                 if test -f $PWD/$SYMVERFILE; then
 464                                 egrep -v $(echo $(awk '{ print $2 }' $O2IBPATH/$O2IB_SYMVER) | tr ' ' '|') $PWD/$SYMVERFILE > $PWD/$SYMVERFILE.old
 465                                 else
 466                                     touch $PWD/$SYMVERFILE.old
 467                                 fi
 468                                 cat $PWD/$SYMVERFILE.old $O2IBPATH/$O2IB_SYMVER > $PWD/$SYMVERFILE
 469                                 rm $PWD/$SYMVERFILE.old
 470                         else
 471                                 AC_MSG_ERROR([an external source tree was specified for o2iblnd however I could not find a $O2IBPATH/Module.symvers there])
 472                         fi
 473                 fi
 474
 475                 LN_CONFIG_OFED_SPEC
 476                 EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 477         fi
 478 fi
 479
 480 AC_SUBST(EXTRA_LNET_INCLUDE)
 481 AC_SUBST(O2IBCPPFLAGS)
 482 AC_SUBST(O2IBLND)
 483
 484 # In RHEL 6.2, rdma_create_id() takes the queue-pair type as a fourth argument
 485 if test $ENABLEO2IB -ne 0; then
 486         AC_MSG_CHECKING([if rdma_create_id wants four args])
 487         LB_LINUX_TRY_COMPILE([
 488                 #ifdef HAVE_COMPAT_RDMA
 489                 #include <linux/compat-2.6.h>
 490                 #endif
 491                 #include <rdma/rdma_cm.h>
 492         ],[
 493                 rdma_create_id(NULL, NULL, 0, 0);
 494         ],[
 495                 AC_MSG_RESULT([yes])
 496                 AC_DEFINE(HAVE_RDMA_CREATE_ID_4ARG, 1,
 497                         [rdma_create_id wants 4 args])
 498         ],[
 499                 AC_MSG_RESULT([no])
 500         ])
 501 fi
 502 ])
 503
 504 #
 505 # LN_CONFIG_RALND
 506 #
 507 # check whether to use the RapidArray lnd
 508 #
 509 AC_DEFUN([LN_CONFIG_RALND],
 510 [#### Rapid Array
 511 AC_MSG_CHECKING([if RapidArray kernel headers are present])
 512 # placeholder
 513 RACPPFLAGS="-I${LINUX}/drivers/xd1/include"
 514 EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 515 EXTRA_KCFLAGS="$EXTRA_KCFLAGS $RACPPFLAGS"
 516 LB_LINUX_TRY_COMPILE([
 517         #include <linux/types.h>
 518         #include <rapl.h>
 519 ],[
 520         RAP_RETURN          rc;
 521         RAP_PVOID           dev_handle;
 522
 523         rc = RapkGetDeviceByIndex(0, NULL, &dev_handle);
 524
 525         return rc == RAP_SUCCESS ? 0 : 1;
 526 ],[
 527         AC_MSG_RESULT([yes])
 528         RALND="ralnd"
 529 ],[
 530         AC_MSG_RESULT([no])
 531         RALND=""
 532         RACPPFLAGS=""
 533 ])
 534 EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 535 AC_SUBST(RACPPFLAGS)
 536 AC_SUBST(RALND)
 537 ])
 538
 539 #
 540 # LN_CONFIG_GNILND
 541 #
 542 # check whether to use the Gemini Network Interface lnd
 543 #
 544 AC_DEFUN([LN_CONFIG_GNILND],
 545 [#### Gemini Network Interface
 546 AC_MSG_CHECKING([whether to enable GNI lnd])
 547 AC_ARG_ENABLE([gni],
 548         AC_HELP_STRING([--enable-gni],
 549                         [enable GNI lnd]),
 550         [],[enable_gni='no'])
 551 AC_MSG_RESULT([$enable_gni])
 552
 553 if test x$enable_gni = xyes ; then
 554         AC_MSG_CHECKING([if GNI kernel headers are present])
 555         # placeholder
 556         # GNICPPFLAGS was set in spec file
 557         EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 558         EXTRA_KCFLAGS="$EXTRA_KCFLAGS $GNICPPFLAGS"
 559         LB_LINUX_TRY_COMPILE([
 560                 #include <linux/types.h>
 561                 #include <gni_pub.h>
 562         ],[
 563                 gni_cdm_handle_t        kgni_domain;
 564                 gni_return_t            rc;
 565                 int                     rrc;
 566
 567                 rc = gni_cdm_create(0, 1, 1, 0, &kgni_domain);
 568
 569                 rrc = (rc == GNI_RC_SUCCESS) ? 0 : 1;
 570
 571                 return rrc;
 572         ],[
 573                 AC_MSG_RESULT([yes])
 574                 GNILND="gnilnd"
 575         ],[
 576                 AC_MSG_RESULT([no])
 577                 AC_MSG_ERROR([can't compile gnilnd with given GNICPPFLAGS: $GNICPPFLAGS])
 578         ])
 579         # at this point, we have gnilnd basic support, now check for extra features
 580         AC_MSG_CHECKING([to use RCA in gnilnd])
 581         LB_LINUX_TRY_COMPILE([
 582                 #include <linux/types.h>
 583                 #include <gni_pub.h>
 584                 #include <krca_lib.h>
 585         ],[
 586                 gni_cdm_handle_t        kgni_domain;
 587                 gni_return_t            rc;
 588                 krca_ticket_t           ticket = KRCA_NULL_TICKET;
 589                 int                     rrc;
 590                 __u32                   nid = 0, nic_addr;
 591
 592                 rc = gni_cdm_create(0, 1, 1, 0, &kgni_domain);
 593
 594                 rrc = (rc == GNI_RC_SUCCESS) ? 0 : 1;
 595
 596                 rrc += krca_nid_to_nicaddrs(nid, 1, &nic_addr);
 597
 598                 rrc += krca_register(&ticket, RCA_MAKE_SERVICE_INDEX(RCA_IO_CLASS, 9), 99, 0);
 599
 600                 return rrc;
 601         ],[
 602                 AC_MSG_RESULT([yes])
 603                 GNICPPFLAGS="$GNICPPFLAGS -DGNILND_USE_RCA=1"
 604                 GNILNDRCA="gnilndrca"
 605         ],[
 606                 AC_MSG_RESULT([no])
 607         ])
 608         EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 609 fi
 610 AC_SUBST(GNICPPFLAGS)
 611 AC_SUBST(GNILNDRCA)
 612 AC_SUBST(GNILND)
 613 ])
 614
 615
 616 #
 617 #
 618 # LN_CONFIG_USERSPACE
 619 #
 620 # This is defined but empty because it is called from
 621 # build/autconf/lustre-build.m4 which is shared by all branches.
 622 #
 623 AC_DEFUN([LN_CONFIG_USERSPACE],
 624 [
 625 ])
 626
 627 #
 628 # 2.6.36 tcp_sendpage() first parameter is 'struct sock' instead of 'struct socket'.
 629 #
 630 AC_DEFUN([LN_CONFIG_TCP_SENDPAGE],
 631 [AC_MSG_CHECKING([if tcp_sendpage first parameter is socket])
 632 tmp_flags="$EXTRA_KCFLAGS"
 633 EXTRA_KCFLAGS="-Werror"
 634 LB_LINUX_TRY_COMPILE([
 635         #include <linux/net.h>
 636         #include <net/tcp.h>
 637 ],[
 638         tcp_sendpage((struct socket*)0, NULL, 0, 0, 0);
 639 ],[
 640         AC_MSG_RESULT(yes)
 641         AC_DEFINE(HAVE_TCP_SENDPAGE_USE_SOCKET, 1,
 642                   [tcp_sendpage use socket as first parameter])
 643 ],[
 644         AC_MSG_RESULT(no)
 645 ])
 646 EXTRA_KCFLAGS="$tmp_flags"
 647 ])
 648
 649 #
 650 # LN_PROG_LINUX
 651 #
 652 # LNet linux kernel checks
 653 #
 654 AC_DEFUN([LN_PROG_LINUX],
 655 [
 656 LN_FUNC_DEV_GET_BY_NAME_2ARG
 657 LN_CONFIG_AFFINITY
 658 LN_CONFIG_BACKOFF
 659 LN_CONFIG_QUADRICS
 660 LN_CONFIG_O2IB
 661 LN_CONFIG_RALND
 662 LN_CONFIG_GNILND
 663 LN_CONFIG_PTLLND
 664 LN_CONFIG_MX
 665 # 2.6.36
 666 LN_CONFIG_TCP_SENDPAGE
 667 ])
 668
 669 #
 670 # LN_PROG_DARWIN
 671 #
 672 # Darwin checks
 673 #
 674 AC_DEFUN([LN_PROG_DARWIN],
 675 [LB_DARWIN_CHECK_FUNCS([get_preemption_level])
 676 ])
 677
 678 #
 679 # LN_PATH_DEFAULTS
 680 #
 681 # default paths for installed files
 682 #
 683 AC_DEFUN([LN_PATH_DEFAULTS],
 684 [
 685 ])
 686
 687 #
 688 # LN_CONFIGURE
 689 #
 690 # other configure checks
 691 #
 692 AC_DEFUN([LN_CONFIGURE],
 693 [# lnet/utils/portals.c
 694 AC_CHECK_HEADERS([netdb.h netinet/tcp.h asm/types.h endian.h sys/ioctl.h])
 695 AC_CHECK_FUNCS([gethostbyname socket connect])
 696
 697 # lnet/utils/debug.c
 698 AC_CHECK_HEADERS([linux/version.h])
 699
 700 # lnet/utils/wirecheck.c
 701 AC_CHECK_FUNCS([strnlen])
 702
 703 # --------  Check for required packages  --------------
 704
 705 #
 706 # LC_CONFIG_READLINE
 707 #
 708 # Build with readline
 709 #
 710 AC_MSG_CHECKING([whether to enable readline support])
 711 AC_ARG_ENABLE(readline,
 712         AC_HELP_STRING([--disable-readline],
 713                         [disable readline support]),
 714         [],[enable_readline='yes'])
 715 AC_MSG_RESULT([$enable_readline])
 716
 717 # -------- check for readline if enabled ----
 718 if test x$enable_readline = xyes ; then
 719         LIBS_save="$LIBS"
 720         LIBS="-lncurses $LIBS"
 721         AC_CHECK_LIB([readline],[readline],[
 722         LIBREADLINE="-lreadline -lncurses"
 723         AC_DEFINE(HAVE_LIBREADLINE, 1, [readline library is available])
 724         ],[
 725         LIBREADLINE=""
 726         ])
 727         LIBS="$LIBS_save"
 728 else
 729         LIBREADLINE=""
 730 fi
 731 AC_SUBST(LIBREADLINE)
 732
 733 # -------- enable acceptor libwrap (TCP wrappers) support? -------
 734 AC_MSG_CHECKING([if libwrap support is requested])
 735 AC_ARG_ENABLE([libwrap],
 736         AC_HELP_STRING([--enable-libwrap], [use TCP wrappers]),
 737         [case "${enableval}" in
 738                 yes) enable_libwrap=yes ;;
 739                 no) enable_libwrap=no ;;
 740                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-libwrap) ;;
 741         esac],[enable_libwrap=no])
 742 AC_MSG_RESULT([$enable_libwrap])
 743 if test x$enable_libwrap = xyes ; then
 744         LIBWRAP="-lwrap"
 745         AC_DEFINE(HAVE_LIBWRAP, 1, [libwrap support is requested])
 746 else
 747         LIBWRAP=""
 748 fi
 749 AC_SUBST(LIBWRAP)
 750
 751 # ----------------------------------------
 752 # some tests for catamount-like systems
 753 # ----------------------------------------
 754 AC_ARG_ENABLE([sysio_init],
 755         AC_HELP_STRING([--disable-sysio-init],
 756                 [call sysio init functions when initializing liblustre]),
 757         [],[enable_sysio_init=yes])
 758 AC_MSG_CHECKING([whether to initialize libsysio])
 759 AC_MSG_RESULT([$enable_sysio_init])
 760 if test x$enable_sysio_init != xno ; then
 761         AC_DEFINE([INIT_SYSIO], 1, [call sysio init functions])
 762 fi
 763
 764 AC_ARG_ENABLE([urandom],
 765         AC_HELP_STRING([--disable-urandom],
 766                 [disable use of /dev/urandom for liblustre]),
 767         [],[enable_urandom=yes])
 768 AC_MSG_CHECKING([whether to use /dev/urandom for liblustre])
 769 AC_MSG_RESULT([$enable_urandom])
 770 if test x$enable_urandom != xno ; then
 771         AC_DEFINE([LIBLUSTRE_USE_URANDOM], 1, [use /dev/urandom for random data])
 772 fi
 773
 774 # -------- check for -lcap support ----
 775 if test x$enable_liblustre = xyes ; then
 776         AC_CHECK_LIB([cap], [cap_get_proc],
 777                 [
 778                         CAP_LIBS="-lcap"
 779                         AC_DEFINE([HAVE_LIBCAP], 1, [use libcap])
 780                 ],
 781                 [
 782                         CAP_LIBS=""
 783                 ])
 784         AC_SUBST(CAP_LIBS)
 785
 786 fi
 787
 788 LN_CONFIG_MAX_PAYLOAD
 789 LN_CONFIG_UPTLLND
 790 LN_CONFIG_USOCKLND
 791 ])
 792
 793 #
 794 # LN_CONDITIONALS
 795 #
 796 # AM_CONDITOINAL defines for lnet
 797 #
 798 AC_DEFUN([LN_CONDITIONALS],
 799 [AM_CONDITIONAL(BUILD_QSWLND, test x$QSWLND = "xqswlnd")
 800 AM_CONDITIONAL(BUILD_MXLND, test x$MXLND = "xmxlnd")
 801 AM_CONDITIONAL(BUILD_O2IBLND, test x$O2IBLND = "xo2iblnd")
 802 AM_CONDITIONAL(BUILD_RALND, test x$RALND = "xralnd")
 803 AM_CONDITIONAL(BUILD_GNILND, test x$GNILND = "xgnilnd")
 804 AM_CONDITIONAL(BUILD_GNILND_RCA, test x$GNILNDRCA = "xgnilndrca")
 805 AM_CONDITIONAL(BUILD_PTLLND, test x$PTLLND = "xptllnd")
 806 AM_CONDITIONAL(BUILD_USOCKLND, test x$USOCKLND = "xusocklnd")
 807 ])
 808
 809 #
 810 # LN_CONFIG_FILES
 811 #
 812 # files that should be generated with AC_OUTPUT
 813 #
 814 AC_DEFUN([LN_CONFIG_FILES],
 815 [AC_CONFIG_FILES([
 816 lnet/Kernelenv
 817 lnet/Makefile
 818 lnet/autoMakefile
 819 lnet/autoconf/Makefile
 820 lnet/doc/Makefile
 821 lnet/include/Makefile
 822 lnet/include/lnet/Makefile
 823 lnet/include/lnet/linux/Makefile
 824 lnet/klnds/Makefile
 825 lnet/klnds/autoMakefile
 826 lnet/klnds/mxlnd/autoMakefile
 827 lnet/klnds/mxlnd/Makefile
 828 lnet/klnds/o2iblnd/Makefile
 829 lnet/klnds/o2iblnd/autoMakefile
 830 lnet/klnds/qswlnd/Makefile
 831 lnet/klnds/qswlnd/autoMakefile
 832 lnet/klnds/ralnd/Makefile
 833 lnet/klnds/ralnd/autoMakefile
 834 lnet/klnds/gnilnd/Makefile
 835 lnet/klnds/gnilnd/autoMakefile
 836 lnet/klnds/socklnd/Makefile
 837 lnet/klnds/socklnd/autoMakefile
 838 lnet/klnds/ptllnd/Makefile
 839 lnet/klnds/ptllnd/autoMakefile
 840 lnet/lnet/Makefile
 841 lnet/lnet/autoMakefile
 842 lnet/selftest/Makefile
 843 lnet/selftest/autoMakefile
 844 lnet/ulnds/Makefile
 845 lnet/ulnds/autoMakefile
 846 lnet/ulnds/socklnd/Makefile
 847 lnet/utils/Makefile
 848 lnet/include/lnet/darwin/Makefile
 849 ])
 850 ])