lnet/autoconf/lustre-lnet.m4

   1 #
   2 # LN_CONFIG_MAX_PAYLOAD
   3 #
   4 # configure maximum payload
   5 #
   6 AC_DEFUN([LN_CONFIG_MAX_PAYLOAD], [
   7 AC_MSG_CHECKING([for non-default maximum LNET payload])
   8 AC_ARG_WITH([max-payload-mb],
   9         AC_HELP_STRING([--with-max-payload-mb=MBytes],
  10                 [set maximum lnet payload in MBytes]),
  11         [
  12                 AC_MSG_RESULT([$with_max_payload_mb])
  13                 CONFIG_LNET_MAX_PAYLOAD_MB=$with_max_payload_mb
  14                 CONFIG_LNET_MAX_PAYLOAD="(($with_max_payload_mb)<<20)"
  15         ], [
  16                 AC_MSG_RESULT([no])
  17                 CONFIG_LNET_MAX_PAYLOAD="LNET_MTU"
  18         ])
  19 AC_DEFINE_UNQUOTED(CONFIG_LNET_MAX_PAYLOAD, $CONFIG_LNET_MAX_PAYLOAD,
  20         [Max LNET payload])
  21 ]) # LN_CONFIG_MAX_PAYLOAD
  22
  23 #
  24 # LN_CHECK_GCC_VERSION
  25 #
  26 # Check compiler version
  27 #
  28 AC_DEFUN([LN_CHECK_GCC_VERSION], [
  29 AC_MSG_CHECKING([compiler version])
  30 PTL_CC_VERSION=`$CC --version | awk '/^gcc/{print $ 3}'`
  31 PTL_MIN_CC_VERSION="3.2.2"
  32 v2n() {
  33         awk -F. '{printf "%d\n", (($ 1)*100+($ 2))*100+($ 3)}'
  34 }
  35 if test -z "$PTL_CC_VERSION" -o \
  36         $(echo $PTL_CC_VERSION | v2n) -ge $(echo $PTL_MIN_CC_VERSION | v2n); then
  37         AC_MSG_RESULT([ok])
  38 else
  39         AC_MSG_RESULT([Buggy compiler found])
  40         AC_MSG_ERROR([Need gcc version >= $PTL_MIN_CC_VERSION])
  41 fi
  42 ]) # LN_CHECK_GCC_VERSION
  43
  44 #
  45 # LN_CONFIG_AFFINITY
  46 #
  47 # check if cpu affinity is available/wanted
  48 #
  49 AC_DEFUN([LN_CONFIG_AFFINITY], [
  50 AC_MSG_CHECKING([whether to enable CPU affinity support])
  51 AC_ARG_ENABLE([affinity],
  52         AC_HELP_STRING([--disable-affinity],
  53                 [disable process/irq affinity]),
  54         [], [enable_affinity="yes"])
  55 AC_MSG_RESULT([$enable_affinity])
  56 AS_IF([test "x$enable_affinity" = xyes], [
  57         LB_CHECK_COMPILE([if Linux kernel has cpu affinity support],
  58         set_cpus_allowed_ptr, [
  59                 #include <linux/sched.h>
  60         ],[
  61                 struct task_struct *t;
  62                 #if HAVE_CPUMASK_T
  63                 cpumask_t     m;
  64                 #else
  65                 unsigned long m;
  66                 #endif
  67                 set_cpus_allowed_ptr(t, &m);
  68         ],[
  69                 AC_DEFINE(CPU_AFFINITY, 1,
  70                         [kernel has cpu affinity support])
  71         ])
  72 ])
  73 ]) # LN_CONFIG_AFFINITY
  74
  75 #
  76 # LN_CONFIG_BACKOFF
  77 #
  78 # check if tunable tcp backoff is available/wanted
  79 #
  80 AC_DEFUN([LN_CONFIG_BACKOFF], [
  81 AC_MSG_CHECKING([whether to enable tunable backoff TCP support])
  82 AC_ARG_ENABLE([backoff],
  83         AC_HELP_STRING([--disable-backoff],
  84                 [disable socknal tunable backoff]),
  85         [], [enable_backoff="yes"])
  86 AC_MSG_RESULT([$enable_backoff])
  87 AS_IF([test "x$enable_backoff" = xyes], [
  88         AC_MSG_CHECKING([if Linux kernel has tunable backoff TCP support])
  89         AS_IF([grep -c TCP_BACKOFF $LINUX/include/linux/tcp.h >/dev/null], [
  90                 AC_MSG_RESULT([yes])
  91                 AC_DEFINE(SOCKNAL_BACKOFF, 1, [use tunable backoff TCP])
  92                 AS_IF([grep rto_max $LINUX/include/linux/tcp.h | grep -q __u16 >/dev/null],
  93                         [AC_DEFINE(SOCKNAL_BACKOFF_MS, 1,
  94                                 [tunable backoff TCP in ms])])
  95         ], [
  96                 AC_MSG_RESULT([no])
  97         ])
  98 ])
  99 ]) # LN_CONFIG_BACKOFF
 100
 101 #
 102 # LN_CONFIG_DLC
 103 #
 104 # Configure dlc if enabled
 105 #
 106 # if libyaml is set (IE libyaml installed) and enable_dlc = yes then build
 107 # dlc other wise (IE if libyaml is not set or enable_dlc = no) then don't
 108 # build dlc.
 109 #
 110 AC_DEFUN([LN_CONFIG_DLC], [
 111         AC_CHECK_LIB([yaml],  [yaml_parser_initialize],[
 112                 LIBYAML="libyaml"],[
 113                 LIBYAML=""],[-lm])
 114         AC_MSG_CHECKING([whether to enable dlc])
 115         AC_ARG_ENABLE([dlc],
 116                 AC_HELP_STRING([--disable-dlc],
 117                         [disable building dlc]),
 118                         [], [enable_dlc="yes"])
 119         USE_DLC=""
 120         AS_IF([test "x$enable_dlc" = xyes],
 121                 [AS_IF([test "x$LIBYAML" = xlibyaml], [
 122                         USE_DLC="yes"
 123                         AC_MSG_RESULT([yes])
 124                 ], [
 125                         AC_MSG_RESULT([no (libyaml not present)])
 126                 ])
 127         ], [
 128                 AC_MSG_RESULT([no])
 129         ])
 130         AC_SUBST(USE_DLC)
 131 ])
 132
 133 #
 134 # LN_CONFIG_O2IB
 135 #
 136 # If current OFED installed (assume with "ofed_info") and devel
 137 # headers are not found, error because we assume OFED infiniband
 138 # driver needs to be used and we must configure/build with it.
 139 # Current OFED headers detection mechanism allow for non-standard
 140 # prefix but relies on "ofed_info" command and on "%prefix/openib"
 141 # link (both are ok for 1.5.x and 3.x versions), and should work
 142 # for both source and DKMS builds.
 143 #
 144 AC_DEFUN([LN_CONFIG_O2IB], [
 145 AC_MSG_CHECKING([whether to use Compat RDMA])
 146 AC_ARG_WITH([o2ib],
 147         AC_HELP_STRING([--with-o2ib=[yes|no|<path>]],
 148                 [build o2iblnd against path]),
 149         [], [with_o2ib="yes"])
 150
 151 case $with_o2ib in
 152         yes)    AS_IF([which ofed_info 2>/dev/null], [
 153                         O2IBPATHS=$(ofed_info | egrep -w 'compat-rdma-devel|kernel-ib-devel|ofa_kernel-devel' | xargs rpm -ql | grep '/openib$')
 154                         AS_IF([test -z "$O2IBPATHS"], [
 155                                 AC_MSG_ERROR([
 156 You seem to have an OFED installed but have not installed it's devel package.
 157 If you still want to build Lustre for your OFED I/B stack, you need to install its devel headers RPM.
 158 Instead, if you want to build Lustre for your kernel's built-in I/B stack rather than your installed OFED stack, either remove the OFED package(s) or use --with-o2ib=no.
 159                                              ])
 160                         ])
 161                         AS_IF([test $(echo $O2IBPATHS | wc -w) -ge 2], [
 162                                 AC_MSG_ERROR([
 163 It appears that you have multiple OFED versions installed.
 164 If you still want to build Lustre for your OFED I/B stack, you need to install a single version with its devel headers RPM.
 165 Instead, if you want to build Lustre for your kernel's built-in I/B stack rather than your installed OFED stack, either remove the OFED package(s) or use --with-o2ib=no.
 166                                              ])
 167                         ])
 168                         OFED="yes"
 169                 ], [
 170                         O2IBPATHS="$LINUX $LINUX/drivers/infiniband"
 171                 ])
 172                 ENABLEO2IB="yes"
 173                 ;;
 174         no)     ENABLEO2IB="no"
 175                 ;;
 176         *)      O2IBPATHS=$with_o2ib
 177                 ENABLEO2IB="withpath"
 178                 OFED="yes"
 179                 ;;
 180 esac
 181
 182 AS_IF([test $ENABLEO2IB = "no"], [
 183         AC_MSG_RESULT([no])
 184 ], [
 185         o2ib_found=false
 186         for O2IBPATH in $O2IBPATHS; do
 187                 AS_IF([test \( -f ${O2IBPATH}/include/rdma/rdma_cm.h -a \
 188                            -f ${O2IBPATH}/include/rdma/ib_cm.h -a \
 189                            -f ${O2IBPATH}/include/rdma/ib_verbs.h -a \
 190                            -f ${O2IBPATH}/include/rdma/ib_fmr_pool.h \)], [
 191                         o2ib_found=true
 192                         break
 193                 ])
 194         done
 195         if ! $o2ib_found; then
 196                 AC_MSG_RESULT([no])
 197                 case $ENABLEO2IB in
 198                         "yes") AC_MSG_ERROR([no OFED nor kernel OpenIB gen2 headers present]) ;;
 199                         "withpath") AC_MSG_ERROR([bad --with-o2ib path]) ;;
 200                         *) AC_MSG_ERROR([internal error]) ;;
 201                 esac
 202         else
 203                 COMPAT_AUTOCONF=""
 204                 compatrdma_found=false
 205                 if test -f ${O2IBPATH}/include/linux/compat-2.6.h; then
 206                         AC_MSG_RESULT([yes])
 207                         compatrdma_found=true
 208                         AC_DEFINE(HAVE_COMPAT_RDMA, 1, [compat rdma found])
 209                         EXTRA_OFED_CONFIG="$EXTRA_OFED_CONFIG -include ${O2IBPATH}/include/linux/compat-2.6.h"
 210                         if test -f "$O2IBPATH/include/linux/compat_autoconf.h"; then
 211                                 COMPAT_AUTOCONF="$O2IBPATH/include/linux/compat_autoconf.h"
 212                         fi
 213                 else
 214                         AC_MSG_RESULT([no])
 215                 fi
 216                 if ! $compatrdma_found; then
 217                         if test -f "$O2IBPATH/config.mk"; then
 218                                 . "$O2IBPATH/config.mk"
 219                         elif test -f "$O2IBPATH/ofed_patch.mk"; then
 220                                 . "$O2IBPATH/ofed_patch.mk"
 221                         fi
 222                 elif test -z "$COMPAT_AUTOCONF"; then
 223                         # Depreciated checks
 224                         if test "x$RHEL_KERNEL" = xyes; then
 225                                 RHEL_MAJOR=$(awk '/ RHEL_MAJOR / { print [$]3 }' $LINUX_OBJ/include/$VERSION_HDIR/version.h)
 226                                 I=$(awk '/ RHEL_MINOR / { print [$]3 }' $LINUX_OBJ/include/$VERSION_HDIR/version.h)
 227                                 while test "$I" -ge 0; do
 228                                         EXTRA_OFED_INCLUDE="$EXTRA_OFED_INCLUDE -DCONFIG_COMPAT_RHEL_${RHEL_MAJOR}_$I"
 229                                         I=$(($I-1))
 230                                 done
 231                         elif test "x$SUSE_KERNEL" = xyes; then
 232                                 SP=$(grep PATCHLEVEL /etc/SuSE-release | sed -e 's/.*= *//')
 233                                 EXTRA_OFED_INCLUDE="$EXTRA_OFED_INCLUDE -DCONFIG_COMPAT_SLES_11_$SP"
 234                         fi
 235                 fi
 236
 237                 AC_MSG_CHECKING([whether to use any OFED backport headers])
 238                 if test -n "$BACKPORT_INCLUDES"; then
 239                         AC_MSG_RESULT([yes])
 240                         OFED_BACKPORT_PATH="$O2IBPATH/${BACKPORT_INCLUDES/*\/kernel_addons/kernel_addons}/"
 241                         EXTRA_OFED_INCLUDE="-I$OFED_BACKPORT_PATH $EXTRA_OFED_INCLUDE"
 242                 else
 243                         AC_MSG_RESULT([no])
 244                 fi
 245
 246                 O2IBLND=""
 247                 O2IBPATH=$(readlink --canonicalize $O2IBPATH)
 248                 EXTRA_OFED_INCLUDE="$EXTRA_OFED_INCLUDE -I$O2IBPATH/include"
 249                 LB_CHECK_COMPILE([whether to enable OpenIB gen2 support],
 250                 openib_gen2_support, [
 251                         #ifdef HAVE_COMPAT_RDMA
 252                         #undef PACKAGE_NAME
 253                         #undef PACKAGE_TARNAME
 254                         #undef PACKAGE_VERSION
 255                         #undef PACKAGE_STRING
 256                         #undef PACKAGE_BUGREPORT
 257                         #undef PACKAGE_URL
 258                         #include <linux/compat-2.6.h>
 259                         #endif
 260                         #include <linux/version.h>
 261                         #include <linux/pci.h>
 262                         #include <linux/gfp.h>
 263                         #include <rdma/rdma_cm.h>
 264                         #include <rdma/ib_cm.h>
 265                         #include <rdma/ib_verbs.h>
 266                         #include <rdma/ib_fmr_pool.h>
 267                 ],[
 268                         struct rdma_cm_id      *cm_idi __attribute__ ((unused));
 269                         struct rdma_conn_param  conn_param __attribute__ ((unused));
 270                         struct ib_device_attr   device_attr __attribute__ ((unused));
 271                         struct ib_qp_attr       qp_attr __attribute__ ((unused));
 272                         struct ib_pool_fmr      pool_fmr __attribute__ ((unused));
 273                         enum   ib_cm_rej_reason rej_reason __attribute__ ((unused));
 274                         rdma_destroy_id(NULL);
 275                 ],[
 276                         O2IBLND="o2iblnd"
 277                 ],[
 278                         case $ENABLEO2IB in
 279                         "yes") AC_MSG_ERROR([can't compile with OpenIB gen2 headers]) ;;
 280                         "withpath") AC_MSG_ERROR([can't compile with OpenIB gen2 headers under $O2IBPATH]) ;;
 281                         *) AC_MSG_ERROR([internal error]) ;;
 282                         esac
 283                 ])
 284                 # we know at this point that the found OFED source is good
 285                 O2IB_SYMVER=""
 286                 if test $ENABLEO2IB = "withpath" -o "x$OFED" = "xyes" ; then
 287                         # OFED default rpm not handle sles10 Modules.symvers name
 288                         for name in Module.symvers Modules.symvers; do
 289                                 if test -f $O2IBPATH/$name; then
 290                                         O2IB_SYMVER=$name;
 291                                         break;
 292                                 fi
 293                         done
 294                         if test -n "$O2IB_SYMVER"; then
 295                                 AC_MSG_NOTICE([adding $O2IBPATH/$O2IB_SYMVER to Symbol Path])
 296                                 EXTRA_SYMBOLS="$EXTRA_SYMBOLS $O2IBPATH/$O2IB_SYMVER"
 297                                 AC_SUBST(EXTRA_SYMBOLS)
 298                         else
 299                                 AC_MSG_ERROR([an external source tree was, either specified or detected, for o2iblnd however I could not find a $O2IBPATH/Module.symvers there])
 300                         fi
 301                 fi
 302
 303                 LB_CHECK_COMPILE([if Linux kernel has kthread_worker],
 304                 linux_kthread_worker, [
 305                         #ifdef HAVE_COMPAT_RDMA
 306                         #undef PACKAGE_NAME
 307                         #undef PACKAGE_TARNAME
 308                         #undef PACKAGE_VERSION
 309                         #undef PACKAGE_STRING
 310                         #undef PACKAGE_BUGREPORT
 311                         #undef PACKAGE_URL
 312                         #include <linux/compat-2.6.h>
 313                         #endif
 314                         #include <linux/kthread.h>
 315                 ],[
 316                         struct kthread_work     *kth_wrk __attribute__ ((unused));
 317                         flush_kthread_work(kth_wrk);
 318                 ],[
 319                         AC_DEFINE(HAVE_KTHREAD_WORK, 1, [kthread_worker found])
 320                         if test -z "$COMPAT_AUTOCONF"; then
 321                                 EXTRA_OFED_INCLUDE="$EXTRA_OFED_INCLUDE -DCONFIG_COMPAT_IS_KTHREAD"
 322                         fi
 323                 ])
 324         fi
 325 ])
 326 AC_SUBST(EXTRA_OFED_CONFIG)
 327 AC_SUBST(EXTRA_OFED_INCLUDE)
 328 AC_SUBST(O2IBLND)
 329 AC_SUBST(O2IBPATH)
 330 AC_SUBST(ENABLEO2IB)
 331
 332 # In RHEL 6.2, rdma_create_id() takes the queue-pair type as a fourth argument
 333 AS_IF([test $ENABLEO2IB != "no"], [
 334         LB_CHECK_COMPILE([if 'rdma_create_id' wants four args],
 335         rdma_create_id_4args, [
 336                 #ifdef HAVE_COMPAT_RDMA
 337                 #undef PACKAGE_NAME
 338                 #undef PACKAGE_TARNAME
 339                 #undef PACKAGE_VERSION
 340                 #undef PACKAGE_STRING
 341                 #undef PACKAGE_BUGREPORT
 342                 #undef PACKAGE_URL
 343                 #include <linux/compat-2.6.h>
 344                 #endif
 345                 #include <rdma/rdma_cm.h>
 346         ],[
 347                 rdma_create_id(NULL, NULL, 0, 0);
 348         ],[
 349                 AC_DEFINE(HAVE_RDMA_CREATE_ID_4ARG, 1,
 350                         [rdma_create_id wants 4 args])
 351         ])
 352 ])
 353 #
 354 # 4.2 introduced struct ib_cq_init_attr which is used
 355 # by ib_create_cq(). Note some OFED stacks only keep
 356 # their headers in sync with latest kernels but not
 357 # the functionality which means for infiniband testing
 358 # we need to always test functionality testings.
 359 #
 360 AS_IF([test $ENABLEO2IB != "no"], [
 361         LB_CHECK_COMPILE([if 'struct ib_cq_init_attr' is used],
 362         ib_cq_init_attr, [
 363                 #ifdef HAVE_COMPAT_RDMA
 364                 #undef PACKAGE_NAME
 365                 #undef PACKAGE_TARNAME
 366                 #undef PACKAGE_VERSION
 367                 #undef PACKAGE_STRING
 368                 #undef PACKAGE_BUGREPORT
 369                 #undef PACKAGE_URL
 370                 #include <linux/compat-2.6.h>
 371                 #endif
 372                 #include <rdma/ib_verbs.h>
 373         ],[
 374                 struct ib_cq_init_attr cq_attr;
 375
 376                 ib_create_cq(NULL, NULL, NULL, NULL, &cq_attr);
 377         ],[
 378                 AC_DEFINE(HAVE_IB_CQ_INIT_ATTR, 1,
 379                         [struct ib_cq_init_attr is used by ib_create_cq])
 380         ])
 381 ])
 382
 383 # 4.3 removed ib_alloc_fast_reg_mr()
 384 AS_IF([test $ENABLEO2IB != "no"], [
 385         LB_CHECK_COMPILE([if 'ib_alloc_fast_reg_mr' exists],
 386         ib_alloc_fast_reg_mr, [
 387                 #ifdef HAVE_COMPAT_RDMA
 388                 #undef PACKAGE_NAME
 389                 #undef PACKAGE_TARNAME
 390                 #undef PACKAGE_VERSION
 391                 #undef PACKAGE_STRING
 392                 #undef PACKAGE_BUGREPORT
 393                 #undef PACKAGE_URL
 394                 #include <linux/compat-2.6.h>
 395                 #endif
 396                 #include <rdma/ib_verbs.h>
 397         ],[
 398                 ib_alloc_fast_reg_mr(NULL, 0);
 399         ],[
 400                 AC_DEFINE(HAVE_IB_ALLOC_FAST_REG_MR, 1,
 401                         [ib_alloc_fast_reg_mr is defined])
 402         ])
 403 ])
 404
 405 # 4.4 added network namespace parameter for rdma_create_id()
 406 AS_IF([test $ENABLEO2IB != "no"], [
 407         LB_CHECK_COMPILE([if 'rdma_create_id' wants five args],
 408         rdma_create_id_5args, [
 409                 #ifdef HAVE_COMPAT_RDMA
 410                 #undef PACKAGE_NAME
 411                 #undef PACKAGE_TARNAME
 412                 #undef PACKAGE_VERSION
 413                 #undef PACKAGE_STRING
 414                 #undef PACKAGE_BUGREPORT
 415                 #undef PACKAGE_URL
 416                 #include <linux/compat-2.6.h>
 417                 #endif
 418                 #include <rdma/rdma_cm.h>
 419         ],[
 420                 rdma_create_id(NULL, NULL, NULL, 0, 0);
 421         ],[
 422                 AC_DEFINE(HAVE_RDMA_CREATE_ID_5ARG, 1,
 423                         [rdma_create_id wants 5 args])
 424         ])
 425 ])
 426 ]) # LN_CONFIG_O2IB
 427
 428 #
 429 # LN_CONFIG_GNILND
 430 #
 431 # check whether to use the Gemini Network Interface lnd
 432 #
 433 AC_DEFUN([LN_CONFIG_GNILND], [
 434 AC_MSG_CHECKING([whether to enable GNI lnd])
 435 AC_ARG_ENABLE([gni],
 436         AC_HELP_STRING([--enable-gni],
 437                 [enable GNI lnd]),
 438         [], [enable_gni="no"])
 439 AC_MSG_RESULT([$enable_gni])
 440
 441 AS_IF([test "x$enable_gni" = xyes], [
 442         # GNICPPFLAGS was set in spec file
 443         EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 444         EXTRA_KCFLAGS="$EXTRA_KCFLAGS $GNICPPFLAGS"
 445         LB_CHECK_COMPILE([if GNI kernel headers are present],
 446         GNI_header, [
 447                 #include <linux/types.h>
 448                 #include <gni_pub.h>
 449         ],[
 450                 gni_cdm_handle_t kgni_domain;
 451                 gni_return_t     rc;
 452                 int              rrc;
 453                 rc = gni_cdm_create(0, 1, 1, 0, &kgni_domain);
 454                 rrc = (rc == GNI_RC_SUCCESS) ? 0 : 1;
 455                 return rrc;
 456         ],[
 457                 GNILND="gnilnd"
 458         ],[
 459                 AC_MSG_ERROR([can't compile gnilnd with given GNICPPFLAGS: $GNICPPFLAGS])
 460         ])
 461         # at this point, we have gnilnd basic support,
 462         # now check for extra features
 463         LB_CHECK_COMPILE([to use RCA in gnilnd],
 464         RCA_gnilnd, [
 465                 #include <linux/types.h>
 466                 #include <gni_pub.h>
 467                 #include <krca_lib.h>
 468         ],[
 469                 gni_cdm_handle_t kgni_domain;
 470                 gni_return_t     rc;
 471                 krca_ticket_t    ticket = KRCA_NULL_TICKET;
 472                 int              rrc;
 473                 __u32            nid = 0, nic_addr;
 474                 rc = gni_cdm_create(0, 1, 1, 0, &kgni_domain);
 475                 rrc = (rc == GNI_RC_SUCCESS) ? 0 : 1;
 476                 rrc += krca_nid_to_nicaddrs(nid, 1, &nic_addr);
 477                 rrc += krca_register(&ticket, RCA_MAKE_SERVICE_INDEX(RCA_IO_CLASS, 9), 99, 0);
 478                 return rrc;
 479         ],[
 480                 GNICPPFLAGS="$GNICPPFLAGS -DGNILND_USE_RCA=1"
 481         ])
 482         EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 483 ])
 484 AC_SUBST(GNICPPFLAGS)
 485 AC_SUBST(GNILND)
 486 ]) # LN_CONFIG_GNILND
 487
 488 #
 489 # LN_CONFIG_SK_SLEEP
 490 #
 491 # 2.6.35 kernel has sk_sleep function
 492 #
 493 AC_DEFUN([LN_CONFIG_SK_SLEEP], [
 494 LB_CHECK_COMPILE([if Linux kernel has 'sk_sleep'],
 495 sk_sleep, [
 496         #ifdef HAVE_COMPAT_RDMA
 497         #undef PACKAGE_NAME
 498         #undef PACKAGE_TARNAME
 499         #undef PACKAGE_VERSION
 500         #undef PACKAGE_STRING
 501         #undef PACKAGE_BUGREPORT
 502         #undef PACKAGE_URL
 503         #include <linux/compat-2.6.h>
 504         #endif
 505         #include <net/sock.h>
 506 ],[
 507         sk_sleep(NULL);
 508 ],[
 509         AC_DEFINE(HAVE_SK_SLEEP, 1,
 510                   [kernel has sk_sleep])
 511 ])
 512 ]) # LN_CONFIG_SK_SLEEP
 513
 514 #
 515 # LN_CONFIG_TCP_SENDPAGE
 516 #
 517 # 2.6.36 tcp_sendpage() first parameter is 'struct sock' instead of 'struct socket'.
 518 #
 519 AC_DEFUN([LN_CONFIG_TCP_SENDPAGE], [
 520 tmp_flags="$EXTRA_KCFLAGS"
 521 EXTRA_KCFLAGS="-Werror"
 522 LB_CHECK_COMPILE([if 'tcp_sendpage' first parameter is socket],
 523 tcp_sendpage_socket, [
 524         #ifdef HAVE_COMPAT_RDMA
 525         #undef PACKAGE_NAME
 526         #undef PACKAGE_TARNAME
 527         #undef PACKAGE_VERSION
 528         #undef PACKAGE_STRING
 529         #undef PACKAGE_BUGREPORT
 530         #undef PACKAGE_URL
 531         #include <linux/compat-2.6.h>
 532         #endif
 533         #include <linux/net.h>
 534         #include <net/tcp.h>
 535 ],[
 536         tcp_sendpage((struct socket*)0, NULL, 0, 0, 0);
 537 ],[
 538         AC_DEFINE(HAVE_TCP_SENDPAGE_USE_SOCKET, 1,
 539                 [tcp_sendpage use socket as first parameter])
 540 ])
 541 EXTRA_KCFLAGS="$tmp_flags"
 542 ]) # LN_CONFIG_TCP_SENDPAGE
 543
 544 #
 545 # LN_CONFIG_SK_DATA_READY
 546 #
 547 # 3.15 for struct sock the *sk_data_ready() field only takes one argument now
 548 #
 549 AC_DEFUN([LN_CONFIG_SK_DATA_READY], [
 550 tmp_flags="$EXTRA_KCFLAGS"
 551 EXTRA_KCFLAGS="-Werror"
 552 LB_CHECK_COMPILE([if 'sk_data_ready' takes only one argument],
 553 sk_data_ready, [
 554         #ifdef HAVE_COMPAT_RDMA
 555         #undef PACKAGE_NAME
 556         #undef PACKAGE_TARNAME
 557         #undef PACKAGE_VERSION
 558         #undef PACKAGE_STRING
 559         #undef PACKAGE_BUGREPORT
 560         #undef PACKAGE_URL
 561         #include <linux/compat-2.6.h>
 562         #endif
 563         #include <linux/net.h>
 564         #include <net/sock.h>
 565 ],[
 566         ((struct sock *)0)->sk_data_ready(NULL);
 567 ],[
 568         AC_DEFINE(HAVE_SK_DATA_READY_ONE_ARG, 1,
 569                 [sk_data_ready uses only one argument])
 570 ])
 571 EXTRA_KCFLAGS="$tmp_flags"
 572 ]) # LN_CONFIG_SK_DATA_READY
 573
 574 #
 575 # LN_CONFIG_IB_INC_RKEY
 576 #
 577 AC_DEFUN([LN_CONFIG_IB_INC_RKEY], [
 578 tmp_flags="$EXTRA_KCFLAGS"
 579 EXTRA_KCFLAGS="-Werror"
 580 LB_CHECK_COMPILE([if function 'ib_inc_rkey' is defined],
 581 ib_inc_rkey, [
 582         #ifdef HAVE_COMPAT_RDMA
 583         #undef PACKAGE_NAME
 584         #undef PACKAGE_TARNAME
 585         #undef PACKAGE_VERSION
 586         #undef PACKAGE_STRING
 587         #undef PACKAGE_BUGREPORT
 588         #undef PACKAGE_URL
 589         #include <linux/compat-2.6.h>
 590         #endif
 591         #include <rdma/ib_verbs.h>
 592 ],[
 593         (void)ib_inc_rkey(0);
 594 ],[
 595         AC_DEFINE(HAVE_IB_INC_RKEY, 1,
 596                   [function ib_inc_rkey exist])
 597 ])
 598 EXTRA_KCFLAGS="$tmp_flags"
 599 ]) # LN_CONFIG_IB_INC_RKEY
 600
 601 #
 602 # LN_PROG_LINUX
 603 #
 604 # LNet linux kernel checks
 605 #
 606 AC_DEFUN([LN_PROG_LINUX], [
 607 AC_MSG_NOTICE([LNet kernel checks
 608 ==============================================================================])
 609
 610 LN_CONFIG_AFFINITY
 611 LN_CONFIG_BACKOFF
 612 LN_CONFIG_O2IB
 613 LN_CONFIG_GNILND
 614 LN_CONFIG_IB_INC_RKEY
 615 # 2.6.35
 616 LN_CONFIG_SK_SLEEP
 617 # 2.6.36
 618 LN_CONFIG_TCP_SENDPAGE
 619 # 3.15
 620 LN_CONFIG_SK_DATA_READY
 621 ]) # LN_PROG_LINUX
 622
 623 #
 624 # LN_PATH_DEFAULTS
 625 #
 626 # default paths for installed files
 627 #
 628 AC_DEFUN([LN_PATH_DEFAULTS], [
 629 ]) # LN_PATH_DEFAULTS
 630
 631 #
 632 # LN_CONFIGURE
 633 #
 634 # other configure checks
 635 #
 636 AC_DEFUN([LN_CONFIGURE], [
 637 AC_MSG_NOTICE([LNet core checks
 638 ==============================================================================])
 639
 640 # lnet/utils/portals.c
 641 AC_CHECK_HEADERS([netdb.h])
 642 AC_CHECK_FUNCS([gethostbyname])
 643
 644 # lnet/utils/wirecheck.c
 645 AC_CHECK_FUNCS([strnlen])
 646
 647 # --------  Check for required packages  --------------
 648
 649 AC_MSG_CHECKING([whether to enable 'efence' debugging support])
 650 AC_ARG_ENABLE(efence,
 651         AC_HELP_STRING([--enable-efence],
 652                 [use efence library]),
 653         [], [enable_efence="no"])
 654 AC_MSG_RESULT([$enable_efence])
 655
 656 LIBEFENCE=""
 657 AS_IF([test "$enable_efence" = yes], [
 658         LIBEFENCE="-lefence"
 659         AC_DEFINE(HAVE_LIBEFENCE, 1,
 660                 [libefence support is requested])
 661 ])
 662 AC_SUBST(LIBEFENCE)
 663
 664 LN_CONFIG_MAX_PAYLOAD
 665 LN_CONFIG_DLC
 666 ]) # LN_CONFIGURE
 667
 668 #
 669 # LN_CONDITIONALS
 670 #
 671 # AM_CONDITIONAL defines for lnet
 672 #
 673 AC_DEFUN([LN_CONDITIONALS], [
 674 AM_CONDITIONAL(BUILD_O2IBLND,    test x$O2IBLND = "xo2iblnd")
 675 AM_CONDITIONAL(BUILD_GNILND,     test x$GNILND  = "xgnilnd")
 676 AM_CONDITIONAL(BUILD_DLC,        test x$USE_DLC = "xyes")
 677 ]) # LN_CONDITIONALS
 678
 679 #
 680 # LN_CONFIG_FILES
 681 #
 682 # files that should be generated with AC_OUTPUT
 683 #
 684 AC_DEFUN([LN_CONFIG_FILES], [
 685 AC_CONFIG_FILES([
 686 lnet/Makefile
 687 lnet/autoMakefile
 688 lnet/autoconf/Makefile
 689 lnet/doc/Makefile
 690 lnet/include/Makefile
 691 lnet/include/lnet/Makefile
 692 lnet/klnds/Makefile
 693 lnet/klnds/autoMakefile
 694 lnet/klnds/o2iblnd/Makefile
 695 lnet/klnds/o2iblnd/autoMakefile
 696 lnet/klnds/gnilnd/Makefile
 697 lnet/klnds/gnilnd/autoMakefile
 698 lnet/klnds/socklnd/Makefile
 699 lnet/klnds/socklnd/autoMakefile
 700 lnet/lnet/Makefile
 701 lnet/lnet/autoMakefile
 702 lnet/selftest/Makefile
 703 lnet/selftest/autoMakefile
 704 lnet/utils/Makefile
 705 lnet/utils/lnetconfig/Makefile
 706 ])
 707 ]) # LN_CONFIG_FILES