lnet/autoconf/lustre-lnet.m4

   1 #
   2 # LP_CHECK_GCC_VERSION
   3 #
   4 # Check compiler version
   5 #
   6 AC_DEFUN([LP_CHECK_GCC_VERSION],
   7 [AC_MSG_CHECKING([compiler version])
   8 PTL_CC_VERSION=`$CC --version | awk '/^gcc/{print $ 3}'`
   9 PTL_MIN_CC_VERSION="3.2.3"
  10 v2n() {
  11         awk -F. '{printf "%d\n", (($ 1)*100+($ 2))*100+($ 3)}'
  12 }
  13 if test -z "$PTL_CC_VERSION" -o \
  14         `echo $PTL_CC_VERSION | v2n` -ge `echo $PTL_MIN_CC_VERSION | v2n`; then
  15         AC_MSG_RESULT([ok])
  16 else
  17         AC_MSG_RESULT([Buggy compiler found])
  18         AC_MSG_ERROR([Need gcc version >= $PTL_MIN_CC_VERSION])
  19 fi
  20 ])
  21
  22 #
  23 # LP_CONFIG_ZEROCOPY
  24 #
  25 # check if zerocopy is available/wanted
  26 #
  27 AC_DEFUN([LP_CONFIG_ZEROCOPY],
  28 [AC_MSG_CHECKING([for zero-copy TCP support])
  29 AC_ARG_ENABLE([zerocopy],
  30         AC_HELP_STRING([--disable-zerocopy],
  31                        [disable socknal zerocopy]),
  32         [],[enable_zerocopy='yes'])
  33 if test x$enable_zerocopy = xno ; then
  34         AC_MSG_RESULT([no (by request)])
  35 else
  36         ZCCD="`grep -c zccd $LINUX/include/linux/skbuff.h`"
  37         if test "$ZCCD" != 0 ; then
  38                 AC_DEFINE(SOCKNAL_ZC, 1, [use zero-copy TCP])
  39                 AC_MSG_RESULT(yes)
  40         else
  41                 AC_MSG_RESULT([no (no kernel support)])
  42         fi
  43 fi
  44 ])
  45
  46 #
  47 # LP_CONFIG_AFFINITY
  48 #
  49 # check if cpu affinity is available/wanted
  50 #
  51 AC_DEFUN([LP_CONFIG_AFFINITY],
  52 [AC_ARG_ENABLE([affinity],
  53         AC_HELP_STRING([--disable-affinity],
  54                        [disable process/irq affinity]),
  55         [],[enable_affinity='yes'])
  56
  57 AC_MSG_CHECKING([for CPU affinity support])
  58 if test x$enable_affinity = xno ; then
  59         AC_MSG_RESULT([no (by request)])
  60 else
  61         LB_LINUX_TRY_COMPILE([
  62                 #include <linux/sched.h>
  63         ],[
  64                 struct task_struct t;
  65                 #ifdef CPU_ARRAY_SIZE
  66                 cpumask_t m;
  67                 #else
  68                 unsigned long m;
  69                 #endif
  70                 set_cpus_allowed(&t, m);
  71         ],[
  72                 AC_DEFINE(CPU_AFFINITY, 1, [kernel has cpu affinity support])
  73                 AC_MSG_RESULT([yes])
  74         ],[
  75                 AC_MSG_RESULT([no (no kernel support)])
  76         ])
  77 fi
  78 ])
  79
  80 #
  81 # LP_CONFIG_QUADRICS
  82 #
  83 # check if quadrics support is in this kernel
  84 #
  85 AC_DEFUN([LP_CONFIG_QUADRICS],
  86 [AC_MSG_CHECKING([for QsNet sources])
  87 AC_ARG_WITH([qsnet],
  88         AC_HELP_STRING([--with-qsnet=path],
  89                        [set path to qsnet source (default=$LINUX)]),
  90         [QSNET=$with_qsnet],
  91         [QSNET=$LINUX])
  92 AC_MSG_RESULT([$QSNET])
  93
  94 AC_MSG_CHECKING([if quadrics kernel headers are present])
  95 if test -d $QSNET/drivers/net/qsnet ; then
  96         AC_MSG_RESULT([yes])
  97         QSWNAL="qswnal"
  98         AC_MSG_CHECKING([for multirail EKC])
  99         if test -f $QSNET/include/elan/epcomms.h; then
 100                 AC_MSG_RESULT([supported])
 101                 QSWCPPFLAGS="-I$QSNET/include -DMULTIRAIL_EKC=1"
 102         else
 103                 AC_MSG_RESULT([not supported])
 104                 if test -d $QSNET/drivers/net/qsnet/include; then
 105                         QSWCPPFLAGS="-I$QSNET/drivers/net/qsnet/include"
 106                 else
 107                         QSWCPPFLAGS="-I$QSNET/include/linux"
 108                 fi
 109         fi
 110 else
 111         AC_MSG_RESULT([no])
 112         QSWNAL=""
 113         QSWCPPFLAGS=""
 114 fi
 115 AC_SUBST(QSWCPPFLAGS)
 116 AC_SUBST(QSWNAL)
 117 ])
 118
 119 #
 120 # LP_CONFIG_GM
 121 #
 122 # check if GM support is available
 123 #
 124 AC_DEFUN([LP_CONFIG_GM],
 125 [LB_ARG_LIBS_INCLUDES([Myrinet],[gm])
 126 if test x$gm_includes != x ; then
 127         GMCPPFLAGS="-I$gm_includes"
 128         if test -d "$gm/drivers" ; then
 129                 GMCPPFLAGS="$GMCPPFLAGS -I$gm/drivers -I$gm/drivers/linux/gm"
 130         fi
 131 fi
 132 AC_SUBST(GMCPPFLAGS)
 133
 134 if test x$gm_libs != x ; then
 135         GMLIBS="-L$gm_libs"
 136 fi
 137 AC_SUBST(GMLIBS)
 138
 139 ENABLE_GM=0
 140 if test x$gm != x ; then
 141         GMNAL="gmnal"
 142         ENABLE_GM=1
 143 fi
 144 AC_SUBST(GMNAL)
 145 AC_SUBST(ENABLE_GM)
 146 ])
 147
 148 #
 149 # LP_CONFIG_OPENIB
 150 #
 151 # check for OpenIB in the kernel
 152 AC_DEFUN([LP_CONFIG_OPENIB],[
 153 AC_MSG_CHECKING([whether to enable OpenIB support])
 154 # set default
 155 OPENIBPATH="$LINUX/drivers/infiniband"
 156 AC_ARG_WITH([openib],
 157         AC_HELP_STRING([--with-openib=path],
 158                        [build openibnal against path]),
 159         [
 160                 case $with_openib in
 161                 yes)    ENABLEOPENIB=2
 162                         ;;
 163                 no)     ENABLEOPENIB=0
 164                         ;;
 165                 *)      OPENIBPATH="$with_openib"
 166                         ENABLEOPENIB=3
 167                         ;;
 168                 esac
 169         ],[
 170                 ENABLEOPENIB=1
 171         ])
 172 if test $ENABLEOPENIB -eq 0; then
 173         AC_MSG_RESULT([disabled])
 174 elif test ! \( -f ${OPENIBPATH}/include/ts_ib_core.h -a \
 175                -f ${OPENIBPATH}/include/ts_ib_cm.h -a\
 176                -f ${OPENIBPATH}/include/ts_ib_sa_client.h \); then
 177         AC_MSG_RESULT([no])
 178         case $ENABLEOPENIB in
 179         1) ;;
 180         2) AC_MSG_ERROR([kernel OpenIB headers not present]);;
 181         3) AC_MSG_ERROR([bad --with-openib path]);;
 182         *) AC_MSG_ERROR([internal error]);;
 183         esac
 184 else
 185         case $ENABLEOPENIB in
 186         1|2) OPENIBCPPFLAGS="-I$OPENIBPATH/include -DIN_TREE_BUILD";;
 187         3)   OPENIBCPPFLAGS="-I$OPENIBPATH/include";;
 188         *)   AC_MSG_RESULT([no])
 189              AC_MSG_ERROR([internal error]);;
 190         esac
 191         EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 192         EXTRA_KCFLAGS="$EXTRA_KCFLAGS $OPENIBCPPFLAGS"
 193         LB_LINUX_TRY_COMPILE([
 194                 #include <ts_ib_core.h>
 195                 #include <ts_ib_cm.h>
 196                 #include <ts_ib_sa_client.h>
 197         ],[
 198                 struct ib_device_properties dev_props;
 199                 struct ib_cm_active_param   cm_active_params;
 200                 tTS_IB_CLIENT_QUERY_TID     tid;
 201                 int                         enum1 = IB_QP_ATTRIBUTE_STATE;
 202                 int                         enum2 = IB_ACCESS_LOCAL_WRITE;
 203                 int                         enum3 = IB_CQ_CALLBACK_INTERRUPT;
 204                 int                         enum4 = IB_CQ_PROVIDER_REARM;
 205                 return 0;
 206         ],[
 207                 AC_MSG_RESULT([yes])
 208                 OPENIBNAL="openibnal"
 209         ],[
 210                 AC_MSG_RESULT([no])
 211                 case $ENABLEOPENIB in
 212                 1) ;;
 213                 2) AC_MSG_ERROR([can't compile with kernel OpenIB headers]);;
 214                 3) AC_MSG_ERROR([can't compile with OpenIB headers under $OPENIBPATH]);;
 215                 *) AC_MSG_ERROR([internal error]);;
 216                 esac
 217                 OPENIBNAL=""
 218                 OPENIBCPPFLAGS=""
 219         ])
 220         EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 221 fi
 222 AC_SUBST(OPENIBCPPFLAGS)
 223 AC_SUBST(OPENIBNAL)
 224 ])
 225
 226 #
 227 # LP_CONFIG_IIB
 228 #
 229 # check for infinicon infiniband support
 230 #
 231 AC_DEFUN([LP_CONFIG_IIB],
 232 [AC_MSG_CHECKING([if Infinicon IB kernel headers are present])
 233 # for how the only infinicon ib build has headers in /usr/include/iba
 234 IIBCPPFLAGS="-I/usr/include -DIN_TREE_BUILD"
 235 EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 236 EXTRA_KCFLAGS="$EXTRA_KCFLAGS $IIBCPPFLAGS"
 237 LB_LINUX_TRY_COMPILE([
 238         #include <linux/iba/ibt.h>
 239 ],[
 240         IBT_INTERFACE_UNION interfaces;
 241         FSTATUS             rc;
 242
 243          rc = IbtGetInterfaceByVersion(IBT_INTERFACE_VERSION_2,
 244                                        &interfaces);
 245
 246         return rc == FSUCCESS ? 0 : 1;
 247 ],[
 248         AC_MSG_RESULT([yes])
 249         IIBNAL="iibnal"
 250 ],[
 251         AC_MSG_RESULT([no])
 252         IIBNAL=""
 253         IIBCPPFLAGS=""
 254 ])
 255 EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 256 AC_SUBST(IIBCPPFLAGS)
 257 AC_SUBST(IIBNAL)
 258 ])
 259
 260 #
 261 # LP_CONFIG_VIB
 262 #
 263 # check for Voltaire infiniband support
 264 #
 265 AC_DEFUN([LP_CONFIG_VIB],
 266 [AC_MSG_CHECKING([whether to enable Voltaire IB support])
 267 VIBPATH=""
 268 AC_ARG_WITH([vib],
 269         AC_HELP_STRING([--with-vib=path],
 270                        [build vibnal against path]),
 271         [
 272                 case $with_vib in
 273                 no)     AC_MSG_RESULT([no]);;
 274                 *)      VIBPATH="${with_vib}/src/nvigor/ib-code"
 275                         if test -d "$with_vib" -a -d "$VIBPATH"; then
 276                                 AC_MSG_RESULT([yes])
 277                         else
 278                                 AC_MSG_RESULT([no])
 279                                 AC_MSG_ERROR([No directory $VIBPATH])
 280                         fi;;
 281                 esac
 282         ],[
 283                 AC_MSG_RESULT([no])
 284         ])
 285 if test -z "$VIBPATH"; then
 286         VIBNAL=""
 287 else
 288         VIBCPPFLAGS="-I${VIBPATH}/include -I${VIBPATH}/cm"
 289         EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 290         EXTRA_KCFLAGS="$EXTRA_KCFLAGS $VIBCPPFLAGS"
 291         LB_LINUX_TRY_COMPILE([
 292                 #include <linux/list.h>
 293                 #include <asm/byteorder.h>
 294                 #ifdef __BIG_ENDIAN
 295                 # define CPU_BE 1
 296                 # define CPU_LE 0
 297                 #endif
 298                 #ifdef __LITTLE_ENDIAN
 299                 # define CPU_BE 0
 300                 # define CPU_LE 1
 301                 #endif
 302                 #include <vverbs.h>
 303                 #include <ib-cm.h>
 304                 #include <ibat.h>
 305         ],[
 306                 vv_hca_h_t       kib_hca;
 307                 vv_return_t      vvrc;
 308                 cm_cep_handle_t  cep;
 309                 ibat_arp_data_t  arp_data;
 310                 ibat_stat_t      ibatrc;
 311
 312                 vvrc = vv_hca_open("ANY_HCA", NULL, &kib_hca);
 313                 cep = cm_create_cep(cm_cep_transp_rc);
 314                 ibatrc = ibat_get_ib_data((uint32_t)0, (uint32_t)0,
 315                                           ibat_paths_primary, &arp_data,
 316                                           (ibat_get_ib_data_reply_fn_t)NULL,
 317                                           NULL, 0);
 318                 return 0;
 319         ],[
 320                 VIBNAL="vibnal"
 321         ],[
 322                 AC_MSG_ERROR([can't compile vibnal with given path])
 323         ])
 324         EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 325 fi
 326 AC_SUBST(VIBCPPFLAGS)
 327 AC_SUBST(VIBNAL)
 328 ])
 329
 330 #
 331 # LP_CONFIG_RANAL
 332 #
 333 # check whether to use the RapidArray nal
 334 #
 335 AC_DEFUN([LP_CONFIG_RANAL],
 336 [#### Rapid Array
 337 AC_MSG_CHECKING([if RapidArray kernel headers are present])
 338 # placeholder
 339 RACPPFLAGS="-I${LINUX}/drivers/xd1/include"
 340 EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 341 EXTRA_KCFLAGS="$EXTRA_KCFLAGS $RACPPFLAGS"
 342 LB_LINUX_TRY_COMPILE([
 343         #include <linux/types.h>
 344         #include <rapl.h>
 345 ],[
 346         RAP_RETURN          rc;
 347         RAP_PVOID           dev_handle;
 348
 349         rc = RapkGetDeviceByIndex(0, NULL, &dev_handle);
 350
 351         return rc == RAP_SUCCESS ? 0 : 1;
 352 ],[
 353         AC_MSG_RESULT([yes])
 354         RANAL="ranal"
 355 ],[
 356         AC_MSG_RESULT([no])
 357         RANAL=""
 358         RACPPFLAGS=""
 359 ])
 360 EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 361 AC_SUBST(RACPPFLAGS)
 362 AC_SUBST(RANAL)
 363 ])
 364
 365 #
 366 # LP_STRUCT_PAGE_LIST
 367 #
 368 # 2.6.4 no longer has page->list
 369 #
 370 AC_DEFUN([LP_STRUCT_PAGE_LIST],
 371 [AC_MSG_CHECKING([if struct page has a list field])
 372 LB_LINUX_TRY_COMPILE([
 373         #include <linux/mm.h>
 374 ],[
 375         struct page page;
 376         &page.list;
 377 ],[
 378         AC_MSG_RESULT([yes])
 379         AC_DEFINE(HAVE_PAGE_LIST, 1, [struct page has a list field])
 380 ],[
 381         AC_MSG_RESULT([no])
 382 ])
 383 ])
 384
 385 #
 386 # LP_STRUCT_SIGHAND
 387 #
 388 # red hat 2.4 adds sighand to struct task_struct
 389 #
 390 AC_DEFUN([LP_STRUCT_SIGHAND],
 391 [AC_MSG_CHECKING([if task_struct has a sighand field])
 392 LB_LINUX_TRY_COMPILE([
 393         #include <linux/sched.h>
 394 ],[
 395         struct task_struct p;
 396         p.sighand = NULL;
 397 ],[
 398         AC_DEFINE(CONFIG_RH_2_4_20, 1, [this kernel contains Red Hat 2.4.20 patches])
 399         AC_MSG_RESULT([yes])
 400 ],[
 401         AC_MSG_RESULT([no])
 402 ])
 403 ])
 404
 405 #
 406 # LP_FUNC_CPU_ONLINE
 407 #
 408 # cpu_online is different in rh 2.4, vanilla 2.4, and 2.6
 409 #
 410 AC_DEFUN([LP_FUNC_CPU_ONLINE],
 411 [AC_MSG_CHECKING([if kernel defines cpu_online()])
 412 LB_LINUX_TRY_COMPILE([
 413         #include <linux/sched.h>
 414 ],[
 415         cpu_online(0);
 416 ],[
 417         AC_MSG_RESULT([yes])
 418         AC_DEFINE(HAVE_CPU_ONLINE, 1, [cpu_online found])
 419 ],[
 420         AC_MSG_RESULT([no])
 421 ])
 422 ])
 423
 424 #
 425 # LP_TYPE_CPUMASK_T
 426 #
 427 # same goes for cpumask_t
 428 #
 429 AC_DEFUN([LP_TYPE_CPUMASK_T],
 430 [AC_MSG_CHECKING([if kernel defines cpumask_t])
 431 LB_LINUX_TRY_COMPILE([
 432         #include <linux/sched.h>
 433 ],[
 434         return sizeof (cpumask_t);
 435 ],[
 436         AC_MSG_RESULT([yes])
 437         AC_DEFINE(HAVE_CPUMASK_T, 1, [cpumask_t found])
 438 ],[
 439         AC_MSG_RESULT([no])
 440 ])
 441 ])
 442
 443 #
 444 # LP_FUNC_SHOW_TASK
 445 #
 446 # we export show_task(), but not all kernels have it (yet)
 447 #
 448 AC_DEFUN([LP_FUNC_SHOW_TASK],
 449 [AC_MSG_CHECKING([if kernel exports show_task])
 450 have_show_task=0
 451 for file in ksyms sched ; do
 452         if grep -q "EXPORT_SYMBOL(show_task)" \
 453                  "$LINUX/kernel/$file.c" 2>/dev/null ; then
 454                 have_show_task=1
 455                 break
 456         fi
 457 done
 458 if test x$have_show_task = x1 ; then
 459         AC_DEFINE(HAVE_SHOW_TASK, 1, [show_task is exported])
 460         AC_MSG_RESULT([yes])
 461 else
 462         AC_MSG_RESULT([no])
 463 fi
 464 ])
 465
 466 #
 467 # LP_PROG_LINUX
 468 #
 469 # Portals linux kernel checks
 470 #
 471 AC_DEFUN([LP_PROG_LINUX],
 472 [LP_CHECK_GCC_VERSION
 473
 474 LP_CONFIG_ZEROCOPY
 475 LP_CONFIG_AFFINITY
 476 LP_CONFIG_QUADRICS
 477 LP_CONFIG_GM
 478 LP_CONFIG_OPENIB
 479 LP_CONFIG_VIB
 480 LP_CONFIG_IIB
 481 LP_CONFIG_RANAL
 482
 483 LP_STRUCT_PAGE_LIST
 484 LP_STRUCT_SIGHAND
 485 LP_FUNC_CPU_ONLINE
 486 LP_TYPE_CPUMASK_T
 487 LP_FUNC_SHOW_TASK
 488 ])
 489
 490 #
 491 # LP_PROG_DARWIN
 492 #
 493 # Darwin checks
 494 #
 495 AC_DEFUN([LP_PROG_DARWIN],
 496 [LB_DARWIN_CHECK_FUNCS([get_preemption_level])
 497 ])
 498
 499 #
 500 # LP_PATH_DEFAULTS
 501 #
 502 # default paths for installed files
 503 #
 504 AC_DEFUN([LP_PATH_DEFAULTS],
 505 [
 506 ])
 507
 508 #
 509 # LP_CONFIGURE
 510 #
 511 # other configure checks
 512 #
 513 AC_DEFUN([LP_CONFIGURE],
 514 [# portals/utils/portals.c
 515 AC_CHECK_HEADERS([netdb.h netinet/tcp.h asm/types.h endian.h])
 516 AC_CHECK_FUNCS([gethostbyname socket connect])
 517
 518 # portals/utils/debug.c
 519 AC_CHECK_HEADERS([linux/version.h])
 520
 521 AC_CHECK_TYPE([spinlock_t],
 522         [AC_DEFINE(HAVE_SPINLOCK_T, 1, [spinlock_t is defined])],
 523         [],
 524         [#include <linux/spinlock.h>])
 525
 526 # portals/utils/wirecheck.c
 527 AC_CHECK_FUNCS([strnlen])
 528
 529 # --------  Check for required packages  --------------
 530
 531 LIBS_save="$LIBS"
 532 LIBS="-lncurses $LIBS"
 533 AC_CHECK_LIB([readline],[readline],[
 534         LIBREADLINE="-lreadline -lncurses"
 535         AC_DEFINE(HAVE_LIBREADLINE, 1, [readline library is available])
 536 ],[
 537         LIBREADLINE=""
 538 ])
 539 LIBS="$LIBS_save"
 540 AC_SUBST(LIBREADLINE)
 541
 542 AC_MSG_CHECKING([if efence debugging support is requested])
 543 AC_ARG_ENABLE(efence,
 544         AC_HELP_STRING([--enable-efence],
 545                         [use efence library]),
 546         [],[enable_efence='no'])
 547 AC_MSG_RESULT([$enable_efence])
 548 if test "$enable_efence" = "yes" ; then
 549         LIBEFENCE="-lefence"
 550         AC_DEFINE(HAVE_LIBEFENCE, 1, [libefence support is requested])
 551 else
 552         LIBEFENCE=""
 553 fi
 554 AC_SUBST(LIBEFENCE)
 555
 556 # -------- enable acceptor libwrap (TCP wrappers) support? -------
 557 AC_MSG_CHECKING([if libwrap support is requested])
 558 AC_ARG_ENABLE([libwrap],
 559         AC_HELP_STRING([--enable-libwrap], [use TCP wrappers]),
 560         [case "${enableval}" in
 561                 yes) enable_libwrap=yes ;;
 562                 no) enable_libwrap=no ;;
 563                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-libwrap) ;;
 564         esac],[enable_libwrap=no])
 565 AC_MSG_RESULT([$enable_libwrap])
 566 if test x$enable_libwrap = xyes ; then
 567         LIBWRAP="-lwrap"
 568         AC_DEFINE(HAVE_LIBWRAP, 1, [libwrap support is requested])
 569 else
 570         LIBWRAP=""
 571 fi
 572 AC_SUBST(LIBWRAP)
 573
 574 # ----------------------------------------
 575 # some tests for catamount-like systems
 576 # ----------------------------------------
 577 AC_ARG_ENABLE([sysio_init],
 578         AC_HELP_STRING([--disable-sysio-init],
 579                 [call sysio init functions when initializing liblustre]),
 580         [],[enable_sysio_init=yes])
 581 AC_MSG_CHECKING([whether to initialize libsysio])
 582 AC_MSG_RESULT([$enable_sysio_init])
 583 if test x$enable_sysio_init != xno ; then
 584         AC_DEFINE([INIT_SYSIO], 1, [call sysio init functions])
 585 fi
 586
 587 AC_ARG_ENABLE([urandom],
 588         AC_HELP_STRING([--disable-urandom],
 589                 [disable use of /dev/urandom for liblustre]),
 590         [],[enable_urandom=yes])
 591 AC_MSG_CHECKING([whether to use /dev/urandom for liblustre])
 592 AC_MSG_RESULT([$enable_urandom])
 593 if test x$enable_urandom != xno ; then
 594         AC_DEFINE([LIBLUSTRE_USE_URANDOM], 1, [use /dev/urandom for random data])
 595 fi
 596
 597 # -------- check for -lcap and -lpthread ----
 598 if test x$enable_liblustre = xyes ; then
 599         AC_CHECK_LIB([cap], [cap_get_proc],
 600                 [
 601                         CAP_LIBS="-lcap"
 602                         AC_DEFINE([HAVE_LIBCAP], 1, [use libcap])
 603                 ],
 604                 [CAP_LIBS=""])
 605         AC_SUBST(CAP_LIBS)
 606         AC_CHECK_LIB([pthread], [pthread_create],
 607                 [
 608                         PTHREAD_LIBS="-lpthread"
 609                         AC_DEFINE([HAVE_LIBPTHREAD], 1, [use libpthread])
 610                 ],
 611                 [PTHREAD_LIBS=""])
 612         AC_SUBST(PTHREAD_LIBS)
 613 fi
 614 ])
 615
 616 #
 617 # LP_CONDITIONALS
 618 #
 619 # AM_CONDITOINAL defines for portals
 620 #
 621 AC_DEFUN([LP_CONDITIONALS],
 622 [AM_CONDITIONAL(BUILD_QSWNAL, test x$QSWNAL = "xqswnal")
 623 AM_CONDITIONAL(BUILD_GMNAL, test x$GMNAL = "xgmnal")
 624 AM_CONDITIONAL(BUILD_OPENIBNAL, test x$OPENIBNAL = "xopenibnal")
 625 AM_CONDITIONAL(BUILD_IIBNAL, test x$IIBNAL = "xiibnal")
 626 AM_CONDITIONAL(BUILD_VIBNAL, test x$VIBNAL = "xvibnal")
 627 AM_CONDITIONAL(BUILD_RANAL, test x$RANAL = "xranal")
 628 ])
 629
 630 #
 631 # LP_CONFIG_FILES
 632 #
 633 # files that should be generated with AC_OUTPUT
 634 #
 635 AC_DEFUN([LP_CONFIG_FILES],
 636 [AC_CONFIG_FILES([
 637 portals/Kernelenv
 638 portals/Makefile
 639 portals/autoMakefile
 640 portals/autoconf/Makefile
 641 portals/doc/Makefile
 642 portals/include/Makefile
 643 portals/include/libcfs/Makefile
 644 portals/include/libcfs/linux/Makefile
 645 portals/include/portals/Makefile
 646 portals/include/portals/linux/Makefile
 647 portals/knals/Makefile
 648 portals/knals/autoMakefile
 649 portals/knals/gmnal/Makefile
 650 portals/knals/gmnal/autoMakefile
 651 portals/knals/openibnal/Makefile
 652 portals/knals/openibnal/autoMakefile
 653 portals/knals/iibnal/Makefile
 654 portals/knals/iibnal/autoMakefile
 655 portals/knals/vibnal/Makefile
 656 portals/knals/vibnal/autoMakefile
 657 portals/knals/lonal/Makefile
 658 portals/knals/lonal/autoMakefile
 659 portals/knals/qswnal/Makefile
 660 portals/knals/qswnal/autoMakefile
 661 portals/knals/ranal/Makefile
 662 portals/knals/ranal/autoMakefile
 663 portals/knals/socknal/Makefile
 664 portals/knals/socknal/autoMakefile
 665 portals/libcfs/Makefile
 666 portals/libcfs/autoMakefile
 667 portals/libcfs/linux/Makefile
 668 portals/portals/Makefile
 669 portals/portals/autoMakefile
 670 portals/router/Makefile
 671 portals/router/autoMakefile
 672 portals/tests/Makefile
 673 portals/tests/autoMakefile
 674 portals/unals/Makefile
 675 portals/utils/Makefile
 676 ])
 677 case $lb_target_os in
 678         darwin)
 679                 AC_CONFIG_FILES([
 680 portals/include/libcfs/darwin/Makefile
 681 portals/include/portals/darwin/Makefile
 682 portals/libcfs/darwin/Makefile
 683 ])
 684                 ;;
 685 esac
 686 ])