lnet/autoconf/lustre-lnet.m4

   1 #
   2 # LN_CONFIG_MAX_PAYLOAD
   3 #
   4 # configure maximum payload
   5 #
   6 AC_DEFUN([LN_CONFIG_MAX_PAYLOAD], [
   7 AC_MSG_CHECKING([for non-default maximum LNET payload])
   8 AC_ARG_WITH([max-payload-mb],
   9         AC_HELP_STRING([--with-max-payload-mb=MBytes],
  10                 [set maximum lnet payload in MBytes]),
  11         [
  12                 AC_MSG_RESULT([$with_max_payload_mb])
  13                 CONFIG_LNET_MAX_PAYLOAD_MB=$with_max_payload_mb
  14                 CONFIG_LNET_MAX_PAYLOAD="(($with_max_payload_mb)<<20)"
  15         ], [
  16                 AC_MSG_RESULT([no])
  17                 CONFIG_LNET_MAX_PAYLOAD="LNET_MTU"
  18         ])
  19 AC_DEFINE_UNQUOTED(CONFIG_LNET_MAX_PAYLOAD, $CONFIG_LNET_MAX_PAYLOAD,
  20         [Max LNET payload])
  21 ]) # LN_CONFIG_MAX_PAYLOAD
  22
  23 #
  24 # LN_CHECK_GCC_VERSION
  25 #
  26 # Check compiler version
  27 #
  28 AC_DEFUN([LN_CHECK_GCC_VERSION], [
  29 AC_MSG_CHECKING([compiler version])
  30 PTL_CC_VERSION=`$CC --version | awk '/^gcc/{print $ 3}'`
  31 PTL_MIN_CC_VERSION="3.2.2"
  32 v2n() {
  33         awk -F. '{printf "%d\n", (($ 1)*100+($ 2))*100+($ 3)}'
  34 }
  35 if test -z "$PTL_CC_VERSION" -o \
  36         $(echo $PTL_CC_VERSION | v2n) -ge $(echo $PTL_MIN_CC_VERSION | v2n); then
  37         AC_MSG_RESULT([ok])
  38 else
  39         AC_MSG_RESULT([Buggy compiler found])
  40         AC_MSG_ERROR([Need gcc version >= $PTL_MIN_CC_VERSION])
  41 fi
  42 ]) # LN_CHECK_GCC_VERSION
  43
  44 #
  45 # LN_CONFIG_AFFINITY
  46 #
  47 # check if cpu affinity is available/wanted
  48 #
  49 AC_DEFUN([LN_CONFIG_AFFINITY], [
  50 AC_MSG_CHECKING([whether to enable CPU affinity support])
  51 AC_ARG_ENABLE([affinity],
  52         AC_HELP_STRING([--disable-affinity],
  53                 [disable process/irq affinity]),
  54         [], [enable_affinity="yes"])
  55 AC_MSG_RESULT([$enable_affinity])
  56 AS_IF([test "x$enable_affinity" = xyes], [
  57         LB_CHECK_COMPILE([if Linux kernel has cpu affinity support],
  58         set_cpus_allowed_ptr, [
  59                 #include <linux/sched.h>
  60         ],[
  61                 struct task_struct *t;
  62                 #if HAVE_CPUMASK_T
  63                 cpumask_t     m;
  64                 #else
  65                 unsigned long m;
  66                 #endif
  67                 set_cpus_allowed_ptr(t, &m);
  68         ],[
  69                 AC_DEFINE(CPU_AFFINITY, 1,
  70                         [kernel has cpu affinity support])
  71         ])
  72 ])
  73 ]) # LN_CONFIG_AFFINITY
  74
  75 #
  76 # LN_CONFIG_BACKOFF
  77 #
  78 # check if tunable tcp backoff is available/wanted
  79 #
  80 AC_DEFUN([LN_CONFIG_BACKOFF], [
  81 AC_MSG_CHECKING([whether to enable tunable backoff TCP support])
  82 AC_ARG_ENABLE([backoff],
  83         AC_HELP_STRING([--disable-backoff],
  84                 [disable socknal tunable backoff]),
  85         [], [enable_backoff="yes"])
  86 AC_MSG_RESULT([$enable_backoff])
  87 AS_IF([test "x$enable_backoff" = xyes], [
  88         AC_MSG_CHECKING([if Linux kernel has tunable backoff TCP support])
  89         AS_IF([grep -c TCP_BACKOFF $LINUX/include/linux/tcp.h >/dev/null], [
  90                 AC_MSG_RESULT([yes])
  91                 AC_DEFINE(SOCKNAL_BACKOFF, 1, [use tunable backoff TCP])
  92                 AS_IF([grep rto_max $LINUX/include/linux/tcp.h | grep -q __u16 >/dev/null],
  93                         [AC_DEFINE(SOCKNAL_BACKOFF_MS, 1,
  94                                 [tunable backoff TCP in ms])])
  95         ], [
  96                 AC_MSG_RESULT([no])
  97         ])
  98 ])
  99 ]) # LN_CONFIG_BACKOFF
 100
 101 #
 102 # LN_CONFIG_DLC
 103 #
 104 # Configure dlc if enabled
 105 #
 106 # if libyaml is set (IE libyaml installed) and enable_dlc = yes then build
 107 # dlc other wise (IE if libyaml is not set or enable_dlc = no) then don't
 108 # build dlc.
 109 #
 110 AC_DEFUN([LN_CONFIG_DLC], [
 111         AC_CHECK_LIB([yaml],  [yaml_parser_initialize],[
 112                 LIBYAML="libyaml"],[
 113                 LIBYAML=""],[-lm])
 114         AC_MSG_CHECKING([whether to enable dlc])
 115         AC_ARG_ENABLE([dlc],
 116                 AC_HELP_STRING([--disable-dlc],
 117                         [disable building dlc]),
 118                         [], [enable_dlc="yes"])
 119         USE_DLC=""
 120         AS_IF([test "x$enable_dlc" = xyes],
 121                 [AS_IF([test "x$LIBYAML" = xlibyaml], [
 122                         USE_DLC="yes"
 123                         AC_MSG_RESULT([yes])
 124                 ], [
 125                         AC_MSG_RESULT([no (libyaml not present)])
 126                 ])
 127         ], [
 128                 AC_MSG_RESULT([no])
 129         ])
 130         AC_SUBST(USE_DLC)
 131 ])
 132
 133 #
 134 # LN_CONFIG_O2IB
 135 #
 136 # If current OFED installed (assume with "ofed_info") and devel
 137 # headers are not found, error because we assume OFED infiniband
 138 # driver needs to be used and we must configure/build with it.
 139 # Current OFED headers detection mechanism allow for non-standard
 140 # prefix but relies on "ofed_info" command and on "%prefix/openib"
 141 # link (both are ok for 1.5.x and 3.x versions), and should work
 142 # for both source and DKMS builds.
 143 #
 144 AC_DEFUN([LN_CONFIG_O2IB], [
 145 AC_MSG_CHECKING([whether to use Compat RDMA])
 146 AC_ARG_WITH([o2ib],
 147         AC_HELP_STRING([--with-o2ib=[yes|no|<path>]],
 148                 [build o2iblnd against path]),
 149         [], [with_o2ib="yes"])
 150
 151 case $with_o2ib in
 152         yes)    AS_IF([which ofed_info 2>/dev/null], [
 153                         O2IBPATHS=$(ofed_info | egrep -w 'compat-rdma-devel|kernel-ib-devel|ofa_kernel-devel' | xargs rpm -ql | grep '/openib$')
 154                         AS_IF([test -z "$O2IBPATHS"], [
 155                                 AC_MSG_ERROR([
 156 You seem to have an OFED installed but have not installed it's devel package.
 157 If you still want to build Lustre for your OFED I/B stack, you need to install its devel headers RPM.
 158 Instead, if you want to build Lustre for your kernel's built-in I/B stack rather than your installed OFED stack, either remove the OFED package(s) or use --with-o2ib=no.
 159                                              ])
 160                         ])
 161                         AS_IF([test $(echo $O2IBPATHS | wc -w) -ge 2], [
 162                                 AC_MSG_ERROR([
 163 It appears that you have multiple OFED versions installed.
 164 If you still want to build Lustre for your OFED I/B stack, you need to install a single version with its devel headers RPM.
 165 Instead, if you want to build Lustre for your kernel's built-in I/B stack rather than your installed OFED stack, either remove the OFED package(s) or use --with-o2ib=no.
 166                                              ])
 167                         ])
 168                         OFED="yes"
 169                 ], [
 170                         O2IBPATHS="$LINUX $LINUX/drivers/infiniband"
 171                 ])
 172                 ENABLEO2IB="yes"
 173                 ;;
 174         no)     ENABLEO2IB="no"
 175                 ;;
 176         *)      O2IBPATHS=$with_o2ib
 177                 ENABLEO2IB="withpath"
 178                 OFED="yes"
 179                 ;;
 180 esac
 181
 182 AS_IF([test $ENABLEO2IB = "no"], [
 183         AC_MSG_RESULT([no])
 184 ], [
 185         o2ib_found=false
 186         for O2IBPATH in $O2IBPATHS; do
 187                 AS_IF([test \( -f ${O2IBPATH}/include/rdma/rdma_cm.h -a \
 188                            -f ${O2IBPATH}/include/rdma/ib_cm.h -a \
 189                            -f ${O2IBPATH}/include/rdma/ib_verbs.h -a \
 190                            -f ${O2IBPATH}/include/rdma/ib_fmr_pool.h \)], [
 191                         o2ib_found=true
 192                         break
 193                 ])
 194         done
 195         if ! $o2ib_found; then
 196                 AC_MSG_RESULT([no])
 197                 case $ENABLEO2IB in
 198                         "yes") AC_MSG_ERROR([no OFED nor kernel OpenIB gen2 headers present]) ;;
 199                         "withpath") AC_MSG_ERROR([bad --with-o2ib path]) ;;
 200                         *) AC_MSG_ERROR([internal error]) ;;
 201                 esac
 202         else
 203                 COMPAT_AUTOCONF=""
 204                 compatrdma_found=false
 205                 if test -f ${O2IBPATH}/include/linux/compat-2.6.h; then
 206                         AC_MSG_RESULT([yes])
 207                         compatrdma_found=true
 208                         AC_DEFINE(HAVE_COMPAT_RDMA, 1, [compat rdma found])
 209                         EXTRA_OFED_INCLUDE="$EXTRA_OFED_INCLUDE -include ${O2IBPATH}/include/linux/compat-2.6.h"
 210                         if test -f "$O2IBPATH/include/linux/compat_autoconf.h"; then
 211                                 COMPAT_AUTOCONF="$O2IBPATH/include/linux/compat_autoconf.h"
 212                         fi
 213                 else
 214                         AC_MSG_RESULT([no])
 215                 fi
 216                 if ! $compatrdma_found; then
 217                         if test -f "$O2IBPATH/config.mk"; then
 218                                 . "$O2IBPATH/config.mk"
 219                         elif test -f "$O2IBPATH/ofed_patch.mk"; then
 220                                 . "$O2IBPATH/ofed_patch.mk"
 221                         fi
 222                 elif test -z "$COMPAT_AUTOCONF"; then
 223                         # Depreciated checks
 224                         if test "x$RHEL_KERNEL" = xyes; then
 225                                 RHEL_MAJOR=$(awk '/ RHEL_MAJOR / { print [$]3 }' $LINUX_OBJ/include/$VERSION_HDIR/version.h)
 226                                 I=$(awk '/ RHEL_MINOR / { print [$]3 }' $LINUX_OBJ/include/$VERSION_HDIR/version.h)
 227                                 while test "$I" -ge 0; do
 228                                         EXTRA_OFED_INCLUDE="$EXTRA_OFED_INCLUDE -DCONFIG_COMPAT_RHEL_${RHEL_MAJOR}_$I"
 229                                         I=$(($I-1))
 230                                 done
 231                         elif test "x$SUSE_KERNEL" = xyes; then
 232                                 SP=$(grep PATCHLEVEL /etc/SuSE-release | sed -e 's/.*= *//')
 233                                 EXTRA_OFED_INCLUDE="$EXTRA_OFED_INCLUDE -DCONFIG_COMPAT_SLES_11_$SP"
 234                         fi
 235                 fi
 236
 237                 LB_CHECK_COMPILE([if Linux kernel has kthread_worker],
 238                 linux_kthread_worker, [
 239                         #include <linux/kthread.h>
 240                 ],[
 241                         struct kthread_work     *kth_wrk __attribute__ ((unused));
 242                         flush_kthread_work(kth_wrk);
 243                 ],[
 244                         AC_DEFINE(HAVE_KTHREAD_WORK, 1, [kthread_worker found])
 245                         if test -z "$COMPAT_AUTOCONF"; then
 246                                 EXTRA_OFED_INCLUDE="$EXTRA_OFED_INCLUDE -DCONFIG_COMPAT_IS_KTHREAD"
 247                         fi
 248                 ])
 249
 250                 AC_MSG_CHECKING([whether to use any OFED backport headers])
 251                 if test -n "$BACKPORT_INCLUDES"; then
 252                         AC_MSG_RESULT([yes])
 253                         OFED_BACKPORT_PATH="$O2IBPATH/${BACKPORT_INCLUDES/*\/kernel_addons/kernel_addons}/"
 254                         EXTRA_OFED_INCLUDE="-I$OFED_BACKPORT_PATH $EXTRA_OFED_INCLUDE"
 255                 else
 256                         AC_MSG_RESULT([no])
 257                 fi
 258
 259                 O2IBLND=""
 260                 O2IBPATH=$(readlink --canonicalize $O2IBPATH)
 261                 EXTRA_OFED_INCLUDE="$EXTRA_OFED_INCLUDE -I$O2IBPATH/include"
 262                 LB_CHECK_COMPILE([whether to enable OpenIB gen2 support],
 263                 openib_gen2_support, [
 264                         #ifdef HAVE_COMPAT_RDMA
 265                         #include <linux/compat-2.6.h>
 266                         #endif
 267                         #include <linux/version.h>
 268                         #include <linux/pci.h>
 269                         #include <linux/gfp.h>
 270                         #include <rdma/rdma_cm.h>
 271                         #include <rdma/ib_cm.h>
 272                         #include <rdma/ib_verbs.h>
 273                         #include <rdma/ib_fmr_pool.h>
 274                 ],[
 275                         struct rdma_cm_id      *cm_idi __attribute__ ((unused));
 276                         struct rdma_conn_param  conn_param __attribute__ ((unused));
 277                         struct ib_device_attr   device_attr __attribute__ ((unused));
 278                         struct ib_qp_attr       qp_attr __attribute__ ((unused));
 279                         struct ib_pool_fmr      pool_fmr __attribute__ ((unused));
 280                         enum   ib_cm_rej_reason rej_reason __attribute__ ((unused));
 281                         rdma_destroy_id(NULL);
 282                 ],[
 283                         O2IBLND="o2iblnd"
 284                 ],[
 285                         case $ENABLEO2IB in
 286                         "yes") AC_MSG_ERROR([can't compile with OpenIB gen2 headers]) ;;
 287                         "withpath") AC_MSG_ERROR([can't compile with OpenIB gen2 headers under $O2IBPATH]) ;;
 288                         *) AC_MSG_ERROR([internal error]) ;;
 289                         esac
 290                 ])
 291                 # we know at this point that the found OFED source is good
 292                 O2IB_SYMVER=""
 293                 if test $ENABLEO2IB = "withpath" -o "x$OFED" = "xyes" ; then
 294                         # OFED default rpm not handle sles10 Modules.symvers name
 295                         for name in Module.symvers Modules.symvers; do
 296                                 if test -f $O2IBPATH/$name; then
 297                                         O2IB_SYMVER=$name;
 298                                         break;
 299                                 fi
 300                         done
 301                         if test -n "$O2IB_SYMVER"; then
 302                                 AC_MSG_NOTICE([adding $O2IBPATH/$O2IB_SYMVER to Symbol Path])
 303                                 EXTRA_SYMBOLS="$EXTRA_SYMBOLS $O2IBPATH/$O2IB_SYMVER"
 304                                 AC_SUBST(EXTRA_SYMBOLS)
 305                         else
 306                                 AC_MSG_ERROR([an external source tree was, either specified or detected, for o2iblnd however I could not find a $O2IBPATH/Module.symvers there])
 307                         fi
 308                 fi
 309         fi
 310 ])
 311 AC_SUBST(EXTRA_OFED_INCLUDE)
 312 AC_SUBST(O2IBLND)
 313 AC_SUBST(O2IBPATHS)
 314 AC_SUBST(ENABLEO2IB)
 315
 316 # In RHEL 6.2, rdma_create_id() takes the queue-pair type as a fourth argument
 317 AS_IF([test $ENABLEO2IB != "no"], [
 318         LB_CHECK_COMPILE([if 'rdma_create_id' wants four args],
 319         rdma_create_id_4args, [
 320                 #ifdef HAVE_COMPAT_RDMA
 321                 #include <linux/compat-2.6.h>
 322                 #endif
 323                 #include <rdma/rdma_cm.h>
 324         ],[
 325                 rdma_create_id(NULL, NULL, 0, 0);
 326         ],[
 327                 AC_DEFINE(HAVE_RDMA_CREATE_ID_4ARG, 1,
 328                         [rdma_create_id wants 4 args])
 329         ])
 330 ])
 331 ]) # LN_CONFIG_O2IB
 332
 333 #
 334 # LN_CONFIG_GNILND
 335 #
 336 # check whether to use the Gemini Network Interface lnd
 337 #
 338 AC_DEFUN([LN_CONFIG_GNILND], [
 339 AC_MSG_CHECKING([whether to enable GNI lnd])
 340 AC_ARG_ENABLE([gni],
 341         AC_HELP_STRING([--enable-gni],
 342                 [enable GNI lnd]),
 343         [], [enable_gni="no"])
 344 AC_MSG_RESULT([$enable_gni])
 345
 346 AS_IF([test "x$enable_gni" = xyes], [
 347         # GNICPPFLAGS was set in spec file
 348         EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 349         EXTRA_KCFLAGS="$EXTRA_KCFLAGS $GNICPPFLAGS"
 350         LB_CHECK_COMPILE([if GNI kernel headers are present],
 351         GNI_header, [
 352                 #include <linux/types.h>
 353                 #include <gni_pub.h>
 354         ],[
 355                 gni_cdm_handle_t kgni_domain;
 356                 gni_return_t     rc;
 357                 int              rrc;
 358                 rc = gni_cdm_create(0, 1, 1, 0, &kgni_domain);
 359                 rrc = (rc == GNI_RC_SUCCESS) ? 0 : 1;
 360                 return rrc;
 361         ],[
 362                 GNILND="gnilnd"
 363         ],[
 364                 AC_MSG_ERROR([can't compile gnilnd with given GNICPPFLAGS: $GNICPPFLAGS])
 365         ])
 366         # at this point, we have gnilnd basic support,
 367         # now check for extra features
 368         LB_CHECK_COMPILE([to use RCA in gnilnd],
 369         RCA_gnilnd, [
 370                 #include <linux/types.h>
 371                 #include <gni_pub.h>
 372                 #include <krca_lib.h>
 373         ],[
 374                 gni_cdm_handle_t kgni_domain;
 375                 gni_return_t     rc;
 376                 krca_ticket_t    ticket = KRCA_NULL_TICKET;
 377                 int              rrc;
 378                 __u32            nid = 0, nic_addr;
 379                 rc = gni_cdm_create(0, 1, 1, 0, &kgni_domain);
 380                 rrc = (rc == GNI_RC_SUCCESS) ? 0 : 1;
 381                 rrc += krca_nid_to_nicaddrs(nid, 1, &nic_addr);
 382                 rrc += krca_register(&ticket, RCA_MAKE_SERVICE_INDEX(RCA_IO_CLASS, 9), 99, 0);
 383                 return rrc;
 384         ],[
 385                 GNICPPFLAGS="$GNICPPFLAGS -DGNILND_USE_RCA=1"
 386         ])
 387         EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 388 ])
 389 AC_SUBST(GNICPPFLAGS)
 390 AC_SUBST(GNILND)
 391 ]) # LN_CONFIG_GNILND
 392
 393 #
 394 # LN_CONFIG_SK_SLEEP
 395 #
 396 # 2.6.35 kernel has sk_sleep function
 397 #
 398 AC_DEFUN([LN_CONFIG_SK_SLEEP], [
 399 LB_CHECK_COMPILE([if Linux kernel has 'sk_sleep'],
 400 sk_sleep, [
 401         #ifdef HAVE_COMPAT_RDMA
 402         #include <linux/compat-2.6.h>
 403         #endif
 404         #include <net/sock.h>
 405 ],[
 406         sk_sleep(NULL);
 407 ],[
 408         AC_DEFINE(HAVE_SK_SLEEP, 1,
 409                   [kernel has sk_sleep])
 410 ])
 411 ]) # LN_CONFIG_SK_SLEEP
 412
 413 #
 414 # LN_CONFIG_TCP_SENDPAGE
 415 #
 416 # 2.6.36 tcp_sendpage() first parameter is 'struct sock' instead of 'struct socket'.
 417 #
 418 AC_DEFUN([LN_CONFIG_TCP_SENDPAGE], [
 419 tmp_flags="$EXTRA_KCFLAGS"
 420 EXTRA_KCFLAGS="-Werror"
 421 LB_CHECK_COMPILE([if 'tcp_sendpage' first parameter is socket],
 422 tcp_sendpage_socket, [
 423         #include <linux/net.h>
 424         #include <net/tcp.h>
 425 ],[
 426         tcp_sendpage((struct socket*)0, NULL, 0, 0, 0);
 427 ],[
 428         AC_DEFINE(HAVE_TCP_SENDPAGE_USE_SOCKET, 1,
 429                 [tcp_sendpage use socket as first parameter])
 430 ])
 431 EXTRA_KCFLAGS="$tmp_flags"
 432 ]) # LN_CONFIG_TCP_SENDPAGE
 433
 434 #
 435 # LN_CONFIG_SK_DATA_READY
 436 #
 437 # 3.15 for struct sock the *sk_data_ready() field only takes one argument now
 438 #
 439 AC_DEFUN([LN_CONFIG_SK_DATA_READY], [
 440 tmp_flags="$EXTRA_KCFLAGS"
 441 EXTRA_KCFLAGS="-Werror"
 442 LB_CHECK_COMPILE([if 'sk_data_ready' takes only one argument],
 443 sk_data_ready, [
 444         #include <linux/net.h>
 445         #include <net/sock.h>
 446 ],[
 447         ((struct sock *)0)->sk_data_ready(NULL);
 448 ],[
 449         AC_DEFINE(HAVE_SK_DATA_READY_ONE_ARG, 1,
 450                 [sk_data_ready uses only one argument])
 451 ])
 452 EXTRA_KCFLAGS="$tmp_flags"
 453 ]) # LN_CONFIG_SK_DATA_READY
 454
 455 #
 456 # LN_PROG_LINUX
 457 #
 458 # LNet linux kernel checks
 459 #
 460 AC_DEFUN([LN_PROG_LINUX], [
 461 AC_MSG_NOTICE([LNet kernel checks
 462 ==============================================================================])
 463
 464 LN_CONFIG_AFFINITY
 465 LN_CONFIG_BACKOFF
 466 LN_CONFIG_O2IB
 467 LN_CONFIG_GNILND
 468 # 2.6.35
 469 LN_CONFIG_SK_SLEEP
 470 # 2.6.36
 471 LN_CONFIG_TCP_SENDPAGE
 472 # 3.15
 473 LN_CONFIG_SK_DATA_READY
 474 ]) # LN_PROG_LINUX
 475
 476 #
 477 # LN_PATH_DEFAULTS
 478 #
 479 # default paths for installed files
 480 #
 481 AC_DEFUN([LN_PATH_DEFAULTS], [
 482 ]) # LN_PATH_DEFAULTS
 483
 484 #
 485 # LN_CONFIGURE
 486 #
 487 # other configure checks
 488 #
 489 AC_DEFUN([LN_CONFIGURE], [
 490 AC_MSG_NOTICE([LNet core checks
 491 ==============================================================================])
 492
 493 # lnet/utils/portals.c
 494 AC_CHECK_HEADERS([netdb.h])
 495 AC_CHECK_FUNCS([gethostbyname])
 496
 497 # lnet/utils/wirecheck.c
 498 AC_CHECK_FUNCS([strnlen])
 499
 500 # --------  Check for required packages  --------------
 501
 502 AC_MSG_CHECKING([whether to enable 'efence' debugging support])
 503 AC_ARG_ENABLE(efence,
 504         AC_HELP_STRING([--enable-efence],
 505                 [use efence library]),
 506         [], [enable_efence="no"])
 507 AC_MSG_RESULT([$enable_efence])
 508
 509 LIBEFENCE=""
 510 AS_IF([test "$enable_efence" = yes], [
 511         LIBEFENCE="-lefence"
 512         AC_DEFINE(HAVE_LIBEFENCE, 1,
 513                 [libefence support is requested])
 514 ])
 515 AC_SUBST(LIBEFENCE)
 516
 517 LN_CONFIG_MAX_PAYLOAD
 518 LN_CONFIG_DLC
 519 ]) # LN_CONFIGURE
 520
 521 #
 522 # LN_CONDITIONALS
 523 #
 524 # AM_CONDITIONAL defines for lnet
 525 #
 526 AC_DEFUN([LN_CONDITIONALS], [
 527 AM_CONDITIONAL(BUILD_O2IBLND,    test x$O2IBLND = "xo2iblnd")
 528 AM_CONDITIONAL(BUILD_GNILND,     test x$GNILND  = "xgnilnd")
 529 AM_CONDITIONAL(BUILD_DLC,        test x$USE_DLC = "xyes")
 530 ]) # LN_CONDITIONALS
 531
 532 #
 533 # LN_CONFIG_FILES
 534 #
 535 # files that should be generated with AC_OUTPUT
 536 #
 537 AC_DEFUN([LN_CONFIG_FILES], [
 538 AC_CONFIG_FILES([
 539 lnet/Makefile
 540 lnet/autoMakefile
 541 lnet/autoconf/Makefile
 542 lnet/doc/Makefile
 543 lnet/include/Makefile
 544 lnet/include/lnet/Makefile
 545 lnet/klnds/Makefile
 546 lnet/klnds/autoMakefile
 547 lnet/klnds/o2iblnd/Makefile
 548 lnet/klnds/o2iblnd/autoMakefile
 549 lnet/klnds/gnilnd/Makefile
 550 lnet/klnds/gnilnd/autoMakefile
 551 lnet/klnds/socklnd/Makefile
 552 lnet/klnds/socklnd/autoMakefile
 553 lnet/lnet/Makefile
 554 lnet/lnet/autoMakefile
 555 lnet/selftest/Makefile
 556 lnet/selftest/autoMakefile
 557 lnet/utils/Makefile
 558 lnet/utils/lnetconfig/Makefile
 559 ])
 560 ]) # LN_CONFIG_FILES