lnet/autoconf/lustre-lnet.m4

   1 #
   2 # LN_CONFIG_MAX_PAYLOAD
   3 #
   4 # configure maximum payload
   5 #
   6 AC_DEFUN([LN_CONFIG_MAX_PAYLOAD],
   7 [AC_MSG_CHECKING([for non-default maximum LNET payload])
   8 AC_ARG_WITH([max-payload-mb],
   9         AC_HELP_STRING([--with-max-payload-mb=MBytes],
  10                        [set maximum lnet payload in MBytes]),
  11         [
  12                 AC_MSG_RESULT([$with_max_payload_mb])
  13                 LNET_MAX_PAYLOAD_MB=$with_max_payload_mb
  14                 LNET_MAX_PAYLOAD="(($with_max_payload_mb)<<20)"
  15         ], [
  16                 AC_MSG_RESULT([no])
  17                 LNET_MAX_PAYLOAD="LNET_MTU"
  18         ])
  19         AC_DEFINE_UNQUOTED(LNET_MAX_PAYLOAD, $LNET_MAX_PAYLOAD,
  20                            [Max LNET payload])
  21 ])
  22
  23 #
  24 # LN_CHECK_GCC_VERSION
  25 #
  26 # Check compiler version
  27 #
  28 AC_DEFUN([LN_CHECK_GCC_VERSION],
  29 [AC_MSG_CHECKING([compiler version])
  30 PTL_CC_VERSION=`$CC --version | awk '/^gcc/{print $ 3}'`
  31 PTL_MIN_CC_VERSION="3.2.2"
  32 v2n() {
  33         awk -F. '{printf "%d\n", (($ 1)*100+($ 2))*100+($ 3)}'
  34 }
  35 if test -z "$PTL_CC_VERSION" -o \
  36         `echo $PTL_CC_VERSION | v2n` -ge `echo $PTL_MIN_CC_VERSION | v2n`; then
  37         AC_MSG_RESULT([ok])
  38 else
  39         AC_MSG_RESULT([Buggy compiler found])
  40         AC_MSG_ERROR([Need gcc version >= $PTL_MIN_CC_VERSION])
  41 fi
  42 ])
  43
  44 #
  45 # LN_FUNC_DEV_GET_BY_NAME_2ARG
  46 #
  47 AC_DEFUN([LN_FUNC_DEV_GET_BY_NAME_2ARG],
  48 [AC_MSG_CHECKING([if dev_get_by_name has two args])
  49 LB_LINUX_TRY_COMPILE([
  50         #include <linux/netdevice.h>
  51 ],[
  52         dev_get_by_name(NULL, NULL);
  53 ],[
  54         AC_MSG_RESULT([yes])
  55         AC_DEFINE(HAVE_DEV_GET_BY_NAME_2ARG, 1, [dev_get_by_name has 2 args])
  56 ],[
  57         AC_MSG_RESULT([no])
  58 ])
  59 ])
  60
  61 #
  62 # LN_CONFIG_AFFINITY
  63 #
  64 # check if cpu affinity is available/wanted
  65 #
  66 AC_DEFUN([LN_CONFIG_AFFINITY],
  67 [AC_ARG_ENABLE([affinity],
  68         AC_HELP_STRING([--disable-affinity],
  69                        [disable process/irq affinity]),
  70         [],[enable_affinity='yes'])
  71
  72 AC_MSG_CHECKING([for CPU affinity support])
  73 if test x$enable_affinity = xno ; then
  74         AC_MSG_RESULT([no (by request)])
  75 else
  76         LB_LINUX_TRY_COMPILE([
  77                 #include <linux/sched.h>
  78         ],[
  79                 struct task_struct t;
  80                 #if HAVE_CPUMASK_T
  81                 cpumask_t     m;
  82                 #else
  83                 unsigned long m;
  84                 #endif
  85                 set_cpus_allowed(&t, m);
  86         ],[
  87                 AC_DEFINE(CPU_AFFINITY, 1, [kernel has cpu affinity support])
  88                 AC_MSG_RESULT([yes])
  89         ],[
  90                 AC_MSG_RESULT([no (no kernel support)])
  91         ])
  92 fi
  93 ])
  94
  95 #
  96 # LN_CONFIG_PORTALS
  97 #
  98 # configure support for Portals
  99 #
 100 AC_DEFUN([LN_CONFIG_PORTALS],
 101 [AC_MSG_CHECKING([for portals])
 102 AC_ARG_WITH([portals],
 103         AC_HELP_STRING([--with-portals=path],
 104                        [set path to portals]),
 105         [
 106                 case $with_portals in
 107                         no)     ENABLEPORTALS=0
 108                                 ;;
 109                         *)      PORTALS="${with_portals}"
 110                                 ENABLEPORTALS=1
 111                                 ;;
 112                 esac
 113         ], [
 114                 ENABLEPORTALS=0
 115         ])
 116 PTLLNDCPPFLAGS=""
 117 if test $ENABLEPORTALS -eq 0; then
 118         AC_MSG_RESULT([no])
 119 elif test ! \( -f ${PORTALS}/include/portals/p30.h \); then
 120         AC_MSG_RESULT([no])
 121         AC_MSG_ERROR([bad --with-portals path])
 122 else
 123         AC_MSG_RESULT([$PORTALS])
 124         PTLLNDCPPFLAGS="-I${PORTALS}/include"
 125 fi
 126 AC_SUBST(PTLLNDCPPFLAGS)
 127 ])
 128
 129 #
 130 # LN_CONFIG_BACKOFF
 131 #
 132 # check if tunable tcp backoff is available/wanted
 133 #
 134 AC_DEFUN([LN_CONFIG_BACKOFF],
 135 [AC_MSG_CHECKING([for tunable backoff TCP support])
 136 AC_ARG_ENABLE([backoff],
 137        AC_HELP_STRING([--disable-backoff],
 138                       [disable socknal tunable backoff]),
 139        [],[enable_backoff='yes'])
 140 if test x$enable_backoff = xno ; then
 141        AC_MSG_RESULT([no (by request)])
 142 else
 143        BOCD="`grep -c TCP_BACKOFF $LINUX/include/linux/tcp.h`"
 144        if test "$BOCD" != 0 ; then
 145                AC_DEFINE(SOCKNAL_BACKOFF, 1, [use tunable backoff TCP])
 146                AC_MSG_RESULT(yes)
 147                if grep rto_max $LINUX/include/linux/tcp.h|grep -q __u16; then
 148                    AC_DEFINE(SOCKNAL_BACKOFF_MS, 1, [tunable backoff TCP in ms])
 149                fi
 150        else
 151                AC_MSG_RESULT([no (no kernel support)])
 152        fi
 153 fi
 154 ])
 155
 156
 157 #
 158 # LN_CONFIG_PTLLND
 159 #
 160 # configure support for Portals LND
 161 #
 162 AC_DEFUN([LN_CONFIG_PTLLND],
 163 [
 164 if test -z "$ENABLEPORTALS"; then
 165         LN_CONFIG_PORTALS
 166 fi
 167
 168 AC_MSG_CHECKING([whether to build the kernel portals LND])
 169
 170 PTLLND=""
 171 if test $ENABLEPORTALS -ne 0; then
 172         AC_MSG_RESULT([yes])
 173         PTLLND="ptllnd"
 174 else
 175         AC_MSG_RESULT([no])
 176 fi
 177 AC_SUBST(PTLLND)
 178 ])
 179
 180 #
 181 # LN_CONFIG_UPTLLND
 182 #
 183 # configure support for Portals LND
 184 #
 185 AC_DEFUN([LN_CONFIG_UPTLLND],
 186 [
 187 if test -z "$ENABLEPORTALS"; then
 188         LN_CONFIG_PORTALS
 189 fi
 190
 191 AC_MSG_CHECKING([whether to build the userspace portals LND])
 192
 193 UPTLLND=""
 194 if test $ENABLEPORTALS -ne 0; then
 195         AC_MSG_RESULT([yes])
 196         UPTLLND="ptllnd"
 197 else
 198         AC_MSG_RESULT([no])
 199 fi
 200 AC_SUBST(UPTLLND)
 201 ])
 202
 203 #
 204 # LN_CONFIG_USOCKLND
 205 #
 206 # configure support for userspace TCP/IP LND
 207 #
 208 AC_DEFUN([LN_CONFIG_USOCKLND],
 209 [AC_MSG_CHECKING([whether to build usocklnd])
 210 AC_ARG_ENABLE([usocklnd],
 211         AC_HELP_STRING([--disable-usocklnd],
 212                         [disable usocklnd]),
 213         [],[enable_usocklnd='yes'])
 214
 215 if test x$enable_usocklnd = xyes ; then
 216         if test "$ENABLE_LIBPTHREAD" = "yes" ; then
 217                 AC_MSG_RESULT([yes])
 218                 USOCKLND="usocklnd"
 219         else
 220                 AC_MSG_RESULT([no (libpthread not present or disabled)])
 221                 USOCKLND=""
 222         fi
 223 else
 224         AC_MSG_RESULT([no (disabled explicitly)])
 225         USOCKLND=""
 226 fi
 227 AC_SUBST(USOCKLND)
 228 ])
 229
 230 #
 231 # LN_CONFIG_QUADRICS
 232 #
 233 # check if quadrics support is in this kernel
 234 #
 235 AC_DEFUN([LN_CONFIG_QUADRICS],
 236 [AC_MSG_CHECKING([for QsNet sources])
 237 AC_ARG_WITH([qsnet],
 238         AC_HELP_STRING([--with-qsnet=path],
 239                        [set path to qsnet source (default=$LINUX)]),
 240         [QSNET=$with_qsnet],
 241         [QSNET=$LINUX])
 242 AC_MSG_RESULT([$QSNET])
 243
 244 AC_MSG_CHECKING([if quadrics kernel headers are present])
 245 if test -d $QSNET/drivers/net/qsnet ; then
 246         AC_MSG_RESULT([yes])
 247         QSWLND="qswlnd"
 248         AC_MSG_CHECKING([for multirail EKC])
 249         if test -f $QSNET/include/elan/epcomms.h; then
 250                 AC_MSG_RESULT([supported])
 251                 QSWCPPFLAGS="-I$QSNET/include -DMULTIRAIL_EKC=1"
 252         else
 253                 AC_MSG_RESULT([not supported])
 254                 AC_MSG_ERROR([Need multirail EKC])
 255         fi
 256
 257         if test x$QSNET = x$LINUX ; then
 258                 LB_LINUX_CONFIG([QSNET],[],[
 259                         LB_LINUX_CONFIG([QSNET_MODULE],[],[
 260                                 AC_MSG_WARN([QSNET is not enabled in this kernel; not building qswlnd.])
 261                                 QSWLND=""
 262                                 QSWCPPFLAGS=""
 263                         ])
 264                 ])
 265         fi
 266 else
 267         AC_MSG_RESULT([no])
 268         QSWLND=""
 269         QSWCPPFLAGS=""
 270 fi
 271 AC_SUBST(QSWCPPFLAGS)
 272 AC_SUBST(QSWLND)
 273 ])
 274
 275
 276 #
 277 # LN_CONFIG_MX
 278 #
 279 AC_DEFUN([LN_CONFIG_MX],
 280 [AC_MSG_CHECKING([whether to enable Myrinet MX support])
 281 # set default
 282 MXPATH="/opt/mx"
 283 AC_ARG_WITH([mx],
 284        AC_HELP_STRING([--with-mx=path],
 285                       [build mxlnd against path]),
 286        [
 287                case $with_mx in
 288                yes)    ENABLEMX=2
 289                        ;;
 290                no)     ENABLEMX=0
 291                        ;;
 292                *)      MXPATH=$with_mx
 293                        ENABLEMX=3
 294                        ;;
 295                esac
 296        ],[
 297                ENABLEMX=1
 298        ])
 299 if test $ENABLEMX -eq 0; then
 300        AC_MSG_RESULT([disabled])
 301 elif test ! \( -f ${MXPATH}/include/myriexpress.h -a \
 302               -f ${MXPATH}/include/mx_kernel_api.h -a \
 303               -f ${MXPATH}/include/mx_pin.h \); then
 304        AC_MSG_RESULT([no])
 305        case $ENABLEMX in
 306        1) ;;
 307        2) AC_MSG_ERROR([Myrinet MX kernel headers not present]);;
 308        3) AC_MSG_ERROR([bad --with-mx path]);;
 309        *) AC_MSG_ERROR([internal error]);;
 310        esac
 311 else
 312        MXCPPFLAGS="-I$MXPATH/include"
 313        EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 314        EXTRA_KCFLAGS="$EXTRA_KCFLAGS $MXCPPFLAGS"
 315        MXLIBS="-L$MXPATH/lib"
 316        LB_LINUX_TRY_COMPILE([
 317                #define MX_KERNEL 1
 318                #include <mx_extensions.h>
 319                #include <myriexpress.h>
 320        ],[
 321                mx_endpoint_t   end;
 322                mx_status_t     status;
 323                mx_request_t    request;
 324                int             result;
 325
 326                mx_init();
 327                mx_open_endpoint(MX_ANY_NIC, MX_ANY_ENDPOINT, 0, NULL, 0, &end);
 328                mx_register_unexp_handler(end, (mx_unexp_handler_t) NULL, NULL);
 329                mx_wait_any(end, MX_INFINITE, 0LL, 0LL, &status, &result);
 330                mx_iconnect(end, 0LL, 0, 0, 0, NULL, &request);
 331                return 0;
 332        ],[
 333                AC_MSG_RESULT([yes])
 334                MXLND="mxlnd"
 335        ],[
 336                AC_MSG_RESULT([no])
 337                case $ENABLEMX in
 338                1) ;;
 339                2) AC_MSG_ERROR([can't compile with Myrinet MX kernel headers]);;
 340                3) AC_MSG_ERROR([can't compile with Myrinet MX headers under $MXPATH]);;
 341                *) AC_MSG_ERROR([internal error]);;
 342                esac
 343                MXLND=""
 344                MXCPPFLAGS=""
 345        ])
 346        EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 347 fi
 348 AC_SUBST(MXCPPFLAGS)
 349 AC_SUBST(MXLIBS)
 350 AC_SUBST(MXLND)
 351 ])
 352
 353
 354
 355 #
 356 # LN_CONFIG_O2IB
 357 #
 358 AC_DEFUN([LN_CONFIG_O2IB],[
 359
 360 AC_MSG_CHECKING([whether to enable OpenIB gen2 support])
 361 # set default
 362 AC_ARG_WITH([o2ib],
 363         AC_HELP_STRING([--with-o2ib=path],
 364                        [build o2iblnd against path]),
 365         [
 366                 case $with_o2ib in
 367                 yes)    O2IBPATHS="$LINUX $LINUX/drivers/infiniband"
 368                         ENABLEO2IB=2
 369                         ;;
 370                 no)     ENABLEO2IB=0
 371                         ;;
 372                 *)      O2IBPATHS=$with_o2ib
 373                         ENABLEO2IB=3
 374                         ;;
 375                 esac
 376         ],[
 377                 O2IBPATHS="$LINUX $LINUX/drivers/infiniband"
 378                 ENABLEO2IB=1
 379         ])
 380 if test $ENABLEO2IB -eq 0; then
 381         AC_MSG_RESULT([disabled])
 382 else
 383         o2ib_found=false
 384         for O2IBPATH in $O2IBPATHS; do
 385                 if test \( -f ${O2IBPATH}/include/rdma/rdma_cm.h -a \
 386                            -f ${O2IBPATH}/include/rdma/ib_cm.h -a \
 387                            -f ${O2IBPATH}/include/rdma/ib_verbs.h -a \
 388                            -f ${O2IBPATH}/include/rdma/ib_fmr_pool.h \); then
 389                         if test \( -d ${O2IBPATH}/kernel_patches -a \
 390                                    -f ${O2IBPATH}/Makefile \); then
 391                                 AC_MSG_RESULT([no])
 392                                 AC_MSG_ERROR([you appear to be trying to use the OFED distribution's source directory (${O2IBPATH}) rather than the "development/headers" directory which is likely in ${O2IBPATH%-*}])
 393                         fi
 394                         o2ib_found=true
 395                         break
 396                 fi
 397         done
 398         if ! $o2ib_found; then
 399                 AC_MSG_RESULT([no])
 400                 case $ENABLEO2IB in
 401                         1) ;;
 402                         2) AC_MSG_ERROR([kernel OpenIB gen2 headers not present]);;
 403                         3) AC_MSG_ERROR([bad --with-o2ib path]);;
 404                         *) AC_MSG_ERROR([internal error]);;
 405                 esac
 406         else
 407                 O2IBCPPFLAGS="-I$O2IBPATH/include"
 408                 EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 409                 EXTRA_KCFLAGS="$EXTRA_KCFLAGS $O2IBCPPFLAGS"
 410                 EXTRA_LNET_INCLUDE="$EXTRA_LNET_INCLUDE $O2IBCPPFLAGS"
 411
 412                 LB_LINUX_TRY_COMPILE([
 413                         #include <linux/version.h>
 414                         #include <linux/pci.h>
 415                         #include <linux/gfp.h>
 416                         #include <rdma/rdma_cm.h>
 417                         #include <rdma/ib_cm.h>
 418                         #include <rdma/ib_verbs.h>
 419                         #include <rdma/ib_fmr_pool.h>
 420                 ],[
 421                         struct rdma_cm_id      *cm_idi __attribute__ ((unused));
 422                         struct rdma_conn_param  conn_param __attribute__ ((unused));
 423                         struct ib_device_attr   device_attr __attribute__ ((unused));
 424                         struct ib_qp_attr       qp_attr __attribute__ ((unused));
 425                         struct ib_pool_fmr      pool_fmr __attribute__ ((unused));
 426                         enum   ib_cm_rej_reason rej_reason __attribute__ ((unused));
 427
 428                         rdma_destroy_id(NULL);
 429                 ],[
 430                         AC_MSG_RESULT([yes])
 431                         O2IBLND="o2iblnd"
 432                 ],[
 433                         AC_MSG_RESULT([no])
 434                         case $ENABLEO2IB in
 435                         1) ;;
 436                         2) AC_MSG_ERROR([can't compile with kernel OpenIB gen2 headers]);;
 437                         3) AC_MSG_ERROR([can't compile with OpenIB gen2 headers under $O2IBPATH]);;
 438                         *) AC_MSG_ERROR([internal error]);;
 439                         esac
 440                         O2IBLND=""
 441                         O2IBCPPFLAGS=""
 442                 ])
 443                 # we know at this point that the found OFED source is good
 444                 O2IB_SYMVER=""
 445                 if test $ENABLEO2IB -eq 3 ; then
 446                         # OFED default rpm not handle sles10 Modules.symvers name
 447                         for name in Module.symvers Modules.symvers; do
 448                                 if test -f $O2IBPATH/$name; then
 449                                         O2IB_SYMVER=$name;
 450                                         break;
 451                                 fi
 452                         done
 453                         if test -n "$O2IB_SYMVER"; then
 454                                 AC_MSG_NOTICE([adding $O2IBPATH/$O2IB_SYMVER to $PWD/$SYMVERFILE])
 455                                 # strip out the existing symbols versions first
 456                                 if test -f $PWD/$SYMVERFILE; then
 457                                 egrep -v $(echo $(awk '{ print $2 }' $O2IBPATH/$O2IB_SYMVER) | tr ' ' '|') $PWD/$SYMVERFILE > $PWD/$SYMVERFILE.old
 458                                 else
 459                                     touch $PWD/$SYMVERFILE.old
 460                                 fi
 461                                 cat $PWD/$SYMVERFILE.old $O2IBPATH/$O2IB_SYMVER > $PWD/$SYMVERFILE
 462                                 rm $PWD/$SYMVERFILE.old
 463                         else
 464                                 AC_MSG_ERROR([an external source tree was specified for o2iblnd however I could not find a $O2IBPATH/Module.symvers there])
 465                         fi
 466                 fi
 467
 468                 LN_CONFIG_OFED_SPEC
 469                 EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 470         fi
 471 fi
 472
 473 AC_SUBST(EXTRA_LNET_INCLUDE)
 474 AC_SUBST(O2IBCPPFLAGS)
 475 AC_SUBST(O2IBLND)
 476
 477 # In RHEL 6.2, rdma_create_id() takes the queue-pair type as a fourth argument
 478 if test $ENABLEO2IB -ne 0; then
 479         AC_MSG_CHECKING([if rdma_create_id wants four args])
 480         LB_LINUX_TRY_COMPILE([
 481                 #include <rdma/rdma_cm.h>
 482         ],[
 483                 rdma_create_id(NULL, NULL, 0, 0);
 484         ],[
 485                 AC_MSG_RESULT([yes])
 486                 AC_DEFINE(HAVE_RDMA_CREATE_ID_4ARG, 1,
 487                         [rdma_create_id wants 4 args])
 488         ],[
 489                 AC_MSG_RESULT([no])
 490         ])
 491 fi
 492 ])
 493
 494 #
 495 # LN_CONFIG_RALND
 496 #
 497 # check whether to use the RapidArray lnd
 498 #
 499 AC_DEFUN([LN_CONFIG_RALND],
 500 [#### Rapid Array
 501 AC_MSG_CHECKING([if RapidArray kernel headers are present])
 502 # placeholder
 503 RACPPFLAGS="-I${LINUX}/drivers/xd1/include"
 504 EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 505 EXTRA_KCFLAGS="$EXTRA_KCFLAGS $RACPPFLAGS"
 506 LB_LINUX_TRY_COMPILE([
 507         #include <linux/types.h>
 508         #include <rapl.h>
 509 ],[
 510         RAP_RETURN          rc;
 511         RAP_PVOID           dev_handle;
 512
 513         rc = RapkGetDeviceByIndex(0, NULL, &dev_handle);
 514
 515         return rc == RAP_SUCCESS ? 0 : 1;
 516 ],[
 517         AC_MSG_RESULT([yes])
 518         RALND="ralnd"
 519 ],[
 520         AC_MSG_RESULT([no])
 521         RALND=""
 522         RACPPFLAGS=""
 523 ])
 524 EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 525 AC_SUBST(RACPPFLAGS)
 526 AC_SUBST(RALND)
 527 ])
 528
 529 #
 530 # LN_CONFIG_GNILND
 531 #
 532 # check whether to use the Gemini Network Interface lnd
 533 #
 534 AC_DEFUN([LN_CONFIG_GNILND],
 535 [#### Gemini Network Interface
 536 AC_MSG_CHECKING([whether to enable GNI lnd])
 537 AC_ARG_ENABLE([gni],
 538         AC_HELP_STRING([--enable-gni],
 539                         [enable GNI lnd]),
 540         [],[enable_gni='no'])
 541 AC_MSG_RESULT([$enable_gni])
 542
 543 if test x$enable_gni = xyes ; then
 544         AC_MSG_CHECKING([if GNI kernel headers are present])
 545         # placeholder
 546         # GNICPPFLAGS was set in spec file
 547         EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 548         EXTRA_KCFLAGS="$EXTRA_KCFLAGS $GNICPPFLAGS"
 549         LB_LINUX_TRY_COMPILE([
 550                 #include <linux/types.h>
 551                 #include <gni_pub.h>
 552         ],[
 553                 gni_cdm_handle_t        kgni_domain;
 554                 gni_return_t            rc;
 555                 int                     rrc;
 556
 557                 rc = gni_cdm_create(0, 1, 1, 0, &kgni_domain);
 558
 559                 rrc = (rc == GNI_RC_SUCCESS) ? 0 : 1;
 560
 561                 return rrc;
 562         ],[
 563                 AC_MSG_RESULT([yes])
 564                 GNILND="gnilnd"
 565         ],[
 566                 AC_MSG_RESULT([no])
 567                 AC_MSG_ERROR([can't compile gnilnd with given GNICPPFLAGS: $GNICPPFLAGS])
 568         ])
 569         # at this point, we have gnilnd basic support, now check for extra features
 570         AC_MSG_CHECKING([to use RCA in gnilnd])
 571         LB_LINUX_TRY_COMPILE([
 572                 #include <linux/types.h>
 573                 #include <gni_pub.h>
 574                 #include <krca_lib.h>
 575         ],[
 576                 gni_cdm_handle_t        kgni_domain;
 577                 gni_return_t            rc;
 578                 krca_ticket_t           ticket = KRCA_NULL_TICKET;
 579                 int                     rrc;
 580                 __u32                   nid = 0, nic_addr;
 581
 582                 rc = gni_cdm_create(0, 1, 1, 0, &kgni_domain);
 583
 584                 rrc = (rc == GNI_RC_SUCCESS) ? 0 : 1;
 585
 586                 rrc += krca_nid_to_nicaddrs(nid, 1, &nic_addr);
 587
 588                 rrc += krca_register(&ticket, RCA_MAKE_SERVICE_INDEX(RCA_IO_CLASS, 9), 99, 0);
 589
 590                 return rrc;
 591         ],[
 592                 AC_MSG_RESULT([yes])
 593                 GNICPPFLAGS="$GNICPPFLAGS -DGNILND_USE_RCA=1"
 594                 GNILNDRCA="gnilndrca"
 595         ],[
 596                 AC_MSG_RESULT([no])
 597         ])
 598         EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 599 fi
 600 AC_SUBST(GNICPPFLAGS)
 601 AC_SUBST(GNILNDRCA)
 602 AC_SUBST(GNILND)
 603 ])
 604
 605
 606 #
 607 #
 608 # LN_CONFIG_USERSPACE
 609 #
 610 # This is defined but empty because it is called from
 611 # build/autconf/lustre-build.m4 which is shared by all branches.
 612 #
 613 AC_DEFUN([LN_CONFIG_USERSPACE],
 614 [
 615 ])
 616
 617 # See if sysctl proc_handler wants only 5 arguments (since 2.6.32)
 618 AC_DEFUN([LN_5ARGS_SYSCTL_PROC_HANDLER],
 619 [AC_MSG_CHECKING([if sysctl proc_handler wants 5 args])
 620 LB_LINUX_TRY_COMPILE([
 621         #include <linux/sysctl.h>
 622 ],[
 623         struct ctl_table *table = NULL;
 624         int write = 1;
 625         void __user *buffer = NULL;
 626         size_t *lenp = NULL;
 627         loff_t *ppos = NULL;
 628
 629         proc_handler *proc_handler = NULL;
 630         proc_handler(table, write, buffer, lenp, ppos);
 631
 632 ],[
 633         AC_MSG_RESULT(yes)
 634         AC_DEFINE(HAVE_5ARGS_SYSCTL_PROC_HANDLER, 1,
 635                   [sysctl proc_handler wants 5 args])
 636 ],[
 637         AC_MSG_RESULT(no)
 638 ])
 639 ])
 640
 641 #
 642 # 2.6.36 tcp_sendpage() first parameter is 'struct sock' instead of 'struct socket'.
 643 #
 644 AC_DEFUN([LN_CONFIG_TCP_SENDPAGE],
 645 [AC_MSG_CHECKING([if tcp_sendpage first parameter is socket])
 646 tmp_flags="$EXTRA_KCFLAGS"
 647 EXTRA_KCFLAGS="-Werror"
 648 LB_LINUX_TRY_COMPILE([
 649         #include <linux/net.h>
 650         #include <net/tcp.h>
 651 ],[
 652         tcp_sendpage((struct socket*)0, NULL, 0, 0, 0);
 653 ],[
 654         AC_MSG_RESULT(yes)
 655         AC_DEFINE(HAVE_TCP_SENDPAGE_USE_SOCKET, 1,
 656                   [tcp_sendpage use socket as first parameter])
 657 ],[
 658         AC_MSG_RESULT(no)
 659 ])
 660 EXTRA_KCFLAGS="$tmp_flags"
 661 ])
 662
 663 #
 664 # LN_PROG_LINUX
 665 #
 666 # LNet linux kernel checks
 667 #
 668 AC_DEFUN([LN_PROG_LINUX],
 669 [
 670 LN_FUNC_DEV_GET_BY_NAME_2ARG
 671 LN_CONFIG_AFFINITY
 672 LN_CONFIG_BACKOFF
 673 LN_CONFIG_QUADRICS
 674 LN_CONFIG_O2IB
 675 LN_CONFIG_RALND
 676 LN_CONFIG_GNILND
 677 LN_CONFIG_PTLLND
 678 LN_CONFIG_MX
 679 # 2.6.32
 680 LN_5ARGS_SYSCTL_PROC_HANDLER
 681 # 2.6.36
 682 LN_CONFIG_TCP_SENDPAGE
 683 ])
 684
 685 #
 686 # LN_PROG_DARWIN
 687 #
 688 # Darwin checks
 689 #
 690 AC_DEFUN([LN_PROG_DARWIN],
 691 [LB_DARWIN_CHECK_FUNCS([get_preemption_level])
 692 ])
 693
 694 #
 695 # LN_PATH_DEFAULTS
 696 #
 697 # default paths for installed files
 698 #
 699 AC_DEFUN([LN_PATH_DEFAULTS],
 700 [
 701 ])
 702
 703 #
 704 # LN_CONFIGURE
 705 #
 706 # other configure checks
 707 #
 708 AC_DEFUN([LN_CONFIGURE],
 709 [# lnet/utils/portals.c
 710 AC_CHECK_HEADERS([netdb.h netinet/tcp.h asm/types.h endian.h sys/ioctl.h])
 711 AC_CHECK_FUNCS([gethostbyname socket connect])
 712
 713 # lnet/utils/debug.c
 714 AC_CHECK_HEADERS([linux/version.h])
 715
 716 # lnet/utils/wirecheck.c
 717 AC_CHECK_FUNCS([strnlen])
 718
 719 # --------  Check for required packages  --------------
 720
 721 #
 722 # LC_CONFIG_READLINE
 723 #
 724 # Build with readline
 725 #
 726 AC_MSG_CHECKING([whether to enable readline support])
 727 AC_ARG_ENABLE(readline,
 728         AC_HELP_STRING([--disable-readline],
 729                         [disable readline support]),
 730         [],[enable_readline='yes'])
 731 AC_MSG_RESULT([$enable_readline])
 732
 733 # -------- check for readline if enabled ----
 734 if test x$enable_readline = xyes ; then
 735         LIBS_save="$LIBS"
 736         LIBS="-lncurses $LIBS"
 737         AC_CHECK_LIB([readline],[readline],[
 738         LIBREADLINE="-lreadline -lncurses"
 739         AC_DEFINE(HAVE_LIBREADLINE, 1, [readline library is available])
 740         ],[
 741         LIBREADLINE=""
 742         ])
 743         LIBS="$LIBS_save"
 744 else
 745         LIBREADLINE=""
 746 fi
 747 AC_SUBST(LIBREADLINE)
 748
 749 # -------- enable acceptor libwrap (TCP wrappers) support? -------
 750 AC_MSG_CHECKING([if libwrap support is requested])
 751 AC_ARG_ENABLE([libwrap],
 752         AC_HELP_STRING([--enable-libwrap], [use TCP wrappers]),
 753         [case "${enableval}" in
 754                 yes) enable_libwrap=yes ;;
 755                 no) enable_libwrap=no ;;
 756                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-libwrap) ;;
 757         esac],[enable_libwrap=no])
 758 AC_MSG_RESULT([$enable_libwrap])
 759 if test x$enable_libwrap = xyes ; then
 760         LIBWRAP="-lwrap"
 761         AC_DEFINE(HAVE_LIBWRAP, 1, [libwrap support is requested])
 762 else
 763         LIBWRAP=""
 764 fi
 765 AC_SUBST(LIBWRAP)
 766
 767 # ----------------------------------------
 768 # some tests for catamount-like systems
 769 # ----------------------------------------
 770 AC_ARG_ENABLE([sysio_init],
 771         AC_HELP_STRING([--disable-sysio-init],
 772                 [call sysio init functions when initializing liblustre]),
 773         [],[enable_sysio_init=yes])
 774 AC_MSG_CHECKING([whether to initialize libsysio])
 775 AC_MSG_RESULT([$enable_sysio_init])
 776 if test x$enable_sysio_init != xno ; then
 777         AC_DEFINE([INIT_SYSIO], 1, [call sysio init functions])
 778 fi
 779
 780 AC_ARG_ENABLE([urandom],
 781         AC_HELP_STRING([--disable-urandom],
 782                 [disable use of /dev/urandom for liblustre]),
 783         [],[enable_urandom=yes])
 784 AC_MSG_CHECKING([whether to use /dev/urandom for liblustre])
 785 AC_MSG_RESULT([$enable_urandom])
 786 if test x$enable_urandom != xno ; then
 787         AC_DEFINE([LIBLUSTRE_USE_URANDOM], 1, [use /dev/urandom for random data])
 788 fi
 789
 790 # -------- check for -lcap support ----
 791 if test x$enable_liblustre = xyes ; then
 792         AC_CHECK_LIB([cap], [cap_get_proc],
 793                 [
 794                         CAP_LIBS="-lcap"
 795                         AC_DEFINE([HAVE_LIBCAP], 1, [use libcap])
 796                 ],
 797                 [
 798                         CAP_LIBS=""
 799                 ])
 800         AC_SUBST(CAP_LIBS)
 801
 802 fi
 803
 804 LN_CONFIG_MAX_PAYLOAD
 805 LN_CONFIG_UPTLLND
 806 LN_CONFIG_USOCKLND
 807 ])
 808
 809 #
 810 # LN_CONDITIONALS
 811 #
 812 # AM_CONDITOINAL defines for lnet
 813 #
 814 AC_DEFUN([LN_CONDITIONALS],
 815 [AM_CONDITIONAL(BUILD_QSWLND, test x$QSWLND = "xqswlnd")
 816 AM_CONDITIONAL(BUILD_MXLND, test x$MXLND = "xmxlnd")
 817 AM_CONDITIONAL(BUILD_O2IBLND, test x$O2IBLND = "xo2iblnd")
 818 AM_CONDITIONAL(BUILD_RALND, test x$RALND = "xralnd")
 819 AM_CONDITIONAL(BUILD_GNILND, test x$GNILND = "xgnilnd")
 820 AM_CONDITIONAL(BUILD_GNILND_RCA, test x$GNILNDRCA = "xgnilndrca")
 821 AM_CONDITIONAL(BUILD_PTLLND, test x$PTLLND = "xptllnd")
 822 AM_CONDITIONAL(BUILD_USOCKLND, test x$USOCKLND = "xusocklnd")
 823 ])
 824
 825 #
 826 # LN_CONFIG_FILES
 827 #
 828 # files that should be generated with AC_OUTPUT
 829 #
 830 AC_DEFUN([LN_CONFIG_FILES],
 831 [AC_CONFIG_FILES([
 832 lnet/Kernelenv
 833 lnet/Makefile
 834 lnet/autoMakefile
 835 lnet/autoconf/Makefile
 836 lnet/doc/Makefile
 837 lnet/include/Makefile
 838 lnet/include/lnet/Makefile
 839 lnet/include/lnet/linux/Makefile
 840 lnet/klnds/Makefile
 841 lnet/klnds/autoMakefile
 842 lnet/klnds/mxlnd/autoMakefile
 843 lnet/klnds/mxlnd/Makefile
 844 lnet/klnds/o2iblnd/Makefile
 845 lnet/klnds/o2iblnd/autoMakefile
 846 lnet/klnds/qswlnd/Makefile
 847 lnet/klnds/qswlnd/autoMakefile
 848 lnet/klnds/ralnd/Makefile
 849 lnet/klnds/ralnd/autoMakefile
 850 lnet/klnds/gnilnd/Makefile
 851 lnet/klnds/gnilnd/autoMakefile
 852 lnet/klnds/socklnd/Makefile
 853 lnet/klnds/socklnd/autoMakefile
 854 lnet/klnds/ptllnd/Makefile
 855 lnet/klnds/ptllnd/autoMakefile
 856 lnet/lnet/Makefile
 857 lnet/lnet/autoMakefile
 858 lnet/selftest/Makefile
 859 lnet/selftest/autoMakefile
 860 lnet/ulnds/Makefile
 861 lnet/ulnds/autoMakefile
 862 lnet/ulnds/socklnd/Makefile
 863 lnet/utils/Makefile
 864 lnet/include/lnet/darwin/Makefile
 865 ])
 866 ])