lnet/autoconf/lustre-lnet.m4

   1 #
   2 # LN_CONFIG_MAX_PAYLOAD
   3 #
   4 # configure maximum payload
   5 #
   6 AC_DEFUN([LN_CONFIG_MAX_PAYLOAD], [
   7 AC_MSG_CHECKING([for non-default maximum LNET payload])
   8 AC_ARG_WITH([max-payload-mb],
   9         AC_HELP_STRING([--with-max-payload-mb=MBytes],
  10                 [set maximum lnet payload in MBytes]),
  11         [
  12                 AC_MSG_RESULT([$with_max_payload_mb])
  13                 CONFIG_LNET_MAX_PAYLOAD_MB=$with_max_payload_mb
  14                 CONFIG_LNET_MAX_PAYLOAD="(($with_max_payload_mb)<<20)"
  15         ], [
  16                 AC_MSG_RESULT([no])
  17                 CONFIG_LNET_MAX_PAYLOAD="LNET_MTU"
  18         ])
  19 AC_DEFINE_UNQUOTED(CONFIG_LNET_MAX_PAYLOAD, $CONFIG_LNET_MAX_PAYLOAD,
  20         [Max LNET payload])
  21 ]) # LN_CONFIG_MAX_PAYLOAD
  22
  23 #
  24 # LN_CHECK_GCC_VERSION
  25 #
  26 # Check compiler version
  27 #
  28 AC_DEFUN([LN_CHECK_GCC_VERSION], [
  29 AC_MSG_CHECKING([compiler version])
  30 PTL_CC_VERSION=`$CC --version | awk '/^gcc/{print $ 3}'`
  31 PTL_MIN_CC_VERSION="3.2.2"
  32 v2n() {
  33         awk -F. '{printf "%d\n", (($ 1)*100+($ 2))*100+($ 3)}'
  34 }
  35 if test -z "$PTL_CC_VERSION" -o \
  36         $(echo $PTL_CC_VERSION | v2n) -ge $(echo $PTL_MIN_CC_VERSION | v2n); then
  37         AC_MSG_RESULT([ok])
  38 else
  39         AC_MSG_RESULT([Buggy compiler found])
  40         AC_MSG_ERROR([Need gcc version >= $PTL_MIN_CC_VERSION])
  41 fi
  42 ]) # LN_CHECK_GCC_VERSION
  43
  44 #
  45 # LN_FUNC_DEV_GET_BY_NAME_2ARG
  46 #
  47 AC_DEFUN([LN_FUNC_DEV_GET_BY_NAME_2ARG], [
  48 LB_CHECK_COMPILE([if 'dev_get_by_name' has two args],
  49 dev_get_by_name_2args, [
  50         #include <linux/netdevice.h>
  51 ],[
  52         dev_get_by_name(NULL, NULL);
  53 ],[
  54         AC_DEFINE(HAVE_DEV_GET_BY_NAME_2ARG, 1,
  55                 [dev_get_by_name has 2 args])
  56 ])
  57 ]) # LN_FUNC_DEV_GET_BY_NAME_2ARG
  58
  59 #
  60 # LN_CONFIG_AFFINITY
  61 #
  62 # check if cpu affinity is available/wanted
  63 #
  64 AC_DEFUN([LN_CONFIG_AFFINITY], [
  65 AC_MSG_CHECKING([whether to enable CPU affinity support])
  66 AC_ARG_ENABLE([affinity],
  67         AC_HELP_STRING([--disable-affinity],
  68                 [disable process/irq affinity]),
  69         [], [enable_affinity="yes"])
  70 AC_MSG_RESULT([$enable_affinity])
  71 AS_IF([test "x$enable_affinity" = xyes], [
  72         LB_CHECK_COMPILE([if Linux kernel has cpu affinity support],
  73         set_cpus_allowed_ptr, [
  74                 #include <linux/sched.h>
  75         ],[
  76                 struct task_struct *t;
  77                 #if HAVE_CPUMASK_T
  78                 cpumask_t     m;
  79                 #else
  80                 unsigned long m;
  81                 #endif
  82                 set_cpus_allowed_ptr(t, &m);
  83         ],[
  84                 AC_DEFINE(CPU_AFFINITY, 1,
  85                         [kernel has cpu affinity support])
  86         ])
  87 ])
  88 ]) # LN_CONFIG_AFFINITY
  89
  90 #
  91 # LN_CONFIG_BACKOFF
  92 #
  93 # check if tunable tcp backoff is available/wanted
  94 #
  95 AC_DEFUN([LN_CONFIG_BACKOFF], [
  96 AC_MSG_CHECKING([whether to enable tunable backoff TCP support])
  97 AC_ARG_ENABLE([backoff],
  98         AC_HELP_STRING([--disable-backoff],
  99                 [disable socknal tunable backoff]),
 100         [], [enable_backoff="yes"])
 101 AC_MSG_RESULT([$enable_backoff])
 102 AS_IF([test "x$enable_backoff" = xyes], [
 103         AC_MSG_CHECKING([if Linux kernel has tunable backoff TCP support])
 104         AS_IF([grep -c TCP_BACKOFF $LINUX/include/linux/tcp.h >/dev/null], [
 105                 AC_MSG_RESULT([yes])
 106                 AC_DEFINE(SOCKNAL_BACKOFF, 1, [use tunable backoff TCP])
 107                 AS_IF([grep rto_max $LINUX/include/linux/tcp.h | grep -q __u16 >/dev/null],
 108                         [AC_DEFINE(SOCKNAL_BACKOFF_MS, 1,
 109                                 [tunable backoff TCP in ms])])
 110         ], [
 111                 AC_MSG_RESULT([no])
 112         ])
 113 ])
 114 ]) # LN_CONFIG_BACKOFF
 115
 116 #
 117 # LN_CONFIG_USOCKLND
 118 #
 119 # configure support for userspace TCP/IP LND
 120 #
 121 AC_DEFUN([LN_CONFIG_USOCKLND], [
 122 AC_MSG_CHECKING([whether to enable usocklnd])
 123 AC_ARG_ENABLE([usocklnd],
 124         AC_HELP_STRING([--disable-usocklnd],
 125                 [disable usocklnd]),
 126         [], [enable_usocklnd="yes"])
 127 AC_MSG_RESULT([$enable_usocklnd])
 128 USOCKLND=""
 129 AS_IF([test "x$enable_usocklnd" = xyes], [
 130         AC_MSG_CHECKING([whether to build usocklnd])
 131         AS_IF([test "$ENABLE_LIBPTHREAD" = yes], [
 132                 AC_MSG_RESULT([yes])
 133                 USOCKLND="usocklnd"
 134         ], [
 135                 AC_MSG_RESULT([no (libpthread not present or disabled)])
 136         ])
 137 ])
 138 AC_SUBST(USOCKLND)
 139 ]) # LN_CONFIG_USOCKLND
 140
 141 #
 142 # LN_CONFIG_QUADRICS
 143 #
 144 # check if quadrics support is in this kernel
 145 #
 146 AC_DEFUN([LN_CONFIG_QUADRICS], [
 147 AC_MSG_CHECKING([for QsNet sources])
 148 AC_ARG_WITH([qsnet],
 149         AC_HELP_STRING([--with-qsnet=path],
 150                 [set path to qsnet source (default=$LINUX)]),
 151         [QSNET=$with_qsnet], [QSNET=$LINUX])
 152 AC_MSG_RESULT([$QSNET])
 153
 154 QSWLND=""
 155 QSWCPPFLAGS=""
 156 AC_MSG_CHECKING([if quadrics kernel headers are present])
 157 AS_IF([test -d $QSNET/drivers/net/qsnet], [
 158         AC_MSG_RESULT([yes])
 159         QSWLND="qswlnd"
 160         AC_MSG_CHECKING([for multirail EKC])
 161         AS_IF([test -f $QSNET/include/elan/epcomms.h], [
 162                 AC_MSG_RESULT([supported])
 163                 QSNET=$(readlink --canonicalize $QSNET)
 164                 QSWCPPFLAGS="-I$QSNET/include -DMULTIRAIL_EKC=1"
 165         ], [
 166                 AC_MSG_RESULT([not supported])
 167                 AC_MSG_ERROR([Need multirail EKC])
 168         ])
 169
 170         AS_IF([test x$QSNET = x$LINUX], [
 171                 LB_CHECK_CONFIG([QSNET], [], [
 172                         LB_CHECK_CONFIG([QSNET_MODULE], [], [
 173                                 AC_MSG_WARN([QSNET is not enabled in this kernel; not building qswlnd.])
 174                                 QSWLND=""
 175                                 QSWCPPFLAGS=""
 176                         ])
 177                 ])
 178         ])
 179 ], [
 180         AC_MSG_RESULT([no])
 181 ])
 182 AC_SUBST(QSWLND)
 183 AC_SUBST(QSWCPPFLAGS)
 184 ]) # LN_CONFIG_QUADRICS
 185
 186 #
 187 # LN_CONFIG_MX
 188 #
 189 AC_DEFUN([LN_CONFIG_MX], [
 190 # set default
 191 MXPATH="/opt/mx"
 192 AC_MSG_CHECKING([whether to enable Myrinet MX support])
 193 AC_ARG_WITH([mx],
 194         AC_HELP_STRING([--with-mx=path],
 195                 [build mxlnd against path]),
 196         [
 197                 case $with_mx in
 198                 yes) ENABLEMX=2 ;;
 199                 no)  ENABLEMX=0 ;;
 200                 *)   ENABLEMX=3; MXPATH=$with_mx ;;
 201                 esac
 202         ],[
 203                 ENABLEMX=1
 204         ])
 205 AS_IF([test $ENABLEMX -eq 0], [
 206         AC_MSG_RESULT([disabled])
 207 ], [test ! \( -f ${MXPATH}/include/myriexpress.h -a \
 208               -f ${MXPATH}/include/mx_kernel_api.h -a \
 209               -f ${MXPATH}/include/mx_pin.h \)], [
 210         AC_MSG_RESULT([no])
 211         case $ENABLEMX in
 212         1) ;;
 213         2) AC_MSG_ERROR([Myrinet MX kernel headers not present]) ;;
 214         3) AC_MSG_ERROR([bad --with-mx path]) ;;
 215         *) AC_MSG_ERROR([internal error]) ;;
 216         esac
 217 ], [
 218         AC_MSG_RESULT([check])
 219         MXPATH=$(readlink --canonicalize $MXPATH)
 220         MXCPPFLAGS="-I$MXPATH/include"
 221         MXLIBS="-L$MXPATH/lib"
 222         EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 223         EXTRA_KCFLAGS="$EXTRA_KCFLAGS $MXCPPFLAGS"
 224         LB_CHECK_COMPILE([if have Myrinet MX support],
 225         myrinet_mx_support, [
 226                 #define MX_KERNEL 1
 227                 #include <mx_extensions.h>
 228                 #include <myriexpress.h>
 229         ],[
 230                 mx_endpoint_t   end;
 231                 mx_status_t     status;
 232                 mx_request_t    request;
 233                 int             result;
 234                 mx_init();
 235                 mx_open_endpoint(MX_ANY_NIC, MX_ANY_ENDPOINT, 0, NULL, 0, &end);
 236                 mx_register_unexp_handler(end, (mx_unexp_handler_t) NULL, NULL);
 237                 mx_wait_any(end, MX_INFINITE, 0LL, 0LL, &status, &result);
 238                 mx_iconnect(end, 0LL, 0, 0, 0, NULL, &request);
 239                 return 0;
 240         ],[
 241                 MXLND="mxlnd"
 242         ],[
 243                 case $ENABLEMX in
 244                 1) ;;
 245                 2) AC_MSG_ERROR([can't compile with Myrinet MX kernel headers]) ;;
 246                 3) AC_MSG_ERROR([can't compile with Myrinet MX headers under $MXPATH]) ;;
 247                 *) AC_MSG_ERROR([internal error]) ;;
 248                 esac
 249                 MXCPPFLAGS=""
 250                 MXLIBS=""
 251                 MXLND=""
 252         ])
 253         EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 254 ])
 255 AC_SUBST(MXCPPFLAGS)
 256 AC_SUBST(MXLIBS)
 257 AC_SUBST(MXLND)
 258 ]) # LN_CONFIG_MX
 259
 260 #
 261 # LN_CONFIG_O2IB
 262 #
 263 AC_DEFUN([LN_CONFIG_O2IB], [
 264 AC_MSG_CHECKING([whether to use Compat RDMA])
 265 AC_ARG_WITH([o2ib],
 266         AC_HELP_STRING([--with-o2ib=path],
 267                 [build o2iblnd against path]),
 268         [
 269                 case $with_o2ib in
 270                 yes)    O2IBPATHS="$LINUX $LINUX/drivers/infiniband"
 271                         ENABLEO2IB=2
 272                         ;;
 273                 no)     ENABLEO2IB=0
 274                         ;;
 275                 *)      O2IBPATHS=$with_o2ib
 276                         ENABLEO2IB=3
 277                         ;;
 278                 esac
 279         ],[
 280                 O2IBPATHS="$LINUX $LINUX/drivers/infiniband"
 281                 ENABLEO2IB=1
 282         ])
 283 AS_IF([test $ENABLEO2IB -eq 0], [
 284         AC_MSG_RESULT([no])
 285 ], [
 286         o2ib_found=false
 287         for O2IBPATH in $O2IBPATHS; do
 288                 AS_IF([test \( -f ${O2IBPATH}/include/rdma/rdma_cm.h -a \
 289                            -f ${O2IBPATH}/include/rdma/ib_cm.h -a \
 290                            -f ${O2IBPATH}/include/rdma/ib_verbs.h -a \
 291                            -f ${O2IBPATH}/include/rdma/ib_fmr_pool.h \)], [
 292                         AS_IF([test \( -d ${O2IBPATH}/kernel_patches -a \
 293                                    -f ${O2IBPATH}/Makefile \)], [
 294                                 AC_MSG_RESULT([no])
 295                                 AC_MSG_ERROR([
 296
 297 you appear to be trying to use the OFED distribution's source
 298 directory (${O2IBPATH}) rather than the "development/headers"
 299 directory which is likely in ${O2IBPATH%-*}
 300 ])
 301                         ])
 302                         o2ib_found=true
 303                         break
 304                 ])
 305         done
 306         if ! $o2ib_found; then
 307                 AC_MSG_RESULT([no])
 308                 case $ENABLEO2IB in
 309                         1) ;;
 310                         2) AC_MSG_ERROR([kernel OpenIB gen2 headers not present]) ;;
 311                         3) AC_MSG_ERROR([bad --with-o2ib path]) ;;
 312                         *) AC_MSG_ERROR([internal error]) ;;
 313                 esac
 314         else
 315                 compatrdma_found=false
 316                 if test -f ${O2IBPATH}/include/linux/compat-2.6.h; then
 317                         AC_MSG_RESULT([yes])
 318                         compatrdma_found=true
 319                         AC_DEFINE(HAVE_COMPAT_RDMA, 1, [compat rdma found])
 320                 else
 321                         AC_MSG_RESULT([no])
 322                 fi
 323                 if ! $compatrdma_found; then
 324                         if test -f "$O2IBPATH/config.mk"; then
 325                                 . "$O2IBPATH/config.mk"
 326                         elif test -f "$O2IBPATH/ofed_patch.mk"; then
 327                                 . "$O2IBPATH/ofed_patch.mk"
 328                         fi
 329                 else
 330                         if test "x$RHEL_KERNEL" = xyes; then
 331                                 case "$RHEL_KERNEL_VERSION" in
 332                                         2.6.32-358*)
 333                                                 EXTRA_OFED_INCLUDE="$EXTRA_OFED_INCLUDE -DCONFIG_COMPAT_RHEL_6_4" ;;
 334                                         2.6.32-431*)
 335                                                 EXTRA_OFED_INCLUDE="$EXTRA_OFED_INCLUDE -DCONFIG_COMPAT_RHEL_6_5" ;;
 336                                 esac
 337                         elif test "x$SUSE_KERNEL" = xyes; then
 338                                 SP=$(grep PATCHLEVEL /etc/SuSE-release | sed -e 's/.*= *//')
 339                                 EXTRA_OFED_INCLUDE="$EXTRA_OFED_INCLUDE -DCONFIG_COMPAT_SLES_11_$SP"
 340                         fi
 341                 fi
 342                 AC_MSG_CHECKING([whether to use any OFED backport headers])
 343                 if test -n "$BACKPORT_INCLUDES"; then
 344                         AC_MSG_RESULT([yes])
 345                         OFED_BACKPORT_PATH="$O2IBPATH/${BACKPORT_INCLUDES/*\/kernel_addons/kernel_addons}/"
 346                         EXTRA_OFED_INCLUDE="-I$OFED_BACKPORT_PATH $EXTRA_OFED_INCLUDE"
 347                 else
 348                         AC_MSG_RESULT([no])
 349                 fi
 350
 351                 O2IBLND=""
 352                 O2IBPATH=$(readlink --canonicalize $O2IBPATH)
 353                 EXTRA_OFED_INCLUDE="$EXTRA_OFED_INCLUDE -I$O2IBPATH/include"
 354                 LB_CHECK_COMPILE([whether to enable OpenIB gen2 support],
 355                 openib_gen2_support, [
 356                         #include <linux/version.h>
 357                         #include <linux/pci.h>
 358                         #include <linux/gfp.h>
 359                         #ifdef HAVE_COMPAT_RDMA
 360                         #include <linux/compat-2.6.h>
 361                         #endif
 362                         #include <rdma/rdma_cm.h>
 363                         #include <rdma/ib_cm.h>
 364                         #include <rdma/ib_verbs.h>
 365                         #include <rdma/ib_fmr_pool.h>
 366                 ],[
 367                         struct rdma_cm_id      *cm_idi __attribute__ ((unused));
 368                         struct rdma_conn_param  conn_param __attribute__ ((unused));
 369                         struct ib_device_attr   device_attr __attribute__ ((unused));
 370                         struct ib_qp_attr       qp_attr __attribute__ ((unused));
 371                         struct ib_pool_fmr      pool_fmr __attribute__ ((unused));
 372                         enum   ib_cm_rej_reason rej_reason __attribute__ ((unused));
 373                         rdma_destroy_id(NULL);
 374                 ],[
 375                         O2IBLND="o2iblnd"
 376                 ],[
 377                         case $ENABLEO2IB in
 378                         1) ;;
 379                         2) AC_MSG_ERROR([can't compile with kernel OpenIB gen2 headers]) ;;
 380                         3) AC_MSG_ERROR([can't compile with OpenIB gen2 headers under $O2IBPATH]) ;;
 381                         *) AC_MSG_ERROR([internal error]) ;;
 382                         esac
 383                 ])
 384                 # we know at this point that the found OFED source is good
 385                 O2IB_SYMVER=""
 386                 if test $ENABLEO2IB -eq 3 ; then
 387                         # OFED default rpm not handle sles10 Modules.symvers name
 388                         for name in Module.symvers Modules.symvers; do
 389                                 if test -f $O2IBPATH/$name; then
 390                                         O2IB_SYMVER=$name;
 391                                         break;
 392                                 fi
 393                         done
 394                         if test -n "$O2IB_SYMVER"; then
 395                                 AC_MSG_NOTICE([adding $O2IBPATH/$O2IB_SYMVER to $PWD/$SYMVERFILE])
 396                                 # strip out the existing symbols versions first
 397                                 if test -f $PWD/$SYMVERFILE; then
 398                                 egrep -v $(echo $(awk '{ print $2 }' $O2IBPATH/$O2IB_SYMVER) | tr ' ' '|') $PWD/$SYMVERFILE > $PWD/$SYMVERFILE.old
 399                                 else
 400                                         touch $PWD/$SYMVERFILE.old
 401                                 fi
 402                                 cat $PWD/$SYMVERFILE.old $O2IBPATH/$O2IB_SYMVER > $PWD/$SYMVERFILE
 403                                 rm $PWD/$SYMVERFILE.old
 404                         else
 405                                 AC_MSG_ERROR([an external source tree was specified for o2iblnd however I could not find a $O2IBPATH/Module.symvers there])
 406                         fi
 407                 fi
 408
 409                 LN_CONFIG_OFED_SPEC
 410         fi
 411 ])
 412 AC_SUBST(EXTRA_OFED_INCLUDE)
 413 AC_SUBST(O2IBLND)
 414
 415 # In RHEL 6.2, rdma_create_id() takes the queue-pair type as a fourth argument
 416 AS_IF([test $ENABLEO2IB -ne 0], [
 417         LB_CHECK_COMPILE([if 'rdma_create_id' wants four args],
 418         rdma_create_id_4args, [
 419                 #ifdef HAVE_COMPAT_RDMA
 420                 #include <linux/compat-2.6.h>
 421                 #endif
 422                 #include <rdma/rdma_cm.h>
 423         ],[
 424                 rdma_create_id(NULL, NULL, 0, 0);
 425         ],[
 426                 AC_DEFINE(HAVE_RDMA_CREATE_ID_4ARG, 1,
 427                         [rdma_create_id wants 4 args])
 428         ])
 429 ])
 430 ]) # LN_CONFIG_O2IB
 431
 432 #
 433 # LN_CONFIG_RALND
 434 #
 435 # check whether to use the RapidArray lnd
 436 #
 437 AC_DEFUN([LN_CONFIG_RALND], [
 438 RALND=""
 439 RACPPFLAGS="-I${LINUX}/drivers/xd1/include"
 440 EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 441 EXTRA_KCFLAGS="$EXTRA_KCFLAGS $RACPPFLAGS"
 442 LB_CHECK_COMPILE([if 'RapidArray' kernel headers are present],
 443 RapkGetDeviceByIndex, [
 444         #include <linux/types.h>
 445         #include <rapl.h>
 446 ],[
 447         RAP_RETURN rc;
 448         RAP_PVOID  dev_handle;
 449         rc = RapkGetDeviceByIndex(0, NULL, &dev_handle);
 450         return rc == RAP_SUCCESS ? 0 : 1;
 451 ],[
 452         RALND="ralnd"
 453 ],[
 454         RACPPFLAGS=""
 455 ])
 456 EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 457 AC_SUBST(RACPPFLAGS)
 458 AC_SUBST(RALND)
 459 ]) # LN_CONFIG_RALND
 460
 461 #
 462 # LN_CONFIG_GNILND
 463 #
 464 # check whether to use the Gemini Network Interface lnd
 465 #
 466 AC_DEFUN([LN_CONFIG_GNILND], [
 467 AC_MSG_CHECKING([whether to enable GNI lnd])
 468 AC_ARG_ENABLE([gni],
 469         AC_HELP_STRING([--enable-gni],
 470                 [enable GNI lnd]),
 471         [], [enable_gni="no"])
 472 AC_MSG_RESULT([$enable_gni])
 473
 474 AS_IF([test "x$enable_gni" = xyes], [
 475         # GNICPPFLAGS was set in spec file
 476         EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 477         EXTRA_KCFLAGS="$EXTRA_KCFLAGS $GNICPPFLAGS"
 478         LB_CHECK_COMPILE([if GNI kernel headers are present],
 479         GNI_header, [
 480                 #include <linux/types.h>
 481                 #include <gni_pub.h>
 482         ],[
 483                 gni_cdm_handle_t kgni_domain;
 484                 gni_return_t     rc;
 485                 int              rrc;
 486                 rc = gni_cdm_create(0, 1, 1, 0, &kgni_domain);
 487                 rrc = (rc == GNI_RC_SUCCESS) ? 0 : 1;
 488                 return rrc;
 489         ],[
 490                 GNILND="gnilnd"
 491         ],[
 492                 AC_MSG_ERROR([can't compile gnilnd with given GNICPPFLAGS: $GNICPPFLAGS])
 493         ])
 494         # at this point, we have gnilnd basic support,
 495         # now check for extra features
 496         LB_CHECK_COMPILE([to use RCA in gnilnd],
 497         RCA_gnilnd, [
 498                 #include <linux/types.h>
 499                 #include <gni_pub.h>
 500                 #include <krca_lib.h>
 501         ],[
 502                 gni_cdm_handle_t kgni_domain;
 503                 gni_return_t     rc;
 504                 krca_ticket_t    ticket = KRCA_NULL_TICKET;
 505                 int              rrc;
 506                 __u32            nid = 0, nic_addr;
 507                 rc = gni_cdm_create(0, 1, 1, 0, &kgni_domain);
 508                 rrc = (rc == GNI_RC_SUCCESS) ? 0 : 1;
 509                 rrc += krca_nid_to_nicaddrs(nid, 1, &nic_addr);
 510                 rrc += krca_register(&ticket, RCA_MAKE_SERVICE_INDEX(RCA_IO_CLASS, 9), 99, 0);
 511                 return rrc;
 512         ],[
 513                 GNICPPFLAGS="$GNICPPFLAGS -DGNILND_USE_RCA=1"
 514                 GNILNDRCA="gnilndrca"
 515         ])
 516         EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 517 ])
 518 AC_SUBST(GNICPPFLAGS)
 519 AC_SUBST(GNILNDRCA)
 520 AC_SUBST(GNILND)
 521 ]) # LN_CONFIG_GNILND
 522
 523 #
 524 # LN_CONFIG_USERSPACE
 525 #
 526 # This is defined but empty because it is called from
 527 # build/autconf/lustre-build.m4 which is shared by all branches.
 528 #
 529 AC_DEFUN([LN_CONFIG_USERSPACE], [
 530 ]) # LN_CONFIG_USERSPACE
 531
 532 #
 533 # LN_CONFIG_TCP_SENDPAGE
 534 #
 535 # 2.6.36 tcp_sendpage() first parameter is 'struct sock' instead of 'struct socket'.
 536 #
 537 AC_DEFUN([LN_CONFIG_TCP_SENDPAGE], [
 538 tmp_flags="$EXTRA_KCFLAGS"
 539 EXTRA_KCFLAGS="-Werror"
 540 LB_CHECK_COMPILE([if 'tcp_sendpage' first parameter is socket],
 541 tcp_sendpage_socket, [
 542         #include <linux/net.h>
 543         #include <net/tcp.h>
 544 ],[
 545         tcp_sendpage((struct socket*)0, NULL, 0, 0, 0);
 546 ],[
 547         AC_DEFINE(HAVE_TCP_SENDPAGE_USE_SOCKET, 1,
 548                 [tcp_sendpage use socket as first parameter])
 549 ])
 550 EXTRA_KCFLAGS="$tmp_flags"
 551 ]) # LN_CONFIG_TCP_SENDPAGE
 552
 553 #
 554 # LN_PROG_LINUX
 555 #
 556 # LNet linux kernel checks
 557 #
 558 AC_DEFUN([LN_PROG_LINUX], [
 559 AC_MSG_NOTICE([LNet kernel checks
 560 ==============================================================================])
 561
 562 LN_FUNC_DEV_GET_BY_NAME_2ARG
 563 LN_CONFIG_AFFINITY
 564 LN_CONFIG_BACKOFF
 565 LN_CONFIG_QUADRICS
 566 LN_CONFIG_O2IB
 567 LN_CONFIG_RALND
 568 LN_CONFIG_GNILND
 569 LN_CONFIG_MX
 570 # 2.6.36
 571 LN_CONFIG_TCP_SENDPAGE
 572 ]) # LN_PROG_LINUX
 573
 574 #
 575 # LN_PROG_DARWIN
 576 #
 577 # Darwin checks
 578 #
 579 AC_DEFUN([LN_PROG_DARWIN], [
 580 LB_DARWIN_CHECK_FUNCS([get_preemption_level])
 581 ]) # LN_PROG_DARWIN
 582
 583 #
 584 # LN_PATH_DEFAULTS
 585 #
 586 # default paths for installed files
 587 #
 588 AC_DEFUN([LN_PATH_DEFAULTS], [
 589 ]) # LN_PATH_DEFAULTS
 590
 591 #
 592 # LN_CONFIGURE
 593 #
 594 # other configure checks
 595 #
 596 AC_DEFUN([LN_CONFIGURE], [
 597 AC_MSG_NOTICE([LNet core checks
 598 ==============================================================================])
 599
 600 # lnet/utils/portals.c
 601 AC_CHECK_HEADERS([netdb.h netinet/tcp.h asm/types.h endian.h sys/ioctl.h])
 602 AC_CHECK_FUNCS([gethostbyname socket connect])
 603
 604 # lnet/utils/debug.c
 605 AC_CHECK_HEADERS([linux/version.h])
 606
 607 # lnet/utils/wirecheck.c
 608 AC_CHECK_FUNCS([strnlen])
 609
 610 # --------  Check for required packages  --------------
 611
 612 #
 613 # LC_CONFIG_READLINE
 614 #
 615 # Build with readline
 616 #
 617 AC_MSG_CHECKING([whether to enable readline support])
 618 AC_ARG_ENABLE(readline,
 619         AC_HELP_STRING([--disable-readline],
 620                 [disable readline support]),
 621         [], [enable_readline="yes"])
 622 AC_MSG_RESULT([$enable_readline])
 623
 624 # -------- check for readline if enabled ----
 625
 626 LIBREADLINE=""
 627 AS_IF([test "x$enable_readline" = xyes], [
 628         AC_CHECK_LIB([readline], [readline], [
 629                 LIBREADLINE="-lreadline"
 630                 AC_DEFINE(HAVE_LIBREADLINE, 1,
 631                         [readline library is available])])
 632 ])
 633 AC_SUBST(LIBREADLINE)
 634
 635 # -------- enable acceptor libwrap (TCP wrappers) support? -------
 636
 637 AC_MSG_CHECKING([if libwrap support is requested])
 638 AC_ARG_ENABLE([libwrap],
 639         AC_HELP_STRING([--enable-libwrap], [use TCP wrappers]),
 640         [case "${enableval}" in
 641                 yes) enable_libwrap="yes" ;;
 642                 no)  enable_libwrap="no" ;;
 643                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-libwrap) ;;
 644         esac], [enable_libwrap="no"])
 645 AC_MSG_RESULT([$enable_libwrap])
 646 LIBWRAP=""
 647 AS_IF([test "x$enable_libwrap" = xyes], [
 648         LIBWRAP="-lwrap"
 649         AC_DEFINE(HAVE_LIBWRAP, 1,
 650                 [libwrap support is requested])
 651 ])
 652 AC_SUBST(LIBWRAP)
 653
 654 LN_CONFIG_MAX_PAYLOAD
 655 LN_CONFIG_USOCKLND
 656 ]) # LN_CONFIGURE
 657
 658 #
 659 # LN_CONDITIONALS
 660 #
 661 # AM_CONDITOINAL defines for lnet
 662 #
 663 AC_DEFUN([LN_CONDITIONALS], [
 664 AM_CONDITIONAL(BUILD_QSWLND,     test x$QSWLND = "xqswlnd")
 665 AM_CONDITIONAL(BUILD_MXLND,      test x$MXLND = "xmxlnd")
 666 AM_CONDITIONAL(BUILD_O2IBLND,    test x$O2IBLND = "xo2iblnd")
 667 AM_CONDITIONAL(BUILD_RALND,      test x$RALND = "xralnd")
 668 AM_CONDITIONAL(BUILD_GNILND,     test x$GNILND = "xgnilnd")
 669 AM_CONDITIONAL(BUILD_GNILND_RCA, test x$GNILNDRCA = "xgnilndrca")
 670 AM_CONDITIONAL(BUILD_USOCKLND,   test x$USOCKLND = "xusocklnd")
 671 ]) # LN_CONDITIONALS
 672
 673 #
 674 # LN_CONFIG_FILES
 675 #
 676 # files that should be generated with AC_OUTPUT
 677 #
 678 AC_DEFUN([LN_CONFIG_FILES], [
 679 AC_CONFIG_FILES([
 680 lnet/Kernelenv
 681 lnet/Makefile
 682 lnet/autoMakefile
 683 lnet/autoconf/Makefile
 684 lnet/doc/Makefile
 685 lnet/include/Makefile
 686 lnet/include/lnet/Makefile
 687 lnet/include/lnet/linux/Makefile
 688 lnet/klnds/Makefile
 689 lnet/klnds/autoMakefile
 690 lnet/klnds/mxlnd/autoMakefile
 691 lnet/klnds/mxlnd/Makefile
 692 lnet/klnds/o2iblnd/Makefile
 693 lnet/klnds/o2iblnd/autoMakefile
 694 lnet/klnds/qswlnd/Makefile
 695 lnet/klnds/qswlnd/autoMakefile
 696 lnet/klnds/ralnd/Makefile
 697 lnet/klnds/ralnd/autoMakefile
 698 lnet/klnds/gnilnd/Makefile
 699 lnet/klnds/gnilnd/autoMakefile
 700 lnet/klnds/socklnd/Makefile
 701 lnet/klnds/socklnd/autoMakefile
 702 lnet/lnet/Makefile
 703 lnet/lnet/autoMakefile
 704 lnet/selftest/Makefile
 705 lnet/selftest/autoMakefile
 706 lnet/ulnds/Makefile
 707 lnet/ulnds/autoMakefile
 708 lnet/ulnds/socklnd/Makefile
 709 lnet/utils/Makefile
 710 lnet/include/lnet/darwin/Makefile
 711 ])
 712 ]) # LN_CONFIG_FILES