lnet/autoconf/lustre-lnet.m4

   1 #
   2 # LN_CONFIG_MAX_PAYLOAD
   3 #
   4 # configure maximum payload
   5 #
   6 AC_DEFUN([LN_CONFIG_MAX_PAYLOAD],
   7 [AC_MSG_CHECKING([for non-default maximum LNET payload])
   8 AC_ARG_WITH([max-payload-mb],
   9         AC_HELP_STRING([--with-max-payload-mb=MBytes],
  10                        [set maximum lnet payload in MBytes]),
  11         [
  12                 AC_MSG_RESULT([$with_max_payload_mb])
  13                 LNET_MAX_PAYLOAD_MB=$with_max_payload_mb
  14                 LNET_MAX_PAYLOAD="(($with_max_payload_mb)<<20)"
  15         ], [
  16                 AC_MSG_RESULT([no])
  17                 LNET_MAX_PAYLOAD="LNET_MTU"
  18         ])
  19         AC_DEFINE_UNQUOTED(LNET_MAX_PAYLOAD, $LNET_MAX_PAYLOAD,
  20                            [Max LNET payload])
  21 ])
  22
  23 #
  24 # LN_CHECK_GCC_VERSION
  25 #
  26 # Check compiler version
  27 #
  28 AC_DEFUN([LN_CHECK_GCC_VERSION],
  29 [AC_MSG_CHECKING([compiler version])
  30 PTL_CC_VERSION=`$CC --version | awk '/^gcc/{print $ 3}'`
  31 PTL_MIN_CC_VERSION="3.2.2"
  32 v2n() {
  33         awk -F. '{printf "%d\n", (($ 1)*100+($ 2))*100+($ 3)}'
  34 }
  35 if test -z "$PTL_CC_VERSION" -o \
  36         `echo $PTL_CC_VERSION | v2n` -ge `echo $PTL_MIN_CC_VERSION | v2n`; then
  37         AC_MSG_RESULT([ok])
  38 else
  39         AC_MSG_RESULT([Buggy compiler found])
  40         AC_MSG_ERROR([Need gcc version >= $PTL_MIN_CC_VERSION])
  41 fi
  42 ])
  43
  44 #
  45 # LC_CONFIG_CDEBUG
  46 #
  47 # whether to enable various libcfs debugs (CDEBUG, ENTRY/EXIT, LASSERT, etc.)
  48 #
  49 AC_DEFUN([LC_CONFIG_CDEBUG],
  50 [
  51 AC_MSG_CHECKING([whether to enable CDEBUG, CWARN])
  52 AC_ARG_ENABLE([libcfs_cdebug],
  53         AC_HELP_STRING([--disable-libcfs-cdebug],
  54                         [disable libcfs CDEBUG, CWARN]),
  55         [],[enable_libcfs_cdebug='yes'])
  56 AC_MSG_RESULT([$enable_libcfs_cdebug])
  57 if test x$enable_libcfs_cdebug = xyes; then
  58    AC_DEFINE(CDEBUG_ENABLED, 1, [enable libcfs CDEBUG, CWARN])
  59 else
  60    AC_DEFINE(CDEBUG_ENABLED, 0, [disable libcfs CDEBUG, CWARN])
  61 fi
  62
  63 AC_MSG_CHECKING([whether to enable ENTRY/EXIT])
  64 AC_ARG_ENABLE([libcfs_trace],
  65         AC_HELP_STRING([--disable-libcfs-trace],
  66                         [disable libcfs ENTRY/EXIT]),
  67         [],[enable_libcfs_trace='yes'])
  68 AC_MSG_RESULT([$enable_libcfs_trace])
  69 if test x$enable_libcfs_trace = xyes; then
  70    AC_DEFINE(CDEBUG_ENTRY_EXIT, 1, [enable libcfs ENTRY/EXIT])
  71 else
  72    AC_DEFINE(CDEBUG_ENTRY_EXIT, 0, [disable libcfs ENTRY/EXIT])
  73 fi
  74
  75 AC_MSG_CHECKING([whether to enable LASSERT, LASSERTF])
  76 AC_ARG_ENABLE([libcfs_assert],
  77         AC_HELP_STRING([--disable-libcfs-assert],
  78                         [disable libcfs LASSERT, LASSERTF]),
  79         [],[enable_libcfs_assert='yes'])
  80 AC_MSG_RESULT([$enable_libcfs_assert])
  81 if test x$enable_libcfs_assert = xyes; then
  82    AC_DEFINE(LIBCFS_DEBUG, 1, [enable libcfs LASSERT, LASSERTF])
  83 fi
  84 ])
  85
  86 #
  87 # LN_CONFIG_AFFINITY
  88 #
  89 # check if cpu affinity is available/wanted
  90 #
  91 AC_DEFUN([LN_CONFIG_AFFINITY],
  92 [AC_ARG_ENABLE([affinity],
  93         AC_HELP_STRING([--disable-affinity],
  94                        [disable process/irq affinity]),
  95         [],[enable_affinity='yes'])
  96
  97 AC_MSG_CHECKING([for CPU affinity support])
  98 if test x$enable_affinity = xno ; then
  99         AC_MSG_RESULT([no (by request)])
 100 else
 101         LB_LINUX_TRY_COMPILE([
 102                 #include <linux/sched.h>
 103         ],[
 104                 struct task_struct t;
 105                 #if HAVE_CPUMASK_T
 106                 cpumask_t     m;
 107                 #else
 108                 unsigned long m;
 109                 #endif
 110                 set_cpus_allowed(&t, m);
 111         ],[
 112                 AC_DEFINE(CPU_AFFINITY, 1, [kernel has cpu affinity support])
 113                 AC_MSG_RESULT([yes])
 114         ],[
 115                 AC_MSG_RESULT([no (no kernel support)])
 116         ])
 117 fi
 118 ])
 119
 120 #
 121 # LN_CONFIG_PORTALS
 122 #
 123 # configure support for Portals
 124 #
 125 AC_DEFUN([LN_CONFIG_PORTALS],
 126 [AC_MSG_CHECKING([for portals])
 127 AC_ARG_WITH([portals],
 128         AC_HELP_STRING([--with-portals=path],
 129                        [set path to portals]),
 130         [
 131                 case $with_portals in
 132                         no)     ENABLEPORTALS=0
 133                                 ;;
 134                         *)      PORTALS="${with_portals}"
 135                                 ENABLEPORTALS=1
 136                                 ;;
 137                 esac
 138
 139         ], [
 140                 ENABLEPORTALS=0
 141         ])
 142 PTLLNDCPPFLAGS=""
 143 if test $ENABLEPORTALS -eq 0; then
 144         AC_MSG_RESULT([no])
 145 elif test ! \( -f ${PORTALS}/include/portals/p30.h \); then
 146         AC_MSG_RESULT([no])
 147         AC_MSG_ERROR([bad --with-portals path])
 148 else
 149         AC_MSG_RESULT([$PORTALS])
 150         PTLLNDCPPFLAGS="-I${PORTALS}/include"
 151 fi
 152 AC_SUBST(PTLLNDCPPFLAGS)
 153 ])
 154
 155 #
 156 # LN_CONFIG_BACKOFF
 157 #
 158 # check if tunable tcp backoff is available/wanted
 159 #
 160 AC_DEFUN([LN_CONFIG_BACKOFF],
 161 [AC_MSG_CHECKING([for tunable backoff TCP support])
 162 AC_ARG_ENABLE([backoff],
 163        AC_HELP_STRING([--disable-backoff],
 164                       [disable socknal tunable backoff]),
 165        [],[enable_backoff='yes'])
 166 if test x$enable_backoff = xno ; then
 167        AC_MSG_RESULT([no (by request)])
 168 else
 169        BOCD="`grep -c TCP_BACKOFF $LINUX/include/linux/tcp.h`"
 170        if test "$BOCD" != 0 ; then
 171                AC_DEFINE(SOCKNAL_BACKOFF, 1, [use tunable backoff TCP])
 172                AC_MSG_RESULT(yes)
 173        else
 174                AC_MSG_RESULT([no (no kernel support)])
 175        fi
 176 fi
 177 ])
 178
 179 #
 180 # LN_CONFIG_PANIC_DUMPLOG
 181 #
 182 # check if tunable panic_dumplog is wanted
 183 #
 184 AC_DEFUN([LN_CONFIG_PANIC_DUMPLOG],
 185 [AC_MSG_CHECKING([for tunable panic_dumplog support])
 186 AC_ARG_ENABLE([panic_dumplog],
 187        AC_HELP_STRING([--enable-panic_dumplog],
 188                       [enable panic_dumplog]),
 189        [],[enable_panic_dumplog='no'])
 190 if test x$enable_panic_dumplog = xyes ; then
 191        AC_DEFINE(LNET_DUMP_ON_PANIC, 1, [use dumplog on panic])
 192        AC_MSG_RESULT([yes (by request)])
 193 else
 194        AC_MSG_RESULT([no])
 195 fi
 196 ])
 197
 198 #
 199 # LN_CONFIG_PTLLND
 200 #
 201 # configure support for Portals LND
 202 #
 203 AC_DEFUN([LN_CONFIG_PTLLND],
 204 [
 205 if test -z "$ENABLEPORTALS"; then
 206         LN_CONFIG_PORTALS
 207 fi
 208
 209 AC_MSG_CHECKING([whether to build the kernel portals LND])
 210
 211 PTLLND=""
 212 if test $ENABLEPORTALS -ne 0; then
 213         AC_MSG_RESULT([yes])
 214         PTLLND="ptllnd"
 215 else
 216         AC_MSG_RESULT([no])
 217 fi
 218 AC_SUBST(PTLLND)
 219 ])
 220
 221 #
 222 # LN_CONFIG_UPTLLND
 223 #
 224 # configure support for Portals LND
 225 #
 226 AC_DEFUN([LN_CONFIG_UPTLLND],
 227 [
 228 if test -z "$ENABLEPORTALS"; then
 229         LN_CONFIG_PORTALS
 230 fi
 231
 232 AC_MSG_CHECKING([whether to build the userspace portals LND])
 233
 234 UPTLLND=""
 235 if test $ENABLEPORTALS -ne 0; then
 236         AC_MSG_RESULT([yes])
 237         UPTLLND="ptllnd"
 238 else
 239         AC_MSG_RESULT([no])
 240 fi
 241 AC_SUBST(UPTLLND)
 242 ])
 243
 244 #
 245 # LN_CONFIG_USOCKLND
 246 #
 247 # configure support for userspace TCP/IP LND
 248 #
 249 AC_DEFUN([LN_CONFIG_USOCKLND],
 250 [AC_MSG_CHECKING([whether to build usocklnd])
 251 AC_ARG_ENABLE([usocklnd],
 252         AC_HELP_STRING([--disable-usocklnd],
 253                         [disable usocklnd]),
 254         [],[enable_usocklnd='yes'])
 255
 256 if test x$enable_usocklnd = xyes ; then
 257         if test "$ENABLE_LIBPTHREAD" = "yes" ; then
 258                 AC_MSG_RESULT([yes])
 259                 USOCKLND="usocklnd"
 260         else
 261                 AC_MSG_RESULT([no (libpthread not present or disabled)])
 262                 USOCKLND=""
 263         fi
 264 else
 265         AC_MSG_RESULT([no (disabled explicitly)])
 266         USOCKLND=""
 267 fi
 268 AC_SUBST(USOCKLND)
 269 ])
 270
 271 #
 272 # LN_CONFIG_QUADRICS
 273 #
 274 # check if quadrics support is in this kernel
 275 #
 276 AC_DEFUN([LN_CONFIG_QUADRICS],
 277 [AC_MSG_CHECKING([for QsNet sources])
 278 AC_ARG_WITH([qsnet],
 279         AC_HELP_STRING([--with-qsnet=path],
 280                        [set path to qsnet source (default=$LINUX)]),
 281         [QSNET=$with_qsnet],
 282         [QSNET=$LINUX])
 283 AC_MSG_RESULT([$QSNET])
 284
 285 AC_MSG_CHECKING([if quadrics kernel headers are present])
 286 if test -d $QSNET/drivers/net/qsnet ; then
 287         AC_MSG_RESULT([yes])
 288         QSWLND="qswlnd"
 289         AC_MSG_CHECKING([for multirail EKC])
 290         if test -f $QSNET/include/elan/epcomms.h; then
 291                 AC_MSG_RESULT([supported])
 292                 QSWCPPFLAGS="-I$QSNET/include -DMULTIRAIL_EKC=1"
 293         else
 294                 AC_MSG_RESULT([not supported])
 295                 AC_MSG_ERROR([Need multirail EKC])
 296         fi
 297
 298         if test x$QSNET = x$LINUX ; then
 299                 LB_LINUX_CONFIG([QSNET],[],[
 300                         LB_LINUX_CONFIG([QSNET_MODULE],[],[
 301                                 AC_MSG_WARN([QSNET is not enabled in this kernel; not building qswlnd.])
 302                                 QSWLND=""
 303                                 QSWCPPFLAGS=""
 304                         ])
 305                 ])
 306         fi
 307 else
 308         AC_MSG_RESULT([no])
 309         QSWLND=""
 310         QSWCPPFLAGS=""
 311 fi
 312 AC_SUBST(QSWCPPFLAGS)
 313 AC_SUBST(QSWLND)
 314 ])
 315
 316 #
 317 # LN_CONFIG_GM
 318 #
 319 # check if GM support is available
 320 #
 321 AC_DEFUN([LN_CONFIG_GM],[
 322 AC_MSG_CHECKING([whether to enable GM support])
 323 AC_ARG_WITH([gm],
 324         AC_HELP_STRING([--with-gm=path-to-gm-source-tree],
 325                        [build gmlnd against path]),
 326         [
 327                 case $with_gm in
 328                 no)    ENABLE_GM=0
 329                        ;;
 330                 *)     ENABLE_GM=1
 331                        GM_SRC="$with_gm"
 332                        ;;
 333                 esac
 334         ],[
 335                 ENABLE_GM=0
 336         ])
 337 AC_ARG_WITH([gm-install],
 338         AC_HELP_STRING([--with-gm-install=path-to-gm-install-tree],
 339                        [say where GM has been installed]),
 340         [
 341                 GM_INSTALL=$with_gm_install
 342         ],[
 343                 GM_INSTALL="/opt/gm"
 344         ])
 345 if test $ENABLE_GM -eq 0; then
 346         AC_MSG_RESULT([no])
 347 else
 348         AC_MSG_RESULT([yes])
 349
 350         GMLND="gmlnd"
 351         GMCPPFLAGS="-I$GM_SRC/include -I$GM_SRC/drivers -I$GM_SRC/drivers/linux/gm"
 352
 353         if test -f $GM_INSTALL/lib/libgm.a -o \
 354                 -f $GM_INSTALL/lib64/libgm.a; then
 355                 GMLIBS="-L$GM_INSTALL/lib -L$GM_INSTALL/lib64"
 356         else
 357                 AC_MSG_ERROR([Cant find GM libraries under $GM_INSTALL])
 358         fi
 359
 360         EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 361         EXTRA_KCFLAGS="$GMCPPFLAGS -DGM_KERNEL $EXTRA_KCFLAGS"
 362
 363         AC_MSG_CHECKING([that code using GM compiles with given path])
 364         LB_LINUX_TRY_COMPILE([
 365                 #define GM_STRONG_TYPES 1
 366                 #ifdef VERSION
 367                 #undef VERSION
 368                 #endif
 369                 #include "gm.h"
 370                 #include "gm_internal.h"
 371         ],[
 372                 struct gm_port *port = NULL;
 373                 gm_recv_event_t *rxevent = gm_blocking_receive_no_spin(port);
 374                 return 0;
 375         ],[
 376                 AC_MSG_RESULT([yes])
 377         ],[
 378                 AC_MSG_RESULT([no])
 379                 AC_MSG_ERROR([Bad --with-gm path])
 380         ])
 381
 382         AC_MSG_CHECKING([that GM has gm_register_memory_ex_phys()])
 383         LB_LINUX_TRY_COMPILE([
 384                 #define GM_STRONG_TYPES 1
 385                 #ifdef VERSION
 386                 #undef VERSION
 387                 #endif
 388                 #include "gm.h"
 389                 #include "gm_internal.h"
 390         ],[
 391                 gm_status_t     gmrc;
 392                 struct gm_port *port = NULL;
 393                 gm_u64_t        phys = 0;
 394                 gm_up_t         pvma = 0;
 395
 396                 gmrc = gm_register_memory_ex_phys(port, phys, 100, pvma);
 397                 return 0;
 398         ],[
 399                 AC_MSG_RESULT([yes])
 400         ],[
 401                 AC_MSG_RESULT([no.
 402 Please patch the GM sources as follows...
 403     cd $GM_SRC
 404     patch -p0 < $PWD/lnet/klnds/gmlnd/gm-reg-phys.patch
 405 ...then rebuild and re-install them])
 406                 AC_MSG_ERROR([Can't build GM without gm_register_memory_ex_phys()])
 407         ])
 408
 409         EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 410 fi
 411 AC_SUBST(GMCPPFLAGS)
 412 AC_SUBST(GMLIBS)
 413 AC_SUBST(GMLND)
 414 ])
 415
 416
 417 #
 418 # LN_CONFIG_MX
 419 #
 420 AC_DEFUN([LN_CONFIG_MX],
 421 [AC_MSG_CHECKING([whether to enable Myrinet MX support])
 422 # set default
 423 MXPATH="/opt/mx"
 424 AC_ARG_WITH([mx],
 425        AC_HELP_STRING([--with-mx=path],
 426                       [build mxlnd against path]),
 427        [
 428                case $with_mx in
 429                yes)    ENABLEMX=2
 430                        ;;
 431                no)     ENABLEMX=0
 432                        ;;
 433                *)      MXPATH=$with_mx
 434                        ENABLEMX=3
 435                        ;;
 436                esac
 437        ],[
 438                ENABLEMX=1
 439        ])
 440 if test $ENABLEMX -eq 0; then
 441        AC_MSG_RESULT([disabled])
 442 elif test ! \( -f ${MXPATH}/include/myriexpress.h -a \
 443               -f ${MXPATH}/include/mx_kernel_api.h -a \
 444               -f ${MXPATH}/include/mx_pin.h \); then
 445        AC_MSG_RESULT([no])
 446        case $ENABLEMX in
 447        1) ;;
 448        2) AC_MSG_ERROR([Myrinet MX kernel headers not present]);;
 449        3) AC_MSG_ERROR([bad --with-mx path]);;
 450        *) AC_MSG_ERROR([internal error]);;
 451        esac
 452 else
 453        MXCPPFLAGS="-I$MXPATH/include"
 454        EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 455        EXTRA_KCFLAGS="$EXTRA_KCFLAGS $MXCPPFLAGS"
 456        MXLIBS="-L$MXPATH/lib"
 457        LB_LINUX_TRY_COMPILE([
 458                #define MX_KERNEL 1
 459                #include <mx_extensions.h>
 460                #include <myriexpress.h>
 461        ],[
 462                mx_endpoint_t   end;
 463                mx_status_t     status;
 464                mx_request_t    request;
 465                int             result;
 466
 467                mx_init();
 468                mx_open_endpoint(MX_ANY_NIC, MX_ANY_ENDPOINT, 0, NULL, 0, &end);
 469                mx_register_unexp_handler(end, (mx_unexp_handler_t) NULL, NULL);
 470                mx_wait_any(end, MX_INFINITE, 0LL, 0LL, &status, &result);
 471                mx_iconnect(end, 0LL, 0, 0, 0, NULL, &request);
 472                return 0;
 473        ],[
 474                AC_MSG_RESULT([yes])
 475                MXLND="mxlnd"
 476        ],[
 477                AC_MSG_RESULT([no])
 478                case $ENABLEMX in
 479                1) ;;
 480                2) AC_MSG_ERROR([can't compile with Myrinet MX kernel headers]);;
 481                3) AC_MSG_ERROR([can't compile with Myrinet MX headers under $MXPATH]);;
 482                *) AC_MSG_ERROR([internal error]);;
 483                esac
 484                MXLND=""
 485                MXCPPFLAGS=""
 486        ])
 487        EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 488 fi
 489 AC_SUBST(MXCPPFLAGS)
 490 AC_SUBST(MXLIBS)
 491 AC_SUBST(MXLND)
 492 ])
 493
 494
 495
 496 #
 497 # LN_CONFIG_O2IB
 498 #
 499 AC_DEFUN([LN_CONFIG_O2IB],[
 500 AC_MSG_CHECKING([whether to enable OpenIB gen2 support])
 501 # set default
 502 O2IBPATH="$LINUX/drivers/infiniband"
 503 AC_ARG_WITH([o2ib],
 504         AC_HELP_STRING([--with-o2ib=path],
 505                        [build o2iblnd against path]),
 506         [
 507                 case $with_o2ib in
 508                 yes)    ENABLEO2IB=2
 509                         ;;
 510                 no)     ENABLEO2IB=0
 511                         ;;
 512                 *)      O2IBPATH=$with_o2ib
 513                         ENABLEO2IB=3
 514                         ;;
 515                 esac
 516         ],[
 517                 ENABLEO2IB=1
 518         ])
 519 if test $ENABLEO2IB -eq 0; then
 520         AC_MSG_RESULT([disabled])
 521 elif test ! \( -f ${O2IBPATH}/include/rdma/rdma_cm.h -a \
 522                -f ${O2IBPATH}/include/rdma/ib_cm.h -a\
 523                -f ${O2IBPATH}/include/rdma/ib_verbs.h -a\
 524                -f ${O2IBPATH}/include/rdma/ib_fmr_pool.h \); then
 525         AC_MSG_RESULT([no])
 526         case $ENABLEO2IB in
 527         1) ;;
 528         2) AC_MSG_ERROR([kernel OpenIB gen2 headers not present]);;
 529         3) AC_MSG_ERROR([bad --with-o2ib path]);;
 530         *) AC_MSG_ERROR([internal error]);;
 531         esac
 532 else
 533         O2IBCPPFLAGS="-I$O2IBPATH/include"
 534         EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 535         EXTRA_KCFLAGS="$EXTRA_KCFLAGS $O2IBCPPFLAGS"
 536         LB_LINUX_TRY_COMPILE([
 537                 #include <linux/version.h>
 538                 #if !HAVE_GFP_T
 539                 typedef int gfp_t;
 540                 #endif
 541                 #include <rdma/rdma_cm.h>
 542                 #include <rdma/ib_cm.h>
 543                 #include <rdma/ib_verbs.h>
 544                 #include <rdma/ib_fmr_pool.h>
 545         ],[
 546                 struct rdma_cm_id          *cm_id;
 547                 struct rdma_conn_param      conn_param;
 548                 struct ib_device_attr       device_attr;
 549                 struct ib_qp_attr           qp_attr;
 550                 struct ib_pool_fmr          pool_fmr;
 551                 enum   ib_cm_rej_reason     rej_reason;
 552
 553                 cm_id = rdma_create_id(NULL, NULL, RDMA_PS_TCP);
 554                 return PTR_ERR(cm_id);
 555         ],[
 556                 AC_MSG_RESULT([yes])
 557                 O2IBLND="o2iblnd"
 558         ],[
 559                 AC_MSG_RESULT([no])
 560                 case $ENABLEO2IB in
 561                 1) ;;
 562                 2) AC_MSG_ERROR([can't compile with kernel OpenIB gen2 headers]);;
 563                 3) AC_MSG_ERROR([can't compile with OpenIB gen2 headers under $O2IBPATH]);;
 564                 *) AC_MSG_ERROR([internal error]);;
 565                 esac
 566                 O2IBLND=""
 567                 O2IBCPPFLAGS=""
 568         ])
 569         EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 570 fi
 571 AC_SUBST(O2IBCPPFLAGS)
 572 AC_SUBST(O2IBLND)
 573 ])
 574
 575 #
 576 # LN_CONFIG_OPENIB
 577 #
 578 # check for OpenIB in the kernel
 579 AC_DEFUN([LN_CONFIG_OPENIB],[
 580 AC_MSG_CHECKING([whether to enable OpenIB support])
 581 # set default
 582 OPENIBPATH="$LINUX/drivers/infiniband"
 583 AC_ARG_WITH([openib],
 584         AC_HELP_STRING([--with-openib=path],
 585                        [build openiblnd against path]),
 586         [
 587                 case $with_openib in
 588                 yes)    ENABLEOPENIB=2
 589                         ;;
 590                 no)     ENABLEOPENIB=0
 591                         ;;
 592                 *)      OPENIBPATH="$with_openib"
 593                         ENABLEOPENIB=3
 594                         ;;
 595                 esac
 596         ],[
 597                 ENABLEOPENIB=1
 598         ])
 599 if test $ENABLEOPENIB -eq 0; then
 600         AC_MSG_RESULT([disabled])
 601 elif test ! \( -f ${OPENIBPATH}/include/ts_ib_core.h -a \
 602                -f ${OPENIBPATH}/include/ts_ib_cm.h -a\
 603                -f ${OPENIBPATH}/include/ts_ib_sa_client.h \); then
 604         AC_MSG_RESULT([no])
 605         case $ENABLEOPENIB in
 606         1) ;;
 607         2) AC_MSG_ERROR([kernel OpenIB headers not present]);;
 608         3) AC_MSG_ERROR([bad --with-openib path]);;
 609         *) AC_MSG_ERROR([internal error]);;
 610         esac
 611 else
 612         case $ENABLEOPENIB in
 613         1|2) OPENIBCPPFLAGS="-I$OPENIBPATH/include -DIN_TREE_BUILD";;
 614         3)   OPENIBCPPFLAGS="-I$OPENIBPATH/include";;
 615         *)   AC_MSG_RESULT([no])
 616              AC_MSG_ERROR([internal error]);;
 617         esac
 618         OPENIBCPPFLAGS="$OPENIBCPPFLAGS -DIB_NTXRXPARAMS=4"
 619         EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 620         EXTRA_KCFLAGS="$EXTRA_KCFLAGS $OPENIBCPPFLAGS"
 621         LB_LINUX_TRY_COMPILE([
 622                 #include <ts_ib_core.h>
 623                 #include <ts_ib_cm.h>
 624                 #include <ts_ib_sa_client.h>
 625         ],[
 626                 struct ib_device_properties dev_props;
 627                 struct ib_cm_active_param   cm_active_params;
 628                 tTS_IB_CLIENT_QUERY_TID     tid;
 629                 int                         enum1 = IB_QP_ATTRIBUTE_STATE;
 630                 int                         enum2 = IB_ACCESS_LOCAL_WRITE;
 631                 int                         enum3 = IB_CQ_CALLBACK_INTERRUPT;
 632                 int                         enum4 = IB_CQ_PROVIDER_REARM;
 633                 return 0;
 634         ],[
 635                 AC_MSG_RESULT([yes])
 636                 OPENIBLND="openiblnd"
 637         ],[
 638                 AC_MSG_RESULT([no])
 639                 case $ENABLEOPENIB in
 640                 1) ;;
 641                 2) AC_MSG_ERROR([can't compile with kernel OpenIB headers]);;
 642                 3) AC_MSG_ERROR([can't compile with OpenIB headers under $OPENIBPATH]);;
 643                 *) AC_MSG_ERROR([internal error]);;
 644                 esac
 645                 OPENIBLND=""
 646                 OPENIBCPPFLAGS=""
 647         ])
 648         EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 649 fi
 650 AC_SUBST(OPENIBCPPFLAGS)
 651 AC_SUBST(OPENIBLND)
 652 ])
 653
 654 #
 655 # LN_CONFIG_CIBLND
 656 #
 657 AC_DEFUN([LN_CONFIG_CIB],[
 658 AC_MSG_CHECKING([whether to enable Cisco/TopSpin IB support])
 659 # set default
 660 CIBPATH=""
 661 CIBLND=""
 662 AC_ARG_WITH([cib],
 663         AC_HELP_STRING([--with-cib=path],
 664                        [build ciblnd against path]),
 665         [
 666                 case $with_cib in
 667                 no)     AC_MSG_RESULT([no]);;
 668                 *)      CIBPATH="$with_cib"
 669                         if test -d "$CIBPATH"; then
 670                                 AC_MSG_RESULT([yes])
 671                         else
 672                                 AC_MSG_RESULT([no])
 673                                 AC_MSG_ERROR([No directory $CIBPATH])
 674                         fi;;
 675                 esac
 676         ],[
 677                 AC_MSG_RESULT([no])
 678         ])
 679 if test -n "$CIBPATH"; then
 680         CIBCPPFLAGS="-I${CIBPATH}/ib/ts_api_ng/include -I${CIBPATH}/all/kernel_services/include -DUSING_TSAPI"
 681         CIBCPPFLAGS="$CIBCPPFLAGS -DIB_NTXRXPARAMS=3"
 682         EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 683         EXTRA_KCFLAGS="$EXTRA_KCFLAGS $CIBCPPFLAGS"
 684         LB_LINUX_TRY_COMPILE([
 685                 #include <ts_ib_core.h>
 686                 #include <ts_ib_cm.h>
 687                 #include <ts_ib_sa_client.h>
 688         ],[
 689                 struct ib_device_properties dev_props;
 690                 struct ib_cm_active_param   cm_active_params;
 691                 tTS_IB_CLIENT_QUERY_TID     tid;
 692                 int                         enum1 = TS_IB_QP_ATTRIBUTE_STATE;
 693                 int                         enum2 = TS_IB_ACCESS_LOCAL_WRITE;
 694                 int                         enum3 = TS_IB_CQ_CALLBACK_INTERRUPT;
 695                 int                         enum4 = TS_IB_CQ_PROVIDER_REARM;
 696                 return 0;
 697         ],[
 698                 CIBLND="ciblnd"
 699         ],[
 700                 AC_MSG_ERROR([can't compile ciblnd with given path])
 701                 CIBCPPFLAGS=""
 702         ])
 703         EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 704 fi
 705 AC_SUBST(CIBCPPFLAGS)
 706 AC_SUBST(CIBLND)
 707 ])
 708
 709 #
 710 # LN_CONFIG_IIB
 711 #
 712 # check for infinicon infiniband support
 713 #
 714 AC_DEFUN([LN_CONFIG_IIB],[
 715 AC_MSG_CHECKING([whether to enable Infinicon support])
 716 # set default
 717 IIBPATH="/usr/include"
 718 AC_ARG_WITH([iib],
 719         AC_HELP_STRING([--with-iib=path],
 720                        [build iiblnd against path]),
 721         [
 722                 case $with_iib in
 723                 yes)    ENABLEIIB=2
 724                         ;;
 725                 no)     ENABLEIIB=0
 726                         ;;
 727                 *)      IIBPATH="${with_iib}/include"
 728                         ENABLEIIB=3
 729                         ;;
 730                 esac
 731         ],[
 732                 ENABLEIIB=1
 733         ])
 734 if test $ENABLEIIB -eq 0; then
 735         AC_MSG_RESULT([disabled])
 736 elif test ! \( -f ${IIBPATH}/linux/iba/ibt.h \); then
 737         AC_MSG_RESULT([no])
 738         case $ENABLEIIB in
 739         1) ;;
 740         2) AC_MSG_ERROR([default Infinicon headers not present]);;
 741         3) AC_MSG_ERROR([bad --with-iib path]);;
 742         *) AC_MSG_ERROR([internal error]);;
 743         esac
 744 else
 745         IIBCPPFLAGS="-I$IIBPATH"
 746         if test $IIBPATH != "/usr/include"; then
 747                 # we need /usr/include come what may
 748                 IIBCPPFLAGS="$IIBCPPFLAGS -I/usr/include"
 749         fi
 750         EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 751         EXTRA_KCFLAGS="$EXTRA_KCFLAGS $IIBCPPFLAGS"
 752         LB_LINUX_TRY_COMPILE([
 753                 #include <linux/iba/ibt.h>
 754         ],[
 755                 IBT_INTERFACE_UNION interfaces;
 756                 FSTATUS             rc;
 757
 758                  rc = IbtGetInterfaceByVersion(IBT_INTERFACE_VERSION_2,
 759                                                &interfaces);
 760
 761                 return rc == FSUCCESS ? 0 : 1;
 762         ],[
 763                 AC_MSG_RESULT([yes])
 764                 IIBLND="iiblnd"
 765         ],[
 766                 AC_MSG_RESULT([no])
 767                 case $ENABLEIIB in
 768                 1) ;;
 769                 2) AC_MSG_ERROR([can't compile with default Infinicon headers]);;
 770                 3) AC_MSG_ERROR([can't compile with Infinicon headers under $IIBPATH]);;
 771                 *) AC_MSG_ERROR([internal error]);;
 772                 esac
 773                 IIBLND=""
 774                 IIBCPPFLAGS=""
 775         ])
 776         EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 777 fi
 778 AC_SUBST(IIBCPPFLAGS)
 779 AC_SUBST(IIBLND)
 780 ])
 781
 782 #
 783 # LN_CONFIG_VIB
 784 #
 785 # check for Voltaire infiniband support
 786 #
 787 AC_DEFUN([LN_CONFIG_VIB],
 788 [AC_MSG_CHECKING([whether to enable Voltaire IB support])
 789 VIBPATH=""
 790 AC_ARG_WITH([vib],
 791         AC_HELP_STRING([--with-vib=path],
 792                        [build viblnd against path]),
 793         [
 794                 case $with_vib in
 795                 no)     AC_MSG_RESULT([no]);;
 796                 *)      VIBPATH="${with_vib}/src/nvigor/ib-code"
 797                         if test -d "$with_vib" -a -d "$VIBPATH"; then
 798                                 AC_MSG_RESULT([yes])
 799                         else
 800                                 AC_MSG_RESULT([no])
 801                                 AC_MSG_ERROR([No directory $VIBPATH])
 802                         fi;;
 803                 esac
 804         ],[
 805                 AC_MSG_RESULT([no])
 806         ])
 807 if test -z "$VIBPATH"; then
 808         VIBLND=""
 809 else
 810         VIBCPPFLAGS="-I${VIBPATH}/include -I${VIBPATH}/cm"
 811         EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 812         EXTRA_KCFLAGS="$EXTRA_KCFLAGS $VIBCPPFLAGS"
 813         LB_LINUX_TRY_COMPILE([
 814                 #include <linux/list.h>
 815                 #include <asm/byteorder.h>
 816                 #ifdef __BIG_ENDIAN
 817                 # define CPU_BE 1
 818                 # define CPU_LE 0
 819                 #endif
 820                 #ifdef __LITTLE_ENDIAN
 821                 # define CPU_BE 0
 822                 # define CPU_LE 1
 823                 #endif
 824                 #include <vverbs.h>
 825                 #include <ib-cm.h>
 826                 #include <ibat.h>
 827         ],[
 828                 vv_hca_h_t       kib_hca;
 829                 vv_return_t      vvrc;
 830                 cm_cep_handle_t  cep;
 831                 ibat_arp_data_t  arp_data;
 832                 ibat_stat_t      ibatrc;
 833
 834                 vvrc = vv_hca_open("ANY_HCA", NULL, &kib_hca);
 835                 cep = cm_create_cep(cm_cep_transp_rc);
 836                 ibatrc = ibat_get_ib_data((uint32_t)0, (uint32_t)0,
 837                                           ibat_paths_primary, &arp_data,
 838                                           (ibat_get_ib_data_reply_fn_t)NULL,
 839                                           NULL, 0);
 840                 return 0;
 841         ],[
 842                 VIBLND="viblnd"
 843         ],[
 844                 AC_MSG_ERROR([can't compile viblnd with given path])
 845         ])
 846         EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 847 fi
 848 if test -n "$VIBLND"; then
 849         EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 850         EXTRA_KCFLAGS="$EXTRA_KCFLAGS $VIBCPPFLAGS"
 851         AC_MSG_CHECKING([if Voltaire still uses void * sg addresses])
 852         LB_LINUX_TRY_COMPILE([
 853                 #include <linux/list.h>
 854                 #include <asm/byteorder.h>
 855                 #ifdef __BIG_ENDIAN
 856                 # define CPU_BE 1
 857                 # define CPU_LE 0
 858                 #endif
 859                 #ifdef __LITTLE_ENDIAN
 860                 # define CPU_BE 0
 861                 # define CPU_LE 1
 862                 #endif
 863                 #include <vverbs.h>
 864                 #include <ib-cm.h>
 865                 #include <ibat.h>
 866         ],[
 867                 vv_scatgat_t  sg;
 868
 869                 return &sg.v_address[3] == NULL;
 870         ],[
 871                 AC_MSG_RESULT([yes])
 872                 VIBCPPFLAGS="$VIBCPPFLAGS -DIBNAL_VOIDSTAR_SGADDR=1"
 873         ],[
 874                 AC_MSG_RESULT([no])
 875         ])
 876         EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 877 fi
 878 AC_SUBST(VIBCPPFLAGS)
 879 AC_SUBST(VIBLND)
 880 ])
 881
 882 #
 883 # LN_CONFIG_RALND
 884 #
 885 # check whether to use the RapidArray lnd
 886 #
 887 AC_DEFUN([LN_CONFIG_RALND],
 888 [#### Rapid Array
 889 AC_MSG_CHECKING([if RapidArray kernel headers are present])
 890 # placeholder
 891 RACPPFLAGS="-I${LINUX}/drivers/xd1/include"
 892 EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 893 EXTRA_KCFLAGS="$EXTRA_KCFLAGS $RACPPFLAGS"
 894 LB_LINUX_TRY_COMPILE([
 895         #include <linux/types.h>
 896         #include <rapl.h>
 897 ],[
 898         RAP_RETURN          rc;
 899         RAP_PVOID           dev_handle;
 900
 901         rc = RapkGetDeviceByIndex(0, NULL, &dev_handle);
 902
 903         return rc == RAP_SUCCESS ? 0 : 1;
 904 ],[
 905         AC_MSG_RESULT([yes])
 906         RALND="ralnd"
 907 ],[
 908         AC_MSG_RESULT([no])
 909         RALND=""
 910         RACPPFLAGS=""
 911 ])
 912 EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 913 AC_SUBST(RACPPFLAGS)
 914 AC_SUBST(RALND)
 915 ])
 916
 917 #
 918 # LN_STRUCT_PAGE_LIST
 919 #
 920 # 2.6.4 no longer has page->list
 921 #
 922 AC_DEFUN([LN_STRUCT_PAGE_LIST],
 923 [AC_MSG_CHECKING([if struct page has a list field])
 924 LB_LINUX_TRY_COMPILE([
 925         #include <linux/mm.h>
 926 ],[
 927         struct page page;
 928         &page.list;
 929 ],[
 930         AC_MSG_RESULT([yes])
 931         AC_DEFINE(HAVE_PAGE_LIST, 1, [struct page has a list field])
 932 ],[
 933         AC_MSG_RESULT([no])
 934 ])
 935 ])
 936
 937 #
 938 # LN_STRUCT_SIGHAND
 939 #
 940 # red hat 2.4 adds sighand to struct task_struct
 941 #
 942 AC_DEFUN([LN_STRUCT_SIGHAND],
 943 [AC_MSG_CHECKING([if task_struct has a sighand field])
 944 LB_LINUX_TRY_COMPILE([
 945         #include <linux/sched.h>
 946 ],[
 947         struct task_struct p;
 948         p.sighand = NULL;
 949 ],[
 950         AC_DEFINE(CONFIG_RH_2_4_20, 1, [this kernel contains Red Hat 2.4.20 patches])
 951         AC_MSG_RESULT([yes])
 952 ],[
 953         AC_MSG_RESULT([no])
 954 ])
 955 ])
 956
 957 #
 958 # LN_FUNC_CPU_ONLINE
 959 #
 960 # cpu_online is different in rh 2.4, vanilla 2.4, and 2.6
 961 #
 962 AC_DEFUN([LN_FUNC_CPU_ONLINE],
 963 [AC_MSG_CHECKING([if kernel defines cpu_online()])
 964 LB_LINUX_TRY_COMPILE([
 965         #include <linux/sched.h>
 966 ],[
 967         cpu_online(0);
 968 ],[
 969         AC_MSG_RESULT([yes])
 970         AC_DEFINE(HAVE_CPU_ONLINE, 1, [cpu_online found])
 971 ],[
 972         AC_MSG_RESULT([no])
 973 ])
 974 ])
 975
 976 #
 977 # LN_TYPE_GFP_T
 978 #
 979 # check if gfp_t is typedef-ed
 980 #
 981 AC_DEFUN([LN_TYPE_GFP_T],
 982 [AC_MSG_CHECKING([if kernel defines gfp_t])
 983 LB_LINUX_TRY_COMPILE([
 984         #include <linux/gfp.h>
 985 ],[
 986         return sizeof(gfp_t);
 987 ],[
 988         AC_MSG_RESULT([yes])
 989         AC_DEFINE(HAVE_GFP_T, 1, [gfp_t found])
 990 ],[
 991         AC_MSG_RESULT([no])
 992 ])
 993 ])
 994
 995 #
 996 # LN_TYPE_CPUMASK_T
 997 #
 998 # same goes for cpumask_t
 999 #
1000 AC_DEFUN([LN_TYPE_CPUMASK_T],
1001 [AC_MSG_CHECKING([if kernel defines cpumask_t])
1002 LB_LINUX_TRY_COMPILE([
1003         #include <linux/sched.h>
1004 ],[
1005         return sizeof (cpumask_t);
1006 ],[
1007         AC_MSG_RESULT([yes])
1008         AC_DEFINE(HAVE_CPUMASK_T, 1, [cpumask_t found])
1009 ],[
1010         AC_MSG_RESULT([no])
1011 ])
1012 ])
1013
1014 #
1015 # LN_FUNC_SHOW_TASK
1016 #
1017 # we export show_task(), but not all kernels have it (yet)
1018 #
1019 AC_DEFUN([LN_FUNC_SHOW_TASK],
1020 [AC_MSG_CHECKING([if kernel exports show_task])
1021 have_show_task=0
1022 for file in ksyms sched ; do
1023         if grep -q "EXPORT_SYMBOL(show_task)" \
1024                  "$LINUX/kernel/$file.c" 2>/dev/null ; then
1025                 have_show_task=1
1026                 break
1027         fi
1028 done
1029 if test x$have_show_task = x1 ; then
1030         AC_DEFINE(HAVE_SHOW_TASK, 1, [show_task is exported])
1031         AC_MSG_RESULT([yes])
1032 else
1033         AC_MSG_RESULT([no])
1034 fi
1035 ])
1036
1037 # LN_TASKLIST_LOCK
1038 # 2.6.18 remove tasklist_lock export
1039 AC_DEFUN([LN_TASKLIST_LOCK],
1040 [AC_MSG_CHECKING([kernel export tasklist_lock])
1041         if grep -q "EXPORT_SYMBOL(tasklist_lock)" \
1042                  "$LINUX/kernel/fork.c" 2>/dev/null ; then
1043                 AC_DEFINE(HAVE_TASKLIST_LOCK, 1,
1044                           [tasklist_lock exported])
1045                 AC_MSG_RESULT([yes])
1046         else
1047                 AC_MSG_RESULT([no])
1048         fi
1049 ])
1050
1051 # 2.6.19 API changes
1052 # kmem_cache_destroy(cachep) return void instead of
1053 # int
1054 AC_DEFUN([LN_KMEM_CACHE_DESTROY_INT],
1055 [AC_MSG_CHECKING([kmem_cache_destroy(cachep) return int])
1056 LB_LINUX_TRY_COMPILE([
1057         #include <linux/slab.h>
1058 ],[
1059         int i = kmem_cache_destroy(NULL);
1060 ],[
1061         AC_MSG_RESULT(yes)
1062         AC_DEFINE(HAVE_KMEM_CACHE_DESTROY_INT, 1,
1063                 [kmem_cache_destroy(cachep) return int])
1064 ],[
1065         AC_MSG_RESULT(NO)
1066 ])
1067 ])
1068
1069 #2.6.19 API change
1070 #panic_notifier_list use atomic_notifier operations
1071 #
1072 AC_DEFUN([LN_ATOMIC_PANIC_NOTIFIER],
1073 [AC_MSG_CHECKING([panic_notifier_list is atomic])
1074 LB_LINUX_TRY_COMPILE([
1075         #include <linux/notifier.h>
1076         #include <linux/kernel.h>
1077 ],[
1078         struct atomic_notifier_head panic_notifier_list;
1079 ],[
1080         AC_MSG_RESULT(yes)
1081         AC_DEFINE(HAVE_ATOMIC_PANIC_NOTIFIER, 1,
1082                 [panic_notifier_list is atomic_notifier_head])
1083 ],[
1084         AC_MSG_RESULT(NO)
1085 ])
1086 ])
1087
1088 #
1089 # LN_PROG_LINUX
1090 #
1091 # LNet linux kernel checks
1092 #
1093 AC_DEFUN([LN_PROG_LINUX],
1094 [
1095 LC_CONFIG_CDEBUG
1096 LN_FUNC_CPU_ONLINE
1097 LN_TYPE_GFP_T
1098 LN_TYPE_CPUMASK_T
1099 LN_CONFIG_AFFINITY
1100 LN_CONFIG_BACKOFF
1101 LN_CONFIG_PANIC_DUMPLOG
1102 LN_CONFIG_QUADRICS
1103 LN_CONFIG_GM
1104 LN_CONFIG_OPENIB
1105 LN_CONFIG_CIB
1106 LN_CONFIG_VIB
1107 LN_CONFIG_IIB
1108 LN_CONFIG_O2IB
1109 LN_CONFIG_RALND
1110 LN_CONFIG_PTLLND
1111 LN_CONFIG_MX
1112
1113 LN_STRUCT_PAGE_LIST
1114 LN_STRUCT_SIGHAND
1115 LN_FUNC_SHOW_TASK
1116 # 2.6.18
1117 LN_TASKLIST_LOCK
1118 # 2.6.19
1119 LN_KMEM_CACHE_DESTROY_INT
1120 LN_ATOMIC_PANIC_NOTIFIER
1121 ])
1122
1123 #
1124 # LN_PROG_DARWIN
1125 #
1126 # Darwin checks
1127 #
1128 AC_DEFUN([LN_PROG_DARWIN],
1129 [LB_DARWIN_CHECK_FUNCS([get_preemption_level])
1130 ])
1131
1132 #
1133 # LN_PATH_DEFAULTS
1134 #
1135 # default paths for installed files
1136 #
1137 AC_DEFUN([LN_PATH_DEFAULTS],
1138 [
1139 ])
1140
1141 #
1142 # LN_CONFIGURE
1143 #
1144 # other configure checks
1145 #
1146 AC_DEFUN([LN_CONFIGURE],
1147 [# lnet/utils/portals.c
1148 AC_CHECK_HEADERS([netdb.h netinet/tcp.h asm/types.h endian.h sys/ioctl.h])
1149 AC_CHECK_FUNCS([gethostbyname socket connect])
1150
1151 # lnet/utils/debug.c
1152 AC_CHECK_HEADERS([linux/version.h])
1153
1154 AC_CHECK_TYPE([spinlock_t],
1155         [AC_DEFINE(HAVE_SPINLOCK_T, 1, [spinlock_t is defined])],
1156         [],
1157         [#include <linux/spinlock.h>])
1158
1159 # lnet/utils/wirecheck.c
1160 AC_CHECK_FUNCS([strnlen])
1161
1162 # --------  Check for required packages  --------------
1163
1164 #
1165 # LC_CONFIG_READLINE
1166 #
1167 # Build with readline
1168 #
1169 AC_MSG_CHECKING([whether to enable readline support])
1170 AC_ARG_ENABLE(readline,
1171         AC_HELP_STRING([--disable-readline],
1172                         [disable readline support]),
1173         [],[enable_readline='yes'])
1174 AC_MSG_RESULT([$enable_readline])
1175
1176 # -------- check for readline if enabled ----
1177 if test x$enable_readline = xyes ; then
1178         LIBS_save="$LIBS"
1179         LIBS="-lncurses $LIBS"
1180         AC_CHECK_LIB([readline],[readline],[
1181         LIBREADLINE="-lreadline -lncurses"
1182         AC_DEFINE(HAVE_LIBREADLINE, 1, [readline library is available])
1183         ],[
1184         LIBREADLINE=""
1185         ])
1186         LIBS="$LIBS_save"
1187 else
1188         LIBREADLINE=""
1189 fi
1190 AC_SUBST(LIBREADLINE)
1191
1192 AC_MSG_CHECKING([if efence debugging support is requested])
1193 AC_ARG_ENABLE(efence,
1194         AC_HELP_STRING([--enable-efence],
1195                         [use efence library]),
1196         [],[enable_efence='no'])
1197 AC_MSG_RESULT([$enable_efence])
1198 if test "$enable_efence" = "yes" ; then
1199         LIBEFENCE="-lefence"
1200         AC_DEFINE(HAVE_LIBEFENCE, 1, [libefence support is requested])
1201 else
1202         LIBEFENCE=""
1203 fi
1204 AC_SUBST(LIBEFENCE)
1205
1206 # -------- enable acceptor libwrap (TCP wrappers) support? -------
1207 AC_MSG_CHECKING([if libwrap support is requested])
1208 AC_ARG_ENABLE([libwrap],
1209         AC_HELP_STRING([--enable-libwrap], [use TCP wrappers]),
1210         [case "${enableval}" in
1211                 yes) enable_libwrap=yes ;;
1212                 no) enable_libwrap=no ;;
1213                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-libwrap) ;;
1214         esac],[enable_libwrap=no])
1215 AC_MSG_RESULT([$enable_libwrap])
1216 if test x$enable_libwrap = xyes ; then
1217         LIBWRAP="-lwrap"
1218         AC_DEFINE(HAVE_LIBWRAP, 1, [libwrap support is requested])
1219 else
1220         LIBWRAP=""
1221 fi
1222 AC_SUBST(LIBWRAP)
1223
1224 # -------- check for -lpthread support ----
1225 AC_MSG_CHECKING([whether to use libpthread for lnet library])
1226 AC_ARG_ENABLE([libpthread],
1227         AC_HELP_STRING([--disable-libpthread],
1228                 [disable libpthread]),
1229         [],[enable_libpthread=yes])
1230 if test "$enable_libpthread" = "yes" ; then
1231         AC_CHECK_LIB([pthread], [pthread_create],
1232                 [ENABLE_LIBPTHREAD="yes"],
1233                 [ENABLE_LIBPTHREAD="no"])
1234         if test "$ENABLE_LIBPTHREAD" = "yes" ; then
1235                 AC_MSG_RESULT([$ENABLE_LIBPTHREAD])
1236                 PTHREAD_LIBS="-lpthread"
1237                 AC_DEFINE([HAVE_LIBPTHREAD], 1, [use libpthread])
1238         else
1239                 PTHREAD_LIBS=""
1240                 AC_MSG_RESULT([no libpthread is found])
1241         fi
1242         AC_SUBST(PTHREAD_LIBS)
1243 else
1244         AC_MSG_RESULT([no (disabled explicitly)])
1245         ENABLE_LIBPTHREAD="no"
1246 fi
1247 AC_SUBST(ENABLE_LIBPTHREAD)
1248
1249 # ----------------------------------------
1250 # some tests for catamount-like systems
1251 # ----------------------------------------
1252 AC_ARG_ENABLE([sysio_init],
1253         AC_HELP_STRING([--disable-sysio-init],
1254                 [call sysio init functions when initializing liblustre]),
1255         [],[enable_sysio_init=yes])
1256 AC_MSG_CHECKING([whether to initialize libsysio])
1257 AC_MSG_RESULT([$enable_sysio_init])
1258 if test x$enable_sysio_init != xno ; then
1259         AC_DEFINE([INIT_SYSIO], 1, [call sysio init functions])
1260 fi
1261
1262 AC_ARG_ENABLE([urandom],
1263         AC_HELP_STRING([--disable-urandom],
1264                 [disable use of /dev/urandom for liblustre]),
1265         [],[enable_urandom=yes])
1266 AC_MSG_CHECKING([whether to use /dev/urandom for liblustre])
1267 AC_MSG_RESULT([$enable_urandom])
1268 if test x$enable_urandom != xno ; then
1269         AC_DEFINE([LIBLUSTRE_USE_URANDOM], 1, [use /dev/urandom for random data])
1270 fi
1271
1272 # -------- check for -lcap support ----
1273 if test x$enable_liblustre = xyes ; then
1274         AC_CHECK_LIB([cap], [cap_get_proc],
1275                 [
1276                         CAP_LIBS="-lcap"
1277                         AC_DEFINE([HAVE_LIBCAP], 1, [use libcap])
1278                 ],
1279                 [
1280                         CAP_LIBS=""
1281                 ])
1282         AC_SUBST(CAP_LIBS)
1283
1284 fi
1285
1286 LN_CONFIG_MAX_PAYLOAD
1287 LN_CONFIG_UPTLLND
1288 LN_CONFIG_USOCKLND
1289 ])
1290
1291 #
1292 # LN_CONDITIONALS
1293 #
1294 # AM_CONDITOINAL defines for lnet
1295 #
1296 AC_DEFUN([LN_CONDITIONALS],
1297 [AM_CONDITIONAL(BUILD_QSWLND, test x$QSWLND = "xqswlnd")
1298 AM_CONDITIONAL(BUILD_GMLND, test x$GMLND = "xgmlnd")
1299 AM_CONDITIONAL(BUILD_MXLND, test x$MXLND = "xmxlnd")
1300 AM_CONDITIONAL(BUILD_O2IBLND, test x$O2IBLND = "xo2iblnd")
1301 AM_CONDITIONAL(BUILD_OPENIBLND, test x$OPENIBLND = "xopeniblnd")
1302 AM_CONDITIONAL(BUILD_CIBLND, test x$CIBLND = "xciblnd")
1303 AM_CONDITIONAL(BUILD_IIBLND, test x$IIBLND = "xiiblnd")
1304 AM_CONDITIONAL(BUILD_VIBLND, test x$VIBLND = "xviblnd")
1305 AM_CONDITIONAL(BUILD_RALND, test x$RALND = "xralnd")
1306 AM_CONDITIONAL(BUILD_PTLLND, test x$PTLLND = "xptllnd")
1307 AM_CONDITIONAL(BUILD_UPTLLND, test x$UPTLLND = "xptllnd")
1308 AM_CONDITIONAL(BUILD_USOCKLND, test x$USOCKLND = "xusocklnd")
1309 ])
1310
1311 #
1312 # LN_CONFIG_FILES
1313 #
1314 # files that should be generated with AC_OUTPUT
1315 #
1316 AC_DEFUN([LN_CONFIG_FILES],
1317 [AC_CONFIG_FILES([
1318 lnet/Kernelenv
1319 lnet/Makefile
1320 lnet/autoMakefile
1321 lnet/autoconf/Makefile
1322 lnet/doc/Makefile
1323 lnet/include/Makefile
1324 lnet/include/libcfs/Makefile
1325 lnet/include/libcfs/linux/Makefile
1326 lnet/include/lnet/Makefile
1327 lnet/include/lnet/linux/Makefile
1328 lnet/klnds/Makefile
1329 lnet/klnds/autoMakefile
1330 lnet/klnds/gmlnd/Makefile
1331 lnet/klnds/mxlnd/autoMakefile
1332 lnet/klnds/mxlnd/Makefile
1333 lnet/klnds/gmlnd/autoMakefile
1334 lnet/klnds/openiblnd/Makefile
1335 lnet/klnds/openiblnd/autoMakefile
1336 lnet/klnds/o2iblnd/Makefile
1337 lnet/klnds/o2iblnd/autoMakefile
1338 lnet/klnds/ciblnd/Makefile
1339 lnet/klnds/ciblnd/autoMakefile
1340 lnet/klnds/iiblnd/Makefile
1341 lnet/klnds/iiblnd/autoMakefile
1342 lnet/klnds/viblnd/Makefile
1343 lnet/klnds/viblnd/autoMakefile
1344 lnet/klnds/qswlnd/Makefile
1345 lnet/klnds/qswlnd/autoMakefile
1346 lnet/klnds/ralnd/Makefile
1347 lnet/klnds/ralnd/autoMakefile
1348 lnet/klnds/socklnd/Makefile
1349 lnet/klnds/socklnd/autoMakefile
1350 lnet/klnds/ptllnd/Makefile
1351 lnet/klnds/ptllnd/autoMakefile
1352 lnet/libcfs/Makefile
1353 lnet/libcfs/autoMakefile
1354 lnet/libcfs/linux/Makefile
1355 lnet/lnet/Makefile
1356 lnet/lnet/autoMakefile
1357 lnet/tests/Makefile
1358 lnet/tests/autoMakefile
1359 lnet/ulnds/Makefile
1360 lnet/ulnds/autoMakefile
1361 lnet/ulnds/socklnd/Makefile
1362 lnet/ulnds/ptllnd/Makefile
1363 lnet/utils/Makefile
1364 ])
1365 case $lb_target_os in
1366         darwin)
1367                 AC_CONFIG_FILES([
1368 lnet/include/libcfs/darwin/Makefile
1369 lnet/include/lnet/darwin/Makefile
1370 lnet/libcfs/darwin/Makefile
1371 ])
1372                 ;;
1373 esac
1374 ])