lnet/autoconf/lustre-lnet.m4

   1 #
   2 # LN_CONFIG_MAX_PAYLOAD
   3 #
   4 # configure maximum payload
   5 #
   6 AC_DEFUN([LN_CONFIG_MAX_PAYLOAD],
   7 [AC_MSG_CHECKING([for non-default maximum LNET payload])
   8 AC_ARG_WITH([max-payload-mb],
   9         AC_HELP_STRING([--with-max-payload-mb=MBytes],
  10                        [set maximum lnet payload in MBytes]),
  11         [
  12                 AC_MSG_RESULT([$with_max_payload_mb])
  13                 LNET_MAX_PAYLOAD_MB=$with_max_payload_mb
  14                 LNET_MAX_PAYLOAD="(($with_max_payload_mb)<<20)"
  15         ], [
  16                 AC_MSG_RESULT([no])
  17                 LNET_MAX_PAYLOAD="LNET_MTU"
  18         ])
  19         AC_DEFINE_UNQUOTED(LNET_MAX_PAYLOAD, $LNET_MAX_PAYLOAD,
  20                            [Max LNET payload])
  21 ])
  22
  23 #
  24 # LN_CHECK_GCC_VERSION
  25 #
  26 # Check compiler version
  27 #
  28 AC_DEFUN([LN_CHECK_GCC_VERSION],
  29 [AC_MSG_CHECKING([compiler version])
  30 PTL_CC_VERSION=`$CC --version | awk '/^gcc/{print $ 3}'`
  31 PTL_MIN_CC_VERSION="3.2.2"
  32 v2n() {
  33         awk -F. '{printf "%d\n", (($ 1)*100+($ 2))*100+($ 3)}'
  34 }
  35 if test -z "$PTL_CC_VERSION" -o \
  36         `echo $PTL_CC_VERSION | v2n` -ge `echo $PTL_MIN_CC_VERSION | v2n`; then
  37         AC_MSG_RESULT([ok])
  38 else
  39         AC_MSG_RESULT([Buggy compiler found])
  40         AC_MSG_ERROR([Need gcc version >= $PTL_MIN_CC_VERSION])
  41 fi
  42 ])
  43
  44 #
  45 # LN_CONFIG_CDEBUG
  46 #
  47 # whether to enable various libcfs debugs (CDEBUG, ENTRY/EXIT, LASSERT, etc.)
  48 #
  49 AC_DEFUN([LN_CONFIG_CDEBUG],
  50 [
  51 AC_MSG_CHECKING([whether to enable CDEBUG, CWARN])
  52 AC_ARG_ENABLE([libcfs_cdebug],
  53         AC_HELP_STRING([--disable-libcfs-cdebug],
  54                         [disable libcfs CDEBUG, CWARN]),
  55         [],[enable_libcfs_cdebug='yes'])
  56 AC_MSG_RESULT([$enable_libcfs_cdebug])
  57 if test x$enable_libcfs_cdebug = xyes; then
  58    AC_DEFINE(CDEBUG_ENABLED, 1, [enable libcfs CDEBUG, CWARN])
  59 else
  60    AC_DEFINE(CDEBUG_ENABLED, 0, [disable libcfs CDEBUG, CWARN])
  61 fi
  62
  63 AC_MSG_CHECKING([whether to enable ENTRY/EXIT])
  64 AC_ARG_ENABLE([libcfs_trace],
  65         AC_HELP_STRING([--disable-libcfs-trace],
  66                         [disable libcfs ENTRY/EXIT]),
  67         [],[enable_libcfs_trace='yes'])
  68 AC_MSG_RESULT([$enable_libcfs_trace])
  69 if test x$enable_libcfs_trace = xyes; then
  70    AC_DEFINE(CDEBUG_ENTRY_EXIT, 1, [enable libcfs ENTRY/EXIT])
  71 else
  72    AC_DEFINE(CDEBUG_ENTRY_EXIT, 0, [disable libcfs ENTRY/EXIT])
  73 fi
  74
  75 AC_MSG_CHECKING([whether to enable LASSERT, LASSERTF])
  76 AC_ARG_ENABLE([libcfs_assert],
  77         AC_HELP_STRING([--disable-libcfs-assert],
  78                         [disable libcfs LASSERT, LASSERTF]),
  79         [],[enable_libcfs_assert='yes'])
  80 AC_MSG_RESULT([$enable_libcfs_assert])
  81 if test x$enable_libcfs_assert = xyes; then
  82    AC_DEFINE(LIBCFS_DEBUG, 1, [enable libcfs LASSERT, LASSERTF])
  83 fi
  84 ])
  85
  86 #
  87 # LN_CONFIG_AFFINITY
  88 #
  89 # check if cpu affinity is available/wanted
  90 #
  91 AC_DEFUN([LN_CONFIG_AFFINITY],
  92 [AC_ARG_ENABLE([affinity],
  93         AC_HELP_STRING([--disable-affinity],
  94                        [disable process/irq affinity]),
  95         [],[enable_affinity='yes'])
  96
  97 AC_MSG_CHECKING([for CPU affinity support])
  98 if test x$enable_affinity = xno ; then
  99         AC_MSG_RESULT([no (by request)])
 100 else
 101         LB_LINUX_TRY_COMPILE([
 102                 #include <linux/sched.h>
 103         ],[
 104                 struct task_struct t;
 105                 #if HAVE_CPUMASK_T
 106                 cpumask_t     m;
 107                 #else
 108                 unsigned long m;
 109                 #endif
 110                 set_cpus_allowed(&t, m);
 111         ],[
 112                 AC_DEFINE(CPU_AFFINITY, 1, [kernel has cpu affinity support])
 113                 AC_MSG_RESULT([yes])
 114         ],[
 115                 AC_MSG_RESULT([no (no kernel support)])
 116         ])
 117 fi
 118 ])
 119
 120 #
 121 # LN_CONFIG_PORTALS
 122 #
 123 # configure support for Portals
 124 #
 125 AC_DEFUN([LN_CONFIG_PORTALS],
 126 [AC_MSG_CHECKING([for portals])
 127 AC_ARG_WITH([portals],
 128         AC_HELP_STRING([--with-portals=path],
 129                        [set path to portals]),
 130         [
 131                 case $with_portals in
 132                         no)     ENABLEPORTALS=0
 133                                 ;;
 134                         *)      PORTALS="${with_portals}"
 135                                 ENABLEPORTALS=1
 136                                 ;;
 137                 esac
 138
 139         ], [
 140                 ENABLEPORTALS=0
 141         ])
 142 PTLLNDCPPFLAGS=""
 143 if test $ENABLEPORTALS -eq 0; then
 144         AC_MSG_RESULT([no])
 145 elif test ! \( -f ${PORTALS}/include/portals/p30.h \); then
 146         AC_MSG_RESULT([no])
 147         AC_MSG_ERROR([bad --with-portals path])
 148 else
 149         AC_MSG_RESULT([$PORTALS])
 150         PTLLNDCPPFLAGS="-I${PORTALS}/include"
 151 fi
 152 AC_SUBST(PTLLNDCPPFLAGS)
 153 ])
 154
 155 #
 156 # LN_CONFIG_BACKOFF
 157 #
 158 # check if tunable tcp backoff is available/wanted
 159 #
 160 AC_DEFUN([LN_CONFIG_BACKOFF],
 161 [AC_MSG_CHECKING([for tunable backoff TCP support])
 162 AC_ARG_ENABLE([backoff],
 163        AC_HELP_STRING([--disable-backoff],
 164                       [disable socknal tunable backoff]),
 165        [],[enable_backoff='yes'])
 166 if test x$enable_backoff = xno ; then
 167        AC_MSG_RESULT([no (by request)])
 168 else
 169        BOCD="`grep -c TCP_BACKOFF $LINUX/include/linux/tcp.h`"
 170        if test "$BOCD" != 0 ; then
 171                AC_DEFINE(SOCKNAL_BACKOFF, 1, [use tunable backoff TCP])
 172                AC_MSG_RESULT(yes)
 173        else
 174                AC_MSG_RESULT([no (no kernel support)])
 175        fi
 176 fi
 177 ])
 178
 179 #
 180 # LN_CONFIG_PANIC_DUMPLOG
 181 #
 182 # check if tunable panic_dumplog is wanted
 183 #
 184 AC_DEFUN([LN_CONFIG_PANIC_DUMPLOG],
 185 [AC_MSG_CHECKING([for tunable panic_dumplog support])
 186 AC_ARG_ENABLE([panic_dumplog],
 187        AC_HELP_STRING([--enable-panic_dumplog],
 188                       [enable panic_dumplog]),
 189        [],[enable_panic_dumplog='no'])
 190 if test x$enable_panic_dumplog = xyes ; then
 191        AC_DEFINE(LNET_DUMP_ON_PANIC, 1, [use dumplog on panic])
 192        AC_MSG_RESULT([yes (by request)])
 193 else
 194        AC_MSG_RESULT([no])
 195 fi
 196 ])
 197
 198 #
 199 # LN_CONFIG_PTLLND
 200 #
 201 # configure support for Portals LND
 202 #
 203 AC_DEFUN([LN_CONFIG_PTLLND],
 204 [
 205 if test -z "$ENABLEPORTALS"; then
 206         LN_CONFIG_PORTALS
 207 fi
 208
 209 AC_MSG_CHECKING([whether to build the kernel portals LND])
 210
 211 PTLLND=""
 212 if test $ENABLEPORTALS -ne 0; then
 213         AC_MSG_RESULT([yes])
 214         PTLLND="ptllnd"
 215 else
 216         AC_MSG_RESULT([no])
 217 fi
 218 AC_SUBST(PTLLND)
 219 ])
 220
 221 #
 222 # LN_CONFIG_UPTLLND
 223 #
 224 # configure support for Portals LND
 225 #
 226 AC_DEFUN([LN_CONFIG_UPTLLND],
 227 [
 228 if test -z "$ENABLEPORTALS"; then
 229         LN_CONFIG_PORTALS
 230 fi
 231
 232 AC_MSG_CHECKING([whether to build the userspace portals LND])
 233
 234 UPTLLND=""
 235 if test $ENABLEPORTALS -ne 0; then
 236         AC_MSG_RESULT([yes])
 237         UPTLLND="ptllnd"
 238 else
 239         AC_MSG_RESULT([no])
 240 fi
 241 AC_SUBST(UPTLLND)
 242 ])
 243
 244 #
 245 # LN_CONFIG_USOCKLND
 246 #
 247 # configure support for userspace TCP/IP LND
 248 #
 249 AC_DEFUN([LN_CONFIG_USOCKLND],
 250 [AC_MSG_CHECKING([whether to build usocklnd])
 251 AC_ARG_ENABLE([usocklnd],
 252         AC_HELP_STRING([--disable-usocklnd],
 253                         [disable usocklnd]),
 254         [],[enable_usocklnd='yes'])
 255
 256 if test x$enable_usocklnd = xyes ; then
 257         if test "$ENABLE_LIBPTHREAD" = "yes" ; then
 258                 AC_MSG_RESULT([yes])
 259                 USOCKLND="usocklnd"
 260         else
 261                 AC_MSG_RESULT([no (libpthread not present or disabled)])
 262                 USOCKLND=""
 263         fi
 264 else
 265         AC_MSG_RESULT([no (disabled explicitly)])
 266         USOCKLND=""
 267 fi
 268 AC_SUBST(USOCKLND)
 269 ])
 270
 271 #
 272 # LN_CONFIG_QUADRICS
 273 #
 274 # check if quadrics support is in this kernel
 275 #
 276 AC_DEFUN([LN_CONFIG_QUADRICS],
 277 [AC_MSG_CHECKING([for QsNet sources])
 278 AC_ARG_WITH([qsnet],
 279         AC_HELP_STRING([--with-qsnet=path],
 280                        [set path to qsnet source (default=$LINUX)]),
 281         [QSNET=$with_qsnet],
 282         [QSNET=$LINUX])
 283 AC_MSG_RESULT([$QSNET])
 284
 285 AC_MSG_CHECKING([if quadrics kernel headers are present])
 286 if test -d $QSNET/drivers/net/qsnet ; then
 287         AC_MSG_RESULT([yes])
 288         QSWLND="qswlnd"
 289         AC_MSG_CHECKING([for multirail EKC])
 290         if test -f $QSNET/include/elan/epcomms.h; then
 291                 AC_MSG_RESULT([supported])
 292                 QSWCPPFLAGS="-I$QSNET/include -DMULTIRAIL_EKC=1"
 293         else
 294                 AC_MSG_RESULT([not supported])
 295                 AC_MSG_ERROR([Need multirail EKC])
 296         fi
 297
 298         if test x$QSNET = x$LINUX ; then
 299                 LB_LINUX_CONFIG([QSNET],[],[
 300                         LB_LINUX_CONFIG([QSNET_MODULE],[],[
 301                                 AC_MSG_WARN([QSNET is not enabled in this kernel; not building qswlnd.])
 302                                 QSWLND=""
 303                                 QSWCPPFLAGS=""
 304                         ])
 305                 ])
 306         fi
 307 else
 308         AC_MSG_RESULT([no])
 309         QSWLND=""
 310         QSWCPPFLAGS=""
 311 fi
 312 AC_SUBST(QSWCPPFLAGS)
 313 AC_SUBST(QSWLND)
 314 ])
 315
 316 #
 317 # LN_CONFIG_GM
 318 #
 319 # check if GM support is available
 320 #
 321 AC_DEFUN([LN_CONFIG_GM],[
 322 AC_MSG_CHECKING([whether to enable GM support])
 323 AC_ARG_WITH([gm],
 324         AC_HELP_STRING([--with-gm=path-to-gm-source-tree],
 325                        [build gmlnd against path]),
 326         [
 327                 case $with_gm in
 328                 no)    ENABLE_GM=0
 329                        ;;
 330                 *)     ENABLE_GM=1
 331                        GM_SRC="$with_gm"
 332                        ;;
 333                 esac
 334         ],[
 335                 ENABLE_GM=0
 336         ])
 337 AC_ARG_WITH([gm-install],
 338         AC_HELP_STRING([--with-gm-install=path-to-gm-install-tree],
 339                        [say where GM has been installed]),
 340         [
 341                 GM_INSTALL=$with_gm_install
 342         ],[
 343                 GM_INSTALL="/opt/gm"
 344         ])
 345 if test $ENABLE_GM -eq 0; then
 346         AC_MSG_RESULT([no])
 347 else
 348         AC_MSG_RESULT([yes])
 349
 350         GMLND="gmlnd"
 351         GMCPPFLAGS="-I$GM_SRC/include -I$GM_SRC/drivers -I$GM_SRC/drivers/linux/gm"
 352
 353         if test -f $GM_INSTALL/lib/libgm.a -o \
 354                 -f $GM_INSTALL/lib64/libgm.a; then
 355                 GMLIBS="-L$GM_INSTALL/lib -L$GM_INSTALL/lib64"
 356         else
 357                 AC_MSG_ERROR([Cant find GM libraries under $GM_INSTALL])
 358         fi
 359
 360         EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 361         EXTRA_KCFLAGS="$GMCPPFLAGS -DGM_KERNEL $EXTRA_KCFLAGS"
 362
 363         AC_MSG_CHECKING([that code using GM compiles with given path])
 364         LB_LINUX_TRY_COMPILE([
 365                 #define GM_STRONG_TYPES 1
 366                 #ifdef VERSION
 367                 #undef VERSION
 368                 #endif
 369                 #include "gm.h"
 370                 #include "gm_internal.h"
 371         ],[
 372                 struct gm_port *port = NULL;
 373                 gm_recv_event_t *rxevent = gm_blocking_receive_no_spin(port);
 374                 return 0;
 375         ],[
 376                 AC_MSG_RESULT([yes])
 377         ],[
 378                 AC_MSG_RESULT([no])
 379                 AC_MSG_ERROR([Bad --with-gm path])
 380         ])
 381
 382         AC_MSG_CHECKING([that GM has gm_register_memory_ex_phys()])
 383         LB_LINUX_TRY_COMPILE([
 384                 #define GM_STRONG_TYPES 1
 385                 #ifdef VERSION
 386                 #undef VERSION
 387                 #endif
 388                 #include "gm.h"
 389                 #include "gm_internal.h"
 390         ],[
 391                 gm_status_t     gmrc;
 392                 struct gm_port *port = NULL;
 393                 gm_u64_t        phys = 0;
 394                 gm_up_t         pvma = 0;
 395
 396                 gmrc = gm_register_memory_ex_phys(port, phys, 100, pvma);
 397                 return 0;
 398         ],[
 399                 AC_MSG_RESULT([yes])
 400         ],[
 401                 AC_MSG_RESULT([no.
 402 Please patch the GM sources as follows...
 403     cd $GM_SRC
 404     patch -p0 < $PWD/lnet/klnds/gmlnd/gm-reg-phys.patch
 405 ...then rebuild and re-install them])
 406                 AC_MSG_ERROR([Can't build GM without gm_register_memory_ex_phys()])
 407         ])
 408
 409         EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 410 fi
 411 AC_SUBST(GMCPPFLAGS)
 412 AC_SUBST(GMLIBS)
 413 AC_SUBST(GMLND)
 414 ])
 415
 416
 417 #
 418 # LN_CONFIG_MX
 419 #
 420 AC_DEFUN([LN_CONFIG_MX],
 421 [AC_MSG_CHECKING([whether to enable Myrinet MX support])
 422 # set default
 423 MXPATH="/opt/mx"
 424 AC_ARG_WITH([mx],
 425        AC_HELP_STRING([--with-mx=path],
 426                       [build mxlnd against path]),
 427        [
 428                case $with_mx in
 429                yes)    ENABLEMX=2
 430                        ;;
 431                no)     ENABLEMX=0
 432                        ;;
 433                *)      MXPATH=$with_mx
 434                        ENABLEMX=3
 435                        ;;
 436                esac
 437        ],[
 438                ENABLEMX=1
 439        ])
 440 if test $ENABLEMX -eq 0; then
 441        AC_MSG_RESULT([disabled])
 442 elif test ! \( -f ${MXPATH}/include/myriexpress.h -a \
 443               -f ${MXPATH}/include/mx_kernel_api.h -a \
 444               -f ${MXPATH}/include/mx_pin.h \); then
 445        AC_MSG_RESULT([no])
 446        case $ENABLEMX in
 447        1) ;;
 448        2) AC_MSG_ERROR([Myrinet MX kernel headers not present]);;
 449        3) AC_MSG_ERROR([bad --with-mx path]);;
 450        *) AC_MSG_ERROR([internal error]);;
 451        esac
 452 else
 453        MXCPPFLAGS="-I$MXPATH/include"
 454        EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 455        EXTRA_KCFLAGS="$EXTRA_KCFLAGS $MXCPPFLAGS"
 456        MXLIBS="-L$MXPATH/lib"
 457        LB_LINUX_TRY_COMPILE([
 458                #define MX_KERNEL 1
 459                #include <mx_extensions.h>
 460                #include <myriexpress.h>
 461        ],[
 462                mx_endpoint_t   end;
 463                mx_status_t     status;
 464                mx_request_t    request;
 465                int             result;
 466
 467                mx_init();
 468                mx_open_endpoint(MX_ANY_NIC, MX_ANY_ENDPOINT, 0, NULL, 0, &end);
 469                mx_register_unexp_handler(end, (mx_unexp_handler_t) NULL, NULL);
 470                mx_wait_any(end, MX_INFINITE, 0LL, 0LL, &status, &result);
 471                mx_iconnect(end, 0LL, 0, 0, 0, NULL, &request);
 472                return 0;
 473        ],[
 474                AC_MSG_RESULT([yes])
 475                MXLND="mxlnd"
 476        ],[
 477                AC_MSG_RESULT([no])
 478                case $ENABLEMX in
 479                1) ;;
 480                2) AC_MSG_ERROR([can't compile with Myrinet MX kernel headers]);;
 481                3) AC_MSG_ERROR([can't compile with Myrinet MX headers under $MXPATH]);;
 482                *) AC_MSG_ERROR([internal error]);;
 483                esac
 484                MXLND=""
 485                MXCPPFLAGS=""
 486        ])
 487        EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 488 fi
 489 AC_SUBST(MXCPPFLAGS)
 490 AC_SUBST(MXLIBS)
 491 AC_SUBST(MXLND)
 492 ])
 493
 494
 495
 496 #
 497 # LN_CONFIG_O2IB
 498 #
 499 AC_DEFUN([LN_CONFIG_O2IB],[
 500 AC_MSG_CHECKING([whether to enable OpenIB gen2 support])
 501 # set default
 502 O2IBPATH="$LINUX/drivers/infiniband"
 503 AC_ARG_WITH([o2ib],
 504         AC_HELP_STRING([--with-o2ib=path],
 505                        [build o2iblnd against path]),
 506         [
 507                 case $with_o2ib in
 508                 yes)    ENABLEO2IB=2
 509                         ;;
 510                 no)     ENABLEO2IB=0
 511                         ;;
 512                 *)      O2IBPATH=$with_o2ib
 513                         ENABLEO2IB=3
 514                         ;;
 515                 esac
 516         ],[
 517                 ENABLEO2IB=1
 518         ])
 519 if test $ENABLEO2IB -eq 0; then
 520         AC_MSG_RESULT([disabled])
 521 elif test ! \( -f ${O2IBPATH}/include/rdma/rdma_cm.h -a \
 522                -f ${O2IBPATH}/include/rdma/ib_cm.h -a\
 523                -f ${O2IBPATH}/include/rdma/ib_verbs.h -a\
 524                -f ${O2IBPATH}/include/rdma/ib_fmr_pool.h \); then
 525         AC_MSG_RESULT([no])
 526         case $ENABLEO2IB in
 527         1) ;;
 528         2) AC_MSG_ERROR([kernel OpenIB gen2 headers not present]);;
 529         3) AC_MSG_ERROR([bad --with-o2ib path]);;
 530         *) AC_MSG_ERROR([internal error]);;
 531         esac
 532 else
 533         O2IBCPPFLAGS="-I$O2IBPATH/include"
 534         EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 535         EXTRA_KCFLAGS="$EXTRA_KCFLAGS $O2IBCPPFLAGS"
 536         EXTRA_LNET_INCLUDE="$O2IBCPPFLAGS $EXTRA_LNET_INCLUDE"
 537         LB_LINUX_TRY_COMPILE([
 538                 #include <linux/version.h>
 539                 #include <linux/pci.h>
 540                 #if !HAVE_GFP_T
 541                 typedef int gfp_t;
 542                 #endif
 543                 #include <rdma/rdma_cm.h>
 544                 #include <rdma/ib_cm.h>
 545                 #include <rdma/ib_verbs.h>
 546                 #include <rdma/ib_fmr_pool.h>
 547         ],[
 548                 struct rdma_cm_id          *cm_id;
 549                 struct rdma_conn_param      conn_param;
 550                 struct ib_device_attr       device_attr;
 551                 struct ib_qp_attr           qp_attr;
 552                 struct ib_pool_fmr          pool_fmr;
 553                 enum   ib_cm_rej_reason     rej_reason;
 554
 555                 cm_id = rdma_create_id(NULL, NULL, RDMA_PS_TCP);
 556                 return PTR_ERR(cm_id);
 557         ],[
 558                 AC_MSG_RESULT([yes])
 559                 O2IBLND="o2iblnd"
 560         ],[
 561                 AC_MSG_RESULT([no])
 562                 case $ENABLEO2IB in
 563                 1) ;;
 564                 2) AC_MSG_ERROR([can't compile with kernel OpenIB gen2 headers]);;
 565                 3) AC_MSG_ERROR([can't compile with OpenIB gen2 headers under $O2IBPATH]);;
 566                 *) AC_MSG_ERROR([internal error]);;
 567                 esac
 568                 O2IBLND=""
 569                 O2IBCPPFLAGS=""
 570         ])
 571
 572 # version checking is a hack and isn't reliable, we need verify it
 573 # with each new ofed release
 574
 575         IB_DMA_MAP="`grep -c ib_dma_map_single ${O2IBPATH}/include/rdma/ib_verbs.h`"
 576         if test "$IB_DMA_MAP" != 0 ; then
 577                 IB_COMP_VECT="`grep -c comp_vector ${O2IBPATH}/include/rdma/ib_verbs.h`"
 578                 if test "$IB_COMP_VECT" != 0 ; then
 579                         IBLND_OFED_VERSION="1025"
 580                 else
 581                         IBLND_OFED_VERSION="1020"
 582                 fi
 583         else
 584                 IBLND_OFED_VERSION="1010"
 585         fi
 586
 587         AC_DEFINE_UNQUOTED(IBLND_OFED_VERSION, $IBLND_OFED_VERSION,
 588                            [OFED version])
 589
 590         EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 591 fi
 592
 593 AC_SUBST(EXTRA_LNET_INCLUDE)
 594 AC_SUBST(O2IBCPPFLAGS)
 595 AC_SUBST(O2IBLND)
 596 ])
 597
 598 #
 599 # LN_CONFIG_OPENIB
 600 #
 601 # check for OpenIB in the kernel
 602 AC_DEFUN([LN_CONFIG_OPENIB],[
 603 AC_MSG_CHECKING([whether to enable OpenIB support])
 604 # set default
 605 OPENIBPATH="$LINUX/drivers/infiniband"
 606 AC_ARG_WITH([openib],
 607         AC_HELP_STRING([--with-openib=path],
 608                        [build openiblnd against path]),
 609         [
 610                 case $with_openib in
 611                 yes)    ENABLEOPENIB=2
 612                         ;;
 613                 no)     ENABLEOPENIB=0
 614                         ;;
 615                 *)      OPENIBPATH="$with_openib"
 616                         ENABLEOPENIB=3
 617                         ;;
 618                 esac
 619         ],[
 620                 ENABLEOPENIB=1
 621         ])
 622 if test $ENABLEOPENIB -eq 0; then
 623         AC_MSG_RESULT([disabled])
 624 elif test ! \( -f ${OPENIBPATH}/include/ts_ib_core.h -a \
 625                -f ${OPENIBPATH}/include/ts_ib_cm.h -a\
 626                -f ${OPENIBPATH}/include/ts_ib_sa_client.h \); then
 627         AC_MSG_RESULT([no])
 628         case $ENABLEOPENIB in
 629         1) ;;
 630         2) AC_MSG_ERROR([kernel OpenIB headers not present]);;
 631         3) AC_MSG_ERROR([bad --with-openib path]);;
 632         *) AC_MSG_ERROR([internal error]);;
 633         esac
 634 else
 635         case $ENABLEOPENIB in
 636         1|2) OPENIBCPPFLAGS="-I$OPENIBPATH/include -DIN_TREE_BUILD";;
 637         3)   OPENIBCPPFLAGS="-I$OPENIBPATH/include";;
 638         *)   AC_MSG_RESULT([no])
 639              AC_MSG_ERROR([internal error]);;
 640         esac
 641         OPENIBCPPFLAGS="$OPENIBCPPFLAGS -DIB_NTXRXPARAMS=4"
 642         EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 643         EXTRA_KCFLAGS="$EXTRA_KCFLAGS $OPENIBCPPFLAGS"
 644         LB_LINUX_TRY_COMPILE([
 645                 #include <ts_ib_core.h>
 646                 #include <ts_ib_cm.h>
 647                 #include <ts_ib_sa_client.h>
 648         ],[
 649                 struct ib_device_properties dev_props;
 650                 struct ib_cm_active_param   cm_active_params;
 651                 tTS_IB_CLIENT_QUERY_TID     tid;
 652                 int                         enum1 = IB_QP_ATTRIBUTE_STATE;
 653                 int                         enum2 = IB_ACCESS_LOCAL_WRITE;
 654                 int                         enum3 = IB_CQ_CALLBACK_INTERRUPT;
 655                 int                         enum4 = IB_CQ_PROVIDER_REARM;
 656                 return 0;
 657         ],[
 658                 AC_MSG_RESULT([yes])
 659                 OPENIBLND="openiblnd"
 660         ],[
 661                 AC_MSG_RESULT([no])
 662                 case $ENABLEOPENIB in
 663                 1) ;;
 664                 2) AC_MSG_ERROR([can't compile with kernel OpenIB headers]);;
 665                 3) AC_MSG_ERROR([can't compile with OpenIB headers under $OPENIBPATH]);;
 666                 *) AC_MSG_ERROR([internal error]);;
 667                 esac
 668                 OPENIBLND=""
 669                 OPENIBCPPFLAGS=""
 670         ])
 671         EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 672 fi
 673 AC_SUBST(OPENIBCPPFLAGS)
 674 AC_SUBST(OPENIBLND)
 675 ])
 676
 677 #
 678 # LN_CONFIG_CIBLND
 679 #
 680 AC_DEFUN([LN_CONFIG_CIB],[
 681 AC_MSG_CHECKING([whether to enable Cisco/TopSpin IB support])
 682 # set default
 683 CIBPATH=""
 684 CIBLND=""
 685 AC_ARG_WITH([cib],
 686         AC_HELP_STRING([--with-cib=path],
 687                        [build ciblnd against path]),
 688         [
 689                 case $with_cib in
 690                 no)     AC_MSG_RESULT([no]);;
 691                 *)      CIBPATH="$with_cib"
 692                         if test -d "$CIBPATH"; then
 693                                 AC_MSG_RESULT([yes])
 694                         else
 695                                 AC_MSG_RESULT([no])
 696                                 AC_MSG_ERROR([No directory $CIBPATH])
 697                         fi;;
 698                 esac
 699         ],[
 700                 AC_MSG_RESULT([no])
 701         ])
 702 if test -n "$CIBPATH"; then
 703         CIBCPPFLAGS="-I${CIBPATH}/ib/ts_api_ng/include -I${CIBPATH}/all/kernel_services/include -DUSING_TSAPI"
 704         CIBCPPFLAGS="$CIBCPPFLAGS -DIB_NTXRXPARAMS=3"
 705         EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 706         EXTRA_KCFLAGS="$EXTRA_KCFLAGS $CIBCPPFLAGS"
 707         LB_LINUX_TRY_COMPILE([
 708                 #include <ts_ib_core.h>
 709                 #include <ts_ib_cm.h>
 710                 #include <ts_ib_sa_client.h>
 711         ],[
 712                 struct ib_device_properties dev_props;
 713                 struct ib_cm_active_param   cm_active_params;
 714                 tTS_IB_CLIENT_QUERY_TID     tid;
 715                 int                         enum1 = TS_IB_QP_ATTRIBUTE_STATE;
 716                 int                         enum2 = TS_IB_ACCESS_LOCAL_WRITE;
 717                 int                         enum3 = TS_IB_CQ_CALLBACK_INTERRUPT;
 718                 int                         enum4 = TS_IB_CQ_PROVIDER_REARM;
 719                 return 0;
 720         ],[
 721                 CIBLND="ciblnd"
 722         ],[
 723                 AC_MSG_ERROR([can't compile ciblnd with given path])
 724                 CIBCPPFLAGS=""
 725         ])
 726         EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 727 fi
 728 AC_SUBST(CIBCPPFLAGS)
 729 AC_SUBST(CIBLND)
 730 ])
 731
 732 #
 733 # LN_CONFIG_IIB
 734 #
 735 # check for infinicon infiniband support
 736 #
 737 AC_DEFUN([LN_CONFIG_IIB],[
 738 AC_MSG_CHECKING([whether to enable Infinicon support])
 739 # set default
 740 IIBPATH="/usr/include"
 741 AC_ARG_WITH([iib],
 742         AC_HELP_STRING([--with-iib=path],
 743                        [build iiblnd against path]),
 744         [
 745                 case $with_iib in
 746                 yes)    ENABLEIIB=2
 747                         ;;
 748                 no)     ENABLEIIB=0
 749                         ;;
 750                 *)      IIBPATH="${with_iib}/include"
 751                         ENABLEIIB=3
 752                         ;;
 753                 esac
 754         ],[
 755                 ENABLEIIB=1
 756         ])
 757 if test $ENABLEIIB -eq 0; then
 758         AC_MSG_RESULT([disabled])
 759 elif test ! \( -f ${IIBPATH}/linux/iba/ibt.h \); then
 760         AC_MSG_RESULT([no])
 761         case $ENABLEIIB in
 762         1) ;;
 763         2) AC_MSG_ERROR([default Infinicon headers not present]);;
 764         3) AC_MSG_ERROR([bad --with-iib path]);;
 765         *) AC_MSG_ERROR([internal error]);;
 766         esac
 767 else
 768         IIBCPPFLAGS="-I$IIBPATH"
 769         if test $IIBPATH != "/usr/include"; then
 770                 # we need /usr/include come what may
 771                 IIBCPPFLAGS="$IIBCPPFLAGS -I/usr/include"
 772         fi
 773         EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 774         EXTRA_KCFLAGS="$EXTRA_KCFLAGS $IIBCPPFLAGS"
 775         LB_LINUX_TRY_COMPILE([
 776                 #include <linux/iba/ibt.h>
 777         ],[
 778                 IBT_INTERFACE_UNION interfaces;
 779                 FSTATUS             rc;
 780
 781                  rc = IbtGetInterfaceByVersion(IBT_INTERFACE_VERSION_2,
 782                                                &interfaces);
 783
 784                 return rc == FSUCCESS ? 0 : 1;
 785         ],[
 786                 AC_MSG_RESULT([yes])
 787                 IIBLND="iiblnd"
 788         ],[
 789                 AC_MSG_RESULT([no])
 790                 case $ENABLEIIB in
 791                 1) ;;
 792                 2) AC_MSG_ERROR([can't compile with default Infinicon headers]);;
 793                 3) AC_MSG_ERROR([can't compile with Infinicon headers under $IIBPATH]);;
 794                 *) AC_MSG_ERROR([internal error]);;
 795                 esac
 796                 IIBLND=""
 797                 IIBCPPFLAGS=""
 798         ])
 799         EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 800 fi
 801 AC_SUBST(IIBCPPFLAGS)
 802 AC_SUBST(IIBLND)
 803 ])
 804
 805 #
 806 # LN_CONFIG_VIB
 807 #
 808 # check for Voltaire infiniband support
 809 #
 810 AC_DEFUN([LN_CONFIG_VIB],
 811 [AC_MSG_CHECKING([whether to enable Voltaire IB support])
 812 VIBPATH=""
 813 AC_ARG_WITH([vib],
 814         AC_HELP_STRING([--with-vib=path],
 815                        [build viblnd against path]),
 816         [
 817                 case $with_vib in
 818                 no)     AC_MSG_RESULT([no]);;
 819                 *)      VIBPATH="${with_vib}/src/nvigor/ib-code"
 820                         if test -d "$with_vib" -a -d "$VIBPATH"; then
 821                                 AC_MSG_RESULT([yes])
 822                         else
 823                                 AC_MSG_RESULT([no])
 824                                 AC_MSG_ERROR([No directory $VIBPATH])
 825                         fi;;
 826                 esac
 827         ],[
 828                 AC_MSG_RESULT([no])
 829         ])
 830 if test -z "$VIBPATH"; then
 831         VIBLND=""
 832 else
 833         VIBCPPFLAGS="-I${VIBPATH}/include -I${VIBPATH}/cm"
 834         EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 835         EXTRA_KCFLAGS="$EXTRA_KCFLAGS $VIBCPPFLAGS"
 836         LB_LINUX_TRY_COMPILE([
 837                 #include <linux/list.h>
 838                 #include <asm/byteorder.h>
 839                 #ifdef __BIG_ENDIAN
 840                 # define CPU_BE 1
 841                 # define CPU_LE 0
 842                 #endif
 843                 #ifdef __LITTLE_ENDIAN
 844                 # define CPU_BE 0
 845                 # define CPU_LE 1
 846                 #endif
 847                 #include <vverbs.h>
 848                 #include <ib-cm.h>
 849                 #include <ibat.h>
 850         ],[
 851                 vv_hca_h_t       kib_hca;
 852                 vv_return_t      vvrc;
 853                 cm_cep_handle_t  cep;
 854                 ibat_arp_data_t  arp_data;
 855                 ibat_stat_t      ibatrc;
 856
 857                 vvrc = vv_hca_open("ANY_HCA", NULL, &kib_hca);
 858                 cep = cm_create_cep(cm_cep_transp_rc);
 859                 ibatrc = ibat_get_ib_data((uint32_t)0, (uint32_t)0,
 860                                           ibat_paths_primary, &arp_data,
 861                                           (ibat_get_ib_data_reply_fn_t)NULL,
 862                                           NULL, 0);
 863                 return 0;
 864         ],[
 865                 VIBLND="viblnd"
 866         ],[
 867                 AC_MSG_ERROR([can't compile viblnd with given path])
 868         ])
 869         EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 870 fi
 871 if test -n "$VIBLND"; then
 872         EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 873         EXTRA_KCFLAGS="$EXTRA_KCFLAGS $VIBCPPFLAGS"
 874         AC_MSG_CHECKING([if Voltaire still uses void * sg addresses])
 875         LB_LINUX_TRY_COMPILE([
 876                 #include <linux/list.h>
 877                 #include <asm/byteorder.h>
 878                 #ifdef __BIG_ENDIAN
 879                 # define CPU_BE 1
 880                 # define CPU_LE 0
 881                 #endif
 882                 #ifdef __LITTLE_ENDIAN
 883                 # define CPU_BE 0
 884                 # define CPU_LE 1
 885                 #endif
 886                 #include <vverbs.h>
 887                 #include <ib-cm.h>
 888                 #include <ibat.h>
 889         ],[
 890                 vv_scatgat_t  sg;
 891
 892                 return &sg.v_address[3] == NULL;
 893         ],[
 894                 AC_MSG_RESULT([yes])
 895                 VIBCPPFLAGS="$VIBCPPFLAGS -DIBNAL_VOIDSTAR_SGADDR=1"
 896         ],[
 897                 AC_MSG_RESULT([no])
 898         ])
 899         EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 900 fi
 901 AC_SUBST(VIBCPPFLAGS)
 902 AC_SUBST(VIBLND)
 903 ])
 904
 905 #
 906 # LN_CONFIG_RALND
 907 #
 908 # check whether to use the RapidArray lnd
 909 #
 910 AC_DEFUN([LN_CONFIG_RALND],
 911 [#### Rapid Array
 912 AC_MSG_CHECKING([if RapidArray kernel headers are present])
 913 # placeholder
 914 RACPPFLAGS="-I${LINUX}/drivers/xd1/include"
 915 EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 916 EXTRA_KCFLAGS="$EXTRA_KCFLAGS $RACPPFLAGS"
 917 LB_LINUX_TRY_COMPILE([
 918         #include <linux/types.h>
 919         #include <rapl.h>
 920 ],[
 921         RAP_RETURN          rc;
 922         RAP_PVOID           dev_handle;
 923
 924         rc = RapkGetDeviceByIndex(0, NULL, &dev_handle);
 925
 926         return rc == RAP_SUCCESS ? 0 : 1;
 927 ],[
 928         AC_MSG_RESULT([yes])
 929         RALND="ralnd"
 930 ],[
 931         AC_MSG_RESULT([no])
 932         RALND=""
 933         RACPPFLAGS=""
 934 ])
 935 EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 936 AC_SUBST(RACPPFLAGS)
 937 AC_SUBST(RALND)
 938 ])
 939
 940 #
 941 # LN_STRUCT_PAGE_LIST
 942 #
 943 # 2.6.4 no longer has page->list
 944 #
 945 AC_DEFUN([LN_STRUCT_PAGE_LIST],
 946 [AC_MSG_CHECKING([if struct page has a list field])
 947 LB_LINUX_TRY_COMPILE([
 948         #include <linux/mm.h>
 949 ],[
 950         struct page page;
 951         &page.list;
 952 ],[
 953         AC_MSG_RESULT([yes])
 954         AC_DEFINE(HAVE_PAGE_LIST, 1, [struct page has a list field])
 955 ],[
 956         AC_MSG_RESULT([no])
 957 ])
 958 ])
 959
 960 #
 961 # LN_STRUCT_SIGHAND
 962 #
 963 # red hat 2.4 adds sighand to struct task_struct
 964 #
 965 AC_DEFUN([LN_STRUCT_SIGHAND],
 966 [AC_MSG_CHECKING([if task_struct has a sighand field])
 967 LB_LINUX_TRY_COMPILE([
 968         #include <linux/sched.h>
 969 ],[
 970         struct task_struct p;
 971         p.sighand = NULL;
 972 ],[
 973         AC_DEFINE(CONFIG_RH_2_4_20, 1, [this kernel contains Red Hat 2.4.20 patches])
 974         AC_MSG_RESULT([yes])
 975 ],[
 976         AC_MSG_RESULT([no])
 977 ])
 978 ])
 979
 980 #
 981 # LN_FUNC_CPU_ONLINE
 982 #
 983 # cpu_online is different in rh 2.4, vanilla 2.4, and 2.6
 984 #
 985 AC_DEFUN([LN_FUNC_CPU_ONLINE],
 986 [AC_MSG_CHECKING([if kernel defines cpu_online()])
 987 LB_LINUX_TRY_COMPILE([
 988         #include <linux/sched.h>
 989 ],[
 990         cpu_online(0);
 991 ],[
 992         AC_MSG_RESULT([yes])
 993         AC_DEFINE(HAVE_CPU_ONLINE, 1, [cpu_online found])
 994 ],[
 995         AC_MSG_RESULT([no])
 996 ])
 997 ])
 998
 999 #
1000 # LN_TYPE_GFP_T
1001 #
1002 # check if gfp_t is typedef-ed
1003 #
1004 AC_DEFUN([LN_TYPE_GFP_T],
1005 [AC_MSG_CHECKING([if kernel defines gfp_t])
1006 LB_LINUX_TRY_COMPILE([
1007         #include <linux/gfp.h>
1008 ],[
1009         return sizeof(gfp_t);
1010 ],[
1011         AC_MSG_RESULT([yes])
1012         AC_DEFINE(HAVE_GFP_T, 1, [gfp_t found])
1013 ],[
1014         AC_MSG_RESULT([no])
1015 ])
1016 ])
1017
1018 #
1019 # LN_TYPE_CPUMASK_T
1020 #
1021 # same goes for cpumask_t
1022 #
1023 AC_DEFUN([LN_TYPE_CPUMASK_T],
1024 [AC_MSG_CHECKING([if kernel defines cpumask_t])
1025 LB_LINUX_TRY_COMPILE([
1026         #include <linux/sched.h>
1027 ],[
1028         return sizeof (cpumask_t);
1029 ],[
1030         AC_MSG_RESULT([yes])
1031         AC_DEFINE(HAVE_CPUMASK_T, 1, [cpumask_t found])
1032 ],[
1033         AC_MSG_RESULT([no])
1034 ])
1035 ])
1036
1037 #
1038 # LN_FUNC_SHOW_TASK
1039 #
1040 # we export show_task(), but not all kernels have it (yet)
1041 #
1042 AC_DEFUN([LN_FUNC_SHOW_TASK],
1043 [LB_CHECK_SYMBOL_EXPORT([show_task],
1044 [kernel/ksyms.c kernel/sched.c],[
1045 AC_DEFINE(HAVE_SHOW_TASK, 1, [show_task is exported])
1046 ],[
1047 ])
1048 ])
1049
1050 # LN_TASKLIST_LOCK
1051 # 2.6.18 remove tasklist_lock export
1052 AC_DEFUN([LN_TASKLIST_LOCK],
1053 [LB_CHECK_SYMBOL_EXPORT([tasklist_lock],
1054 [kernel/fork.c],[
1055 AC_DEFINE(HAVE_TASKLIST_LOCK, 1,
1056          [tasklist_lock exported])
1057 ],[
1058 ])
1059 ])
1060
1061 # 2.6.19 API changes
1062 # kmem_cache_destroy(cachep) return void instead of
1063 # int
1064 AC_DEFUN([LN_KMEM_CACHE_DESTROY_INT],
1065 [AC_MSG_CHECKING([kmem_cache_destroy(cachep) return int])
1066 LB_LINUX_TRY_COMPILE([
1067         #include <linux/slab.h>
1068 ],[
1069         int i = kmem_cache_destroy(NULL);
1070 ],[
1071         AC_MSG_RESULT(yes)
1072         AC_DEFINE(HAVE_KMEM_CACHE_DESTROY_INT, 1,
1073                 [kmem_cache_destroy(cachep) return int])
1074 ],[
1075         AC_MSG_RESULT(NO)
1076 ])
1077 ])
1078
1079 # 2.6.19 API change
1080 #panic_notifier_list use atomic_notifier operations
1081 #
1082 AC_DEFUN([LN_ATOMIC_PANIC_NOTIFIER],
1083 [AC_MSG_CHECKING([panic_notifier_list is atomic])
1084 LB_LINUX_TRY_COMPILE([
1085         #include <linux/notifier.h>
1086         #include <linux/kernel.h>
1087 ],[
1088         struct atomic_notifier_head panic_notifier_list;
1089 ],[
1090         AC_MSG_RESULT(yes)
1091         AC_DEFINE(HAVE_ATOMIC_PANIC_NOTIFIER, 1,
1092                 [panic_notifier_list is atomic_notifier_head])
1093 ],[
1094         AC_MSG_RESULT(NO)
1095 ])
1096 ])
1097
1098 # 2.6.20 API change INIT_WORK use 2 args and not
1099 # store data inside
1100 AC_DEFUN([LN_3ARGS_INIT_WORK],
1101 [AC_MSG_CHECKING([check INIT_WORK want 3 args])
1102 LB_LINUX_TRY_COMPILE([
1103         #include <linux/workqueue.h>
1104 ],[
1105         struct work_struct work;
1106
1107         INIT_WORK(&work, NULL, NULL);
1108 ],[
1109         AC_MSG_RESULT(yes)
1110         AC_DEFINE(HAVE_3ARGS_INIT_WORK, 1,
1111                   [INIT_WORK use 3 args and store data inside])
1112 ],[
1113         AC_MSG_RESULT(NO)
1114 ])
1115 ])
1116
1117 # 2.6.21 api change. 'register_sysctl_table' use only one argument,
1118 # instead of more old which need two.
1119 AC_DEFUN([LN_2ARGS_REGISTER_SYSCTL],
1120 [AC_MSG_CHECKING([check register_sysctl_table want 2 args])
1121 LB_LINUX_TRY_COMPILE([
1122         #include <linux/sysctl.h>
1123 ],[
1124         return register_sysctl_table(NULL,0);
1125 ],[
1126         AC_MSG_RESULT(yes)
1127         AC_DEFINE(HAVE_2ARGS_REGISTER_SYSCTL, 1,
1128                   [register_sysctl_table want 2 args])
1129 ],[
1130         AC_MSG_RESULT(NO)
1131 ])
1132 ])
1133
1134 # 2.6.21 marks kmem_cache_t deprecated and uses struct kmem_cache
1135 # instead
1136 AC_DEFUN([LN_KMEM_CACHE],
1137 [AC_MSG_CHECKING([check kernel has struct kmem_cache])
1138 tmp_flags="$EXTRA_KCFLAGS"
1139 EXTRA_KCFLAGS="-Werror"
1140 LB_LINUX_TRY_COMPILE([
1141         #include <linux/slab.h>
1142         typedef struct kmem_cache cache_t;
1143 ],[
1144         cache_t *cachep = NULL;
1145
1146         kmem_cache_alloc(cachep, 0);
1147 ],[
1148         AC_MSG_RESULT(yes)
1149         AC_DEFINE(HAVE_KMEM_CACHE, 1,
1150                   [kernel has struct kmem_cache])
1151 ],[
1152         AC_MSG_RESULT(NO)
1153 ])
1154 EXTRA_KCFLAGS="$tmp_flags"
1155 ])
1156 # 2.6.23 lost dtor argument
1157 AC_DEFUN([LN_KMEM_CACHE_CREATE_DTOR],
1158 [AC_MSG_CHECKING([check kmem_cache_create has dtor argument])
1159 LB_LINUX_TRY_COMPILE([
1160         #include <linux/slab.h>
1161 ],[
1162         kmem_cache_create(NULL, 0, 0, 0, NULL, NULL);
1163 ],[
1164         AC_MSG_RESULT(yes)
1165         AC_DEFINE(HAVE_KMEM_CACHE_CREATE_DTOR, 1,
1166                   [kmem_cache_create has dtor argument])
1167 ],[
1168         AC_MSG_RESULT(NO)
1169 ])
1170 ])
1171
1172 #
1173 # LN_PROG_LINUX
1174 #
1175 # LNet linux kernel checks
1176 #
1177 AC_DEFUN([LN_PROG_LINUX],
1178 [
1179 LN_FUNC_CPU_ONLINE
1180 LN_TYPE_GFP_T
1181 LN_TYPE_CPUMASK_T
1182 LN_CONFIG_AFFINITY
1183 LN_CONFIG_BACKOFF
1184 LN_CONFIG_PANIC_DUMPLOG
1185 LN_CONFIG_QUADRICS
1186 LN_CONFIG_GM
1187 LN_CONFIG_OPENIB
1188 LN_CONFIG_CIB
1189 LN_CONFIG_VIB
1190 LN_CONFIG_IIB
1191 LN_CONFIG_O2IB
1192 LN_CONFIG_RALND
1193 LN_CONFIG_PTLLND
1194 LN_CONFIG_MX
1195
1196 LN_STRUCT_PAGE_LIST
1197 LN_STRUCT_SIGHAND
1198 LN_FUNC_SHOW_TASK
1199 # 2.6.18
1200 LN_TASKLIST_LOCK
1201 # 2.6.19
1202 LN_KMEM_CACHE_DESTROY_INT
1203 LN_ATOMIC_PANIC_NOTIFIER
1204 # 2.6.20
1205 LN_3ARGS_INIT_WORK
1206 # 2.6.21
1207 LN_2ARGS_REGISTER_SYSCTL
1208 LN_KMEM_CACHE
1209 # 2.6.23
1210 LN_KMEM_CACHE_CREATE_DTOR
1211 ])
1212
1213 #
1214 # LN_PROG_DARWIN
1215 #
1216 # Darwin checks
1217 #
1218 AC_DEFUN([LN_PROG_DARWIN],
1219 [LB_DARWIN_CHECK_FUNCS([get_preemption_level])
1220 ])
1221
1222 #
1223 # LN_PATH_DEFAULTS
1224 #
1225 # default paths for installed files
1226 #
1227 AC_DEFUN([LN_PATH_DEFAULTS],
1228 [
1229 ])
1230
1231 #
1232 # LN_CONFIGURE
1233 #
1234 # other configure checks
1235 #
1236 AC_DEFUN([LN_CONFIGURE],
1237 [# lnet/utils/portals.c
1238 AC_CHECK_HEADERS([netdb.h netinet/tcp.h asm/types.h endian.h sys/ioctl.h])
1239 AC_CHECK_FUNCS([gethostbyname socket connect])
1240
1241 # lnet/utils/debug.c
1242 AC_CHECK_HEADERS([linux/version.h])
1243
1244 AC_CHECK_TYPE([spinlock_t],
1245         [AC_DEFINE(HAVE_SPINLOCK_T, 1, [spinlock_t is defined])],
1246         [],
1247         [#include <linux/spinlock.h>])
1248
1249 # lnet/utils/wirecheck.c
1250 AC_CHECK_FUNCS([strnlen])
1251
1252 # --------  Check for required packages  --------------
1253
1254 #
1255 # LC_CONFIG_READLINE
1256 #
1257 # Build with readline
1258 #
1259 AC_MSG_CHECKING([whether to enable readline support])
1260 AC_ARG_ENABLE(readline,
1261         AC_HELP_STRING([--disable-readline],
1262                         [disable readline support]),
1263         [],[enable_readline='yes'])
1264 AC_MSG_RESULT([$enable_readline])
1265
1266 # -------- check for readline if enabled ----
1267 if test x$enable_readline = xyes ; then
1268         LIBS_save="$LIBS"
1269         LIBS="-lncurses $LIBS"
1270         AC_CHECK_LIB([readline],[readline],[
1271         LIBREADLINE="-lreadline -lncurses"
1272         AC_DEFINE(HAVE_LIBREADLINE, 1, [readline library is available])
1273         ],[
1274         LIBREADLINE=""
1275         ])
1276         LIBS="$LIBS_save"
1277 else
1278         LIBREADLINE=""
1279 fi
1280 AC_SUBST(LIBREADLINE)
1281
1282 AC_MSG_CHECKING([if efence debugging support is requested])
1283 AC_ARG_ENABLE(efence,
1284         AC_HELP_STRING([--enable-efence],
1285                         [use efence library]),
1286         [],[enable_efence='no'])
1287 AC_MSG_RESULT([$enable_efence])
1288 if test "$enable_efence" = "yes" ; then
1289         LIBEFENCE="-lefence"
1290         AC_DEFINE(HAVE_LIBEFENCE, 1, [libefence support is requested])
1291 else
1292         LIBEFENCE=""
1293 fi
1294 AC_SUBST(LIBEFENCE)
1295
1296 # -------- enable acceptor libwrap (TCP wrappers) support? -------
1297 AC_MSG_CHECKING([if libwrap support is requested])
1298 AC_ARG_ENABLE([libwrap],
1299         AC_HELP_STRING([--enable-libwrap], [use TCP wrappers]),
1300         [case "${enableval}" in
1301                 yes) enable_libwrap=yes ;;
1302                 no) enable_libwrap=no ;;
1303                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-libwrap) ;;
1304         esac],[enable_libwrap=no])
1305 AC_MSG_RESULT([$enable_libwrap])
1306 if test x$enable_libwrap = xyes ; then
1307         LIBWRAP="-lwrap"
1308         AC_DEFINE(HAVE_LIBWRAP, 1, [libwrap support is requested])
1309 else
1310         LIBWRAP=""
1311 fi
1312 AC_SUBST(LIBWRAP)
1313
1314 # -------- check for -lpthread support ----
1315 AC_MSG_CHECKING([whether to use libpthread for lnet library])
1316 AC_ARG_ENABLE([libpthread],
1317         AC_HELP_STRING([--disable-libpthread],
1318                 [disable libpthread]),
1319         [],[enable_libpthread=yes])
1320 if test "$enable_libpthread" = "yes" ; then
1321         AC_CHECK_LIB([pthread], [pthread_create],
1322                 [ENABLE_LIBPTHREAD="yes"],
1323                 [ENABLE_LIBPTHREAD="no"])
1324         if test "$ENABLE_LIBPTHREAD" = "yes" ; then
1325                 AC_MSG_RESULT([$ENABLE_LIBPTHREAD])
1326                 PTHREAD_LIBS="-lpthread"
1327                 AC_DEFINE([HAVE_LIBPTHREAD], 1, [use libpthread])
1328         else
1329                 PTHREAD_LIBS=""
1330                 AC_MSG_RESULT([no libpthread is found])
1331         fi
1332         AC_SUBST(PTHREAD_LIBS)
1333 else
1334         AC_MSG_RESULT([no (disabled explicitly)])
1335         ENABLE_LIBPTHREAD="no"
1336 fi
1337 AC_SUBST(ENABLE_LIBPTHREAD)
1338
1339 # ----------------------------------------
1340 # some tests for catamount-like systems
1341 # ----------------------------------------
1342 AC_ARG_ENABLE([sysio_init],
1343         AC_HELP_STRING([--disable-sysio-init],
1344                 [call sysio init functions when initializing liblustre]),
1345         [],[enable_sysio_init=yes])
1346 AC_MSG_CHECKING([whether to initialize libsysio])
1347 AC_MSG_RESULT([$enable_sysio_init])
1348 if test x$enable_sysio_init != xno ; then
1349         AC_DEFINE([INIT_SYSIO], 1, [call sysio init functions])
1350 fi
1351
1352 AC_ARG_ENABLE([urandom],
1353         AC_HELP_STRING([--disable-urandom],
1354                 [disable use of /dev/urandom for liblustre]),
1355         [],[enable_urandom=yes])
1356 AC_MSG_CHECKING([whether to use /dev/urandom for liblustre])
1357 AC_MSG_RESULT([$enable_urandom])
1358 if test x$enable_urandom != xno ; then
1359         AC_DEFINE([LIBLUSTRE_USE_URANDOM], 1, [use /dev/urandom for random data])
1360 fi
1361
1362 # -------- check for -lcap support ----
1363 if test x$enable_liblustre = xyes ; then
1364         AC_CHECK_LIB([cap], [cap_get_proc],
1365                 [
1366                         CAP_LIBS="-lcap"
1367                         AC_DEFINE([HAVE_LIBCAP], 1, [use libcap])
1368                 ],
1369                 [
1370                         CAP_LIBS=""
1371                 ])
1372         AC_SUBST(CAP_LIBS)
1373
1374 fi
1375
1376 LN_CONFIG_MAX_PAYLOAD
1377 LN_CONFIG_UPTLLND
1378 LN_CONFIG_USOCKLND
1379 ])
1380
1381 #
1382 # LN_CONDITIONALS
1383 #
1384 # AM_CONDITOINAL defines for lnet
1385 #
1386 AC_DEFUN([LN_CONDITIONALS],
1387 [AM_CONDITIONAL(BUILD_QSWLND, test x$QSWLND = "xqswlnd")
1388 AM_CONDITIONAL(BUILD_GMLND, test x$GMLND = "xgmlnd")
1389 AM_CONDITIONAL(BUILD_MXLND, test x$MXLND = "xmxlnd")
1390 AM_CONDITIONAL(BUILD_O2IBLND, test x$O2IBLND = "xo2iblnd")
1391 AM_CONDITIONAL(BUILD_OPENIBLND, test x$OPENIBLND = "xopeniblnd")
1392 AM_CONDITIONAL(BUILD_CIBLND, test x$CIBLND = "xciblnd")
1393 AM_CONDITIONAL(BUILD_IIBLND, test x$IIBLND = "xiiblnd")
1394 AM_CONDITIONAL(BUILD_VIBLND, test x$VIBLND = "xviblnd")
1395 AM_CONDITIONAL(BUILD_RALND, test x$RALND = "xralnd")
1396 AM_CONDITIONAL(BUILD_PTLLND, test x$PTLLND = "xptllnd")
1397 AM_CONDITIONAL(BUILD_UPTLLND, test x$UPTLLND = "xptllnd")
1398 AM_CONDITIONAL(BUILD_USOCKLND, test x$USOCKLND = "xusocklnd")
1399 ])
1400
1401 #
1402 # LN_CONFIG_FILES
1403 #
1404 # files that should be generated with AC_OUTPUT
1405 #
1406 AC_DEFUN([LN_CONFIG_FILES],
1407 [AC_CONFIG_FILES([
1408 lnet/Kernelenv
1409 lnet/Makefile
1410 lnet/autoMakefile
1411 lnet/autoconf/Makefile
1412 lnet/doc/Makefile
1413 lnet/include/Makefile
1414 lnet/include/libcfs/Makefile
1415 lnet/include/libcfs/linux/Makefile
1416 lnet/include/lnet/Makefile
1417 lnet/include/lnet/linux/Makefile
1418 lnet/klnds/Makefile
1419 lnet/klnds/autoMakefile
1420 lnet/klnds/gmlnd/Makefile
1421 lnet/klnds/mxlnd/autoMakefile
1422 lnet/klnds/mxlnd/Makefile
1423 lnet/klnds/gmlnd/autoMakefile
1424 lnet/klnds/openiblnd/Makefile
1425 lnet/klnds/openiblnd/autoMakefile
1426 lnet/klnds/o2iblnd/Makefile
1427 lnet/klnds/o2iblnd/autoMakefile
1428 lnet/klnds/ciblnd/Makefile
1429 lnet/klnds/ciblnd/autoMakefile
1430 lnet/klnds/iiblnd/Makefile
1431 lnet/klnds/iiblnd/autoMakefile
1432 lnet/klnds/viblnd/Makefile
1433 lnet/klnds/viblnd/autoMakefile
1434 lnet/klnds/qswlnd/Makefile
1435 lnet/klnds/qswlnd/autoMakefile
1436 lnet/klnds/ralnd/Makefile
1437 lnet/klnds/ralnd/autoMakefile
1438 lnet/klnds/socklnd/Makefile
1439 lnet/klnds/socklnd/autoMakefile
1440 lnet/klnds/ptllnd/Makefile
1441 lnet/klnds/ptllnd/autoMakefile
1442 lnet/libcfs/Makefile
1443 lnet/libcfs/autoMakefile
1444 lnet/libcfs/linux/Makefile
1445 lnet/lnet/Makefile
1446 lnet/lnet/autoMakefile
1447 lnet/selftest/Makefile
1448 lnet/selftest/autoMakefile
1449 lnet/ulnds/Makefile
1450 lnet/ulnds/autoMakefile
1451 lnet/ulnds/socklnd/Makefile
1452 lnet/ulnds/ptllnd/Makefile
1453 lnet/utils/Makefile
1454 ])
1455 case $lb_target_os in
1456         darwin)
1457                 AC_CONFIG_FILES([
1458 lnet/include/libcfs/darwin/Makefile
1459 lnet/include/lnet/darwin/Makefile
1460 lnet/libcfs/darwin/Makefile
1461 ])
1462                 ;;
1463 esac
1464 ])