lnet/autoconf/lustre-lnet.m4

   1 #
   2 # LN_CONFIG_MAX_PAYLOAD
   3 #
   4 # configure maximum payload
   5 #
   6 AC_DEFUN([LN_CONFIG_MAX_PAYLOAD],
   7 [AC_MSG_CHECKING([for non-default maximum LNET payload])
   8 AC_ARG_WITH([max-payload-mb],
   9         AC_HELP_STRING([--with-max-payload-mb=MBytes],
  10                        [set maximum lnet payload in MBytes]),
  11         [
  12                 AC_MSG_RESULT([$with_max_payload_mb])
  13                 LNET_MAX_PAYLOAD_MB=$with_max_payload_mb
  14                 LNET_MAX_PAYLOAD="(($with_max_payload_mb)<<20)"
  15         ], [
  16                 AC_MSG_RESULT([no])
  17                 LNET_MAX_PAYLOAD="LNET_MTU"
  18         ])
  19         AC_DEFINE_UNQUOTED(LNET_MAX_PAYLOAD, $LNET_MAX_PAYLOAD,
  20                            [Max LNET payload])
  21 ])
  22
  23 #
  24 # LN_CHECK_GCC_VERSION
  25 #
  26 # Check compiler version
  27 #
  28 AC_DEFUN([LN_CHECK_GCC_VERSION],
  29 [AC_MSG_CHECKING([compiler version])
  30 PTL_CC_VERSION=`$CC --version | awk '/^gcc/{print $ 3}'`
  31 PTL_MIN_CC_VERSION="3.2.2"
  32 v2n() {
  33         awk -F. '{printf "%d\n", (($ 1)*100+($ 2))*100+($ 3)}'
  34 }
  35 if test -z "$PTL_CC_VERSION" -o \
  36         `echo $PTL_CC_VERSION | v2n` -ge `echo $PTL_MIN_CC_VERSION | v2n`; then
  37         AC_MSG_RESULT([ok])
  38 else
  39         AC_MSG_RESULT([Buggy compiler found])
  40         AC_MSG_ERROR([Need gcc version >= $PTL_MIN_CC_VERSION])
  41 fi
  42 ])
  43
  44 #
  45 # LN_CONFIG_CDEBUG
  46 #
  47 # whether to enable various libcfs debugs (CDEBUG, ENTRY/EXIT, LASSERT, etc.)
  48 #
  49 AC_DEFUN([LN_CONFIG_CDEBUG],
  50 [
  51 AC_MSG_CHECKING([whether to enable CDEBUG, CWARN])
  52 AC_ARG_ENABLE([libcfs_cdebug],
  53         AC_HELP_STRING([--disable-libcfs-cdebug],
  54                         [disable libcfs CDEBUG, CWARN]),
  55         [],[enable_libcfs_cdebug='yes'])
  56 AC_MSG_RESULT([$enable_libcfs_cdebug])
  57 if test x$enable_libcfs_cdebug = xyes; then
  58    AC_DEFINE(CDEBUG_ENABLED, 1, [enable libcfs CDEBUG, CWARN])
  59 else
  60    AC_DEFINE(CDEBUG_ENABLED, 0, [disable libcfs CDEBUG, CWARN])
  61 fi
  62
  63 AC_MSG_CHECKING([whether to enable ENTRY/EXIT])
  64 AC_ARG_ENABLE([libcfs_trace],
  65         AC_HELP_STRING([--disable-libcfs-trace],
  66                         [disable libcfs ENTRY/EXIT]),
  67         [],[enable_libcfs_trace='yes'])
  68 AC_MSG_RESULT([$enable_libcfs_trace])
  69 if test x$enable_libcfs_trace = xyes; then
  70    AC_DEFINE(CDEBUG_ENTRY_EXIT, 1, [enable libcfs ENTRY/EXIT])
  71 else
  72    AC_DEFINE(CDEBUG_ENTRY_EXIT, 0, [disable libcfs ENTRY/EXIT])
  73 fi
  74
  75 AC_MSG_CHECKING([whether to enable LASSERT, LASSERTF])
  76 AC_ARG_ENABLE([libcfs_assert],
  77         AC_HELP_STRING([--disable-libcfs-assert],
  78                         [disable libcfs LASSERT, LASSERTF]),
  79         [],[enable_libcfs_assert='yes'])
  80 AC_MSG_RESULT([$enable_libcfs_assert])
  81 if test x$enable_libcfs_assert = xyes; then
  82    AC_DEFINE(LIBCFS_DEBUG, 1, [enable libcfs LASSERT, LASSERTF])
  83 fi
  84 ])
  85
  86 #
  87 # LN_CONFIG_AFFINITY
  88 #
  89 # check if cpu affinity is available/wanted
  90 #
  91 AC_DEFUN([LN_CONFIG_AFFINITY],
  92 [AC_ARG_ENABLE([affinity],
  93         AC_HELP_STRING([--disable-affinity],
  94                        [disable process/irq affinity]),
  95         [],[enable_affinity='yes'])
  96
  97 AC_MSG_CHECKING([for CPU affinity support])
  98 if test x$enable_affinity = xno ; then
  99         AC_MSG_RESULT([no (by request)])
 100 else
 101         LB_LINUX_TRY_COMPILE([
 102                 #include <linux/sched.h>
 103         ],[
 104                 struct task_struct t;
 105                 #if HAVE_CPUMASK_T
 106                 cpumask_t     m;
 107                 #else
 108                 unsigned long m;
 109                 #endif
 110                 set_cpus_allowed(&t, m);
 111         ],[
 112                 AC_DEFINE(CPU_AFFINITY, 1, [kernel has cpu affinity support])
 113                 AC_MSG_RESULT([yes])
 114         ],[
 115                 AC_MSG_RESULT([no (no kernel support)])
 116         ])
 117 fi
 118 ])
 119
 120 #
 121 # LN_CONFIG_PORTALS
 122 #
 123 # configure support for Portals
 124 #
 125 AC_DEFUN([LN_CONFIG_PORTALS],
 126 [AC_MSG_CHECKING([for portals])
 127 AC_ARG_WITH([portals],
 128         AC_HELP_STRING([--with-portals=path],
 129                        [set path to portals]),
 130         [
 131                 case $with_portals in
 132                         no)     ENABLEPORTALS=0
 133                                 ;;
 134                         *)      PORTALS="${with_portals}"
 135                                 ENABLEPORTALS=1
 136                                 ;;
 137                 esac
 138         ], [
 139                 ENABLEPORTALS=0
 140         ])
 141 PTLLNDCPPFLAGS=""
 142 if test $ENABLEPORTALS -eq 0; then
 143         AC_MSG_RESULT([no])
 144 elif test ! \( -f ${PORTALS}/include/portals/p30.h \); then
 145         AC_MSG_RESULT([no])
 146         AC_MSG_ERROR([bad --with-portals path])
 147 else
 148         AC_MSG_RESULT([$PORTALS])
 149         PTLLNDCPPFLAGS="-I${PORTALS}/include"
 150 fi
 151 AC_SUBST(PTLLNDCPPFLAGS)
 152 ])
 153
 154 #
 155 # LN_CONFIG_BACKOFF
 156 #
 157 # check if tunable tcp backoff is available/wanted
 158 #
 159 AC_DEFUN([LN_CONFIG_BACKOFF],
 160 [AC_MSG_CHECKING([for tunable backoff TCP support])
 161 AC_ARG_ENABLE([backoff],
 162        AC_HELP_STRING([--disable-backoff],
 163                       [disable socknal tunable backoff]),
 164        [],[enable_backoff='yes'])
 165 if test x$enable_backoff = xno ; then
 166        AC_MSG_RESULT([no (by request)])
 167 else
 168        BOCD="`grep -c TCP_BACKOFF $LINUX/include/linux/tcp.h`"
 169        if test "$BOCD" != 0 ; then
 170                AC_DEFINE(SOCKNAL_BACKOFF, 1, [use tunable backoff TCP])
 171                AC_MSG_RESULT(yes)
 172        else
 173                AC_MSG_RESULT([no (no kernel support)])
 174        fi
 175 fi
 176 ])
 177
 178 #
 179 # LN_CONFIG_PANIC_DUMPLOG
 180 #
 181 # check if tunable panic_dumplog is wanted
 182 #
 183 AC_DEFUN([LN_CONFIG_PANIC_DUMPLOG],
 184 [AC_MSG_CHECKING([for tunable panic_dumplog support])
 185 AC_ARG_ENABLE([panic_dumplog],
 186        AC_HELP_STRING([--enable-panic_dumplog],
 187                       [enable panic_dumplog]),
 188        [],[enable_panic_dumplog='no'])
 189 if test x$enable_panic_dumplog = xyes ; then
 190        AC_DEFINE(LNET_DUMP_ON_PANIC, 1, [use dumplog on panic])
 191        AC_MSG_RESULT([yes (by request)])
 192 else
 193        AC_MSG_RESULT([no])
 194 fi
 195 ])
 196
 197 #
 198 # LN_CONFIG_PTLLND
 199 #
 200 # configure support for Portals LND
 201 #
 202 AC_DEFUN([LN_CONFIG_PTLLND],
 203 [
 204 if test -z "$ENABLEPORTALS"; then
 205         LN_CONFIG_PORTALS
 206 fi
 207
 208 AC_MSG_CHECKING([whether to build the kernel portals LND])
 209
 210 PTLLND=""
 211 if test $ENABLEPORTALS -ne 0; then
 212         AC_MSG_RESULT([yes])
 213         PTLLND="ptllnd"
 214 else
 215         AC_MSG_RESULT([no])
 216 fi
 217 AC_SUBST(PTLLND)
 218 ])
 219
 220 #
 221 # LN_CONFIG_UPTLLND
 222 #
 223 # configure support for Portals LND
 224 #
 225 AC_DEFUN([LN_CONFIG_UPTLLND],
 226 [
 227 if test -z "$ENABLEPORTALS"; then
 228         LN_CONFIG_PORTALS
 229 fi
 230
 231 AC_MSG_CHECKING([whether to build the userspace portals LND])
 232
 233 UPTLLND=""
 234 if test $ENABLEPORTALS -ne 0; then
 235         AC_MSG_RESULT([yes])
 236         UPTLLND="ptllnd"
 237 else
 238         AC_MSG_RESULT([no])
 239 fi
 240 AC_SUBST(UPTLLND)
 241 ])
 242
 243 #
 244 # LN_CONFIG_USOCKLND
 245 #
 246 # configure support for userspace TCP/IP LND
 247 #
 248 AC_DEFUN([LN_CONFIG_USOCKLND],
 249 [AC_MSG_CHECKING([whether to build usocklnd])
 250 AC_ARG_ENABLE([usocklnd],
 251         AC_HELP_STRING([--disable-usocklnd],
 252                         [disable usocklnd]),
 253         [],[enable_usocklnd='yes'])
 254
 255 if test x$enable_usocklnd = xyes ; then
 256         if test "$ENABLE_LIBPTHREAD" = "yes" ; then
 257                 AC_MSG_RESULT([yes])
 258                 USOCKLND="usocklnd"
 259         else
 260                 AC_MSG_RESULT([no (libpthread not present or disabled)])
 261                 USOCKLND=""
 262         fi
 263 else
 264         AC_MSG_RESULT([no (disabled explicitly)])
 265         USOCKLND=""
 266 fi
 267 AC_SUBST(USOCKLND)
 268 ])
 269
 270 #
 271 # LN_CONFIG_QUADRICS
 272 #
 273 # check if quadrics support is in this kernel
 274 #
 275 AC_DEFUN([LN_CONFIG_QUADRICS],
 276 [AC_MSG_CHECKING([for QsNet sources])
 277 AC_ARG_WITH([qsnet],
 278         AC_HELP_STRING([--with-qsnet=path],
 279                        [set path to qsnet source (default=$LINUX)]),
 280         [QSNET=$with_qsnet],
 281         [QSNET=$LINUX])
 282 AC_MSG_RESULT([$QSNET])
 283
 284 AC_MSG_CHECKING([if quadrics kernel headers are present])
 285 if test -d $QSNET/drivers/net/qsnet ; then
 286         AC_MSG_RESULT([yes])
 287         QSWLND="qswlnd"
 288         AC_MSG_CHECKING([for multirail EKC])
 289         if test -f $QSNET/include/elan/epcomms.h; then
 290                 AC_MSG_RESULT([supported])
 291                 QSWCPPFLAGS="-I$QSNET/include -DMULTIRAIL_EKC=1"
 292         else
 293                 AC_MSG_RESULT([not supported])
 294                 AC_MSG_ERROR([Need multirail EKC])
 295         fi
 296
 297         if test x$QSNET = x$LINUX ; then
 298                 LB_LINUX_CONFIG([QSNET],[],[
 299                         LB_LINUX_CONFIG([QSNET_MODULE],[],[
 300                                 AC_MSG_WARN([QSNET is not enabled in this kernel; not building qswlnd.])
 301                                 QSWLND=""
 302                                 QSWCPPFLAGS=""
 303                         ])
 304                 ])
 305         fi
 306 else
 307         AC_MSG_RESULT([no])
 308         QSWLND=""
 309         QSWCPPFLAGS=""
 310 fi
 311 AC_SUBST(QSWCPPFLAGS)
 312 AC_SUBST(QSWLND)
 313 ])
 314
 315 #
 316 # LN_CONFIG_GM
 317 #
 318 # check if GM support is available
 319 #
 320 AC_DEFUN([LN_CONFIG_GM],[
 321 AC_MSG_CHECKING([whether to enable GM support])
 322 AC_ARG_WITH([gm],
 323         AC_HELP_STRING([--with-gm=path-to-gm-source-tree],
 324                        [build gmlnd against path]),
 325         [
 326                 case $with_gm in
 327                 no)    ENABLE_GM=0
 328                        ;;
 329                 *)     ENABLE_GM=1
 330                        GM_SRC="$with_gm"
 331                        ;;
 332                 esac
 333         ],[
 334                 ENABLE_GM=0
 335         ])
 336 AC_ARG_WITH([gm-install],
 337         AC_HELP_STRING([--with-gm-install=path-to-gm-install-tree],
 338                        [say where GM has been installed]),
 339         [
 340                 GM_INSTALL=$with_gm_install
 341         ],[
 342                 GM_INSTALL="/opt/gm"
 343         ])
 344 if test $ENABLE_GM -eq 0; then
 345         AC_MSG_RESULT([no])
 346 else
 347         AC_MSG_RESULT([yes])
 348
 349         GMLND="gmlnd"
 350         GMCPPFLAGS="-I$GM_SRC/include -I$GM_SRC/drivers -I$GM_SRC/drivers/linux/gm"
 351
 352         if test -f $GM_INSTALL/lib/libgm.a -o \
 353                 -f $GM_INSTALL/lib64/libgm.a; then
 354                 GMLIBS="-L$GM_INSTALL/lib -L$GM_INSTALL/lib64"
 355         else
 356                 AC_MSG_ERROR([Cant find GM libraries under $GM_INSTALL])
 357         fi
 358
 359         EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 360         EXTRA_KCFLAGS="$GMCPPFLAGS -DGM_KERNEL $EXTRA_KCFLAGS"
 361
 362         AC_MSG_CHECKING([that code using GM compiles with given path])
 363         LB_LINUX_TRY_COMPILE([
 364                 #define GM_STRONG_TYPES 1
 365                 #ifdef VERSION
 366                 #undef VERSION
 367                 #endif
 368                 #include "gm.h"
 369                 #include "gm_internal.h"
 370         ],[
 371                 struct gm_port *port = NULL;
 372                 gm_recv_event_t *rxevent = gm_blocking_receive_no_spin(port);
 373                 return 0;
 374         ],[
 375                 AC_MSG_RESULT([yes])
 376         ],[
 377                 AC_MSG_RESULT([no])
 378                 AC_MSG_ERROR([Bad --with-gm path])
 379         ])
 380
 381         AC_MSG_CHECKING([that GM has gm_register_memory_ex_phys()])
 382         LB_LINUX_TRY_COMPILE([
 383                 #define GM_STRONG_TYPES 1
 384                 #ifdef VERSION
 385                 #undef VERSION
 386                 #endif
 387                 #include "gm.h"
 388                 #include "gm_internal.h"
 389         ],[
 390                 gm_status_t     gmrc;
 391                 struct gm_port *port = NULL;
 392                 gm_u64_t        phys = 0;
 393                 gm_up_t         pvma = 0;
 394
 395                 gmrc = gm_register_memory_ex_phys(port, phys, 100, pvma);
 396                 return 0;
 397         ],[
 398                 AC_MSG_RESULT([yes])
 399         ],[
 400                 AC_MSG_RESULT([no.
 401 Please patch the GM sources as follows...
 402     cd $GM_SRC
 403     patch -p0 < $PWD/lnet/klnds/gmlnd/gm-reg-phys.patch
 404 ...then rebuild and re-install them])
 405                 AC_MSG_ERROR([Can't build GM without gm_register_memory_ex_phys()])
 406         ])
 407
 408         EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 409 fi
 410 AC_SUBST(GMCPPFLAGS)
 411 AC_SUBST(GMLIBS)
 412 AC_SUBST(GMLND)
 413 ])
 414
 415
 416 #
 417 # LN_CONFIG_MX
 418 #
 419 AC_DEFUN([LN_CONFIG_MX],
 420 [AC_MSG_CHECKING([whether to enable Myrinet MX support])
 421 # set default
 422 MXPATH="/opt/mx"
 423 AC_ARG_WITH([mx],
 424        AC_HELP_STRING([--with-mx=path],
 425                       [build mxlnd against path]),
 426        [
 427                case $with_mx in
 428                yes)    ENABLEMX=2
 429                        ;;
 430                no)     ENABLEMX=0
 431                        ;;
 432                *)      MXPATH=$with_mx
 433                        ENABLEMX=3
 434                        ;;
 435                esac
 436        ],[
 437                ENABLEMX=1
 438        ])
 439 if test $ENABLEMX -eq 0; then
 440        AC_MSG_RESULT([disabled])
 441 elif test ! \( -f ${MXPATH}/include/myriexpress.h -a \
 442               -f ${MXPATH}/include/mx_kernel_api.h -a \
 443               -f ${MXPATH}/include/mx_pin.h \); then
 444        AC_MSG_RESULT([no])
 445        case $ENABLEMX in
 446        1) ;;
 447        2) AC_MSG_ERROR([Myrinet MX kernel headers not present]);;
 448        3) AC_MSG_ERROR([bad --with-mx path]);;
 449        *) AC_MSG_ERROR([internal error]);;
 450        esac
 451 else
 452        MXCPPFLAGS="-I$MXPATH/include"
 453        EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 454        EXTRA_KCFLAGS="$EXTRA_KCFLAGS $MXCPPFLAGS"
 455        MXLIBS="-L$MXPATH/lib"
 456        LB_LINUX_TRY_COMPILE([
 457                #define MX_KERNEL 1
 458                #include <mx_extensions.h>
 459                #include <myriexpress.h>
 460        ],[
 461                mx_endpoint_t   end;
 462                mx_status_t     status;
 463                mx_request_t    request;
 464                int             result;
 465
 466                mx_init();
 467                mx_open_endpoint(MX_ANY_NIC, MX_ANY_ENDPOINT, 0, NULL, 0, &end);
 468                mx_register_unexp_handler(end, (mx_unexp_handler_t) NULL, NULL);
 469                mx_wait_any(end, MX_INFINITE, 0LL, 0LL, &status, &result);
 470                mx_iconnect(end, 0LL, 0, 0, 0, NULL, &request);
 471                return 0;
 472        ],[
 473                AC_MSG_RESULT([yes])
 474                MXLND="mxlnd"
 475        ],[
 476                AC_MSG_RESULT([no])
 477                case $ENABLEMX in
 478                1) ;;
 479                2) AC_MSG_ERROR([can't compile with Myrinet MX kernel headers]);;
 480                3) AC_MSG_ERROR([can't compile with Myrinet MX headers under $MXPATH]);;
 481                *) AC_MSG_ERROR([internal error]);;
 482                esac
 483                MXLND=""
 484                MXCPPFLAGS=""
 485        ])
 486        EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 487 fi
 488 AC_SUBST(MXCPPFLAGS)
 489 AC_SUBST(MXLIBS)
 490 AC_SUBST(MXLND)
 491 ])
 492
 493
 494
 495 #
 496 # LN_CONFIG_O2IB
 497 #
 498 AC_DEFUN([LN_CONFIG_O2IB],[
 499 AC_MSG_CHECKING([whether to enable OpenIB gen2 support])
 500 # set default
 501 AC_ARG_WITH([o2ib],
 502         AC_HELP_STRING([--with-o2ib=path],
 503                        [build o2iblnd against path]),
 504         [
 505                 case $with_o2ib in
 506                 yes)    O2IBPATHS="$LINUX $LINUX/drivers/infiniband"
 507                         ENABLEO2IB=2
 508                         ;;
 509                 no)     ENABLEO2IB=0
 510                         ;;
 511                 *)      O2IBPATHS=$with_o2ib
 512                         ENABLEO2IB=3
 513                         ;;
 514                 esac
 515         ],[
 516                 O2IBPATHS="$LINUX $LINUX/drivers/infiniband"
 517                 ENABLEO2IB=1
 518         ])
 519 if test $ENABLEO2IB -eq 0; then
 520         AC_MSG_RESULT([disabled])
 521 else
 522         o2ib_found=false
 523         for O2IBPATH in $O2IBPATHS; do
 524                 if test \( -f ${O2IBPATH}/include/rdma/rdma_cm.h -a \
 525                            -f ${O2IBPATH}/include/rdma/ib_cm.h -a \
 526                            -f ${O2IBPATH}/include/rdma/ib_verbs.h -a \
 527                            -f ${O2IBPATH}/include/rdma/ib_fmr_pool.h \); then
 528                         o2ib_found=true
 529                         break
 530                 fi
 531         done
 532         if ! $o2ib_found; then
 533                 AC_MSG_RESULT([no])
 534                 case $ENABLEO2IB in
 535                         1) ;;
 536                         2) AC_MSG_ERROR([kernel OpenIB gen2 headers not present]);;
 537                         3) AC_MSG_ERROR([bad --with-o2ib path]);;
 538                         *) AC_MSG_ERROR([internal error]);;
 539                 esac
 540         else
 541                 O2IBCPPFLAGS="-I$O2IBPATH/include"
 542                 EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 543                 EXTRA_KCFLAGS="$EXTRA_KCFLAGS $O2IBCPPFLAGS"
 544                 EXTRA_LNET_INCLUDE="$O2IBCPPFLAGS $EXTRA_LNET_INCLUDE"
 545                 LB_LINUX_TRY_COMPILE([
 546                         #include <linux/version.h>
 547                         #include <linux/pci.h>
 548                         #if !HAVE_GFP_T
 549                         typedef int gfp_t;
 550                         #endif
 551                         #include <rdma/rdma_cm.h>
 552                         #include <rdma/ib_cm.h>
 553                         #include <rdma/ib_verbs.h>
 554                         #include <rdma/ib_fmr_pool.h>
 555                 ],[
 556                         struct rdma_cm_id          *cm_id;
 557                         struct rdma_conn_param      conn_param;
 558                         struct ib_device_attr       device_attr;
 559                         struct ib_qp_attr           qp_attr;
 560                         struct ib_pool_fmr          pool_fmr;
 561                         enum   ib_cm_rej_reason     rej_reason;
 562
 563                         cm_id = rdma_create_id(NULL, NULL, RDMA_PS_TCP);
 564                         return PTR_ERR(cm_id);
 565                 ],[
 566                         AC_MSG_RESULT([yes])
 567                         O2IBLND="o2iblnd"
 568                 ],[
 569                         AC_MSG_RESULT([no])
 570                         case $ENABLEO2IB in
 571                         1) ;;
 572                         2) AC_MSG_ERROR([can't compile with kernel OpenIB gen2 headers]);;
 573                         3) AC_MSG_ERROR([can't compile with OpenIB gen2 headers under $O2IBPATH]);;
 574                         *) AC_MSG_ERROR([internal error]);;
 575                         esac
 576                         O2IBLND=""
 577                         O2IBCPPFLAGS=""
 578                 ])
 579
 580                 # version checking is a hack and isn't reliable,
 581                 # we need verify it with each new ofed release
 582
 583                 if grep -q ib_dma_map_single \
 584                         ${O2IBPATH}/include/rdma/ib_verbs.h; then
 585                         if grep -q comp_vector \
 586                                 ${O2IBPATH}/include/rdma/ib_verbs.h; then
 587                                 IBLND_OFED_VERSION="1025"
 588                         else
 589                                 IBLND_OFED_VERSION="1020"
 590                         fi
 591                 else
 592                         IBLND_OFED_VERSION="1010"
 593                 fi
 594
 595                 AC_DEFINE_UNQUOTED(IBLND_OFED_VERSION, $IBLND_OFED_VERSION,
 596                                    [OFED version])
 597
 598                 EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 599         fi
 600 fi
 601
 602 AC_SUBST(EXTRA_LNET_INCLUDE)
 603 AC_SUBST(O2IBCPPFLAGS)
 604 AC_SUBST(O2IBLND)
 605 ])
 606
 607 #
 608 # LN_CONFIG_OPENIB
 609 #
 610 # check for OpenIB in the kernel
 611 AC_DEFUN([LN_CONFIG_OPENIB],[
 612 AC_MSG_CHECKING([whether to enable OpenIB support])
 613 # set default
 614 OPENIBPATH="$LINUX/drivers/infiniband"
 615 AC_ARG_WITH([openib],
 616         AC_HELP_STRING([--with-openib=path],
 617                        [build openiblnd against path]),
 618         [
 619                 case $with_openib in
 620                 yes)    ENABLEOPENIB=2
 621                         ;;
 622                 no)     ENABLEOPENIB=0
 623                         ;;
 624                 *)      OPENIBPATH="$with_openib"
 625                         ENABLEOPENIB=3
 626                         ;;
 627                 esac
 628         ],[
 629                 ENABLEOPENIB=1
 630         ])
 631 if test $ENABLEOPENIB -eq 0; then
 632         AC_MSG_RESULT([disabled])
 633 elif test ! \( -f ${OPENIBPATH}/include/ts_ib_core.h -a \
 634                -f ${OPENIBPATH}/include/ts_ib_cm.h -a\
 635                -f ${OPENIBPATH}/include/ts_ib_sa_client.h \); then
 636         AC_MSG_RESULT([no])
 637         case $ENABLEOPENIB in
 638         1) ;;
 639         2) AC_MSG_ERROR([kernel OpenIB headers not present]);;
 640         3) AC_MSG_ERROR([bad --with-openib path]);;
 641         *) AC_MSG_ERROR([internal error]);;
 642         esac
 643 else
 644         case $ENABLEOPENIB in
 645         1|2) OPENIBCPPFLAGS="-I$OPENIBPATH/include -DIN_TREE_BUILD";;
 646         3)   OPENIBCPPFLAGS="-I$OPENIBPATH/include";;
 647         *)   AC_MSG_RESULT([no])
 648              AC_MSG_ERROR([internal error]);;
 649         esac
 650         OPENIBCPPFLAGS="$OPENIBCPPFLAGS -DIB_NTXRXPARAMS=4"
 651         EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 652         EXTRA_KCFLAGS="$EXTRA_KCFLAGS $OPENIBCPPFLAGS"
 653         LB_LINUX_TRY_COMPILE([
 654                 #include <ts_ib_core.h>
 655                 #include <ts_ib_cm.h>
 656                 #include <ts_ib_sa_client.h>
 657         ],[
 658                 struct ib_device_properties dev_props;
 659                 struct ib_cm_active_param   cm_active_params;
 660                 tTS_IB_CLIENT_QUERY_TID     tid;
 661                 int                         enum1 = IB_QP_ATTRIBUTE_STATE;
 662                 int                         enum2 = IB_ACCESS_LOCAL_WRITE;
 663                 int                         enum3 = IB_CQ_CALLBACK_INTERRUPT;
 664                 int                         enum4 = IB_CQ_PROVIDER_REARM;
 665                 return 0;
 666         ],[
 667                 AC_MSG_RESULT([yes])
 668                 OPENIBLND="openiblnd"
 669         ],[
 670                 AC_MSG_RESULT([no])
 671                 case $ENABLEOPENIB in
 672                 1) ;;
 673                 2) AC_MSG_ERROR([can't compile with kernel OpenIB headers]);;
 674                 3) AC_MSG_ERROR([can't compile with OpenIB headers under $OPENIBPATH]);;
 675                 *) AC_MSG_ERROR([internal error]);;
 676                 esac
 677                 OPENIBLND=""
 678                 OPENIBCPPFLAGS=""
 679         ])
 680         EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 681 fi
 682 AC_SUBST(OPENIBCPPFLAGS)
 683 AC_SUBST(OPENIBLND)
 684 ])
 685
 686 #
 687 # LN_CONFIG_CIBLND
 688 #
 689 AC_DEFUN([LN_CONFIG_CIB],[
 690 AC_MSG_CHECKING([whether to enable Cisco/TopSpin IB support])
 691 # set default
 692 CIBPATH=""
 693 CIBLND=""
 694 AC_ARG_WITH([cib],
 695         AC_HELP_STRING([--with-cib=path],
 696                        [build ciblnd against path]),
 697         [
 698                 case $with_cib in
 699                 no)     AC_MSG_RESULT([no]);;
 700                 *)      CIBPATH="$with_cib"
 701                         if test -d "$CIBPATH"; then
 702                                 AC_MSG_RESULT([yes])
 703                         else
 704                                 AC_MSG_RESULT([no])
 705                                 AC_MSG_ERROR([No directory $CIBPATH])
 706                         fi;;
 707                 esac
 708         ],[
 709                 AC_MSG_RESULT([no])
 710         ])
 711 if test -n "$CIBPATH"; then
 712         CIBCPPFLAGS="-I${CIBPATH}/ib/ts_api_ng/include -I${CIBPATH}/all/kernel_services/include -DUSING_TSAPI"
 713         CIBCPPFLAGS="$CIBCPPFLAGS -DIB_NTXRXPARAMS=3"
 714         EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 715         EXTRA_KCFLAGS="$EXTRA_KCFLAGS $CIBCPPFLAGS"
 716         LB_LINUX_TRY_COMPILE([
 717                 #include <ts_ib_core.h>
 718                 #include <ts_ib_cm.h>
 719                 #include <ts_ib_sa_client.h>
 720         ],[
 721                 struct ib_device_properties dev_props;
 722                 struct ib_cm_active_param   cm_active_params;
 723                 tTS_IB_CLIENT_QUERY_TID     tid;
 724                 int                         enum1 = TS_IB_QP_ATTRIBUTE_STATE;
 725                 int                         enum2 = TS_IB_ACCESS_LOCAL_WRITE;
 726                 int                         enum3 = TS_IB_CQ_CALLBACK_INTERRUPT;
 727                 int                         enum4 = TS_IB_CQ_PROVIDER_REARM;
 728                 return 0;
 729         ],[
 730                 CIBLND="ciblnd"
 731         ],[
 732                 AC_MSG_ERROR([can't compile ciblnd with given path])
 733                 CIBCPPFLAGS=""
 734         ])
 735         EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 736 fi
 737 AC_SUBST(CIBCPPFLAGS)
 738 AC_SUBST(CIBLND)
 739 ])
 740
 741 #
 742 # LN_CONFIG_IIB
 743 #
 744 # check for infinicon infiniband support
 745 #
 746 AC_DEFUN([LN_CONFIG_IIB],[
 747 AC_MSG_CHECKING([whether to enable Infinicon support])
 748 # set default
 749 IIBPATH="/usr/include"
 750 AC_ARG_WITH([iib],
 751         AC_HELP_STRING([--with-iib=path],
 752                        [build iiblnd against path]),
 753         [
 754                 case $with_iib in
 755                 yes)    ENABLEIIB=2
 756                         ;;
 757                 no)     ENABLEIIB=0
 758                         ;;
 759                 *)      IIBPATH="${with_iib}/include"
 760                         ENABLEIIB=3
 761                         ;;
 762                 esac
 763         ],[
 764                 ENABLEIIB=1
 765         ])
 766 if test $ENABLEIIB -eq 0; then
 767         AC_MSG_RESULT([disabled])
 768 elif test ! \( -f ${IIBPATH}/linux/iba/ibt.h \); then
 769         AC_MSG_RESULT([no])
 770         case $ENABLEIIB in
 771         1) ;;
 772         2) AC_MSG_ERROR([default Infinicon headers not present]);;
 773         3) AC_MSG_ERROR([bad --with-iib path]);;
 774         *) AC_MSG_ERROR([internal error]);;
 775         esac
 776 else
 777         IIBCPPFLAGS="-I$IIBPATH"
 778         if test $IIBPATH != "/usr/include"; then
 779                 # we need /usr/include come what may
 780                 IIBCPPFLAGS="$IIBCPPFLAGS -I/usr/include"
 781         fi
 782         EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 783         EXTRA_KCFLAGS="$EXTRA_KCFLAGS $IIBCPPFLAGS"
 784         LB_LINUX_TRY_COMPILE([
 785                 #include <linux/iba/ibt.h>
 786         ],[
 787                 IBT_INTERFACE_UNION interfaces;
 788                 FSTATUS             rc;
 789
 790                  rc = IbtGetInterfaceByVersion(IBT_INTERFACE_VERSION_2,
 791                                                &interfaces);
 792
 793                 return rc == FSUCCESS ? 0 : 1;
 794         ],[
 795                 AC_MSG_RESULT([yes])
 796                 IIBLND="iiblnd"
 797         ],[
 798                 AC_MSG_RESULT([no])
 799                 case $ENABLEIIB in
 800                 1) ;;
 801                 2) AC_MSG_ERROR([can't compile with default Infinicon headers]);;
 802                 3) AC_MSG_ERROR([can't compile with Infinicon headers under $IIBPATH]);;
 803                 *) AC_MSG_ERROR([internal error]);;
 804                 esac
 805                 IIBLND=""
 806                 IIBCPPFLAGS=""
 807         ])
 808         EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 809 fi
 810 AC_SUBST(IIBCPPFLAGS)
 811 AC_SUBST(IIBLND)
 812 ])
 813
 814 #
 815 # LN_CONFIG_VIB
 816 #
 817 # check for Voltaire infiniband support
 818 #
 819 AC_DEFUN([LN_CONFIG_VIB],
 820 [AC_MSG_CHECKING([whether to enable Voltaire IB support])
 821 VIBPATH=""
 822 AC_ARG_WITH([vib],
 823         AC_HELP_STRING([--with-vib=path],
 824                        [build viblnd against path]),
 825         [
 826                 case $with_vib in
 827                 no)     AC_MSG_RESULT([no]);;
 828                 *)      VIBPATH="${with_vib}/src/nvigor/ib-code"
 829                         if test -d "$with_vib" -a -d "$VIBPATH"; then
 830                                 AC_MSG_RESULT([yes])
 831                         else
 832                                 AC_MSG_RESULT([no])
 833                                 AC_MSG_ERROR([No directory $VIBPATH])
 834                         fi;;
 835                 esac
 836         ],[
 837                 AC_MSG_RESULT([no])
 838         ])
 839 if test -z "$VIBPATH"; then
 840         VIBLND=""
 841 else
 842         VIBCPPFLAGS="-I${VIBPATH}/include -I${VIBPATH}/cm"
 843         EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 844         EXTRA_KCFLAGS="$EXTRA_KCFLAGS $VIBCPPFLAGS"
 845         LB_LINUX_TRY_COMPILE([
 846                 #include <linux/list.h>
 847                 #include <asm/byteorder.h>
 848                 #ifdef __BIG_ENDIAN
 849                 # define CPU_BE 1
 850                 # define CPU_LE 0
 851                 #endif
 852                 #ifdef __LITTLE_ENDIAN
 853                 # define CPU_BE 0
 854                 # define CPU_LE 1
 855                 #endif
 856                 #include <vverbs.h>
 857                 #include <ib-cm.h>
 858                 #include <ibat.h>
 859         ],[
 860                 vv_hca_h_t       kib_hca;
 861                 vv_return_t      vvrc;
 862                 cm_cep_handle_t  cep;
 863                 ibat_arp_data_t  arp_data;
 864                 ibat_stat_t      ibatrc;
 865
 866                 vvrc = vv_hca_open("ANY_HCA", NULL, &kib_hca);
 867                 cep = cm_create_cep(cm_cep_transp_rc);
 868                 ibatrc = ibat_get_ib_data((uint32_t)0, (uint32_t)0,
 869                                           ibat_paths_primary, &arp_data,
 870                                           (ibat_get_ib_data_reply_fn_t)NULL,
 871                                           NULL, 0);
 872                 return 0;
 873         ],[
 874                 VIBLND="viblnd"
 875         ],[
 876                 AC_MSG_ERROR([can't compile viblnd with given path])
 877         ])
 878         EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 879 fi
 880 if test -n "$VIBLND"; then
 881         EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 882         EXTRA_KCFLAGS="$EXTRA_KCFLAGS $VIBCPPFLAGS"
 883         AC_MSG_CHECKING([if Voltaire still uses void * sg addresses])
 884         LB_LINUX_TRY_COMPILE([
 885                 #include <linux/list.h>
 886                 #include <asm/byteorder.h>
 887                 #ifdef __BIG_ENDIAN
 888                 # define CPU_BE 1
 889                 # define CPU_LE 0
 890                 #endif
 891                 #ifdef __LITTLE_ENDIAN
 892                 # define CPU_BE 0
 893                 # define CPU_LE 1
 894                 #endif
 895                 #include <vverbs.h>
 896                 #include <ib-cm.h>
 897                 #include <ibat.h>
 898         ],[
 899                 vv_scatgat_t  sg;
 900
 901                 return &sg.v_address[3] == NULL;
 902         ],[
 903                 AC_MSG_RESULT([yes])
 904                 VIBCPPFLAGS="$VIBCPPFLAGS -DIBNAL_VOIDSTAR_SGADDR=1"
 905         ],[
 906                 AC_MSG_RESULT([no])
 907         ])
 908         EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 909 fi
 910 AC_SUBST(VIBCPPFLAGS)
 911 AC_SUBST(VIBLND)
 912 ])
 913
 914 #
 915 # LN_CONFIG_RALND
 916 #
 917 # check whether to use the RapidArray lnd
 918 #
 919 AC_DEFUN([LN_CONFIG_RALND],
 920 [#### Rapid Array
 921 AC_MSG_CHECKING([if RapidArray kernel headers are present])
 922 # placeholder
 923 RACPPFLAGS="-I${LINUX}/drivers/xd1/include"
 924 EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 925 EXTRA_KCFLAGS="$EXTRA_KCFLAGS $RACPPFLAGS"
 926 LB_LINUX_TRY_COMPILE([
 927         #include <linux/types.h>
 928         #include <rapl.h>
 929 ],[
 930         RAP_RETURN          rc;
 931         RAP_PVOID           dev_handle;
 932
 933         rc = RapkGetDeviceByIndex(0, NULL, &dev_handle);
 934
 935         return rc == RAP_SUCCESS ? 0 : 1;
 936 ],[
 937         AC_MSG_RESULT([yes])
 938         RALND="ralnd"
 939 ],[
 940         AC_MSG_RESULT([no])
 941         RALND=""
 942         RACPPFLAGS=""
 943 ])
 944 EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 945 AC_SUBST(RACPPFLAGS)
 946 AC_SUBST(RALND)
 947 ])
 948
 949 #
 950 # LN_STRUCT_PAGE_LIST
 951 #
 952 # 2.6.4 no longer has page->list
 953 #
 954 AC_DEFUN([LN_STRUCT_PAGE_LIST],
 955 [AC_MSG_CHECKING([if struct page has a list field])
 956 LB_LINUX_TRY_COMPILE([
 957         #include <linux/mm.h>
 958 ],[
 959         struct page page;
 960         &page.list;
 961 ],[
 962         AC_MSG_RESULT([yes])
 963         AC_DEFINE(HAVE_PAGE_LIST, 1, [struct page has a list field])
 964 ],[
 965         AC_MSG_RESULT([no])
 966 ])
 967 ])
 968
 969 #
 970 # LN_STRUCT_SIGHAND
 971 #
 972 # red hat 2.4 adds sighand to struct task_struct
 973 #
 974 AC_DEFUN([LN_STRUCT_SIGHAND],
 975 [AC_MSG_CHECKING([if task_struct has a sighand field])
 976 LB_LINUX_TRY_COMPILE([
 977         #include <linux/sched.h>
 978 ],[
 979         struct task_struct p;
 980         p.sighand = NULL;
 981 ],[
 982         AC_DEFINE(CONFIG_RH_2_4_20, 1, [this kernel contains Red Hat 2.4.20 patches])
 983         AC_MSG_RESULT([yes])
 984 ],[
 985         AC_MSG_RESULT([no])
 986 ])
 987 ])
 988
 989 #
 990 # LN_FUNC_CPU_ONLINE
 991 #
 992 # cpu_online is different in rh 2.4, vanilla 2.4, and 2.6
 993 #
 994 AC_DEFUN([LN_FUNC_CPU_ONLINE],
 995 [AC_MSG_CHECKING([if kernel defines cpu_online()])
 996 LB_LINUX_TRY_COMPILE([
 997         #include <linux/sched.h>
 998 ],[
 999         cpu_online(0);
1000 ],[
1001         AC_MSG_RESULT([yes])
1002         AC_DEFINE(HAVE_CPU_ONLINE, 1, [cpu_online found])
1003 ],[
1004         AC_MSG_RESULT([no])
1005 ])
1006 ])
1007
1008 #
1009 # LN_TYPE_GFP_T
1010 #
1011 # check if gfp_t is typedef-ed
1012 #
1013 AC_DEFUN([LN_TYPE_GFP_T],
1014 [AC_MSG_CHECKING([if kernel defines gfp_t])
1015 LB_LINUX_TRY_COMPILE([
1016         #include <linux/gfp.h>
1017 ],[
1018         return sizeof(gfp_t);
1019 ],[
1020         AC_MSG_RESULT([yes])
1021         AC_DEFINE(HAVE_GFP_T, 1, [gfp_t found])
1022 ],[
1023         AC_MSG_RESULT([no])
1024 ])
1025 ])
1026
1027 #
1028 # LN_TYPE_CPUMASK_T
1029 #
1030 # same goes for cpumask_t
1031 #
1032 AC_DEFUN([LN_TYPE_CPUMASK_T],
1033 [AC_MSG_CHECKING([if kernel defines cpumask_t])
1034 LB_LINUX_TRY_COMPILE([
1035         #include <linux/sched.h>
1036 ],[
1037         return sizeof (cpumask_t);
1038 ],[
1039         AC_MSG_RESULT([yes])
1040         AC_DEFINE(HAVE_CPUMASK_T, 1, [cpumask_t found])
1041 ],[
1042         AC_MSG_RESULT([no])
1043 ])
1044 ])
1045
1046 #
1047 # LN_FUNC_SHOW_TASK
1048 #
1049 # we export show_task(), but not all kernels have it (yet)
1050 #
1051 AC_DEFUN([LN_FUNC_SHOW_TASK],
1052 [LB_CHECK_SYMBOL_EXPORT([show_task],
1053 [kernel/ksyms.c kernel/sched.c],[
1054 AC_DEFINE(HAVE_SHOW_TASK, 1, [show_task is exported])
1055 ],[
1056 ])
1057 ])
1058
1059 # check userland __u64 type
1060 AC_DEFUN([LN_U64_LONG_LONG],
1061 [AC_MSG_CHECKING([u64 is long long type])
1062 tmp_flags="$CFLAGS"
1063 CFLAGS="$CFLAGS -Werror"
1064 AC_COMPILE_IFELSE([
1065         #include <linux/types.h>
1066         int main(void) {
1067                 unsigned long long *data1;
1068                 __u64 *data2;
1069
1070                 data1 = data2;
1071                 return 0;
1072         }
1073 ],[
1074         AC_MSG_RESULT([yes])
1075         AC_DEFINE(HAVE_U64_LONG_LONG, 1,
1076                   [__u64 is long long type])
1077 ],[
1078         AC_MSG_RESULT([no])
1079 ])
1080 CFLAGS="$tmp_flags"
1081 ])
1082
1083 # check userland size_t type
1084 AC_DEFUN([LN_SIZE_T_LONG],
1085 [AC_MSG_CHECKING([size_t is unsigned long type])
1086 tmp_flags="$CFLAGS"
1087 CFLAGS="$CFLAGS -Werror"
1088 AC_COMPILE_IFELSE([
1089         #include <linux/types.h>
1090         int main(void) {
1091                 unsigned long *data1;
1092                 size_t *data2;
1093
1094                 data1 = data2;
1095                 return 0;
1096         }
1097 ],[
1098         AC_MSG_RESULT([yes])
1099         AC_DEFINE(HAVE_SIZE_T_LONG, 1,
1100                   [size_t is long type])
1101 ],[
1102         AC_MSG_RESULT([no])
1103 ])
1104 CFLAGS="$tmp_flags"
1105 ])
1106
1107 AC_DEFUN([LN_SSIZE_T_LONG],
1108 [AC_MSG_CHECKING([ssize_t is signed long type])
1109 tmp_flags="$CFLAGS"
1110 CFLAGS="$CFLAGS -Werror"
1111 AC_COMPILE_IFELSE([
1112         #include <linux/types.h>
1113         int main(void) {
1114                 long *data1;
1115                 ssize_t *data2;
1116
1117                 data1 = data2;
1118                 return 0;
1119         }
1120 ],[
1121         AC_MSG_RESULT([yes])
1122         AC_DEFINE(HAVE_SSIZE_T_LONG, 1,
1123                   [ssize_t is long type])
1124 ],[
1125         AC_MSG_RESULT([no])
1126 ])
1127 CFLAGS="$tmp_flags"
1128 ])
1129
1130
1131 # LN_TASKLIST_LOCK
1132 # 2.6.18 remove tasklist_lock export
1133 AC_DEFUN([LN_TASKLIST_LOCK],
1134 [LB_CHECK_SYMBOL_EXPORT([tasklist_lock],
1135 [kernel/fork.c],[
1136 AC_DEFINE(HAVE_TASKLIST_LOCK, 1,
1137          [tasklist_lock exported])
1138 ],[
1139 ])
1140 ])
1141
1142 # 2.6.19 API changes
1143 # kmem_cache_destroy(cachep) return void instead of
1144 # int
1145 AC_DEFUN([LN_KMEM_CACHE_DESTROY_INT],
1146 [AC_MSG_CHECKING([kmem_cache_destroy(cachep) return int])
1147 LB_LINUX_TRY_COMPILE([
1148         #include <linux/slab.h>
1149 ],[
1150         int i = kmem_cache_destroy(NULL);
1151 ],[
1152         AC_MSG_RESULT(yes)
1153         AC_DEFINE(HAVE_KMEM_CACHE_DESTROY_INT, 1,
1154                 [kmem_cache_destroy(cachep) return int])
1155 ],[
1156         AC_MSG_RESULT(NO)
1157 ])
1158 ])
1159
1160 # 2.6.19 API change
1161 #panic_notifier_list use atomic_notifier operations
1162 #
1163 AC_DEFUN([LN_ATOMIC_PANIC_NOTIFIER],
1164 [AC_MSG_CHECKING([panic_notifier_list is atomic])
1165 LB_LINUX_TRY_COMPILE([
1166         #include <linux/notifier.h>
1167         #include <linux/kernel.h>
1168 ],[
1169         struct atomic_notifier_head panic_notifier_list;
1170 ],[
1171         AC_MSG_RESULT(yes)
1172         AC_DEFINE(HAVE_ATOMIC_PANIC_NOTIFIER, 1,
1173                 [panic_notifier_list is atomic_notifier_head])
1174 ],[
1175         AC_MSG_RESULT(NO)
1176 ])
1177 ])
1178
1179 # 2.6.20 API change INIT_WORK use 2 args and not
1180 # store data inside
1181 AC_DEFUN([LN_3ARGS_INIT_WORK],
1182 [AC_MSG_CHECKING([check INIT_WORK want 3 args])
1183 LB_LINUX_TRY_COMPILE([
1184         #include <linux/workqueue.h>
1185 ],[
1186         struct work_struct work;
1187
1188         INIT_WORK(&work, NULL, NULL);
1189 ],[
1190         AC_MSG_RESULT(yes)
1191         AC_DEFINE(HAVE_3ARGS_INIT_WORK, 1,
1192                   [INIT_WORK use 3 args and store data inside])
1193 ],[
1194         AC_MSG_RESULT(NO)
1195 ])
1196 ])
1197
1198 # 2.6.21 api change. 'register_sysctl_table' use only one argument,
1199 # instead of more old which need two.
1200 AC_DEFUN([LN_2ARGS_REGISTER_SYSCTL],
1201 [AC_MSG_CHECKING([check register_sysctl_table want 2 args])
1202 LB_LINUX_TRY_COMPILE([
1203         #include <linux/sysctl.h>
1204 ],[
1205         return register_sysctl_table(NULL,0);
1206 ],[
1207         AC_MSG_RESULT(yes)
1208         AC_DEFINE(HAVE_2ARGS_REGISTER_SYSCTL, 1,
1209                   [register_sysctl_table want 2 args])
1210 ],[
1211         AC_MSG_RESULT(NO)
1212 ])
1213 ])
1214
1215 # 2.6.21 marks kmem_cache_t deprecated and uses struct kmem_cache
1216 # instead
1217 AC_DEFUN([LN_KMEM_CACHE],
1218 [AC_MSG_CHECKING([check kernel has struct kmem_cache])
1219 tmp_flags="$EXTRA_KCFLAGS"
1220 EXTRA_KCFLAGS="-Werror"
1221 LB_LINUX_TRY_COMPILE([
1222         #include <linux/slab.h>
1223         typedef struct kmem_cache cache_t;
1224 ],[
1225         cache_t *cachep = NULL;
1226
1227         kmem_cache_alloc(cachep, 0);
1228 ],[
1229         AC_MSG_RESULT(yes)
1230         AC_DEFINE(HAVE_KMEM_CACHE, 1,
1231                   [kernel has struct kmem_cache])
1232 ],[
1233         AC_MSG_RESULT(NO)
1234 ])
1235 EXTRA_KCFLAGS="$tmp_flags"
1236 ])
1237 # 2.6.23 lost dtor argument
1238 AC_DEFUN([LN_KMEM_CACHE_CREATE_DTOR],
1239 [AC_MSG_CHECKING([check kmem_cache_create has dtor argument])
1240 LB_LINUX_TRY_COMPILE([
1241         #include <linux/slab.h>
1242 ],[
1243         kmem_cache_create(NULL, 0, 0, 0, NULL, NULL);
1244 ],[
1245         AC_MSG_RESULT(yes)
1246         AC_DEFINE(HAVE_KMEM_CACHE_CREATE_DTOR, 1,
1247                   [kmem_cache_create has dtor argument])
1248 ],[
1249         AC_MSG_RESULT(NO)
1250 ])
1251 ])
1252
1253 #
1254 # LN_PROG_LINUX
1255 #
1256 # LNet linux kernel checks
1257 #
1258 AC_DEFUN([LN_PROG_LINUX],
1259 [
1260 LN_FUNC_CPU_ONLINE
1261 LN_TYPE_GFP_T
1262 LN_TYPE_CPUMASK_T
1263 LN_CONFIG_AFFINITY
1264 LN_CONFIG_BACKOFF
1265 LN_CONFIG_PANIC_DUMPLOG
1266 LN_CONFIG_QUADRICS
1267 LN_CONFIG_GM
1268 LN_CONFIG_OPENIB
1269 LN_CONFIG_CIB
1270 LN_CONFIG_VIB
1271 LN_CONFIG_IIB
1272 LN_CONFIG_O2IB
1273 LN_CONFIG_RALND
1274 LN_CONFIG_PTLLND
1275 LN_CONFIG_MX
1276
1277 LN_STRUCT_PAGE_LIST
1278 LN_STRUCT_SIGHAND
1279 LN_FUNC_SHOW_TASK
1280 LN_U64_LONG_LONG
1281 LN_SSIZE_T_LONG
1282 LN_SIZE_T_LONG
1283 # 2.6.18
1284 LN_TASKLIST_LOCK
1285 # 2.6.19
1286 LN_KMEM_CACHE_DESTROY_INT
1287 LN_ATOMIC_PANIC_NOTIFIER
1288 # 2.6.20
1289 LN_3ARGS_INIT_WORK
1290 # 2.6.21
1291 LN_2ARGS_REGISTER_SYSCTL
1292 LN_KMEM_CACHE
1293 # 2.6.23
1294 LN_KMEM_CACHE_CREATE_DTOR
1295 ])
1296
1297 #
1298 # LN_PROG_DARWIN
1299 #
1300 # Darwin checks
1301 #
1302 AC_DEFUN([LN_PROG_DARWIN],
1303 [LB_DARWIN_CHECK_FUNCS([get_preemption_level])
1304 ])
1305
1306 #
1307 # LN_PATH_DEFAULTS
1308 #
1309 # default paths for installed files
1310 #
1311 AC_DEFUN([LN_PATH_DEFAULTS],
1312 [
1313 ])
1314
1315 #
1316 # LN_CONFIGURE
1317 #
1318 # other configure checks
1319 #
1320 AC_DEFUN([LN_CONFIGURE],
1321 [# lnet/utils/portals.c
1322 AC_CHECK_HEADERS([netdb.h netinet/tcp.h asm/types.h endian.h sys/ioctl.h])
1323 AC_CHECK_FUNCS([gethostbyname socket connect])
1324
1325 # lnet/utils/debug.c
1326 AC_CHECK_HEADERS([linux/version.h])
1327
1328 AC_CHECK_TYPE([spinlock_t],
1329         [AC_DEFINE(HAVE_SPINLOCK_T, 1, [spinlock_t is defined])],
1330         [],
1331         [#include <linux/spinlock.h>])
1332
1333 # lnet/utils/wirecheck.c
1334 AC_CHECK_FUNCS([strnlen])
1335
1336 # --------  Check for required packages  --------------
1337
1338 #
1339 # LC_CONFIG_READLINE
1340 #
1341 # Build with readline
1342 #
1343 AC_MSG_CHECKING([whether to enable readline support])
1344 AC_ARG_ENABLE(readline,
1345         AC_HELP_STRING([--disable-readline],
1346                         [disable readline support]),
1347         [],[enable_readline='yes'])
1348 AC_MSG_RESULT([$enable_readline])
1349
1350 # -------- check for readline if enabled ----
1351 if test x$enable_readline = xyes ; then
1352         LIBS_save="$LIBS"
1353         LIBS="-lncurses $LIBS"
1354         AC_CHECK_LIB([readline],[readline],[
1355         LIBREADLINE="-lreadline -lncurses"
1356         AC_DEFINE(HAVE_LIBREADLINE, 1, [readline library is available])
1357         ],[
1358         LIBREADLINE=""
1359         ])
1360         LIBS="$LIBS_save"
1361 else
1362         LIBREADLINE=""
1363 fi
1364 AC_SUBST(LIBREADLINE)
1365
1366 AC_MSG_CHECKING([if efence debugging support is requested])
1367 AC_ARG_ENABLE(efence,
1368         AC_HELP_STRING([--enable-efence],
1369                         [use efence library]),
1370         [],[enable_efence='no'])
1371 AC_MSG_RESULT([$enable_efence])
1372 if test "$enable_efence" = "yes" ; then
1373         LIBEFENCE="-lefence"
1374         AC_DEFINE(HAVE_LIBEFENCE, 1, [libefence support is requested])
1375 else
1376         LIBEFENCE=""
1377 fi
1378 AC_SUBST(LIBEFENCE)
1379
1380 # -------- enable acceptor libwrap (TCP wrappers) support? -------
1381 AC_MSG_CHECKING([if libwrap support is requested])
1382 AC_ARG_ENABLE([libwrap],
1383         AC_HELP_STRING([--enable-libwrap], [use TCP wrappers]),
1384         [case "${enableval}" in
1385                 yes) enable_libwrap=yes ;;
1386                 no) enable_libwrap=no ;;
1387                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-libwrap) ;;
1388         esac],[enable_libwrap=no])
1389 AC_MSG_RESULT([$enable_libwrap])
1390 if test x$enable_libwrap = xyes ; then
1391         LIBWRAP="-lwrap"
1392         AC_DEFINE(HAVE_LIBWRAP, 1, [libwrap support is requested])
1393 else
1394         LIBWRAP=""
1395 fi
1396 AC_SUBST(LIBWRAP)
1397
1398 # -------- check for -lpthread support ----
1399 AC_MSG_CHECKING([whether to use libpthread for lnet library])
1400 AC_ARG_ENABLE([libpthread],
1401         AC_HELP_STRING([--disable-libpthread],
1402                 [disable libpthread]),
1403         [],[enable_libpthread=yes])
1404 if test "$enable_libpthread" = "yes" ; then
1405         AC_CHECK_LIB([pthread], [pthread_create],
1406                 [ENABLE_LIBPTHREAD="yes"],
1407                 [ENABLE_LIBPTHREAD="no"])
1408         if test "$ENABLE_LIBPTHREAD" = "yes" ; then
1409                 AC_MSG_RESULT([$ENABLE_LIBPTHREAD])
1410                 PTHREAD_LIBS="-lpthread"
1411                 AC_DEFINE([HAVE_LIBPTHREAD], 1, [use libpthread])
1412         else
1413                 PTHREAD_LIBS=""
1414                 AC_MSG_RESULT([no libpthread is found])
1415         fi
1416         AC_SUBST(PTHREAD_LIBS)
1417 else
1418         AC_MSG_RESULT([no (disabled explicitly)])
1419         ENABLE_LIBPTHREAD="no"
1420 fi
1421 AC_SUBST(ENABLE_LIBPTHREAD)
1422
1423 # ----------------------------------------
1424 # some tests for catamount-like systems
1425 # ----------------------------------------
1426 AC_ARG_ENABLE([sysio_init],
1427         AC_HELP_STRING([--disable-sysio-init],
1428                 [call sysio init functions when initializing liblustre]),
1429         [],[enable_sysio_init=yes])
1430 AC_MSG_CHECKING([whether to initialize libsysio])
1431 AC_MSG_RESULT([$enable_sysio_init])
1432 if test x$enable_sysio_init != xno ; then
1433         AC_DEFINE([INIT_SYSIO], 1, [call sysio init functions])
1434 fi
1435
1436 AC_ARG_ENABLE([urandom],
1437         AC_HELP_STRING([--disable-urandom],
1438                 [disable use of /dev/urandom for liblustre]),
1439         [],[enable_urandom=yes])
1440 AC_MSG_CHECKING([whether to use /dev/urandom for liblustre])
1441 AC_MSG_RESULT([$enable_urandom])
1442 if test x$enable_urandom != xno ; then
1443         AC_DEFINE([LIBLUSTRE_USE_URANDOM], 1, [use /dev/urandom for random data])
1444 fi
1445
1446 # -------- check for -lcap support ----
1447 if test x$enable_liblustre = xyes ; then
1448         AC_CHECK_LIB([cap], [cap_get_proc],
1449                 [
1450                         CAP_LIBS="-lcap"
1451                         AC_DEFINE([HAVE_LIBCAP], 1, [use libcap])
1452                 ],
1453                 [
1454                         CAP_LIBS=""
1455                 ])
1456         AC_SUBST(CAP_LIBS)
1457
1458 fi
1459
1460 LN_CONFIG_MAX_PAYLOAD
1461 LN_CONFIG_UPTLLND
1462 LN_CONFIG_USOCKLND
1463 ])
1464
1465 #
1466 # LN_CONDITIONALS
1467 #
1468 # AM_CONDITOINAL defines for lnet
1469 #
1470 AC_DEFUN([LN_CONDITIONALS],
1471 [AM_CONDITIONAL(BUILD_QSWLND, test x$QSWLND = "xqswlnd")
1472 AM_CONDITIONAL(BUILD_GMLND, test x$GMLND = "xgmlnd")
1473 AM_CONDITIONAL(BUILD_MXLND, test x$MXLND = "xmxlnd")
1474 AM_CONDITIONAL(BUILD_O2IBLND, test x$O2IBLND = "xo2iblnd")
1475 AM_CONDITIONAL(BUILD_OPENIBLND, test x$OPENIBLND = "xopeniblnd")
1476 AM_CONDITIONAL(BUILD_CIBLND, test x$CIBLND = "xciblnd")
1477 AM_CONDITIONAL(BUILD_IIBLND, test x$IIBLND = "xiiblnd")
1478 AM_CONDITIONAL(BUILD_VIBLND, test x$VIBLND = "xviblnd")
1479 AM_CONDITIONAL(BUILD_RALND, test x$RALND = "xralnd")
1480 AM_CONDITIONAL(BUILD_PTLLND, test x$PTLLND = "xptllnd")
1481 AM_CONDITIONAL(BUILD_UPTLLND, test x$UPTLLND = "xptllnd")
1482 AM_CONDITIONAL(BUILD_USOCKLND, test x$USOCKLND = "xusocklnd")
1483 ])
1484
1485 #
1486 # LN_CONFIG_FILES
1487 #
1488 # files that should be generated with AC_OUTPUT
1489 #
1490 AC_DEFUN([LN_CONFIG_FILES],
1491 [AC_CONFIG_FILES([
1492 lnet/Kernelenv
1493 lnet/Makefile
1494 lnet/autoMakefile
1495 lnet/autoconf/Makefile
1496 lnet/doc/Makefile
1497 lnet/include/Makefile
1498 lnet/include/libcfs/Makefile
1499 lnet/include/libcfs/linux/Makefile
1500 lnet/include/lnet/Makefile
1501 lnet/include/lnet/linux/Makefile
1502 lnet/klnds/Makefile
1503 lnet/klnds/autoMakefile
1504 lnet/klnds/gmlnd/Makefile
1505 lnet/klnds/mxlnd/autoMakefile
1506 lnet/klnds/mxlnd/Makefile
1507 lnet/klnds/gmlnd/autoMakefile
1508 lnet/klnds/openiblnd/Makefile
1509 lnet/klnds/openiblnd/autoMakefile
1510 lnet/klnds/o2iblnd/Makefile
1511 lnet/klnds/o2iblnd/autoMakefile
1512 lnet/klnds/ciblnd/Makefile
1513 lnet/klnds/ciblnd/autoMakefile
1514 lnet/klnds/iiblnd/Makefile
1515 lnet/klnds/iiblnd/autoMakefile
1516 lnet/klnds/viblnd/Makefile
1517 lnet/klnds/viblnd/autoMakefile
1518 lnet/klnds/qswlnd/Makefile
1519 lnet/klnds/qswlnd/autoMakefile
1520 lnet/klnds/ralnd/Makefile
1521 lnet/klnds/ralnd/autoMakefile
1522 lnet/klnds/socklnd/Makefile
1523 lnet/klnds/socklnd/autoMakefile
1524 lnet/klnds/ptllnd/Makefile
1525 lnet/klnds/ptllnd/autoMakefile
1526 lnet/libcfs/Makefile
1527 lnet/libcfs/autoMakefile
1528 lnet/libcfs/linux/Makefile
1529 lnet/lnet/Makefile
1530 lnet/lnet/autoMakefile
1531 lnet/selftest/Makefile
1532 lnet/selftest/autoMakefile
1533 lnet/ulnds/Makefile
1534 lnet/ulnds/autoMakefile
1535 lnet/ulnds/socklnd/Makefile
1536 lnet/ulnds/ptllnd/Makefile
1537 lnet/utils/Makefile
1538 ])
1539 case $lb_target_os in
1540         darwin)
1541                 AC_CONFIG_FILES([
1542 lnet/include/libcfs/darwin/Makefile
1543 lnet/include/lnet/darwin/Makefile
1544 lnet/libcfs/darwin/Makefile
1545 ])
1546                 ;;
1547 esac
1548 ])