Whamcloud - gitweb
2a4eb2fc0420be3ebfadf8e44130549de2df67c5
[fs/lustre-release.git] / lnet / autoconf / lustre-lnet.m4
1 #
2 # LN_CONFIG_MAX_PAYLOAD
3 #
4 # configure maximum payload
5 #
6 AC_DEFUN([LN_CONFIG_MAX_PAYLOAD],
7 [AC_MSG_CHECKING([for non-default maximum LNET payload])
8 AC_ARG_WITH([max-payload-mb],
9         AC_HELP_STRING([--with-max-payload-mb=MBytes],
10                        [set maximum lnet payload in MBytes]),
11         [
12                 AC_MSG_RESULT([$with_max_payload_mb])
13                 LNET_MAX_PAYLOAD_MB=$with_max_payload_mb
14                 LNET_MAX_PAYLOAD="(($with_max_payload_mb)<<20)"
15         ], [
16                 AC_MSG_RESULT([no])
17                 LNET_MAX_PAYLOAD="LNET_MTU"
18         ])
19         AC_DEFINE_UNQUOTED(LNET_MAX_PAYLOAD, $LNET_MAX_PAYLOAD,
20                            [Max LNET payload])
21 ])
22
23 #
24 # LN_CHECK_GCC_VERSION
25 #
26 # Check compiler version
27 #
28 AC_DEFUN([LN_CHECK_GCC_VERSION],
29 [AC_MSG_CHECKING([compiler version])
30 PTL_CC_VERSION=`$CC --version | awk '/^gcc/{print $ 3}'`
31 PTL_MIN_CC_VERSION="3.2.2"
32 v2n() {
33         awk -F. '{printf "%d\n", (($ 1)*100+($ 2))*100+($ 3)}'
34 }
35 if test -z "$PTL_CC_VERSION" -o \
36         `echo $PTL_CC_VERSION | v2n` -ge `echo $PTL_MIN_CC_VERSION | v2n`; then
37         AC_MSG_RESULT([ok])
38 else
39         AC_MSG_RESULT([Buggy compiler found])
40         AC_MSG_ERROR([Need gcc version >= $PTL_MIN_CC_VERSION])
41 fi
42 ])
43
44 #
45 # LN_CONFIG_CDEBUG
46 #
47 # whether to enable various libcfs debugs (CDEBUG, ENTRY/EXIT, LASSERT, etc.)
48 #
49 AC_DEFUN([LN_CONFIG_CDEBUG],
50 [
51 AC_MSG_CHECKING([whether to enable CDEBUG, CWARN])
52 AC_ARG_ENABLE([libcfs_cdebug],
53         AC_HELP_STRING([--disable-libcfs-cdebug],
54                         [disable libcfs CDEBUG, CWARN]),
55         [],[enable_libcfs_cdebug='yes'])
56 AC_MSG_RESULT([$enable_libcfs_cdebug])
57 if test x$enable_libcfs_cdebug = xyes; then
58    AC_DEFINE(CDEBUG_ENABLED, 1, [enable libcfs CDEBUG, CWARN])
59 else
60    AC_DEFINE(CDEBUG_ENABLED, 0, [disable libcfs CDEBUG, CWARN])
61 fi
62
63 AC_MSG_CHECKING([whether to enable ENTRY/EXIT])
64 AC_ARG_ENABLE([libcfs_trace],
65         AC_HELP_STRING([--disable-libcfs-trace],
66                         [disable libcfs ENTRY/EXIT]),
67         [],[enable_libcfs_trace='yes'])
68 AC_MSG_RESULT([$enable_libcfs_trace])
69 if test x$enable_libcfs_trace = xyes; then
70    AC_DEFINE(CDEBUG_ENTRY_EXIT, 1, [enable libcfs ENTRY/EXIT])
71 else
72    AC_DEFINE(CDEBUG_ENTRY_EXIT, 0, [disable libcfs ENTRY/EXIT])
73 fi
74
75 AC_MSG_CHECKING([whether to enable LASSERT, LASSERTF])
76 AC_ARG_ENABLE([libcfs_assert],
77         AC_HELP_STRING([--disable-libcfs-assert],
78                         [disable libcfs LASSERT, LASSERTF]),
79         [],[enable_libcfs_assert='yes'])
80 AC_MSG_RESULT([$enable_libcfs_assert])
81 if test x$enable_libcfs_assert = xyes; then
82    AC_DEFINE(LIBCFS_DEBUG, 1, [enable libcfs LASSERT, LASSERTF])
83 fi
84 ])
85
86 #
87 # LN_CONFIG_AFFINITY
88 #
89 # check if cpu affinity is available/wanted
90 #
91 AC_DEFUN([LN_CONFIG_AFFINITY],
92 [AC_ARG_ENABLE([affinity],
93         AC_HELP_STRING([--disable-affinity],
94                        [disable process/irq affinity]),
95         [],[enable_affinity='yes'])
96
97 AC_MSG_CHECKING([for CPU affinity support])
98 if test x$enable_affinity = xno ; then
99         AC_MSG_RESULT([no (by request)])
100 else
101         LB_LINUX_TRY_COMPILE([
102                 #include <linux/sched.h>
103         ],[
104                 struct task_struct t;
105                 #if HAVE_CPUMASK_T
106                 cpumask_t     m;
107                 #else
108                 unsigned long m;
109                 #endif
110                 set_cpus_allowed(&t, m);
111         ],[
112                 AC_DEFINE(CPU_AFFINITY, 1, [kernel has cpu affinity support])
113                 AC_MSG_RESULT([yes])
114         ],[
115                 AC_MSG_RESULT([no (no kernel support)])
116         ])
117 fi
118 ])
119
120 #
121 # LN_CONFIG_PORTALS
122 #
123 # configure support for Portals
124 #
125 AC_DEFUN([LN_CONFIG_PORTALS],
126 [AC_MSG_CHECKING([for portals])
127 AC_ARG_WITH([portals],
128         AC_HELP_STRING([--with-portals=path],
129                        [set path to portals]),
130         [
131                 case $with_portals in
132                         no)     ENABLEPORTALS=0
133                                 ;;
134                         *)      PORTALS="${with_portals}"
135                                 ENABLEPORTALS=1
136                                 ;;
137                 esac
138         ], [
139                 ENABLEPORTALS=0
140         ])
141 PTLLNDCPPFLAGS=""
142 if test $ENABLEPORTALS -eq 0; then
143         AC_MSG_RESULT([no])
144 elif test ! \( -f ${PORTALS}/include/portals/p30.h \); then
145         AC_MSG_RESULT([no])
146         AC_MSG_ERROR([bad --with-portals path])
147 else
148         AC_MSG_RESULT([$PORTALS])
149         PTLLNDCPPFLAGS="-I${PORTALS}/include"
150 fi
151 AC_SUBST(PTLLNDCPPFLAGS)
152 ])
153
154 #
155 # LN_CONFIG_BACKOFF
156 #
157 # check if tunable tcp backoff is available/wanted
158 #
159 AC_DEFUN([LN_CONFIG_BACKOFF],
160 [AC_MSG_CHECKING([for tunable backoff TCP support])
161 AC_ARG_ENABLE([backoff],
162        AC_HELP_STRING([--disable-backoff],
163                       [disable socknal tunable backoff]),
164        [],[enable_backoff='yes'])
165 if test x$enable_backoff = xno ; then
166        AC_MSG_RESULT([no (by request)])
167 else
168        BOCD="`grep -c TCP_BACKOFF $LINUX/include/linux/tcp.h`"
169        if test "$BOCD" != 0 ; then
170                AC_DEFINE(SOCKNAL_BACKOFF, 1, [use tunable backoff TCP])
171                AC_MSG_RESULT(yes)
172        else
173                AC_MSG_RESULT([no (no kernel support)])
174        fi
175 fi
176 ])
177
178 #
179 # LN_CONFIG_PANIC_DUMPLOG
180 #
181 # check if tunable panic_dumplog is wanted
182 #
183 AC_DEFUN([LN_CONFIG_PANIC_DUMPLOG],
184 [AC_MSG_CHECKING([for tunable panic_dumplog support])
185 AC_ARG_ENABLE([panic_dumplog],
186        AC_HELP_STRING([--enable-panic_dumplog],
187                       [enable panic_dumplog]),
188        [],[enable_panic_dumplog='no'])
189 if test x$enable_panic_dumplog = xyes ; then
190        AC_DEFINE(LNET_DUMP_ON_PANIC, 1, [use dumplog on panic])
191        AC_MSG_RESULT([yes (by request)])
192 else
193        AC_MSG_RESULT([no])
194 fi
195 ])
196
197 #
198 # LN_CONFIG_PTLLND
199 #
200 # configure support for Portals LND
201 #
202 AC_DEFUN([LN_CONFIG_PTLLND],
203 [
204 if test -z "$ENABLEPORTALS"; then
205         LN_CONFIG_PORTALS
206 fi
207
208 AC_MSG_CHECKING([whether to build the kernel portals LND])
209
210 PTLLND=""
211 if test $ENABLEPORTALS -ne 0; then
212         AC_MSG_RESULT([yes])
213         PTLLND="ptllnd"
214 else
215         AC_MSG_RESULT([no])
216 fi
217 AC_SUBST(PTLLND)
218 ])
219
220 #
221 # LN_CONFIG_UPTLLND
222 #
223 # configure support for Portals LND
224 #
225 AC_DEFUN([LN_CONFIG_UPTLLND],
226 [
227 if test -z "$ENABLEPORTALS"; then
228         LN_CONFIG_PORTALS
229 fi
230
231 AC_MSG_CHECKING([whether to build the userspace portals LND])
232
233 UPTLLND=""
234 if test $ENABLEPORTALS -ne 0; then
235         AC_MSG_RESULT([yes])
236         UPTLLND="ptllnd"
237 else
238         AC_MSG_RESULT([no])
239 fi
240 AC_SUBST(UPTLLND)
241 ])
242
243 #
244 # LN_CONFIG_USOCKLND
245 #
246 # configure support for userspace TCP/IP LND
247 #
248 AC_DEFUN([LN_CONFIG_USOCKLND],
249 [AC_MSG_CHECKING([whether to build usocklnd])
250 AC_ARG_ENABLE([usocklnd],
251         AC_HELP_STRING([--disable-usocklnd],
252                         [disable usocklnd]),
253         [],[enable_usocklnd='yes'])
254
255 if test x$enable_usocklnd = xyes ; then
256         if test "$ENABLE_LIBPTHREAD" = "yes" ; then
257                 AC_MSG_RESULT([yes])
258                 USOCKLND="usocklnd"
259         else
260                 AC_MSG_RESULT([no (libpthread not present or disabled)])
261                 USOCKLND=""
262         fi
263 else
264         AC_MSG_RESULT([no (disabled explicitly)])
265         USOCKLND=""
266 fi
267 AC_SUBST(USOCKLND)
268 ])
269
270 #
271 # LN_CONFIG_QUADRICS
272 #
273 # check if quadrics support is in this kernel
274 #
275 AC_DEFUN([LN_CONFIG_QUADRICS],
276 [AC_MSG_CHECKING([for QsNet sources])
277 AC_ARG_WITH([qsnet],
278         AC_HELP_STRING([--with-qsnet=path],
279                        [set path to qsnet source (default=$LINUX)]),
280         [QSNET=$with_qsnet],
281         [QSNET=$LINUX])
282 AC_MSG_RESULT([$QSNET])
283
284 AC_MSG_CHECKING([if quadrics kernel headers are present])
285 if test -d $QSNET/drivers/net/qsnet ; then
286         AC_MSG_RESULT([yes])
287         QSWLND="qswlnd"
288         AC_MSG_CHECKING([for multirail EKC])
289         if test -f $QSNET/include/elan/epcomms.h; then
290                 AC_MSG_RESULT([supported])
291                 QSWCPPFLAGS="-I$QSNET/include -DMULTIRAIL_EKC=1"
292         else
293                 AC_MSG_RESULT([not supported])
294                 AC_MSG_ERROR([Need multirail EKC])
295         fi
296
297         if test x$QSNET = x$LINUX ; then
298                 LB_LINUX_CONFIG([QSNET],[],[
299                         LB_LINUX_CONFIG([QSNET_MODULE],[],[
300                                 AC_MSG_WARN([QSNET is not enabled in this kernel; not building qswlnd.])
301                                 QSWLND=""
302                                 QSWCPPFLAGS=""
303                         ])
304                 ])
305         fi
306 else
307         AC_MSG_RESULT([no])
308         QSWLND=""
309         QSWCPPFLAGS=""
310 fi
311 AC_SUBST(QSWCPPFLAGS)
312 AC_SUBST(QSWLND)
313 ])
314
315 #
316 # LN_CONFIG_GM
317 #
318 # check if GM support is available
319 #
320 AC_DEFUN([LN_CONFIG_GM],[
321 AC_MSG_CHECKING([whether to enable GM support])
322 AC_ARG_WITH([gm],
323         AC_HELP_STRING([--with-gm=path-to-gm-source-tree],
324                        [build gmlnd against path]),
325         [
326                 case $with_gm in
327                 no)    ENABLE_GM=0
328                        ;;
329                 *)     ENABLE_GM=1
330                        GM_SRC="$with_gm"
331                        ;;
332                 esac
333         ],[
334                 ENABLE_GM=0
335         ])
336 AC_ARG_WITH([gm-install],
337         AC_HELP_STRING([--with-gm-install=path-to-gm-install-tree],
338                        [say where GM has been installed]),
339         [
340                 GM_INSTALL=$with_gm_install
341         ],[
342                 GM_INSTALL="/opt/gm"
343         ])
344 if test $ENABLE_GM -eq 0; then
345         AC_MSG_RESULT([no])
346 else
347         AC_MSG_RESULT([yes])
348
349         GMLND="gmlnd"
350         GMCPPFLAGS="-I$GM_SRC/include -I$GM_SRC/drivers -I$GM_SRC/drivers/linux/gm"
351
352         if test -f $GM_INSTALL/lib/libgm.a -o \
353                 -f $GM_INSTALL/lib64/libgm.a; then
354                 GMLIBS="-L$GM_INSTALL/lib -L$GM_INSTALL/lib64"
355         else
356                 AC_MSG_ERROR([Cant find GM libraries under $GM_INSTALL])
357         fi
358
359         EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
360         EXTRA_KCFLAGS="$GMCPPFLAGS -DGM_KERNEL $EXTRA_KCFLAGS"
361
362         AC_MSG_CHECKING([that code using GM compiles with given path])
363         LB_LINUX_TRY_COMPILE([
364                 #define GM_STRONG_TYPES 1
365                 #ifdef VERSION
366                 #undef VERSION
367                 #endif
368                 #include "gm.h"
369                 #include "gm_internal.h"
370         ],[
371                 struct gm_port *port = NULL;
372                 gm_recv_event_t *rxevent = gm_blocking_receive_no_spin(port);
373                 return 0;
374         ],[
375                 AC_MSG_RESULT([yes])
376         ],[
377                 AC_MSG_RESULT([no])
378                 AC_MSG_ERROR([Bad --with-gm path])
379         ])
380
381         AC_MSG_CHECKING([that GM has gm_register_memory_ex_phys()])
382         LB_LINUX_TRY_COMPILE([
383                 #define GM_STRONG_TYPES 1
384                 #ifdef VERSION
385                 #undef VERSION
386                 #endif
387                 #include "gm.h"
388                 #include "gm_internal.h"
389         ],[
390                 gm_status_t     gmrc;
391                 struct gm_port *port = NULL;
392                 gm_u64_t        phys = 0;
393                 gm_up_t         pvma = 0;
394
395                 gmrc = gm_register_memory_ex_phys(port, phys, 100, pvma);
396                 return 0;
397         ],[
398                 AC_MSG_RESULT([yes])
399         ],[
400                 AC_MSG_RESULT([no.
401 Please patch the GM sources as follows...
402     cd $GM_SRC
403     patch -p0 < $PWD/lnet/klnds/gmlnd/gm-reg-phys.patch
404 ...then rebuild and re-install them])
405                 AC_MSG_ERROR([Can't build GM without gm_register_memory_ex_phys()])
406         ])
407
408         EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
409 fi
410 AC_SUBST(GMCPPFLAGS)
411 AC_SUBST(GMLIBS)
412 AC_SUBST(GMLND)
413 ])
414
415
416 #
417 # LN_CONFIG_MX
418 #
419 AC_DEFUN([LN_CONFIG_MX],
420 [AC_MSG_CHECKING([whether to enable Myrinet MX support])
421 # set default
422 MXPATH="/opt/mx"
423 AC_ARG_WITH([mx],
424        AC_HELP_STRING([--with-mx=path],
425                       [build mxlnd against path]),
426        [
427                case $with_mx in
428                yes)    ENABLEMX=2
429                        ;;
430                no)     ENABLEMX=0
431                        ;;
432                *)      MXPATH=$with_mx
433                        ENABLEMX=3
434                        ;;
435                esac
436        ],[
437                ENABLEMX=1
438        ])
439 if test $ENABLEMX -eq 0; then
440        AC_MSG_RESULT([disabled])
441 elif test ! \( -f ${MXPATH}/include/myriexpress.h -a \
442               -f ${MXPATH}/include/mx_kernel_api.h -a \
443               -f ${MXPATH}/include/mx_pin.h \); then
444        AC_MSG_RESULT([no])
445        case $ENABLEMX in
446        1) ;;
447        2) AC_MSG_ERROR([Myrinet MX kernel headers not present]);;
448        3) AC_MSG_ERROR([bad --with-mx path]);;
449        *) AC_MSG_ERROR([internal error]);;
450        esac
451 else
452        MXCPPFLAGS="-I$MXPATH/include"
453        EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
454        EXTRA_KCFLAGS="$EXTRA_KCFLAGS $MXCPPFLAGS"
455        MXLIBS="-L$MXPATH/lib"
456        LB_LINUX_TRY_COMPILE([
457                #define MX_KERNEL 1
458                #include <mx_extensions.h>
459                #include <myriexpress.h>
460        ],[
461                mx_endpoint_t   end;
462                mx_status_t     status;
463                mx_request_t    request;
464                int             result;
465
466                mx_init();
467                mx_open_endpoint(MX_ANY_NIC, MX_ANY_ENDPOINT, 0, NULL, 0, &end);
468                mx_register_unexp_handler(end, (mx_unexp_handler_t) NULL, NULL);
469                mx_wait_any(end, MX_INFINITE, 0LL, 0LL, &status, &result);
470                mx_iconnect(end, 0LL, 0, 0, 0, NULL, &request);
471                return 0;
472        ],[
473                AC_MSG_RESULT([yes])
474                MXLND="mxlnd"
475        ],[
476                AC_MSG_RESULT([no])
477                case $ENABLEMX in
478                1) ;;
479                2) AC_MSG_ERROR([can't compile with Myrinet MX kernel headers]);;
480                3) AC_MSG_ERROR([can't compile with Myrinet MX headers under $MXPATH]);;
481                *) AC_MSG_ERROR([internal error]);;
482                esac
483                MXLND=""
484                MXCPPFLAGS=""
485        ])
486        EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
487 fi
488 AC_SUBST(MXCPPFLAGS)
489 AC_SUBST(MXLIBS)
490 AC_SUBST(MXLND)
491 ])
492
493
494
495 #
496 # LN_CONFIG_O2IB
497 #
498 AC_DEFUN([LN_CONFIG_O2IB],[
499 AC_MSG_CHECKING([whether to enable OpenIB gen2 support])
500 # set default
501 AC_ARG_WITH([o2ib],
502         AC_HELP_STRING([--with-o2ib=path],
503                        [build o2iblnd against path]),
504         [
505                 case $with_o2ib in
506                 yes)    O2IBPATHS="$LINUX $LINUX/drivers/infiniband"
507                         ENABLEO2IB=2
508                         ;;
509                 no)     ENABLEO2IB=0
510                         ;;
511                 *)      O2IBPATHS=$with_o2ib
512                         ENABLEO2IB=3
513                         ;;
514                 esac
515         ],[
516                 O2IBPATHS="$LINUX $LINUX/drivers/infiniband"
517                 ENABLEO2IB=1
518         ])
519 if test $ENABLEO2IB -eq 0; then
520         AC_MSG_RESULT([disabled])
521 else
522         o2ib_found=false
523         for O2IBPATH in $O2IBPATHS; do
524                 if test \( -f ${O2IBPATH}/include/rdma/rdma_cm.h -a \
525                            -f ${O2IBPATH}/include/rdma/ib_cm.h -a \
526                            -f ${O2IBPATH}/include/rdma/ib_verbs.h -a \
527                            -f ${O2IBPATH}/include/rdma/ib_fmr_pool.h \); then
528                         o2ib_found=true
529                         break
530                 fi
531         done
532         if ! $o2ib_found; then
533                 AC_MSG_RESULT([no])
534                 case $ENABLEO2IB in
535                         1) ;;
536                         2) AC_MSG_ERROR([kernel OpenIB gen2 headers not present]);;
537                         3) AC_MSG_ERROR([bad --with-o2ib path]);;
538                         *) AC_MSG_ERROR([internal error]);;
539                 esac
540         else
541                 O2IBCPPFLAGS="-I$O2IBPATH/include"
542                 EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
543                 EXTRA_KCFLAGS="$EXTRA_KCFLAGS $O2IBCPPFLAGS"
544                 EXTRA_LNET_INCLUDE="$O2IBCPPFLAGS $EXTRA_LNET_INCLUDE"
545                 LB_LINUX_TRY_COMPILE([
546                         #include <linux/version.h>
547                         #include <linux/pci.h>
548                         #if !HAVE_GFP_T
549                         typedef int gfp_t;
550                         #endif
551                         #include <rdma/rdma_cm.h>
552                         #include <rdma/ib_cm.h>
553                         #include <rdma/ib_verbs.h>
554                         #include <rdma/ib_fmr_pool.h>
555                 ],[
556                         struct rdma_cm_id          *cm_id;
557                         struct rdma_conn_param      conn_param;
558                         struct ib_device_attr       device_attr;
559                         struct ib_qp_attr           qp_attr;
560                         struct ib_pool_fmr          pool_fmr;
561                         enum   ib_cm_rej_reason     rej_reason;
562
563                         cm_id = rdma_create_id(NULL, NULL, RDMA_PS_TCP);
564                         return PTR_ERR(cm_id);
565                 ],[
566                         AC_MSG_RESULT([yes])
567                         O2IBLND="o2iblnd"
568                 ],[
569                         AC_MSG_RESULT([no])
570                         case $ENABLEO2IB in
571                         1) ;;
572                         2) AC_MSG_ERROR([can't compile with kernel OpenIB gen2 headers]);;
573                         3) AC_MSG_ERROR([can't compile with OpenIB gen2 headers under $O2IBPATH]);;
574                         *) AC_MSG_ERROR([internal error]);;
575                         esac
576                         O2IBLND=""
577                         O2IBCPPFLAGS=""
578                 ])
579
580                 # we know at this point that the found OFED source is good
581                 if test \( $ENABLEO2IB = 3 \); then
582                         if test \( -f $O2IBPATH/$SYMVERFILE \); then
583                                 AC_MSG_NOTICE([adding $O2IBPATH/$SYMVERFILE to $PWD/$SYMVERFILE])
584                                 cat $O2IBPATH/$SYMVERFILE >> $PWD/$SYMVERFILE
585                         else
586                                 AC_MSG_ERROR([an external source tree was specified for o2iblnd however I could not find a $O2IBPATH/$SYMVERFILE there])
587                         fi
588                 fi
589
590                 # version checking is a hack and isn't reliable,
591                 # we need verify it with each new ofed release
592
593                 if grep -q ib_dma_map_single \
594                         ${O2IBPATH}/include/rdma/ib_verbs.h; then
595                         if grep -q comp_vector \
596                                 ${O2IBPATH}/include/rdma/ib_verbs.h; then
597                                 IBLND_OFED_VERSION="1025"
598                         else
599                                 IBLND_OFED_VERSION="1020"
600                         fi
601                 else
602                         IBLND_OFED_VERSION="1010"
603                 fi
604
605                 AC_DEFINE_UNQUOTED(IBLND_OFED_VERSION, $IBLND_OFED_VERSION,
606                                    [OFED version])
607
608                 EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
609         fi
610 fi
611
612 AC_SUBST(EXTRA_LNET_INCLUDE)
613 AC_SUBST(O2IBCPPFLAGS)
614 AC_SUBST(O2IBLND)
615 ])
616
617 #
618 # LN_CONFIG_OPENIB
619 #
620 # check for OpenIB in the kernel
621 AC_DEFUN([LN_CONFIG_OPENIB],[
622 AC_MSG_CHECKING([whether to enable OpenIB support])
623 # set default
624 OPENIBPATH="$LINUX/drivers/infiniband"
625 AC_ARG_WITH([openib],
626         AC_HELP_STRING([--with-openib=path],
627                        [build openiblnd against path]),
628         [
629                 case $with_openib in
630                 yes)    ENABLEOPENIB=2
631                         ;;
632                 no)     ENABLEOPENIB=0
633                         ;;
634                 *)      OPENIBPATH="$with_openib"
635                         ENABLEOPENIB=3
636                         ;;
637                 esac
638         ],[
639                 ENABLEOPENIB=1
640         ])
641 if test $ENABLEOPENIB -eq 0; then
642         AC_MSG_RESULT([disabled])
643 elif test ! \( -f ${OPENIBPATH}/include/ts_ib_core.h -a \
644                -f ${OPENIBPATH}/include/ts_ib_cm.h -a \
645                -f ${OPENIBPATH}/include/ts_ib_sa_client.h \); then
646         AC_MSG_RESULT([no])
647         case $ENABLEOPENIB in
648         1) ;;
649         2) AC_MSG_ERROR([kernel OpenIB headers not present]);;
650         3) AC_MSG_ERROR([bad --with-openib path]);;
651         *) AC_MSG_ERROR([internal error]);;
652         esac
653 else
654         case $ENABLEOPENIB in
655         1|2) OPENIBCPPFLAGS="-I$OPENIBPATH/include -DIN_TREE_BUILD";;
656         3)   OPENIBCPPFLAGS="-I$OPENIBPATH/include";;
657         *)   AC_MSG_RESULT([no])
658              AC_MSG_ERROR([internal error]);;
659         esac
660         OPENIBCPPFLAGS="$OPENIBCPPFLAGS -DIB_NTXRXPARAMS=4"
661         EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
662         EXTRA_KCFLAGS="$EXTRA_KCFLAGS $OPENIBCPPFLAGS"
663         LB_LINUX_TRY_COMPILE([
664                 #include <ts_ib_core.h>
665                 #include <ts_ib_cm.h>
666                 #include <ts_ib_sa_client.h>
667         ],[
668                 struct ib_device_properties dev_props;
669                 struct ib_cm_active_param   cm_active_params;
670                 tTS_IB_CLIENT_QUERY_TID     tid;
671                 int                         enum1 = IB_QP_ATTRIBUTE_STATE;
672                 int                         enum2 = IB_ACCESS_LOCAL_WRITE;
673                 int                         enum3 = IB_CQ_CALLBACK_INTERRUPT;
674                 int                         enum4 = IB_CQ_PROVIDER_REARM;
675                 return 0;
676         ],[
677                 AC_MSG_RESULT([yes])
678                 OPENIBLND="openiblnd"
679         ],[
680                 AC_MSG_RESULT([no])
681                 case $ENABLEOPENIB in
682                 1) ;;
683                 2) AC_MSG_ERROR([can't compile with kernel OpenIB headers]);;
684                 3) AC_MSG_ERROR([can't compile with OpenIB headers under $OPENIBPATH]);;
685                 *) AC_MSG_ERROR([internal error]);;
686                 esac
687                 OPENIBLND=""
688                 OPENIBCPPFLAGS=""
689         ])
690         EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
691 fi
692 AC_SUBST(OPENIBCPPFLAGS)
693 AC_SUBST(OPENIBLND)
694 ])
695
696 #
697 # LN_CONFIG_CIBLND
698 #
699 AC_DEFUN([LN_CONFIG_CIB],[
700 AC_MSG_CHECKING([whether to enable Cisco/TopSpin IB support])
701 # set default
702 CIBPATH=""
703 CIBLND=""
704 AC_ARG_WITH([cib],
705         AC_HELP_STRING([--with-cib=path],
706                        [build ciblnd against path]),
707         [
708                 case $with_cib in
709                 no)     AC_MSG_RESULT([no]);;
710                 *)      CIBPATH="$with_cib"
711                         if test -d "$CIBPATH"; then
712                                 AC_MSG_RESULT([yes])
713                         else
714                                 AC_MSG_RESULT([no])
715                                 AC_MSG_ERROR([No directory $CIBPATH])
716                         fi;;
717                 esac
718         ],[
719                 AC_MSG_RESULT([no])
720         ])
721 if test -n "$CIBPATH"; then
722         CIBCPPFLAGS="-I${CIBPATH}/ib/ts_api_ng/include -I${CIBPATH}/all/kernel_services/include -DUSING_TSAPI"
723         CIBCPPFLAGS="$CIBCPPFLAGS -DIB_NTXRXPARAMS=3"
724         EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
725         EXTRA_KCFLAGS="$EXTRA_KCFLAGS $CIBCPPFLAGS"
726         LB_LINUX_TRY_COMPILE([
727                 #include <ts_ib_core.h>
728                 #include <ts_ib_cm.h>
729                 #include <ts_ib_sa_client.h>
730         ],[
731                 struct ib_device_properties dev_props;
732                 struct ib_cm_active_param   cm_active_params;
733                 tTS_IB_CLIENT_QUERY_TID     tid;
734                 int                         enum1 = TS_IB_QP_ATTRIBUTE_STATE;
735                 int                         enum2 = TS_IB_ACCESS_LOCAL_WRITE;
736                 int                         enum3 = TS_IB_CQ_CALLBACK_INTERRUPT;
737                 int                         enum4 = TS_IB_CQ_PROVIDER_REARM;
738                 return 0;
739         ],[
740                 CIBLND="ciblnd"
741         ],[
742                 AC_MSG_ERROR([can't compile ciblnd with given path])
743                 CIBCPPFLAGS=""
744         ])
745         EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
746 fi
747 AC_SUBST(CIBCPPFLAGS)
748 AC_SUBST(CIBLND)
749 ])
750
751 #
752 # LN_CONFIG_IIB
753 #
754 # check for infinicon infiniband support
755 #
756 AC_DEFUN([LN_CONFIG_IIB],[
757 AC_MSG_CHECKING([whether to enable Infinicon support])
758 # set default
759 IIBPATH="/usr/include"
760 AC_ARG_WITH([iib],
761         AC_HELP_STRING([--with-iib=path],
762                        [build iiblnd against path]),
763         [
764                 case $with_iib in
765                 yes)    ENABLEIIB=2
766                         ;;
767                 no)     ENABLEIIB=0
768                         ;;
769                 *)      IIBPATH="${with_iib}/include"
770                         ENABLEIIB=3
771                         ;;
772                 esac
773         ],[
774                 ENABLEIIB=1
775         ])
776 if test $ENABLEIIB -eq 0; then
777         AC_MSG_RESULT([disabled])
778 elif test ! \( -f ${IIBPATH}/linux/iba/ibt.h \); then
779         AC_MSG_RESULT([no])
780         case $ENABLEIIB in
781         1) ;;
782         2) AC_MSG_ERROR([default Infinicon headers not present]);;
783         3) AC_MSG_ERROR([bad --with-iib path]);;
784         *) AC_MSG_ERROR([internal error]);;
785         esac
786 else
787         IIBCPPFLAGS="-I$IIBPATH"
788         if test $IIBPATH != "/usr/include"; then
789                 # we need /usr/include come what may
790                 IIBCPPFLAGS="$IIBCPPFLAGS -I/usr/include"
791         fi
792         EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
793         EXTRA_KCFLAGS="$EXTRA_KCFLAGS $IIBCPPFLAGS"
794         LB_LINUX_TRY_COMPILE([
795                 #include <linux/iba/ibt.h>
796         ],[
797                 IBT_INTERFACE_UNION interfaces;
798                 FSTATUS             rc;
799
800                  rc = IbtGetInterfaceByVersion(IBT_INTERFACE_VERSION_2,
801                                                &interfaces);
802
803                 return rc == FSUCCESS ? 0 : 1;
804         ],[
805                 AC_MSG_RESULT([yes])
806                 IIBLND="iiblnd"
807         ],[
808                 AC_MSG_RESULT([no])
809                 case $ENABLEIIB in
810                 1) ;;
811                 2) AC_MSG_ERROR([can't compile with default Infinicon headers]);;
812                 3) AC_MSG_ERROR([can't compile with Infinicon headers under $IIBPATH]);;
813                 *) AC_MSG_ERROR([internal error]);;
814                 esac
815                 IIBLND=""
816                 IIBCPPFLAGS=""
817         ])
818         EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
819 fi
820 AC_SUBST(IIBCPPFLAGS)
821 AC_SUBST(IIBLND)
822 ])
823
824 #
825 # LN_CONFIG_VIB
826 #
827 # check for Voltaire infiniband support
828 #
829 AC_DEFUN([LN_CONFIG_VIB],
830 [AC_MSG_CHECKING([whether to enable Voltaire IB support])
831 VIBPATH=""
832 AC_ARG_WITH([vib],
833         AC_HELP_STRING([--with-vib=path],
834                        [build viblnd against path]),
835         [
836                 case $with_vib in
837                 no)     AC_MSG_RESULT([no]);;
838                 *)      VIBPATH="${with_vib}/src/nvigor/ib-code"
839                         if test -d "$with_vib" -a -d "$VIBPATH"; then
840                                 AC_MSG_RESULT([yes])
841                         else
842                                 AC_MSG_RESULT([no])
843                                 AC_MSG_ERROR([No directory $VIBPATH])
844                         fi;;
845                 esac
846         ],[
847                 AC_MSG_RESULT([no])
848         ])
849 if test -z "$VIBPATH"; then
850         VIBLND=""
851 else
852         VIBCPPFLAGS="-I${VIBPATH}/include -I${VIBPATH}/cm"
853         EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
854         EXTRA_KCFLAGS="$EXTRA_KCFLAGS $VIBCPPFLAGS"
855         LB_LINUX_TRY_COMPILE([
856                 #include <linux/list.h>
857                 #include <asm/byteorder.h>
858                 #ifdef __BIG_ENDIAN
859                 # define CPU_BE 1
860                 # define CPU_LE 0
861                 #endif
862                 #ifdef __LITTLE_ENDIAN
863                 # define CPU_BE 0
864                 # define CPU_LE 1
865                 #endif
866                 #include <vverbs.h>
867                 #include <ib-cm.h>
868                 #include <ibat.h>
869         ],[
870                 vv_hca_h_t       kib_hca;
871                 vv_return_t      vvrc;
872                 cm_cep_handle_t  cep;
873                 ibat_arp_data_t  arp_data;
874                 ibat_stat_t      ibatrc;
875
876                 vvrc = vv_hca_open("ANY_HCA", NULL, &kib_hca);
877                 cep = cm_create_cep(cm_cep_transp_rc);
878                 ibatrc = ibat_get_ib_data((uint32_t)0, (uint32_t)0,
879                                           ibat_paths_primary, &arp_data,
880                                           (ibat_get_ib_data_reply_fn_t)NULL,
881                                           NULL, 0);
882                 return 0;
883         ],[
884                 VIBLND="viblnd"
885         ],[
886                 AC_MSG_ERROR([can't compile viblnd with given path])
887         ])
888         EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
889 fi
890 if test -n "$VIBLND"; then
891         EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
892         EXTRA_KCFLAGS="$EXTRA_KCFLAGS $VIBCPPFLAGS"
893         AC_MSG_CHECKING([if Voltaire still uses void * sg addresses])
894         LB_LINUX_TRY_COMPILE([
895                 #include <linux/list.h>
896                 #include <asm/byteorder.h>
897                 #ifdef __BIG_ENDIAN
898                 # define CPU_BE 1
899                 # define CPU_LE 0
900                 #endif
901                 #ifdef __LITTLE_ENDIAN
902                 # define CPU_BE 0
903                 # define CPU_LE 1
904                 #endif
905                 #include <vverbs.h>
906                 #include <ib-cm.h>
907                 #include <ibat.h>
908         ],[
909                 vv_scatgat_t  sg;
910
911                 return &sg.v_address[3] == NULL;
912         ],[
913                 AC_MSG_RESULT([yes])
914                 VIBCPPFLAGS="$VIBCPPFLAGS -DIBNAL_VOIDSTAR_SGADDR=1"
915         ],[
916                 AC_MSG_RESULT([no])
917         ])
918         EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
919 fi
920 AC_SUBST(VIBCPPFLAGS)
921 AC_SUBST(VIBLND)
922 ])
923
924 #
925 # LN_CONFIG_RALND
926 #
927 # check whether to use the RapidArray lnd
928 #
929 AC_DEFUN([LN_CONFIG_RALND],
930 [#### Rapid Array
931 AC_MSG_CHECKING([if RapidArray kernel headers are present])
932 # placeholder
933 RACPPFLAGS="-I${LINUX}/drivers/xd1/include"
934 EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
935 EXTRA_KCFLAGS="$EXTRA_KCFLAGS $RACPPFLAGS"
936 LB_LINUX_TRY_COMPILE([
937         #include <linux/types.h>
938         #include <rapl.h>
939 ],[
940         RAP_RETURN          rc;
941         RAP_PVOID           dev_handle;
942
943         rc = RapkGetDeviceByIndex(0, NULL, &dev_handle);
944
945         return rc == RAP_SUCCESS ? 0 : 1;
946 ],[
947         AC_MSG_RESULT([yes])
948         RALND="ralnd"
949 ],[
950         AC_MSG_RESULT([no])
951         RALND=""
952         RACPPFLAGS=""
953 ])
954 EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
955 AC_SUBST(RACPPFLAGS)
956 AC_SUBST(RALND)
957 ])
958
959 #
960 # LN_STRUCT_PAGE_LIST
961 #
962 # 2.6.4 no longer has page->list
963 #
964 AC_DEFUN([LN_STRUCT_PAGE_LIST],
965 [AC_MSG_CHECKING([if struct page has a list field])
966 LB_LINUX_TRY_COMPILE([
967         #include <linux/mm.h>
968 ],[
969         struct page page;
970         &page.list;
971 ],[
972         AC_MSG_RESULT([yes])
973         AC_DEFINE(HAVE_PAGE_LIST, 1, [struct page has a list field])
974 ],[
975         AC_MSG_RESULT([no])
976 ])
977 ])
978
979 #
980 # LN_STRUCT_SIGHAND
981 #
982 # red hat 2.4 adds sighand to struct task_struct
983 #
984 AC_DEFUN([LN_STRUCT_SIGHAND],
985 [AC_MSG_CHECKING([if task_struct has a sighand field])
986 LB_LINUX_TRY_COMPILE([
987         #include <linux/sched.h>
988 ],[
989         struct task_struct p;
990         p.sighand = NULL;
991 ],[
992         AC_DEFINE(CONFIG_RH_2_4_20, 1, [this kernel contains Red Hat 2.4.20 patches])
993         AC_MSG_RESULT([yes])
994 ],[
995         AC_MSG_RESULT([no])
996 ])
997 ])
998
999 #
1000 # LN_FUNC_CPU_ONLINE
1001 #
1002 # cpu_online is different in rh 2.4, vanilla 2.4, and 2.6
1003 #
1004 AC_DEFUN([LN_FUNC_CPU_ONLINE],
1005 [AC_MSG_CHECKING([if kernel defines cpu_online()])
1006 LB_LINUX_TRY_COMPILE([
1007         #include <linux/sched.h>
1008 ],[
1009         cpu_online(0);
1010 ],[
1011         AC_MSG_RESULT([yes])
1012         AC_DEFINE(HAVE_CPU_ONLINE, 1, [cpu_online found])
1013 ],[
1014         AC_MSG_RESULT([no])
1015 ])
1016 ])
1017
1018 #
1019 # LN_TYPE_GFP_T
1020 #
1021 # check if gfp_t is typedef-ed
1022 #
1023 AC_DEFUN([LN_TYPE_GFP_T],
1024 [AC_MSG_CHECKING([if kernel defines gfp_t])
1025 LB_LINUX_TRY_COMPILE([
1026         #include <linux/gfp.h>
1027 ],[
1028         return sizeof(gfp_t);
1029 ],[
1030         AC_MSG_RESULT([yes])
1031         AC_DEFINE(HAVE_GFP_T, 1, [gfp_t found])
1032 ],[
1033         AC_MSG_RESULT([no])
1034 ])
1035 ])
1036
1037 #
1038 # LN_TYPE_CPUMASK_T
1039 #
1040 # same goes for cpumask_t
1041 #
1042 AC_DEFUN([LN_TYPE_CPUMASK_T],
1043 [AC_MSG_CHECKING([if kernel defines cpumask_t])
1044 LB_LINUX_TRY_COMPILE([
1045         #include <linux/sched.h>
1046 ],[
1047         return sizeof (cpumask_t);
1048 ],[
1049         AC_MSG_RESULT([yes])
1050         AC_DEFINE(HAVE_CPUMASK_T, 1, [cpumask_t found])
1051 ],[
1052         AC_MSG_RESULT([no])
1053 ])
1054 ])
1055
1056 #
1057 # LN_FUNC_SHOW_TASK
1058 #
1059 # we export show_task(), but not all kernels have it (yet)
1060 #
1061 AC_DEFUN([LN_FUNC_SHOW_TASK],
1062 [LB_CHECK_SYMBOL_EXPORT([show_task],
1063 [kernel/ksyms.c kernel/sched.c],[
1064 AC_DEFINE(HAVE_SHOW_TASK, 1, [show_task is exported])
1065 ],[
1066 ])
1067 ])
1068
1069 # check userland __u64 type
1070 AC_DEFUN([LN_U64_LONG_LONG],
1071 [AC_MSG_CHECKING([u64 is long long type])
1072 tmp_flags="$CFLAGS"
1073 CFLAGS="$CFLAGS -Werror"
1074 AC_COMPILE_IFELSE([
1075         #include <linux/types.h>
1076         int main(void) {
1077                 unsigned long long *data1;
1078                 __u64 *data2;
1079                 
1080                 data1 = data2;
1081                 return 0;
1082         }
1083 ],[
1084         AC_MSG_RESULT([yes])
1085         AC_DEFINE(HAVE_U64_LONG_LONG, 1,
1086                   [__u64 is long long type])
1087 ],[
1088         AC_MSG_RESULT([no])
1089 ])
1090 CFLAGS="$tmp_flags"
1091 ])
1092
1093 # check userland size_t type
1094 AC_DEFUN([LN_SIZE_T_LONG],
1095 [AC_MSG_CHECKING([size_t is unsigned long type])
1096 tmp_flags="$CFLAGS"
1097 CFLAGS="$CFLAGS -Werror"
1098 AC_COMPILE_IFELSE([
1099         #include <linux/types.h>
1100         int main(void) {
1101                 unsigned long *data1;
1102                 size_t *data2;
1103                 
1104                 data1 = data2;
1105                 return 0;
1106         }
1107 ],[
1108         AC_MSG_RESULT([yes])
1109         AC_DEFINE(HAVE_SIZE_T_LONG, 1,
1110                   [size_t is long type])
1111 ],[
1112         AC_MSG_RESULT([no])
1113 ])
1114 CFLAGS="$tmp_flags"
1115 ])
1116
1117 AC_DEFUN([LN_SSIZE_T_LONG],
1118 [AC_MSG_CHECKING([ssize_t is signed long type])
1119 tmp_flags="$CFLAGS"
1120 CFLAGS="$CFLAGS -Werror"
1121 AC_COMPILE_IFELSE([
1122         #include <linux/types.h>
1123         int main(void) {
1124                 long *data1;
1125                 ssize_t *data2;
1126                 
1127                 data1 = data2;
1128                 return 0;
1129         }
1130 ],[
1131         AC_MSG_RESULT([yes])
1132         AC_DEFINE(HAVE_SSIZE_T_LONG, 1,
1133                   [ssize_t is long type])
1134 ],[
1135         AC_MSG_RESULT([no])
1136 ])
1137 CFLAGS="$tmp_flags"
1138 ])
1139
1140
1141 # LN_TASKLIST_LOCK
1142 # 2.6.18 remove tasklist_lock export
1143 AC_DEFUN([LN_TASKLIST_LOCK],
1144 [LB_CHECK_SYMBOL_EXPORT([tasklist_lock],
1145 [kernel/fork.c],[
1146 AC_DEFINE(HAVE_TASKLIST_LOCK, 1,
1147          [tasklist_lock exported])
1148 ],[
1149 ])
1150 ])
1151
1152 # 2.6.19 API changes
1153 # kmem_cache_destroy(cachep) return void instead of
1154 # int
1155 AC_DEFUN([LN_KMEM_CACHE_DESTROY_INT],
1156 [AC_MSG_CHECKING([kmem_cache_destroy(cachep) return int])
1157 LB_LINUX_TRY_COMPILE([
1158         #include <linux/slab.h>
1159 ],[
1160         int i = kmem_cache_destroy(NULL);
1161 ],[
1162         AC_MSG_RESULT(yes)
1163         AC_DEFINE(HAVE_KMEM_CACHE_DESTROY_INT, 1,
1164                 [kmem_cache_destroy(cachep) return int])
1165 ],[
1166         AC_MSG_RESULT(NO)
1167 ])
1168 ])
1169
1170 # 2.6.19 API change
1171 #panic_notifier_list use atomic_notifier operations
1172 #
1173 AC_DEFUN([LN_ATOMIC_PANIC_NOTIFIER],
1174 [AC_MSG_CHECKING([panic_notifier_list is atomic])
1175 LB_LINUX_TRY_COMPILE([
1176         #include <linux/notifier.h>
1177         #include <linux/kernel.h>
1178 ],[
1179         struct atomic_notifier_head panic_notifier_list;
1180 ],[
1181         AC_MSG_RESULT(yes)
1182         AC_DEFINE(HAVE_ATOMIC_PANIC_NOTIFIER, 1,
1183                 [panic_notifier_list is atomic_notifier_head])
1184 ],[
1185         AC_MSG_RESULT(NO)
1186 ])
1187 ])
1188
1189 # 2.6.20 API change INIT_WORK use 2 args and not
1190 # store data inside
1191 AC_DEFUN([LN_3ARGS_INIT_WORK],
1192 [AC_MSG_CHECKING([check INIT_WORK want 3 args])
1193 LB_LINUX_TRY_COMPILE([
1194         #include <linux/workqueue.h>
1195 ],[
1196         struct work_struct work;
1197
1198         INIT_WORK(&work, NULL, NULL);
1199 ],[
1200         AC_MSG_RESULT(yes)
1201         AC_DEFINE(HAVE_3ARGS_INIT_WORK, 1,
1202                   [INIT_WORK use 3 args and store data inside])
1203 ],[
1204         AC_MSG_RESULT(NO)
1205 ])
1206 ])
1207
1208 # 2.6.21 api change. 'register_sysctl_table' use only one argument,
1209 # instead of more old which need two.
1210 AC_DEFUN([LN_2ARGS_REGISTER_SYSCTL],
1211 [AC_MSG_CHECKING([check register_sysctl_table want 2 args])
1212 LB_LINUX_TRY_COMPILE([
1213         #include <linux/sysctl.h>
1214 ],[
1215         return register_sysctl_table(NULL,0);
1216 ],[
1217         AC_MSG_RESULT(yes)
1218         AC_DEFINE(HAVE_2ARGS_REGISTER_SYSCTL, 1,
1219                   [register_sysctl_table want 2 args])
1220 ],[
1221         AC_MSG_RESULT(NO)
1222 ])
1223 ])
1224
1225 # 2.6.21 marks kmem_cache_t deprecated and uses struct kmem_cache
1226 # instead
1227 AC_DEFUN([LN_KMEM_CACHE],
1228 [AC_MSG_CHECKING([check kernel has struct kmem_cache])
1229 tmp_flags="$EXTRA_KCFLAGS"
1230 EXTRA_KCFLAGS="-Werror"
1231 LB_LINUX_TRY_COMPILE([
1232         #include <linux/slab.h>
1233         typedef struct kmem_cache cache_t;
1234 ],[
1235         cache_t *cachep = NULL;
1236
1237         kmem_cache_alloc(cachep, 0);
1238 ],[
1239         AC_MSG_RESULT(yes)
1240         AC_DEFINE(HAVE_KMEM_CACHE, 1,
1241                   [kernel has struct kmem_cache])
1242 ],[
1243         AC_MSG_RESULT(NO)
1244 ])
1245 EXTRA_KCFLAGS="$tmp_flags"
1246 ])
1247 # 2.6.23 lost dtor argument
1248 AC_DEFUN([LN_KMEM_CACHE_CREATE_DTOR],
1249 [AC_MSG_CHECKING([check kmem_cache_create has dtor argument])
1250 LB_LINUX_TRY_COMPILE([
1251         #include <linux/slab.h>
1252 ],[
1253         kmem_cache_create(NULL, 0, 0, 0, NULL, NULL);
1254 ],[
1255         AC_MSG_RESULT(yes)
1256         AC_DEFINE(HAVE_KMEM_CACHE_CREATE_DTOR, 1,
1257                   [kmem_cache_create has dtor argument])
1258 ],[
1259         AC_MSG_RESULT(NO)
1260 ])
1261 ])
1262
1263 #
1264 # LN_PROG_LINUX
1265 #
1266 # LNet linux kernel checks
1267 #
1268 AC_DEFUN([LN_PROG_LINUX],
1269 [
1270 LN_FUNC_CPU_ONLINE
1271 LN_TYPE_GFP_T
1272 LN_TYPE_CPUMASK_T
1273 LN_CONFIG_AFFINITY
1274 LN_CONFIG_BACKOFF
1275 LN_CONFIG_PANIC_DUMPLOG
1276 LN_CONFIG_QUADRICS
1277 LN_CONFIG_GM
1278 LN_CONFIG_OPENIB
1279 LN_CONFIG_CIB
1280 LN_CONFIG_VIB
1281 LN_CONFIG_IIB
1282 LN_CONFIG_O2IB
1283 LN_CONFIG_RALND
1284 LN_CONFIG_PTLLND
1285 LN_CONFIG_MX
1286
1287 LN_STRUCT_PAGE_LIST
1288 LN_STRUCT_SIGHAND
1289 LN_FUNC_SHOW_TASK
1290 LN_U64_LONG_LONG
1291 LN_SSIZE_T_LONG
1292 LN_SIZE_T_LONG
1293 # 2.6.18
1294 LN_TASKLIST_LOCK
1295 # 2.6.19
1296 LN_KMEM_CACHE_DESTROY_INT
1297 LN_ATOMIC_PANIC_NOTIFIER
1298 # 2.6.20
1299 LN_3ARGS_INIT_WORK
1300 # 2.6.21
1301 LN_2ARGS_REGISTER_SYSCTL
1302 LN_KMEM_CACHE
1303 # 2.6.23
1304 LN_KMEM_CACHE_CREATE_DTOR
1305 ])
1306
1307 #
1308 # LN_PROG_DARWIN
1309 #
1310 # Darwin checks
1311 #
1312 AC_DEFUN([LN_PROG_DARWIN],
1313 [LB_DARWIN_CHECK_FUNCS([get_preemption_level])
1314 ])
1315
1316 #
1317 # LN_PATH_DEFAULTS
1318 #
1319 # default paths for installed files
1320 #
1321 AC_DEFUN([LN_PATH_DEFAULTS],
1322 [
1323 ])
1324
1325 #
1326 # LN_CONFIGURE
1327 #
1328 # other configure checks
1329 #
1330 AC_DEFUN([LN_CONFIGURE],
1331 [# lnet/utils/portals.c
1332 AC_CHECK_HEADERS([netdb.h netinet/tcp.h asm/types.h endian.h sys/ioctl.h])
1333 AC_CHECK_FUNCS([gethostbyname socket connect])
1334
1335 # lnet/utils/debug.c
1336 AC_CHECK_HEADERS([linux/version.h])
1337
1338 AC_CHECK_TYPE([spinlock_t],
1339         [AC_DEFINE(HAVE_SPINLOCK_T, 1, [spinlock_t is defined])],
1340         [],
1341         [#include <linux/spinlock.h>])
1342
1343 # lnet/utils/wirecheck.c
1344 AC_CHECK_FUNCS([strnlen])
1345
1346 # --------  Check for required packages  --------------
1347
1348 #
1349 # LC_CONFIG_READLINE
1350 #
1351 # Build with readline
1352 #
1353 AC_MSG_CHECKING([whether to enable readline support])
1354 AC_ARG_ENABLE(readline,
1355         AC_HELP_STRING([--disable-readline],
1356                         [disable readline support]),
1357         [],[enable_readline='yes'])
1358 AC_MSG_RESULT([$enable_readline])
1359
1360 # -------- check for readline if enabled ----
1361 if test x$enable_readline = xyes ; then
1362         LIBS_save="$LIBS"
1363         LIBS="-lncurses $LIBS"
1364         AC_CHECK_LIB([readline],[readline],[
1365         LIBREADLINE="-lreadline -lncurses"
1366         AC_DEFINE(HAVE_LIBREADLINE, 1, [readline library is available])
1367         ],[
1368         LIBREADLINE=""
1369         ])
1370         LIBS="$LIBS_save"
1371 else
1372         LIBREADLINE=""
1373 fi
1374 AC_SUBST(LIBREADLINE)
1375
1376 AC_MSG_CHECKING([if efence debugging support is requested])
1377 AC_ARG_ENABLE(efence,
1378         AC_HELP_STRING([--enable-efence],
1379                         [use efence library]),
1380         [],[enable_efence='no'])
1381 AC_MSG_RESULT([$enable_efence])
1382 if test "$enable_efence" = "yes" ; then
1383         LIBEFENCE="-lefence"
1384         AC_DEFINE(HAVE_LIBEFENCE, 1, [libefence support is requested])
1385 else
1386         LIBEFENCE=""
1387 fi
1388 AC_SUBST(LIBEFENCE)
1389
1390 # -------- enable acceptor libwrap (TCP wrappers) support? -------
1391 AC_MSG_CHECKING([if libwrap support is requested])
1392 AC_ARG_ENABLE([libwrap],
1393         AC_HELP_STRING([--enable-libwrap], [use TCP wrappers]),
1394         [case "${enableval}" in
1395                 yes) enable_libwrap=yes ;;
1396                 no) enable_libwrap=no ;;
1397                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-libwrap) ;;
1398         esac],[enable_libwrap=no])
1399 AC_MSG_RESULT([$enable_libwrap])
1400 if test x$enable_libwrap = xyes ; then
1401         LIBWRAP="-lwrap"
1402         AC_DEFINE(HAVE_LIBWRAP, 1, [libwrap support is requested])
1403 else
1404         LIBWRAP=""
1405 fi
1406 AC_SUBST(LIBWRAP)
1407
1408 # -------- check for -lpthread support ----
1409 AC_MSG_CHECKING([whether to use libpthread for lnet library])
1410 AC_ARG_ENABLE([libpthread],
1411         AC_HELP_STRING([--disable-libpthread],
1412                 [disable libpthread]),
1413         [],[enable_libpthread=yes])
1414 if test "$enable_libpthread" = "yes" ; then
1415         AC_CHECK_LIB([pthread], [pthread_create],
1416                 [ENABLE_LIBPTHREAD="yes"],
1417                 [ENABLE_LIBPTHREAD="no"])
1418         if test "$ENABLE_LIBPTHREAD" = "yes" ; then
1419                 AC_MSG_RESULT([$ENABLE_LIBPTHREAD])
1420                 PTHREAD_LIBS="-lpthread"
1421                 AC_DEFINE([HAVE_LIBPTHREAD], 1, [use libpthread])
1422         else
1423                 PTHREAD_LIBS=""
1424                 AC_MSG_RESULT([no libpthread is found])
1425         fi
1426         AC_SUBST(PTHREAD_LIBS)
1427 else
1428         AC_MSG_RESULT([no (disabled explicitly)])
1429         ENABLE_LIBPTHREAD="no"
1430 fi
1431 AC_SUBST(ENABLE_LIBPTHREAD)
1432
1433 # ----------------------------------------
1434 # some tests for catamount-like systems
1435 # ----------------------------------------
1436 AC_ARG_ENABLE([sysio_init],
1437         AC_HELP_STRING([--disable-sysio-init],
1438                 [call sysio init functions when initializing liblustre]),
1439         [],[enable_sysio_init=yes])
1440 AC_MSG_CHECKING([whether to initialize libsysio])
1441 AC_MSG_RESULT([$enable_sysio_init])
1442 if test x$enable_sysio_init != xno ; then
1443         AC_DEFINE([INIT_SYSIO], 1, [call sysio init functions])
1444 fi
1445
1446 AC_ARG_ENABLE([urandom],
1447         AC_HELP_STRING([--disable-urandom],
1448                 [disable use of /dev/urandom for liblustre]),
1449         [],[enable_urandom=yes])
1450 AC_MSG_CHECKING([whether to use /dev/urandom for liblustre])
1451 AC_MSG_RESULT([$enable_urandom])
1452 if test x$enable_urandom != xno ; then
1453         AC_DEFINE([LIBLUSTRE_USE_URANDOM], 1, [use /dev/urandom for random data])
1454 fi
1455
1456 # -------- check for -lcap support ----
1457 if test x$enable_liblustre = xyes ; then
1458         AC_CHECK_LIB([cap], [cap_get_proc],
1459                 [
1460                         CAP_LIBS="-lcap"
1461                         AC_DEFINE([HAVE_LIBCAP], 1, [use libcap])
1462                 ],
1463                 [
1464                         CAP_LIBS=""
1465                 ])
1466         AC_SUBST(CAP_LIBS)
1467
1468 fi
1469
1470 LN_CONFIG_MAX_PAYLOAD
1471 LN_CONFIG_UPTLLND
1472 LN_CONFIG_USOCKLND
1473 ])
1474
1475 #
1476 # LN_CONDITIONALS
1477 #
1478 # AM_CONDITOINAL defines for lnet
1479 #
1480 AC_DEFUN([LN_CONDITIONALS],
1481 [AM_CONDITIONAL(BUILD_QSWLND, test x$QSWLND = "xqswlnd")
1482 AM_CONDITIONAL(BUILD_GMLND, test x$GMLND = "xgmlnd")
1483 AM_CONDITIONAL(BUILD_MXLND, test x$MXLND = "xmxlnd")
1484 AM_CONDITIONAL(BUILD_O2IBLND, test x$O2IBLND = "xo2iblnd")
1485 AM_CONDITIONAL(BUILD_OPENIBLND, test x$OPENIBLND = "xopeniblnd")
1486 AM_CONDITIONAL(BUILD_CIBLND, test x$CIBLND = "xciblnd")
1487 AM_CONDITIONAL(BUILD_IIBLND, test x$IIBLND = "xiiblnd")
1488 AM_CONDITIONAL(BUILD_VIBLND, test x$VIBLND = "xviblnd")
1489 AM_CONDITIONAL(BUILD_RALND, test x$RALND = "xralnd")
1490 AM_CONDITIONAL(BUILD_PTLLND, test x$PTLLND = "xptllnd")
1491 AM_CONDITIONAL(BUILD_UPTLLND, test x$UPTLLND = "xptllnd")
1492 AM_CONDITIONAL(BUILD_USOCKLND, test x$USOCKLND = "xusocklnd")
1493 ])
1494
1495 #
1496 # LN_CONFIG_FILES
1497 #
1498 # files that should be generated with AC_OUTPUT
1499 #
1500 AC_DEFUN([LN_CONFIG_FILES],
1501 [AC_CONFIG_FILES([
1502 lnet/Kernelenv
1503 lnet/Makefile
1504 lnet/autoMakefile
1505 lnet/autoconf/Makefile
1506 lnet/doc/Makefile
1507 lnet/include/Makefile
1508 lnet/include/libcfs/Makefile
1509 lnet/include/libcfs/linux/Makefile
1510 lnet/include/lnet/Makefile
1511 lnet/include/lnet/linux/Makefile
1512 lnet/klnds/Makefile
1513 lnet/klnds/autoMakefile
1514 lnet/klnds/gmlnd/Makefile
1515 lnet/klnds/mxlnd/autoMakefile
1516 lnet/klnds/mxlnd/Makefile
1517 lnet/klnds/gmlnd/autoMakefile
1518 lnet/klnds/openiblnd/Makefile
1519 lnet/klnds/openiblnd/autoMakefile
1520 lnet/klnds/o2iblnd/Makefile
1521 lnet/klnds/o2iblnd/autoMakefile
1522 lnet/klnds/ciblnd/Makefile
1523 lnet/klnds/ciblnd/autoMakefile
1524 lnet/klnds/iiblnd/Makefile
1525 lnet/klnds/iiblnd/autoMakefile
1526 lnet/klnds/viblnd/Makefile
1527 lnet/klnds/viblnd/autoMakefile
1528 lnet/klnds/qswlnd/Makefile
1529 lnet/klnds/qswlnd/autoMakefile
1530 lnet/klnds/ralnd/Makefile
1531 lnet/klnds/ralnd/autoMakefile
1532 lnet/klnds/socklnd/Makefile
1533 lnet/klnds/socklnd/autoMakefile
1534 lnet/klnds/ptllnd/Makefile
1535 lnet/klnds/ptllnd/autoMakefile
1536 lnet/libcfs/Makefile
1537 lnet/libcfs/autoMakefile
1538 lnet/libcfs/linux/Makefile
1539 lnet/lnet/Makefile
1540 lnet/lnet/autoMakefile
1541 lnet/selftest/Makefile
1542 lnet/selftest/autoMakefile
1543 lnet/ulnds/Makefile
1544 lnet/ulnds/autoMakefile
1545 lnet/ulnds/socklnd/Makefile
1546 lnet/ulnds/ptllnd/Makefile
1547 lnet/utils/Makefile
1548 ])
1549 case $lb_target_os in
1550         darwin)
1551                 AC_CONFIG_FILES([
1552 lnet/include/libcfs/darwin/Makefile
1553 lnet/include/lnet/darwin/Makefile
1554 lnet/libcfs/darwin/Makefile
1555 ])
1556                 ;;
1557 esac
1558 ])