lnet/autoconf/lustre-lnet.m4

   1 #
   2 # LN_CONFIG_MAX_PAYLOAD
   3 #
   4 # configure maximum payload
   5 #
   6 AC_DEFUN([LN_CONFIG_MAX_PAYLOAD], [
   7 AC_MSG_CHECKING([for non-default maximum LNET payload])
   8 AC_ARG_WITH([max-payload-mb],
   9         AC_HELP_STRING([--with-max-payload-mb=MBytes],
  10                 [set maximum lnet payload in MBytes]),
  11         [
  12                 AC_MSG_RESULT([$with_max_payload_mb])
  13                 CONFIG_LNET_MAX_PAYLOAD_MB=$with_max_payload_mb
  14                 CONFIG_LNET_MAX_PAYLOAD="(($with_max_payload_mb)<<20)"
  15         ], [
  16                 AC_MSG_RESULT([no])
  17                 CONFIG_LNET_MAX_PAYLOAD="LNET_MTU"
  18         ])
  19 AC_DEFINE_UNQUOTED(CONFIG_LNET_MAX_PAYLOAD, $CONFIG_LNET_MAX_PAYLOAD,
  20         [Max LNET payload])
  21 ]) # LN_CONFIG_MAX_PAYLOAD
  22
  23 #
  24 # LN_CHECK_GCC_VERSION
  25 #
  26 # Check compiler version
  27 #
  28 AC_DEFUN([LN_CHECK_GCC_VERSION], [
  29 AC_MSG_CHECKING([compiler version])
  30 PTL_CC_VERSION=`$CC --version | awk '/^gcc/{print $ 3}'`
  31 PTL_MIN_CC_VERSION="3.2.2"
  32 v2n() {
  33         awk -F. '{printf "%d\n", (($ 1)*100+($ 2))*100+($ 3)}'
  34 }
  35 if test -z "$PTL_CC_VERSION" -o \
  36         $(echo $PTL_CC_VERSION | v2n) -ge $(echo $PTL_MIN_CC_VERSION | v2n); then
  37         AC_MSG_RESULT([ok])
  38 else
  39         AC_MSG_RESULT([Buggy compiler found])
  40         AC_MSG_ERROR([Need gcc version >= $PTL_MIN_CC_VERSION])
  41 fi
  42 ]) # LN_CHECK_GCC_VERSION
  43
  44 #
  45 # LN_FUNC_DEV_GET_BY_NAME_2ARG
  46 #
  47 AC_DEFUN([LN_FUNC_DEV_GET_BY_NAME_2ARG], [
  48 LB_CHECK_COMPILE([if 'dev_get_by_name' has two args],
  49 dev_get_by_name_2args, [
  50         #include <linux/netdevice.h>
  51 ],[
  52         dev_get_by_name(NULL, NULL);
  53 ],[
  54         AC_DEFINE(HAVE_DEV_GET_BY_NAME_2ARG, 1,
  55                 [dev_get_by_name has 2 args])
  56 ])
  57 ]) # LN_FUNC_DEV_GET_BY_NAME_2ARG
  58
  59 #
  60 # LN_CONFIG_AFFINITY
  61 #
  62 # check if cpu affinity is available/wanted
  63 #
  64 AC_DEFUN([LN_CONFIG_AFFINITY], [
  65 AC_MSG_CHECKING([whether to enable CPU affinity support])
  66 AC_ARG_ENABLE([affinity],
  67         AC_HELP_STRING([--disable-affinity],
  68                 [disable process/irq affinity]),
  69         [], [enable_affinity="yes"])
  70 AC_MSG_RESULT([$enable_affinity])
  71 AS_IF([test "x$enable_affinity" = xyes], [
  72         LB_CHECK_COMPILE([if Linux kernel has cpu affinity support],
  73         set_cpus_allowed_ptr, [
  74                 #include <linux/sched.h>
  75         ],[
  76                 struct task_struct *t;
  77                 #if HAVE_CPUMASK_T
  78                 cpumask_t     m;
  79                 #else
  80                 unsigned long m;
  81                 #endif
  82                 set_cpus_allowed_ptr(t, &m);
  83         ],[
  84                 AC_DEFINE(CPU_AFFINITY, 1,
  85                         [kernel has cpu affinity support])
  86         ])
  87 ])
  88 ]) # LN_CONFIG_AFFINITY
  89
  90 #
  91 # LN_CONFIG_BACKOFF
  92 #
  93 # check if tunable tcp backoff is available/wanted
  94 #
  95 AC_DEFUN([LN_CONFIG_BACKOFF], [
  96 AC_MSG_CHECKING([whether to enable tunable backoff TCP support])
  97 AC_ARG_ENABLE([backoff],
  98         AC_HELP_STRING([--disable-backoff],
  99                 [disable socknal tunable backoff]),
 100         [], [enable_backoff="yes"])
 101 AC_MSG_RESULT([$enable_backoff])
 102 AS_IF([test "x$enable_backoff" = xyes], [
 103         AC_MSG_CHECKING([if Linux kernel has tunable backoff TCP support])
 104         AS_IF([grep -c TCP_BACKOFF $LINUX/include/linux/tcp.h >/dev/null], [
 105                 AC_MSG_RESULT([yes])
 106                 AC_DEFINE(SOCKNAL_BACKOFF, 1, [use tunable backoff TCP])
 107                 AS_IF([grep rto_max $LINUX/include/linux/tcp.h | grep -q __u16 >/dev/null],
 108                         [AC_DEFINE(SOCKNAL_BACKOFF_MS, 1,
 109                                 [tunable backoff TCP in ms])])
 110         ], [
 111                 AC_MSG_RESULT([no])
 112         ])
 113 ])
 114 ]) # LN_CONFIG_BACKOFF
 115
 116 #
 117 # LN_CONFIG_DLC
 118 #
 119 # Configure dlc if enabled
 120 #
 121 # if libyaml is set (IE libyaml installed) and enable_dlc = yes then build
 122 # dlc other wise (IE if libyaml is not set or enable_dlc = no) then don't
 123 # build dlc.
 124 #
 125 AC_DEFUN([LN_CONFIG_DLC], [
 126         AC_CHECK_LIB([yaml],  [yaml_parser_initialize],[
 127                 LIBYAML="libyaml"],[
 128                 LIBYAML=""],[-lm])
 129         AC_MSG_CHECKING([whether to enable dlc])
 130         AC_ARG_ENABLE([dlc],
 131                 AC_HELP_STRING([--disable-dlc],
 132                         [disable building dlc]),
 133                         [], [enable_dlc="yes"])
 134         AC_MSG_RESULT([$enable_dlc])
 135         USE_DLC=""
 136         AS_IF([test "x$enable_dlc" = xyes],
 137               [AS_IF([test "x$LIBYAML" = xlibyaml], [
 138                         USE_DLC="yes"
 139                 ], [
 140                         AC_MSG_RESULT([no (libyaml not present)])
 141                 ])
 142         ])
 143         AC_SUBST(USE_DLC)
 144 ])
 145
 146 #
 147 # LN_CONFIG_QUADRICS
 148 #
 149 # check if quadrics support is in this kernel
 150 #
 151 AC_DEFUN([LN_CONFIG_QUADRICS], [
 152 AC_MSG_CHECKING([for QsNet sources])
 153 AC_ARG_WITH([qsnet],
 154         AC_HELP_STRING([--with-qsnet=path],
 155                 [set path to qsnet source (default=$LINUX)]),
 156         [QSNET=$with_qsnet], [QSNET=$LINUX])
 157 AC_MSG_RESULT([$QSNET])
 158
 159 QSWLND=""
 160 QSWCPPFLAGS=""
 161 AC_MSG_CHECKING([if quadrics kernel headers are present])
 162 AS_IF([test -d $QSNET/drivers/net/qsnet], [
 163         AC_MSG_RESULT([yes])
 164         QSWLND="qswlnd"
 165         AC_MSG_CHECKING([for multirail EKC])
 166         AS_IF([test -f $QSNET/include/elan/epcomms.h], [
 167                 AC_MSG_RESULT([supported])
 168                 QSNET=$(readlink --canonicalize $QSNET)
 169                 QSWCPPFLAGS="-I$QSNET/include -DMULTIRAIL_EKC=1"
 170         ], [
 171                 AC_MSG_RESULT([not supported])
 172                 AC_MSG_ERROR([Need multirail EKC])
 173         ])
 174
 175         AS_IF([test x$QSNET = x$LINUX], [
 176                 LB_CHECK_CONFIG([QSNET], [], [
 177                         LB_CHECK_CONFIG([QSNET_MODULE], [], [
 178                                 AC_MSG_WARN([QSNET is not enabled in this kernel; not building qswlnd.])
 179                                 QSWLND=""
 180                                 QSWCPPFLAGS=""
 181                         ])
 182                 ])
 183         ])
 184 ], [
 185         AC_MSG_RESULT([no])
 186 ])
 187 AC_SUBST(QSWLND)
 188 AC_SUBST(QSWCPPFLAGS)
 189 ]) # LN_CONFIG_QUADRICS
 190
 191 #
 192 # LN_CONFIG_MX
 193 #
 194 AC_DEFUN([LN_CONFIG_MX], [
 195 # set default
 196 MXPATH="/opt/mx"
 197 AC_MSG_CHECKING([whether to enable Myrinet MX support])
 198 AC_ARG_WITH([mx],
 199         AC_HELP_STRING([--with-mx=path],
 200                 [build mxlnd against path]),
 201         [
 202                 case $with_mx in
 203                 yes) ENABLEMX=2 ;;
 204                 no)  ENABLEMX=0 ;;
 205                 *)   ENABLEMX=3; MXPATH=$with_mx ;;
 206                 esac
 207         ],[
 208                 ENABLEMX=1
 209         ])
 210 AS_IF([test $ENABLEMX -eq 0], [
 211         AC_MSG_RESULT([disabled])
 212 ], [test ! \( -f ${MXPATH}/include/myriexpress.h -a \
 213               -f ${MXPATH}/include/mx_kernel_api.h -a \
 214               -f ${MXPATH}/include/mx_pin.h \)], [
 215         AC_MSG_RESULT([no])
 216         case $ENABLEMX in
 217         1) ;;
 218         2) AC_MSG_ERROR([Myrinet MX kernel headers not present]) ;;
 219         3) AC_MSG_ERROR([bad --with-mx path]) ;;
 220         *) AC_MSG_ERROR([internal error]) ;;
 221         esac
 222 ], [
 223         AC_MSG_RESULT([check])
 224         MXPATH=$(readlink --canonicalize $MXPATH)
 225         MXCPPFLAGS="-I$MXPATH/include"
 226         MXLIBS="-L$MXPATH/lib"
 227         EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 228         EXTRA_KCFLAGS="$EXTRA_KCFLAGS $MXCPPFLAGS"
 229         LB_CHECK_COMPILE([if have Myrinet MX support],
 230         myrinet_mx_support, [
 231                 #define MX_KERNEL 1
 232                 #include <mx_extensions.h>
 233                 #include <myriexpress.h>
 234         ],[
 235                 mx_endpoint_t   end;
 236                 mx_status_t     status;
 237                 mx_request_t    request;
 238                 int             result;
 239                 mx_init();
 240                 mx_open_endpoint(MX_ANY_NIC, MX_ANY_ENDPOINT, 0, NULL, 0, &end);
 241                 mx_register_unexp_handler(end, (mx_unexp_handler_t) NULL, NULL);
 242                 mx_wait_any(end, MX_INFINITE, 0LL, 0LL, &status, &result);
 243                 mx_iconnect(end, 0LL, 0, 0, 0, NULL, &request);
 244                 return 0;
 245         ],[
 246                 MXLND="mxlnd"
 247         ],[
 248                 case $ENABLEMX in
 249                 1) ;;
 250                 2) AC_MSG_ERROR([can't compile with Myrinet MX kernel headers]) ;;
 251                 3) AC_MSG_ERROR([can't compile with Myrinet MX headers under $MXPATH]) ;;
 252                 *) AC_MSG_ERROR([internal error]) ;;
 253                 esac
 254                 MXCPPFLAGS=""
 255                 MXLIBS=""
 256                 MXLND=""
 257         ])
 258         EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 259 ])
 260 AC_SUBST(MXCPPFLAGS)
 261 AC_SUBST(MXLIBS)
 262 AC_SUBST(MXLND)
 263 ]) # LN_CONFIG_MX
 264
 265 #
 266 # LN_CONFIG_O2IB
 267 #
 268 AC_DEFUN([LN_CONFIG_O2IB], [
 269 AC_MSG_CHECKING([whether to use Compat RDMA])
 270 AC_ARG_WITH([o2ib],
 271         AC_HELP_STRING([--with-o2ib=path],
 272                 [build o2iblnd against path]),
 273         [
 274                 case $with_o2ib in
 275                 yes)    O2IBPATHS="$LINUX $LINUX/drivers/infiniband"
 276                         ENABLEO2IB=2
 277                         ;;
 278                 no)     ENABLEO2IB=0
 279                         ;;
 280                 *)      O2IBPATHS=$with_o2ib
 281                         ENABLEO2IB=3
 282                         ;;
 283                 esac
 284         ],[
 285                 O2IBPATHS="$LINUX $LINUX/drivers/infiniband"
 286                 ENABLEO2IB=1
 287         ])
 288 AS_IF([test $ENABLEO2IB -eq 0], [
 289         AC_MSG_RESULT([no])
 290 ], [
 291         o2ib_found=false
 292         for O2IBPATH in $O2IBPATHS; do
 293                 AS_IF([test \( -f ${O2IBPATH}/include/rdma/rdma_cm.h -a \
 294                            -f ${O2IBPATH}/include/rdma/ib_cm.h -a \
 295                            -f ${O2IBPATH}/include/rdma/ib_verbs.h -a \
 296                            -f ${O2IBPATH}/include/rdma/ib_fmr_pool.h \)], [
 297                         AS_IF([test \( -d ${O2IBPATH}/kernel_patches -a \
 298                                    -f ${O2IBPATH}/Makefile \)], [
 299                                 AC_MSG_RESULT([no])
 300                                 AC_MSG_ERROR([
 301
 302 you appear to be trying to use the OFED distribution's source
 303 directory (${O2IBPATH}) rather than the "development/headers"
 304 directory which is likely in ${O2IBPATH%-*}
 305 ])
 306                         ])
 307                         o2ib_found=true
 308                         break
 309                 ])
 310         done
 311         if ! $o2ib_found; then
 312                 AC_MSG_RESULT([no])
 313                 case $ENABLEO2IB in
 314                         1) ;;
 315                         2) AC_MSG_ERROR([kernel OpenIB gen2 headers not present]) ;;
 316                         3) AC_MSG_ERROR([bad --with-o2ib path]) ;;
 317                         *) AC_MSG_ERROR([internal error]) ;;
 318                 esac
 319         else
 320                 compatrdma_found=false
 321                 if test -f ${O2IBPATH}/include/linux/compat-2.6.h; then
 322                         AC_MSG_RESULT([yes])
 323                         compatrdma_found=true
 324                         AC_DEFINE(HAVE_COMPAT_RDMA, 1, [compat rdma found])
 325                 else
 326                         AC_MSG_RESULT([no])
 327                 fi
 328                 if ! $compatrdma_found; then
 329                         if test -f "$O2IBPATH/config.mk"; then
 330                                 . "$O2IBPATH/config.mk"
 331                         elif test -f "$O2IBPATH/ofed_patch.mk"; then
 332                                 . "$O2IBPATH/ofed_patch.mk"
 333                         fi
 334                 else
 335                         if test "x$RHEL_KERNEL" = xyes; then
 336                                 case "$RHEL_KERNEL_VERSION" in
 337                                         2.6.32-358*)
 338                                                 EXTRA_OFED_INCLUDE="$EXTRA_OFED_INCLUDE -DCONFIG_COMPAT_RHEL_6_4" ;;
 339                                         2.6.32-431*)
 340                                                 EXTRA_OFED_INCLUDE="$EXTRA_OFED_INCLUDE -DCONFIG_COMPAT_RHEL_6_4 -DCONFIG_COMPAT_RHEL_6_5" ;;
 341                                 esac
 342                         elif test "x$SUSE_KERNEL" = xyes; then
 343                                 SP=$(grep PATCHLEVEL /etc/SuSE-release | sed -e 's/.*= *//')
 344                                 EXTRA_OFED_INCLUDE="$EXTRA_OFED_INCLUDE -DCONFIG_COMPAT_SLES_11_$SP"
 345                         fi
 346                 fi
 347                 AC_MSG_CHECKING([whether to use any OFED backport headers])
 348                 if test -n "$BACKPORT_INCLUDES"; then
 349                         AC_MSG_RESULT([yes])
 350                         OFED_BACKPORT_PATH="$O2IBPATH/${BACKPORT_INCLUDES/*\/kernel_addons/kernel_addons}/"
 351                         EXTRA_OFED_INCLUDE="-I$OFED_BACKPORT_PATH $EXTRA_OFED_INCLUDE"
 352                 else
 353                         AC_MSG_RESULT([no])
 354                 fi
 355
 356                 O2IBLND=""
 357                 O2IBPATH=$(readlink --canonicalize $O2IBPATH)
 358                 EXTRA_OFED_INCLUDE="$EXTRA_OFED_INCLUDE -I$O2IBPATH/include"
 359                 LB_CHECK_COMPILE([whether to enable OpenIB gen2 support],
 360                 openib_gen2_support, [
 361                         #include <linux/version.h>
 362                         #include <linux/pci.h>
 363                         #include <linux/gfp.h>
 364                         #ifdef HAVE_COMPAT_RDMA
 365                         #include <linux/compat-2.6.h>
 366                         #endif
 367                         #include <rdma/rdma_cm.h>
 368                         #include <rdma/ib_cm.h>
 369                         #include <rdma/ib_verbs.h>
 370                         #include <rdma/ib_fmr_pool.h>
 371                 ],[
 372                         struct rdma_cm_id      *cm_idi __attribute__ ((unused));
 373                         struct rdma_conn_param  conn_param __attribute__ ((unused));
 374                         struct ib_device_attr   device_attr __attribute__ ((unused));
 375                         struct ib_qp_attr       qp_attr __attribute__ ((unused));
 376                         struct ib_pool_fmr      pool_fmr __attribute__ ((unused));
 377                         enum   ib_cm_rej_reason rej_reason __attribute__ ((unused));
 378                         rdma_destroy_id(NULL);
 379                 ],[
 380                         O2IBLND="o2iblnd"
 381                 ],[
 382                         case $ENABLEO2IB in
 383                         1) ;;
 384                         2) AC_MSG_ERROR([can't compile with kernel OpenIB gen2 headers]) ;;
 385                         3) AC_MSG_ERROR([can't compile with OpenIB gen2 headers under $O2IBPATH]) ;;
 386                         *) AC_MSG_ERROR([internal error]) ;;
 387                         esac
 388                 ])
 389                 # we know at this point that the found OFED source is good
 390                 O2IB_SYMVER=""
 391                 if test $ENABLEO2IB -eq 3 ; then
 392                         # OFED default rpm not handle sles10 Modules.symvers name
 393                         for name in Module.symvers Modules.symvers; do
 394                                 if test -f $O2IBPATH/$name; then
 395                                         O2IB_SYMVER=$name;
 396                                         break;
 397                                 fi
 398                         done
 399                         if test -n "$O2IB_SYMVER"; then
 400                                 AC_MSG_NOTICE([adding $O2IBPATH/$O2IB_SYMVER to $PWD/$SYMVERFILE])
 401                                 # strip out the existing symbols versions first
 402                                 if test -f $PWD/$SYMVERFILE; then
 403                                 egrep -v $(echo $(awk '{ print $2 }' $O2IBPATH/$O2IB_SYMVER) | tr ' ' '|') $PWD/$SYMVERFILE > $PWD/$SYMVERFILE.old
 404                                 else
 405                                         touch $PWD/$SYMVERFILE.old
 406                                 fi
 407                                 cat $PWD/$SYMVERFILE.old $O2IBPATH/$O2IB_SYMVER > $PWD/$SYMVERFILE
 408                                 rm $PWD/$SYMVERFILE.old
 409                         else
 410                                 AC_MSG_ERROR([an external source tree was specified for o2iblnd however I could not find a $O2IBPATH/Module.symvers there])
 411                         fi
 412                 fi
 413
 414                 LN_CONFIG_OFED_SPEC
 415         fi
 416 ])
 417 AC_SUBST(EXTRA_OFED_INCLUDE)
 418 AC_SUBST(O2IBLND)
 419
 420 # In RHEL 6.2, rdma_create_id() takes the queue-pair type as a fourth argument
 421 AS_IF([test $ENABLEO2IB -ne 0], [
 422         LB_CHECK_COMPILE([if 'rdma_create_id' wants four args],
 423         rdma_create_id_4args, [
 424                 #ifdef HAVE_COMPAT_RDMA
 425                 #include <linux/compat-2.6.h>
 426                 #endif
 427                 #include <rdma/rdma_cm.h>
 428         ],[
 429                 rdma_create_id(NULL, NULL, 0, 0);
 430         ],[
 431                 AC_DEFINE(HAVE_RDMA_CREATE_ID_4ARG, 1,
 432                         [rdma_create_id wants 4 args])
 433         ])
 434 ])
 435 ]) # LN_CONFIG_O2IB
 436
 437 #
 438 # LN_CONFIG_RALND
 439 #
 440 # check whether to use the RapidArray lnd
 441 #
 442 AC_DEFUN([LN_CONFIG_RALND], [
 443 RALND=""
 444 RACPPFLAGS="-I${LINUX}/drivers/xd1/include"
 445 EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 446 EXTRA_KCFLAGS="$EXTRA_KCFLAGS $RACPPFLAGS"
 447 LB_CHECK_COMPILE([if 'RapidArray' kernel headers are present],
 448 RapkGetDeviceByIndex, [
 449         #include <linux/types.h>
 450         #include <rapl.h>
 451 ],[
 452         RAP_RETURN rc;
 453         RAP_PVOID  dev_handle;
 454         rc = RapkGetDeviceByIndex(0, NULL, &dev_handle);
 455         return rc == RAP_SUCCESS ? 0 : 1;
 456 ],[
 457         RALND="ralnd"
 458 ],[
 459         RACPPFLAGS=""
 460 ])
 461 EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 462 AC_SUBST(RACPPFLAGS)
 463 AC_SUBST(RALND)
 464 ]) # LN_CONFIG_RALND
 465
 466 #
 467 # LN_CONFIG_GNILND
 468 #
 469 # check whether to use the Gemini Network Interface lnd
 470 #
 471 AC_DEFUN([LN_CONFIG_GNILND], [
 472 AC_MSG_CHECKING([whether to enable GNI lnd])
 473 AC_ARG_ENABLE([gni],
 474         AC_HELP_STRING([--enable-gni],
 475                 [enable GNI lnd]),
 476         [], [enable_gni="no"])
 477 AC_MSG_RESULT([$enable_gni])
 478
 479 AS_IF([test "x$enable_gni" = xyes], [
 480         # GNICPPFLAGS was set in spec file
 481         EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 482         EXTRA_KCFLAGS="$EXTRA_KCFLAGS $GNICPPFLAGS"
 483         LB_CHECK_COMPILE([if GNI kernel headers are present],
 484         GNI_header, [
 485                 #include <linux/types.h>
 486                 #include <gni_pub.h>
 487         ],[
 488                 gni_cdm_handle_t kgni_domain;
 489                 gni_return_t     rc;
 490                 int              rrc;
 491                 rc = gni_cdm_create(0, 1, 1, 0, &kgni_domain);
 492                 rrc = (rc == GNI_RC_SUCCESS) ? 0 : 1;
 493                 return rrc;
 494         ],[
 495                 GNILND="gnilnd"
 496         ],[
 497                 AC_MSG_ERROR([can't compile gnilnd with given GNICPPFLAGS: $GNICPPFLAGS])
 498         ])
 499         # at this point, we have gnilnd basic support,
 500         # now check for extra features
 501         LB_CHECK_COMPILE([to use RCA in gnilnd],
 502         RCA_gnilnd, [
 503                 #include <linux/types.h>
 504                 #include <gni_pub.h>
 505                 #include <krca_lib.h>
 506         ],[
 507                 gni_cdm_handle_t kgni_domain;
 508                 gni_return_t     rc;
 509                 krca_ticket_t    ticket = KRCA_NULL_TICKET;
 510                 int              rrc;
 511                 __u32            nid = 0, nic_addr;
 512                 rc = gni_cdm_create(0, 1, 1, 0, &kgni_domain);
 513                 rrc = (rc == GNI_RC_SUCCESS) ? 0 : 1;
 514                 rrc += krca_nid_to_nicaddrs(nid, 1, &nic_addr);
 515                 rrc += krca_register(&ticket, RCA_MAKE_SERVICE_INDEX(RCA_IO_CLASS, 9), 99, 0);
 516                 return rrc;
 517         ],[
 518                 GNICPPFLAGS="$GNICPPFLAGS -DGNILND_USE_RCA=1"
 519                 GNILNDRCA="gnilndrca"
 520         ])
 521         EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 522 ])
 523 AC_SUBST(GNICPPFLAGS)
 524 AC_SUBST(GNILNDRCA)
 525 AC_SUBST(GNILND)
 526 ]) # LN_CONFIG_GNILND
 527
 528 #
 529 # LN_CONFIG_USERSPACE
 530 #
 531 # This is defined but empty because it is called from
 532 # build/autconf/lustre-build.m4 which is shared by all branches.
 533 #
 534 AC_DEFUN([LN_CONFIG_USERSPACE], [
 535 ]) # LN_CONFIG_USERSPACE
 536
 537 #
 538 # LN_CONFIG_TCP_SENDPAGE
 539 #
 540 # 2.6.36 tcp_sendpage() first parameter is 'struct sock' instead of 'struct socket'.
 541 #
 542 AC_DEFUN([LN_CONFIG_TCP_SENDPAGE], [
 543 tmp_flags="$EXTRA_KCFLAGS"
 544 EXTRA_KCFLAGS="-Werror"
 545 LB_CHECK_COMPILE([if 'tcp_sendpage' first parameter is socket],
 546 tcp_sendpage_socket, [
 547         #include <linux/net.h>
 548         #include <net/tcp.h>
 549 ],[
 550         tcp_sendpage((struct socket*)0, NULL, 0, 0, 0);
 551 ],[
 552         AC_DEFINE(HAVE_TCP_SENDPAGE_USE_SOCKET, 1,
 553                 [tcp_sendpage use socket as first parameter])
 554 ])
 555 EXTRA_KCFLAGS="$tmp_flags"
 556 ]) # LN_CONFIG_TCP_SENDPAGE
 557
 558 #
 559 # LN_CONFIG_SK_DATA_READY
 560 #
 561 # 2.6.36 tcp_sendpage() first parameter is 'struct sock' instead of 'struct socket'.
 562 #
 563 AC_DEFUN([LN_CONFIG_SK_DATA_READY], [
 564 tmp_flags="$EXTRA_KCFLAGS"
 565 EXTRA_KCFLAGS="-Werror"
 566 LB_CHECK_COMPILE([if 'sk_data_ready' takes only one argument],
 567 sk_data_ready, [
 568         #include <linux/net.h>
 569         #include <net/sock.h>
 570 ],[
 571         ((struct sock *)0)->sk_data_ready(NULL);
 572 ],[
 573         AC_DEFINE(HAVE_SK_DATA_READY_ONE_ARG, 1,
 574                 [sk_data_ready uses only one argument])
 575 ])
 576 EXTRA_KCFLAGS="$tmp_flags"
 577 ]) # LN_CONFIG_SK_DATA_READY
 578
 579 #
 580 # LN_PROG_LINUX
 581 #
 582 # LNet linux kernel checks
 583 #
 584 AC_DEFUN([LN_PROG_LINUX], [
 585 AC_MSG_NOTICE([LNet kernel checks
 586 ==============================================================================])
 587
 588 LN_FUNC_DEV_GET_BY_NAME_2ARG
 589 LN_CONFIG_AFFINITY
 590 LN_CONFIG_BACKOFF
 591 LN_CONFIG_QUADRICS
 592 LN_CONFIG_O2IB
 593 LN_CONFIG_RALND
 594 LN_CONFIG_GNILND
 595 LN_CONFIG_MX
 596 # 2.6.36
 597 LN_CONFIG_TCP_SENDPAGE
 598 # 3.15
 599 LN_CONFIG_SK_DATA_READY
 600 ]) # LN_PROG_LINUX
 601
 602 #
 603 # LN_PATH_DEFAULTS
 604 #
 605 # default paths for installed files
 606 #
 607 AC_DEFUN([LN_PATH_DEFAULTS], [
 608 ]) # LN_PATH_DEFAULTS
 609
 610 #
 611 # LN_CONFIGURE
 612 #
 613 # other configure checks
 614 #
 615 AC_DEFUN([LN_CONFIGURE], [
 616 AC_MSG_NOTICE([LNet core checks
 617 ==============================================================================])
 618
 619 # lnet/utils/portals.c
 620 AC_CHECK_HEADERS([netdb.h netinet/tcp.h asm/types.h endian.h sys/ioctl.h])
 621 AC_CHECK_FUNCS([gethostbyname socket connect])
 622
 623 # lnet/utils/debug.c
 624 AC_CHECK_HEADERS([linux/version.h])
 625
 626 # lnet/utils/wirecheck.c
 627 AC_CHECK_FUNCS([strnlen])
 628
 629 # --------  Check for required packages  --------------
 630
 631 #
 632 # LC_CONFIG_READLINE
 633 #
 634 # Build with readline
 635 #
 636 AC_MSG_CHECKING([whether to enable readline support])
 637 AC_ARG_ENABLE(readline,
 638         AC_HELP_STRING([--disable-readline],
 639                 [disable readline support]),
 640         [], [enable_readline="yes"])
 641 AC_MSG_RESULT([$enable_readline])
 642
 643 # -------- check for readline if enabled ----
 644
 645 LIBREADLINE=""
 646 AS_IF([test "x$enable_readline" = xyes], [
 647         AC_CHECK_LIB([readline], [readline], [
 648                 LIBREADLINE="-lreadline"
 649                 AC_DEFINE(HAVE_LIBREADLINE, 1,
 650                         [readline library is available])])
 651 ])
 652 AC_SUBST(LIBREADLINE)
 653
 654 # -------- enable acceptor libwrap (TCP wrappers) support? -------
 655
 656 AC_MSG_CHECKING([if libwrap support is requested])
 657 AC_ARG_ENABLE([libwrap],
 658         AC_HELP_STRING([--enable-libwrap], [use TCP wrappers]),
 659         [case "${enableval}" in
 660                 yes) enable_libwrap="yes" ;;
 661                 no)  enable_libwrap="no" ;;
 662                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-libwrap) ;;
 663         esac], [enable_libwrap="no"])
 664 AC_MSG_RESULT([$enable_libwrap])
 665 LIBWRAP=""
 666 AS_IF([test "x$enable_libwrap" = xyes], [
 667         LIBWRAP="-lwrap"
 668         AC_DEFINE(HAVE_LIBWRAP, 1,
 669                 [libwrap support is requested])
 670 ])
 671 AC_SUBST(LIBWRAP)
 672
 673 LN_CONFIG_MAX_PAYLOAD
 674 LN_CONFIG_DLC
 675 ]) # LN_CONFIGURE
 676
 677 #
 678 # LN_CONDITIONALS
 679 #
 680 # AM_CONDITOINAL defines for lnet
 681 #
 682 AC_DEFUN([LN_CONDITIONALS], [
 683 AM_CONDITIONAL(BUILD_QSWLND,     test x$QSWLND = "xqswlnd")
 684 AM_CONDITIONAL(BUILD_MXLND,      test x$MXLND = "xmxlnd")
 685 AM_CONDITIONAL(BUILD_O2IBLND,    test x$O2IBLND = "xo2iblnd")
 686 AM_CONDITIONAL(BUILD_RALND,      test x$RALND = "xralnd")
 687 AM_CONDITIONAL(BUILD_GNILND,     test x$GNILND = "xgnilnd")
 688 AM_CONDITIONAL(BUILD_GNILND_RCA, test x$GNILNDRCA = "xgnilndrca")
 689 AM_CONDITIONAL(BUILD_DLC,        test x$USE_DLC = "xyes")
 690 ]) # LN_CONDITIONALS
 691
 692 #
 693 # LN_CONFIG_FILES
 694 #
 695 # files that should be generated with AC_OUTPUT
 696 #
 697 AC_DEFUN([LN_CONFIG_FILES], [
 698 AC_CONFIG_FILES([
 699 lnet/Kernelenv
 700 lnet/Makefile
 701 lnet/autoMakefile
 702 lnet/autoconf/Makefile
 703 lnet/doc/Makefile
 704 lnet/include/Makefile
 705 lnet/include/lnet/Makefile
 706 lnet/include/lnet/linux/Makefile
 707 lnet/klnds/Makefile
 708 lnet/klnds/autoMakefile
 709 lnet/klnds/mxlnd/autoMakefile
 710 lnet/klnds/mxlnd/Makefile
 711 lnet/klnds/o2iblnd/Makefile
 712 lnet/klnds/o2iblnd/autoMakefile
 713 lnet/klnds/qswlnd/Makefile
 714 lnet/klnds/qswlnd/autoMakefile
 715 lnet/klnds/ralnd/Makefile
 716 lnet/klnds/ralnd/autoMakefile
 717 lnet/klnds/gnilnd/Makefile
 718 lnet/klnds/gnilnd/autoMakefile
 719 lnet/klnds/socklnd/Makefile
 720 lnet/klnds/socklnd/autoMakefile
 721 lnet/lnet/Makefile
 722 lnet/lnet/autoMakefile
 723 lnet/selftest/Makefile
 724 lnet/selftest/autoMakefile
 725 lnet/utils/Makefile
 726 lnet/utils/lnetconfig/Makefile
 727 ])
 728 ]) # LN_CONFIG_FILES