lnet/autoconf/lustre-lnet.m4

   1 #
   2 # LN_CONFIG_MAX_PAYLOAD
   3 #
   4 # configure maximum payload
   5 #
   6 AC_DEFUN([LN_CONFIG_MAX_PAYLOAD],
   7 [AC_MSG_CHECKING([for non-default maximum LNET payload])
   8 AC_ARG_WITH([max-payload-mb],
   9         AC_HELP_STRING([--with-max-payload-mb=MBytes],
  10                        [set maximum lnet payload in MBytes]),
  11         [
  12                 AC_MSG_RESULT([$with_max_payload_mb])
  13                 LNET_MAX_PAYLOAD_MB=$with_max_payload_mb
  14                 LNET_MAX_PAYLOAD="(($with_max_payload_mb)<<20)"
  15         ], [
  16                 AC_MSG_RESULT([no])
  17                 LNET_MAX_PAYLOAD="LNET_MTU"
  18         ])
  19         AC_DEFINE_UNQUOTED(LNET_MAX_PAYLOAD, $LNET_MAX_PAYLOAD,
  20                            [Max LNET payload])
  21 ])
  22
  23 #
  24 # LN_CHECK_GCC_VERSION
  25 #
  26 # Check compiler version
  27 #
  28 AC_DEFUN([LN_CHECK_GCC_VERSION],
  29 [AC_MSG_CHECKING([compiler version])
  30 PTL_CC_VERSION=`$CC --version | awk '/^gcc/{print $ 3}'`
  31 PTL_MIN_CC_VERSION="3.2.2"
  32 v2n() {
  33         awk -F. '{printf "%d\n", (($ 1)*100+($ 2))*100+($ 3)}'
  34 }
  35 if test -z "$PTL_CC_VERSION" -o \
  36         `echo $PTL_CC_VERSION | v2n` -ge `echo $PTL_MIN_CC_VERSION | v2n`; then
  37         AC_MSG_RESULT([ok])
  38 else
  39         AC_MSG_RESULT([Buggy compiler found])
  40         AC_MSG_ERROR([Need gcc version >= $PTL_MIN_CC_VERSION])
  41 fi
  42 ])
  43
  44 #
  45 # LN_CONFIG_AFFINITY
  46 #
  47 # check if cpu affinity is available/wanted
  48 #
  49 AC_DEFUN([LN_CONFIG_AFFINITY],
  50 [AC_ARG_ENABLE([affinity],
  51         AC_HELP_STRING([--disable-affinity],
  52                        [disable process/irq affinity]),
  53         [],[enable_affinity='yes'])
  54
  55 AC_MSG_CHECKING([for CPU affinity support])
  56 if test x$enable_affinity = xno ; then
  57         AC_MSG_RESULT([no (by request)])
  58 else
  59         LB_LINUX_TRY_COMPILE([
  60                 #include <linux/sched.h>
  61         ],[
  62                 struct task_struct t;
  63                 #if HAVE_CPUMASK_T
  64                 cpumask_t     m;
  65                 #else
  66                 unsigned long m;
  67                 #endif
  68                 set_cpus_allowed(&t, m);
  69         ],[
  70                 AC_DEFINE(CPU_AFFINITY, 1, [kernel has cpu affinity support])
  71                 AC_MSG_RESULT([yes])
  72         ],[
  73                 AC_MSG_RESULT([no (no kernel support)])
  74         ])
  75 fi
  76 ])
  77
  78 #
  79 # LN_CONFIG_PORTALS
  80 #
  81 # configure support for Portals
  82 #
  83 AC_DEFUN([LN_CONFIG_PORTALS],
  84 [AC_MSG_CHECKING([for portals])
  85 AC_ARG_WITH([portals],
  86         AC_HELP_STRING([--with-portals=path],
  87                        [set path to portals]),
  88         [
  89                 case $with_portals in
  90                         no)     ENABLEPORTALS=0
  91                                 ;;
  92                         *)      PORTALS="${with_portals}"
  93                                 ENABLEPORTALS=1
  94                                 ;;
  95                 esac
  96         ], [
  97                 ENABLEPORTALS=0
  98         ])
  99 PTLLNDCPPFLAGS=""
 100 if test $ENABLEPORTALS -eq 0; then
 101         AC_MSG_RESULT([no])
 102 elif test ! \( -f ${PORTALS}/include/portals/p30.h \); then
 103         AC_MSG_RESULT([no])
 104         AC_MSG_ERROR([bad --with-portals path])
 105 else
 106         AC_MSG_RESULT([$PORTALS])
 107         PTLLNDCPPFLAGS="-I${PORTALS}/include"
 108 fi
 109 AC_SUBST(PTLLNDCPPFLAGS)
 110 ])
 111
 112 #
 113 # LN_CONFIG_BACKOFF
 114 #
 115 # check if tunable tcp backoff is available/wanted
 116 #
 117 AC_DEFUN([LN_CONFIG_BACKOFF],
 118 [AC_MSG_CHECKING([for tunable backoff TCP support])
 119 AC_ARG_ENABLE([backoff],
 120        AC_HELP_STRING([--disable-backoff],
 121                       [disable socknal tunable backoff]),
 122        [],[enable_backoff='yes'])
 123 if test x$enable_backoff = xno ; then
 124        AC_MSG_RESULT([no (by request)])
 125 else
 126        BOCD="`grep -c TCP_BACKOFF $LINUX/include/linux/tcp.h`"
 127        if test "$BOCD" != 0 ; then
 128                AC_DEFINE(SOCKNAL_BACKOFF, 1, [use tunable backoff TCP])
 129                AC_MSG_RESULT(yes)
 130                if grep rto_max $LINUX/include/linux/tcp.h|grep -q __u16; then
 131                    AC_DEFINE(SOCKNAL_BACKOFF_MS, 1, [tunable backoff TCP in ms])
 132                fi
 133        else
 134                AC_MSG_RESULT([no (no kernel support)])
 135        fi
 136 fi
 137 ])
 138
 139
 140 #
 141 # LN_CONFIG_PTLLND
 142 #
 143 # configure support for Portals LND
 144 #
 145 AC_DEFUN([LN_CONFIG_PTLLND],
 146 [
 147 if test -z "$ENABLEPORTALS"; then
 148         LN_CONFIG_PORTALS
 149 fi
 150
 151 AC_MSG_CHECKING([whether to build the kernel portals LND])
 152
 153 PTLLND=""
 154 if test $ENABLEPORTALS -ne 0; then
 155         AC_MSG_RESULT([yes])
 156         PTLLND="ptllnd"
 157 else
 158         AC_MSG_RESULT([no])
 159 fi
 160 AC_SUBST(PTLLND)
 161 ])
 162
 163 #
 164 # LN_CONFIG_UPTLLND
 165 #
 166 # configure support for Portals LND
 167 #
 168 AC_DEFUN([LN_CONFIG_UPTLLND],
 169 [
 170 if test -z "$ENABLEPORTALS"; then
 171         LN_CONFIG_PORTALS
 172 fi
 173
 174 AC_MSG_CHECKING([whether to build the userspace portals LND])
 175
 176 UPTLLND=""
 177 if test $ENABLEPORTALS -ne 0; then
 178         AC_MSG_RESULT([yes])
 179         UPTLLND="ptllnd"
 180 else
 181         AC_MSG_RESULT([no])
 182 fi
 183 AC_SUBST(UPTLLND)
 184 ])
 185
 186 #
 187 # LN_CONFIG_USOCKLND
 188 #
 189 # configure support for userspace TCP/IP LND
 190 #
 191 AC_DEFUN([LN_CONFIG_USOCKLND],
 192 [AC_MSG_CHECKING([whether to build usocklnd])
 193 AC_ARG_ENABLE([usocklnd],
 194         AC_HELP_STRING([--disable-usocklnd],
 195                         [disable usocklnd]),
 196         [],[enable_usocklnd='yes'])
 197
 198 if test x$enable_usocklnd = xyes ; then
 199         if test "$ENABLE_LIBPTHREAD" = "yes" ; then
 200                 AC_MSG_RESULT([yes])
 201                 USOCKLND="usocklnd"
 202         else
 203                 AC_MSG_RESULT([no (libpthread not present or disabled)])
 204                 USOCKLND=""
 205         fi
 206 else
 207         AC_MSG_RESULT([no (disabled explicitly)])
 208         USOCKLND=""
 209 fi
 210 AC_SUBST(USOCKLND)
 211 ])
 212
 213 #
 214 # LN_CONFIG_QUADRICS
 215 #
 216 # check if quadrics support is in this kernel
 217 #
 218 AC_DEFUN([LN_CONFIG_QUADRICS],
 219 [AC_MSG_CHECKING([for QsNet sources])
 220 AC_ARG_WITH([qsnet],
 221         AC_HELP_STRING([--with-qsnet=path],
 222                        [set path to qsnet source (default=$LINUX)]),
 223         [QSNET=$with_qsnet],
 224         [QSNET=$LINUX])
 225 AC_MSG_RESULT([$QSNET])
 226
 227 AC_MSG_CHECKING([if quadrics kernel headers are present])
 228 if test -d $QSNET/drivers/net/qsnet ; then
 229         AC_MSG_RESULT([yes])
 230         QSWLND="qswlnd"
 231         AC_MSG_CHECKING([for multirail EKC])
 232         if test -f $QSNET/include/elan/epcomms.h; then
 233                 AC_MSG_RESULT([supported])
 234                 QSWCPPFLAGS="-I$QSNET/include -DMULTIRAIL_EKC=1"
 235         else
 236                 AC_MSG_RESULT([not supported])
 237                 AC_MSG_ERROR([Need multirail EKC])
 238         fi
 239
 240         if test x$QSNET = x$LINUX ; then
 241                 LB_LINUX_CONFIG([QSNET],[],[
 242                         LB_LINUX_CONFIG([QSNET_MODULE],[],[
 243                                 AC_MSG_WARN([QSNET is not enabled in this kernel; not building qswlnd.])
 244                                 QSWLND=""
 245                                 QSWCPPFLAGS=""
 246                         ])
 247                 ])
 248         fi
 249 else
 250         AC_MSG_RESULT([no])
 251         QSWLND=""
 252         QSWCPPFLAGS=""
 253 fi
 254 AC_SUBST(QSWCPPFLAGS)
 255 AC_SUBST(QSWLND)
 256 ])
 257
 258 #
 259 # LN_CONFIG_GM
 260 #
 261 # check if GM support is available
 262 #
 263 AC_DEFUN([LN_CONFIG_GM],[
 264 AC_MSG_CHECKING([whether to enable GM support])
 265 AC_ARG_WITH([gm],
 266         AC_HELP_STRING([--with-gm=path-to-gm-source-tree],
 267                        [build gmlnd against path]),
 268         [
 269                 case $with_gm in
 270                 no)    ENABLE_GM=0
 271                        ;;
 272                 *)     ENABLE_GM=1
 273                        GM_SRC="$with_gm"
 274                        ;;
 275                 esac
 276         ],[
 277                 ENABLE_GM=0
 278         ])
 279 AC_ARG_WITH([gm-install],
 280         AC_HELP_STRING([--with-gm-install=path-to-gm-install-tree],
 281                        [say where GM has been installed]),
 282         [
 283                 GM_INSTALL=$with_gm_install
 284         ],[
 285                 GM_INSTALL="/opt/gm"
 286         ])
 287 if test $ENABLE_GM -eq 0; then
 288         AC_MSG_RESULT([no])
 289 else
 290         AC_MSG_RESULT([yes])
 291
 292         GMLND="gmlnd"
 293         GMCPPFLAGS="-I$GM_SRC/include -I$GM_SRC/drivers -I$GM_SRC/drivers/linux/gm"
 294
 295         if test -f $GM_INSTALL/lib/libgm.a -o \
 296                 -f $GM_INSTALL/lib64/libgm.a; then
 297                 GMLIBS="-L$GM_INSTALL/lib -L$GM_INSTALL/lib64"
 298         else
 299                 AC_MSG_ERROR([Cant find GM libraries under $GM_INSTALL])
 300         fi
 301
 302         EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 303         EXTRA_KCFLAGS="$GMCPPFLAGS -DGM_KERNEL $EXTRA_KCFLAGS"
 304
 305         AC_MSG_CHECKING([that code using GM compiles with given path])
 306         LB_LINUX_TRY_COMPILE([
 307                 #define GM_STRONG_TYPES 1
 308                 #ifdef VERSION
 309                 #undef VERSION
 310                 #endif
 311                 #include "gm.h"
 312                 #include "gm_internal.h"
 313         ],[
 314                 struct gm_port *port = NULL;
 315                 gm_recv_event_t *rxevent = gm_blocking_receive_no_spin(port);
 316                 return 0;
 317         ],[
 318                 AC_MSG_RESULT([yes])
 319         ],[
 320                 AC_MSG_RESULT([no])
 321                 AC_MSG_ERROR([Bad --with-gm path])
 322         ])
 323
 324         AC_MSG_CHECKING([that GM has gm_register_memory_ex_phys()])
 325         LB_LINUX_TRY_COMPILE([
 326                 #define GM_STRONG_TYPES 1
 327                 #ifdef VERSION
 328                 #undef VERSION
 329                 #endif
 330                 #include "gm.h"
 331                 #include "gm_internal.h"
 332         ],[
 333                 gm_status_t     gmrc;
 334                 struct gm_port *port = NULL;
 335                 gm_u64_t        phys = 0;
 336                 gm_up_t         pvma = 0;
 337
 338                 gmrc = gm_register_memory_ex_phys(port, phys, 100, pvma);
 339                 return 0;
 340         ],[
 341                 AC_MSG_RESULT([yes])
 342         ],[
 343                 AC_MSG_RESULT([no.
 344 Please patch the GM sources as follows...
 345     cd $GM_SRC
 346     patch -p0 < $PWD/lnet/klnds/gmlnd/gm-reg-phys.patch
 347 ...then rebuild and re-install them])
 348                 AC_MSG_ERROR([Can't build GM without gm_register_memory_ex_phys()])
 349         ])
 350
 351         EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 352 fi
 353 AC_SUBST(GMCPPFLAGS)
 354 AC_SUBST(GMLIBS)
 355 AC_SUBST(GMLND)
 356 ])
 357
 358
 359 #
 360 # LN_CONFIG_MX
 361 #
 362 AC_DEFUN([LN_CONFIG_MX],
 363 [AC_MSG_CHECKING([whether to enable Myrinet MX support])
 364 # set default
 365 MXPATH="/opt/mx"
 366 AC_ARG_WITH([mx],
 367        AC_HELP_STRING([--with-mx=path],
 368                       [build mxlnd against path]),
 369        [
 370                case $with_mx in
 371                yes)    ENABLEMX=2
 372                        ;;
 373                no)     ENABLEMX=0
 374                        ;;
 375                *)      MXPATH=$with_mx
 376                        ENABLEMX=3
 377                        ;;
 378                esac
 379        ],[
 380                ENABLEMX=1
 381        ])
 382 if test $ENABLEMX -eq 0; then
 383        AC_MSG_RESULT([disabled])
 384 elif test ! \( -f ${MXPATH}/include/myriexpress.h -a \
 385               -f ${MXPATH}/include/mx_kernel_api.h -a \
 386               -f ${MXPATH}/include/mx_pin.h \); then
 387        AC_MSG_RESULT([no])
 388        case $ENABLEMX in
 389        1) ;;
 390        2) AC_MSG_ERROR([Myrinet MX kernel headers not present]);;
 391        3) AC_MSG_ERROR([bad --with-mx path]);;
 392        *) AC_MSG_ERROR([internal error]);;
 393        esac
 394 else
 395        MXCPPFLAGS="-I$MXPATH/include"
 396        EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 397        EXTRA_KCFLAGS="$EXTRA_KCFLAGS $MXCPPFLAGS"
 398        MXLIBS="-L$MXPATH/lib"
 399        LB_LINUX_TRY_COMPILE([
 400                #define MX_KERNEL 1
 401                #include <mx_extensions.h>
 402                #include <myriexpress.h>
 403        ],[
 404                mx_endpoint_t   end;
 405                mx_status_t     status;
 406                mx_request_t    request;
 407                int             result;
 408
 409                mx_init();
 410                mx_open_endpoint(MX_ANY_NIC, MX_ANY_ENDPOINT, 0, NULL, 0, &end);
 411                mx_register_unexp_handler(end, (mx_unexp_handler_t) NULL, NULL);
 412                mx_wait_any(end, MX_INFINITE, 0LL, 0LL, &status, &result);
 413                mx_iconnect(end, 0LL, 0, 0, 0, NULL, &request);
 414                return 0;
 415        ],[
 416                AC_MSG_RESULT([yes])
 417                MXLND="mxlnd"
 418        ],[
 419                AC_MSG_RESULT([no])
 420                case $ENABLEMX in
 421                1) ;;
 422                2) AC_MSG_ERROR([can't compile with Myrinet MX kernel headers]);;
 423                3) AC_MSG_ERROR([can't compile with Myrinet MX headers under $MXPATH]);;
 424                *) AC_MSG_ERROR([internal error]);;
 425                esac
 426                MXLND=""
 427                MXCPPFLAGS=""
 428        ])
 429        EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 430 fi
 431 AC_SUBST(MXCPPFLAGS)
 432 AC_SUBST(MXLIBS)
 433 AC_SUBST(MXLND)
 434 ])
 435
 436
 437
 438 #
 439 # LN_CONFIG_O2IB
 440 #
 441 AC_DEFUN([LN_CONFIG_O2IB],[
 442 AC_MSG_CHECKING([whether to enable OpenIB gen2 support])
 443 # set default
 444 AC_ARG_WITH([o2ib],
 445         AC_HELP_STRING([--with-o2ib=path],
 446                        [build o2iblnd against path]),
 447         [
 448                 case $with_o2ib in
 449                 yes)    O2IBPATHS="$LINUX $LINUX/drivers/infiniband"
 450                         ENABLEO2IB=2
 451                         ;;
 452                 no)     ENABLEO2IB=0
 453                         ;;
 454                 *)      O2IBPATHS=$with_o2ib
 455                         ENABLEO2IB=3
 456                         ;;
 457                 esac
 458         ],[
 459                 O2IBPATHS="$LINUX $LINUX/drivers/infiniband"
 460                 ENABLEO2IB=1
 461         ])
 462 if test $ENABLEO2IB -eq 0; then
 463         AC_MSG_RESULT([disabled])
 464 else
 465         o2ib_found=false
 466         for O2IBPATH in $O2IBPATHS; do
 467                 if test \( -f ${O2IBPATH}/include/rdma/rdma_cm.h -a \
 468                            -f ${O2IBPATH}/include/rdma/ib_cm.h -a \
 469                            -f ${O2IBPATH}/include/rdma/ib_verbs.h -a \
 470                            -f ${O2IBPATH}/include/rdma/ib_fmr_pool.h \); then
 471                         o2ib_found=true
 472                         break
 473                 fi
 474         done
 475         if ! $o2ib_found; then
 476                 AC_MSG_RESULT([no])
 477                 case $ENABLEO2IB in
 478                         1) ;;
 479                         2) AC_MSG_ERROR([kernel OpenIB gen2 headers not present]);;
 480                         3) AC_MSG_ERROR([bad --with-o2ib path]);;
 481                         *) AC_MSG_ERROR([internal error]);;
 482                 esac
 483         else
 484                 O2IBCPPFLAGS="-I$O2IBPATH/include"
 485                 EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 486                 EXTRA_KCFLAGS="$EXTRA_KCFLAGS $O2IBCPPFLAGS"
 487                 EXTRA_LNET_INCLUDE="$O2IBCPPFLAGS $EXTRA_LNET_INCLUDE"
 488                 LB_LINUX_TRY_COMPILE([
 489                         #include <linux/version.h>
 490                         #include <linux/pci.h>
 491                         #if !HAVE_GFP_T
 492                         typedef int gfp_t;
 493                         #endif
 494                         #include <rdma/rdma_cm.h>
 495                         #include <rdma/ib_cm.h>
 496                         #include <rdma/ib_verbs.h>
 497                         #include <rdma/ib_fmr_pool.h>
 498                 ],[
 499                         struct rdma_cm_id          *cm_id;
 500                         struct rdma_conn_param      conn_param;
 501                         struct ib_device_attr       device_attr;
 502                         struct ib_qp_attr           qp_attr;
 503                         struct ib_pool_fmr          pool_fmr;
 504                         enum   ib_cm_rej_reason     rej_reason;
 505
 506                         cm_id = rdma_create_id(NULL, NULL, RDMA_PS_TCP);
 507                         return PTR_ERR(cm_id);
 508                 ],[
 509                         AC_MSG_RESULT([yes])
 510                         O2IBLND="o2iblnd"
 511                 ],[
 512                         AC_MSG_RESULT([no])
 513                         case $ENABLEO2IB in
 514                         1) ;;
 515                         2) AC_MSG_ERROR([can't compile with kernel OpenIB gen2 headers]);;
 516                         3) AC_MSG_ERROR([can't compile with OpenIB gen2 headers under $O2IBPATH]);;
 517                         *) AC_MSG_ERROR([internal error]);;
 518                         esac
 519                         O2IBLND=""
 520                         O2IBCPPFLAGS=""
 521                 ])
 522                 # we know at this point that the found OFED source is good
 523                 O2IB_SYMVER=""
 524                 if test $ENABLEO2IB -eq 3 ; then
 525                         # OFED default rpm not handle sles10 Modules.symvers name
 526                         for name in Module.symvers Modules.symvers; do
 527                                 if test -f $O2IBPATH/$name; then
 528                                         O2IB_SYMVER=$name;
 529                                         break;
 530                                 fi
 531                         done
 532                         if test -n $O2IB_SYMVER ; then
 533                                 AC_MSG_NOTICE([adding $O2IBPATH/$O2IB_SYMVER to $PWD/$SYMVERFILE])
 534                                 # strip out the existing symbols versions first
 535                                 egrep -v $(echo $(awk '{ print $2 }' $O2IBPATH/$O2IB_SYMVER) | tr ' ' '|') $PWD/$SYMVERFILE > $PWD/$SYMVERFILE.old
 536                                 cat $PWD/$SYMVERFILE.old $O2IBPATH/$O2IB_SYMVER > $PWD/$SYMVERFILE
 537                         else
 538                                 AC_MSG_ERROR([an external source tree was specified for o2iblnd however I could not find a $O2IBPATH/Module.symvers there])
 539                         fi
 540                 fi
 541
 542                 LN_CONFIG_OFED_SPEC
 543                 EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 544         fi
 545 fi
 546
 547 AC_SUBST(EXTRA_LNET_INCLUDE)
 548 AC_SUBST(O2IBCPPFLAGS)
 549 AC_SUBST(O2IBLND)
 550 ])
 551
 552 #
 553 # LN_CONFIG_OPENIB
 554 #
 555 # check for OpenIB in the kernel
 556 AC_DEFUN([LN_CONFIG_OPENIB],[
 557 AC_MSG_CHECKING([whether to enable OpenIB support])
 558 # set default
 559 OPENIBPATH="$LINUX/drivers/infiniband"
 560 AC_ARG_WITH([openib],
 561         AC_HELP_STRING([--with-openib=path],
 562                        [build openiblnd against path]),
 563         [
 564                 case $with_openib in
 565                 yes)    ENABLEOPENIB=2
 566                         ;;
 567                 no)     ENABLEOPENIB=0
 568                         ;;
 569                 *)      OPENIBPATH="$with_openib"
 570                         ENABLEOPENIB=3
 571                         ;;
 572                 esac
 573         ],[
 574                 ENABLEOPENIB=1
 575         ])
 576 if test $ENABLEOPENIB -eq 0; then
 577         AC_MSG_RESULT([disabled])
 578 elif test ! \( -f ${OPENIBPATH}/include/ts_ib_core.h -a \
 579                -f ${OPENIBPATH}/include/ts_ib_cm.h -a \
 580                -f ${OPENIBPATH}/include/ts_ib_sa_client.h \); then
 581         AC_MSG_RESULT([no])
 582         case $ENABLEOPENIB in
 583         1) ;;
 584         2) AC_MSG_ERROR([kernel OpenIB headers not present]);;
 585         3) AC_MSG_ERROR([bad --with-openib path]);;
 586         *) AC_MSG_ERROR([internal error]);;
 587         esac
 588 else
 589         case $ENABLEOPENIB in
 590         1|2) OPENIBCPPFLAGS="-I$OPENIBPATH/include -DIN_TREE_BUILD";;
 591         3)   OPENIBCPPFLAGS="-I$OPENIBPATH/include";;
 592         *)   AC_MSG_RESULT([no])
 593              AC_MSG_ERROR([internal error]);;
 594         esac
 595         OPENIBCPPFLAGS="$OPENIBCPPFLAGS -DIB_NTXRXPARAMS=4"
 596         EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 597         EXTRA_KCFLAGS="$EXTRA_KCFLAGS $OPENIBCPPFLAGS"
 598         LB_LINUX_TRY_COMPILE([
 599                 #include <ts_ib_core.h>
 600                 #include <ts_ib_cm.h>
 601                 #include <ts_ib_sa_client.h>
 602         ],[
 603                 struct ib_device_properties dev_props;
 604                 struct ib_cm_active_param   cm_active_params;
 605                 tTS_IB_CLIENT_QUERY_TID     tid;
 606                 int                         enum1 = IB_QP_ATTRIBUTE_STATE;
 607                 int                         enum2 = IB_ACCESS_LOCAL_WRITE;
 608                 int                         enum3 = IB_CQ_CALLBACK_INTERRUPT;
 609                 int                         enum4 = IB_CQ_PROVIDER_REARM;
 610                 return 0;
 611         ],[
 612                 AC_MSG_RESULT([yes])
 613                 OPENIBLND="openiblnd"
 614         ],[
 615                 AC_MSG_RESULT([no])
 616                 case $ENABLEOPENIB in
 617                 1) ;;
 618                 2) AC_MSG_ERROR([can't compile with kernel OpenIB headers]);;
 619                 3) AC_MSG_ERROR([can't compile with OpenIB headers under $OPENIBPATH]);;
 620                 *) AC_MSG_ERROR([internal error]);;
 621                 esac
 622                 OPENIBLND=""
 623                 OPENIBCPPFLAGS=""
 624         ])
 625         EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 626 fi
 627 AC_SUBST(OPENIBCPPFLAGS)
 628 AC_SUBST(OPENIBLND)
 629 ])
 630
 631 #
 632 # LN_CONFIG_CIBLND
 633 #
 634 AC_DEFUN([LN_CONFIG_CIB],[
 635 AC_MSG_CHECKING([whether to enable Cisco/TopSpin IB support])
 636 # set default
 637 CIBPATH=""
 638 CIBLND=""
 639 AC_ARG_WITH([cib],
 640         AC_HELP_STRING([--with-cib=path],
 641                        [build ciblnd against path]),
 642         [
 643                 case $with_cib in
 644                 no)     AC_MSG_RESULT([no]);;
 645                 *)      CIBPATH="$with_cib"
 646                         if test -d "$CIBPATH"; then
 647                                 AC_MSG_RESULT([yes])
 648                         else
 649                                 AC_MSG_RESULT([no])
 650                                 AC_MSG_ERROR([No directory $CIBPATH])
 651                         fi;;
 652                 esac
 653         ],[
 654                 AC_MSG_RESULT([no])
 655         ])
 656 if test -n "$CIBPATH"; then
 657         CIBCPPFLAGS="-I${CIBPATH}/ib/ts_api_ng/include -I${CIBPATH}/all/kernel_services/include -DUSING_TSAPI"
 658         CIBCPPFLAGS="$CIBCPPFLAGS -DIB_NTXRXPARAMS=3"
 659         EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 660         EXTRA_KCFLAGS="$EXTRA_KCFLAGS $CIBCPPFLAGS"
 661         LB_LINUX_TRY_COMPILE([
 662                 #include <ts_ib_core.h>
 663                 #include <ts_ib_cm.h>
 664                 #include <ts_ib_sa_client.h>
 665         ],[
 666                 struct ib_device_properties dev_props;
 667                 struct ib_cm_active_param   cm_active_params;
 668                 tTS_IB_CLIENT_QUERY_TID     tid;
 669                 int                         enum1 = TS_IB_QP_ATTRIBUTE_STATE;
 670                 int                         enum2 = TS_IB_ACCESS_LOCAL_WRITE;
 671                 int                         enum3 = TS_IB_CQ_CALLBACK_INTERRUPT;
 672                 int                         enum4 = TS_IB_CQ_PROVIDER_REARM;
 673                 return 0;
 674         ],[
 675                 CIBLND="ciblnd"
 676         ],[
 677                 AC_MSG_ERROR([can't compile ciblnd with given path])
 678                 CIBCPPFLAGS=""
 679         ])
 680         EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 681 fi
 682 AC_SUBST(CIBCPPFLAGS)
 683 AC_SUBST(CIBLND)
 684 ])
 685
 686 #
 687 # LN_CONFIG_IIB
 688 #
 689 # check for infinicon infiniband support
 690 #
 691 AC_DEFUN([LN_CONFIG_IIB],[
 692 AC_MSG_CHECKING([whether to enable Infinicon support])
 693 # set default
 694 IIBPATH="/usr/include"
 695 AC_ARG_WITH([iib],
 696         AC_HELP_STRING([--with-iib=path],
 697                        [build iiblnd against path]),
 698         [
 699                 case $with_iib in
 700                 yes)    ENABLEIIB=2
 701                         ;;
 702                 no)     ENABLEIIB=0
 703                         ;;
 704                 *)      IIBPATH="${with_iib}/include"
 705                         ENABLEIIB=3
 706                         ;;
 707                 esac
 708         ],[
 709                 ENABLEIIB=1
 710         ])
 711 if test $ENABLEIIB -eq 0; then
 712         AC_MSG_RESULT([disabled])
 713 elif test ! \( -f ${IIBPATH}/linux/iba/ibt.h \); then
 714         AC_MSG_RESULT([no])
 715         case $ENABLEIIB in
 716         1) ;;
 717         2) AC_MSG_ERROR([default Infinicon headers not present]);;
 718         3) AC_MSG_ERROR([bad --with-iib path]);;
 719         *) AC_MSG_ERROR([internal error]);;
 720         esac
 721 else
 722         IIBCPPFLAGS="-I$IIBPATH"
 723         if test $IIBPATH != "/usr/include"; then
 724                 # we need /usr/include come what may
 725                 IIBCPPFLAGS="$IIBCPPFLAGS -I/usr/include"
 726         fi
 727         EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 728         EXTRA_KCFLAGS="$EXTRA_KCFLAGS $IIBCPPFLAGS"
 729         LB_LINUX_TRY_COMPILE([
 730                 #include <linux/iba/ibt.h>
 731         ],[
 732                 IBT_INTERFACE_UNION interfaces;
 733                 FSTATUS             rc;
 734
 735                  rc = IbtGetInterfaceByVersion(IBT_INTERFACE_VERSION_2,
 736                                                &interfaces);
 737
 738                 return rc == FSUCCESS ? 0 : 1;
 739         ],[
 740                 AC_MSG_RESULT([yes])
 741                 IIBLND="iiblnd"
 742         ],[
 743                 AC_MSG_RESULT([no])
 744                 case $ENABLEIIB in
 745                 1) ;;
 746                 2) AC_MSG_ERROR([can't compile with default Infinicon headers]);;
 747                 3) AC_MSG_ERROR([can't compile with Infinicon headers under $IIBPATH]);;
 748                 *) AC_MSG_ERROR([internal error]);;
 749                 esac
 750                 IIBLND=""
 751                 IIBCPPFLAGS=""
 752         ])
 753         EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 754 fi
 755 AC_SUBST(IIBCPPFLAGS)
 756 AC_SUBST(IIBLND)
 757 ])
 758
 759 #
 760 # LN_CONFIG_VIB
 761 #
 762 # check for Voltaire infiniband support
 763 #
 764 AC_DEFUN([LN_CONFIG_VIB],
 765 [AC_MSG_CHECKING([whether to enable Voltaire IB support])
 766 VIBPATH=""
 767 AC_ARG_WITH([vib],
 768         AC_HELP_STRING([--with-vib=path],
 769                        [build viblnd against path]),
 770         [
 771                 case $with_vib in
 772                 no)     AC_MSG_RESULT([no]);;
 773                 *)      VIBPATH="${with_vib}/src/nvigor/ib-code"
 774                         if test -d "$with_vib" -a -d "$VIBPATH"; then
 775                                 AC_MSG_RESULT([yes])
 776                         else
 777                                 AC_MSG_RESULT([no])
 778                                 AC_MSG_ERROR([No directory $VIBPATH])
 779                         fi;;
 780                 esac
 781         ],[
 782                 AC_MSG_RESULT([no])
 783         ])
 784 if test -z "$VIBPATH"; then
 785         VIBLND=""
 786 else
 787         VIBCPPFLAGS="-I${VIBPATH}/include -I${VIBPATH}/cm"
 788         EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 789         EXTRA_KCFLAGS="$EXTRA_KCFLAGS $VIBCPPFLAGS"
 790         LB_LINUX_TRY_COMPILE([
 791                 #include <linux/list.h>
 792                 #include <asm/byteorder.h>
 793                 #ifdef __BIG_ENDIAN
 794                 # define CPU_BE 1
 795                 # define CPU_LE 0
 796                 #endif
 797                 #ifdef __LITTLE_ENDIAN
 798                 # define CPU_BE 0
 799                 # define CPU_LE 1
 800                 #endif
 801                 #include <vverbs.h>
 802                 #include <ib-cm.h>
 803                 #include <ibat.h>
 804         ],[
 805                 vv_hca_h_t       kib_hca;
 806                 vv_return_t      vvrc;
 807                 cm_cep_handle_t  cep;
 808                 ibat_arp_data_t  arp_data;
 809                 ibat_stat_t      ibatrc;
 810
 811                 vvrc = vv_hca_open("ANY_HCA", NULL, &kib_hca);
 812                 cep = cm_create_cep(cm_cep_transp_rc);
 813                 ibatrc = ibat_get_ib_data((uint32_t)0, (uint32_t)0,
 814                                           ibat_paths_primary, &arp_data,
 815                                           (ibat_get_ib_data_reply_fn_t)NULL,
 816                                           NULL, 0);
 817                 return 0;
 818         ],[
 819                 VIBLND="viblnd"
 820         ],[
 821                 AC_MSG_ERROR([can't compile viblnd with given path])
 822         ])
 823         EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 824 fi
 825 if test -n "$VIBLND"; then
 826         EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 827         EXTRA_KCFLAGS="$EXTRA_KCFLAGS $VIBCPPFLAGS"
 828         AC_MSG_CHECKING([if Voltaire still uses void * sg addresses])
 829         LB_LINUX_TRY_COMPILE([
 830                 #include <linux/list.h>
 831                 #include <asm/byteorder.h>
 832                 #ifdef __BIG_ENDIAN
 833                 # define CPU_BE 1
 834                 # define CPU_LE 0
 835                 #endif
 836                 #ifdef __LITTLE_ENDIAN
 837                 # define CPU_BE 0
 838                 # define CPU_LE 1
 839                 #endif
 840                 #include <vverbs.h>
 841                 #include <ib-cm.h>
 842                 #include <ibat.h>
 843         ],[
 844                 vv_scatgat_t  sg;
 845
 846                 return &sg.v_address[3] == NULL;
 847         ],[
 848                 AC_MSG_RESULT([yes])
 849                 VIBCPPFLAGS="$VIBCPPFLAGS -DIBNAL_VOIDSTAR_SGADDR=1"
 850         ],[
 851                 AC_MSG_RESULT([no])
 852         ])
 853         EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 854 fi
 855 AC_SUBST(VIBCPPFLAGS)
 856 AC_SUBST(VIBLND)
 857 ])
 858
 859 #
 860 # LN_CONFIG_RALND
 861 #
 862 # check whether to use the RapidArray lnd
 863 #
 864 AC_DEFUN([LN_CONFIG_RALND],
 865 [#### Rapid Array
 866 AC_MSG_CHECKING([if RapidArray kernel headers are present])
 867 # placeholder
 868 RACPPFLAGS="-I${LINUX}/drivers/xd1/include"
 869 EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 870 EXTRA_KCFLAGS="$EXTRA_KCFLAGS $RACPPFLAGS"
 871 LB_LINUX_TRY_COMPILE([
 872         #include <linux/types.h>
 873         #include <rapl.h>
 874 ],[
 875         RAP_RETURN          rc;
 876         RAP_PVOID           dev_handle;
 877
 878         rc = RapkGetDeviceByIndex(0, NULL, &dev_handle);
 879
 880         return rc == RAP_SUCCESS ? 0 : 1;
 881 ],[
 882         AC_MSG_RESULT([yes])
 883         RALND="ralnd"
 884 ],[
 885         AC_MSG_RESULT([no])
 886         RALND=""
 887         RACPPFLAGS=""
 888 ])
 889 EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 890 AC_SUBST(RACPPFLAGS)
 891 AC_SUBST(RALND)
 892 ])
 893
 894
 895
 896 #
 897 # LN_PROG_LINUX
 898 #
 899 # LNet linux kernel checks
 900 #
 901 AC_DEFUN([LN_PROG_LINUX],
 902 [
 903 LN_CONFIG_AFFINITY
 904 LN_CONFIG_BACKOFF
 905 LN_CONFIG_QUADRICS
 906 LN_CONFIG_GM
 907 LN_CONFIG_OPENIB
 908 LN_CONFIG_CIB
 909 LN_CONFIG_VIB
 910 LN_CONFIG_IIB
 911 LN_CONFIG_O2IB
 912 LN_CONFIG_RALND
 913 LN_CONFIG_PTLLND
 914 LN_CONFIG_MX
 915 ])
 916
 917 #
 918 # LN_PROG_DARWIN
 919 #
 920 # Darwin checks
 921 #
 922 AC_DEFUN([LN_PROG_DARWIN],
 923 [LB_DARWIN_CHECK_FUNCS([get_preemption_level])
 924 ])
 925
 926 #
 927 # LN_PATH_DEFAULTS
 928 #
 929 # default paths for installed files
 930 #
 931 AC_DEFUN([LN_PATH_DEFAULTS],
 932 [
 933 ])
 934
 935 #
 936 # LN_CONFIGURE
 937 #
 938 # other configure checks
 939 #
 940 AC_DEFUN([LN_CONFIGURE],
 941 [# lnet/utils/portals.c
 942 AC_CHECK_HEADERS([netdb.h netinet/tcp.h asm/types.h endian.h sys/ioctl.h])
 943 AC_CHECK_FUNCS([gethostbyname socket connect])
 944
 945 # lnet/utils/debug.c
 946 AC_CHECK_HEADERS([linux/version.h])
 947
 948 AC_CHECK_TYPE([spinlock_t],
 949         [AC_DEFINE(HAVE_SPINLOCK_T, 1, [spinlock_t is defined])],
 950         [],
 951         [#include <linux/spinlock.h>])
 952
 953 # lnet/utils/wirecheck.c
 954 AC_CHECK_FUNCS([strnlen])
 955
 956 # --------  Check for required packages  --------------
 957
 958 #
 959 # LC_CONFIG_READLINE
 960 #
 961 # Build with readline
 962 #
 963 AC_MSG_CHECKING([whether to enable readline support])
 964 AC_ARG_ENABLE(readline,
 965         AC_HELP_STRING([--disable-readline],
 966                         [disable readline support]),
 967         [],[enable_readline='yes'])
 968 AC_MSG_RESULT([$enable_readline])
 969
 970 # -------- check for readline if enabled ----
 971 if test x$enable_readline = xyes ; then
 972         LIBS_save="$LIBS"
 973         LIBS="-lncurses $LIBS"
 974         AC_CHECK_LIB([readline],[readline],[
 975         LIBREADLINE="-lreadline -lncurses"
 976         AC_DEFINE(HAVE_LIBREADLINE, 1, [readline library is available])
 977         ],[
 978         LIBREADLINE=""
 979         ])
 980         LIBS="$LIBS_save"
 981 else
 982         LIBREADLINE=""
 983 fi
 984 AC_SUBST(LIBREADLINE)
 985
 986 # -------- enable acceptor libwrap (TCP wrappers) support? -------
 987 AC_MSG_CHECKING([if libwrap support is requested])
 988 AC_ARG_ENABLE([libwrap],
 989         AC_HELP_STRING([--enable-libwrap], [use TCP wrappers]),
 990         [case "${enableval}" in
 991                 yes) enable_libwrap=yes ;;
 992                 no) enable_libwrap=no ;;
 993                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-libwrap) ;;
 994         esac],[enable_libwrap=no])
 995 AC_MSG_RESULT([$enable_libwrap])
 996 if test x$enable_libwrap = xyes ; then
 997         LIBWRAP="-lwrap"
 998         AC_DEFINE(HAVE_LIBWRAP, 1, [libwrap support is requested])
 999 else
1000         LIBWRAP=""
1001 fi
1002 AC_SUBST(LIBWRAP)
1003
1004 # ----------------------------------------
1005 # some tests for catamount-like systems
1006 # ----------------------------------------
1007 AC_ARG_ENABLE([sysio_init],
1008         AC_HELP_STRING([--disable-sysio-init],
1009                 [call sysio init functions when initializing liblustre]),
1010         [],[enable_sysio_init=yes])
1011 AC_MSG_CHECKING([whether to initialize libsysio])
1012 AC_MSG_RESULT([$enable_sysio_init])
1013 if test x$enable_sysio_init != xno ; then
1014         AC_DEFINE([INIT_SYSIO], 1, [call sysio init functions])
1015 fi
1016
1017 AC_ARG_ENABLE([urandom],
1018         AC_HELP_STRING([--disable-urandom],
1019                 [disable use of /dev/urandom for liblustre]),
1020         [],[enable_urandom=yes])
1021 AC_MSG_CHECKING([whether to use /dev/urandom for liblustre])
1022 AC_MSG_RESULT([$enable_urandom])
1023 if test x$enable_urandom != xno ; then
1024         AC_DEFINE([LIBLUSTRE_USE_URANDOM], 1, [use /dev/urandom for random data])
1025 fi
1026
1027 # -------- check for -lcap support ----
1028 if test x$enable_liblustre = xyes ; then
1029         AC_CHECK_LIB([cap], [cap_get_proc],
1030                 [
1031                         CAP_LIBS="-lcap"
1032                         AC_DEFINE([HAVE_LIBCAP], 1, [use libcap])
1033                 ],
1034                 [
1035                         CAP_LIBS=""
1036                 ])
1037         AC_SUBST(CAP_LIBS)
1038
1039 fi
1040
1041 LN_CONFIG_MAX_PAYLOAD
1042 LN_CONFIG_UPTLLND
1043 LN_CONFIG_USOCKLND
1044 ])
1045
1046 #
1047 # LN_CONDITIONALS
1048 #
1049 # AM_CONDITOINAL defines for lnet
1050 #
1051 AC_DEFUN([LN_CONDITIONALS],
1052 [AM_CONDITIONAL(BUILD_QSWLND, test x$QSWLND = "xqswlnd")
1053 AM_CONDITIONAL(BUILD_GMLND, test x$GMLND = "xgmlnd")
1054 AM_CONDITIONAL(BUILD_MXLND, test x$MXLND = "xmxlnd")
1055 AM_CONDITIONAL(BUILD_O2IBLND, test x$O2IBLND = "xo2iblnd")
1056 AM_CONDITIONAL(BUILD_OPENIBLND, test x$OPENIBLND = "xopeniblnd")
1057 AM_CONDITIONAL(BUILD_CIBLND, test x$CIBLND = "xciblnd")
1058 AM_CONDITIONAL(BUILD_IIBLND, test x$IIBLND = "xiiblnd")
1059 AM_CONDITIONAL(BUILD_VIBLND, test x$VIBLND = "xviblnd")
1060 AM_CONDITIONAL(BUILD_RALND, test x$RALND = "xralnd")
1061 AM_CONDITIONAL(BUILD_PTLLND, test x$PTLLND = "xptllnd")
1062 AM_CONDITIONAL(BUILD_UPTLLND, test x$UPTLLND = "xptllnd")
1063 AM_CONDITIONAL(BUILD_USOCKLND, test x$USOCKLND = "xusocklnd")
1064 ])
1065
1066 #
1067 # LN_CONFIG_FILES
1068 #
1069 # files that should be generated with AC_OUTPUT
1070 #
1071 AC_DEFUN([LN_CONFIG_FILES],
1072 [AC_CONFIG_FILES([
1073 lnet/Kernelenv
1074 lnet/Makefile
1075 lnet/autoMakefile
1076 lnet/autoconf/Makefile
1077 lnet/doc/Makefile
1078 lnet/include/Makefile
1079 lnet/include/lnet/Makefile
1080 lnet/include/lnet/linux/Makefile
1081 lnet/klnds/Makefile
1082 lnet/klnds/autoMakefile
1083 lnet/klnds/gmlnd/Makefile
1084 lnet/klnds/mxlnd/autoMakefile
1085 lnet/klnds/mxlnd/Makefile
1086 lnet/klnds/gmlnd/autoMakefile
1087 lnet/klnds/openiblnd/Makefile
1088 lnet/klnds/openiblnd/autoMakefile
1089 lnet/klnds/o2iblnd/Makefile
1090 lnet/klnds/o2iblnd/autoMakefile
1091 lnet/klnds/ciblnd/Makefile
1092 lnet/klnds/ciblnd/autoMakefile
1093 lnet/klnds/iiblnd/Makefile
1094 lnet/klnds/iiblnd/autoMakefile
1095 lnet/klnds/viblnd/Makefile
1096 lnet/klnds/viblnd/autoMakefile
1097 lnet/klnds/qswlnd/Makefile
1098 lnet/klnds/qswlnd/autoMakefile
1099 lnet/klnds/ralnd/Makefile
1100 lnet/klnds/ralnd/autoMakefile
1101 lnet/klnds/socklnd/Makefile
1102 lnet/klnds/socklnd/autoMakefile
1103 lnet/klnds/ptllnd/Makefile
1104 lnet/klnds/ptllnd/autoMakefile
1105 lnet/lnet/Makefile
1106 lnet/lnet/autoMakefile
1107 lnet/selftest/Makefile
1108 lnet/selftest/autoMakefile
1109 lnet/ulnds/Makefile
1110 lnet/ulnds/autoMakefile
1111 lnet/ulnds/socklnd/Makefile
1112 lnet/ulnds/ptllnd/Makefile
1113 lnet/utils/Makefile
1114 ])
1115 case $lb_target_os in
1116         darwin)
1117                 AC_CONFIG_FILES([
1118 lnet/include/lnet/darwin/Makefile
1119 ])
1120                 ;;
1121 esac
1122 ])