lnet/autoconf/lustre-lnet.m4

   1 #
   2 # LN_CONFIG_MAX_PAYLOAD
   3 #
   4 # configure maximum payload
   5 #
   6 AC_DEFUN([LN_CONFIG_MAX_PAYLOAD], [
   7 AC_MSG_CHECKING([for non-default maximum LNET payload])
   8 AC_ARG_WITH([max-payload-mb],
   9         AC_HELP_STRING([--with-max-payload-mb=MBytes],
  10                 [set maximum lnet payload in MBytes]),
  11         [
  12                 AC_MSG_RESULT([$with_max_payload_mb])
  13                 CONFIG_LNET_MAX_PAYLOAD_MB=$with_max_payload_mb
  14                 CONFIG_LNET_MAX_PAYLOAD="(($with_max_payload_mb)<<20)"
  15         ], [
  16                 AC_MSG_RESULT([no])
  17                 CONFIG_LNET_MAX_PAYLOAD="LNET_MTU"
  18         ])
  19 AC_DEFINE_UNQUOTED(CONFIG_LNET_MAX_PAYLOAD, $CONFIG_LNET_MAX_PAYLOAD,
  20         [Max LNET payload])
  21 ]) # LN_CONFIG_MAX_PAYLOAD
  22
  23 #
  24 # LN_CHECK_GCC_VERSION
  25 #
  26 # Check compiler version
  27 #
  28 AC_DEFUN([LN_CHECK_GCC_VERSION], [
  29 AC_MSG_CHECKING([compiler version])
  30 PTL_CC_VERSION=`$CC --version | awk '/^gcc/{print $ 3}'`
  31 PTL_MIN_CC_VERSION="3.2.2"
  32 v2n() {
  33         awk -F. '{printf "%d\n", (($ 1)*100+($ 2))*100+($ 3)}'
  34 }
  35 if test -z "$PTL_CC_VERSION" -o \
  36         $(echo $PTL_CC_VERSION | v2n) -ge $(echo $PTL_MIN_CC_VERSION | v2n); then
  37         AC_MSG_RESULT([ok])
  38 else
  39         AC_MSG_RESULT([Buggy compiler found])
  40         AC_MSG_ERROR([Need gcc version >= $PTL_MIN_CC_VERSION])
  41 fi
  42 ]) # LN_CHECK_GCC_VERSION
  43
  44 #
  45 # LN_CONFIG_AFFINITY
  46 #
  47 # check if cpu affinity is available/wanted
  48 #
  49 AC_DEFUN([LN_CONFIG_AFFINITY], [
  50 AC_MSG_CHECKING([whether to enable CPU affinity support])
  51 AC_ARG_ENABLE([affinity],
  52         AC_HELP_STRING([--disable-affinity],
  53                 [disable process/irq affinity]),
  54         [], [enable_affinity="yes"])
  55 AC_MSG_RESULT([$enable_affinity])
  56 AS_IF([test "x$enable_affinity" = xyes], [
  57         LB_CHECK_COMPILE([if Linux kernel has cpu affinity support],
  58         set_cpus_allowed_ptr, [
  59                 #include <linux/sched.h>
  60         ],[
  61                 struct task_struct *t;
  62                 #if HAVE_CPUMASK_T
  63                 cpumask_t     m;
  64                 #else
  65                 unsigned long m;
  66                 #endif
  67                 set_cpus_allowed_ptr(t, &m);
  68         ],[
  69                 AC_DEFINE(CPU_AFFINITY, 1,
  70                         [kernel has cpu affinity support])
  71         ])
  72 ])
  73 ]) # LN_CONFIG_AFFINITY
  74
  75 #
  76 # LN_CONFIG_BACKOFF
  77 #
  78 # check if tunable tcp backoff is available/wanted
  79 #
  80 AC_DEFUN([LN_CONFIG_BACKOFF], [
  81 AC_MSG_CHECKING([whether to enable tunable backoff TCP support])
  82 AC_ARG_ENABLE([backoff],
  83         AC_HELP_STRING([--disable-backoff],
  84                 [disable socknal tunable backoff]),
  85         [], [enable_backoff="yes"])
  86 AC_MSG_RESULT([$enable_backoff])
  87 AS_IF([test "x$enable_backoff" = xyes], [
  88         AC_MSG_CHECKING([if Linux kernel has tunable backoff TCP support])
  89         AS_IF([grep -c TCP_BACKOFF $LINUX/include/linux/tcp.h >/dev/null], [
  90                 AC_MSG_RESULT([yes])
  91                 AC_DEFINE(SOCKNAL_BACKOFF, 1, [use tunable backoff TCP])
  92                 AS_IF([grep rto_max $LINUX/include/linux/tcp.h | grep -q __u16 >/dev/null],
  93                         [AC_DEFINE(SOCKNAL_BACKOFF_MS, 1,
  94                                 [tunable backoff TCP in ms])])
  95         ], [
  96                 AC_MSG_RESULT([no])
  97         ])
  98 ])
  99 ]) # LN_CONFIG_BACKOFF
 100
 101 #
 102 # LN_CONFIG_DLC
 103 #
 104 # Configure dlc if enabled
 105 #
 106 # if libyaml is set (IE libyaml installed) and enable_dlc = yes then build
 107 # dlc other wise (IE if libyaml is not set or enable_dlc = no) then don't
 108 # build dlc.
 109 #
 110 AC_DEFUN([LN_CONFIG_DLC], [
 111         AC_CHECK_LIB([yaml],  [yaml_parser_initialize],[
 112                 LIBYAML="libyaml"],[
 113                 LIBYAML=""],[-lm])
 114         AC_MSG_CHECKING([whether to enable dlc])
 115         AC_ARG_ENABLE([dlc],
 116                 AC_HELP_STRING([--disable-dlc],
 117                         [disable building dlc]),
 118                         [], [enable_dlc="yes"])
 119         USE_DLC=""
 120         AS_IF([test "x$enable_dlc" = xyes],
 121                 [AS_IF([test "x$LIBYAML" = xlibyaml], [
 122                         USE_DLC="yes"
 123                         AC_MSG_RESULT([yes])
 124                 ], [
 125                         AC_MSG_RESULT([no (libyaml not present)])
 126                 ])
 127         ], [
 128                 AC_MSG_RESULT([no])
 129         ])
 130         AC_SUBST(USE_DLC)
 131 ])
 132
 133 #
 134 # LN_CONFIG_O2IB
 135 #
 136 # If current OFED installed (assume with "ofed_info") and devel
 137 # headers are not found, error because we assume OFED infiniband
 138 # driver needs to be used and we must configure/build with it.
 139 # Current OFED headers detection mechanism allow for non-standard
 140 # prefix but relies on "ofed_info" command and on "%prefix/openib"
 141 # link (both are ok for 1.5.x and 3.x versions), and should work
 142 # for both source and DKMS builds.
 143 #
 144 AC_DEFUN([LN_CONFIG_O2IB], [
 145 AC_MSG_CHECKING([whether to use Compat RDMA])
 146 AC_ARG_WITH([o2ib],
 147         AC_HELP_STRING([--with-o2ib=[yes|no|<path>]],
 148                 [build o2iblnd against path]),
 149         [], [with_o2ib="yes"])
 150
 151 case $with_o2ib in
 152         yes)    AS_IF([which ofed_info 2>/dev/null], [
 153                         O2IBPATHS=$(ofed_info | egrep -w 'compat-rdma-devel|kernel-ib-devel|ofa_kernel-devel' | xargs rpm -ql | grep '/openib$')
 154                         AS_IF([test -z "$O2IBPATHS"], [
 155                                 AC_MSG_ERROR([
 156 You seem to have an OFED installed but have not installed it's devel package.
 157 If you still want to build Lustre for your OFED I/B stack, you need to install its devel headers RPM.
 158 Instead, if you want to build Lustre for your kernel's built-in I/B stack rather than your installed OFED stack, either remove the OFED package(s) or use --with-o2ib=no.
 159                                              ])
 160                         ])
 161                         AS_IF([test $(echo $O2IBPATHS | wc -w) -ge 2], [
 162                                 AC_MSG_ERROR([
 163 It appears that you have multiple OFED versions installed.
 164 If you still want to build Lustre for your OFED I/B stack, you need to install a single version with its devel headers RPM.
 165 Instead, if you want to build Lustre for your kernel's built-in I/B stack rather than your installed OFED stack, either remove the OFED package(s) or use --with-o2ib=no.
 166                                              ])
 167                         ])
 168                         OFED="yes"
 169                 ], [
 170                         O2IBPATHS="$LINUX $LINUX/drivers/infiniband"
 171                 ])
 172                 ENABLEO2IB="yes"
 173                 ;;
 174         no)     ENABLEO2IB="no"
 175                 ;;
 176         *)      O2IBPATHS=$with_o2ib
 177                 ENABLEO2IB="withpath"
 178                 OFED="yes"
 179                 ;;
 180 esac
 181
 182 AS_IF([test $ENABLEO2IB = "no"], [
 183         AC_MSG_RESULT([no])
 184 ], [
 185         o2ib_found=false
 186         for O2IBPATH in $O2IBPATHS; do
 187                 AS_IF([test \( -f ${O2IBPATH}/include/rdma/rdma_cm.h -a \
 188                            -f ${O2IBPATH}/include/rdma/ib_cm.h -a \
 189                            -f ${O2IBPATH}/include/rdma/ib_verbs.h -a \
 190                            -f ${O2IBPATH}/include/rdma/ib_fmr_pool.h \)], [
 191                         o2ib_found=true
 192                         break
 193                 ])
 194         done
 195         if ! $o2ib_found; then
 196                 AC_MSG_RESULT([no])
 197                 case $ENABLEO2IB in
 198                         "yes") AC_MSG_ERROR([no OFED nor kernel OpenIB gen2 headers present]) ;;
 199                         "withpath") AC_MSG_ERROR([bad --with-o2ib path]) ;;
 200                         *) AC_MSG_ERROR([internal error]) ;;
 201                 esac
 202         else
 203                 COMPAT_AUTOCONF=""
 204                 compatrdma_found=false
 205                 if test -f ${O2IBPATH}/include/linux/compat-2.6.h; then
 206                         AC_MSG_RESULT([yes])
 207                         compatrdma_found=true
 208                         AC_DEFINE(HAVE_COMPAT_RDMA, 1, [compat rdma found])
 209                         EXTRA_OFED_CONFIG="$EXTRA_OFED_CONFIG -include ${O2IBPATH}/include/linux/compat-2.6.h"
 210                         if test -f "$O2IBPATH/include/linux/compat_autoconf.h"; then
 211                                 COMPAT_AUTOCONF="$O2IBPATH/include/linux/compat_autoconf.h"
 212                         fi
 213                 else
 214                         AC_MSG_RESULT([no])
 215                 fi
 216                 if ! $compatrdma_found; then
 217                         if test -f "$O2IBPATH/config.mk"; then
 218                                 . "$O2IBPATH/config.mk"
 219                         elif test -f "$O2IBPATH/ofed_patch.mk"; then
 220                                 . "$O2IBPATH/ofed_patch.mk"
 221                         fi
 222                 elif test -z "$COMPAT_AUTOCONF"; then
 223                         # Depreciated checks
 224                         if test "x$RHEL_KERNEL" = xyes; then
 225                                 RHEL_MAJOR=$(awk '/ RHEL_MAJOR / { print [$]3 }' $LINUX_OBJ/include/$VERSION_HDIR/version.h)
 226                                 I=$(awk '/ RHEL_MINOR / { print [$]3 }' $LINUX_OBJ/include/$VERSION_HDIR/version.h)
 227                                 while test "$I" -ge 0; do
 228                                         EXTRA_OFED_INCLUDE="$EXTRA_OFED_INCLUDE -DCONFIG_COMPAT_RHEL_${RHEL_MAJOR}_$I"
 229                                         I=$(($I-1))
 230                                 done
 231                         elif test "x$SUSE_KERNEL" = xyes; then
 232                                 SP=$(grep PATCHLEVEL /etc/SuSE-release | sed -e 's/.*= *//')
 233                                 EXTRA_OFED_INCLUDE="$EXTRA_OFED_INCLUDE -DCONFIG_COMPAT_SLES_11_$SP"
 234                         fi
 235                 fi
 236
 237                 AC_MSG_CHECKING([whether to use any OFED backport headers])
 238                 if test -n "$BACKPORT_INCLUDES"; then
 239                         AC_MSG_RESULT([yes])
 240                         OFED_BACKPORT_PATH="$O2IBPATH/${BACKPORT_INCLUDES/*\/kernel_addons/kernel_addons}/"
 241                         EXTRA_OFED_INCLUDE="-I$OFED_BACKPORT_PATH $EXTRA_OFED_INCLUDE"
 242                 else
 243                         AC_MSG_RESULT([no])
 244                 fi
 245
 246                 O2IBLND=""
 247                 O2IBPATH=$(readlink --canonicalize $O2IBPATH)
 248                 EXTRA_OFED_INCLUDE="$EXTRA_OFED_INCLUDE -I$O2IBPATH/include"
 249                 LB_CHECK_COMPILE([whether to enable OpenIB gen2 support],
 250                 openib_gen2_support, [
 251                         #ifdef HAVE_COMPAT_RDMA
 252                         #undef PACKAGE_NAME
 253                         #undef PACKAGE_TARNAME
 254                         #undef PACKAGE_VERSION
 255                         #undef PACKAGE_STRING
 256                         #undef PACKAGE_BUGREPORT
 257                         #undef PACKAGE_URL
 258                         #include <linux/compat-2.6.h>
 259                         #endif
 260                         #include <linux/version.h>
 261                         #include <linux/pci.h>
 262                         #include <linux/gfp.h>
 263                         #include <rdma/rdma_cm.h>
 264                         #include <rdma/ib_cm.h>
 265                         #include <rdma/ib_verbs.h>
 266                         #include <rdma/ib_fmr_pool.h>
 267                 ],[
 268                         struct rdma_cm_id      *cm_idi __attribute__ ((unused));
 269                         struct rdma_conn_param  conn_param __attribute__ ((unused));
 270                         struct ib_device_attr   device_attr __attribute__ ((unused));
 271                         struct ib_qp_attr       qp_attr __attribute__ ((unused));
 272                         struct ib_pool_fmr      pool_fmr __attribute__ ((unused));
 273                         enum   ib_cm_rej_reason rej_reason __attribute__ ((unused));
 274                         rdma_destroy_id(NULL);
 275                 ],[
 276                         O2IBLND="o2iblnd"
 277                 ],[
 278                         case $ENABLEO2IB in
 279                         "yes") AC_MSG_ERROR([can't compile with OpenIB gen2 headers]) ;;
 280                         "withpath") AC_MSG_ERROR([can't compile with OpenIB gen2 headers under $O2IBPATH]) ;;
 281                         *) AC_MSG_ERROR([internal error]) ;;
 282                         esac
 283                 ])
 284                 # we know at this point that the found OFED source is good
 285                 O2IB_SYMVER=""
 286                 if test $ENABLEO2IB = "withpath" -o "x$OFED" = "xyes" ; then
 287                         # OFED default rpm not handle sles10 Modules.symvers name
 288                         for name in Module.symvers Modules.symvers; do
 289                                 if test -f $O2IBPATH/$name; then
 290                                         O2IB_SYMVER=$name;
 291                                         break;
 292                                 fi
 293                         done
 294                         if test -n "$O2IB_SYMVER"; then
 295                                 AC_MSG_NOTICE([adding $O2IBPATH/$O2IB_SYMVER to Symbol Path])
 296                                 EXTRA_SYMBOLS="$EXTRA_SYMBOLS $O2IBPATH/$O2IB_SYMVER"
 297                                 AC_SUBST(EXTRA_SYMBOLS)
 298                         else
 299                                 AC_MSG_ERROR([an external source tree was, either specified or detected, for o2iblnd however I could not find a $O2IBPATH/Module.symvers there])
 300                         fi
 301                 fi
 302
 303                 LB_CHECK_COMPILE([if Linux kernel has kthread_worker],
 304                 linux_kthread_worker, [
 305                         #ifdef HAVE_COMPAT_RDMA
 306                         #undef PACKAGE_NAME
 307                         #undef PACKAGE_TARNAME
 308                         #undef PACKAGE_VERSION
 309                         #undef PACKAGE_STRING
 310                         #undef PACKAGE_BUGREPORT
 311                         #undef PACKAGE_URL
 312                         #include <linux/compat-2.6.h>
 313                         #endif
 314                         #include <linux/kthread.h>
 315                 ],[
 316                         struct kthread_work     *kth_wrk __attribute__ ((unused));
 317                         flush_kthread_work(kth_wrk);
 318                 ],[
 319                         AC_DEFINE(HAVE_KTHREAD_WORK, 1, [kthread_worker found])
 320                         if test -z "$COMPAT_AUTOCONF"; then
 321                                 EXTRA_OFED_INCLUDE="$EXTRA_OFED_INCLUDE -DCONFIG_COMPAT_IS_KTHREAD"
 322                         fi
 323                 ])
 324         fi
 325 ])
 326 AC_SUBST(EXTRA_OFED_CONFIG)
 327 AC_SUBST(EXTRA_OFED_INCLUDE)
 328 AC_SUBST(O2IBLND)
 329 AC_SUBST(O2IBPATH)
 330 AC_SUBST(ENABLEO2IB)
 331
 332 AS_IF([test $ENABLEO2IB != "no"], [
 333         # In RHEL 6.2, rdma_create_id() takes the queue-pair type as a fourth argument
 334         LB_CHECK_COMPILE([if 'rdma_create_id' wants four args],
 335         rdma_create_id_4args, [
 336                 #ifdef HAVE_COMPAT_RDMA
 337                 #undef PACKAGE_NAME
 338                 #undef PACKAGE_TARNAME
 339                 #undef PACKAGE_VERSION
 340                 #undef PACKAGE_STRING
 341                 #undef PACKAGE_BUGREPORT
 342                 #undef PACKAGE_URL
 343                 #include <linux/compat-2.6.h>
 344                 #endif
 345                 #include <rdma/rdma_cm.h>
 346         ],[
 347                 rdma_create_id(NULL, NULL, 0, 0);
 348         ],[
 349                 AC_DEFINE(HAVE_RDMA_CREATE_ID_4ARG, 1,
 350                         [rdma_create_id wants 4 args])
 351         ])
 352
 353         # 4.4 added network namespace parameter for rdma_create_id()
 354         LB_CHECK_COMPILE([if 'rdma_create_id' wants five args],
 355         rdma_create_id_5args, [
 356                 #ifdef HAVE_COMPAT_RDMA
 357                 #undef PACKAGE_NAME
 358                 #undef PACKAGE_TARNAME
 359                 #undef PACKAGE_VERSION
 360                 #undef PACKAGE_STRING
 361                 #undef PACKAGE_BUGREPORT
 362                 #undef PACKAGE_URL
 363                 #include <linux/compat-2.6.h>
 364                 #endif
 365                 #include <rdma/rdma_cm.h>
 366         ],[
 367                 rdma_create_id(NULL, NULL, NULL, 0, 0);
 368         ],[
 369                 AC_DEFINE(HAVE_RDMA_CREATE_ID_5ARG, 1,
 370                         [rdma_create_id wants 5 args])
 371         ])
 372
 373         # 4.2 introduced struct ib_cq_init_attr which is used
 374         # by ib_create_cq(). Note some OFED stacks only keep
 375         # their headers in sync with latest kernels but not
 376         # the functionality which means for infiniband testing
 377         # we need to always test functionality testings.
 378         LB_CHECK_COMPILE([if 'struct ib_cq_init_attr' is used],
 379         ib_cq_init_attr, [
 380                 #ifdef HAVE_COMPAT_RDMA
 381                 #undef PACKAGE_NAME
 382                 #undef PACKAGE_TARNAME
 383                 #undef PACKAGE_VERSION
 384                 #undef PACKAGE_STRING
 385                 #undef PACKAGE_BUGREPORT
 386                 #undef PACKAGE_URL
 387                 #include <linux/compat-2.6.h>
 388                 #endif
 389                 #include <rdma/ib_verbs.h>
 390         ],[
 391                 struct ib_cq_init_attr cq_attr;
 392
 393                 ib_create_cq(NULL, NULL, NULL, NULL, &cq_attr);
 394         ],[
 395                 AC_DEFINE(HAVE_IB_CQ_INIT_ATTR, 1,
 396                         [struct ib_cq_init_attr is used by ib_create_cq])
 397         ])
 398
 399         # 4.3 removed ib_alloc_fast_reg_mr()
 400         LB_CHECK_COMPILE([if 'ib_alloc_fast_reg_mr' exists],
 401         ib_alloc_fast_reg_mr, [
 402                 #ifdef HAVE_COMPAT_RDMA
 403                 #undef PACKAGE_NAME
 404                 #undef PACKAGE_TARNAME
 405                 #undef PACKAGE_VERSION
 406                 #undef PACKAGE_STRING
 407                 #undef PACKAGE_BUGREPORT
 408                 #undef PACKAGE_URL
 409                 #include <linux/compat-2.6.h>
 410                 #endif
 411                 #include <rdma/ib_verbs.h>
 412         ],[
 413                 ib_alloc_fast_reg_mr(NULL, 0);
 414         ],[
 415                 AC_DEFINE(HAVE_IB_ALLOC_FAST_REG_MR, 1,
 416                         [ib_alloc_fast_reg_mr is defined])
 417         ])
 418
 419         # In v4.4 Linux kernel,
 420         # commit e622f2f4ad2142d2a613a57fb85f8cf737935ef5
 421         # split up struct ib_send_wr so that all non-trivial verbs
 422         # use their own structure which embedds struct ib_send_wr.
 423         LB_CHECK_COMPILE([if 'struct ib_rdma_wr' is defined],
 424         ib_rdma_wr, [
 425                 #ifdef HAVE_COMPAT_RDMA
 426                 #undef PACKAGE_NAME
 427                 #undef PACKAGE_TARNAME
 428                 #undef PACKAGE_VERSION
 429                 #undef PACKAGE_STRING
 430                 #undef PACKAGE_BUGREPORT
 431                 #undef PACKAGE_URL
 432                 #include <linux/compat-2.6.h>
 433                 #endif
 434                 #include <rdma/ib_verbs.h>
 435         ],[
 436                 struct ib_rdma_wr *wr __attribute__ ((unused));
 437
 438                 wr = rdma_wr(NULL);
 439         ],[
 440                 AC_DEFINE(HAVE_IB_RDMA_WR, 1,
 441                         [struct ib_rdma_wr is defined])
 442         ])
 443
 444         # new fast registration API introduced in 4.4
 445         LB_CHECK_COMPILE([if 'ib_map_mr_sg' exists],
 446         ib_map_mr_sg, [
 447                 #ifdef HAVE_COMPAT_RDMA
 448                 #undef PACKAGE_NAME
 449                 #undef PACKAGE_TARNAME
 450                 #undef PACKAGE_VERSION
 451                 #undef PACKAGE_STRING
 452                 #undef PACKAGE_BUGREPORT
 453                 #undef PACKAGE_URL
 454                 #include <linux/compat-2.6.h>
 455                 #endif
 456                 #include <rdma/ib_verbs.h>
 457         ],[
 458                 ib_map_mr_sg(NULL, NULL, 0, 0);
 459         ],[
 460                 AC_DEFINE(HAVE_IB_MAP_MR_SG, 1,
 461                         [ib_map_mr_sg exists])
 462         ])
 463 ]) # ENABLEO2IB != "no"
 464 ]) # LN_CONFIG_O2IB
 465
 466 #
 467 # LN_CONFIG_GNILND
 468 #
 469 # check whether to use the Gemini Network Interface lnd
 470 #
 471 AC_DEFUN([LN_CONFIG_GNILND], [
 472 AC_MSG_CHECKING([whether to enable GNI lnd])
 473 AC_ARG_ENABLE([gni],
 474         AC_HELP_STRING([--enable-gni],
 475                 [enable GNI lnd]),
 476         [], [enable_gni="no"])
 477 AC_MSG_RESULT([$enable_gni])
 478
 479 AS_IF([test "x$enable_gni" = xyes], [
 480         # GNICPPFLAGS was set in spec file
 481         EXTRA_KCFLAGS_save="$EXTRA_KCFLAGS"
 482         EXTRA_KCFLAGS="$EXTRA_KCFLAGS $GNICPPFLAGS"
 483         LB_CHECK_COMPILE([if GNI kernel headers are present],
 484         GNI_header, [
 485                 #include <linux/types.h>
 486                 #include <gni_pub.h>
 487         ],[
 488                 gni_cdm_handle_t kgni_domain;
 489                 gni_return_t     rc;
 490                 int              rrc;
 491                 rc = gni_cdm_create(0, 1, 1, 0, &kgni_domain);
 492                 rrc = (rc == GNI_RC_SUCCESS) ? 0 : 1;
 493                 return rrc;
 494         ],[
 495                 GNILND="gnilnd"
 496         ],[
 497                 AC_MSG_ERROR([can't compile gnilnd with given GNICPPFLAGS: $GNICPPFLAGS])
 498         ])
 499         # at this point, we have gnilnd basic support,
 500         # now check for extra features
 501         LB_CHECK_COMPILE([to use RCA in gnilnd],
 502         RCA_gnilnd, [
 503                 #include <linux/types.h>
 504                 #include <gni_pub.h>
 505                 #include <krca_lib.h>
 506         ],[
 507                 gni_cdm_handle_t kgni_domain;
 508                 gni_return_t     rc;
 509                 krca_ticket_t    ticket = KRCA_NULL_TICKET;
 510                 int              rrc;
 511                 __u32            nid = 0, nic_addr;
 512                 rc = gni_cdm_create(0, 1, 1, 0, &kgni_domain);
 513                 rrc = (rc == GNI_RC_SUCCESS) ? 0 : 1;
 514                 rrc += krca_nid_to_nicaddrs(nid, 1, &nic_addr);
 515                 rrc += krca_register(&ticket, RCA_MAKE_SERVICE_INDEX(RCA_IO_CLASS, 9), 99, 0);
 516                 return rrc;
 517         ],[
 518                 GNICPPFLAGS="$GNICPPFLAGS -DGNILND_USE_RCA=1"
 519         ])
 520         EXTRA_KCFLAGS="$EXTRA_KCFLAGS_save"
 521 ])
 522 AC_SUBST(GNICPPFLAGS)
 523 AC_SUBST(GNILND)
 524 ]) # LN_CONFIG_GNILND
 525
 526 #
 527 # LN_CONFIG_SK_SLEEP
 528 #
 529 # 2.6.35 kernel has sk_sleep function
 530 #
 531 AC_DEFUN([LN_CONFIG_SK_SLEEP], [
 532 LB_CHECK_COMPILE([if Linux kernel has 'sk_sleep'],
 533 sk_sleep, [
 534         #ifdef HAVE_COMPAT_RDMA
 535         #undef PACKAGE_NAME
 536         #undef PACKAGE_TARNAME
 537         #undef PACKAGE_VERSION
 538         #undef PACKAGE_STRING
 539         #undef PACKAGE_BUGREPORT
 540         #undef PACKAGE_URL
 541         #include <linux/compat-2.6.h>
 542         #endif
 543         #include <net/sock.h>
 544 ],[
 545         sk_sleep(NULL);
 546 ],[
 547         AC_DEFINE(HAVE_SK_SLEEP, 1,
 548                   [kernel has sk_sleep])
 549 ])
 550 ]) # LN_CONFIG_SK_SLEEP
 551
 552 #
 553 # LN_CONFIG_TCP_SENDPAGE
 554 #
 555 # 2.6.36 tcp_sendpage() first parameter is 'struct sock' instead of 'struct socket'.
 556 #
 557 AC_DEFUN([LN_CONFIG_TCP_SENDPAGE], [
 558 tmp_flags="$EXTRA_KCFLAGS"
 559 EXTRA_KCFLAGS="-Werror"
 560 LB_CHECK_COMPILE([if 'tcp_sendpage' first parameter is socket],
 561 tcp_sendpage_socket, [
 562         #ifdef HAVE_COMPAT_RDMA
 563         #undef PACKAGE_NAME
 564         #undef PACKAGE_TARNAME
 565         #undef PACKAGE_VERSION
 566         #undef PACKAGE_STRING
 567         #undef PACKAGE_BUGREPORT
 568         #undef PACKAGE_URL
 569         #include <linux/compat-2.6.h>
 570         #endif
 571         #include <linux/net.h>
 572         #include <net/tcp.h>
 573 ],[
 574         tcp_sendpage((struct socket*)0, NULL, 0, 0, 0);
 575 ],[
 576         AC_DEFINE(HAVE_TCP_SENDPAGE_USE_SOCKET, 1,
 577                 [tcp_sendpage use socket as first parameter])
 578 ])
 579 EXTRA_KCFLAGS="$tmp_flags"
 580 ]) # LN_CONFIG_TCP_SENDPAGE
 581
 582 #
 583 # LN_CONFIG_SK_DATA_READY
 584 #
 585 # 3.15 for struct sock the *sk_data_ready() field only takes one argument now
 586 #
 587 AC_DEFUN([LN_CONFIG_SK_DATA_READY], [
 588 tmp_flags="$EXTRA_KCFLAGS"
 589 EXTRA_KCFLAGS="-Werror"
 590 LB_CHECK_COMPILE([if 'sk_data_ready' takes only one argument],
 591 sk_data_ready, [
 592         #ifdef HAVE_COMPAT_RDMA
 593         #undef PACKAGE_NAME
 594         #undef PACKAGE_TARNAME
 595         #undef PACKAGE_VERSION
 596         #undef PACKAGE_STRING
 597         #undef PACKAGE_BUGREPORT
 598         #undef PACKAGE_URL
 599         #include <linux/compat-2.6.h>
 600         #endif
 601         #include <linux/net.h>
 602         #include <net/sock.h>
 603 ],[
 604         ((struct sock *)0)->sk_data_ready(NULL);
 605 ],[
 606         AC_DEFINE(HAVE_SK_DATA_READY_ONE_ARG, 1,
 607                 [sk_data_ready uses only one argument])
 608 ])
 609 EXTRA_KCFLAGS="$tmp_flags"
 610 ]) # LN_CONFIG_SK_DATA_READY
 611
 612 #
 613 # LN_CONFIG_IB_INC_RKEY
 614 #
 615 AC_DEFUN([LN_CONFIG_IB_INC_RKEY], [
 616 tmp_flags="$EXTRA_KCFLAGS"
 617 EXTRA_KCFLAGS="-Werror"
 618 LB_CHECK_COMPILE([if function 'ib_inc_rkey' is defined],
 619 ib_inc_rkey, [
 620         #ifdef HAVE_COMPAT_RDMA
 621         #undef PACKAGE_NAME
 622         #undef PACKAGE_TARNAME
 623         #undef PACKAGE_VERSION
 624         #undef PACKAGE_STRING
 625         #undef PACKAGE_BUGREPORT
 626         #undef PACKAGE_URL
 627         #include <linux/compat-2.6.h>
 628         #endif
 629         #include <rdma/ib_verbs.h>
 630 ],[
 631         (void)ib_inc_rkey(0);
 632 ],[
 633         AC_DEFINE(HAVE_IB_INC_RKEY, 1,
 634                   [function ib_inc_rkey exist])
 635 ])
 636 EXTRA_KCFLAGS="$tmp_flags"
 637 ]) # LN_CONFIG_IB_INC_RKEY
 638
 639 #
 640 # LN_PROG_LINUX
 641 #
 642 # LNet linux kernel checks
 643 #
 644 AC_DEFUN([LN_PROG_LINUX], [
 645 AC_MSG_NOTICE([LNet kernel checks
 646 ==============================================================================])
 647
 648 LN_CONFIG_AFFINITY
 649 LN_CONFIG_BACKOFF
 650 LN_CONFIG_O2IB
 651 LN_CONFIG_GNILND
 652 LN_CONFIG_IB_INC_RKEY
 653 # 2.6.35
 654 LN_CONFIG_SK_SLEEP
 655 # 2.6.36
 656 LN_CONFIG_TCP_SENDPAGE
 657 # 3.15
 658 LN_CONFIG_SK_DATA_READY
 659 ]) # LN_PROG_LINUX
 660
 661 #
 662 # LN_PATH_DEFAULTS
 663 #
 664 # default paths for installed files
 665 #
 666 AC_DEFUN([LN_PATH_DEFAULTS], [
 667 ]) # LN_PATH_DEFAULTS
 668
 669 #
 670 # LN_CONFIGURE
 671 #
 672 # other configure checks
 673 #
 674 AC_DEFUN([LN_CONFIGURE], [
 675 AC_MSG_NOTICE([LNet core checks
 676 ==============================================================================])
 677
 678 # lnet/utils/portals.c
 679 AC_CHECK_HEADERS([netdb.h])
 680 AC_CHECK_FUNCS([gethostbyname])
 681
 682 # lnet/utils/wirecheck.c
 683 AC_CHECK_FUNCS([strnlen])
 684
 685 # --------  Check for required packages  --------------
 686
 687 AC_MSG_CHECKING([whether to enable 'efence' debugging support])
 688 AC_ARG_ENABLE(efence,
 689         AC_HELP_STRING([--enable-efence],
 690                 [use efence library]),
 691         [], [enable_efence="no"])
 692 AC_MSG_RESULT([$enable_efence])
 693
 694 LIBEFENCE=""
 695 AS_IF([test "$enable_efence" = yes], [
 696         LIBEFENCE="-lefence"
 697         AC_DEFINE(HAVE_LIBEFENCE, 1,
 698                 [libefence support is requested])
 699 ])
 700 AC_SUBST(LIBEFENCE)
 701
 702 LN_CONFIG_MAX_PAYLOAD
 703 LN_CONFIG_DLC
 704 ]) # LN_CONFIGURE
 705
 706 #
 707 # LN_CONDITIONALS
 708 #
 709 # AM_CONDITIONAL defines for lnet
 710 #
 711 AC_DEFUN([LN_CONDITIONALS], [
 712 AM_CONDITIONAL(BUILD_O2IBLND,    test x$O2IBLND = "xo2iblnd")
 713 AM_CONDITIONAL(BUILD_GNILND,     test x$GNILND  = "xgnilnd")
 714 AM_CONDITIONAL(BUILD_DLC,        test x$USE_DLC = "xyes")
 715 ]) # LN_CONDITIONALS
 716
 717 #
 718 # LN_CONFIG_FILES
 719 #
 720 # files that should be generated with AC_OUTPUT
 721 #
 722 AC_DEFUN([LN_CONFIG_FILES], [
 723 AC_CONFIG_FILES([
 724 lnet/Makefile
 725 lnet/autoMakefile
 726 lnet/autoconf/Makefile
 727 lnet/doc/Makefile
 728 lnet/include/Makefile
 729 lnet/include/lnet/Makefile
 730 lnet/klnds/Makefile
 731 lnet/klnds/autoMakefile
 732 lnet/klnds/o2iblnd/Makefile
 733 lnet/klnds/o2iblnd/autoMakefile
 734 lnet/klnds/gnilnd/Makefile
 735 lnet/klnds/gnilnd/autoMakefile
 736 lnet/klnds/socklnd/Makefile
 737 lnet/klnds/socklnd/autoMakefile
 738 lnet/lnet/Makefile
 739 lnet/lnet/autoMakefile
 740 lnet/selftest/Makefile
 741 lnet/selftest/autoMakefile
 742 lnet/utils/Makefile
 743 lnet/utils/lnetconfig/Makefile
 744 ])
 745 ]) # LN_CONFIG_FILES