libcfs/autoconf/lustre-libcfs.m4

   1 #
   2 # LIBCFS_CONFIG_CDEBUG
   3 #
   4 # whether to enable various libcfs debugs (CDEBUG, ENTRY/EXIT, LASSERT, etc.)
   5 #
   6 AC_DEFUN([LIBCFS_CONFIG_CDEBUG], [
   7 AC_MSG_CHECKING([whether to enable CDEBUG, CWARN])
   8 AC_ARG_ENABLE([libcfs_cdebug],
   9         AC_HELP_STRING([--disable-libcfs-cdebug],
  10                 [disable libcfs CDEBUG, CWARN]),
  11         [], [enable_libcfs_cdebug="yes"])
  12 AC_MSG_RESULT([$enable_libcfs_cdebug])
  13 AS_IF([test "x$enable_libcfs_cdebug" = xyes],
  14         [AC_DEFINE(CDEBUG_ENABLED, 1, [enable libcfs CDEBUG, CWARN])])
  15
  16 AC_MSG_CHECKING([whether to enable ENTRY/EXIT])
  17 AC_ARG_ENABLE([libcfs_trace],
  18         AC_HELP_STRING([--disable-libcfs-trace],
  19                 [disable libcfs ENTRY/EXIT]),
  20         [], [enable_libcfs_trace="yes"])
  21 AC_MSG_RESULT([$enable_libcfs_trace])
  22 AS_IF([test "x$enable_libcfs_trace" = xyes],
  23         [AC_DEFINE(CDEBUG_ENTRY_EXIT, 1, [enable libcfs ENTRY/EXIT])])
  24
  25 AC_MSG_CHECKING([whether to enable LASSERT, LASSERTF])
  26 AC_ARG_ENABLE([libcfs_assert],
  27         AC_HELP_STRING([--disable-libcfs-assert],
  28                 [disable libcfs LASSERT, LASSERTF]),
  29         [], [enable_libcfs_assert="yes"])
  30 AC_MSG_RESULT([$enable_libcfs_assert])
  31 AS_IF([test x$enable_libcfs_assert = xyes],
  32         [AC_DEFINE(LIBCFS_DEBUG, 1, [enable libcfs LASSERT, LASSERTF])])
  33 ]) # LIBCFS_CONFIG_CDEBUG
  34
  35 #
  36 # LIBCFS_CONFIG_PANIC_DUMPLOG
  37 #
  38 # check if tunable panic_dumplog is wanted
  39 #
  40 AC_DEFUN([LIBCFS_CONFIG_PANIC_DUMPLOG], [
  41 AC_MSG_CHECKING([whether to use tunable 'panic_dumplog' support])
  42 AC_ARG_ENABLE([panic_dumplog],
  43         AC_HELP_STRING([--enable-panic_dumplog],
  44                 [enable panic_dumplog]),
  45         [], [enable_panic_dumplog="no"])
  46 AC_MSG_RESULT([$enable_panic_dumplog])
  47 AS_IF([test "x$enable_panic_dumplog" = xyes],
  48         [AC_DEFINE(LNET_DUMP_ON_PANIC, 1, [use dumplog on panic])])
  49 ]) # LIBCFS_CONFIG_PANIC_DUMPLOG
  50
  51 #
  52 # Kernel version 3.11 introduced ktime_get_ts64
  53 #
  54 AC_DEFUN([LIBCFS_KTIME_GET_TS64],[
  55 LB_CHECK_COMPILE([does function 'ktime_get_ts64' exist],
  56 ktime_get_ts64, [
  57         #include <linux/hrtimer.h>
  58         #include <linux/ktime.h>
  59 ],[
  60         struct timespec64 *ts = NULL;
  61
  62         ktime_get_ts64(ts);
  63 ],[
  64         AC_DEFINE(HAVE_KTIME_GET_TS64, 1,
  65                 ['ktime_get_ts64' is available])
  66 ])
  67 ]) # LIBCFS_KTIME_GET_TS64
  68
  69 #
  70 # Kernel version 3.12-rc4 commit c2d816443ef30 added prepare_to_wait_event()
  71 #
  72 AC_DEFUN([LIBCFS_PREPARE_TO_WAIT_EVENT],[
  73 LB_CHECK_COMPILE([does function 'prepare_to_wait_event' exist],
  74 prepare_to_wait_event, [
  75         #include <linux/wait.h>
  76 ],[
  77         prepare_to_wait_event(NULL, NULL, 0);
  78 ],[
  79         AC_DEFINE(HAVE_PREPARE_TO_WAIT_EVENT, 1,
  80                 ['prepare_to_wait_event' is available])
  81 ])
  82 ]) # LIBCFS_PREPARE_TO_WAIT_EVENT
  83
  84 #
  85 # Linux kernel 3.12 introduced struct kernel_param_ops
  86 # This has been backported to all lustre supported
  87 # clients except RHEL6. We have to handle the differences.
  88 #
  89 AC_DEFUN([LIBCFS_KERNEL_PARAM_OPS],[
  90 LB_CHECK_COMPILE([does 'struct kernel_param_ops' exist],
  91 kernel_param_ops, [
  92         #include <linux/module.h>
  93 ],[
  94         struct kernel_param_ops ops;
  95
  96         ops.set = NULL;
  97 ],[
  98         AC_DEFINE(HAVE_KERNEL_PARAM_OPS, 1,
  99                 ['struct kernel_param_ops' is available])
 100 ])
 101 ]) # LIBCFS_KERNEL_PARAM_OPS
 102
 103 #
 104 # Kernel version 3.12 introduced ktime_add
 105 #
 106 AC_DEFUN([LIBCFS_KTIME_ADD],[
 107 LB_CHECK_COMPILE([does function 'ktime_add' exist],
 108 ktime_add, [
 109         #include <linux/hrtimer.h>
 110         #include <linux/ktime.h>
 111 ],[
 112         ktime_t start = ktime_set(0, 0);
 113         ktime_t end = start;
 114         ktime_t total;
 115
 116         total = ktime_add(start, end);
 117 ],[
 118         AC_DEFINE(HAVE_KTIME_ADD, 1,
 119                 [ktime_add is available])
 120 ])
 121 ]) # LIBCFS_KTIME_ADD
 122
 123 #
 124 # Kernel version 3.12 introduced ktime_after
 125 #
 126 AC_DEFUN([LIBCFS_KTIME_AFTER],[
 127 LB_CHECK_COMPILE([does function 'ktime_after' exist],
 128 ktime_after, [
 129         #include <linux/hrtimer.h>
 130         #include <linux/ktime.h>
 131 ],[
 132         ktime_t start = ktime_set(0, 0);
 133         ktime_t end = start;
 134
 135         ktime_after(start, end);
 136 ],[
 137         AC_DEFINE(HAVE_KTIME_AFTER, 1,
 138                 [ktime_after is available])
 139 ])
 140 ]) # LIBCFS_KTIME_AFTER
 141
 142 #
 143 # Kernel version 3.12 introduced ktime_before
 144 # See linux commit 67cb9366ff5f99868100198efba5ca88aaa6ad25
 145 #
 146 AC_DEFUN([LIBCFS_KTIME_BEFORE],[
 147 LB_CHECK_COMPILE([does function 'ktime_before' exist],
 148 ktime_before, [
 149         #include <linux/hrtimer.h>
 150         #include <linux/ktime.h>
 151 ],[
 152         ktime_t start = ktime_set(0, 0);
 153         ktime_t end = start;
 154
 155         ktime_before(start, end);
 156 ],[
 157         AC_DEFINE(HAVE_KTIME_BEFORE, 1,
 158                 [ktime_before is available])
 159 ])
 160 ]) # LIBCFS_KTIME_BEFORE
 161
 162 #
 163 # Kernel version 3.12 introduced ktime_compare
 164 #
 165 AC_DEFUN([LIBCFS_KTIME_COMPARE],[
 166 LB_CHECK_COMPILE([does function 'ktime_compare' exist],
 167 ktime_compare, [
 168         #include <linux/hrtimer.h>
 169         #include <linux/ktime.h>
 170 ],[
 171         ktime_t start = ktime_set(0, 0);
 172         ktime_t end = start;
 173
 174         ktime_compare(start, end);
 175 ],[
 176         AC_DEFINE(HAVE_KTIME_COMPARE, 1,
 177                 [ktime_compare is available])
 178 ])
 179 ]) # LIBCFS_KTIME_COMPARE
 180
 181 #
 182 # FC19 3.12 kernel struct shrinker change
 183 #
 184 AC_DEFUN([LIBCFS_SHRINKER_COUNT],[
 185 LB_CHECK_COMPILE([shrinker has 'count_objects'],
 186 shrinker_count_objects, [
 187         #include <linux/mmzone.h>
 188         #include <linux/shrinker.h>
 189 ],[
 190         struct shrinker shrinker;
 191
 192         shrinker.count_objects = NULL;
 193 ],[
 194         AC_DEFINE(HAVE_SHRINKER_COUNT, 1,
 195                 [shrinker has count_objects member])
 196 ])
 197 ]) # LIBCFS_SHRINKER_COUNT
 198
 199 #
 200 # LIBCFS_IOV_ITER_HAS_TYPE
 201 #
 202 # kernel 3.15-rc4 commit 71d8e532b1549a478e6a6a8a44f309d050294d00
 203 # start adding the tag to iov_iter
 204 #
 205 AC_DEFUN([LIBCFS_IOV_ITER_HAS_TYPE], [
 206 tmp_flags="$EXTRA_KCFLAGS"
 207 EXTRA_KCFLAGS="-Werror"
 208 LB_CHECK_COMPILE([if iov_iter has member type],
 209 iov_iter_has_type_member, [
 210         #include <linux/uio.h>
 211 ],[
 212         struct iov_iter iter = { .type = ITER_KVEC };
 213         (void)iter;
 214 ],[
 215         AC_DEFINE(HAVE_IOV_ITER_HAS_TYPE_MEMBER, 1,
 216                 [if iov_iter has member type])
 217 ])
 218 EXTRA_KCFLAGS="$tmp_flags"
 219 ]) # LIBCFS_IOV_ITER_HAS_TYPE
 220
 221 #
 222 # LIBCFS_HAVE_NS_TO_TIMESPEC64
 223 #
 224 # Kernel version 4.16-rc3 commit a84d1169164b274f13b97a23ff235c000efe3b49
 225 # introduced struct __kernel_old_timeval
 226 #
 227 AC_DEFUN([LIBCFS_HAVE_NS_TO_TIMESPEC64],[
 228 LB_CHECK_COMPILE([does 'ns_to_timespec64()' exist],
 229 kernel_old_timeval, [
 230         #include <linux/time.h>
 231 ],[
 232         struct timespec64 kts;
 233
 234         kts = ns_to_timespec64(0);
 235 ],[
 236         AC_DEFINE(HAVE_NS_TO_TIMESPEC64, 1,
 237                 [ns_to_timespec64() is available])
 238 ])
 239 ]) # LIBCFS_HAVE_NS_TO_TIMESPEC64
 240
 241 #
 242 # Kernel version 3.17 changed hlist_add_after to
 243 # hlist_add_behind
 244 #
 245 AC_DEFUN([LIBCFS_HLIST_ADD_AFTER],[
 246 LB_CHECK_COMPILE([does function 'hlist_add_after' exist],
 247 hlist_add_after, [
 248         #include <linux/list.h>
 249 ],[
 250         hlist_add_after(NULL, NULL);
 251 ],[
 252         AC_DEFINE(HAVE_HLIST_ADD_AFTER, 1,
 253                 [hlist_add_after is available])
 254 ])
 255 ]) # LIBCFS_HLIST_ADD_AFTER
 256
 257 #
 258 # Kernel version 3.17 introduced struct timespec64
 259 #
 260 AC_DEFUN([LIBCFS_TIMESPEC64],[
 261 LB_CHECK_COMPILE([does 'struct timespec64' exist],
 262 timespec64, [
 263         #include <linux/time.h>
 264 ],[
 265         struct timespec64 ts;
 266
 267         ts.tv_sec = 0;
 268         ts.tv_nsec = 0;
 269 ],[
 270         AC_DEFINE(HAVE_TIMESPEC64, 1,
 271                 ['struct timespec64' is available])
 272 ])
 273 ]) # LIBCFS_TIMESPEC64
 274
 275 #
 276 # Kernel version 3.17 introduced ktime_get_real_ts64
 277 #
 278 AC_DEFUN([LIBCFS_KTIME_GET_REAL_TS64],[
 279 LB_CHECK_COMPILE([does function 'ktime_get_real_ts64' exist],
 280 ktime_get_real_ts64, [
 281         #include <linux/ktime.h>
 282 ],[
 283         struct timespec64 *ts = NULL;
 284
 285         ktime_get_real_ts64(ts);
 286 ],[
 287         AC_DEFINE(HAVE_KTIME_GET_REAL_TS64, 1,
 288                 ['ktime_get_real_ts64' is available])
 289 ])
 290 ]) # LIBCFS_KTIME_GET_REAL_TS64
 291
 292 #
 293 # Kernel version 3.17 introduced ktime_get_real_seconds
 294 #
 295 AC_DEFUN([LIBCFS_KTIME_GET_REAL_SECONDS],[
 296 LB_CHECK_COMPILE([does function 'ktime_get_real_seconds' exist],
 297 ktime_get_real_seconds, [
 298         #include <linux/hrtimer.h>
 299         #include <linux/ktime.h>
 300 ],[
 301         time64_t now;
 302
 303         now = ktime_get_real_seconds();
 304 ],[
 305         AC_DEFINE(HAVE_KTIME_GET_REAL_SECONDS, 1,
 306                 ['ktime_get_real_seconds' is available])
 307 ])
 308 ]) # LIBCFS_KTIME_GET_REAL_SECONDS
 309
 310 #
 311 # Kernel version 3.17 created ktime_get_ns wrapper
 312 #
 313 AC_DEFUN([LIBCFS_KTIME_GET_NS],[
 314 LB_CHECK_COMPILE([does function 'ktime_get_ns' exist],
 315 ktime_get_ns, [
 316         #include <linux/hrtimer.h>
 317         #include <linux/ktime.h>
 318 ],[
 319         u64 nanoseconds;
 320
 321         nanoseconds = ktime_get_ns();
 322 ],[],[
 323         AC_DEFINE(NEED_KTIME_GET_NS, 1,
 324                 ['ktime_get_ns' is not available])
 325 ])
 326 ]) # LIBCFS_KTIME_GET_NS
 327
 328 #
 329 # Kernel version 3.17 created ktime_get_real_ns wrapper
 330 #
 331 AC_DEFUN([LIBCFS_KTIME_GET_REAL_NS],[
 332 LB_CHECK_COMPILE([does function 'ktime_get_real_ns' exist],
 333 ktime_get_real_ns, [
 334         #include <linux/hrtimer.h>
 335         #include <linux/ktime.h>
 336 ],[
 337         u64 nanoseconds;
 338
 339         nanoseconds = ktime_get_real_ns();
 340 ],[],[
 341         AC_DEFINE(NEED_KTIME_GET_REAL_NS, 1,
 342                 ['ktime_get_real_ns' is not available])
 343 ])
 344 ]) # LIBCFS_KTIME_GET_REAL_NS
 345
 346 #
 347 # Kernel version 3.17 introduced ktime_to_timespec64
 348 #
 349 AC_DEFUN([LIBCFS_KTIME_TO_TIMESPEC64],[
 350 LB_CHECK_COMPILE([does function 'ktime_to_timespec64' exist],
 351 ktime_to_timespec64, [
 352         #include <linux/hrtimer.h>
 353         #include <linux/ktime.h>
 354 ],[
 355         ktime_t now = ktime_set(0, 0);
 356         struct timespec64 ts;
 357
 358         ts = ktime_to_timespec64(now);
 359 ],[
 360         AC_DEFINE(HAVE_KTIME_TO_TIMESPEC64, 1,
 361                 ['ktime_to_timespec64' is available])
 362 ])
 363 ]) # LIBCFS_KTIME_TO_TIMESPEC64
 364
 365 #
 366 # Kernel version 3.17 introduced timespec64_sub
 367 #
 368 AC_DEFUN([LIBCFS_TIMESPEC64_SUB],[
 369 LB_CHECK_COMPILE([does function 'timespec64_sub' exist],
 370 timespec64_sub, [
 371         #include <linux/time.h>
 372 ],[
 373         struct timespec64 later = { }, earlier = { }, diff;
 374
 375         diff = timespec64_sub(later, earlier);
 376 ],[
 377         AC_DEFINE(HAVE_TIMESPEC64_SUB, 1,
 378                 ['timespec64_sub' is available])
 379 ])
 380 ]) # LIBCFS_TIMESPEC64_SUB
 381
 382 #
 383 # Kernel version 3.17 introduced timespec64_to_ktime
 384 #
 385 AC_DEFUN([LIBCFS_TIMESPEC64_TO_KTIME],[
 386 LB_CHECK_COMPILE([does function 'timespec64_to_ktime' exist],
 387 timespec64_to_ktime, [
 388         #include <linux/ktime.h>
 389 ],[
 390         struct timespec64 ts;
 391         ktime_t now;
 392
 393         now = timespec64_to_ktime(ts);
 394 ],[
 395         AC_DEFINE(HAVE_TIMESPEC64_TO_KTIME, 1,
 396                 ['timespec64_to_ktime' is available])
 397 ])
 398 ]) # LIBCFS_TIMESPEC64_TO_KTIME
 399
 400 #
 401 # Kernel version 3.19 introduced ktime_get_seconds
 402 #
 403 AC_DEFUN([LIBCFS_KTIME_GET_SECONDS],[
 404 LB_CHECK_COMPILE([does function 'ktime_get_seconds' exist],
 405 ktime_get_seconds, [
 406         #include <linux/ktime.h>
 407 ],[
 408         time64_t now;
 409
 410         now = ktime_get_seconds();
 411 ],[
 412         AC_DEFINE(HAVE_KTIME_GET_SECONDS, 1,
 413                 ['ktime_get_seconds' is available])
 414 ])
 415 ]) # LIBCFS_KTIME_GET_SECONDS
 416
 417 #
 418 # Kernel version 4.0 commit 41fbf3b39d5eca01527338b4d0ee15ee1ae1023c
 419 # introduced the helper function ktime_ms_delta.
 420 #
 421 AC_DEFUN([LIBCFS_KTIME_MS_DELTA],[
 422 LB_CHECK_COMPILE([does function 'ktime_ms_delta' exist],
 423 ktime_ms_delta, [
 424         #include <linux/ktime.h>
 425 ],[
 426         ktime_t start = ktime_set(0, 0);
 427         ktime_t end = start;
 428
 429         ktime_ms_delta(start, end);
 430 ],[
 431         AC_DEFINE(HAVE_KTIME_MS_DELTA, 1,
 432                 ['ktime_ms_delta' is available])
 433 ])
 434 ]) # LIBCFS_KTIME_MS_DELTA
 435
 436 #
 437 # Kernel version 4.1 commit b51d23e4e9fea6f264d39535c2a62d1f51e7ccc3
 438 # create per module locks which added kernel_param_[un]lock(). Older
 439 # kernels you have to use __kernel_param_[un]lock(). In that case its
 440 # a global lock for all modules but that is okay since its a rare event.
 441 #
 442 AC_DEFUN([LIBCFS_KERNEL_PARAM_LOCK],[
 443 LB_CHECK_COMPILE([does function 'kernel_param_[un]lock' exist],
 444 kernel_param_lock, [
 445         #include <linux/moduleparam.h>
 446 ],[
 447         kernel_param_lock(NULL);
 448         kernel_param_unlock(NULL);
 449 ],[
 450         AC_DEFINE(HAVE_KERNEL_PARAM_LOCK, 1,
 451                 ['kernel_param_[un]lock' is available])
 452 ])
 453 ]) # LIBCFS_KERNEL_PARAM_LOCK
 454
 455 #
 456 # Kernel version 4.2 changed topology_thread_cpumask
 457 # to topology_sibling_cpumask
 458 #
 459 AC_DEFUN([LIBCFS_HAVE_TOPOLOGY_SIBLING_CPUMASK],[
 460 LB_CHECK_COMPILE([does function 'topology_sibling_cpumask' exist],
 461 topology_sibling_cpumask, [
 462         #include <linux/topology.h>
 463 ],[
 464         const struct cpumask *mask;
 465
 466         mask = topology_sibling_cpumask(0);
 467 ],[
 468         AC_DEFINE(HAVE_TOPOLOGY_SIBLING_CPUMASK, 1,
 469                 [topology_sibling_cpumask is available])
 470 ])
 471 ]) # LIBCFS_HAVE_TOPOLOGY_SIBLING_CPUMASK
 472
 473 #
 474 # Kernel version 4.4 commit ef951599074ba4fad2d0efa0a977129b41e6d203
 475 # introduced kstrtobool and kstrtobool_from_user.
 476 #
 477 AC_DEFUN([LIBCFS_KSTRTOBOOL_FROM_USER], [
 478 LB_CHECK_COMPILE([if Linux kernel has 'kstrtobool_from_user'],
 479 kstrtobool_from_user, [
 480         #include <linux/kernel.h>
 481 ],[
 482         bool result;
 483         return kstrtobool_from_user(NULL, 0, &result);
 484 ],[
 485         AC_DEFINE(HAVE_KSTRTOBOOL_FROM_USER, 1,
 486                 [kernel has kstrtobool_from_user])
 487 ])
 488 ]) # LIBCFS_KSTRTOBOOL_FROM_USER
 489
 490 #
 491 # Kernel version 4.5-rc1 commit d12481bc58fba89427565f8592e88446ec084a24
 492 # added crypto hash helpers
 493 #
 494 AC_DEFUN([LIBCFS_CRYPTO_HASH_HELPERS], [
 495 LB_CHECK_COMPILE([does crypto hash helper functions exist],
 496 crypto_hash_helpers, [
 497         #include <crypto/hash.h>
 498 ],[
 499         crypto_ahash_alg_name(NULL);
 500         crypto_ahash_driver_name(NULL);
 501 ],[
 502         AC_DEFINE(HAVE_CRYPTO_HASH_HELPERS, 1,
 503                 [crypto hash helper functions are available])
 504 ])
 505 ]) # LIBCFS_CRYPTO_HASH_HELPERS
 506
 507 #
 508 # Kernel version 4.5-rc1 commit 3502cad73c4bbf8f6365d539e814159275252c59
 509 # introduced rhashtable_replace_fast
 510 #
 511 AC_DEFUN([LIBCFS_RHASHTABLE_REPLACE], [
 512 LB_CHECK_COMPILE([if 'rhashtable_replace_fast' exists],
 513 rhashtable_replace_fast, [
 514         #include <linux/rhashtable.h>
 515 ],[
 516         const struct rhashtable_params params = { 0 };
 517
 518         rhashtable_replace_fast(NULL, NULL, NULL, params);
 519 ],[
 520         AC_DEFINE(HAVE_RHASHTABLE_REPLACE, 1,
 521                 [rhashtable_replace_fast() is available])
 522 ])
 523 ]) # LIBCFS_RHASHTABLE_REPLACE
 524
 525 #
 526 # Kernel version 4.5-rc3 commit 2fe829aca9d7bed5fd6b49c6a1452e5e486b6cc3dd
 527 # made kset_find_obj() exportable to modules
 528 #
 529 AC_DEFUN([LIBCFS_EXPORT_KSET_FIND_OBJ], [
 530 LB_CHECK_EXPORT([kset_find_obj], [lib/kobject.c],
 531         [AC_DEFINE(HAVE_KSET_FIND_OBJ, 1,
 532                 [kset_find_obj is exported by the kernel])])
 533 ]) # LIBCFS_EXPORT_KSET_FIND_OBJ
 534
 535 #
 536 # Kernel version 4.6+ commit ef703f49a6c5b909a85149bb6625c4ed0d697186
 537 # fixed the brokenness of hash_64(). The fix removed GOLDEN_RATIO_PRIME_64
 538 # since it was a poor prime value.
 539 #
 540 AC_DEFUN([LIBCFS_BROKEN_HASH_64], [
 541 LB_CHECK_COMPILE([kernel has fixed hash_64()],
 542 broken_hash_64, [
 543         #include <linux/hash.h>
 544 ],[
 545         int tmp = GOLDEN_RATIO_PRIME_64;
 546 ],[
 547         AC_DEFINE(HAVE_BROKEN_HASH_64, 1, [kernel hash_64() is broken])
 548 ])
 549 ]) # LIBCFS_BROKEN_HASH_64
 550
 551 #
 552 # LIBCFS_STACKTRACE_OPS_ADDRESS_RETURN_INT
 553 #
 554 # linux 4.6 kernel changed stacktrace_ops address to return an int
 555 #
 556 AC_DEFUN([LIBCFS_STACKTRACE_OPS_ADDRESS_RETURN_INT], [
 557 LB_CHECK_COMPILE([if 'struct stacktrace_ops' address function returns an int],
 558 stacktrace_ops_address_return_int, [
 559         #include <asm/stacktrace.h>
 560 ],[
 561         int rc;
 562
 563         rc = ((struct stacktrace_ops *)0)->address(NULL, 0, 0);
 564 ],[
 565         AC_DEFINE(STACKTRACE_OPS_ADDRESS_RETURN_INT, 1,
 566                 ['struct stacktrace_ops' address function returns an int])
 567 ])
 568 ]) # LIBCFS_STACKTRACE_OPS_ADDRESS_RETURN_INT
 569
 570 #
 571 # Kernel version 4.6 removed both struct task_struct and struct mm_struct
 572 # arguments to get_user_pages
 573 #
 574 AC_DEFUN([LIBCFS_GET_USER_PAGES_6ARG], [
 575 LB_CHECK_COMPILE([if 'get_user_pages()' takes 6 arguments],
 576 get_user_pages_6arg, [
 577         #include <linux/mm.h>
 578 ],[
 579         int rc;
 580
 581         rc = get_user_pages(0, 0, 0, 0, NULL, NULL);
 582 ],[
 583         AC_DEFINE(HAVE_GET_USER_PAGES_6ARG, 1,
 584                 [get_user_pages takes 6 arguments])
 585 ])
 586 ]) # LIBCFS_GET_USER_PAGES_6ARG
 587
 588 #
 589 # LIBCFS_STRINGHASH
 590 #
 591 # 4.6 kernel created stringhash.h which moved stuff out of dcache.h
 592 # commit f4bcbe792b8f434e32487cff9d9e30ab45a3ce02
 593 #
 594 AC_DEFUN([LIBCFS_STRINGHASH], [
 595 LB_CHECK_LINUX_HEADER([linux/stringhash.h], [
 596         AC_DEFINE(HAVE_STRINGHASH, 1,
 597                 [stringhash.h is present])])
 598 ]) # LIBCFS_STRINGHASH
 599
 600 #
 601 # LIBCFS_RHASHTABLE_INSERT_FAST
 602 #
 603 # 4.7+ kernel commit 5ca8cc5bf11faed257c762018aea9106d529232f
 604 # changed __rhashtable_insert_fast to support the new function
 605 # rhashtable_lookup_get_insert_key().
 606 #
 607 AC_DEFUN([LIBCFS_RHASHTABLE_INSERT_FAST], [
 608 tmp_flags="$EXTRA_KCFLAGS"
 609 EXTRA_KCFLAGS="-Werror"
 610 LB_CHECK_COMPILE([if internal '__rhashtable_insert_fast()' returns int],
 611 rhashtable_insert_fast, [
 612         #include <linux/rhashtable.h>
 613 ],[
 614         const struct rhashtable_params params = { 0 };
 615         int rc;
 616
 617         rc = __rhashtable_insert_fast(NULL, NULL, NULL, params);
 618 ],[
 619         AC_DEFINE(HAVE_HASHTABLE_INSERT_FAST_RETURN_INT, 1,
 620                   ['__rhashtable_insert_fast()' returns int])
 621 ])
 622 EXTRA_KCFLAGS="$tmp_flags"
 623 ]) # LIBCFS_RHASHTABLE_INSERT_FAST
 624
 625 #
 626 # Kernel version 4.7-rc1 commit 8f6fd83c6c5ec66a4a70c728535ddcdfef4f3697
 627 # added 3rd arg to rhashtable_walk_init
 628 #
 629 AC_DEFUN([LIBCFS_RHASHTABLE_WALK_INIT_3ARG], [
 630 LB_CHECK_COMPILE([if 'rhashtable_walk_init' has 3 args],
 631 rhashtable_walk_init, [
 632         #include <linux/gfp.h>
 633         #include <linux/rhashtable.h>
 634 ],[
 635         rhashtable_walk_init(NULL, NULL, GFP_KERNEL);
 636 ],[
 637         AC_DEFINE(HAVE_3ARG_RHASHTABLE_WALK_INIT, 1,
 638                 [rhashtable_walk_init() has 3 args])
 639 ])
 640 ]) # LIBCFS_RHASHTABLE_REPLACE
 641
 642 #
 643 # Kernel version 4.8-rc6 commit ca26893f05e86497a86732768ec53cd38c0819ca
 644 # introduced rhashtable_lookup
 645 #
 646 AC_DEFUN([LIBCFS_RHASHTABLE_LOOKUP], [
 647 LB_CHECK_COMPILE([if 'rhashtable_lookup' exist],
 648 rhashtable_lookup, [
 649         #include <linux/rhashtable.h>
 650 ],[
 651         const struct rhashtable_params params = { 0 };
 652         void *ret;
 653
 654         ret = rhashtable_lookup(NULL, NULL, params);
 655 ],[
 656         AC_DEFINE(HAVE_RHASHTABLE_LOOKUP, 1,
 657                 [rhashtable_lookup() is available])
 658 ])
 659 ]) # LIBCFS_RHASHTABLE_LOOKUP
 660
 661 #
 662 # LIBCFS_RHLTABLE
 663 # Kernel version 4.8-rc6 commit ca26893f05e86497a86732768ec53cd38c0819ca
 664 # created the rhlist interface to allow inserting duplicate objects
 665 # into the same table.
 666 #
 667 AC_DEFUN([LIBCFS_RHLTABLE], [
 668 LB_CHECK_COMPILE([does 'struct rhltable' exist],
 669 rhtable, [
 670         #include <linux/rhashtable.h>
 671 ],[
 672         struct rhltable *hlt;
 673
 674         rhltable_destroy(hlt);
 675 ],[
 676         AC_DEFINE(HAVE_RHLTABLE, 1,
 677                   [struct rhltable exist])
 678 ])
 679 ]) # LIBCFS_RHLTABLE
 680
 681 #
 682 # LIBCFS_STACKTRACE_OPS
 683 #
 684 # Kernel version 4.8 commit c8fe4609827aedc9c4b45de80e7cdc8ccfa8541b
 685 # removed both struct stacktrace_ops and dump_trace() function
 686 #
 687 AC_DEFUN([LIBCFS_STACKTRACE_OPS], [
 688 LB_CHECK_COMPILE([if 'struct stacktrace_ops' exists],
 689 stacktrace_ops, [
 690         struct task_struct;
 691         struct pt_regs;
 692         #include <asm/stacktrace.h>
 693 ],[
 694         struct stacktrace_ops ops;
 695         ops.stack = NULL;
 696 ],[
 697         AC_DEFINE(HAVE_STACKTRACE_OPS, 1,
 698                 [struct stacktrace_ops exists])
 699 ])
 700 ]) # LIBCFS_STACKTRACE_OPS
 701
 702 #
 703 # Kernel version 4.9-rc1 commit 246779dd090bd1b74d2652b3a6ca7759f593b27a
 704 # introduced rhashtable_walk_enter
 705 #
 706 AC_DEFUN([LIBCFS_RHASHTABLE_WALK_ENTER], [
 707 LB_CHECK_COMPILE([if 'rhashtable_walk_enter' exists],
 708 rhashtable_walk_enter, [
 709         #include <linux/rhashtable.h>
 710 ],[
 711         rhashtable_walk_enter(NULL, NULL);
 712 ],[
 713         AC_DEFINE(HAVE_RHASHTABLE_WALK_ENTER, 1,
 714                 [rhashtable_walk_enter() is available])
 715 ])
 716 ]) # LIBCFS_RHASHTABLE_REPLACE
 717
 718 #
 719 # Kernel version 4.9 commit 768ae309a96103ed02eb1e111e838c87854d8b51
 720 # mm: replace get_user_pages() write/force parameters with gup_flags
 721 #
 722 AC_DEFUN([LIBCFS_GET_USER_PAGES_GUP_FLAGS], [
 723 LB_CHECK_COMPILE([if 'get_user_pages()' takes gup_flags in arguments],
 724 get_user_pages_gup_flags, [
 725         #include <linux/mm.h>
 726 ],[
 727         int rc;
 728         rc = get_user_pages(0, 0, FOLL_WRITE, NULL, NULL);
 729 ],[
 730         AC_DEFINE(HAVE_GET_USER_PAGES_GUP_FLAGS, 1,
 731                 [get_user_pages takes gup_flags in arguments])
 732 ])
 733 ]) # LIBCFS_GET_USER_PAGES_GUP_FLAGS
 734
 735 #
 736 # Kernel version 4.10 commit 7b737965b33188bd3dbb44e938535c4006d97fbb
 737 # libcfs: Convert to hotplug state machine
 738 #
 739 AC_DEFUN([LIBCFS_HOTPLUG_STATE_MACHINE], [
 740 LB_CHECK_COMPILE([if libcfs supports CPU hotplug state machine],
 741 cpu_hotplug_state_machine, [
 742         #include <linux/cpuhotplug.h>
 743 ],[
 744         cpuhp_remove_state(CPUHP_LUSTRE_CFS_DEAD);
 745 ],[
 746         AC_DEFINE(HAVE_HOTPLUG_STATE_MACHINE, 1,
 747                 [hotplug state machine is supported])
 748 ])
 749 ]) # LIBCFS_HOTPLUG_STATE_MACHINE
 750
 751 #
 752 # Kernel version 4.10-rc3 commit f405df5de3170c00e5c54f8b7cf4766044a032ba
 753 # introduced refcount_t which is atomic_t plus over flow guards.
 754 #
 755 AC_DEFUN([LIBCFS_REFCOUNT_T], [
 756 tmp_flags="$EXTRA_KCFLAGS"
 757 EXTRA_KCFLAGS="-Werror"
 758 LB_CHECK_LINUX_HEADER([linux/refcount.h], [
 759         AC_DEFINE(HAVE_REFCOUNT_T, 1,
 760                 [refcount_t is supported])
 761 ])
 762 EXTRA_KCFLAGS="$tmp_flags"
 763 ]) # LIBCFS_REFCOUNT_T
 764
 765 #
 766 # LIBCFS_SCHED_HEADERS
 767 #
 768 # 4.11 has broken up sched.h into more headers.
 769 #
 770 AC_DEFUN([LIBCFS_SCHED_HEADERS], [
 771 LB_CHECK_LINUX_HEADER([linux/sched/signal.h], [
 772         AC_DEFINE(HAVE_SCHED_HEADERS, 1,
 773                 [linux/sched header directory exist])])
 774 ]) # LIBCFS_SCHED_HEADERS
 775
 776 #
 777 # Kernel version 4.11-rc1 commit 2c935bc57221cc2edc787c72ea0e2d30cdcd3d5e
 778 # introduce kref_read
 779 #
 780 AC_DEFUN([LIBCFS_KREF_READ], [
 781 LB_CHECK_COMPILE([if 'kref_read' exists],
 782 kref_read, [
 783         #include <linux/kref.h>
 784 ],[
 785         kref_read(NULL);
 786 ],[
 787         AC_DEFINE(HAVE_KREF_READ, 1,
 788                 [kref_read() is available])
 789 ])
 790 ]) LIBCFS_KREF_READ
 791
 792 #
 793 # Kernel version 4.11-rc1 commit da20420f83ea0fbcf3d03afda08d971ea1d8a356
 794 # introduced rht_bucket_var
 795 #
 796 AC_DEFUN([LIBCFS_RHT_BUCKET_VAR], [
 797 LB_CHECK_COMPILE([if 'rht_bucket_var' exists],
 798 rht_bucket_var, [
 799         #include <linux/rhashtable.h>
 800 ],[
 801
 802         rht_bucket_var(NULL, 0);
 803 ],[
 804         AC_DEFINE(HAVE_RHT_BUCKET_VAR, 1,
 805                 [rht_bucket_var() is available])
 806 ])
 807 ]) # LIBCFS_RHT_BUCKET_VAR
 808
 809 #
 810 # Kernel version 4.11 commit f9fe1c12d126f9887441fa5bb165046f30ddd4b5
 811 # introduced rhashtable_lookup_get_insert_fast
 812 #
 813 AC_DEFUN([LIBCFS_RHASHTABLE_LOOKUP_GET_INSERT_FAST], [
 814 LB_CHECK_COMPILE([if 'rhashtable_lookup_get_insert_fast' exist],
 815 rhashtable_lookup_get_insert_fast, [
 816         #include <linux/rhashtable.h>
 817 ],[
 818         const struct rhashtable_params params = { 0 };
 819         void *ret;
 820
 821         ret = rhashtable_lookup_get_insert_fast(NULL, NULL, params);
 822 ],[
 823         AC_DEFINE(HAVE_RHASHTABLE_LOOKUP_GET_INSERT_FAST, 1,
 824                 [rhashtable_lookup_get_insert_fast() is available])
 825 ])
 826 ]) # LIBCFS_RHASHTABLE_LOOKUP_GET_INSERT_FAST
 827
 828 #
 829 # Kernel version 4.12-rc2 8f553c498e1772cccb39a114da4a498d22992758
 830 # provide proper CPU hotplug locking
 831 #
 832 AC_DEFUN([LIBCFS_CPUS_READ_LOCK], [
 833 LB_CHECK_COMPILE([if 'cpus_read_[un]lock' exist],
 834 cpu_read_lock, [
 835         #include <linux/cpu.h>
 836 ],[
 837         cpus_read_lock();
 838         cpus_read_unlock();
 839 ],[
 840         AC_DEFINE(HAVE_CPUS_READ_LOCK, 1, ['cpus_read_lock' exist])
 841 ])
 842 ]) # LIBCFS_CPUS_READ_LOCK
 843
 844 #
 845 # Kernel version 4.12-rc3 f9727a17db9bab71ddae91f74f11a8a2f9a0ece6
 846 # renamed uuid_be to uuid_t
 847 #
 848 AC_DEFUN([LIBCFS_UUID_T], [
 849 LB_CHECK_COMPILE([if 'uuid_t' exist],
 850 uuid_t, [
 851         #include <linux/uuid.h>
 852 ],[
 853         uuid_t uuid;
 854
 855         memset(uuid.b, 0, 16);
 856 ],[
 857         AC_DEFINE(HAVE_UUID_T, 1, ['uuid_t' exist])
 858 ])
 859 ]) # LIBCFS_UUID_T
 860
 861 #
 862 # Kernel version 4.12-rc3 commit fd851a3cdc196bfc1d229b5f22369069af532bf8
 863 # introduce processor.h
 864 #
 865 AC_DEFUN([LIBCFS_HAVE_PROCESSOR_HEADER], [
 866 tmp_flags="$EXTRA_KCFLAGS"
 867 EXTRA_KCFLAGS="-Werror"
 868 LB_CHECK_LINUX_HEADER([linux/processor.h], [
 869         AC_DEFINE(HAVE_PROCESSOR_H, 1,
 870                 [processor.h is present])
 871 ])
 872 EXTRA_KCFLAGS="$tmp_flags"
 873 ]) # LIBCFS_HAVE_PROCESSOR_HEADER
 874
 875 #
 876 # Kernel verison 4.12-rc6 commit 5dd43ce2f69d42a71dcacdb13d17d8c0ac1fe8f7
 877 # created wait_bit.h
 878 #
 879 AC_DEFUN([LIBCFS_HAVE_WAIT_BIT_HEADER], [
 880 LB_CHECK_LINUX_HEADER([linux/wait_bit.h], [
 881         AC_DEFINE(HAVE_WAIT_BIT_HEADER_H, 1,
 882                 [wait_bit.h is present])])
 883 ]) # LIBCFS_HAVE_WAIT_BIT_HEADER
 884
 885 #
 886 # Kernel version 4.12-rc6 commmit 2055da97389a605c8a00d163d40903afbe413921
 887 # changed:
 888 #       struct wait_queue_head::task_list       => ::head
 889 #       struct wait_queue_entry::task_list      => ::entry
 890 #
 891 AC_DEFUN([LIBCFS_WAIT_QUEUE_TASK_LIST_RENAME], [
 892 LB_CHECK_COMPILE([if linux wait_queue_head list_head is named head],
 893 wait_queue_task_list, [
 894         #include <linux/wait.h>
 895 ],[
 896         wait_queue_head_t e;
 897
 898         INIT_LIST_HEAD(&e.head);
 899 ],[
 900         AC_DEFINE(HAVE_WAIT_QUEUE_ENTRY_LIST, 1,
 901                 [linux wait_queue_head_t list_head is name head])
 902 ])
 903 ]) # LIBCFS_WAIT_QUEUE_TASK_LIST_RENAME
 904
 905 #
 906 # LIBCFS_WAIT_QUEUE_ENTRY
 907 #
 908 # Kernel version 4.13 ac6424b981bce1c4bc55675c6ce11bfe1bbfa64f
 909 # Rename wait_queue_t => wait_queue_entry_t
 910 #
 911 AC_DEFUN([LIBCFS_WAIT_QUEUE_ENTRY], [
 912 LB_CHECK_COMPILE([if 'wait_queue_entry_t' exists],
 913 wait_queue_entry, [
 914         #include <linux/wait.h>
 915 ],[
 916         wait_queue_entry_t e;
 917
 918         e.flags = 0;
 919 ],[
 920         AC_DEFINE(HAVE_WAIT_QUEUE_ENTRY, 1,
 921                 ['wait_queue_entry_t' is available])
 922 ])
 923 ]) # LIBCFS_WAIT_QUEUE_ENTRY
 924
 925 #
 926 # LIBCFS_NEW_KERNEL_WRITE
 927 #
 928 # Kernel version 4.14 e13ec939e96b13e664bb6cee361cc976a0ee621a
 929 # changed kernel_write prototype to make is plug compatible
 930 # with the unexported vfs_write()
 931 #
 932 AC_DEFUN([LIBCFS_NEW_KERNEL_WRITE], [
 933 tmp_flags="$EXTRA_KCFLAGS"
 934 EXTRA_KCFLAGS="-Werror"
 935 LB_CHECK_COMPILE([if 'kernel_write' matches other read/write helpers],
 936 kernel_write_match, [
 937         #include <linux/fs.h>
 938 ],[
 939         const void *buf = NULL;
 940         loff_t pos = 0;
 941         return kernel_write(NULL, buf, 0, &pos);
 942 ],[
 943         AC_DEFINE(HAVE_NEW_KERNEL_WRITE, 1,
 944                 ['kernel_write' aligns with read/write helpers])
 945 ])
 946 EXTRA_KCFLAGS="$tmp_flags"
 947 ]) # LIBCFS_NEW_KERNEL_WRITE
 948
 949 #
 950 # LIBCFS_MM_TOTALRAM_PAGES_FUNC
 951 #
 952 # kernel 5.0 commit ca79b0c211af63fa3276f0e3fd7dd9ada2439839
 953 # mm: convert totalram_pages and totalhigh_pages variables to atomic
 954 #
 955 AC_DEFUN([LIBCFS_MM_TOTALRAM_PAGES_FUNC], [
 956 tmp_flags="$EXTRA_KCFLAGS"
 957 EXTRA_KCFLAGS="-Werror"
 958 LB_CHECK_COMPILE([if totalram_pages is a function],
 959 totalram_pages, [
 960         #include <linux/mm.h>
 961 ],[
 962         totalram_pages_inc();
 963 ],[
 964         AC_DEFINE(HAVE_TOTALRAM_PAGES_AS_FUNC, 1,
 965                 [if totalram_pages is a function])
 966 ])
 967 EXTRA_KCFLAGS="$tmp_flags"
 968 ]) # LIBCFS_MM_TOTALRAM_PAGES_FUNC
 969
 970 #
 971 # LIBCFS_NEW_KERNEL_WRITE
 972 #
 973 # 4.14 commit bdd1d2d3d251c65b74ac4493e08db18971c09240 changed
 974 # the signature of kernel_read to match other read/write helpers
 975 # and place offset last.
 976 #
 977 AC_DEFUN([LIBCFS_NEW_KERNEL_READ], [
 978 tmp_flags="$EXTRA_KCFLAGS"
 979 EXTRA_KCFLAGS="-Werror"
 980 LB_CHECK_COMPILE([if 'kernel_read()' has loff_t *pos as last parameter],
 981 kernel_read, [
 982         #include <linux/fs.h>
 983         ],[
 984         loff_t pos = 0;
 985         kernel_read(NULL, NULL, 0, &pos);
 986 ],[
 987         AC_DEFINE(HAVE_KERNEL_READ_LAST_POSP, 1,
 988                 [kernel_read() signature ends with loff_t *pos])
 989 ])
 990 EXTRA_KCFLAGS="$tmp_flags"
 991 ]) # LIBCFS_NEW_KERNEL_READ
 992
 993 #
 994 # LIBCFS_DEFINE_TIMER
 995 #
 996 # Kernel version 4.14 commit 1d27e3e2252ba9d949ca82fbdb73cde102cb2067
 997 # remove expires and data arguments from DEFINE_TIMER. Also the callback
 998 # when from using unsigned long argument to using struct timer_list pointer.
 999 #
1000 AC_DEFUN([LIBCFS_DEFINE_TIMER], [
1001 LB_CHECK_COMPILE([if DEFINE_TIMER takes only 2 arguments],
1002 define_timer, [
1003         #include <linux/timer.h>
1004 ],[
1005         static DEFINE_TIMER(my_timer, NULL);
1006 ],[
1007         AC_DEFINE(HAVE_NEW_DEFINE_TIMER, 1,
1008                 [DEFINE_TIMER uses only 2 arguements])
1009 ])
1010 ]) # LIBCFS_DEFINE_TIMER
1011
1012 #
1013 # LIBCFS_EXPORT_SAVE_STACK_TRACE_TSK
1014 #
1015 # Kernel 2.6.27 commit 8594698ebddeef5443b7da8258ae33b3eaca61d5
1016 # exported save_stack_trace_tsk for x86.
1017 # Kernel 2.6.27 commit 01f4b8b8b8db09b88be7df7e51192e4e678b69d3
1018 # exported save_stack_trace_tsk for powerpc
1019 # Kernel 4.13 commit e27c7fa015d61c8be6a2c32b2144aad2ae6ec975
1020 # exported save_stack_trace_tsk for arm64
1021 # Kernel 4.14 commit 9a3dc3186fc3795e076a4122da9e0258651a9631
1022 # exported save_stack_trace_tsk for arm
1023 #
1024 AC_DEFUN([LIBCFS_EXPORT_SAVE_STACK_TRACE_TSK], [
1025 LB_CHECK_EXPORT([save_stack_trace_tsk], [arch/$SUBARCH/kernel/stacktrace.c],
1026         [AC_DEFINE(HAVE_SAVE_STACK_TRACE_TSK, 1,
1027                 [save_stack_trace_tsk is exported])])
1028 ]) # LIBCFS_EXPORT_SAVE_STACK_TRACE_TSK
1029
1030 #
1031 # LIBCFS_TIMER_SETUP
1032 #
1033 # Kernel version 4.15 commit e99e88a9d2b067465adaa9c111ada99a041bef9a
1034 # setup_timer() was replaced by timer_setup(), where the callback
1035 # argument is the structure already holding the struct timer_list.
1036 #
1037 AC_DEFUN([LIBCFS_TIMER_SETUP], [
1038 LB_CHECK_COMPILE([if setup_timer has been replaced with timer_setup],
1039 timer_setup, [
1040         #include <linux/timer.h>
1041 ],[
1042         timer_setup(NULL, NULL, 0);
1043 ],[
1044         AC_DEFINE(HAVE_TIMER_SETUP, 1,
1045                 [timer_setup has replaced setup_timer])
1046 ])
1047 ]) # LIBCFS_TIMER_SETUP
1048
1049 #
1050 # LIBCFS_WAIT_VAR_EVENT
1051 #
1052 # Kernel version 4.16-rc4 commit 6b2bb7265f0b62605e8caee3613449ed0db270b9
1053 # added wait_var_event()
1054 #
1055 AC_DEFUN([LIBCFS_WAIT_VAR_EVENT], [
1056 LB_CHECK_COMPILE([if 'wait_var_event' exist],
1057 wait_var_event, [
1058         #ifdef HAVE_WAIT_BIT_HEADER_H
1059         #include <linux/wait_bit.h>
1060         #endif
1061         #include <linux/wait.h>
1062 ],[
1063         wake_up_var(NULL);
1064 ],[
1065         AC_DEFINE(HAVE_WAIT_VAR_EVENT, 1,
1066                 ['wait_var_event' is available])
1067 ])
1068 ]) # LIBCFS_WAIT_VAR_EVENT
1069
1070 #
1071 # LIBCFS_CLEAR_AND_WAKE_UP_BIT
1072 #
1073 # Kernel version 4.17-rc2 commit 8236b0ae31c837d2b3a2565c5f8d77f637e824cc
1074 # added clear_and_wake_up_bit()
1075 #
1076 AC_DEFUN([LIBCFS_CLEAR_AND_WAKE_UP_BIT], [
1077 LB_CHECK_COMPILE([if 'clear_and_wake_up_bit' exist],
1078 clear_and_wake_up_bit, [
1079         #ifdef HAVE_WAIT_BIT_HEADER_H
1080         #include <linux/wait_bit.h>
1081         #endif
1082         #include <linux/wait.h>
1083 ],[
1084         clear_and_wake_up_bit(0, NULL);
1085 ],[
1086         AC_DEFINE(HAVE_CLEAR_AND_WAKE_UP_BIT, 1,
1087                 ['clear_and_wake_up_bit' is available])
1088 ])
1089 ]) # LIBCFS_CLEAR_AND_WAKE_UP_BIT
1090
1091 #
1092 # LIBCFS_XARRAY_SUPPORT
1093 #
1094 # 4.19-rc5 kernel commit 3159f943aafdbacb2f94c38fdaadabf2bbde2a14
1095 # replaced the radix tree implementation with Xarrays. This change
1096 # introduced functionaly needed for general Xarray support
1097 #
1098 AC_DEFUN([LIBCFS_XARRAY_SUPPORT], [
1099 tmp_flags="$EXTRA_KCFLAGS"
1100 EXTRA_KCFLAGS="-Werror"
1101 LB_CHECK_COMPILE([if page cache uses Xarray],
1102 xarray_support, [
1103         #include <linux/radix-tree.h>
1104 ],[
1105         radix_tree_exceptional_entry(NULL);
1106 ],[
1107         AC_DEFINE(HAVE_RADIX_TREE_EXCEPTIONAL_ENTRY, 1,
1108                 [kernel lacks 'xa_is_value'])
1109 ])
1110 EXTRA_KCFLAGS="$tmp_flags"
1111 ]) # LIBCFS_XARRAY_SUPPORT
1112
1113 #
1114 # LIBCFS_HAVE_IOV_ITER_TYPE
1115 #
1116 # kernel 4.20 commit 00e23707442a75b404392cef1405ab4fd498de6b
1117 # iov_iter: Use accessor functions to access an iterator's type and direction.
1118 #
1119 AC_DEFUN([LIBCFS_HAVE_IOV_ITER_TYPE], [
1120 tmp_flags="$EXTRA_KCFLAGS"
1121 EXTRA_KCFLAGS="-Werror"
1122 LB_CHECK_COMPILE([if iov_iter_type exists],
1123 macro_iov_iter_type_exists, [
1124         #include <linux/uio.h>
1125 ],[
1126         struct iov_iter iter = { .type = ITER_KVEC };
1127         enum iter_type type = iov_iter_type(&iter);
1128         (void)type;
1129 ],[
1130         AC_DEFINE(HAVE_IOV_ITER_TYPE, 1,
1131                 [if iov_iter_type exists])
1132 ])
1133 EXTRA_KCFLAGS="$tmp_flags"
1134 ]) # LIBCFS_HAVE_IOV_ITER_TYPE
1135
1136 #
1137 # LIBCFS_GET_REQUEST_KEY_AUTH
1138 #
1139 # kernel 5.0 commit 822ad64d7e46a8e2c8b8a796738d7b657cbb146d
1140 # keys: Fix dependency loop between construction record and auth key
1141 #
1142 # Added <keys/request_key_auth-type.h> and get_request_key_auth()
1143 # which was propagated to stable
1144 #
1145 AC_DEFUN([LIBCFS_GET_REQUEST_KEY_AUTH], [
1146 tmp_flags="$EXTRA_KCFLAGS"
1147 EXTRA_KCFLAGS="-Werror"
1148 LB_CHECK_COMPILE([if get_request_key_auth() is available],
1149 get_request_key_auth_exported, [
1150         #include <linux/key.h>
1151         #include <linux/keyctl.h>
1152         #include <keys/request_key_auth-type.h>
1153 ],[
1154         struct key *ring;
1155         const struct key *key = NULL;
1156         struct request_key_auth *rka = get_request_key_auth(key);
1157
1158         ring = key_get(rka->dest_keyring);
1159 ],[
1160         AC_DEFINE(HAVE_GET_REQUEST_KEY_AUTH, 1,
1161                 [get_request_key_auth() is available])
1162 ])
1163 EXTRA_KCFLAGS="$tmp_flags"
1164 ]) # LIBCFS_GET_REQUEST_KEY_AUTH
1165
1166 #
1167 # LIBCFS_LOOKUP_USER_KEY
1168 #
1169 # kernel 5.3 commit 3cf5d076fb4d48979f382bc9452765bf8b79e740
1170 # signal: Remove task parameter from force_sig
1171 #
1172 AC_DEFUN([LIBCFS_LOOKUP_USER_KEY], [
1173 tmp_flags="$EXTRA_KCFLAGS"
1174 EXTRA_KCFLAGS="-Werror"
1175 LB_CHECK_COMPILE([if lookup_user_key() is available],
1176 lookup_user_key_exported, [
1177         #include <linux/key.h>
1178         #include <linux/keyctl.h>
1179 ],[
1180         lookup_user_key(KEY_SPEC_USER_KEYRING, 0, 0);
1181 ],[
1182         AC_DEFINE(HAVE_LOOKUP_USER_KEY, 1,
1183                 [lookup_user_key() is available])
1184 ])
1185 EXTRA_KCFLAGS="$tmp_flags"
1186 ]) # LIBCFS_LOOKUP_USER_KEY
1187
1188 #
1189 # LIBCFS_FORCE_SIG_WITH_TASK
1190 #
1191 # kernel 5.3 commit 3cf5d076fb4d48979f382bc9452765bf8b79e740
1192 # signal: Remove task parameter from force_sig
1193 #
1194 AC_DEFUN([LIBCFS_FORCE_SIG_WITH_TASK], [
1195 tmp_flags="$EXTRA_KCFLAGS"
1196 EXTRA_KCFLAGS="-Werror"
1197 LB_CHECK_COMPILE([if force_sig has task parameter],
1198 force_sig_with_task, [
1199         #include <linux/sched/signal.h>
1200 ],[
1201         force_sig(SIGINT, NULL);
1202 ],[
1203         AC_DEFINE(HAVE_FORCE_SIG_WITH_TASK, 1,
1204                 [force_sig() has task parameter])
1205 ])
1206 EXTRA_KCFLAGS="$tmp_flags"
1207 ]) # LIBCFS_FORCE_SIG_WITH_TASK
1208
1209 #
1210 # LIBCFS_CACHE_DETAIL_WRITERS
1211 #
1212 # kernel v5.3-rc2-1-g64a38e840ce5
1213 # SUNRPC: Track writers of the 'channel' file to improve cache_listeners_exist
1214 #
1215 AC_DEFUN([LIBCFS_CACHE_DETAIL_WRITERS], [
1216 tmp_flags="$EXTRA_KCFLAGS"
1217 EXTRA_KCFLAGS="-Werror"
1218 LB_CHECK_COMPILE([if struct cache_detail has writers],
1219 cache_detail_writers_atomic, [
1220         #include <linux/sunrpc/cache.h>
1221
1222         static struct cache_detail rsi_cache;
1223 ],[
1224         atomic_set(&rsi_cache.writers, 0);
1225 ],[
1226         AC_DEFINE(HAVE_CACHE_DETAIL_WRITERS, 1,
1227                 [struct cache_detail has writers])
1228 ])
1229 EXTRA_KCFLAGS="$tmp_flags"
1230 ]) # LIBCFS_CACHE_DETAIL_WRITERS
1231
1232 #
1233 # LIBCFS_CONFIG_CRYPTO_CRC32
1234 #
1235 # The kernel must support CONFIG_CRYPTO_CRC32 to RPC checksumming
1236 #
1237 AC_DEFUN([LIBCFS_CONFIG_CRYPTO_CRC32], [
1238 LB_CHECK_CONFIG_IM([CRYPTO_CRC32], [],
1239         [AC_MSG_ERROR([
1240
1241 Lustre requires that CONFIG_CRYPTO_CRC32 is enabled in your kernel.
1242 ])])
1243 ]) # LIBCFS_CONFIG_CRYPTO_CRC32
1244
1245
1246 #
1247 # LIBCFS_PROG_LINUX
1248 #
1249 # LibCFS linux kernel checks
1250 #
1251 AC_DEFUN([LIBCFS_PROG_LINUX], [
1252 AC_MSG_NOTICE([LibCFS kernel checks
1253 ==============================================================================])
1254 LIBCFS_CONFIG_PANIC_DUMPLOG
1255 LIBCFS_CONFIG_CRYPTO_CRC32
1256
1257 # 3.11
1258 LIBCFS_KTIME_GET_TS64
1259 # 3.12
1260 LIBCFS_PREPARE_TO_WAIT_EVENT
1261 LIBCFS_KERNEL_PARAM_OPS
1262 LIBCFS_KTIME_ADD
1263 LIBCFS_KTIME_AFTER
1264 LIBCFS_KTIME_BEFORE
1265 LIBCFS_KTIME_COMPARE
1266 LIBCFS_SHRINKER_COUNT
1267 # 3.15
1268 LIBCFS_IOV_ITER_HAS_TYPE
1269 # 3.16
1270 LIBCFS_HAVE_NS_TO_TIMESPEC64
1271 # 3.17
1272 LIBCFS_HLIST_ADD_AFTER
1273 LIBCFS_TIMESPEC64
1274 LIBCFS_KTIME_GET_NS
1275 LIBCFS_KTIME_GET_REAL_TS64
1276 LIBCFS_KTIME_GET_REAL_SECONDS
1277 LIBCFS_KTIME_GET_REAL_NS
1278 LIBCFS_KTIME_TO_TIMESPEC64
1279 LIBCFS_TIMESPEC64_SUB
1280 LIBCFS_TIMESPEC64_TO_KTIME
1281 # 3.19
1282 LIBCFS_KTIME_GET_SECONDS
1283 # 4.0
1284 LIBCFS_KTIME_MS_DELTA
1285 # 4.1
1286 LIBCFS_KERNEL_PARAM_LOCK
1287 # 4.2
1288 LIBCFS_HAVE_TOPOLOGY_SIBLING_CPUMASK
1289 # 4.4
1290 LIBCFS_KSTRTOBOOL_FROM_USER
1291 # 4.5
1292 LIBCFS_CRYPTO_HASH_HELPERS
1293 LIBCFS_EXPORT_KSET_FIND_OBJ
1294 LIBCFS_RHASHTABLE_REPLACE
1295 # 4.6
1296 LIBCFS_BROKEN_HASH_64
1297 LIBCFS_STACKTRACE_OPS_ADDRESS_RETURN_INT
1298 LIBCFS_GET_USER_PAGES_6ARG
1299 LIBCFS_STRINGHASH
1300 # 4.7
1301 LIBCFS_RHASHTABLE_INSERT_FAST
1302 LIBCFS_RHASHTABLE_WALK_INIT_3ARG
1303 # 4.8
1304 LIBCFS_RHASHTABLE_LOOKUP
1305 LIBCFS_RHLTABLE
1306 LIBCFS_STACKTRACE_OPS
1307 # 4.9
1308 LIBCFS_GET_USER_PAGES_GUP_FLAGS
1309 LIBCFS_RHASHTABLE_WALK_ENTER
1310 # 4.10
1311 LIBCFS_HOTPLUG_STATE_MACHINE
1312 LIBCFS_REFCOUNT_T
1313 # 4.11
1314 LIBCFS_RHASHTABLE_LOOKUP_GET_INSERT_FAST
1315 LIBCFS_SCHED_HEADERS
1316 LIBCFS_KREF_READ
1317 LIBCFS_RHT_BUCKET_VAR
1318 # 4.12
1319 LIBCFS_HAVE_PROCESSOR_HEADER
1320 LIBCFS_HAVE_WAIT_BIT_HEADER
1321 LIBCFS_WAIT_QUEUE_TASK_LIST_RENAME
1322 LIBCFS_CPUS_READ_LOCK
1323 LIBCFS_UUID_T
1324 # 4.13
1325 LIBCFS_WAIT_QUEUE_ENTRY
1326 # 4.14
1327 LIBCFS_DEFINE_TIMER
1328 LIBCFS_NEW_KERNEL_WRITE
1329 LIBCFS_NEW_KERNEL_READ
1330 LIBCFS_EXPORT_SAVE_STACK_TRACE_TSK
1331 # 4.15
1332 LIBCFS_TIMER_SETUP
1333 # 4.16
1334 LIBCFS_WAIT_VAR_EVENT
1335 # 4.17
1336 LIBCFS_CLEAR_AND_WAKE_UP_BIT
1337 # 4.19
1338 LIBCFS_XARRAY_SUPPORT
1339 # 4.20
1340 LIBCFS_HAVE_IOV_ITER_TYPE
1341 # 5.0
1342 LIBCFS_MM_TOTALRAM_PAGES_FUNC
1343 LIBCFS_GET_REQUEST_KEY_AUTH
1344 # 5.3
1345 LIBCFS_LOOKUP_USER_KEY
1346 LIBCFS_FORCE_SIG_WITH_TASK
1347 LIBCFS_CACHE_DETAIL_WRITERS
1348 ]) # LIBCFS_PROG_LINUX
1349
1350 #
1351 # LIBCFS_PATH_DEFAULTS
1352 #
1353 # default paths for installed files
1354 #
1355 AC_DEFUN([LIBCFS_PATH_DEFAULTS], [
1356 ]) # LIBCFS_PATH_DEFAULTS
1357
1358 #
1359 # LIBCFS_CONFIGURE
1360 #
1361 # other configure checks
1362 #
1363 AC_DEFUN([LIBCFS_CONFIGURE], [
1364 AC_MSG_NOTICE([LibCFS core checks
1365 ==============================================================================])
1366
1367 # libcfs/libcfs/util/nidstrings.c
1368 AC_CHECK_HEADERS([netdb.h asm/types.h endian.h])
1369 AC_CHECK_FUNCS([gethostbyname])
1370
1371 # --------  Check for required packages  --------------
1372
1373 AC_MSG_NOTICE([LibCFS required packages checks
1374 ==============================================================================])
1375
1376 AC_MSG_CHECKING([whether to enable readline support])
1377 AC_ARG_ENABLE(readline,
1378         AC_HELP_STRING([--disable-readline],
1379                 [disable readline support]),
1380         [], [enable_readline="yes"])
1381 AC_MSG_RESULT([$enable_readline])
1382
1383 LIBREADLINE=""
1384 AS_IF([test "x$enable_readline" = xyes], [
1385         AC_CHECK_LIB([readline], [readline], [
1386                 LIBREADLINE="-lreadline"
1387                 AC_DEFINE(HAVE_LIBREADLINE, 1,
1388                         [readline library is available])
1389         ])
1390 ])
1391 AC_SUBST(LIBREADLINE)
1392
1393 AC_MSG_CHECKING([whether to use libpthread for libcfs library])
1394 AC_ARG_ENABLE([libpthread],
1395         AC_HELP_STRING([--disable-libpthread],
1396                 [disable libpthread]),
1397         [], [enable_libpthread="yes"])
1398 AC_MSG_RESULT([$enable_libpthread])
1399
1400 PTHREAD_LIBS=""
1401 AS_IF([test "x$enable_libpthread" = xyes], [
1402         AC_CHECK_LIB([pthread], [pthread_create], [
1403                 PTHREAD_LIBS="-lpthread"
1404                 AC_DEFINE([HAVE_LIBPTHREAD], 1,
1405                         [use libpthread for libcfs library])
1406         ])
1407 ], [
1408         AC_MSG_WARN([Using libpthread for libcfs library is disabled explicitly])
1409 ])
1410 AC_SUBST(PTHREAD_LIBS)
1411 ]) # LIBCFS_CONFIGURE
1412
1413 #
1414 # LIBCFS_CONFIG_FILES
1415 #
1416 # files that should be generated with AC_OUTPUT
1417 #
1418 AC_DEFUN([LIBCFS_CONFIG_FILES], [
1419 AC_CONFIG_FILES([
1420 libcfs/Makefile
1421 libcfs/autoMakefile
1422 libcfs/autoconf/Makefile
1423 libcfs/include/Makefile
1424 libcfs/include/libcfs/Makefile
1425 libcfs/include/uapi/Makefile
1426 libcfs/include/libcfs/linux/Makefile
1427 libcfs/include/libcfs/util/Makefile
1428 libcfs/include/libcfs/crypto/Makefile
1429 libcfs/include/uapi/linux/Makefile
1430 libcfs/libcfs/Makefile
1431 libcfs/libcfs/autoMakefile
1432 libcfs/libcfs/linux/Makefile
1433 libcfs/libcfs/util/Makefile
1434 libcfs/libcfs/crypto/Makefile
1435 ])
1436 ]) # LIBCFS_CONFIG_FILES