libcfs/autoconf/lustre-libcfs.m4

   1 #
   2 # LN_CONFIG_CDEBUG
   3 #
   4 # whether to enable various libcfs debugs (CDEBUG, ENTRY/EXIT, LASSERT, etc.)
   5 #
   6 AC_DEFUN([LN_CONFIG_CDEBUG],
   7 [
   8 AC_MSG_CHECKING([whether to enable CDEBUG, CWARN])
   9 AC_ARG_ENABLE([libcfs_cdebug],
  10         AC_HELP_STRING([--disable-libcfs-cdebug],
  11                         [disable libcfs CDEBUG, CWARN]),
  12         [],[enable_libcfs_cdebug='yes'])
  13 AC_MSG_RESULT([$enable_libcfs_cdebug])
  14 if test x$enable_libcfs_cdebug = xyes; then
  15    AC_DEFINE(CDEBUG_ENABLED, 1, [enable libcfs CDEBUG, CWARN])
  16 else
  17    AC_DEFINE(CDEBUG_ENABLED, 0, [disable libcfs CDEBUG, CWARN])
  18 fi
  19
  20 AC_MSG_CHECKING([whether to enable ENTRY/EXIT])
  21 AC_ARG_ENABLE([libcfs_trace],
  22         AC_HELP_STRING([--disable-libcfs-trace],
  23                         [disable libcfs ENTRY/EXIT]),
  24         [],[enable_libcfs_trace='yes'])
  25 AC_MSG_RESULT([$enable_libcfs_trace])
  26 if test x$enable_libcfs_trace = xyes; then
  27    AC_DEFINE(CDEBUG_ENTRY_EXIT, 1, [enable libcfs ENTRY/EXIT])
  28 else
  29    AC_DEFINE(CDEBUG_ENTRY_EXIT, 0, [disable libcfs ENTRY/EXIT])
  30 fi
  31
  32 AC_MSG_CHECKING([whether to enable LASSERT, LASSERTF])
  33 AC_ARG_ENABLE([libcfs_assert],
  34         AC_HELP_STRING([--disable-libcfs-assert],
  35                         [disable libcfs LASSERT, LASSERTF]),
  36         [],[enable_libcfs_assert='yes'])
  37 AC_MSG_RESULT([$enable_libcfs_assert])
  38 if test x$enable_libcfs_assert = xyes; then
  39    AC_DEFINE(LIBCFS_DEBUG, 1, [enable libcfs LASSERT, LASSERTF])
  40 fi
  41 ])
  42
  43 #
  44 # LIBCFS_CONFIG_PANIC_DUMPLOG
  45 #
  46 # check if tunable panic_dumplog is wanted
  47 #
  48 AC_DEFUN([LIBCFS_CONFIG_PANIC_DUMPLOG],
  49 [AC_MSG_CHECKING([for tunable panic_dumplog support])
  50 AC_ARG_ENABLE([panic_dumplog],
  51        AC_HELP_STRING([--enable-panic_dumplog],
  52                       [enable panic_dumplog]),
  53        [],[enable_panic_dumplog='no'])
  54 if test x$enable_panic_dumplog = xyes ; then
  55        AC_DEFINE(LNET_DUMP_ON_PANIC, 1, [use dumplog on panic])
  56        AC_MSG_RESULT([yes (by request)])
  57 else
  58        AC_MSG_RESULT([no])
  59 fi
  60 ])
  61
  62 #
  63 # LIBCFS_STRUCT_PAGE_LIST
  64 #
  65 # 2.6.4 no longer has page->list
  66 #
  67 AC_DEFUN([LIBCFS_STRUCT_PAGE_LIST],
  68 [AC_MSG_CHECKING([if struct page has a list field])
  69 LB_LINUX_TRY_COMPILE([
  70         #include <linux/mm.h>
  71 ],[
  72         struct page page;
  73         &page.list;
  74 ],[
  75         AC_MSG_RESULT([yes])
  76         AC_DEFINE(HAVE_PAGE_LIST, 1, [struct page has a list field])
  77 ],[
  78         AC_MSG_RESULT([no])
  79 ])
  80 ])
  81
  82 #
  83 # LIBCFS_STRUCT_SIGHAND
  84 #
  85 # red hat 2.4 adds sighand to struct task_struct
  86 #
  87 AC_DEFUN([LIBCFS_STRUCT_SIGHAND],
  88 [AC_MSG_CHECKING([if task_struct has a sighand field])
  89 LB_LINUX_TRY_COMPILE([
  90         #include <linux/sched.h>
  91 ],[
  92         struct task_struct p;
  93         p.sighand = NULL;
  94 ],[
  95         AC_DEFINE(CONFIG_RH_2_4_20, 1, [this kernel contains Red Hat 2.4.20 patches])
  96         AC_MSG_RESULT([yes])
  97 ],[
  98         AC_MSG_RESULT([no])
  99 ])
 100 ])
 101
 102 #
 103 # LIBCFS_FUNC_CPU_ONLINE
 104 #
 105 # cpu_online is different in rh 2.4, vanilla 2.4, and 2.6
 106 #
 107 AC_DEFUN([LIBCFS_FUNC_CPU_ONLINE],
 108 [AC_MSG_CHECKING([if kernel defines cpu_online()])
 109 LB_LINUX_TRY_COMPILE([
 110         #include <linux/sched.h>
 111 ],[
 112         cpu_online(0);
 113 ],[
 114         AC_MSG_RESULT([yes])
 115         AC_DEFINE(HAVE_CPU_ONLINE, 1, [cpu_online found])
 116 ],[
 117         AC_MSG_RESULT([no])
 118 ])
 119 ])
 120
 121 #
 122 # LIBCFS_TYPE_GFP_T
 123 #
 124 # check if gfp_t is typedef-ed
 125 #
 126 AC_DEFUN([LIBCFS_TYPE_GFP_T],
 127 [AC_MSG_CHECKING([if kernel defines gfp_t])
 128 LB_LINUX_TRY_COMPILE([
 129         #include <linux/gfp.h>
 130 ],[
 131         return sizeof(gfp_t);
 132 ],[
 133         AC_MSG_RESULT([yes])
 134         AC_DEFINE(HAVE_GFP_T, 1, [gfp_t found])
 135 ],[
 136         AC_MSG_RESULT([no])
 137 ])
 138 ])
 139
 140 #
 141 # LIBCFS_TYPE_CPUMASK_T
 142 #
 143 # same goes for cpumask_t
 144 #
 145 AC_DEFUN([LIBCFS_TYPE_CPUMASK_T],
 146 [AC_MSG_CHECKING([if kernel defines cpumask_t])
 147 LB_LINUX_TRY_COMPILE([
 148         #include <linux/sched.h>
 149 ],[
 150         return sizeof (cpumask_t);
 151 ],[
 152         AC_MSG_RESULT([yes])
 153         AC_DEFINE(HAVE_CPUMASK_T, 1, [cpumask_t found])
 154 ],[
 155         AC_MSG_RESULT([no])
 156 ])
 157 ])
 158
 159 #
 160 # LIBCFS_FUNC_SHOW_TASK
 161 #
 162 # we export show_task(), but not all kernels have it (yet)
 163 #
 164 AC_DEFUN([LIBCFS_FUNC_SHOW_TASK],
 165 [LB_CHECK_SYMBOL_EXPORT([show_task],
 166 [kernel/ksyms.c kernel/sched.c],[
 167 AC_DEFINE(HAVE_SHOW_TASK, 1, [show_task is exported])
 168 ],[
 169 ])
 170 ])
 171
 172 # check userland __u64 type
 173 AC_DEFUN([LIBCFS_U64_LONG_LONG],
 174 [AC_MSG_CHECKING([u64 is long long type])
 175 tmp_flags="$CFLAGS"
 176 CFLAGS="$CFLAGS -Werror"
 177 AC_COMPILE_IFELSE([
 178         #include <linux/types.h>
 179         int main(void) {
 180                 unsigned long long *data1;
 181                 __u64 *data2;
 182
 183                 data1 = data2;
 184                 return 0;
 185         }
 186 ],[
 187         AC_MSG_RESULT([yes])
 188         AC_DEFINE(HAVE_U64_LONG_LONG, 1,
 189                   [__u64 is long long type])
 190 ],[
 191         AC_MSG_RESULT([no])
 192 ])
 193 CFLAGS="$tmp_flags"
 194 ])
 195
 196 # check userland size_t type
 197 AC_DEFUN([LIBCFS_SIZE_T_LONG],
 198 [AC_MSG_CHECKING([size_t is unsigned long type])
 199 tmp_flags="$CFLAGS"
 200 CFLAGS="$CFLAGS -Werror"
 201 AC_COMPILE_IFELSE([
 202         #include <linux/types.h>
 203         int main(void) {
 204                 unsigned long *data1;
 205                 size_t *data2;
 206
 207                 data1 = data2;
 208                 return 0;
 209         }
 210 ],[
 211         AC_MSG_RESULT([yes])
 212         AC_DEFINE(HAVE_SIZE_T_LONG, 1,
 213                   [size_t is long type])
 214 ],[
 215         AC_MSG_RESULT([no])
 216 ])
 217 CFLAGS="$tmp_flags"
 218 ])
 219
 220 AC_DEFUN([LIBCFS_SSIZE_T_LONG],
 221 [AC_MSG_CHECKING([ssize_t is signed long type])
 222 tmp_flags="$CFLAGS"
 223 CFLAGS="$CFLAGS -Werror"
 224 AC_COMPILE_IFELSE([
 225         #include <linux/types.h>
 226         int main(void) {
 227                 long *data1;
 228                 ssize_t *data2;
 229
 230                 data1 = data2;
 231                 return 0;
 232         }
 233 ],[
 234         AC_MSG_RESULT([yes])
 235         AC_DEFINE(HAVE_SSIZE_T_LONG, 1,
 236                   [ssize_t is long type])
 237 ],[
 238         AC_MSG_RESULT([no])
 239 ])
 240 CFLAGS="$tmp_flags"
 241 ])
 242
 243
 244 # check if task_struct with rcu memeber
 245 AC_DEFUN([LIBCFS_TASK_RCU],
 246 [AC_MSG_CHECKING([if task_struct has a rcu field])
 247 LB_LINUX_TRY_COMPILE([
 248         #include <linux/sched.h>
 249 ],[
 250         struct task_struct tsk;
 251
 252         tsk.rcu.next = NULL;
 253 ],[
 254         AC_MSG_RESULT([yes])
 255         AC_DEFINE(HAVE_TASK_RCU, 1,
 256                   [task_struct has rcu field])
 257 ],[
 258         AC_MSG_RESULT([no])
 259 ])
 260 ])
 261
 262 # LIBCFS_TASKLIST_LOCK
 263 # 2.6.18 remove tasklist_lock export
 264 AC_DEFUN([LIBCFS_TASKLIST_LOCK],
 265 [LB_CHECK_SYMBOL_EXPORT([tasklist_lock],
 266 [kernel/fork.c],[
 267 AC_DEFINE(HAVE_TASKLIST_LOCK, 1,
 268          [tasklist_lock exported])
 269 ],[
 270 ])
 271 ])
 272
 273 # 2.6.19 API changes
 274 # kmem_cache_destroy(cachep) return void instead of
 275 # int
 276 AC_DEFUN([LIBCFS_KMEM_CACHE_DESTROY_INT],
 277 [AC_MSG_CHECKING([kmem_cache_destroy(cachep) return int])
 278 LB_LINUX_TRY_COMPILE([
 279         #include <linux/slab.h>
 280 ],[
 281         int i = kmem_cache_destroy(NULL);
 282 ],[
 283         AC_MSG_RESULT(yes)
 284         AC_DEFINE(HAVE_KMEM_CACHE_DESTROY_INT, 1,
 285                 [kmem_cache_destroy(cachep) return int])
 286 ],[
 287         AC_MSG_RESULT(NO)
 288 ])
 289 ])
 290
 291 # 2.6.19 API change
 292 #panic_notifier_list use atomic_notifier operations
 293 #
 294 AC_DEFUN([LIBCFS_ATOMIC_PANIC_NOTIFIER],
 295 [AC_MSG_CHECKING([panic_notifier_list is atomic])
 296 LB_LINUX_TRY_COMPILE([
 297         #include <linux/notifier.h>
 298         #include <linux/kernel.h>
 299 ],[
 300         struct atomic_notifier_head panic_notifier_list;
 301 ],[
 302         AC_MSG_RESULT(yes)
 303         AC_DEFINE(HAVE_ATOMIC_PANIC_NOTIFIER, 1,
 304                 [panic_notifier_list is atomic_notifier_head])
 305 ],[
 306         AC_MSG_RESULT(NO)
 307 ])
 308 ])
 309
 310 # 2.6.20 API change INIT_WORK use 2 args and not
 311 # store data inside
 312 AC_DEFUN([LIBCFS_3ARGS_INIT_WORK],
 313 [AC_MSG_CHECKING([check INIT_WORK want 3 args])
 314 LB_LINUX_TRY_COMPILE([
 315         #include <linux/workqueue.h>
 316 ],[
 317         struct work_struct work;
 318
 319         INIT_WORK(&work, NULL, NULL);
 320 ],[
 321         AC_MSG_RESULT(yes)
 322         AC_DEFINE(HAVE_3ARGS_INIT_WORK, 1,
 323                   [INIT_WORK use 3 args and store data inside])
 324 ],[
 325         AC_MSG_RESULT(NO)
 326 ])
 327 ])
 328
 329 # 2.6.21 api change. 'register_sysctl_table' use only one argument,
 330 # instead of more old which need two.
 331 AC_DEFUN([LIBCFS_2ARGS_REGISTER_SYSCTL],
 332 [AC_MSG_CHECKING([check register_sysctl_table want 2 args])
 333 LB_LINUX_TRY_COMPILE([
 334         #include <linux/sysctl.h>
 335 ],[
 336         return register_sysctl_table(NULL,0);
 337 ],[
 338         AC_MSG_RESULT(yes)
 339         AC_DEFINE(HAVE_2ARGS_REGISTER_SYSCTL, 1,
 340                   [register_sysctl_table want 2 args])
 341 ],[
 342         AC_MSG_RESULT(NO)
 343 ])
 344 ])
 345
 346 # 2.6.21 marks kmem_cache_t deprecated and uses struct kmem_cache
 347 # instead
 348 AC_DEFUN([LIBCFS_KMEM_CACHE],
 349 [AC_MSG_CHECKING([check kernel has struct kmem_cache])
 350 tmp_flags="$EXTRA_KCFLAGS"
 351 EXTRA_KCFLAGS="-Werror"
 352 LB_LINUX_TRY_COMPILE([
 353         #include <linux/slab.h>
 354         typedef struct kmem_cache cache_t;
 355 ],[
 356         cache_t *cachep = NULL;
 357
 358         kmem_cache_alloc(cachep, 0);
 359 ],[
 360         AC_MSG_RESULT(yes)
 361         AC_DEFINE(HAVE_KMEM_CACHE, 1,
 362                   [kernel has struct kmem_cache])
 363 ],[
 364         AC_MSG_RESULT(NO)
 365 ])
 366 EXTRA_KCFLAGS="$tmp_flags"
 367 ])
 368 # 2.6.23 lost dtor argument
 369 AC_DEFUN([LIBCFS_KMEM_CACHE_CREATE_DTOR],
 370 [AC_MSG_CHECKING([check kmem_cache_create has dtor argument])
 371 LB_LINUX_TRY_COMPILE([
 372         #include <linux/slab.h>
 373 ],[
 374         kmem_cache_create(NULL, 0, 0, 0, NULL, NULL);
 375 ],[
 376         AC_MSG_RESULT(yes)
 377         AC_DEFINE(HAVE_KMEM_CACHE_CREATE_DTOR, 1,
 378                   [kmem_cache_create has dtor argument])
 379 ],[
 380         AC_MSG_RESULT(NO)
 381 ])
 382 ])
 383
 384 # 2.6.24 request not use real numbers for ctl_name
 385 AC_DEFUN([LN_SYSCTL_UNNUMBERED],
 386 [AC_MSG_CHECKING([for CTL_UNNUMBERED])
 387 LB_LINUX_TRY_COMPILE([
 388         #include <linux/sysctl.h>
 389 ],[
 390         #ifndef CTL_UNNUMBERED
 391         #error CTL_UNNUMBERED not exist in kernel
 392         #endif
 393 ],[
 394         AC_MSG_RESULT(yes)
 395         AC_DEFINE(HAVE_SYSCTL_UNNUMBERED, 1,
 396                   [sysctl has CTL_UNNUMBERED])
 397 ],[
 398         AC_MSG_RESULT(NO)
 399 ])
 400 ])
 401
 402 # 2.6.24 lost scatterlist->page
 403 AC_DEFUN([LN_SCATTERLIST_SETPAGE],
 404 [AC_MSG_CHECKING([for exist sg_set_page])
 405 LB_LINUX_TRY_COMPILE([
 406         #include <linux/scatterlist.h>
 407 ],[
 408         sg_set_page(NULL,NULL,0,0);
 409 ],[
 410         AC_MSG_RESULT(yes)
 411         AC_DEFINE(HAVE_SCATTERLIST_SETPAGE, 1,
 412                   [struct scatterlist has page member])
 413 ],[
 414         AC_MSG_RESULT(NO)
 415 ])
 416 ])
 417
 418 # 2.6.26 use int instead of atomic for sem.count
 419 AC_DEFUN([LN_SEM_COUNT],
 420 [AC_MSG_CHECKING([atomic sem.count])
 421 LB_LINUX_TRY_COMPILE([
 422         #include <asm/semaphore.h>
 423 ],[
 424         struct semaphore s;
 425
 426         atomic_read(&s.count);
 427 ],[
 428         AC_MSG_RESULT(yes)
 429         AC_DEFINE(HAVE_SEM_COUNT_ATOMIC, 1,
 430                   [semaphore counter is atomic])
 431 ],[
 432         AC_MSG_RESULT(NO)
 433 ])
 434 ])
 435
 436
 437 #
 438 # LIBCFS_PROG_LINUX
 439 #
 440 # LNet linux kernel checks
 441 #
 442 AC_DEFUN([LIBCFS_PROG_LINUX],
 443 [
 444 LIBCFS_FUNC_CPU_ONLINE
 445 LIBCFS_TYPE_GFP_T
 446 LIBCFS_TYPE_CPUMASK_T
 447 LIBCFS_CONFIG_PANIC_DUMPLOG
 448
 449 LIBCFS_STRUCT_PAGE_LIST
 450 LIBCFS_STRUCT_SIGHAND
 451 LIBCFS_FUNC_SHOW_TASK
 452 LIBCFS_U64_LONG_LONG
 453 LIBCFS_SSIZE_T_LONG
 454 LIBCFS_SIZE_T_LONG
 455 LIBCFS_TASK_RCU
 456 # 2.6.18
 457 LIBCFS_TASKLIST_LOCK
 458 # 2.6.19
 459 LIBCFS_KMEM_CACHE_DESTROY_INT
 460 LIBCFS_ATOMIC_PANIC_NOTIFIER
 461 # 2.6.20
 462 LIBCFS_3ARGS_INIT_WORK
 463 # 2.6.21
 464 LIBCFS_2ARGS_REGISTER_SYSCTL
 465 LIBCFS_KMEM_CACHE
 466 # 2.6.23
 467 LIBCFS_KMEM_CACHE_CREATE_DTOR
 468 # 2.6.24
 469 LN_SYSCTL_UNNUMBERED
 470 LN_SCATTERLIST_SETPAGE
 471 # 2.6.26
 472 LN_SEM_COUNT
 473 ])
 474
 475 #
 476 # LIBCFS_PROG_DARWIN
 477 #
 478 # Darwin checks
 479 #
 480 AC_DEFUN([LIBCFS_PROG_DARWIN],
 481 [LB_DARWIN_CHECK_FUNCS([get_preemption_level])
 482 ])
 483
 484 #
 485 # LIBCFS_PATH_DEFAULTS
 486 #
 487 # default paths for installed files
 488 #
 489 AC_DEFUN([LIBCFS_PATH_DEFAULTS],
 490 [
 491 ])
 492
 493 #
 494 # LIBCFS_CONFIGURE
 495 #
 496 # other configure checks
 497 #
 498 AC_DEFUN([LIBCFS_CONFIGURE],
 499 [# lnet/utils/portals.c
 500 AC_CHECK_HEADERS([asm/types.h endian.h sys/ioctl.h])
 501
 502 # lnet/utils/debug.c
 503 AC_CHECK_HEADERS([linux/version.h])
 504
 505 AC_CHECK_TYPE([spinlock_t],
 506         [AC_DEFINE(HAVE_SPINLOCK_T, 1, [spinlock_t is defined])],
 507         [],
 508         [#include <linux/spinlock.h>])
 509
 510 # lnet/utils/wirecheck.c
 511 AC_CHECK_FUNCS([strnlen])
 512
 513 # --------  Check for required packages  --------------
 514
 515
 516 AC_MSG_CHECKING([if efence debugging support is requested])
 517 AC_ARG_ENABLE(efence,
 518         AC_HELP_STRING([--enable-efence],
 519                         [use efence library]),
 520         [],[enable_efence='no'])
 521 AC_MSG_RESULT([$enable_efence])
 522 if test "$enable_efence" = "yes" ; then
 523         LIBEFENCE="-lefence"
 524         AC_DEFINE(HAVE_LIBEFENCE, 1, [libefence support is requested])
 525 else
 526         LIBEFENCE=""
 527 fi
 528 AC_SUBST(LIBEFENCE)
 529
 530
 531 # -------- check for -lpthread support ----
 532 AC_MSG_CHECKING([whether to use libpthread for libcfs library])
 533 AC_ARG_ENABLE([libpthread],
 534         AC_HELP_STRING([--disable-libpthread],
 535                 [disable libpthread]),
 536         [],[enable_libpthread=yes])
 537 if test "$enable_libpthread" = "yes" ; then
 538         AC_CHECK_LIB([pthread], [pthread_create],
 539                 [ENABLE_LIBPTHREAD="yes"],
 540                 [ENABLE_LIBPTHREAD="no"])
 541         if test "$ENABLE_LIBPTHREAD" = "yes" ; then
 542                 AC_MSG_RESULT([$ENABLE_LIBPTHREAD])
 543                 PTHREAD_LIBS="-lpthread"
 544                 AC_DEFINE([HAVE_LIBPTHREAD], 1, [use libpthread])
 545         else
 546                 PTHREAD_LIBS=""
 547                 AC_MSG_RESULT([no libpthread is found])
 548         fi
 549         AC_SUBST(PTHREAD_LIBS)
 550 else
 551         AC_MSG_RESULT([no (disabled explicitly)])
 552         ENABLE_LIBPTHREAD="no"
 553 fi
 554 AC_SUBST(ENABLE_LIBPTHREAD)
 555
 556
 557 ])
 558
 559 #
 560 # LIBCFS_CONDITIONALS
 561 #
 562 # AM_CONDITOINAL defines for lnet
 563 #
 564 AC_DEFUN([LIBCFS_CONDITIONALS],
 565 [
 566 ])
 567
 568 #
 569 # LIBCFS_CONFIG_FILES
 570 #
 571 # files that should be generated with AC_OUTPUT
 572 #
 573 AC_DEFUN([LIBCFS_CONFIG_FILES],
 574 [AC_CONFIG_FILES([
 575 libcfs/Kernelenv
 576 libcfs/Makefile
 577 libcfs/autoMakefile
 578 libcfs/autoconf/Makefile
 579 libcfs/include/Makefile
 580 libcfs/include/libcfs/Makefile
 581 libcfs/include/libcfs/linux/Makefile
 582 libcfs/include/libcfs/posix/Makefile
 583 libcfs/include/libcfs/util/Makefile
 584 libcfs/libcfs/Makefile
 585 libcfs/libcfs/autoMakefile
 586 libcfs/libcfs/linux/Makefile
 587 libcfs/libcfs/posix/Makefile
 588 libcfs/libcfs/util/Makefile
 589 ])
 590 case $lb_target_os in
 591         darwin)
 592                 AC_CONFIG_FILES([
 593 libcfs/include/libcfs/darwin/Makefile
 594 libcfs/libcfs/darwin/Makefile
 595 ])
 596                 ;;
 597 esac
 598 ])