libcfs/autoconf/lustre-libcfs.m4

   1 #
   2 # LN_CONFIG_CDEBUG
   3 #
   4 # whether to enable various libcfs debugs (CDEBUG, ENTRY/EXIT, LASSERT, etc.)
   5 #
   6 AC_DEFUN([LN_CONFIG_CDEBUG],
   7 [
   8 AC_MSG_CHECKING([whether to enable CDEBUG, CWARN])
   9 AC_ARG_ENABLE([libcfs_cdebug],
  10         AC_HELP_STRING([--disable-libcfs-cdebug],
  11                         [disable libcfs CDEBUG, CWARN]),
  12         [],[enable_libcfs_cdebug='yes'])
  13 AC_MSG_RESULT([$enable_libcfs_cdebug])
  14 if test x$enable_libcfs_cdebug = xyes; then
  15    AC_DEFINE(CDEBUG_ENABLED, 1, [enable libcfs CDEBUG, CWARN])
  16 else
  17    AC_DEFINE(CDEBUG_ENABLED, 0, [disable libcfs CDEBUG, CWARN])
  18 fi
  19
  20 AC_MSG_CHECKING([whether to enable ENTRY/EXIT])
  21 AC_ARG_ENABLE([libcfs_trace],
  22         AC_HELP_STRING([--disable-libcfs-trace],
  23                         [disable libcfs ENTRY/EXIT]),
  24         [],[enable_libcfs_trace='yes'])
  25 AC_MSG_RESULT([$enable_libcfs_trace])
  26 if test x$enable_libcfs_trace = xyes; then
  27    AC_DEFINE(CDEBUG_ENTRY_EXIT, 1, [enable libcfs ENTRY/EXIT])
  28 else
  29    AC_DEFINE(CDEBUG_ENTRY_EXIT, 0, [disable libcfs ENTRY/EXIT])
  30 fi
  31
  32 AC_MSG_CHECKING([whether to enable LASSERT, LASSERTF])
  33 AC_ARG_ENABLE([libcfs_assert],
  34         AC_HELP_STRING([--disable-libcfs-assert],
  35                         [disable libcfs LASSERT, LASSERTF]),
  36         [],[enable_libcfs_assert='yes'])
  37 AC_MSG_RESULT([$enable_libcfs_assert])
  38 if test x$enable_libcfs_assert = xyes; then
  39    AC_DEFINE(LIBCFS_DEBUG, 1, [enable libcfs LASSERT, LASSERTF])
  40 fi
  41 ])
  42
  43 #
  44 # LIBCFS_CONFIG_PANIC_DUMPLOG
  45 #
  46 # check if tunable panic_dumplog is wanted
  47 #
  48 AC_DEFUN([LIBCFS_CONFIG_PANIC_DUMPLOG],
  49 [AC_MSG_CHECKING([for tunable panic_dumplog support])
  50 AC_ARG_ENABLE([panic_dumplog],
  51        AC_HELP_STRING([--enable-panic_dumplog],
  52                       [enable panic_dumplog]),
  53        [],[enable_panic_dumplog='no'])
  54 if test x$enable_panic_dumplog = xyes ; then
  55        AC_DEFINE(LNET_DUMP_ON_PANIC, 1, [use dumplog on panic])
  56        AC_MSG_RESULT([yes (by request)])
  57 else
  58        AC_MSG_RESULT([no])
  59 fi
  60 ])
  61
  62 # check kernel __u64 type
  63 AC_DEFUN([LIBCFS_U64_LONG_LONG_LINUX],
  64 [
  65 AC_MSG_CHECKING([kernel __u64 is long long type])
  66 tmp_flags="$EXTRA_KCFLAGS"
  67 EXTRA_KCFLAGS="$EXTRA_KCFLAGS -Werror"
  68 LB_LINUX_TRY_COMPILE([
  69         #include <linux/types.h>
  70         #include <linux/stddef.h>
  71 ],[
  72         unsigned long long *data;
  73
  74         data = (__u64*)sizeof(data);
  75 ],[
  76         AC_MSG_RESULT([yes])
  77         AC_DEFINE(HAVE_KERN__U64_LONG_LONG, 1,
  78                   [kernel __u64 is long long type])
  79 ],[
  80         AC_MSG_RESULT([no])
  81 ])
  82 EXTRA_KCFLAGS="$tmp_flags"
  83 ])
  84
  85 # check cpumask_size (2.6.28)
  86 AC_DEFUN([LIBCFS_CPUMASK_SIZE],
  87 [AC_MSG_CHECKING([whether have cpumask_size()])
  88 LB_LINUX_TRY_COMPILE([
  89         #include <linux/cpumask.h>
  90 ],[
  91         int size = cpumask_size();
  92 ],[
  93         AC_MSG_RESULT(yes)
  94         AC_DEFINE(HAVE_CPUMASK_SIZE, 1, [have cpumask_size()])
  95 ],[
  96         AC_MSG_RESULT(NO)
  97 ])
  98 ])
  99
 100 # check cpu topology functions
 101 #
 102 # topology_core_cpumask (2.6.29, not on all archs)
 103 # topology_core_siblings (not on all archs)
 104 # topology_thread_cpumask (2.6.29, not on all archs)
 105 # topology_thread_siblings (not on all archs)
 106 # cpumask_of_node/node_to_cpumask (not always exported)
 107 AC_DEFUN([LIBCFS_CPU_TOPOLOGY],
 108 [AC_MSG_CHECKING([whether have topology.h])
 109 LB_LINUX_TRY_COMPILE([
 110         #include <linux/topology.h>
 111 ],[],[
 112         AC_DEFINE(HAVE_CPU_TOPOLOGY, 1, [have CPU topology])
 113         AC_MSG_RESULT(yes)
 114
 115         AC_MSG_CHECKING([whether have topology_core_cpumask])
 116         LB_LINUX_TRY_COMPILE([
 117                 #include <linux/topology.h>
 118         ],[
 119                 cpumask_t *mask = topology_core_cpumask(0);
 120         ],[
 121                 AC_DEFINE(HAVE_TOPOLOGY_CORE_CPUMASK, 1,
 122                           [have topology_core_cpumask])
 123                 AC_MSG_RESULT(yes)
 124         ],[
 125                 AC_MSG_RESULT(no)
 126         ])
 127
 128         AC_MSG_CHECKING([whether have topology_core_siblings])
 129         LB_LINUX_TRY_COMPILE([
 130                 #include <linux/topology.h>
 131         ],[
 132                 cpumask_t mask = topology_core_siblings(0);
 133         ],[
 134                 AC_DEFINE(HAVE_TOPOLOGY_CORE_SIBLINGS, 1,
 135                           [have topology_core_siblings])
 136                 AC_MSG_RESULT(yes)
 137         ],[
 138                 AC_MSG_RESULT(no)
 139         ])
 140
 141         AC_MSG_CHECKING([whether have topology_thread_cpumask])
 142         LB_LINUX_TRY_COMPILE([
 143                 #include <linux/topology.h>
 144         ],[
 145                 cpumask_t *mask = topology_thread_cpumask(0);
 146         ],[
 147                 AC_DEFINE(HAVE_TOPOLOGY_THREAD_CPUMASK, 1,
 148                           [have topology_thread_cpumask])
 149                 AC_MSG_RESULT(yes)
 150         ],[
 151                 AC_MSG_RESULT(no)
 152         ])
 153
 154         AC_MSG_CHECKING([whether have topology_thread_siblings])
 155         LB_LINUX_TRY_COMPILE([
 156                 #include <linux/topology.h>
 157         ],[
 158                 cpumask_t mask = topology_thread_siblings(0);
 159         ],[
 160                 AC_DEFINE(HAVE_TOPOLOGY_THREAD_SIBLINGS, 1,
 161                           [have topology_thread_siblings])
 162                 AC_MSG_RESULT(yes)
 163         ],[
 164                 AC_MSG_RESULT(no)
 165         ])
 166
 167         AC_MSG_CHECKING([whether OFED backports have cpumask_of_node])
 168         # Some OFED has cpumask_of_node backports defined in
 169         # its private include/linux/cpumask.h. However, it is
 170         # defined conflictingly with kernel's cpumask_of_node.
 171         if test -f $OFED_BACKPORT_PATH/linux/cpumask.h; then
 172                 grep -q cpumask_of_node $OFED_BACKPORT_PATH/linux/cpumask.h 2>/dev/null
 173                 rc=$?
 174                 if test $rc -eq 0; then
 175                         AC_DEFINE(HAVE_OFED_CPUMASK_OF_NODE, 1, [have cpumask_of_node])
 176                         AC_MSG_RESULT(yes)
 177                 else
 178                         AC_MSG_RESULT(no)
 179                 fi
 180         fi
 181
 182         AC_MSG_CHECKING([whether have cpumask_of_node])
 183         LB_LINUX_TRY_COMPILE([
 184                 #include <linux/topology.h>
 185         ],[
 186                 cpumask_t *mask = cpumask_of_node(0);
 187         ],[
 188                 AC_DEFINE(HAVE_CPUMASK_OF_NODE, 1, [have cpumask_of_node])
 189                 AC_MSG_RESULT(yes)
 190         ],[
 191                 AC_MSG_RESULT(no)
 192         ])
 193
 194         AC_MSG_CHECKING([whether have cpumask_copy])
 195         LB_LINUX_TRY_COMPILE([
 196                 #include <linux/cpumask.h>
 197         ],[
 198                 cpumask_copy(NULL, NULL);
 199         ],[
 200                 AC_DEFINE(HAVE_CPUMASK_COPY, 1, [have cpumask_copy])
 201                 AC_MSG_RESULT(yes)
 202         ],[
 203                 AC_MSG_RESULT(no)
 204         ])
 205
 206         AC_MSG_CHECKING([whether have node_to_cpumask])
 207         LB_LINUX_TRY_COMPILE([
 208                 #include <linux/topology.h>
 209         ],[
 210                 cpumask_t mask = node_to_cpumask(0);
 211         ],[
 212                 AC_DEFINE(HAVE_NODE_TO_CPUMASK, 1, [have node_to_cpumask])
 213                 AC_MSG_RESULT(yes)
 214         ],[
 215                 AC_MSG_RESULT(no)
 216         ])
 217 ],[
 218         AC_MSG_RESULT(NO)
 219 ])
 220 ])
 221
 222
 223 # 2.6.24 request not use real numbers for ctl_name
 224 AC_DEFUN([LIBCFS_SYSCTL_UNNUMBERED],
 225 [AC_MSG_CHECKING([for CTL_UNNUMBERED])
 226 LB_LINUX_TRY_COMPILE([
 227         #include <linux/sysctl.h>
 228 ],[
 229         #ifndef CTL_UNNUMBERED
 230         #error CTL_UNNUMBERED not exist in kernel
 231         #endif
 232 ],[
 233         AC_MSG_RESULT(yes)
 234         AC_DEFINE(HAVE_SYSCTL_UNNUMBERED, 1,
 235                   [sysctl has CTL_UNNUMBERED])
 236 ],[
 237         AC_MSG_RESULT(NO)
 238 ])
 239 ])
 240
 241 #
 242 # LIBCFS_FUNC_DUMP_TRACE
 243 #
 244 # 2.6.23 exports dump_trace() so we can dump_stack() on any task
 245 # 2.6.24 has stacktrace_ops.address with "reliable" parameter
 246 #
 247 AC_DEFUN([LIBCFS_FUNC_DUMP_TRACE],
 248 [LB_CHECK_SYMBOL_EXPORT([dump_trace],
 249 [kernel/ksyms.c arch/${LINUX_ARCH%_64}/kernel/traps_64.c arch/x86/kernel/dumpstack_32.c arch/x86/kernel/dumpstack_64.c],[
 250         tmp_flags="$EXTRA_KCFLAGS"
 251         EXTRA_KCFLAGS="-Werror"
 252         AC_MSG_CHECKING([whether we can really use dump_trace])
 253         LB_LINUX_TRY_COMPILE([
 254                 struct task_struct;
 255                 struct pt_regs;
 256                 #include <asm/stacktrace.h>
 257         ],[
 258         ],[
 259                 AC_MSG_RESULT(yes)
 260                 AC_DEFINE(HAVE_DUMP_TRACE, 1, [dump_trace is exported])
 261         ],[
 262                 AC_MSG_RESULT(no)
 263         ],[
 264         ])
 265         AC_MSG_CHECKING([whether print_trace_address has reliable argument])
 266         LB_LINUX_TRY_COMPILE([
 267                 struct task_struct;
 268                 struct pt_regs;
 269                 #include <asm/stacktrace.h>
 270         ],[
 271                 ((struct stacktrace_ops *)0)->address(NULL, 0, 0);
 272         ],[
 273                 AC_MSG_RESULT(yes)
 274                 AC_DEFINE(HAVE_TRACE_ADDRESS_RELIABLE, 1,
 275                           [print_trace_address has reliable argument])
 276         ],[
 277                 AC_MSG_RESULT(no)
 278         ],[
 279         ])
 280         AC_MSG_CHECKING([whether stacktrace_ops.warning is exist])
 281         LB_LINUX_TRY_COMPILE([
 282                 struct task_struct;
 283                 struct pt_regs;
 284                 #include <asm/stacktrace.h>
 285         ],[
 286                 ((struct stacktrace_ops *)0)->warning(NULL, NULL);
 287         ],[
 288                 AC_MSG_RESULT(yes)
 289                 AC_DEFINE(HAVE_STACKTRACE_WARNING, 1, [stacktrace_ops.warning is exist])
 290         ],[
 291                 AC_MSG_RESULT(no)
 292         ],[
 293         ])
 294         AC_MSG_CHECKING([dump_trace want address])
 295         LB_LINUX_TRY_COMPILE([
 296                 struct task_struct;
 297                 struct pt_regs;
 298                 #include <asm/stacktrace.h>
 299         ],[
 300                 dump_trace(NULL, NULL, NULL, 0, NULL, NULL);
 301         ],[
 302                 AC_MSG_RESULT(yes)
 303                 AC_DEFINE(HAVE_DUMP_TRACE_ADDRESS, 1,
 304                           [dump_trace want address argument])
 305         ],[
 306                 AC_MSG_RESULT(no)
 307         ],[
 308         ])
 309
 310 EXTRA_KCFLAGS="$tmp_flags"
 311 ])
 312 ])
 313
 314
 315 # 2.6.27 have second argument to sock_map_fd
 316 AC_DEFUN([LIBCFS_SOCK_MAP_FD_2ARG],
 317 [AC_MSG_CHECKING([sock_map_fd have second argument])
 318 LB_LINUX_TRY_COMPILE([
 319         #include <linux/net.h>
 320 ],[
 321         sock_map_fd(NULL, 0);
 322 ],[
 323         AC_MSG_RESULT(yes)
 324         AC_DEFINE(HAVE_SOCK_MAP_FD_2ARG, 1,
 325                   [sock_map_fd have second argument])
 326 ],[
 327         AC_MSG_RESULT(NO)
 328 ])
 329 ])
 330
 331 #
 332 # LIBCFS_HAVE_IS_COMPAT_TASK
 333 #
 334 # Added in 2.6.17, it wasn't until 2.6.29 that all
 335 # Linux architectures have is_compat_task()
 336 #
 337 AC_DEFUN([LIBCFS_HAVE_IS_COMPAT_TASK],
 338 [AC_MSG_CHECKING([if is_compat_task() is declared])
 339 LB_LINUX_TRY_COMPILE([
 340         #include <linux/compat.h>
 341 ],[
 342         int i __attribute__ ((unused));
 343         i = is_compat_task();
 344 ],[
 345         AC_MSG_RESULT([yes])
 346         AC_DEFINE(HAVE_IS_COMPAT_TASK, 1, [is_compat_task() is available])
 347 ],[
 348         AC_MSG_RESULT([no])
 349 ])
 350 ])
 351
 352 #
 353 # LIBCFS_STACKTRACE_OPS_HAVE_WALK_STACK
 354 #
 355 # 2.6.32-30.el6 adds a new 'walk_stack' field in 'struct stacktrace_ops'
 356 #
 357 AC_DEFUN([LIBCFS_STACKTRACE_OPS_HAVE_WALK_STACK],
 358 [AC_MSG_CHECKING([if 'struct stacktrace_ops' has 'walk_stack' field])
 359 LB_LINUX_TRY_COMPILE([
 360         #include <asm/stacktrace.h>
 361 ],[
 362         ((struct stacktrace_ops *)0)->walk_stack(NULL, NULL, 0, NULL, NULL, NULL, NULL);
 363 ],[
 364         AC_MSG_RESULT([yes])
 365         AC_DEFINE(STACKTRACE_OPS_HAVE_WALK_STACK, 1, ['struct stacktrace_ops' has 'walk_stack' field])
 366 ],[
 367         AC_MSG_RESULT([no])
 368 ])
 369 ])
 370
 371 AC_DEFUN([LIBCFS_HAVE_KEYTYPE_H],
 372 [LB_CHECK_FILE([$LINUX/include/linux/key-type.h], [
 373         AC_DEFINE(HAVE_LINUX_KEYTYPE_H, 1,
 374                 [kernel has include/key-type.h])
 375 ],[
 376         AC_MSG_RESULT([no])
 377 ])
 378 ])
 379
 380 #
 381 # RHEL6/2.6.32 want to have pointer to shrinker self pointer in handler function
 382 #
 383 AC_DEFUN([LC_SHRINKER_WANT_SHRINK_PTR],
 384 [AC_MSG_CHECKING([shrinker want self pointer in handler])
 385 LB_LINUX_TRY_COMPILE([
 386         #include <linux/mm.h>
 387 ],[
 388         struct shrinker *tmp = NULL;
 389         tmp->shrink(tmp, 0, 0);
 390 ],[
 391         AC_MSG_RESULT(yes)
 392         AC_DEFINE(HAVE_SHRINKER_WANT_SHRINK_PTR, 1,
 393                   [shrinker want self pointer in handler])
 394 ],[
 395         AC_MSG_RESULT(no)
 396 ])
 397 ])
 398
 399 #
 400 # 2.6.33 no longer has ctl_name & strategy field in struct ctl_table.
 401 #
 402 AC_DEFUN([LIBCFS_SYSCTL_CTLNAME],
 403 [AC_MSG_CHECKING([if ctl_table has a ctl_name field])
 404 LB_LINUX_TRY_COMPILE([
 405         #include <linux/sysctl.h>
 406 ],[
 407         struct ctl_table ct;
 408         ct.ctl_name = sizeof(ct);
 409 ],[
 410         AC_MSG_RESULT(yes)
 411         AC_DEFINE(HAVE_SYSCTL_CTLNAME, 1,
 412                   [ctl_table has ctl_name field])
 413 ],[
 414         AC_MSG_RESULT(no)
 415 ])
 416 ])
 417
 418 #
 419 # LIBCFS_ADD_WAIT_QUEUE_EXCLUSIVE
 420 #
 421 # 2.6.34 adds __add_wait_queue_exclusive
 422 #
 423 AC_DEFUN([LIBCFS_ADD_WAIT_QUEUE_EXCLUSIVE],
 424 [AC_MSG_CHECKING([if __add_wait_queue_exclusive exists])
 425 LB_LINUX_TRY_COMPILE([
 426         #include <linux/wait.h>
 427 ],[
 428         wait_queue_head_t queue;
 429         wait_queue_t      wait;
 430
 431         __add_wait_queue_exclusive(&queue, &wait);
 432 ],[
 433         AC_MSG_RESULT(yes)
 434         AC_DEFINE(HAVE___ADD_WAIT_QUEUE_EXCLUSIVE, 1,
 435                   [__add_wait_queue_exclusive exists])
 436 ],[
 437         AC_MSG_RESULT(no)
 438 ])
 439 ])
 440
 441 #
 442 # 2.6.35 kernel has sk_sleep function
 443 #
 444 AC_DEFUN([LC_SK_SLEEP],
 445 [AC_MSG_CHECKING([if kernel has sk_sleep])
 446 LB_LINUX_TRY_COMPILE([
 447         #include <net/sock.h>
 448 ],[
 449         sk_sleep(NULL);
 450 ],[
 451         AC_MSG_RESULT(yes)
 452         AC_DEFINE(HAVE_SK_SLEEP, 1, [kernel has sk_sleep])
 453 ],[
 454         AC_MSG_RESULT(no)
 455 ])
 456 ])
 457
 458 #
 459 # FC15 2.6.40-5 backported the "shrink_control" parameter to the memory
 460 # pressure shrinker from Linux 3.0
 461 #
 462 AC_DEFUN([LC_SHRINK_CONTROL],
 463 [AC_MSG_CHECKING([shrink_control is present])
 464 LB_LINUX_TRY_COMPILE([
 465         #include <linux/mm.h>
 466 ],[
 467         struct shrink_control tmp = {0};
 468         tmp.nr_to_scan = sizeof(tmp);
 469 ],[
 470         AC_MSG_RESULT(yes)
 471         AC_DEFINE(HAVE_SHRINK_CONTROL, 1,
 472                   [shrink_control is present])
 473 ],[
 474         AC_MSG_RESULT(no)
 475 ])
 476 ])
 477
 478 #
 479 # FC18 3.7.2-201 unexport sock_map_fd() change to
 480 # use sock_alloc_file().
 481 # upstream commit 56b31d1c9f1e6a3ad92e7bfe252721e05d92b285
 482 #
 483 AC_DEFUN([LIBCFS_SOCK_ALLOC_FILE],
 484 [AC_MSG_CHECKING([sock_alloc_file is exported])
 485 LB_CHECK_SYMBOL_EXPORT([sock_alloc_file], [net/socket.c],[
 486         LB_LINUX_TRY_COMPILE([
 487                 #include <linux/net.h>
 488         ],[
 489                 sock_alloc_file(NULL, 0, NULL);
 490         ],[
 491                 AC_MSG_RESULT(yes)
 492                 AC_DEFINE(HAVE_SOCK_ALLOC_FILE_3ARGS, 1,
 493                         [sock_alloc_file takes 3 arguments])
 494         ],[
 495                 AC_MSG_RESULT(yes)
 496                 AC_DEFINE(HAVE_SOCK_ALLOC_FILE, 1,
 497                         [sock_alloc_file is exported])
 498         ])
 499 ],[
 500 ])
 501 ])
 502
 503 #
 504 # LIBCFS_PROG_LINUX
 505 #
 506 # LNet linux kernel checks
 507 #
 508 AC_DEFUN([LIBCFS_PROG_LINUX],
 509 [
 510 LIBCFS_CONFIG_PANIC_DUMPLOG
 511
 512 LIBCFS_U64_LONG_LONG_LINUX
 513 # 2.6.18
 514 LIBCFS_HAVE_IS_COMPAT_TASK
 515 # 2.6.24
 516 LIBCFS_SYSCTL_UNNUMBERED
 517 LIBCFS_FUNC_DUMP_TRACE
 518 LIBCFS_HAVE_KEYTYPE_H
 519 # 2.6.28
 520 LIBCFS_CPUMASK_SIZE
 521 # 2.6.29
 522 LIBCFS_CPU_TOPOLOGY
 523 # 2.6.30
 524 LIBCFS_SOCK_MAP_FD_2ARG
 525 # 2.6.32
 526 LIBCFS_STACKTRACE_OPS_HAVE_WALK_STACK
 527 LC_SHRINKER_WANT_SHRINK_PTR
 528 # 2.6.33
 529 LIBCFS_SYSCTL_CTLNAME
 530 # 2.6.34
 531 LIBCFS_ADD_WAIT_QUEUE_EXCLUSIVE
 532 # 2.6.35
 533 LC_SK_SLEEP
 534 # 2.6.40 fc15
 535 LC_SHRINK_CONTROL
 536 # 3.7
 537 LIBCFS_SOCK_ALLOC_FILE
 538 ])
 539
 540 #
 541 # LIBCFS_PROG_DARWIN
 542 #
 543 # Darwin checks
 544 #
 545 AC_DEFUN([LIBCFS_PROG_DARWIN],
 546 [LB_DARWIN_CHECK_FUNCS([get_preemption_level])
 547 ])
 548
 549 #
 550 # LIBCFS_PATH_DEFAULTS
 551 #
 552 # default paths for installed files
 553 #
 554 AC_DEFUN([LIBCFS_PATH_DEFAULTS],
 555 [
 556 ])
 557
 558 #
 559 # LIBCFS_CONFIGURE
 560 #
 561 # other configure checks
 562 #
 563 AC_DEFUN([LIBCFS_CONFIGURE],
 564 [# lnet/utils/portals.c
 565 AC_CHECK_HEADERS([asm/types.h endian.h sys/ioctl.h])
 566
 567 # lnet/utils/debug.c
 568 AC_CHECK_HEADERS([linux/version.h])
 569
 570 AC_CHECK_TYPE([spinlock_t],
 571         [AC_DEFINE(HAVE_SPINLOCK_T, 1, [spinlock_t is defined])],
 572         [],
 573         [#include <linux/spinlock.h>])
 574
 575 # lnet/utils/wirecheck.c
 576 AC_CHECK_FUNCS([strnlen])
 577
 578 # lnet/libcfs/user-prim.c, missing for RHEL5 and earlier userspace
 579 AC_CHECK_FUNCS([strlcpy])
 580
 581 # libcfs/libcfs/user-prim.c, missing for RHEL5 and earlier userspace
 582 AC_CHECK_FUNCS([strlcat])
 583
 584 AC_CHECK_TYPE([umode_t],
 585         [AC_DEFINE(HAVE_UMODE_T, 1, [umode_t is defined])],
 586         [],
 587         [#include <asm/types.h>])
 588
 589 AC_CHECK_TYPE([__s8],
 590         [AC_DEFINE(HAVE___S8, 1, [__s8 is defined])],
 591         [],
 592         [#include <asm/types.h>])
 593
 594 AC_CHECK_TYPE([__u8],
 595         [AC_DEFINE(HAVE___U8, 1, [__u8 is defined])],
 596         [],
 597         [#include <asm/types.h>])
 598
 599 AC_CHECK_TYPE([__s16],
 600         [AC_DEFINE(HAVE___S16, 1, [__s16 is defined])],
 601         [],
 602         [#include <asm/types.h>])
 603
 604 AC_CHECK_TYPE([__u16],
 605         [AC_DEFINE(HAVE___U16, 1, [__u16 is defined])],
 606         [],
 607         [#include <asm/types.h>])
 608
 609 AC_CHECK_TYPE([__s32],
 610         [AC_DEFINE(HAVE___S32, 1, [__s32 is defined])],
 611         [],
 612         [#include <asm/types.h>])
 613
 614 AC_CHECK_TYPE([__u32],
 615         [AC_DEFINE(HAVE___U32, 1, [__u32 is defined])],
 616         [],
 617         [#include <asm/types.h>])
 618
 619 AC_CHECK_TYPE([__u64],
 620         [AC_DEFINE(HAVE___U64, 1, [__u64 is defined])],
 621         [],
 622         [#include <asm/types.h>])
 623
 624 AC_CHECK_TYPE([__s64],
 625         [AC_DEFINE(HAVE___S64, 1, [__s64 is defined])],
 626         [],
 627         [#include <asm/types.h>])
 628
 629 # check userland __u64 type
 630 AC_MSG_CHECKING([userspace __u64 is long long type])
 631 tmp_flags="$CFLAGS"
 632 CFLAGS="$CFLAGS -Werror"
 633 AC_COMPILE_IFELSE([
 634         #include <stdio.h>
 635         #include <linux/types.h>
 636         #include <linux/stddef.h>
 637         int main(void) {
 638                 unsigned long long *data1;
 639                 __u64 *data2 = NULL;
 640
 641                 data1 = data2;
 642                 data2 = data1;
 643                 return 0;
 644         }
 645 ],[
 646         AC_MSG_RESULT([yes])
 647         AC_DEFINE(HAVE_USER__U64_LONG_LONG, 1,
 648                   [__u64 is long long type])
 649 ],[
 650         AC_MSG_RESULT([no])
 651 ])
 652 CFLAGS="$tmp_flags"
 653
 654 # --------  Check for required packages  --------------
 655
 656
 657 AC_MSG_CHECKING([if efence debugging support is requested])
 658 AC_ARG_ENABLE(efence,
 659         AC_HELP_STRING([--enable-efence],
 660                         [use efence library]),
 661         [],[enable_efence='no'])
 662 AC_MSG_RESULT([$enable_efence])
 663 if test "$enable_efence" = "yes" ; then
 664         LIBEFENCE="-lefence"
 665         AC_DEFINE(HAVE_LIBEFENCE, 1, [libefence support is requested])
 666 else
 667         LIBEFENCE=""
 668 fi
 669 AC_SUBST(LIBEFENCE)
 670
 671
 672 # -------- check for -lpthread support ----
 673 AC_MSG_CHECKING([whether to use libpthread for libcfs library])
 674 AC_ARG_ENABLE([libpthread],
 675         AC_HELP_STRING([--disable-libpthread],
 676                 [disable libpthread]),
 677         [],[enable_libpthread=yes])
 678 if test "$enable_libpthread" = "yes" ; then
 679         AC_CHECK_LIB([pthread], [pthread_create],
 680                 [ENABLE_LIBPTHREAD="yes"],
 681                 [ENABLE_LIBPTHREAD="no"])
 682         if test "$ENABLE_LIBPTHREAD" = "yes" ; then
 683                 AC_MSG_RESULT([$ENABLE_LIBPTHREAD])
 684                 PTHREAD_LIBS="-lpthread"
 685                 AC_DEFINE([HAVE_LIBPTHREAD], 1, [use libpthread])
 686         else
 687                 PTHREAD_LIBS=""
 688                 AC_MSG_RESULT([no libpthread is found])
 689         fi
 690         AC_SUBST(PTHREAD_LIBS)
 691 else
 692         AC_MSG_RESULT([no (disabled explicitly)])
 693         ENABLE_LIBPTHREAD="no"
 694 fi
 695 AC_SUBST(ENABLE_LIBPTHREAD)
 696
 697
 698 ])
 699
 700 #
 701 # LIBCFS_CONDITIONALS
 702 #
 703 # AM_CONDITOINAL defines for lnet
 704 #
 705 AC_DEFUN([LIBCFS_CONDITIONALS],
 706 [
 707 ])
 708
 709 #
 710 # LIBCFS_CONFIG_FILES
 711 #
 712 # files that should be generated with AC_OUTPUT
 713 #
 714 AC_DEFUN([LIBCFS_CONFIG_FILES],
 715 [AC_CONFIG_FILES([
 716 libcfs/Kernelenv
 717 libcfs/Makefile
 718 libcfs/autoMakefile
 719 libcfs/autoconf/Makefile
 720 libcfs/include/Makefile
 721 libcfs/include/libcfs/Makefile
 722 libcfs/include/libcfs/linux/Makefile
 723 libcfs/include/libcfs/posix/Makefile
 724 libcfs/include/libcfs/util/Makefile
 725 libcfs/libcfs/Makefile
 726 libcfs/libcfs/autoMakefile
 727 libcfs/libcfs/linux/Makefile
 728 libcfs/libcfs/posix/Makefile
 729 libcfs/libcfs/util/Makefile
 730 libcfs/include/libcfs/darwin/Makefile
 731 libcfs/libcfs/darwin/Makefile
 732 ])
 733 ])