libcfs/autoconf/lustre-libcfs.m4

   1 #
   2 # LIBCFS_CONFIG_CDEBUG
   3 #
   4 # whether to enable various libcfs debugs (CDEBUG, ENTRY/EXIT, LASSERT, etc.)
   5 #
   6 AC_DEFUN([LIBCFS_CONFIG_CDEBUG], [
   7 AC_MSG_CHECKING([whether to enable CDEBUG, CWARN])
   8 AC_ARG_ENABLE([libcfs_cdebug],
   9         AC_HELP_STRING([--disable-libcfs-cdebug],
  10                 [disable libcfs CDEBUG, CWARN]),
  11         [], [enable_libcfs_cdebug="yes"])
  12 AC_MSG_RESULT([$enable_libcfs_cdebug])
  13 AS_IF([test "x$enable_libcfs_cdebug" = xyes],
  14         [AC_DEFINE(CDEBUG_ENABLED, 1, [enable libcfs CDEBUG, CWARN])])
  15
  16 AC_MSG_CHECKING([whether to enable ENTRY/EXIT])
  17 AC_ARG_ENABLE([libcfs_trace],
  18         AC_HELP_STRING([--disable-libcfs-trace],
  19                 [disable libcfs ENTRY/EXIT]),
  20         [], [enable_libcfs_trace="yes"])
  21 AC_MSG_RESULT([$enable_libcfs_trace])
  22 AS_IF([test "x$enable_libcfs_trace" = xyes],
  23         [AC_DEFINE(CDEBUG_ENTRY_EXIT, 1, [enable libcfs ENTRY/EXIT])])
  24
  25 AC_MSG_CHECKING([whether to enable LASSERT, LASSERTF])
  26 AC_ARG_ENABLE([libcfs_assert],
  27         AC_HELP_STRING([--disable-libcfs-assert],
  28                 [disable libcfs LASSERT, LASSERTF]),
  29         [], [enable_libcfs_assert="yes"])
  30 AC_MSG_RESULT([$enable_libcfs_assert])
  31 AS_IF([test x$enable_libcfs_assert = xyes],
  32         [AC_DEFINE(LIBCFS_DEBUG, 1, [enable libcfs LASSERT, LASSERTF])])
  33 ]) # LIBCFS_CONFIG_CDEBUG
  34
  35 #
  36 # LIBCFS_CONFIG_PANIC_DUMPLOG
  37 #
  38 # check if tunable panic_dumplog is wanted
  39 #
  40 AC_DEFUN([LIBCFS_CONFIG_PANIC_DUMPLOG], [
  41 AC_MSG_CHECKING([whether to use tunable 'panic_dumplog' support])
  42 AC_ARG_ENABLE([panic_dumplog],
  43         AC_HELP_STRING([--enable-panic_dumplog],
  44                 [enable panic_dumplog]),
  45         [], [enable_panic_dumplog="no"])
  46 AC_MSG_RESULT([$enable_panic_dumplog])
  47 AS_IF([test "x$enable_panic_dumplog" = xyes],
  48         [AC_DEFINE(LNET_DUMP_ON_PANIC, 1, [use dumplog on panic])])
  49 ]) # LIBCFS_CONFIG_PANIC_DUMPLOG
  50
  51 #
  52 # Kernel version 3.11 introduced ktime_get_ts64
  53 #
  54 AC_DEFUN([LIBCFS_KTIME_GET_TS64],[
  55 LB_CHECK_COMPILE([does function 'ktime_get_ts64' exist],
  56 ktime_get_ts64, [
  57         #include <linux/hrtimer.h>
  58         #include <linux/ktime.h>
  59 ],[
  60         struct timespec64 *ts = NULL;
  61
  62         ktime_get_ts64(ts);
  63 ],[
  64         AC_DEFINE(HAVE_KTIME_GET_TS64, 1,
  65                 ['ktime_get_ts64' is available])
  66 ])
  67 ]) # LIBCFS_KTIME_GET_TS64
  68
  69 #
  70 # Kernel version 3.12-rc4 commit c2d816443ef30 added prepare_to_wait_event()
  71 #
  72 AC_DEFUN([LIBCFS_PREPARE_TO_WAIT_EVENT],[
  73 LB_CHECK_COMPILE([does function 'prepare_to_wait_event' exist],
  74 prepare_to_wait_event, [
  75         #include <linux/wait.h>
  76 ],[
  77         prepare_to_wait_event(NULL, NULL, 0);
  78 ],[
  79         AC_DEFINE(HAVE_PREPARE_TO_WAIT_EVENT, 1,
  80                 ['prepare_to_wait_event' is available])
  81 ])
  82 ]) # LIBCFS_PREPARE_TO_WAIT_EVENT
  83
  84 #
  85 # Linux kernel 3.12 introduced struct kernel_param_ops
  86 # This has been backported to all lustre supported
  87 # clients except RHEL6. We have to handle the differences.
  88 #
  89 AC_DEFUN([LIBCFS_KERNEL_PARAM_OPS],[
  90 LB_CHECK_COMPILE([does 'struct kernel_param_ops' exist],
  91 kernel_param_ops, [
  92         #include <linux/module.h>
  93 ],[
  94         struct kernel_param_ops ops;
  95
  96         ops.set = NULL;
  97 ],[
  98         AC_DEFINE(HAVE_KERNEL_PARAM_OPS, 1,
  99                 ['struct kernel_param_ops' is available])
 100 ])
 101 ]) # LIBCFS_KERNEL_PARAM_OPS
 102
 103 #
 104 # Kernel version 3.12 introduced ktime_add
 105 #
 106 AC_DEFUN([LIBCFS_KTIME_ADD],[
 107 LB_CHECK_COMPILE([does function 'ktime_add' exist],
 108 ktime_add, [
 109         #include <linux/hrtimer.h>
 110         #include <linux/ktime.h>
 111 ],[
 112         ktime_t start = ktime_set(0, 0);
 113         ktime_t end = start;
 114         ktime_t total;
 115
 116         total = ktime_add(start, end);
 117 ],[
 118         AC_DEFINE(HAVE_KTIME_ADD, 1,
 119                 [ktime_add is available])
 120 ])
 121 ]) # LIBCFS_KTIME_ADD
 122
 123 #
 124 # Kernel version 3.12 introduced ktime_after
 125 #
 126 AC_DEFUN([LIBCFS_KTIME_AFTER],[
 127 LB_CHECK_COMPILE([does function 'ktime_after' exist],
 128 ktime_after, [
 129         #include <linux/hrtimer.h>
 130         #include <linux/ktime.h>
 131 ],[
 132         ktime_t start = ktime_set(0, 0);
 133         ktime_t end = start;
 134
 135         ktime_after(start, end);
 136 ],[
 137         AC_DEFINE(HAVE_KTIME_AFTER, 1,
 138                 [ktime_after is available])
 139 ])
 140 ]) # LIBCFS_KTIME_AFTER
 141
 142 #
 143 # Kernel version 3.12 introduced ktime_before
 144 # See linux commit 67cb9366ff5f99868100198efba5ca88aaa6ad25
 145 #
 146 AC_DEFUN([LIBCFS_KTIME_BEFORE],[
 147 LB_CHECK_COMPILE([does function 'ktime_before' exist],
 148 ktime_before, [
 149         #include <linux/hrtimer.h>
 150         #include <linux/ktime.h>
 151 ],[
 152         ktime_t start = ktime_set(0, 0);
 153         ktime_t end = start;
 154
 155         ktime_before(start, end);
 156 ],[
 157         AC_DEFINE(HAVE_KTIME_BEFORE, 1,
 158                 [ktime_before is available])
 159 ])
 160 ]) # LIBCFS_KTIME_BEFORE
 161
 162 #
 163 # Kernel version 3.12 introduced ktime_compare
 164 #
 165 AC_DEFUN([LIBCFS_KTIME_COMPARE],[
 166 LB_CHECK_COMPILE([does function 'ktime_compare' exist],
 167 ktime_compare, [
 168         #include <linux/hrtimer.h>
 169         #include <linux/ktime.h>
 170 ],[
 171         ktime_t start = ktime_set(0, 0);
 172         ktime_t end = start;
 173
 174         ktime_compare(start, end);
 175 ],[
 176         AC_DEFINE(HAVE_KTIME_COMPARE, 1,
 177                 [ktime_compare is available])
 178 ])
 179 ]) # LIBCFS_KTIME_COMPARE
 180
 181 #
 182 # FC19 3.12 kernel struct shrinker change
 183 #
 184 AC_DEFUN([LIBCFS_SHRINKER_COUNT],[
 185 LB_CHECK_COMPILE([shrinker has 'count_objects'],
 186 shrinker_count_objects, [
 187         #include <linux/mmzone.h>
 188         #include <linux/shrinker.h>
 189 ],[
 190         struct shrinker shrinker;
 191
 192         shrinker.count_objects = NULL;
 193 ],[
 194         AC_DEFINE(HAVE_SHRINKER_COUNT, 1,
 195                 [shrinker has count_objects member])
 196 ])
 197 ]) # LIBCFS_SHRINKER_COUNT
 198
 199 #
 200 # LIBCFS_IOV_ITER_HAS_TYPE
 201 #
 202 # kernel 3.15-rc4 commit 71d8e532b1549a478e6a6a8a44f309d050294d00
 203 # start adding the tag to iov_iter
 204 #
 205 AC_DEFUN([LIBCFS_IOV_ITER_HAS_TYPE], [
 206 tmp_flags="$EXTRA_KCFLAGS"
 207 EXTRA_KCFLAGS="-Werror"
 208 LB_CHECK_COMPILE([if iov_iter has member type],
 209 iov_iter_has_type_member, [
 210         #include <linux/uio.h>
 211 ],[
 212         struct iov_iter iter = { .type = ITER_KVEC };
 213         (void)iter;
 214 ],[
 215         AC_DEFINE(HAVE_IOV_ITER_HAS_TYPE_MEMBER, 1,
 216                 [if iov_iter has member type])
 217 ])
 218 EXTRA_KCFLAGS="$tmp_flags"
 219 ]) # LIBCFS_IOV_ITER_HAS_TYPE
 220
 221 #
 222 # LIBCFS_HAVE_NS_TO_TIMESPEC64
 223 #
 224 # Kernel version 4.16-rc3 commit a84d1169164b274f13b97a23ff235c000efe3b49
 225 # introduced struct __kernel_old_timeval
 226 #
 227 AC_DEFUN([LIBCFS_HAVE_NS_TO_TIMESPEC64],[
 228 LB_CHECK_COMPILE([does 'ns_to_timespec64()' exist],
 229 kernel_old_timeval, [
 230         #include <linux/time.h>
 231 ],[
 232         struct timespec64 kts;
 233
 234         kts = ns_to_timespec64(0);
 235 ],[
 236         AC_DEFINE(HAVE_NS_TO_TIMESPEC64, 1,
 237                 [ns_to_timespec64() is available])
 238 ])
 239 ]) # LIBCFS_HAVE_NS_TO_TIMESPEC64
 240
 241 #
 242 # Kernel version 3.17 changed hlist_add_after to
 243 # hlist_add_behind
 244 #
 245 AC_DEFUN([LIBCFS_HLIST_ADD_AFTER],[
 246 LB_CHECK_COMPILE([does function 'hlist_add_after' exist],
 247 hlist_add_after, [
 248         #include <linux/list.h>
 249 ],[
 250         hlist_add_after(NULL, NULL);
 251 ],[
 252         AC_DEFINE(HAVE_HLIST_ADD_AFTER, 1,
 253                 [hlist_add_after is available])
 254 ])
 255 ]) # LIBCFS_HLIST_ADD_AFTER
 256
 257 #
 258 # Kernel version 3.17 introduced struct timespec64
 259 #
 260 AC_DEFUN([LIBCFS_TIMESPEC64],[
 261 LB_CHECK_COMPILE([does 'struct timespec64' exist],
 262 timespec64, [
 263         #include <linux/time.h>
 264 ],[
 265         struct timespec64 ts;
 266
 267         ts.tv_sec = 0;
 268         ts.tv_nsec = 0;
 269 ],[
 270         AC_DEFINE(HAVE_TIMESPEC64, 1,
 271                 ['struct timespec64' is available])
 272 ])
 273 ]) # LIBCFS_TIMESPEC64
 274
 275 #
 276 # Kernel version 3.17 introduced ktime_get_real_ts64
 277 #
 278 AC_DEFUN([LIBCFS_KTIME_GET_REAL_TS64],[
 279 LB_CHECK_COMPILE([does function 'ktime_get_real_ts64' exist],
 280 ktime_get_real_ts64, [
 281         #include <linux/ktime.h>
 282 ],[
 283         struct timespec64 *ts = NULL;
 284
 285         ktime_get_real_ts64(ts);
 286 ],[
 287         AC_DEFINE(HAVE_KTIME_GET_REAL_TS64, 1,
 288                 ['ktime_get_real_ts64' is available])
 289 ])
 290 ]) # LIBCFS_KTIME_GET_REAL_TS64
 291
 292 #
 293 # Kernel version 3.17 introduced ktime_get_real_seconds
 294 #
 295 AC_DEFUN([LIBCFS_KTIME_GET_REAL_SECONDS],[
 296 LB_CHECK_COMPILE([does function 'ktime_get_real_seconds' exist],
 297 ktime_get_real_seconds, [
 298         #include <linux/hrtimer.h>
 299         #include <linux/ktime.h>
 300 ],[
 301         time64_t now;
 302
 303         now = ktime_get_real_seconds();
 304 ],[
 305         AC_DEFINE(HAVE_KTIME_GET_REAL_SECONDS, 1,
 306                 ['ktime_get_real_seconds' is available])
 307 ])
 308 ]) # LIBCFS_KTIME_GET_REAL_SECONDS
 309
 310 #
 311 # Kernel version 3.17 created ktime_get_ns wrapper
 312 #
 313 AC_DEFUN([LIBCFS_KTIME_GET_NS],[
 314 LB_CHECK_COMPILE([does function 'ktime_get_ns' exist],
 315 ktime_get_ns, [
 316         #include <linux/hrtimer.h>
 317         #include <linux/ktime.h>
 318 ],[
 319         u64 nanoseconds;
 320
 321         nanoseconds = ktime_get_ns();
 322 ],[],[
 323         AC_DEFINE(NEED_KTIME_GET_NS, 1,
 324                 ['ktime_get_ns' is not available])
 325 ])
 326 ]) # LIBCFS_KTIME_GET_NS
 327
 328 #
 329 # Kernel version 3.17 created ktime_get_real_ns wrapper
 330 #
 331 AC_DEFUN([LIBCFS_KTIME_GET_REAL_NS],[
 332 LB_CHECK_COMPILE([does function 'ktime_get_real_ns' exist],
 333 ktime_get_real_ns, [
 334         #include <linux/hrtimer.h>
 335         #include <linux/ktime.h>
 336 ],[
 337         u64 nanoseconds;
 338
 339         nanoseconds = ktime_get_real_ns();
 340 ],[],[
 341         AC_DEFINE(NEED_KTIME_GET_REAL_NS, 1,
 342                 ['ktime_get_real_ns' is not available])
 343 ])
 344 ]) # LIBCFS_KTIME_GET_REAL_NS
 345
 346 #
 347 # Kernel version 3.17 introduced ktime_to_timespec64
 348 #
 349 AC_DEFUN([LIBCFS_KTIME_TO_TIMESPEC64],[
 350 LB_CHECK_COMPILE([does function 'ktime_to_timespec64' exist],
 351 ktime_to_timespec64, [
 352         #include <linux/hrtimer.h>
 353         #include <linux/ktime.h>
 354 ],[
 355         ktime_t now = ktime_set(0, 0);
 356         struct timespec64 ts;
 357
 358         ts = ktime_to_timespec64(now);
 359 ],[
 360         AC_DEFINE(HAVE_KTIME_TO_TIMESPEC64, 1,
 361                 ['ktime_to_timespec64' is available])
 362 ])
 363 ]) # LIBCFS_KTIME_TO_TIMESPEC64
 364
 365 #
 366 # Kernel version 3.17 introduced timespec64_sub
 367 #
 368 AC_DEFUN([LIBCFS_TIMESPEC64_SUB],[
 369 LB_CHECK_COMPILE([does function 'timespec64_sub' exist],
 370 timespec64_sub, [
 371         #include <linux/time.h>
 372 ],[
 373         struct timespec64 later = { }, earlier = { }, diff;
 374
 375         diff = timespec64_sub(later, earlier);
 376 ],[
 377         AC_DEFINE(HAVE_TIMESPEC64_SUB, 1,
 378                 ['timespec64_sub' is available])
 379 ])
 380 ]) # LIBCFS_TIMESPEC64_SUB
 381
 382 #
 383 # Kernel version 3.17 introduced timespec64_to_ktime
 384 #
 385 AC_DEFUN([LIBCFS_TIMESPEC64_TO_KTIME],[
 386 LB_CHECK_COMPILE([does function 'timespec64_to_ktime' exist],
 387 timespec64_to_ktime, [
 388         #include <linux/ktime.h>
 389 ],[
 390         struct timespec64 ts;
 391         ktime_t now;
 392
 393         now = timespec64_to_ktime(ts);
 394 ],[
 395         AC_DEFINE(HAVE_TIMESPEC64_TO_KTIME, 1,
 396                 ['timespec64_to_ktime' is available])
 397 ])
 398 ]) # LIBCFS_TIMESPEC64_TO_KTIME
 399
 400 #
 401 # Kernel version 3.19 introduced ktime_get_seconds
 402 #
 403 AC_DEFUN([LIBCFS_KTIME_GET_SECONDS],[
 404 LB_CHECK_COMPILE([does function 'ktime_get_seconds' exist],
 405 ktime_get_seconds, [
 406         #include <linux/ktime.h>
 407 ],[
 408         time64_t now;
 409
 410         now = ktime_get_seconds();
 411 ],[
 412         AC_DEFINE(HAVE_KTIME_GET_SECONDS, 1,
 413                 ['ktime_get_seconds' is available])
 414 ])
 415 ]) # LIBCFS_KTIME_GET_SECONDS
 416
 417 #
 418 # Kernel version 4.0 commit 41fbf3b39d5eca01527338b4d0ee15ee1ae1023c
 419 # introduced the helper function ktime_ms_delta.
 420 #
 421 AC_DEFUN([LIBCFS_KTIME_MS_DELTA],[
 422 LB_CHECK_COMPILE([does function 'ktime_ms_delta' exist],
 423 ktime_ms_delta, [
 424         #include <linux/ktime.h>
 425 ],[
 426         ktime_t start = ktime_set(0, 0);
 427         ktime_t end = start;
 428
 429         ktime_ms_delta(start, end);
 430 ],[
 431         AC_DEFINE(HAVE_KTIME_MS_DELTA, 1,
 432                 ['ktime_ms_delta' is available])
 433 ])
 434 ]) # LIBCFS_KTIME_MS_DELTA
 435
 436 #
 437 # Kernel version 4.1 commit b51d23e4e9fea6f264d39535c2a62d1f51e7ccc3
 438 # create per module locks which added kernel_param_[un]lock(). Older
 439 # kernels you have to use __kernel_param_[un]lock(). In that case its
 440 # a global lock for all modules but that is okay since its a rare event.
 441 #
 442 AC_DEFUN([LIBCFS_KERNEL_PARAM_LOCK],[
 443 LB_CHECK_COMPILE([does function 'kernel_param_[un]lock' exist],
 444 kernel_param_lock, [
 445         #include <linux/moduleparam.h>
 446 ],[
 447         kernel_param_lock(NULL);
 448         kernel_param_unlock(NULL);
 449 ],[
 450         AC_DEFINE(HAVE_KERNEL_PARAM_LOCK, 1,
 451                 ['kernel_param_[un]lock' is available])
 452 ])
 453 ]) # LIBCFS_KERNEL_PARAM_LOCK
 454
 455 #
 456 # Kernel version 4.2 changed topology_thread_cpumask
 457 # to topology_sibling_cpumask
 458 #
 459 AC_DEFUN([LIBCFS_HAVE_TOPOLOGY_SIBLING_CPUMASK],[
 460 LB_CHECK_COMPILE([does function 'topology_sibling_cpumask' exist],
 461 topology_sibling_cpumask, [
 462         #include <linux/topology.h>
 463 ],[
 464         const struct cpumask *mask;
 465
 466         mask = topology_sibling_cpumask(0);
 467 ],[
 468         AC_DEFINE(HAVE_TOPOLOGY_SIBLING_CPUMASK, 1,
 469                 [topology_sibling_cpumask is available])
 470 ])
 471 ]) # LIBCFS_HAVE_TOPOLOGY_SIBLING_CPUMASK
 472
 473 #
 474 # Kernel version 4.4 commit ef951599074ba4fad2d0efa0a977129b41e6d203
 475 # introduced kstrtobool and kstrtobool_from_user.
 476 #
 477 AC_DEFUN([LIBCFS_KSTRTOBOOL_FROM_USER], [
 478 LB_CHECK_COMPILE([if Linux kernel has 'kstrtobool_from_user'],
 479 kstrtobool_from_user, [
 480         #include <linux/kernel.h>
 481 ],[
 482         bool result;
 483         return kstrtobool_from_user(NULL, 0, &result);
 484 ],[
 485         AC_DEFINE(HAVE_KSTRTOBOOL_FROM_USER, 1,
 486                 [kernel has kstrtobool_from_user])
 487 ])
 488 ]) # LIBCFS_KSTRTOBOOL_FROM_USER
 489
 490 #
 491 # LIBCFS_NETLINK_CALLBACK_START
 492 #
 493 # Kernel version 4.4-rc3 commit fc9e50f5a5a4e1fa9ba2756f745a13e693cf6a06
 494 # added a start function callback for struct netlink_callback
 495 #
 496 AC_DEFUN([LIBCFS_NETLINK_CALLBACK_START], [
 497 LB_CHECK_COMPILE([if struct genl_ops has start callback],
 498 cb_start, [
 499         #include <net/genetlink.h>
 500 ],[
 501         struct genl_ops ops;
 502
 503         ops.start = NULL;
 504 ],[
 505         AC_DEFINE(HAVE_NETLINK_CALLBACK_START, 1,
 506                 [struct genl_ops has 'start' callback])
 507 ])
 508 ]) # LIBCFS_NETLINK_CALLBACK_START
 509
 510 #
 511 # Kernel version 4.5-rc1 commit d12481bc58fba89427565f8592e88446ec084a24
 512 # added crypto hash helpers
 513 #
 514 AC_DEFUN([LIBCFS_CRYPTO_HASH_HELPERS], [
 515 LB_CHECK_COMPILE([does crypto hash helper functions exist],
 516 crypto_hash_helpers, [
 517         #include <crypto/hash.h>
 518 ],[
 519         crypto_ahash_alg_name(NULL);
 520         crypto_ahash_driver_name(NULL);
 521 ],[
 522         AC_DEFINE(HAVE_CRYPTO_HASH_HELPERS, 1,
 523                 [crypto hash helper functions are available])
 524 ])
 525 ]) # LIBCFS_CRYPTO_HASH_HELPERS
 526
 527 #
 528 # Kernel version 4.5-rc1 commit 3502cad73c4bbf8f6365d539e814159275252c59
 529 # introduced rhashtable_replace_fast
 530 #
 531 AC_DEFUN([LIBCFS_RHASHTABLE_REPLACE], [
 532 LB_CHECK_COMPILE([if 'rhashtable_replace_fast' exists],
 533 rhashtable_replace_fast, [
 534         #include <linux/rhashtable.h>
 535 ],[
 536         const struct rhashtable_params params = { 0 };
 537
 538         rhashtable_replace_fast(NULL, NULL, NULL, params);
 539 ],[
 540         AC_DEFINE(HAVE_RHASHTABLE_REPLACE, 1,
 541                 [rhashtable_replace_fast() is available])
 542 ])
 543 ]) # LIBCFS_RHASHTABLE_REPLACE
 544
 545 #
 546 # Kernel version 4.5-rc3 commit 2fe829aca9d7bed5fd6b49c6a1452e5e486b6cc3dd
 547 # made kset_find_obj() exportable to modules
 548 #
 549 AC_DEFUN([LIBCFS_EXPORT_KSET_FIND_OBJ], [
 550 LB_CHECK_EXPORT([kset_find_obj], [lib/kobject.c],
 551         [AC_DEFINE(HAVE_KSET_FIND_OBJ, 1,
 552                 [kset_find_obj is exported by the kernel])])
 553 ]) # LIBCFS_EXPORT_KSET_FIND_OBJ
 554
 555 #
 556 # Kernel version 4.6+ commit ef703f49a6c5b909a85149bb6625c4ed0d697186
 557 # fixed the brokenness of hash_64(). The fix removed GOLDEN_RATIO_PRIME_64
 558 # since it was a poor prime value.
 559 #
 560 AC_DEFUN([LIBCFS_BROKEN_HASH_64], [
 561 LB_CHECK_COMPILE([kernel has fixed hash_64()],
 562 broken_hash_64, [
 563         #include <linux/hash.h>
 564 ],[
 565         int tmp = GOLDEN_RATIO_PRIME_64;
 566 ],[
 567         AC_DEFINE(HAVE_BROKEN_HASH_64, 1, [kernel hash_64() is broken])
 568 ])
 569 ]) # LIBCFS_BROKEN_HASH_64
 570
 571 #
 572 # LIBCFS_STACKTRACE_OPS_ADDRESS_RETURN_INT
 573 #
 574 # linux 4.6 kernel changed stacktrace_ops address to return an int
 575 #
 576 AC_DEFUN([LIBCFS_STACKTRACE_OPS_ADDRESS_RETURN_INT], [
 577 LB_CHECK_COMPILE([if 'struct stacktrace_ops' address function returns an int],
 578 stacktrace_ops_address_return_int, [
 579         #include <asm/stacktrace.h>
 580 ],[
 581         int rc;
 582
 583         rc = ((struct stacktrace_ops *)0)->address(NULL, 0, 0);
 584 ],[
 585         AC_DEFINE(STACKTRACE_OPS_ADDRESS_RETURN_INT, 1,
 586                 ['struct stacktrace_ops' address function returns an int])
 587 ])
 588 ]) # LIBCFS_STACKTRACE_OPS_ADDRESS_RETURN_INT
 589
 590 #
 591 # Kernel version 4.6 removed both struct task_struct and struct mm_struct
 592 # arguments to get_user_pages
 593 #
 594 AC_DEFUN([LIBCFS_GET_USER_PAGES_6ARG], [
 595 LB_CHECK_COMPILE([if 'get_user_pages()' takes 6 arguments],
 596 get_user_pages_6arg, [
 597         #include <linux/mm.h>
 598 ],[
 599         int rc;
 600
 601         rc = get_user_pages(0, 0, 0, 0, NULL, NULL);
 602 ],[
 603         AC_DEFINE(HAVE_GET_USER_PAGES_6ARG, 1,
 604                 [get_user_pages takes 6 arguments])
 605 ])
 606 ]) # LIBCFS_GET_USER_PAGES_6ARG
 607
 608 #
 609 # LIBCFS_STRINGHASH
 610 #
 611 # 4.6 kernel created stringhash.h which moved stuff out of dcache.h
 612 # commit f4bcbe792b8f434e32487cff9d9e30ab45a3ce02
 613 #
 614 AC_DEFUN([LIBCFS_STRINGHASH], [
 615 LB_CHECK_LINUX_HEADER([linux/stringhash.h], [
 616         AC_DEFINE(HAVE_STRINGHASH, 1,
 617                 [stringhash.h is present])])
 618 ]) # LIBCFS_STRINGHASH
 619
 620 #
 621 # LIBCFS_RHASHTABLE_INSERT_FAST
 622 #
 623 # 4.7+ kernel commit 5ca8cc5bf11faed257c762018aea9106d529232f
 624 # changed __rhashtable_insert_fast to support the new function
 625 # rhashtable_lookup_get_insert_key().
 626 #
 627 AC_DEFUN([LIBCFS_RHASHTABLE_INSERT_FAST], [
 628 tmp_flags="$EXTRA_KCFLAGS"
 629 EXTRA_KCFLAGS="-Werror"
 630 LB_CHECK_COMPILE([if internal '__rhashtable_insert_fast()' returns int],
 631 rhashtable_insert_fast, [
 632         #include <linux/rhashtable.h>
 633 ],[
 634         const struct rhashtable_params params = { 0 };
 635         int rc;
 636
 637         rc = __rhashtable_insert_fast(NULL, NULL, NULL, params);
 638 ],[
 639         AC_DEFINE(HAVE_HASHTABLE_INSERT_FAST_RETURN_INT, 1,
 640                   ['__rhashtable_insert_fast()' returns int])
 641 ])
 642 EXTRA_KCFLAGS="$tmp_flags"
 643 ]) # LIBCFS_RHASHTABLE_INSERT_FAST
 644
 645 #
 646 # Kernel version 4.7-rc1 commit 8f6fd83c6c5ec66a4a70c728535ddcdfef4f3697
 647 # added 3rd arg to rhashtable_walk_init
 648 #
 649 AC_DEFUN([LIBCFS_RHASHTABLE_WALK_INIT_3ARG], [
 650 LB_CHECK_COMPILE([if 'rhashtable_walk_init' has 3 args],
 651 rhashtable_walk_init, [
 652         #include <linux/gfp.h>
 653         #include <linux/rhashtable.h>
 654 ],[
 655         rhashtable_walk_init(NULL, NULL, GFP_KERNEL);
 656 ],[
 657         AC_DEFINE(HAVE_3ARG_RHASHTABLE_WALK_INIT, 1,
 658                 [rhashtable_walk_init() has 3 args])
 659 ])
 660 ]) # LIBCFS_RHASHTABLE_WALK_INIT_3ARG
 661
 662 #
 663 # Kernel version 4.8-rc6 commit ca26893f05e86497a86732768ec53cd38c0819ca
 664 # introduced rhashtable_lookup
 665 #
 666 AC_DEFUN([LIBCFS_RHASHTABLE_LOOKUP], [
 667 LB_CHECK_COMPILE([if 'rhashtable_lookup' exist],
 668 rhashtable_lookup, [
 669         #include <linux/rhashtable.h>
 670 ],[
 671         const struct rhashtable_params params = { 0 };
 672         void *ret;
 673
 674         ret = rhashtable_lookup(NULL, NULL, params);
 675 ],[
 676         AC_DEFINE(HAVE_RHASHTABLE_LOOKUP, 1,
 677                 [rhashtable_lookup() is available])
 678 ])
 679 ]) # LIBCFS_RHASHTABLE_LOOKUP
 680
 681 #
 682 # LIBCFS_RHLTABLE
 683 # Kernel version 4.8-rc6 commit ca26893f05e86497a86732768ec53cd38c0819ca
 684 # created the rhlist interface to allow inserting duplicate objects
 685 # into the same table.
 686 #
 687 AC_DEFUN([LIBCFS_RHLTABLE], [
 688 LB_CHECK_COMPILE([does 'struct rhltable' exist],
 689 rhtable, [
 690         #include <linux/rhashtable.h>
 691 ],[
 692         struct rhltable *hlt;
 693
 694         rhltable_destroy(hlt);
 695 ],[
 696         AC_DEFINE(HAVE_RHLTABLE, 1,
 697                   [struct rhltable exist])
 698 ])
 699 ]) # LIBCFS_RHLTABLE
 700
 701 #
 702 # LIBCFS_STACKTRACE_OPS
 703 #
 704 # Kernel version 4.8 commit c8fe4609827aedc9c4b45de80e7cdc8ccfa8541b
 705 # removed both struct stacktrace_ops and dump_trace() function
 706 #
 707 AC_DEFUN([LIBCFS_STACKTRACE_OPS], [
 708 LB_CHECK_COMPILE([if 'struct stacktrace_ops' exists],
 709 stacktrace_ops, [
 710         struct task_struct;
 711         struct pt_regs;
 712         #include <asm/stacktrace.h>
 713 ],[
 714         struct stacktrace_ops ops;
 715         ops.stack = NULL;
 716 ],[
 717         AC_DEFINE(HAVE_STACKTRACE_OPS, 1,
 718                 [struct stacktrace_ops exists])
 719 ])
 720 ]) # LIBCFS_STACKTRACE_OPS
 721
 722 #
 723 # Kernel version 4.9-rc1 commit 246779dd090bd1b74d2652b3a6ca7759f593b27a
 724 # introduced rhashtable_walk_enter
 725 #
 726 AC_DEFUN([LIBCFS_RHASHTABLE_WALK_ENTER], [
 727 LB_CHECK_COMPILE([if 'rhashtable_walk_enter' exists],
 728 rhashtable_walk_enter, [
 729         #include <linux/rhashtable.h>
 730 ],[
 731         rhashtable_walk_enter(NULL, NULL);
 732 ],[
 733         AC_DEFINE(HAVE_RHASHTABLE_WALK_ENTER, 1,
 734                 [rhashtable_walk_enter() is available])
 735 ])
 736 ]) # LIBCFS_RHASHTABLE_WALK_ENTER
 737
 738 #
 739 # Kernel version 4.9 commit 768ae309a96103ed02eb1e111e838c87854d8b51
 740 # mm: replace get_user_pages() write/force parameters with gup_flags
 741 #
 742 AC_DEFUN([LIBCFS_GET_USER_PAGES_GUP_FLAGS], [
 743 LB_CHECK_COMPILE([if 'get_user_pages()' takes gup_flags in arguments],
 744 get_user_pages_gup_flags, [
 745         #include <linux/mm.h>
 746 ],[
 747         int rc;
 748         rc = get_user_pages(0, 0, FOLL_WRITE, NULL, NULL);
 749 ],[
 750         AC_DEFINE(HAVE_GET_USER_PAGES_GUP_FLAGS, 1,
 751                 [get_user_pages takes gup_flags in arguments])
 752 ])
 753 ]) # LIBCFS_GET_USER_PAGES_GUP_FLAGS
 754
 755 #
 756 # Kernel version 4.10 commit 7b737965b33188bd3dbb44e938535c4006d97fbb
 757 # libcfs: Convert to hotplug state machine
 758 #
 759 AC_DEFUN([LIBCFS_HOTPLUG_STATE_MACHINE], [
 760 LB_CHECK_COMPILE([if libcfs supports CPU hotplug state machine],
 761 cpu_hotplug_state_machine, [
 762         #include <linux/cpuhotplug.h>
 763 ],[
 764         cpuhp_remove_state(CPUHP_LUSTRE_CFS_DEAD);
 765 ],[
 766         AC_DEFINE(HAVE_HOTPLUG_STATE_MACHINE, 1,
 767                 [hotplug state machine is supported])
 768 ])
 769 ]) # LIBCFS_HOTPLUG_STATE_MACHINE
 770
 771 #
 772 # Kernel version 4.10-rc3 commit f405df5de3170c00e5c54f8b7cf4766044a032ba
 773 # introduced refcount_t which is atomic_t plus over flow guards.
 774 #
 775 AC_DEFUN([LIBCFS_REFCOUNT_T], [
 776 tmp_flags="$EXTRA_KCFLAGS"
 777 EXTRA_KCFLAGS="-Werror"
 778 LB_CHECK_LINUX_HEADER([linux/refcount.h], [
 779         AC_DEFINE(HAVE_REFCOUNT_T, 1,
 780                 [refcount_t is supported])
 781 ])
 782 EXTRA_KCFLAGS="$tmp_flags"
 783 ]) # LIBCFS_REFCOUNT_T
 784
 785 #
 786 # Kernel version 4.12 commit 499118e966f1d2150bd66647c8932343c4e9a0b8
 787 # introduce memalloc_noreclaim_{save,restore}
 788 #
 789 AC_DEFUN([LIBCFS_MEMALLOC_NORECLAIM], [
 790 LB_CHECK_COMPILE([if memalloc_noreclaim_{save,restore} exist],
 791 memalloc_noreclaim, [
 792         #include <linux/sched/mm.h>
 793 ],[
 794         int flag = memalloc_noreclaim_save();
 795         memalloc_noreclaim_restore(flag);
 796 ],[
 797         AC_DEFINE(HAVE_MEMALLOC_RECLAIM, 1,
 798                 [memalloc_noreclaim_{save,restore}() is supported])
 799 ])
 800 ]) # LIBCFS_MEMALLOC_NORECLAIM
 801
 802 #
 803 # LIBCFS_SCHED_HEADERS
 804 #
 805 # 4.11 has broken up sched.h into more headers.
 806 #
 807 AC_DEFUN([LIBCFS_SCHED_HEADERS], [
 808 LB_CHECK_LINUX_HEADER([linux/sched/signal.h], [
 809         AC_DEFINE(HAVE_SCHED_HEADERS, 1,
 810                 [linux/sched header directory exist])])
 811 ]) # LIBCFS_SCHED_HEADERS
 812
 813 #
 814 # Kernel version 4.11-rc1 commit 2c935bc57221cc2edc787c72ea0e2d30cdcd3d5e
 815 # introduce kref_read
 816 #
 817 AC_DEFUN([LIBCFS_KREF_READ], [
 818 LB_CHECK_COMPILE([if 'kref_read' exists],
 819 kref_read, [
 820         #include <linux/kref.h>
 821 ],[
 822         kref_read(NULL);
 823 ],[
 824         AC_DEFINE(HAVE_KREF_READ, 1,
 825                 [kref_read() is available])
 826 ])
 827 ]) # LIBCFS_KREF_READ
 828
 829 #
 830 # Kernel version 4.11-rc1 commit da20420f83ea0fbcf3d03afda08d971ea1d8a356
 831 # introduced rht_bucket_var
 832 #
 833 AC_DEFUN([LIBCFS_RHT_BUCKET_VAR], [
 834 LB_CHECK_COMPILE([if 'rht_bucket_var' exists],
 835 rht_bucket_var, [
 836         #include <linux/rhashtable.h>
 837 ],[
 838
 839         rht_bucket_var(NULL, 0);
 840 ],[
 841         AC_DEFINE(HAVE_RHT_BUCKET_VAR, 1,
 842                 [rht_bucket_var() is available])
 843 ])
 844 ]) # LIBCFS_RHT_BUCKET_VAR
 845
 846 #
 847 # Kernel version 4.11-rc5 commit fceb6435e85298f747fee938415057af837f5a8a
 848 # began the enhanchement of Netlink with extended ACK struct for advanced
 849 # error handling. By commit 7ab606d1609dd6dfeae9c8ad0a8a4e051d831e46 we
 850 # had full support for this new feature.
 851 #
 852 AC_DEFUN([LIBCFS_NL_EXT_ACK], [
 853 LB_CHECK_COMPILE([if Netlink supports netlink_ext_ack],
 854 netlink_ext_ack, [
 855         #include <net/genetlink.h>
 856 ],[
 857         struct genl_info info;
 858
 859         info.extack = NULL;
 860 ],[
 861         AC_DEFINE(HAVE_NL_PARSE_WITH_EXT_ACK, 1,
 862                 [netlink_ext_ack is an argument to nla_parse type function])
 863 ])
 864 ]) # LIBCFS_NL_EXT_ACK
 865
 866 #
 867 # Kernel version 4.11 commit f9fe1c12d126f9887441fa5bb165046f30ddd4b5
 868 # introduced rhashtable_lookup_get_insert_fast
 869 #
 870 AC_DEFUN([LIBCFS_RHASHTABLE_LOOKUP_GET_INSERT_FAST], [
 871 LB_CHECK_COMPILE([if 'rhashtable_lookup_get_insert_fast' exist],
 872 rhashtable_lookup_get_insert_fast, [
 873         #include <linux/rhashtable.h>
 874 ],[
 875         const struct rhashtable_params params = { 0 };
 876         void *ret;
 877
 878         ret = rhashtable_lookup_get_insert_fast(NULL, NULL, params);
 879 ],[
 880         AC_DEFINE(HAVE_RHASHTABLE_LOOKUP_GET_INSERT_FAST, 1,
 881                 [rhashtable_lookup_get_insert_fast() is available])
 882 ])
 883 ]) # LIBCFS_RHASHTABLE_LOOKUP_GET_INSERT_FAST
 884
 885 #
 886 # Kernel version 4.12-rc2 8f553c498e1772cccb39a114da4a498d22992758
 887 # provide proper CPU hotplug locking
 888 #
 889 AC_DEFUN([LIBCFS_CPUS_READ_LOCK], [
 890 LB_CHECK_COMPILE([if 'cpus_read_[un]lock' exist],
 891 cpu_read_lock, [
 892         #include <linux/cpu.h>
 893 ],[
 894         cpus_read_lock();
 895         cpus_read_unlock();
 896 ],[
 897         AC_DEFINE(HAVE_CPUS_READ_LOCK, 1, ['cpus_read_lock' exist])
 898 ])
 899 ]) # LIBCFS_CPUS_READ_LOCK
 900
 901 #
 902 # Kernel version 4.12-rc3 f9727a17db9bab71ddae91f74f11a8a2f9a0ece6
 903 # renamed uuid_be to uuid_t
 904 #
 905 AC_DEFUN([LIBCFS_UUID_T], [
 906 LB_CHECK_COMPILE([if 'uuid_t' exist],
 907 uuid_t, [
 908         #include <linux/uuid.h>
 909 ],[
 910         uuid_t uuid;
 911
 912         memset(uuid.b, 0, 16);
 913 ],[
 914         AC_DEFINE(HAVE_UUID_T, 1, ['uuid_t' exist])
 915 ])
 916 ]) # LIBCFS_UUID_T
 917
 918 #
 919 # Kernel version 4.12-rc3 commit fd851a3cdc196bfc1d229b5f22369069af532bf8
 920 # introduce processor.h
 921 #
 922 AC_DEFUN([LIBCFS_HAVE_PROCESSOR_HEADER], [
 923 tmp_flags="$EXTRA_KCFLAGS"
 924 EXTRA_KCFLAGS="-Werror"
 925 LB_CHECK_LINUX_HEADER([linux/processor.h], [
 926         AC_DEFINE(HAVE_PROCESSOR_H, 1,
 927                 [processor.h is present])
 928 ])
 929 EXTRA_KCFLAGS="$tmp_flags"
 930 ]) # LIBCFS_HAVE_PROCESSOR_HEADER
 931
 932 #
 933 # Kernel verison 4.12-rc6 commit 5dd43ce2f69d42a71dcacdb13d17d8c0ac1fe8f7
 934 # created wait_bit.h
 935 #
 936 AC_DEFUN([LIBCFS_HAVE_WAIT_BIT_HEADER], [
 937 LB_CHECK_LINUX_HEADER([linux/wait_bit.h], [
 938         AC_DEFINE(HAVE_WAIT_BIT_HEADER_H, 1,
 939                 [wait_bit.h is present])])
 940 ]) # LIBCFS_HAVE_WAIT_BIT_HEADER
 941
 942 #
 943 # Kernel version 4.12-rc6 commmit 2055da97389a605c8a00d163d40903afbe413921
 944 # changed:
 945 #       struct wait_queue_head::task_list       => ::head
 946 #       struct wait_queue_entry::task_list      => ::entry
 947 #
 948 AC_DEFUN([LIBCFS_WAIT_QUEUE_TASK_LIST_RENAME], [
 949 LB_CHECK_COMPILE([if linux wait_queue_head list_head is named head],
 950 wait_queue_task_list, [
 951         #include <linux/wait.h>
 952 ],[
 953         wait_queue_head_t e;
 954
 955         INIT_LIST_HEAD(&e.head);
 956 ],[
 957         AC_DEFINE(HAVE_WAIT_QUEUE_ENTRY_LIST, 1,
 958                 [linux wait_queue_head_t list_head is name head])
 959 ])
 960 ]) # LIBCFS_WAIT_QUEUE_TASK_LIST_RENAME
 961
 962 #
 963 # LIBCFS_NLA_STRDUP
 964 #
 965 # Kernel version 4.13-rc1 commit 2cf0c8b3e6942ecafe6ebb1a6d0328a81641bf39
 966 # created nla_strdup(). This is needed since push strings can be
 967 # any size.
 968 #
 969 AC_DEFUN([LIBCFS_NLA_STRDUP], [
 970 LB_CHECK_COMPILE([if 'nla_strdup()' exists],
 971 nla_strdup, [
 972         #include <net/netlink.h>
 973 ],[
 974         char *tmp = nla_strdup(NULL, GFP_KERNEL);
 975 ],[
 976         AC_DEFINE(HAVE_NLA_STRDUP, 1,
 977                 ['nla_strdup' is available])
 978 ])
 979 ]) # LIBCFS_NLA_STRDUP
 980
 981 #
 982 # LIBCFS_WAIT_QUEUE_ENTRY
 983 #
 984 # Kernel version 4.13 ac6424b981bce1c4bc55675c6ce11bfe1bbfa64f
 985 # Rename wait_queue_t => wait_queue_entry_t
 986 #
 987 AC_DEFUN([LIBCFS_WAIT_QUEUE_ENTRY], [
 988 LB_CHECK_COMPILE([if 'wait_queue_entry_t' exists],
 989 wait_queue_entry, [
 990         #include <linux/wait.h>
 991 ],[
 992         wait_queue_entry_t e;
 993
 994         e.flags = 0;
 995 ],[
 996         AC_DEFINE(HAVE_WAIT_QUEUE_ENTRY, 1,
 997                 ['wait_queue_entry_t' is available])
 998 ])
 999 ]) # LIBCFS_WAIT_QUEUE_ENTRY
1000
1001 #
1002 # LIBCFS_NEW_KERNEL_WRITE
1003 #
1004 # Kernel version 4.14 e13ec939e96b13e664bb6cee361cc976a0ee621a
1005 # changed kernel_write prototype to make is plug compatible
1006 # with the unexported vfs_write()
1007 #
1008 AC_DEFUN([LIBCFS_NEW_KERNEL_WRITE], [
1009 tmp_flags="$EXTRA_KCFLAGS"
1010 EXTRA_KCFLAGS="-Werror"
1011 LB_CHECK_COMPILE([if 'kernel_write' matches other read/write helpers],
1012 kernel_write_match, [
1013         #include <linux/fs.h>
1014 ],[
1015         const void *buf = NULL;
1016         loff_t pos = 0;
1017         return kernel_write(NULL, buf, 0, &pos);
1018 ],[
1019         AC_DEFINE(HAVE_NEW_KERNEL_WRITE, 1,
1020                 ['kernel_write' aligns with read/write helpers])
1021 ])
1022 EXTRA_KCFLAGS="$tmp_flags"
1023 ]) # LIBCFS_NEW_KERNEL_WRITE
1024
1025 #
1026 # LIBCFS_MM_TOTALRAM_PAGES_FUNC
1027 #
1028 # kernel 5.0 commit ca79b0c211af63fa3276f0e3fd7dd9ada2439839
1029 # mm: convert totalram_pages and totalhigh_pages variables to atomic
1030 #
1031 AC_DEFUN([LIBCFS_MM_TOTALRAM_PAGES_FUNC], [
1032 tmp_flags="$EXTRA_KCFLAGS"
1033 EXTRA_KCFLAGS="-Werror"
1034 LB_CHECK_COMPILE([if totalram_pages is a function],
1035 totalram_pages, [
1036         #include <linux/mm.h>
1037 ],[
1038         totalram_pages_inc();
1039 ],[
1040         AC_DEFINE(HAVE_TOTALRAM_PAGES_AS_FUNC, 1,
1041                 [if totalram_pages is a function])
1042 ])
1043 EXTRA_KCFLAGS="$tmp_flags"
1044 ]) # LIBCFS_MM_TOTALRAM_PAGES_FUNC
1045
1046 #
1047 # LIBCFS_NEW_KERNEL_READ
1048 #
1049 # 4.14 commit bdd1d2d3d251c65b74ac4493e08db18971c09240 changed
1050 # the signature of kernel_read to match other read/write helpers
1051 # and place offset last.
1052 #
1053 AC_DEFUN([LIBCFS_NEW_KERNEL_READ], [
1054 tmp_flags="$EXTRA_KCFLAGS"
1055 EXTRA_KCFLAGS="-Werror"
1056 LB_CHECK_COMPILE([if 'kernel_read()' has loff_t *pos as last parameter],
1057 kernel_read, [
1058         #include <linux/fs.h>
1059         ],[
1060         loff_t pos = 0;
1061         kernel_read(NULL, NULL, 0, &pos);
1062 ],[
1063         AC_DEFINE(HAVE_KERNEL_READ_LAST_POSP, 1,
1064                 [kernel_read() signature ends with loff_t *pos])
1065 ])
1066 EXTRA_KCFLAGS="$tmp_flags"
1067 ]) # LIBCFS_NEW_KERNEL_READ
1068
1069 #
1070 # LIBCFS_DEFINE_TIMER
1071 #
1072 # Kernel version 4.14 commit 1d27e3e2252ba9d949ca82fbdb73cde102cb2067
1073 # remove expires and data arguments from DEFINE_TIMER. Also the callback
1074 # when from using unsigned long argument to using struct timer_list pointer.
1075 #
1076 AC_DEFUN([LIBCFS_DEFINE_TIMER], [
1077 LB_CHECK_COMPILE([if DEFINE_TIMER takes only 2 arguments],
1078 define_timer, [
1079         #include <linux/timer.h>
1080 ],[
1081         static DEFINE_TIMER(my_timer, NULL);
1082 ],[
1083         AC_DEFINE(HAVE_NEW_DEFINE_TIMER, 1,
1084                 [DEFINE_TIMER uses only 2 arguements])
1085 ])
1086 ]) # LIBCFS_DEFINE_TIMER
1087
1088 #
1089 # LIBCFS_EXPORT_SAVE_STACK_TRACE_TSK
1090 #
1091 # Kernel 2.6.27 commit 8594698ebddeef5443b7da8258ae33b3eaca61d5
1092 # exported save_stack_trace_tsk for x86.
1093 # Kernel 2.6.27 commit 01f4b8b8b8db09b88be7df7e51192e4e678b69d3
1094 # exported save_stack_trace_tsk for powerpc
1095 # Kernel 4.13 commit e27c7fa015d61c8be6a2c32b2144aad2ae6ec975
1096 # exported save_stack_trace_tsk for arm64
1097 # Kernel 4.14 commit 9a3dc3186fc3795e076a4122da9e0258651a9631
1098 # exported save_stack_trace_tsk for arm
1099 #
1100 AC_DEFUN([LIBCFS_EXPORT_SAVE_STACK_TRACE_TSK], [
1101 LB_CHECK_EXPORT([save_stack_trace_tsk], [arch/$SUBARCH/kernel/stacktrace.c],
1102         [AC_DEFINE(HAVE_SAVE_STACK_TRACE_TSK, 1,
1103                 [save_stack_trace_tsk is exported])])
1104 ]) # LIBCFS_EXPORT_SAVE_STACK_TRACE_TSK
1105
1106 #
1107 # LIBCFS_LOCKDEP_IS_HELD
1108 #
1109 # Kernel v4.15-rc8-106-g08f36ff64234
1110 # lockdep: Make lockdep checking constant
1111 #
1112 AC_DEFUN([LIBCFS_LOCKDEP_IS_HELD], [
1113 tmp_flags="$EXTRA_KCFLAGS"
1114 EXTRA_KCFLAGS="-Werror"
1115 LB_CHECK_COMPILE([if 'lockdep_is_held()' uses const argument],
1116 lockdep_is_held, [
1117         #include <linux/lockdep.h>
1118 ],[
1119 #ifdef CONFIG_LOCKDEP
1120         const struct spinlock *lock = NULL;
1121
1122         lockdep_is_held(lock);
1123 #endif
1124 ],[],[
1125         AC_DEFINE(NEED_LOCKDEP_IS_HELD_DISCARD_CONST, 1,
1126                 [lockdep_is_held() argument is const])
1127 ])
1128 EXTRA_KCFLAGS="$tmp_flags"
1129 ]) # LIBCFS_LOCKDEP_IS_HELD
1130
1131 #
1132 # LIBCFS_TIMER_SETUP
1133 #
1134 # Kernel version 4.15 commit e99e88a9d2b067465adaa9c111ada99a041bef9a
1135 # setup_timer() was replaced by timer_setup(), where the callback
1136 # argument is the structure already holding the struct timer_list.
1137 #
1138 AC_DEFUN([LIBCFS_TIMER_SETUP], [
1139 LB_CHECK_COMPILE([if setup_timer has been replaced with timer_setup],
1140 timer_setup, [
1141         #include <linux/timer.h>
1142 ],[
1143         timer_setup(NULL, NULL, 0);
1144 ],[
1145         AC_DEFINE(HAVE_TIMER_SETUP, 1,
1146                 [timer_setup has replaced setup_timer])
1147 ])
1148 ]) # LIBCFS_TIMER_SETUP
1149
1150 #
1151 # LIBCFS_WAIT_VAR_EVENT
1152 #
1153 # Kernel version 4.16-rc4 commit 6b2bb7265f0b62605e8caee3613449ed0db270b9
1154 # added wait_var_event()
1155 #
1156 AC_DEFUN([LIBCFS_WAIT_VAR_EVENT], [
1157 LB_CHECK_COMPILE([if 'wait_var_event' exist],
1158 wait_var_event, [
1159         #ifdef HAVE_WAIT_BIT_HEADER_H
1160         #include <linux/wait_bit.h>
1161         #endif
1162         #include <linux/wait.h>
1163 ],[
1164         wake_up_var(NULL);
1165 ],[
1166         AC_DEFINE(HAVE_WAIT_VAR_EVENT, 1,
1167                 ['wait_var_event' is available])
1168 ])
1169 ]) # LIBCFS_WAIT_VAR_EVENT
1170
1171 #
1172 # LIBCFS_BITMAP_ALLOC
1173 #
1174 # Kernel version 4.17 commit c42b65e363ce97a828f81b59033c3558f8fa7f70
1175 # added bitmap memory allocation handling.
1176 #
1177 AC_DEFUN([LIBCFS_BITMAP_ALLOC], [
1178 LB_CHECK_COMPILE([if Linux bitmap memory management exist],
1179 bitmap_alloc, [
1180         #include <linux/bitmap.h>
1181 ],[
1182         unsigned long *map = bitmap_alloc(1, GFP_KERNEL);
1183 ],[
1184         AC_DEFINE(HAVE_BITMAP_ALLOC, 1,
1185                 [Linux bitmap can be allocated])
1186 ])
1187 ]) # LIBCFS_BITMAP_ALLOC
1188
1189 #
1190 # LIBCFS_CLEAR_AND_WAKE_UP_BIT
1191 #
1192 # Kernel version 4.17-rc2 commit 8236b0ae31c837d2b3a2565c5f8d77f637e824cc
1193 # added clear_and_wake_up_bit()
1194 #
1195 AC_DEFUN([LIBCFS_CLEAR_AND_WAKE_UP_BIT], [
1196 LB_CHECK_COMPILE([if 'clear_and_wake_up_bit' exist],
1197 clear_and_wake_up_bit, [
1198         #ifdef HAVE_WAIT_BIT_HEADER_H
1199         #include <linux/wait_bit.h>
1200         #endif
1201         #include <linux/wait.h>
1202 ],[
1203         clear_and_wake_up_bit(0, NULL);
1204 ],[
1205         AC_DEFINE(HAVE_CLEAR_AND_WAKE_UP_BIT, 1,
1206                 ['clear_and_wake_up_bit' is available])
1207 ])
1208 ]) # LIBCFS_CLEAR_AND_WAKE_UP_BIT
1209
1210 #
1211 # LIBCFS_TCP_SOCK_SET_NODELAY
1212 #
1213 # kernel 4.18.0-293.el8
1214 # tcp_sock_set_nodelay() was added
1215 AC_DEFUN([LIBCFS_TCP_SOCK_SET_NODELAY], [
1216 tmp_flags="$EXTRA_KCFLAGS"
1217 EXTRA_KCFLAGS="-Werror"
1218 LB_CHECK_COMPILE([if 'tcp_sock_set_nodelay()' exists],
1219 tcp_sock_set_nodelay_exists, [
1220         #include <linux/tcp.h>
1221 ],[
1222         tcp_sock_set_nodelay(NULL);
1223 ],[
1224         AC_DEFINE(HAVE_TCP_SOCK_SET_NODELAY, 1,
1225                 ['tcp_sock_set_nodelay()' exists])
1226 ])
1227 EXTRA_KCFLAGS="$tmp_flags"
1228 ]) # LIBCFS_TCP_SOCK_SET_NODELAY
1229
1230 #
1231 # LIBCFS_TCP_SOCK_SET_KEEPIDLE
1232 #
1233 # kernel 4.18.0-293.el8
1234 # tcp_sock_set_keepidle() was added
1235 AC_DEFUN([LIBCFS_TCP_SOCK_SET_KEEPIDLE], [
1236 tmp_flags="$EXTRA_KCFLAGS"
1237 EXTRA_KCFLAGS="-Werror"
1238 LB_CHECK_COMPILE([if 'tcp_sock_set_keepidle()' exists],
1239 tcp_sock_set_keepidle_exists, [
1240         #include <linux/tcp.h>
1241 ],[
1242         tcp_sock_set_keepidle(NULL, 0);
1243 ],[
1244         AC_DEFINE(HAVE_TCP_SOCK_SET_KEEPIDLE, 1,
1245                 ['tcp_sock_set_keepidle()' exists])
1246 ])
1247 EXTRA_KCFLAGS="$tmp_flags"
1248 ]) # LIBCFS_TCP_SOCK_SET_KEEPIDLE
1249
1250 #
1251 # LIBCFS_TCP_SOCK_SET_QUICKACK
1252 # kernel v5.7-rc6-2504-gddd061b8daed
1253 #   tcp: add tcp_sock_set_quickack
1254 #
1255 AC_DEFUN([LIBCFS_TCP_SOCK_SET_QUICKACK], [
1256 tmp_flags="$EXTRA_KCFLAGS"
1257 EXTRA_KCFLAGS="-Werror"
1258 LB_CHECK_COMPILE([if 'tcp_sock_set_quickack()' exists],
1259 tcp_sock_set_quickack_exists, [
1260         #include <linux/tcp.h>
1261 ],[
1262         tcp_sock_set_quickack(NULL, 0);
1263 ],[
1264         AC_DEFINE(HAVE_TCP_SOCK_SET_QUICKACK, 1,
1265                 ['tcp_sock_set_quickack()' exists])
1266 ])
1267 EXTRA_KCFLAGS="$tmp_flags"
1268 ]) # LIBCFS_TCP_SOCK_SET_QUICKACK
1269
1270 #
1271 # LIBCFS_TCP_SOCK_SET_KEEPINTVL
1272 # v5.7-rc6-2508-gd41ecaac903c
1273 # tcp: add tcp_sock_set_keepintvl
1274 #
1275 AC_DEFUN([LIBCFS_TCP_SOCK_SET_KEEPINTVL], [
1276 tmp_flags="$EXTRA_KCFLAGS"
1277 EXTRA_KCFLAGS="-Werror"
1278 LB_CHECK_COMPILE([if 'tcp_sock_set_keepintvl()' exists],
1279 tcp_sock_set_keepintvl_exists, [
1280         #include <linux/tcp.h>
1281 ],[
1282         tcp_sock_set_keepintvl(NULL, 0);
1283 ],[
1284         AC_DEFINE(HAVE_TCP_SOCK_SET_KEEPINTVL, 1,
1285                 ['tcp_sock_set_keepintvl()' exists])
1286 ])
1287 EXTRA_KCFLAGS="$tmp_flags"
1288 ]) # LIBCFS_TCP_SOCK_SET_KEEPINTVL
1289
1290 #
1291 # LIBCFS_TCP_SOCK_SET_KEEPCNT
1292 # v5.7-rc6-2509-g480aeb9639d6
1293 # tcp: add tcp_sock_set_keepcnt
1294 #
1295 AC_DEFUN([LIBCFS_TCP_SOCK_SET_KEEPCNT], [
1296 tmp_flags="$EXTRA_KCFLAGS"
1297 EXTRA_KCFLAGS="-Werror"
1298 LB_CHECK_COMPILE([if 'tcp_sock_set_keepcnt()' exists],
1299 tcp_sock_set_keepcnt_exists, [
1300         #include <linux/tcp.h>
1301 ],[
1302         tcp_sock_set_keepcnt(NULL, 0);
1303 ],[
1304         AC_DEFINE(HAVE_TCP_SOCK_SET_KEEPCNT, 1,
1305                 ['tcp_sock_set_keepcnt()' exists])
1306 ])
1307 EXTRA_KCFLAGS="$tmp_flags"
1308 ]) # LIBCFS_TCP_SOCK_SET_KEEPCNT
1309
1310 #
1311 # LIBCFS_XARRAY_SUPPORT
1312 #
1313 # 4.19-rc5 kernel commit 3159f943aafdbacb2f94c38fdaadabf2bbde2a14
1314 # replaced the radix tree implementation with Xarrays. This change
1315 # introduced functionaly needed for general Xarray support
1316 #
1317 AC_DEFUN([LIBCFS_XARRAY_SUPPORT], [
1318 tmp_flags="$EXTRA_KCFLAGS"
1319 EXTRA_KCFLAGS="-Werror"
1320 LB_CHECK_COMPILE([if page cache uses Xarray],
1321 xarray_support, [
1322         #include <linux/xarray.h>
1323 ],[
1324         xa_is_value(NULL);
1325 ],[
1326         AC_DEFINE(HAVE_XARRAY_SUPPORT, 1,
1327                 [kernel Xarray implementation lacks 'xa_is_value'])
1328 ])
1329 EXTRA_KCFLAGS="$tmp_flags"
1330 ]) # LIBCFS_XARRAY_SUPPORT
1331
1332 #
1333 # Kernel version 4.19-rc6 commit 4a19edb60d0203cd5bf95a8b46ea8f63fd41194c
1334 # added extended ACK handling to Netlink dump handlers
1335 #
1336 AC_DEFUN([LIBCFS_NL_DUMP_EXT_ACK], [
1337 LB_CHECK_COMPILE([if Netlink dump handlers support ext_ack],
1338 netlink_dump_ext_ack, [
1339         #include <net/netlink.h>
1340 ],[
1341         struct netlink_callback *cb = NULL;
1342         cb->extack = NULL;
1343 ],[
1344         AC_DEFINE(HAVE_NL_DUMP_WITH_EXT_ACK, 1,
1345                 [netlink_ext_ack is handled for Netlink dump handlers])
1346 ])
1347 ]) # LIBCFS_NL_DUMP_EXT_ACK
1348
1349 #
1350 # LIBCFS_HAVE_IOV_ITER_TYPE
1351 #
1352 # kernel 4.20 commit 00e23707442a75b404392cef1405ab4fd498de6b
1353 # iov_iter: Use accessor functions to access an iterator's type and direction.
1354 #
1355 AC_DEFUN([LIBCFS_HAVE_IOV_ITER_TYPE], [
1356 tmp_flags="$EXTRA_KCFLAGS"
1357 EXTRA_KCFLAGS="-Werror"
1358 LB_CHECK_COMPILE([if iov_iter_type exists],
1359 macro_iov_iter_type_exists, [
1360         #include <linux/uio.h>
1361 ],[
1362         struct iov_iter iter = { .type = ITER_KVEC };
1363         enum iter_type type = iov_iter_type(&iter);
1364         (void)type;
1365 ],[
1366         AC_DEFINE(HAVE_IOV_ITER_TYPE, 1,
1367                 [if iov_iter_type exists])
1368 ])
1369 EXTRA_KCFLAGS="$tmp_flags"
1370 ]) # LIBCFS_HAVE_IOV_ITER_TYPE
1371
1372 #
1373 # LIBCFS_GET_REQUEST_KEY_AUTH
1374 #
1375 # kernel 5.0 commit 822ad64d7e46a8e2c8b8a796738d7b657cbb146d
1376 # keys: Fix dependency loop between construction record and auth key
1377 #
1378 # Added <keys/request_key_auth-type.h> and get_request_key_auth()
1379 # which was propagated to stable
1380 #
1381 AC_DEFUN([LIBCFS_GET_REQUEST_KEY_AUTH], [
1382 tmp_flags="$EXTRA_KCFLAGS"
1383 EXTRA_KCFLAGS="-Werror"
1384 LB_CHECK_COMPILE([if get_request_key_auth() is available],
1385 get_request_key_auth_exported, [
1386         #include <linux/key.h>
1387         #include <linux/keyctl.h>
1388         #include <keys/request_key_auth-type.h>
1389 ],[
1390         struct key *ring;
1391         const struct key *key = NULL;
1392         struct request_key_auth *rka = get_request_key_auth(key);
1393
1394         ring = key_get(rka->dest_keyring);
1395 ],[
1396         AC_DEFINE(HAVE_GET_REQUEST_KEY_AUTH, 1,
1397                 [get_request_key_auth() is available])
1398 ])
1399 EXTRA_KCFLAGS="$tmp_flags"
1400 ]) # LIBCFS_GET_REQUEST_KEY_AUTH
1401
1402 #
1403 # LIBCFS_LOOKUP_USER_KEY
1404 #
1405 # kernel 5.3 commit 3cf5d076fb4d48979f382bc9452765bf8b79e740
1406 # signal: Remove task parameter from force_sig
1407 #
1408 AC_DEFUN([LIBCFS_LOOKUP_USER_KEY], [
1409 tmp_flags="$EXTRA_KCFLAGS"
1410 EXTRA_KCFLAGS="-Werror"
1411 LB_CHECK_COMPILE([if lookup_user_key() is available],
1412 lookup_user_key_exported, [
1413         #include <linux/key.h>
1414         #include <linux/keyctl.h>
1415 ],[
1416         lookup_user_key(KEY_SPEC_USER_KEYRING, 0, 0);
1417 ],[
1418         AC_DEFINE(HAVE_LOOKUP_USER_KEY, 1,
1419                 [lookup_user_key() is available])
1420 ])
1421 EXTRA_KCFLAGS="$tmp_flags"
1422 ]) # LIBCFS_LOOKUP_USER_KEY
1423
1424 #
1425 # LIBCFS_FORCE_SIG_WITH_TASK
1426 #
1427 # kernel 5.3 commit 3cf5d076fb4d48979f382bc9452765bf8b79e740
1428 # signal: Remove task parameter from force_sig
1429 #
1430 AC_DEFUN([LIBCFS_FORCE_SIG_WITH_TASK], [
1431 tmp_flags="$EXTRA_KCFLAGS"
1432 EXTRA_KCFLAGS="-Werror"
1433 LB_CHECK_COMPILE([if force_sig has task parameter],
1434 force_sig_with_task, [
1435         #include <linux/sched/signal.h>
1436 ],[
1437         force_sig(SIGINT, NULL);
1438 ],[
1439         AC_DEFINE(HAVE_FORCE_SIG_WITH_TASK, 1,
1440                 [force_sig() has task parameter])
1441 ])
1442 EXTRA_KCFLAGS="$tmp_flags"
1443 ]) # LIBCFS_FORCE_SIG_WITH_TASK
1444
1445 #
1446 # LIBCFS_CACHE_DETAIL_WRITERS
1447 #
1448 # kernel v5.3-rc2-1-g64a38e840ce5
1449 # SUNRPC: Track writers of the 'channel' file to improve cache_listeners_exist
1450 #
1451 AC_DEFUN([LIBCFS_CACHE_DETAIL_WRITERS], [
1452 tmp_flags="$EXTRA_KCFLAGS"
1453 EXTRA_KCFLAGS="-Werror"
1454 LB_CHECK_COMPILE([if struct cache_detail has writers],
1455 cache_detail_writers_atomic, [
1456         #include <linux/sunrpc/cache.h>
1457
1458         static struct cache_detail rsi_cache;
1459 ],[
1460         atomic_set(&rsi_cache.writers, 0);
1461 ],[
1462         AC_DEFINE(HAVE_CACHE_DETAIL_WRITERS, 1,
1463                 [struct cache_detail has writers])
1464 ])
1465 EXTRA_KCFLAGS="$tmp_flags"
1466 ]) # LIBCFS_CACHE_DETAIL_WRITERS
1467
1468 #
1469 # LIBCFS_KALLSYMS_LOOKUP
1470 #
1471 # kernel v5.6-11591-g0bd476e6c671
1472 # kallsyms: unexport kallsyms_lookup_name() and kallsyms_on_each_symbol()
1473 AC_DEFUN([LIBCFS_KALLSYMS_LOOKUP], [
1474 LB_CHECK_EXPORT([kallsyms_lookup_name], [kernel/kallsyms.c],
1475         [AC_DEFINE(HAVE_KALLSYMS_LOOKUP_NAME, 1,
1476                 [kallsyms_lookup_name is exported by kernel])])
1477 ]) # LIBCFS_KALLSYMS_LOOKUP
1478
1479 #
1480 # v5.5-8862-gd56c0d45f0e2
1481 # proc: decouple proc from VFS with "struct proc_ops"
1482 #
1483 AC_DEFUN([LIBCFS_SRC_HAVE_PROC_OPS], [
1484         LB2_LINUX_TEST_SRC([proc_ops], [
1485                 #include <linux/proc_fs.h>
1486
1487                 static struct proc_ops *my_proc;
1488         ],[
1489                 my_proc->proc_lseek = NULL;
1490         ],[-Werror])
1491 ]) # LIBCFS_SRC_HAVE_PROC_OPS
1492 AC_DEFUN([LIBCFS_HAVE_PROC_OPS], [
1493         AC_MSG_CHECKING([if struct proc_ops exists])
1494         LB2_LINUX_TEST_RESULT([proc_ops], [
1495                 AC_DEFINE(HAVE_PROC_OPS, 1,
1496                         [struct proc_ops exists])
1497                 AC_MSG_RESULT(yes)
1498         ],[
1499                 AC_MSG_RESULT(no)
1500         ])
1501 ]) # LIBCFS_HAVE_PROC_OPS
1502
1503 #
1504 # LIBCFS_VMALLOC_2ARGS
1505 #
1506 # kernel v5.8-rc1~201^2~19
1507 # mm: remove the pgprot argument to __vmalloc
1508 AC_DEFUN([LIBCFS_VMALLOC_2ARGS], [
1509 LB_CHECK_COMPILE([if __vmalloc has 2 args],
1510 vmalloc_2args, [
1511         #include <linux/vmalloc.h>
1512 ],[
1513         __vmalloc(0, 0);
1514 ],[
1515         AC_DEFINE(HAVE_VMALLOC_2ARGS, 1,
1516                 [__vmalloc only takes 2 args.])
1517 ])
1518 ]) # LIBCFS_VMALLOC_2ARGS
1519
1520 #
1521 # LIBCFS_HAVE_NR_UNSTABLE_NFS
1522 #
1523 # kernel v5.8-rc1~201^2~75
1524 # mm/writeback: discard NR_UNSTABLE_NFS, use NR_WRITEBACK instead
1525 #
1526 AC_DEFUN([LIBCFS_HAVE_NR_UNSTABLE_NFS], [
1527 tmp_flags="$EXTRA_KCFLAGS"
1528 EXTRA_KCFLAGS="-Werror"
1529 LB_CHECK_COMPILE([if NR_UNSTABLE_NFS still in use],
1530 nr_unstable_nfs_exists, [
1531         #include <linux/mm.h>
1532
1533         int i;
1534 ],[
1535         i = NR_UNSTABLE_NFS;
1536 ],[
1537         AC_DEFINE(HAVE_NR_UNSTABLE_NFS, 1,
1538                 [NR_UNSTABLE_NFS is still in use.])
1539 ])
1540 EXTRA_KCFLAGS="$tmp_flags"
1541 ]) # LIBCFS_HAVE_NR_UNSTABLE_NFS
1542
1543 #
1544 # LIBCFS_HAVE_MMAP_LOCK
1545 #
1546 # kernel v5.8-rc1~83^2~24
1547 # mmap locking API: rename mmap_sem to mmap_lock
1548 #
1549 AC_DEFUN([LIBCFS_HAVE_MMAP_LOCK], [
1550 LB_CHECK_COMPILE([if mmap_lock API is available],
1551 mmap_write_lock, [
1552         #include <linux/mm.h>
1553 ],[
1554         mmap_write_lock(NULL);
1555 ],[
1556         AC_DEFINE(HAVE_MMAP_LOCK, 1,
1557                 [mmap_lock API is available.])
1558 ])
1559 ]) # LIBCFS_HAVE_MMAP_LOCK
1560
1561 #
1562 # LIBCFS_KERNEL_SETSOCKOPT
1563 #
1564 # kernel v5.8-rc1~165^2~59^2
1565 # net: remove kernel_setsockopt
1566 AC_DEFUN([LIBCFS_KERNEL_SETSOCKOPT], [
1567 tmp_flags="$EXTRA_KCFLAGS"
1568 EXTRA_KCFLAGS="-Werror"
1569 LB_CHECK_COMPILE([if kernel_setsockopt still in use],
1570 kernel_setsockopt_exists, [
1571         #include <linux/net.h>
1572 ],[
1573         kernel_setsockopt(NULL, 0, 0, NULL, 0);
1574 ],[
1575         AC_DEFINE(HAVE_KERNEL_SETSOCKOPT, 1,
1576                 [kernel_setsockopt still in use])
1577 ])
1578 EXTRA_KCFLAGS="$tmp_flags"
1579 ]) # LIBCFS_KERNEL_SETSOCKOPT
1580
1581 #
1582 # LIBCFS_SEC_RELEASE_SECCTX
1583 #
1584 # kernel linux-hwe-5.8 (5.8.0-22.23~20.04.1)
1585 # LSM: Use lsmcontext in security_release_secctx
1586 AC_DEFUN([LIBCFS_SEC_RELEASE_SECCTX], [
1587 LB_CHECK_COMPILE([if security_release_secctx has 1 arg],
1588 security_release_secctx_1arg, [
1589         #include <linux/security.h>
1590 ],[
1591         security_release_secctx(NULL);
1592 ],[
1593         AC_DEFINE(HAVE_SEC_RELEASE_SECCTX_1ARG, 1,
1594                 [security_release_secctx has 1 arg.])
1595 ])
1596 ]) # LIBCFS_SEC_RELEASE_SECCTX
1597
1598 #
1599 # LIBCFS_HAVE_KFREE_SENSITIVE
1600 #
1601 # kernel v5.10-rc1~3
1602 # mm: remove kzfree() compatibility definition
1603 #
1604 AC_DEFUN([LIBCFS_HAVE_KFREE_SENSITIVE], [
1605 LB_CHECK_COMPILE([if kfree_sensitive() is available],
1606 kfree_sensitive_exists, [
1607         #include <linux/slab.h>
1608
1609 ],[
1610         kfree_sensitive(NULL);
1611 ],[
1612         AC_DEFINE(HAVE_KFREE_SENSITIVE, 1,
1613                 [kfree_sensitive() is available.])
1614 ])
1615 EXTRA_KCFLAGS="$tmp_flags"
1616 ]) # LIBCFS_HAVE_KFREE_SENSITIVE
1617
1618 #
1619 # LIBCFS_HAVE_CRYPTO_SHA2_HEADER
1620 #
1621 # Kernel v5.10-rc1-114-ga24d22b225ce
1622 # crypto: sha - split sha.h into sha1.h and sha2.h
1623 #
1624 AC_DEFUN([LIBCFS_HAVE_CRYPTO_SHA2_HEADER], [
1625 LB_CHECK_LINUX_HEADER([crypto/sha2.h], [
1626         AC_DEFINE(HAVE_CRYPTO_SHA2_HEADER, 1,
1627                 [crypto/sha2.h is present])])
1628 ]) # LIBCFS_HAVE_CRYPTO_SHA2_HEADER
1629
1630 AC_DEFUN([LIBCFS_PROG_LINUX_SRC], [
1631         LIBCFS_SRC_HAVE_PROC_OPS
1632
1633         AC_MSG_CHECKING([for available kernel interfaces to libcfs])
1634         LB2_LINUX_TEST_COMPILE_ALL([libcfs])
1635         AC_MSG_RESULT([done])
1636 ])
1637 AC_DEFUN([LIBCFS_PROG_LINUX_RESULTS], [
1638         # 5.6
1639         LIBCFS_HAVE_PROC_OPS
1640 ])
1641
1642 #
1643 # LIBCFS_PROG_LINUX
1644 #
1645 # LibCFS linux kernel checks
1646 #
1647 AC_DEFUN([LIBCFS_PROG_LINUX], [
1648 AC_MSG_NOTICE([LibCFS kernel checks
1649 ==============================================================================])
1650 LIBCFS_CONFIG_PANIC_DUMPLOG
1651
1652 # 3.11
1653 LIBCFS_KTIME_GET_TS64
1654 # 3.12
1655 LIBCFS_PREPARE_TO_WAIT_EVENT
1656 LIBCFS_KERNEL_PARAM_OPS
1657 LIBCFS_KTIME_ADD
1658 LIBCFS_KTIME_AFTER
1659 LIBCFS_KTIME_BEFORE
1660 LIBCFS_KTIME_COMPARE
1661 LIBCFS_SHRINKER_COUNT
1662 # 3.15
1663 LIBCFS_IOV_ITER_HAS_TYPE
1664 # 3.16
1665 LIBCFS_HAVE_NS_TO_TIMESPEC64
1666 # 3.17
1667 LIBCFS_HLIST_ADD_AFTER
1668 LIBCFS_TIMESPEC64
1669 LIBCFS_KTIME_GET_NS
1670 LIBCFS_KTIME_GET_REAL_TS64
1671 LIBCFS_KTIME_GET_REAL_SECONDS
1672 LIBCFS_KTIME_GET_REAL_NS
1673 LIBCFS_KTIME_TO_TIMESPEC64
1674 LIBCFS_TIMESPEC64_SUB
1675 LIBCFS_TIMESPEC64_TO_KTIME
1676 # 3.19
1677 LIBCFS_KTIME_GET_SECONDS
1678 # 4.0
1679 LIBCFS_KTIME_MS_DELTA
1680 # 4.1
1681 LIBCFS_KERNEL_PARAM_LOCK
1682 # 4.2
1683 LIBCFS_HAVE_TOPOLOGY_SIBLING_CPUMASK
1684 # 4.4
1685 LIBCFS_KSTRTOBOOL_FROM_USER
1686 LIBCFS_NETLINK_CALLBACK_START
1687 # 4.5
1688 LIBCFS_CRYPTO_HASH_HELPERS
1689 LIBCFS_EXPORT_KSET_FIND_OBJ
1690 LIBCFS_RHASHTABLE_REPLACE
1691 # 4.6
1692 LIBCFS_BROKEN_HASH_64
1693 LIBCFS_STACKTRACE_OPS_ADDRESS_RETURN_INT
1694 LIBCFS_GET_USER_PAGES_6ARG
1695 LIBCFS_STRINGHASH
1696 # 4.7
1697 LIBCFS_RHASHTABLE_INSERT_FAST
1698 LIBCFS_RHASHTABLE_WALK_INIT_3ARG
1699 # 4.8
1700 LIBCFS_RHASHTABLE_LOOKUP
1701 LIBCFS_RHLTABLE
1702 LIBCFS_STACKTRACE_OPS
1703 # 4.9
1704 LIBCFS_GET_USER_PAGES_GUP_FLAGS
1705 LIBCFS_RHASHTABLE_WALK_ENTER
1706 # 4.10
1707 LIBCFS_HOTPLUG_STATE_MACHINE
1708 LIBCFS_REFCOUNT_T
1709 # 4.11
1710 LIBCFS_RHASHTABLE_LOOKUP_GET_INSERT_FAST
1711 LIBCFS_SCHED_HEADERS
1712 LIBCFS_KREF_READ
1713 LIBCFS_RHT_BUCKET_VAR
1714 # 4.12
1715 LIBCFS_HAVE_PROCESSOR_HEADER
1716 LIBCFS_HAVE_WAIT_BIT_HEADER
1717 LIBCFS_MEMALLOC_NORECLAIM
1718 LIBCFS_NL_EXT_ACK
1719 LIBCFS_WAIT_QUEUE_TASK_LIST_RENAME
1720 LIBCFS_CPUS_READ_LOCK
1721 LIBCFS_UUID_T
1722 # 4.13
1723 LIBCFS_NLA_STRDUP
1724 LIBCFS_WAIT_QUEUE_ENTRY
1725 # 4.14
1726 LIBCFS_DEFINE_TIMER
1727 LIBCFS_NEW_KERNEL_WRITE
1728 LIBCFS_NEW_KERNEL_READ
1729 LIBCFS_EXPORT_SAVE_STACK_TRACE_TSK
1730 # 4.15
1731 LIBCFS_LOCKDEP_IS_HELD
1732 LIBCFS_TIMER_SETUP
1733 # 4.16
1734 LIBCFS_WAIT_VAR_EVENT
1735 # 4.17
1736 LIBCFS_BITMAP_ALLOC
1737 LIBCFS_CLEAR_AND_WAKE_UP_BIT
1738 # 4.18
1739 LIBCFS_TCP_SOCK_SET_NODELAY
1740 LIBCFS_TCP_SOCK_SET_KEEPIDLE
1741 # 4.19
1742 LIBCFS_XARRAY_SUPPORT
1743 LIBCFS_NL_DUMP_EXT_ACK
1744 # 4.20
1745 LIBCFS_HAVE_IOV_ITER_TYPE
1746 # 5.0
1747 LIBCFS_MM_TOTALRAM_PAGES_FUNC
1748 LIBCFS_GET_REQUEST_KEY_AUTH
1749 # 5.3
1750 LIBCFS_LOOKUP_USER_KEY
1751 LIBCFS_FORCE_SIG_WITH_TASK
1752 LIBCFS_CACHE_DETAIL_WRITERS
1753 LIBCFS_HAVE_NR_UNSTABLE_NFS
1754 # 5.7
1755 LIBCFS_KALLSYMS_LOOKUP
1756 LIBCFS_TCP_SOCK_SET_QUICKACK
1757 LIBCFS_TCP_SOCK_SET_KEEPINTVL
1758 LIBCFS_TCP_SOCK_SET_KEEPCNT
1759 # 5.8
1760 LIBCFS_HAVE_MMAP_LOCK
1761 LIBCFS_KERNEL_SETSOCKOPT
1762 LIBCFS_VMALLOC_2ARGS
1763 LIBCFS_SEC_RELEASE_SECCTX
1764 # 5.10
1765 LIBCFS_HAVE_KFREE_SENSITIVE
1766 LIBCFS_HAVE_CRYPTO_SHA2_HEADER
1767 ]) # LIBCFS_PROG_LINUX
1768
1769 #
1770 # LIBCFS_PATH_DEFAULTS
1771 #
1772 # default paths for installed files
1773 #
1774 AC_DEFUN([LIBCFS_PATH_DEFAULTS], [
1775 ]) # LIBCFS_PATH_DEFAULTS
1776
1777 #
1778 # LIBCFS_CONFIGURE
1779 #
1780 # other configure checks
1781 #
1782 AC_DEFUN([LIBCFS_CONFIGURE], [
1783 AC_MSG_NOTICE([LibCFS core checks
1784 ==============================================================================])
1785
1786 # libcfs/libcfs/util/nidstrings.c
1787 AC_CHECK_HEADERS([netdb.h asm/types.h endian.h])
1788 AC_CHECK_FUNCS([gethostbyname])
1789
1790 # --------  Check for required packages  --------------
1791
1792 AC_MSG_NOTICE([LibCFS required packages checks
1793 ==============================================================================])
1794
1795 AC_MSG_CHECKING([whether to enable readline support])
1796 AC_ARG_ENABLE(readline,
1797         AC_HELP_STRING([--disable-readline],
1798                 [disable readline support]),
1799         [], [enable_readline="yes"])
1800 AC_MSG_RESULT([$enable_readline])
1801
1802 LIBREADLINE=""
1803 AS_IF([test "x$enable_readline" = xyes], [
1804         AC_CHECK_LIB([readline], [readline], [
1805                 LIBREADLINE="-lreadline"
1806                 AC_DEFINE(HAVE_LIBREADLINE, 1,
1807                         [readline library is available])
1808         ])
1809 ])
1810 AC_SUBST(LIBREADLINE)
1811
1812 AC_MSG_CHECKING([whether to use libpthread for libcfs library])
1813 AC_ARG_ENABLE([libpthread],
1814         AC_HELP_STRING([--disable-libpthread],
1815                 [disable libpthread]),
1816         [], [enable_libpthread="yes"])
1817 AC_MSG_RESULT([$enable_libpthread])
1818
1819 PTHREAD_LIBS=""
1820 AS_IF([test "x$enable_libpthread" = xyes], [
1821         AC_CHECK_LIB([pthread], [pthread_create], [
1822                 PTHREAD_LIBS="-lpthread"
1823                 AC_DEFINE([HAVE_LIBPTHREAD], 1,
1824                         [use libpthread for libcfs library])
1825         ])
1826 ], [
1827         AC_MSG_WARN([Using libpthread for libcfs library is disabled explicitly])
1828 ])
1829 AC_SUBST(PTHREAD_LIBS)
1830 ]) # LIBCFS_CONFIGURE
1831
1832 #
1833 # LIBCFS_CONFIG_FILES
1834 #
1835 # files that should be generated with AC_OUTPUT
1836 #
1837 AC_DEFUN([LIBCFS_CONFIG_FILES], [
1838 AC_CONFIG_FILES([
1839 libcfs/Makefile
1840 libcfs/autoMakefile
1841 libcfs/autoconf/Makefile
1842 libcfs/include/Makefile
1843 libcfs/include/libcfs/Makefile
1844 libcfs/include/uapi/Makefile
1845 libcfs/include/libcfs/linux/Makefile
1846 libcfs/include/libcfs/util/Makefile
1847 libcfs/include/libcfs/crypto/Makefile
1848 libcfs/include/uapi/linux/Makefile
1849 libcfs/libcfs/Makefile
1850 libcfs/libcfs/autoMakefile
1851 libcfs/libcfs/linux/Makefile
1852 libcfs/libcfs/util/Makefile
1853 libcfs/libcfs/crypto/Makefile
1854 ])
1855 ]) # LIBCFS_CONFIG_FILES