libcfs/autoconf/lustre-libcfs.m4

   1 #
   2 # LN_CONFIG_CDEBUG
   3 #
   4 # whether to enable various libcfs debugs (CDEBUG, ENTRY/EXIT, LASSERT, etc.)
   5 #
   6 AC_DEFUN([LN_CONFIG_CDEBUG],
   7 [
   8 AC_MSG_CHECKING([whether to enable CDEBUG, CWARN])
   9 AC_ARG_ENABLE([libcfs_cdebug],
  10         AC_HELP_STRING([--disable-libcfs-cdebug],
  11                         [disable libcfs CDEBUG, CWARN]),
  12         [],[enable_libcfs_cdebug='yes'])
  13 AC_MSG_RESULT([$enable_libcfs_cdebug])
  14 if test x$enable_libcfs_cdebug = xyes; then
  15    AC_DEFINE(CDEBUG_ENABLED, 1, [enable libcfs CDEBUG, CWARN])
  16 else
  17    AC_DEFINE(CDEBUG_ENABLED, 0, [disable libcfs CDEBUG, CWARN])
  18 fi
  19
  20 AC_MSG_CHECKING([whether to enable ENTRY/EXIT])
  21 AC_ARG_ENABLE([libcfs_trace],
  22         AC_HELP_STRING([--disable-libcfs-trace],
  23                         [disable libcfs ENTRY/EXIT]),
  24         [],[enable_libcfs_trace='yes'])
  25 AC_MSG_RESULT([$enable_libcfs_trace])
  26 if test x$enable_libcfs_trace = xyes; then
  27    AC_DEFINE(CDEBUG_ENTRY_EXIT, 1, [enable libcfs ENTRY/EXIT])
  28 else
  29    AC_DEFINE(CDEBUG_ENTRY_EXIT, 0, [disable libcfs ENTRY/EXIT])
  30 fi
  31
  32 AC_MSG_CHECKING([whether to enable LASSERT, LASSERTF])
  33 AC_ARG_ENABLE([libcfs_assert],
  34         AC_HELP_STRING([--disable-libcfs-assert],
  35                         [disable libcfs LASSERT, LASSERTF]),
  36         [],[enable_libcfs_assert='yes'])
  37 AC_MSG_RESULT([$enable_libcfs_assert])
  38 if test x$enable_libcfs_assert = xyes; then
  39    AC_DEFINE(LIBCFS_DEBUG, 1, [enable libcfs LASSERT, LASSERTF])
  40 fi
  41 ])
  42
  43 #
  44 # LIBCFS_CONFIG_PANIC_DUMPLOG
  45 #
  46 # check if tunable panic_dumplog is wanted
  47 #
  48 AC_DEFUN([LIBCFS_CONFIG_PANIC_DUMPLOG],
  49 [AC_MSG_CHECKING([for tunable panic_dumplog support])
  50 AC_ARG_ENABLE([panic_dumplog],
  51        AC_HELP_STRING([--enable-panic_dumplog],
  52                       [enable panic_dumplog]),
  53        [],[enable_panic_dumplog='no'])
  54 if test x$enable_panic_dumplog = xyes ; then
  55        AC_DEFINE(LNET_DUMP_ON_PANIC, 1, [use dumplog on panic])
  56        AC_MSG_RESULT([yes (by request)])
  57 else
  58        AC_MSG_RESULT([no])
  59 fi
  60 ])
  61
  62 #
  63 # LIBCFS_STRUCT_PAGE_LIST
  64 #
  65 # 2.6.4 no longer has page->list
  66 #
  67 AC_DEFUN([LIBCFS_STRUCT_PAGE_LIST],
  68 [AC_MSG_CHECKING([if struct page has a list field])
  69 LB_LINUX_TRY_COMPILE([
  70         #include <linux/mm.h>
  71 ],[
  72         struct page page;
  73         &page.list;
  74 ],[
  75         AC_MSG_RESULT([yes])
  76         AC_DEFINE(HAVE_PAGE_LIST, 1, [struct page has a list field])
  77 ],[
  78         AC_MSG_RESULT([no])
  79 ])
  80 ])
  81
  82 #
  83 # LIBCFS_STRUCT_SIGHAND
  84 #
  85 # red hat 2.4 adds sighand to struct task_struct
  86 #
  87 AC_DEFUN([LIBCFS_STRUCT_SIGHAND],
  88 [AC_MSG_CHECKING([if task_struct has a sighand field])
  89 LB_LINUX_TRY_COMPILE([
  90         #include <linux/sched.h>
  91 ],[
  92         struct task_struct p;
  93         p.sighand = NULL;
  94 ],[
  95         AC_DEFINE(CONFIG_RH_2_4_20, 1, [this kernel contains Red Hat 2.4.20 patches])
  96         AC_MSG_RESULT([yes])
  97 ],[
  98         AC_MSG_RESULT([no])
  99 ])
 100 ])
 101
 102 #
 103 # LIBCFS_FUNC_CPU_ONLINE
 104 #
 105 # cpu_online is different in rh 2.4, vanilla 2.4, and 2.6
 106 #
 107 AC_DEFUN([LIBCFS_FUNC_CPU_ONLINE],
 108 [AC_MSG_CHECKING([if kernel defines cpu_online()])
 109 LB_LINUX_TRY_COMPILE([
 110         #include <linux/sched.h>
 111 ],[
 112         cpu_online(0);
 113 ],[
 114         AC_MSG_RESULT([yes])
 115         AC_DEFINE(HAVE_CPU_ONLINE, 1, [cpu_online found])
 116 ],[
 117         AC_MSG_RESULT([no])
 118 ])
 119 ])
 120
 121 #
 122 # LIBCFS_TYPE_GFP_T
 123 #
 124 # check if gfp_t is typedef-ed
 125 #
 126 AC_DEFUN([LIBCFS_TYPE_GFP_T],
 127 [AC_MSG_CHECKING([if kernel defines gfp_t])
 128 LB_LINUX_TRY_COMPILE([
 129         #include <linux/gfp.h>
 130 ],[
 131         return sizeof(gfp_t);
 132 ],[
 133         AC_MSG_RESULT([yes])
 134         AC_DEFINE(HAVE_GFP_T, 1, [gfp_t found])
 135 ],[
 136         AC_MSG_RESULT([no])
 137 ])
 138 ])
 139
 140 #
 141 # LIBCFS_TYPE_CPUMASK_T
 142 #
 143 # same goes for cpumask_t
 144 #
 145 AC_DEFUN([LIBCFS_TYPE_CPUMASK_T],
 146 [AC_MSG_CHECKING([if kernel defines cpumask_t])
 147 LB_LINUX_TRY_COMPILE([
 148         #include <linux/sched.h>
 149 ],[
 150         return sizeof (cpumask_t);
 151 ],[
 152         AC_MSG_RESULT([yes])
 153         AC_DEFINE(HAVE_CPUMASK_T, 1, [cpumask_t found])
 154 ],[
 155         AC_MSG_RESULT([no])
 156 ])
 157 ])
 158
 159 #
 160 # LIBCFS_FUNC_SHOW_TASK
 161 #
 162 # we export show_task(), but not all kernels have it (yet)
 163 #
 164 AC_DEFUN([LIBCFS_FUNC_SHOW_TASK],
 165 [LB_CHECK_SYMBOL_EXPORT([show_task],
 166 [kernel/ksyms.c kernel/sched.c],[
 167 AC_DEFINE(HAVE_SHOW_TASK, 1, [show_task is exported])
 168 ],[
 169 ])
 170 ])
 171
 172 # check userland __u64 type
 173 AC_DEFUN([LIBCFS_U64_LONG_LONG],
 174 [AC_MSG_CHECKING([u64 is long long type])
 175 tmp_flags="$CFLAGS"
 176 CFLAGS="$CFLAGS -Werror"
 177 AC_COMPILE_IFELSE([
 178         #include <linux/types.h>
 179         int main(void) {
 180                 unsigned long long *data1;
 181                 __u64 *data2;
 182
 183                 data1 = data2;
 184                 return 0;
 185         }
 186 ],[
 187         AC_MSG_RESULT([yes])
 188         AC_DEFINE(HAVE_U64_LONG_LONG, 1,
 189                   [__u64 is long long type])
 190 ],[
 191         AC_MSG_RESULT([no])
 192 ])
 193 CFLAGS="$tmp_flags"
 194 ])
 195
 196 # check userland size_t type
 197 AC_DEFUN([LIBCFS_SIZE_T_LONG],
 198 [AC_MSG_CHECKING([size_t is unsigned long type])
 199 tmp_flags="$CFLAGS"
 200 CFLAGS="$CFLAGS -Werror"
 201 AC_COMPILE_IFELSE([
 202         #include <linux/types.h>
 203         int main(void) {
 204                 unsigned long *data1;
 205                 size_t *data2;
 206
 207                 data1 = data2;
 208                 return 0;
 209         }
 210 ],[
 211         AC_MSG_RESULT([yes])
 212         AC_DEFINE(HAVE_SIZE_T_LONG, 1,
 213                   [size_t is long type])
 214 ],[
 215         AC_MSG_RESULT([no])
 216 ])
 217 CFLAGS="$tmp_flags"
 218 ])
 219
 220 AC_DEFUN([LIBCFS_SSIZE_T_LONG],
 221 [AC_MSG_CHECKING([ssize_t is signed long type])
 222 tmp_flags="$CFLAGS"
 223 CFLAGS="$CFLAGS -Werror"
 224 AC_COMPILE_IFELSE([
 225         #include <linux/types.h>
 226         int main(void) {
 227                 long *data1;
 228                 ssize_t *data2;
 229
 230                 data1 = data2;
 231                 return 0;
 232         }
 233 ],[
 234         AC_MSG_RESULT([yes])
 235         AC_DEFINE(HAVE_SSIZE_T_LONG, 1,
 236                   [ssize_t is long type])
 237 ],[
 238         AC_MSG_RESULT([no])
 239 ])
 240 CFLAGS="$tmp_flags"
 241 ])
 242
 243
 244 # check if task_struct with rcu memeber
 245 AC_DEFUN([LIBCFS_TASK_RCU],
 246 [AC_MSG_CHECKING([if task_struct has a rcu field])
 247 LB_LINUX_TRY_COMPILE([
 248         #include <linux/sched.h>
 249 ],[
 250         struct task_struct tsk;
 251
 252         tsk.rcu.next = NULL;
 253 ],[
 254         AC_MSG_RESULT([yes])
 255         AC_DEFINE(HAVE_TASK_RCU, 1,
 256                   [task_struct has rcu field])
 257 ],[
 258         AC_MSG_RESULT([no])
 259 ])
 260 ])
 261
 262 # LIBCFS_TASKLIST_LOCK
 263 # 2.6.18 remove tasklist_lock export
 264 AC_DEFUN([LIBCFS_TASKLIST_LOCK],
 265 [LB_CHECK_SYMBOL_EXPORT([tasklist_lock],
 266 [kernel/fork.c],[
 267 AC_DEFINE(HAVE_TASKLIST_LOCK, 1,
 268          [tasklist_lock exported])
 269 ],[
 270 ])
 271 ])
 272
 273 # 2.6.19 API changes
 274 # kmem_cache_destroy(cachep) return void instead of
 275 # int
 276 AC_DEFUN([LIBCFS_KMEM_CACHE_DESTROY_INT],
 277 [AC_MSG_CHECKING([kmem_cache_destroy(cachep) return int])
 278 LB_LINUX_TRY_COMPILE([
 279         #include <linux/slab.h>
 280 ],[
 281         int i = kmem_cache_destroy(NULL);
 282 ],[
 283         AC_MSG_RESULT(yes)
 284         AC_DEFINE(HAVE_KMEM_CACHE_DESTROY_INT, 1,
 285                 [kmem_cache_destroy(cachep) return int])
 286 ],[
 287         AC_MSG_RESULT(NO)
 288 ])
 289 ])
 290
 291 # 2.6.19 API change
 292 #panic_notifier_list use atomic_notifier operations
 293 #
 294 AC_DEFUN([LIBCFS_ATOMIC_PANIC_NOTIFIER],
 295 [AC_MSG_CHECKING([panic_notifier_list is atomic])
 296 LB_LINUX_TRY_COMPILE([
 297         #include <linux/notifier.h>
 298         #include <linux/kernel.h>
 299 ],[
 300         struct atomic_notifier_head panic_notifier_list;
 301 ],[
 302         AC_MSG_RESULT(yes)
 303         AC_DEFINE(HAVE_ATOMIC_PANIC_NOTIFIER, 1,
 304                 [panic_notifier_list is atomic_notifier_head])
 305 ],[
 306         AC_MSG_RESULT(NO)
 307 ])
 308 ])
 309
 310 # 2.6.20 API change INIT_WORK use 2 args and not
 311 # store data inside
 312 AC_DEFUN([LIBCFS_3ARGS_INIT_WORK],
 313 [AC_MSG_CHECKING([check INIT_WORK want 3 args])
 314 LB_LINUX_TRY_COMPILE([
 315         #include <linux/workqueue.h>
 316 ],[
 317         struct work_struct work;
 318
 319         INIT_WORK(&work, NULL, NULL);
 320 ],[
 321         AC_MSG_RESULT(yes)
 322         AC_DEFINE(HAVE_3ARGS_INIT_WORK, 1,
 323                   [INIT_WORK use 3 args and store data inside])
 324 ],[
 325         AC_MSG_RESULT(NO)
 326 ])
 327 ])
 328
 329 # 2.6.21 api change. 'register_sysctl_table' use only one argument,
 330 # instead of more old which need two.
 331 AC_DEFUN([LIBCFS_2ARGS_REGISTER_SYSCTL],
 332 [AC_MSG_CHECKING([check register_sysctl_table want 2 args])
 333 LB_LINUX_TRY_COMPILE([
 334         #include <linux/sysctl.h>
 335 ],[
 336         return register_sysctl_table(NULL,0);
 337 ],[
 338         AC_MSG_RESULT(yes)
 339         AC_DEFINE(HAVE_2ARGS_REGISTER_SYSCTL, 1,
 340                   [register_sysctl_table want 2 args])
 341 ],[
 342         AC_MSG_RESULT(NO)
 343 ])
 344 ])
 345
 346 # 2.6.21 marks kmem_cache_t deprecated and uses struct kmem_cache
 347 # instead
 348 AC_DEFUN([LIBCFS_KMEM_CACHE],
 349 [AC_MSG_CHECKING([check kernel has struct kmem_cache])
 350 tmp_flags="$EXTRA_KCFLAGS"
 351 EXTRA_KCFLAGS="-Werror"
 352 LB_LINUX_TRY_COMPILE([
 353         #include <linux/slab.h>
 354         typedef struct kmem_cache cache_t;
 355 ],[
 356         cache_t *cachep = NULL;
 357
 358         kmem_cache_alloc(cachep, 0);
 359 ],[
 360         AC_MSG_RESULT(yes)
 361         AC_DEFINE(HAVE_KMEM_CACHE, 1,
 362                   [kernel has struct kmem_cache])
 363 ],[
 364         AC_MSG_RESULT(NO)
 365 ])
 366 EXTRA_KCFLAGS="$tmp_flags"
 367 ])
 368 # 2.6.23 lost dtor argument
 369 AC_DEFUN([LIBCFS_KMEM_CACHE_CREATE_DTOR],
 370 [AC_MSG_CHECKING([check kmem_cache_create has dtor argument])
 371 LB_LINUX_TRY_COMPILE([
 372         #include <linux/slab.h>
 373 ],[
 374         kmem_cache_create(NULL, 0, 0, 0, NULL, NULL);
 375 ],[
 376         AC_MSG_RESULT(yes)
 377         AC_DEFINE(HAVE_KMEM_CACHE_CREATE_DTOR, 1,
 378                   [kmem_cache_create has dtor argument])
 379 ],[
 380         AC_MSG_RESULT(NO)
 381 ])
 382 ])
 383
 384 # 2.6.24 request not use real numbers for ctl_name
 385 AC_DEFUN([LN_SYSCTL_UNNUMBERED],
 386 [AC_MSG_CHECKING([for CTL_UNNUMBERED])
 387 LB_LINUX_TRY_COMPILE([
 388         #include <linux/sysctl.h>
 389 ],[
 390         #ifndef CTL_UNNUMBERED
 391         #error CTL_UNNUMBERED not exist in kernel
 392         #endif
 393 ],[
 394         AC_MSG_RESULT(yes)
 395         AC_DEFINE(HAVE_SYSCTL_UNNUMBERED, 1,
 396                   [sysctl has CTL_UNNUMBERED])
 397 ],[
 398         AC_MSG_RESULT(NO)
 399 ])
 400 ])
 401
 402 # 2.6.24 lost scatterlist->page
 403 AC_DEFUN([LN_SCATTERLIST_SETPAGE],
 404 [AC_MSG_CHECKING([for exist sg_set_page])
 405 LB_LINUX_TRY_COMPILE([
 406         #include <linux/scatterlist.h>
 407 ],[
 408         sg_set_page(NULL,NULL,0,0);
 409 ],[
 410         AC_MSG_RESULT(yes)
 411         AC_DEFINE(HAVE_SCATTERLIST_SETPAGE, 1,
 412                   [struct scatterlist has page member])
 413 ],[
 414         AC_MSG_RESULT(NO)
 415 ])
 416 ])
 417
 418 # 2.6.26 use int instead of atomic for sem.count
 419 AC_DEFUN([LN_SEM_COUNT],
 420 [AC_MSG_CHECKING([atomic sem.count])
 421 LB_LINUX_TRY_COMPILE([
 422         #include <asm/semaphore.h>
 423 ],[
 424         struct semaphore s;
 425
 426         atomic_read(&s.count);
 427 ],[
 428         AC_MSG_RESULT(yes)
 429         AC_DEFINE(HAVE_SEM_COUNT_ATOMIC, 1,
 430                   [semaphore counter is atomic])
 431 ],[
 432         AC_MSG_RESULT(NO)
 433 ])
 434 ])
 435
 436 #
 437 # LIBCFS_PROG_LINUX
 438 #
 439 # LNet linux kernel checks
 440 #
 441 AC_DEFUN([LIBCFS_PROG_LINUX],
 442 [
 443 LIBCFS_FUNC_CPU_ONLINE
 444 LIBCFS_TYPE_GFP_T
 445 LIBCFS_TYPE_CPUMASK_T
 446 LIBCFS_CONFIG_PANIC_DUMPLOG
 447
 448 LIBCFS_STRUCT_PAGE_LIST
 449 LIBCFS_STRUCT_SIGHAND
 450 LIBCFS_FUNC_SHOW_TASK
 451 LIBCFS_U64_LONG_LONG
 452 LIBCFS_SSIZE_T_LONG
 453 LIBCFS_SIZE_T_LONG
 454 LIBCFS_TASK_RCU
 455 # 2.6.18
 456 LIBCFS_TASKLIST_LOCK
 457 # 2.6.19
 458 LIBCFS_KMEM_CACHE_DESTROY_INT
 459 LIBCFS_ATOMIC_PANIC_NOTIFIER
 460 # 2.6.20
 461 LIBCFS_3ARGS_INIT_WORK
 462 # 2.6.21
 463 LIBCFS_2ARGS_REGISTER_SYSCTL
 464 LIBCFS_KMEM_CACHE
 465 # 2.6.23
 466 LIBCFS_KMEM_CACHE_CREATE_DTOR
 467 # 2.6.24
 468 LN_SYSCTL_UNNUMBERED
 469 LN_SCATTERLIST_SETPAGE
 470 # 2.6.26
 471 LN_SEM_COUNT
 472 ])
 473
 474 #
 475 # LIBCFS_PROG_DARWIN
 476 #
 477 # Darwin checks
 478 #
 479 AC_DEFUN([LIBCFS_PROG_DARWIN],
 480 [LB_DARWIN_CHECK_FUNCS([get_preemption_level])
 481 ])
 482
 483 #
 484 # LIBCFS_PATH_DEFAULTS
 485 #
 486 # default paths for installed files
 487 #
 488 AC_DEFUN([LIBCFS_PATH_DEFAULTS],
 489 [
 490 ])
 491
 492 #
 493 # LIBCFS_CONFIGURE
 494 #
 495 # other configure checks
 496 #
 497 AC_DEFUN([LIBCFS_CONFIGURE],
 498 [# lnet/utils/portals.c
 499 AC_CHECK_HEADERS([asm/types.h endian.h sys/ioctl.h])
 500
 501 # lnet/utils/debug.c
 502 AC_CHECK_HEADERS([linux/version.h])
 503
 504 AC_CHECK_TYPE([spinlock_t],
 505         [AC_DEFINE(HAVE_SPINLOCK_T, 1, [spinlock_t is defined])],
 506         [],
 507         [#include <linux/spinlock.h>])
 508
 509 # lnet/utils/wirecheck.c
 510 AC_CHECK_FUNCS([strnlen])
 511
 512 AC_CHECK_TYPE([umode_t],
 513         [AC_DEFINE(HAVE_UMODE_T, 1, [umode_t is defined])],
 514         [],
 515         [#include <signal.h>])
 516
 517 AC_CHECK_TYPE([__u64],
 518         [AC_DEFINE(HAVE___U64, 1, [__u64 is defined])],
 519         [],
 520         [#include <signal.h>])
 521
 522 AC_CHECK_TYPE([__s64],
 523         [AC_DEFINE(HAVE___S64, 1, [__s64 is defined])],
 524         [],
 525         [#include <signal.h>])
 526
 527 # --------  Check for required packages  --------------
 528
 529
 530 AC_MSG_CHECKING([if efence debugging support is requested])
 531 AC_ARG_ENABLE(efence,
 532         AC_HELP_STRING([--enable-efence],
 533                         [use efence library]),
 534         [],[enable_efence='no'])
 535 AC_MSG_RESULT([$enable_efence])
 536 if test "$enable_efence" = "yes" ; then
 537         LIBEFENCE="-lefence"
 538         AC_DEFINE(HAVE_LIBEFENCE, 1, [libefence support is requested])
 539 else
 540         LIBEFENCE=""
 541 fi
 542 AC_SUBST(LIBEFENCE)
 543
 544
 545 # -------- check for -lpthread support ----
 546 AC_MSG_CHECKING([whether to use libpthread for libcfs library])
 547 AC_ARG_ENABLE([libpthread],
 548         AC_HELP_STRING([--disable-libpthread],
 549                 [disable libpthread]),
 550         [],[enable_libpthread=yes])
 551 if test "$enable_libpthread" = "yes" ; then
 552         AC_CHECK_LIB([pthread], [pthread_create],
 553                 [ENABLE_LIBPTHREAD="yes"],
 554                 [ENABLE_LIBPTHREAD="no"])
 555         if test "$ENABLE_LIBPTHREAD" = "yes" ; then
 556                 AC_MSG_RESULT([$ENABLE_LIBPTHREAD])
 557                 PTHREAD_LIBS="-lpthread"
 558                 AC_DEFINE([HAVE_LIBPTHREAD], 1, [use libpthread])
 559         else
 560                 PTHREAD_LIBS=""
 561                 AC_MSG_RESULT([no libpthread is found])
 562         fi
 563         AC_SUBST(PTHREAD_LIBS)
 564 else
 565         AC_MSG_RESULT([no (disabled explicitly)])
 566         ENABLE_LIBPTHREAD="no"
 567 fi
 568 AC_SUBST(ENABLE_LIBPTHREAD)
 569
 570
 571 ])
 572
 573 #
 574 # LIBCFS_CONDITIONALS
 575 #
 576 # AM_CONDITOINAL defines for lnet
 577 #
 578 AC_DEFUN([LIBCFS_CONDITIONALS],
 579 [
 580 ])
 581
 582 #
 583 # LIBCFS_CONFIG_FILES
 584 #
 585 # files that should be generated with AC_OUTPUT
 586 #
 587 AC_DEFUN([LIBCFS_CONFIG_FILES],
 588 [AC_CONFIG_FILES([
 589 libcfs/Kernelenv
 590 libcfs/Makefile
 591 libcfs/autoMakefile
 592 libcfs/autoconf/Makefile
 593 libcfs/include/Makefile
 594 libcfs/include/libcfs/Makefile
 595 libcfs/include/libcfs/linux/Makefile
 596 libcfs/include/libcfs/posix/Makefile
 597 libcfs/include/libcfs/util/Makefile
 598 libcfs/libcfs/Makefile
 599 libcfs/libcfs/autoMakefile
 600 libcfs/libcfs/linux/Makefile
 601 libcfs/libcfs/posix/Makefile
 602 libcfs/libcfs/util/Makefile
 603 ])
 604 case $lb_target_os in
 605         darwin)
 606                 AC_CONFIG_FILES([
 607 libcfs/include/libcfs/darwin/Makefile
 608 libcfs/libcfs/darwin/Makefile
 609 ])
 610                 ;;
 611 esac
 612 ])