Whamcloud - gitweb
9f7230544fa951f10a4c542fada57ae333518167
[fs/lustre-release.git] / libcfs / autoconf / lustre-libcfs.m4
1 #
2 # LIBCFS_CONFIG_CDEBUG
3 #
4 # whether to enable various libcfs debugs (CDEBUG, ENTRY/EXIT, LASSERT, etc.)
5 #
6 AC_DEFUN([LIBCFS_CONFIG_CDEBUG], [
7 AC_MSG_CHECKING([whether to enable CDEBUG, CWARN])
8 AC_ARG_ENABLE([libcfs_cdebug],
9         AC_HELP_STRING([--disable-libcfs-cdebug],
10                 [disable libcfs CDEBUG, CWARN]),
11         [], [enable_libcfs_cdebug="yes"])
12 AC_MSG_RESULT([$enable_libcfs_cdebug])
13 AS_IF([test "x$enable_libcfs_cdebug" = xyes],
14         [AC_DEFINE(CDEBUG_ENABLED, 1, [enable libcfs CDEBUG, CWARN])])
15
16 AC_MSG_CHECKING([whether to enable ENTRY/EXIT])
17 AC_ARG_ENABLE([libcfs_trace],
18         AC_HELP_STRING([--disable-libcfs-trace],
19                 [disable libcfs ENTRY/EXIT]),
20         [], [enable_libcfs_trace="yes"])
21 AC_MSG_RESULT([$enable_libcfs_trace])
22 AS_IF([test "x$enable_libcfs_trace" = xyes],
23         [AC_DEFINE(CDEBUG_ENTRY_EXIT, 1, [enable libcfs ENTRY/EXIT])])
24
25 AC_MSG_CHECKING([whether to enable LASSERT, LASSERTF])
26 AC_ARG_ENABLE([libcfs_assert],
27         AC_HELP_STRING([--disable-libcfs-assert],
28                 [disable libcfs LASSERT, LASSERTF]),
29         [], [enable_libcfs_assert="yes"])
30 AC_MSG_RESULT([$enable_libcfs_assert])
31 AS_IF([test x$enable_libcfs_assert = xyes],
32         [AC_DEFINE(LIBCFS_DEBUG, 1, [enable libcfs LASSERT, LASSERTF])])
33 ]) # LIBCFS_CONFIG_CDEBUG
34
35 #
36 # LIBCFS_CONFIG_PANIC_DUMPLOG
37 #
38 # check if tunable panic_dumplog is wanted
39 #
40 AC_DEFUN([LIBCFS_CONFIG_PANIC_DUMPLOG], [
41 AC_MSG_CHECKING([whether to use tunable 'panic_dumplog' support])
42 AC_ARG_ENABLE([panic_dumplog],
43         AC_HELP_STRING([--enable-panic_dumplog],
44                 [enable panic_dumplog]),
45         [], [enable_panic_dumplog="no"])
46 AC_MSG_RESULT([$enable_panic_dumplog])
47 AS_IF([test "x$enable_panic_dumplog" = xyes],
48         [AC_DEFINE(LNET_DUMP_ON_PANIC, 1, [use dumplog on panic])])
49 ]) # LIBCFS_CONFIG_PANIC_DUMPLOG
50
51 #
52 # LIBCFS_STACKTRACE_OPS_HAVE_WALK_STACK
53 #
54 # 2.6.32-30.el6 adds a new 'walk_stack' field in 'struct stacktrace_ops'
55 #
56 AC_DEFUN([LIBCFS_STACKTRACE_OPS_HAVE_WALK_STACK], [
57 LB_CHECK_COMPILE([if 'struct stacktrace_ops' has 'walk_stack' field],
58 stacktrace_ops_walk_stack, [
59         #include <asm/stacktrace.h>
60 ],[
61         ((struct stacktrace_ops *)0)->walk_stack(NULL, NULL, 0, NULL, NULL, NULL, NULL);
62 ],[
63         AC_DEFINE(STACKTRACE_OPS_HAVE_WALK_STACK, 1,
64                 ['struct stacktrace_ops' has 'walk_stack' field])
65 ])
66 ]) # LIBCFS_STACKTRACE_OPS_HAVE_WALK_STACK
67
68 #
69 # LIBCFS_STACKTRACE_WARNING
70 #
71 # 3.0 removes stacktrace_ops warning* functions
72 #
73 AC_DEFUN([LIBCFS_STACKTRACE_WARNING], [
74 LB_CHECK_COMPILE([if 'stacktrace_ops.warning' is exist],
75 stacktrace_ops_warning, [
76         struct task_struct;
77         struct pt_regs;
78         #include <asm/stacktrace.h>
79 ],[
80         ((struct stacktrace_ops *)0)->warning(NULL, NULL);
81 ],[
82         AC_DEFINE(HAVE_STACKTRACE_WARNING, 1,
83                 [stacktrace_ops.warning is exist])
84 ])
85 ]) # LIBCFS_STACKTRACE_WARNING
86
87 #
88 # LC_SHRINKER_WANT_SHRINK_PTR
89 #
90 # RHEL6/2.6.32 want to have pointer to shrinker self pointer in handler function
91 #
92 AC_DEFUN([LC_SHRINKER_WANT_SHRINK_PTR], [
93 LB_CHECK_COMPILE([if 'shrinker' want self pointer in handler],
94 shrink_self_pointer, [
95         #include <linux/mm.h>
96 ],[
97         struct shrinker *tmp = NULL;
98         tmp->shrink(tmp, 0, 0);
99 ],[
100         AC_DEFINE(HAVE_SHRINKER_WANT_SHRINK_PTR, 1,
101                 [shrinker want self pointer in handler])
102 ])
103 ]) # LC_SHRINKER_WANT_SHRINK_PTR
104
105 #
106 # LIBCFS_SYSCTL_CTLNAME
107 #
108 # 2.6.33 no longer has ctl_name & strategy field in struct ctl_table.
109 #
110 AC_DEFUN([LIBCFS_SYSCTL_CTLNAME], [
111 LB_CHECK_COMPILE([if 'ctl_table' has a 'ctl_name' field],
112 ctl_table_ctl_name, [
113         #include <linux/sysctl.h>
114 ],[
115         struct ctl_table ct;
116         ct.ctl_name = sizeof(ct);
117 ],[
118         AC_DEFINE(HAVE_SYSCTL_CTLNAME, 1,
119                 [ctl_table has ctl_name field])
120 ])
121 ]) # LIBCFS_SYSCTL_CTLNAME
122
123 #
124 # LIBCFS_MODULE_LOCKING
125 #
126 # 2.6.36 introduced locking to module params. RHEL6 lacks this support
127 #
128 AC_DEFUN([LIBCFS_MODULE_LOCKING],[
129 LB_CHECK_COMPILE([does the kernel support module param locking],
130 module_param_locking, [
131         #include <linux/moduleparam.h>
132 ],[
133         __kernel_param_lock(NULL);
134         __kernel_param_unlock(NULL);
135 ],[
136         AC_DEFINE(HAVE_MODULE_PARAM_LOCKING, 1,
137                 [locking module param is supported])
138 ])
139 ]) # LIBCFS_MODULE_LOCKING
140
141 #
142 # LIBCFS_KSTRTOUL
143 #
144 # 2.6.38 kstrtoul is added
145 #
146 AC_DEFUN([LIBCFS_KSTRTOUL], [
147 LB_CHECK_COMPILE([if Linux kernel has 'kstrtoul'],
148 kstrtoul, [
149         #include <linux/kernel.h>
150 ],[
151         unsigned long result;
152         return kstrtoul("12345", 0, &result);
153 ],[
154         AC_DEFINE(HAVE_KSTRTOUL, 1,
155                 [kernel has kstrtoul])
156 ])
157 ]) # LIBCFS_KSTRTOUL
158
159 #
160 # LIBCFS_DUMP_TRACE_ADDRESS
161 #
162 # 2.6.39 adds a base pointer address argument to dump_trace
163 #
164 AC_DEFUN([LIBCFS_DUMP_TRACE_ADDRESS], [
165 LB_CHECK_COMPILE([if 'dump_trace' want address],
166 dump_trace_address, [
167         struct task_struct;
168         struct pt_regs;
169         #include <asm/stacktrace.h>
170 ],[
171         dump_trace(NULL, NULL, NULL, 0, NULL, NULL);
172 ],[
173         AC_DEFINE(HAVE_DUMP_TRACE_ADDRESS, 1,
174                 [dump_trace want address argument])
175 ])
176 ]) # LIBCFS_DUMP_TRACE_ADDRESS
177
178 #
179 # LC_SHRINK_CONTROL
180 #
181 # FC15 2.6.40-5 backported the "shrink_control" parameter to the memory
182 # pressure shrinker from Linux 3.0
183 #
184 AC_DEFUN([LC_SHRINK_CONTROL], [
185 LB_CHECK_COMPILE([if 'shrink_control' is present],
186 shrink_control, [
187         #include <linux/atomic.h>
188         #include <linux/mm.h>
189 ],[
190         struct shrink_control tmp = {0};
191         tmp.nr_to_scan = sizeof(tmp);
192 ],[
193         AC_DEFINE(HAVE_SHRINK_CONTROL, 1,
194                 [shrink_control is present])
195 ])
196 ]) # LC_SHRINK_CONTROL
197
198 #
199 # LIBCFS_PROCESS_NAMESPACE
200 #
201 # 3.5 introduced process namespace
202 AC_DEFUN([LIBCFS_PROCESS_NAMESPACE], [
203 LB_CHECK_LINUX_HEADER([linux/uidgid.h], [
204         AC_DEFINE(HAVE_UIDGID_HEADER, 1,
205                 [uidgid.h is present])])
206 ]) # LIBCFS_PROCESS_NAMESPACE
207
208 #
209 # LIBCFS_I_UID_READ
210 #
211 # 3.5 added helpers to read the new uid/gid types from VFS structures
212 # SLE11 SP3 has uidgid.h but not the helpers
213 #
214 AC_DEFUN([LIBCFS_I_UID_READ], [
215 LB_CHECK_COMPILE([if 'i_uid_read' is present],
216 i_uid_read, [
217         #include <linux/fs.h>
218 ],[
219         i_uid_read(NULL);
220 ],[
221         AC_DEFINE(HAVE_I_UID_READ, 1, [i_uid_read is present])
222 ])
223 ]) # LIBCFS_I_UID_READ
224
225 #
226 # LIBCFS_HAVE_CRC32
227 #
228 AC_DEFUN([LIBCFS_HAVE_CRC32], [
229 LB_CHECK_CONFIG_IM([CRC32],
230         [have_crc32="yes"], [have_crc32="no"])
231 AS_IF([test "x$have_crc32" = xyes],
232         [AC_DEFINE(HAVE_CRC32, 1,
233                 [kernel compiled with CRC32 functions])])
234 ]) # LIBCFS_HAVE_CRC32
235
236 #
237 # LIBCFS_ENABLE_CRC32_ACCEL
238 #
239 AC_DEFUN([LIBCFS_ENABLE_CRC32_ACCEL], [
240 LB_CHECK_CONFIG_IM([CRYPTO_CRC32_PCLMUL],
241         [enable_crc32_crypto="no"], [enable_crc32_crypto="yes"])
242 AS_IF([test "x$have_crc32" = xyes -a "x$enable_crc32_crypto" = xyes], [
243         AC_DEFINE(NEED_CRC32_ACCEL, 1, [need pclmulqdq based crc32])
244         AC_MSG_WARN([No crc32 pclmulqdq crypto api found, enable internal pclmulqdq based crc32])])
245 ]) # LIBCFS_ENABLE_CRC32_ACCEL
246
247 #
248 # LIBCFS_ENABLE_CRC32C_ACCEL
249 #
250 AC_DEFUN([LIBCFS_ENABLE_CRC32C_ACCEL], [
251 LB_CHECK_CONFIG_IM([CRYPTO_CRC32C_INTEL],
252         [enable_crc32c_crypto="no"], [enable_crc32c_crypto="yes"])
253 AS_IF([test "x$enable_crc32c_crypto" = xyes], [
254         AC_DEFINE(NEED_CRC32C_ACCEL, 1, [need pclmulqdq based crc32c])
255         AC_MSG_WARN([No crc32c pclmulqdq crypto api found, enable internal pclmulqdq based crc32c])])
256 ]) # LIBCFS_ENABLE_CRC32C_ACCEL
257
258 #
259 # Kernel version 3.11 introduced ktime_get_ts64
260 #
261 AC_DEFUN([LIBCFS_KTIME_GET_TS64],[
262 LB_CHECK_COMPILE([does function 'ktime_get_ts64' exist],
263 ktime_get_ts64, [
264         #include <linux/hrtimer.h>
265         #include <linux/ktime.h>
266 ],[
267         struct timespec64 *ts = NULL;
268
269         ktime_get_ts64(ts);
270 ],[
271         AC_DEFINE(HAVE_KTIME_GET_TS64, 1,
272                 ['ktime_get_ts64' is available])
273 ])
274 ]) # LIBCFS_KTIME_GET_TS64
275
276 #
277 # Kernel version 3.12-rc4 commit c2d816443ef30 added prepare_to_wait_event()
278 #
279 AC_DEFUN([LIBCFS_PREPARE_TO_WAIT_EVENT],[
280 LB_CHECK_COMPILE([does function 'prepare_to_wait_event' exist],
281 prepare_to_wait_event, [
282         #include <linux/wait.h>
283 ],[
284         prepare_to_wait_event(NULL, NULL, 0);
285 ],[
286         AC_DEFINE(HAVE_PREPARE_TO_WAIT_EVENT, 1,
287                 ['prepare_to_wait_event' is available])
288 ])
289 ]) # LIBCFS_PREPARE_TO_WAIT_EVENT
290
291 #
292 # Linux kernel 3.12 introduced struct kernel_param_ops
293 # This has been backported to all lustre supported
294 # clients except RHEL6. We have to handle the differences.
295 #
296 AC_DEFUN([LIBCFS_KERNEL_PARAM_OPS],[
297 LB_CHECK_COMPILE([does 'struct kernel_param_ops' exist],
298 kernel_param_ops, [
299         #include <linux/module.h>
300 ],[
301         struct kernel_param_ops ops;
302
303         ops.set = NULL;
304 ],[
305         AC_DEFINE(HAVE_KERNEL_PARAM_OPS, 1,
306                 ['struct kernel_param_ops' is available])
307 ])
308 ]) # LIBCFS_KERNEL_PARAM_OPS
309
310 #
311 # Kernel version 3.12 introduced ktime_add
312 #
313 AC_DEFUN([LIBCFS_KTIME_ADD],[
314 LB_CHECK_COMPILE([does function 'ktime_add' exist],
315 ktime_add, [
316         #include <linux/hrtimer.h>
317         #include <linux/ktime.h>
318 ],[
319         ktime_t start = ktime_set(0, 0);
320         ktime_t end = start;
321         ktime_t total;
322
323         total = ktime_add(start, end);
324 ],[
325         AC_DEFINE(HAVE_KTIME_ADD, 1,
326                 [ktime_add is available])
327 ])
328 ]) # LIBCFS_KTIME_ADD
329
330 #
331 # Kernel version 3.12 introduced ktime_after
332 #
333 AC_DEFUN([LIBCFS_KTIME_AFTER],[
334 LB_CHECK_COMPILE([does function 'ktime_after' exist],
335 ktime_after, [
336         #include <linux/hrtimer.h>
337         #include <linux/ktime.h>
338 ],[
339         ktime_t start = ktime_set(0, 0);
340         ktime_t end = start;
341
342         ktime_after(start, end);
343 ],[
344         AC_DEFINE(HAVE_KTIME_AFTER, 1,
345                 [ktime_after is available])
346 ])
347 ]) # LIBCFS_KTIME_AFTER
348
349 #
350 # Kernel version 3.12 introduced ktime_before
351 # See linux commit 67cb9366ff5f99868100198efba5ca88aaa6ad25
352 #
353 AC_DEFUN([LIBCFS_KTIME_BEFORE],[
354 LB_CHECK_COMPILE([does function 'ktime_before' exist],
355 ktime_before, [
356         #include <linux/hrtimer.h>
357         #include <linux/ktime.h>
358 ],[
359         ktime_t start = ktime_set(0, 0);
360         ktime_t end = start;
361
362         ktime_before(start, end);
363 ],[
364         AC_DEFINE(HAVE_KTIME_BEFORE, 1,
365                 [ktime_before is available])
366 ])
367 ]) # LIBCFS_KTIME_BEFORE
368
369 #
370 # Kernel version 3.12 introduced ktime_compare
371 #
372 AC_DEFUN([LIBCFS_KTIME_COMPARE],[
373 LB_CHECK_COMPILE([does function 'ktime_compare' exist],
374 ktime_compare, [
375         #include <linux/hrtimer.h>
376         #include <linux/ktime.h>
377 ],[
378         ktime_t start = ktime_set(0, 0);
379         ktime_t end = start;
380
381         ktime_compare(start, end);
382 ],[
383         AC_DEFINE(HAVE_KTIME_COMPARE, 1,
384                 [ktime_compare is available])
385 ])
386 ]) # LIBCFS_KTIME_COMPARE
387
388 #
389 # FC19 3.12 kernel struct shrinker change
390 #
391 AC_DEFUN([LIBCFS_SHRINKER_COUNT],[
392 LB_CHECK_COMPILE([shrinker has 'count_objects'],
393 shrinker_count_objects, [
394         #include <linux/mmzone.h>
395         #include <linux/shrinker.h>
396 ],[
397         struct shrinker shrinker;
398
399         shrinker.count_objects = NULL;
400 ],[
401         AC_DEFINE(HAVE_SHRINKER_COUNT, 1,
402                 [shrinker has count_objects member])
403 ])
404 ]) # LIBCFS_SHRINKER_COUNT
405
406 #
407 # Kernel version 3.17 changed hlist_add_after to
408 # hlist_add_behind
409 #
410 AC_DEFUN([LIBCFS_HLIST_ADD_AFTER],[
411 LB_CHECK_COMPILE([does function 'hlist_add_after' exist],
412 hlist_add_after, [
413         #include <linux/list.h>
414 ],[
415         hlist_add_after(NULL, NULL);
416 ],[
417         AC_DEFINE(HAVE_HLIST_ADD_AFTER, 1,
418                 [hlist_add_after is available])
419 ])
420 ]) # LIBCFS_HLIST_ADD_AFTER
421
422 #
423 # Kernel version 3.17 introduced struct timespec64
424 #
425 AC_DEFUN([LIBCFS_TIMESPEC64],[
426 LB_CHECK_COMPILE([does 'struct timespec64' exist],
427 timespec64, [
428         #include <linux/time.h>
429 ],[
430         struct timespec64 ts;
431
432         ts.tv_sec = 0;
433         ts.tv_nsec = 0;
434 ],[
435         AC_DEFINE(HAVE_TIMESPEC64, 1,
436                 ['struct timespec64' is available])
437 ])
438 ]) # LIBCFS_TIMESPEC64
439
440 #
441 # Kernel version 3.17 introduced ktime_get_real_ts64
442 #
443 AC_DEFUN([LIBCFS_KTIME_GET_REAL_TS64],[
444 LB_CHECK_COMPILE([does function 'ktime_get_real_ts64' exist],
445 ktime_get_real_ts64, [
446         #include <linux/ktime.h>
447 ],[
448         struct timespec64 *ts = NULL;
449
450         ktime_get_real_ts64(ts);
451 ],[
452         AC_DEFINE(HAVE_KTIME_GET_REAL_TS64, 1,
453                 ['ktime_get_real_ts64' is available])
454 ])
455 ]) # LIBCFS_KTIME_GET_REAL_TS64
456
457 #
458 # Kernel version 3.17 introduced ktime_get_real_seconds
459 #
460 AC_DEFUN([LIBCFS_KTIME_GET_REAL_SECONDS],[
461 LB_CHECK_COMPILE([does function 'ktime_get_real_seconds' exist],
462 ktime_get_real_seconds, [
463         #include <linux/hrtimer.h>
464         #include <linux/ktime.h>
465 ],[
466         time64_t now;
467
468         now = ktime_get_real_seconds();
469 ],[
470         AC_DEFINE(HAVE_KTIME_GET_REAL_SECONDS, 1,
471                 ['ktime_get_real_seconds' is available])
472 ])
473 ]) # LIBCFS_KTIME_GET_REAL_SECONDS
474
475 #
476 # Kernel version 3.17 created ktime_get_ns wrapper
477 #
478 AC_DEFUN([LIBCFS_KTIME_GET_NS],[
479 LB_CHECK_COMPILE([does function 'ktime_get_ns' exist],
480 ktime_get_ns, [
481         #include <linux/hrtimer.h>
482         #include <linux/ktime.h>
483 ],[
484         u64 nanoseconds;
485
486         nanoseconds = ktime_get_ns();
487 ],[],[
488         AC_DEFINE(NEED_KTIME_GET_NS, 1,
489                 ['ktime_get_ns' is not available])
490 ])
491 ]) # LIBCFS_KTIME_GET_NS
492
493 #
494 # Kernel version 3.17 created ktime_get_real_ns wrapper
495 #
496 AC_DEFUN([LIBCFS_KTIME_GET_REAL_NS],[
497 LB_CHECK_COMPILE([does function 'ktime_get_real_ns' exist],
498 ktime_get_real_ns, [
499         #include <linux/hrtimer.h>
500         #include <linux/ktime.h>
501 ],[
502         u64 nanoseconds;
503
504         nanoseconds = ktime_get_real_ns();
505 ],[],[
506         AC_DEFINE(NEED_KTIME_GET_REAL_NS, 1,
507                 ['ktime_get_real_ns' is not available])
508 ])
509 ]) # LIBCFS_KTIME_GET_REAL_NS
510
511 #
512 # Kernel version 3.17 introduced ktime_to_timespec64
513 #
514 AC_DEFUN([LIBCFS_KTIME_TO_TIMESPEC64],[
515 LB_CHECK_COMPILE([does function 'ktime_to_timespec64' exist],
516 ktime_to_timespec64, [
517         #include <linux/hrtimer.h>
518         #include <linux/ktime.h>
519 ],[
520         ktime_t now = ktime_set(0, 0);
521         struct timespec64 ts;
522
523         ts = ktime_to_timespec64(now);
524 ],[
525         AC_DEFINE(HAVE_KTIME_TO_TIMESPEC64, 1,
526                 ['ktime_to_timespec64' is available])
527 ])
528 ]) # LIBCFS_KTIME_TO_TIMESPEC64
529
530 #
531 # Kernel version 3.17 introduced timespec64_sub
532 #
533 AC_DEFUN([LIBCFS_TIMESPEC64_SUB],[
534 LB_CHECK_COMPILE([does function 'timespec64_sub' exist],
535 timespec64_sub, [
536         #include <linux/time.h>
537 ],[
538         struct timespec64 later = { }, earlier = { }, diff;
539
540         diff = timespec64_sub(later, earlier);
541 ],[
542         AC_DEFINE(HAVE_TIMESPEC64_SUB, 1,
543                 ['timespec64_sub' is available])
544 ])
545 ]) # LIBCFS_TIMESPEC64_SUB
546
547 #
548 # Kernel version 3.17 introduced timespec64_to_ktime
549 #
550 AC_DEFUN([LIBCFS_TIMESPEC64_TO_KTIME],[
551 LB_CHECK_COMPILE([does function 'timespec64_to_ktime' exist],
552 timespec64_to_ktime, [
553         #include <linux/ktime.h>
554 ],[
555         struct timespec64 ts;
556         ktime_t now;
557
558         now = timespec64_to_ktime(ts);
559 ],[
560         AC_DEFINE(HAVE_TIMESPEC64_TO_KTIME, 1,
561                 ['timespec64_to_ktime' is available])
562 ])
563 ]) # LIBCFS_TIMESPEC64_TO_KTIME
564
565 #
566 # Kernel version 3.19 introduced ktime_get_seconds
567 #
568 AC_DEFUN([LIBCFS_KTIME_GET_SECONDS],[
569 LB_CHECK_COMPILE([does function 'ktime_get_seconds' exist],
570 ktime_get_seconds, [
571         #include <linux/ktime.h>
572 ],[
573         time64_t now;
574
575         now = ktime_get_seconds();
576 ],[
577         AC_DEFINE(HAVE_KTIME_GET_SECONDS, 1,
578                 ['ktime_get_seconds' is available])
579 ])
580 ]) # LIBCFS_KTIME_GET_SECONDS
581
582 #
583 # Kernel version 4.0 commit 41fbf3b39d5eca01527338b4d0ee15ee1ae1023c
584 # introduced the helper function ktime_ms_delta.
585 #
586 AC_DEFUN([LIBCFS_KTIME_MS_DELTA],[
587 LB_CHECK_COMPILE([does function 'ktime_ms_delta' exist],
588 ktime_ms_delta, [
589         #include <linux/ktime.h>
590 ],[
591         ktime_t start = ktime_set(0, 0);
592         ktime_t end = start;
593
594         ktime_ms_delta(start, end);
595 ],[
596         AC_DEFINE(HAVE_KTIME_MS_DELTA, 1,
597                 ['ktime_ms_delta' is available])
598 ])
599 ]) # LIBCFS_KTIME_MS_DELTA
600
601 #
602 # Kernel version 4.1 commit b51d23e4e9fea6f264d39535c2a62d1f51e7ccc3
603 # create per module locks which added kernel_param_[un]lock(). Older
604 # kernels you have to use __kernel_param_[un]lock(). In that case its
605 # a global lock for all modules but that is okay since its a rare event.
606 #
607 AC_DEFUN([LIBCFS_KERNEL_PARAM_LOCK],[
608 LB_CHECK_COMPILE([does function 'kernel_param_[un]lock' exist],
609 kernel_param_lock, [
610         #include <linux/moduleparam.h>
611 ],[
612         kernel_param_lock(NULL);
613         kernel_param_unlock(NULL);
614 ],[
615         AC_DEFINE(HAVE_KERNEL_PARAM_LOCK, 1,
616                 ['kernel_param_[un]lock' is available])
617 ])
618 ]) # LIBCFS_KERNEL_PARAM_LOCK
619
620 #
621 # Kernel version 4.2 changed topology_thread_cpumask
622 # to topology_sibling_cpumask
623 #
624 AC_DEFUN([LIBCFS_HAVE_TOPOLOGY_SIBLING_CPUMASK],[
625 LB_CHECK_COMPILE([does function 'topology_sibling_cpumask' exist],
626 topology_sibling_cpumask, [
627         #include <linux/topology.h>
628 ],[
629         const struct cpumask *mask;
630
631         mask = topology_sibling_cpumask(0);
632 ],[
633         AC_DEFINE(HAVE_TOPOLOGY_SIBLING_CPUMASK, 1,
634                 [topology_sibling_cpumask is available])
635 ])
636 ]) # LIBCFS_HAVE_TOPOLOGY_SIBLING_CPUMASK
637
638 #
639 # Kernel version 4.2 commit df6b35f409af0a8ff1ef62f552b8402f3fef8665
640 # header file i387.h was renamed to fpu/api.h
641 #
642 AC_DEFUN([LIBCFS_FPU_API], [
643 LB_CHECK_LINUX_HEADER([asm/fpu/api.h], [
644         AC_DEFINE(HAVE_FPU_API_HEADER, 1,
645                 [fpu/api.h is present])])
646 ]) # LIBCFS_FPU_API
647
648 #
649 # Kernel version 4.4 commit ef951599074ba4fad2d0efa0a977129b41e6d203
650 # introduced kstrtobool and kstrtobool_from_user.
651 #
652 AC_DEFUN([LIBCFS_KSTRTOBOOL_FROM_USER], [
653 LB_CHECK_COMPILE([if Linux kernel has 'kstrtobool_from_user'],
654 kstrtobool_from_user, [
655         #include <linux/kernel.h>
656 ],[
657         bool result;
658         return kstrtobool_from_user(NULL, 0, &result);
659 ],[
660         AC_DEFINE(HAVE_KSTRTOBOOL_FROM_USER, 1,
661                 [kernel has kstrtobool_from_user])
662 ])
663 ]) # LIBCFS_KSTRTOBOOL_FROM_USER
664
665 #
666 # Kernel version 4.5-rc1 commit d12481bc58fba89427565f8592e88446ec084a24
667 # added crypto hash helpers
668 #
669 AC_DEFUN([LIBCFS_CRYPTO_HASH_HELPERS], [
670 LB_CHECK_COMPILE([does crypto hash helper functions exist],
671 crypto_hash_helpers, [
672         #include <crypto/hash.h>
673 ],[
674         crypto_ahash_alg_name(NULL);
675         crypto_ahash_driver_name(NULL);
676 ],[
677         AC_DEFINE(HAVE_CRYPTO_HASH_HELPERS, 1,
678                 [crypto hash helper functions are available])
679 ])
680 ]) # LIBCFS_CRYPTO_HASH_HELPERS
681
682 #
683 # Kernel version 4.5-rc1 commit 3502cad73c4bbf8f6365d539e814159275252c59
684 # introduced rhashtable_replace_fast
685 #
686 AC_DEFUN([LIBCFS_RHASHTABLE_REPLACE], [
687 LB_CHECK_COMPILE([if 'rhashtable_replace_fast' exists],
688 rhashtable_replace_fast, [
689         #include <linux/rhashtable.h>
690 ],[
691         const struct rhashtable_params params = { 0 };
692
693         rhashtable_replace_fast(NULL, NULL, NULL, params);
694 ],[
695         AC_DEFINE(HAVE_RHASHTABLE_REPLACE, 1,
696                 [rhashtable_replace_fast() is available])
697 ])
698 ]) # LIBCFS_RHASHTABLE_REPLACE
699
700 #
701 # Kernel version 4.5-rc3 commit 2fe829aca9d7bed5fd6b49c6a1452e5e486b6cc3dd
702 # made kset_find_obj() exportable to modules
703 #
704 AC_DEFUN([LIBCFS_EXPORT_KSET_FIND_OBJ], [
705 LB_CHECK_EXPORT([kset_find_obj], [lib/kobject.c],
706         [AC_DEFINE(HAVE_KSET_FIND_OBJ, 1,
707                 [kset_find_obj is exported by the kernel])])
708 ]) # LIBCFS_EXPORT_KSET_FIND_OBJ
709
710 #
711 # Kernel version 4.6+ commit ef703f49a6c5b909a85149bb6625c4ed0d697186
712 # fixed the brokenness of hash_64(). The fix removed GOLDEN_RATIO_PRIME_64
713 # since it was a poor prime value.
714 #
715 AC_DEFUN([LIBCFS_BROKEN_HASH_64], [
716 LB_CHECK_COMPILE([kernel has fixed hash_64()],
717 broken_hash_64, [
718         #include <linux/hash.h>
719 ],[
720         int tmp = GOLDEN_RATIO_PRIME_64;
721 ],[
722         AC_DEFINE(HAVE_BROKEN_HASH_64, 1, [kernel hash_64() is broken])
723 ])
724 ]) # LIBCFS_BROKEN_HASH_64
725
726 #
727 # LIBCFS_STACKTRACE_OPS_ADDRESS_RETURN_INT
728 #
729 # linux 4.6 kernel changed stacktrace_ops address to return an int
730 #
731 AC_DEFUN([LIBCFS_STACKTRACE_OPS_ADDRESS_RETURN_INT], [
732 LB_CHECK_COMPILE([if 'struct stacktrace_ops' address function returns an int],
733 stacktrace_ops_address_return_int, [
734         #include <asm/stacktrace.h>
735 ],[
736         int rc;
737
738         rc = ((struct stacktrace_ops *)0)->address(NULL, 0, 0);
739 ],[
740         AC_DEFINE(STACKTRACE_OPS_ADDRESS_RETURN_INT, 1,
741                 ['struct stacktrace_ops' address function returns an int])
742 ])
743 ]) # LIBCFS_STACKTRACE_OPS_ADDRESS_RETURN_INT
744
745 #
746 # Kernel version 4.6 removed both struct task_struct and struct mm_struct
747 # arguments to get_user_pages
748 #
749 AC_DEFUN([LIBCFS_GET_USER_PAGES_6ARG], [
750 LB_CHECK_COMPILE([if 'get_user_pages()' takes 6 arguments],
751 get_user_pages_6arg, [
752         #include <linux/mm.h>
753 ],[
754         int rc;
755
756         rc = get_user_pages(0, 0, 0, 0, NULL, NULL);
757 ],[
758         AC_DEFINE(HAVE_GET_USER_PAGES_6ARG, 1,
759                 [get_user_pages takes 6 arguments])
760 ])
761 ]) # LIBCFS_GET_USER_PAGES_6ARG
762
763 #
764 # LIBCFS_STRINGHASH
765 #
766 # 4.6 kernel created stringhash.h which moved stuff out of dcache.h
767 # commit f4bcbe792b8f434e32487cff9d9e30ab45a3ce02
768 #
769 AC_DEFUN([LIBCFS_STRINGHASH], [
770 LB_CHECK_LINUX_HEADER([linux/stringhash.h], [
771         AC_DEFINE(HAVE_STRINGHASH, 1,
772                 [stringhash.h is present])])
773 ]) # LIBCFS_STRINGHASH
774
775 #
776 # LIBCFS_RHASHTABLE_INSERT_FAST
777 #
778 # 4.7+ kernel commit 5ca8cc5bf11faed257c762018aea9106d529232f
779 # changed __rhashtable_insert_fast to support the new function
780 # rhashtable_lookup_get_insert_key().
781 #
782 AC_DEFUN([LIBCFS_RHASHTABLE_INSERT_FAST], [
783 tmp_flags="$EXTRA_KCFLAGS"
784 EXTRA_KCFLAGS="-Werror"
785 LB_CHECK_COMPILE([if internal '__rhashtable_insert_fast()' returns int],
786 rhashtable_insert_fast, [
787         #include <linux/rhashtable.h>
788 ],[
789         const struct rhashtable_params params = { 0 };
790         int rc;
791
792         rc = __rhashtable_insert_fast(NULL, NULL, NULL, params);
793 ],[
794         AC_DEFINE(HAVE_HASHTABLE_INSERT_FAST_RETURN_INT, 1,
795                   ['__rhashtable_insert_fast()' returns int])
796 ])
797 EXTRA_KCFLAGS="$tmp_flags"
798 ]) # LIBCFS_RHASHTABLE_INSERT_FAST
799
800 #
801 # Kernel version 4.7-rc1 commit 8f6fd83c6c5ec66a4a70c728535ddcdfef4f3697
802 # added 3rd arg to rhashtable_walk_init
803 #
804 AC_DEFUN([LIBCFS_RHASHTABLE_WALK_INIT_3ARG], [
805 LB_CHECK_COMPILE([if 'rhashtable_walk_init' has 3 args],
806 rhashtable_walk_init, [
807         #include <linux/gfp.h>
808         #include <linux/rhashtable.h>
809 ],[
810         rhashtable_walk_init(NULL, NULL, GFP_KERNEL);
811 ],[
812         AC_DEFINE(HAVE_3ARG_RHASHTABLE_WALK_INIT, 1,
813                 [rhashtable_walk_init() has 3 args])
814 ])
815 ]) # LIBCFS_RHASHTABLE_REPLACE
816
817 #
818 # Kernel version 4.8-rc6 commit ca26893f05e86497a86732768ec53cd38c0819ca
819 # introduced rhashtable_lookup
820 #
821 AC_DEFUN([LIBCFS_RHASHTABLE_LOOKUP], [
822 LB_CHECK_COMPILE([if 'rhashtable_lookup' exist],
823 rhashtable_lookup, [
824         #include <linux/rhashtable.h>
825 ],[
826         const struct rhashtable_params params = { 0 };
827         void *ret;
828
829         ret = rhashtable_lookup(NULL, NULL, params);
830 ],[
831         AC_DEFINE(HAVE_RHASHTABLE_LOOKUP, 1,
832                 [rhashtable_lookup() is available])
833 ])
834 ]) # LIBCFS_RHASHTABLE_LOOKUP
835
836 #
837 # LIBCFS_RHLTABLE
838 # Kernel version 4.8-rc6 commit ca26893f05e86497a86732768ec53cd38c0819ca
839 # created the rhlist interface to allow inserting duplicate objects
840 # into the same table.
841 #
842 AC_DEFUN([LIBCFS_RHLTABLE], [
843 LB_CHECK_COMPILE([does 'struct rhltable' exist],
844 rhtable, [
845         #include <linux/rhashtable.h>
846 ],[
847         struct rhltable *hlt;
848
849         rhltable_destroy(hlt);
850 ],[
851         AC_DEFINE(HAVE_RHLTABLE, 1,
852                   [struct rhltable exist])
853 ])
854 ]) # LIBCFS_RHLTABLE
855
856 #
857 # LIBCFS_STACKTRACE_OPS
858 #
859 # Kernel version 4.8 commit c8fe4609827aedc9c4b45de80e7cdc8ccfa8541b
860 # removed both struct stacktrace_ops and dump_trace() function
861 #
862 AC_DEFUN([LIBCFS_STACKTRACE_OPS], [
863 LB_CHECK_COMPILE([if 'struct stacktrace_ops' exists],
864 stacktrace_ops, [
865         struct task_struct;
866         struct pt_regs;
867         #include <asm/stacktrace.h>
868 ],[
869         struct stacktrace_ops ops;
870         ops.stack = NULL;
871 ],[
872         AC_DEFINE(HAVE_STACKTRACE_OPS, 1,
873                 [struct stacktrace_ops exists])
874 ])
875 ]) # LIBCFS_STACKTRACE_OPS
876
877 #
878 # Kernel version 4.9-rc1 commit 246779dd090bd1b74d2652b3a6ca7759f593b27a
879 # introduced rhashtable_walk_enter
880 #
881 AC_DEFUN([LIBCFS_RHASHTABLE_WALK_ENTER], [
882 LB_CHECK_COMPILE([if 'rhashtable_walk_enter' exists],
883 rhashtable_walk_enter, [
884         #include <linux/rhashtable.h>
885 ],[
886         rhashtable_walk_enter(NULL, NULL);
887 ],[
888         AC_DEFINE(HAVE_RHASHTABLE_WALK_ENTER, 1,
889                 [rhashtable_walk_enter() is available])
890 ])
891 ]) # LIBCFS_RHASHTABLE_REPLACE
892
893 #
894 # Kernel version 4.9 commit 768ae309a96103ed02eb1e111e838c87854d8b51
895 # mm: replace get_user_pages() write/force parameters with gup_flags
896 #
897 AC_DEFUN([LIBCFS_GET_USER_PAGES_GUP_FLAGS], [
898 LB_CHECK_COMPILE([if 'get_user_pages()' takes gup_flags in arguments],
899 get_user_pages_gup_flags, [
900         #include <linux/mm.h>
901 ],[
902         int rc;
903         rc = get_user_pages(0, 0, FOLL_WRITE, NULL, NULL);
904 ],[
905         AC_DEFINE(HAVE_GET_USER_PAGES_GUP_FLAGS, 1,
906                 [get_user_pages takes gup_flags in arguments])
907 ])
908 ]) # LIBCFS_GET_USER_PAGES_GUP_FLAGS
909
910 #
911 # Kernel version 4.10 commit 7b737965b33188bd3dbb44e938535c4006d97fbb
912 # libcfs: Convert to hotplug state machine
913 #
914 AC_DEFUN([LIBCFS_HOTPLUG_STATE_MACHINE], [
915 LB_CHECK_COMPILE([if libcfs supports CPU hotplug state machine],
916 cpu_hotplug_state_machine, [
917         #include <linux/cpuhotplug.h>
918 ],[
919         cpuhp_remove_state(CPUHP_LUSTRE_CFS_DEAD);
920 ],[
921         AC_DEFINE(HAVE_HOTPLUG_STATE_MACHINE, 1,
922                 [hotplug state machine is supported])
923 ])
924 ]) # LIBCFS_HOTPLUG_STATE_MACHINE
925
926 #
927 # LIBCFS_SCHED_HEADERS
928 #
929 # 4.11 has broken up sched.h into more headers.
930 #
931 AC_DEFUN([LIBCFS_SCHED_HEADERS], [
932 LB_CHECK_LINUX_HEADER([linux/sched/signal.h], [
933         AC_DEFINE(HAVE_SCHED_HEADERS, 1,
934                 [linux/sched header directory exist])])
935 ]) # LIBCFS_SCHED_HEADERS
936
937 #
938 # Kernel version 4.11-rc1 commit da20420f83ea0fbcf3d03afda08d971ea1d8a356
939 # introduced rht_bucket_var
940 #
941 AC_DEFUN([LIBCFS_RHT_BUCKET_VAR], [
942 LB_CHECK_COMPILE([if 'rht_bucket_var' exists],
943 rht_bucket_var, [
944         #include <linux/rhashtable.h>
945 ],[
946
947         rht_bucket_var(NULL, 0);
948 ],[
949         AC_DEFINE(HAVE_RHT_BUCKET_VAR, 1,
950                 [rht_bucket_var() is available])
951 ])
952 ]) # LIBCFS_RHT_BUCKET_VAR
953
954 #
955 # Kernel version 4.11 commit f9fe1c12d126f9887441fa5bb165046f30ddd4b5
956 # introduced rhashtable_lookup_get_insert_fast
957 #
958 AC_DEFUN([LIBCFS_RHASHTABLE_LOOKUP_GET_INSERT_FAST], [
959 LB_CHECK_COMPILE([if 'rhashtable_lookup_get_insert_fast' exist],
960 rhashtable_lookup_get_insert_fast, [
961         #include <linux/rhashtable.h>
962 ],[
963         const struct rhashtable_params params = { 0 };
964         void *ret;
965
966         ret = rhashtable_lookup_get_insert_fast(NULL, NULL, params);
967 ],[
968         AC_DEFINE(HAVE_RHASHTABLE_LOOKUP_GET_INSERT_FAST, 1,
969                 [rhashtable_lookup_get_insert_fast() is available])
970 ])
971 ]) # LIBCFS_RHASHTABLE_LOOKUP_GET_INSERT_FAST
972
973 #
974 # Kernel version 4.12-rc3 f9727a17db9bab71ddae91f74f11a8a2f9a0ece6
975 # renamed uuid_be to uuid_t
976 #
977 AC_DEFUN([LIBCFS_UUID_T], [
978 LB_CHECK_COMPILE([if 'uuid_t' exist],
979 uuid_t, [
980         #include <linux/uuid.h>
981 ],[
982         uuid_t uuid;
983
984         memset(uuid.b, 0, 16);
985 ],[
986         AC_DEFINE(HAVE_UUID_T, 1, ['uuid_t' exist])
987 ])
988 ]) # LIBCFS_UUID_T
989
990 #
991 # Kernel version 4.12-rc3 commit fd851a3cdc196bfc1d229b5f22369069af532bf8
992 # introduce processor.h
993 #
994 AC_DEFUN([LIBCFS_HAVE_PROCESSOR_HEADER], [
995 LB_CHECK_LINUX_HEADER([linux/processor.h], [
996         AC_DEFINE(HAVE_PROCESSOR_H, 1,
997                 [processor.h is present])])
998 ]) # LIBCFS_HAVE_PROCESSOR_HEADER
999
1000 #
1001 # Kernel verison 4.12-rc6 commit 5dd43ce2f69d42a71dcacdb13d17d8c0ac1fe8f7
1002 # created wait_bit.h
1003 #
1004 AC_DEFUN([LIBCFS_HAVE_WAIT_BIT_HEADER], [
1005 LB_CHECK_LINUX_HEADER([linux/wait_bit.h], [
1006         AC_DEFINE(HAVE_WAIT_BIT_HEADER_H, 1,
1007                 [wait_bit.h is present])])
1008 ]) # LIBCFS_HAVE_WAIT_BIT_HEADER
1009
1010 #
1011 # Kernel version 4.12-rc6 commmit 2055da97389a605c8a00d163d40903afbe413921
1012 # changed:
1013 #       struct wait_queue_head::task_list       => ::head
1014 #       struct wait_queue_entry::task_list      => ::entry
1015 #
1016 AC_DEFUN([LIBCFS_WAIT_QUEUE_TASK_LIST_RENAME], [
1017 LB_CHECK_COMPILE([if linux wait_queue_head list_head is named head],
1018 wait_queue_task_list, [
1019         #include <linux/wait.h>
1020 ],[
1021         wait_queue_head_t e;
1022
1023         INIT_LIST_HEAD(&e.head);
1024 ],[
1025         AC_DEFINE(HAVE_WAIT_QUEUE_ENTRY_LIST, 1,
1026                 [linux wait_queue_head_t list_head is name head])
1027 ])
1028 ]) # LIBCFS_WAIT_QUEUE_TASK_LIST_RENAME
1029
1030 #
1031 # LIBCFS_WAIT_QUEUE_ENTRY
1032 #
1033 # Kernel version 4.13 ac6424b981bce1c4bc55675c6ce11bfe1bbfa64f
1034 # Rename wait_queue_t => wait_queue_entry_t
1035 #
1036 AC_DEFUN([LIBCFS_WAIT_QUEUE_ENTRY], [
1037 LB_CHECK_COMPILE([if 'wait_queue_entry_t' exists],
1038 wait_queue_entry, [
1039         #include <linux/wait.h>
1040 ],[
1041         wait_queue_entry_t e;
1042
1043         e.flags = 0;
1044 ],[
1045         AC_DEFINE(HAVE_WAIT_QUEUE_ENTRY, 1,
1046                 ['wait_queue_entry_t' is available])
1047 ])
1048 ]) # LIBCFS_WAIT_QUEUE_ENTRY
1049
1050 #
1051 # LIBCFS_NEW_KERNEL_WRITE
1052 #
1053 # Kernel version 4.14 e13ec939e96b13e664bb6cee361cc976a0ee621a
1054 # changed kernel_write prototype to make is plug compatible
1055 # with the unexported vfs_write()
1056 #
1057 AC_DEFUN([LIBCFS_NEW_KERNEL_WRITE], [
1058 tmp_flags="$EXTRA_KCFLAGS"
1059 EXTRA_KCFLAGS="-Werror"
1060 LB_CHECK_COMPILE([if 'kernel_write' matches other read/write helpers],
1061 kernel_write_match, [
1062         #include <linux/fs.h>
1063 ],[
1064         const void *buf = NULL;
1065         loff_t pos = 0;
1066         return kernel_write(NULL, buf, 0, &pos);
1067 ],[
1068         AC_DEFINE(HAVE_NEW_KERNEL_WRITE, 1,
1069                 ['kernel_write' aligns with read/write helpers])
1070 ])
1071 EXTRA_KCFLAGS="$tmp_flags"
1072 ]) # LIBCFS_NEW_KERNEL_WRITE
1073
1074 #
1075 # LIBCFS_MM_TOTALRAM_PAGES_FUNC
1076 #
1077 # kernel 5.0 commit ca79b0c211af63fa3276f0e3fd7dd9ada2439839
1078 # mm: convert totalram_pages and totalhigh_pages variables to atomic
1079 #
1080 AC_DEFUN([LIBCFS_MM_TOTALRAM_PAGES_FUNC], [
1081 tmp_flags="$EXTRA_KCFLAGS"
1082 EXTRA_KCFLAGS="-Werror"
1083 LB_CHECK_COMPILE([if totalram_pages is a function],
1084 totalram_pages, [
1085         #include <linux/mm.h>
1086 ],[
1087         totalram_pages_inc();
1088 ],[
1089         AC_DEFINE(HAVE_TOTALRAM_PAGES_AS_FUNC, 1,
1090                 [if totalram_pages is a function])
1091 ])
1092 EXTRA_KCFLAGS="$tmp_flags"
1093 ]) # LIBCFS_MM_TOTALRAM_PAGES_FUNC
1094
1095 #
1096 # LIBCFS_NEW_KERNEL_WRITE
1097 #
1098 # 4.14 commit bdd1d2d3d251c65b74ac4493e08db18971c09240 changed
1099 # the signature of kernel_read to match other read/write helpers
1100 # and place offset last.
1101 #
1102 AC_DEFUN([LIBCFS_NEW_KERNEL_READ], [
1103 tmp_flags="$EXTRA_KCFLAGS"
1104 EXTRA_KCFLAGS="-Werror"
1105 LB_CHECK_COMPILE([if 'kernel_read()' has loff_t *pos as last parameter],
1106 kernel_read, [
1107         #include <linux/fs.h>
1108         ],[
1109         loff_t pos = 0;
1110         kernel_read(NULL, NULL, 0, &pos);
1111 ],[
1112         AC_DEFINE(HAVE_KERNEL_READ_LAST_POSP, 1,
1113                 [kernel_read() signature ends with loff_t *pos])
1114 ])
1115 EXTRA_KCFLAGS="$tmp_flags"
1116 ]) # LIBCFS_NEW_KERNEL_READ
1117
1118 #
1119 # LIBCFS_DEFINE_TIMER
1120 #
1121 # Kernel version 4.14 commit 1d27e3e2252ba9d949ca82fbdb73cde102cb2067
1122 # remove expires and data arguments from DEFINE_TIMER. Also the callback
1123 # when from using unsigned long argument to using struct timer_list pointer.
1124 #
1125 AC_DEFUN([LIBCFS_DEFINE_TIMER], [
1126 LB_CHECK_COMPILE([if DEFINE_TIMER takes only 2 arguments],
1127 define_timer, [
1128         #include <linux/timer.h>
1129 ],[
1130         static DEFINE_TIMER(my_timer, NULL);
1131 ],[
1132         AC_DEFINE(HAVE_NEW_DEFINE_TIMER, 1,
1133                 [DEFINE_TIMER uses only 2 arguements])
1134 ])
1135 ]) # LIBCFS_DEFINE_TIMER
1136
1137 #
1138 # LIBCFS_EXPORT_SAVE_STACK_TRACE_TSK
1139 #
1140 # Kernel 2.6.27 commit 8594698ebddeef5443b7da8258ae33b3eaca61d5
1141 # exported save_stack_trace_tsk for x86.
1142 # Kernel 2.6.27 commit 01f4b8b8b8db09b88be7df7e51192e4e678b69d3
1143 # exported save_stack_trace_tsk for powerpc
1144 # Kernel 4.13 commit e27c7fa015d61c8be6a2c32b2144aad2ae6ec975
1145 # exported save_stack_trace_tsk for arm64
1146 # Kernel 4.14 commit 9a3dc3186fc3795e076a4122da9e0258651a9631
1147 # exported save_stack_trace_tsk for arm
1148 #
1149 AC_DEFUN([LIBCFS_EXPORT_SAVE_STACK_TRACE_TSK], [
1150 LB_CHECK_EXPORT([save_stack_trace_tsk], [arch/$SUBARCH/kernel/stacktrace.c],
1151         [AC_DEFINE(HAVE_SAVE_STACK_TRACE_TSK, 1,
1152                 [save_stack_trace_tsk is exported])])
1153 ]) # LIBCFS_EXPORT_SAVE_STACK_TRACE_TSK
1154
1155 #
1156 # LIBCFS_TIMER_SETUP
1157 #
1158 # Kernel version 4.15 commit e99e88a9d2b067465adaa9c111ada99a041bef9a
1159 # setup_timer() was replaced by timer_setup(), where the callback
1160 # argument is the structure already holding the struct timer_list.
1161 #
1162 AC_DEFUN([LIBCFS_TIMER_SETUP], [
1163 LB_CHECK_COMPILE([if setup_timer has been replaced with timer_setup],
1164 timer_setup, [
1165         #include <linux/timer.h>
1166 ],[
1167         timer_setup(NULL, NULL, 0);
1168 ],[
1169         AC_DEFINE(HAVE_TIMER_SETUP, 1,
1170                 [timer_setup has replaced setup_timer])
1171 ])
1172 ]) # LIBCFS_TIMER_SETUP
1173
1174 #
1175 # LIBCFS_WAIT_VAR_EVENT
1176 #
1177 # Kernel version 4.16-rc4 commit 6b2bb7265f0b62605e8caee3613449ed0db270b9
1178 # added wait_var_event()
1179 #
1180 AC_DEFUN([LIBCFS_WAIT_VAR_EVENT], [
1181 LB_CHECK_COMPILE([if 'wait_var_event' exist],
1182 wait_var_event, [
1183         #ifdef HAVE_WAIT_BIT_HEADER_H
1184         #include <linux/wait_bit.h>
1185         #endif
1186         #include <linux/wait.h>
1187 ],[
1188         wake_up_var(NULL);
1189 ],[
1190         AC_DEFINE(HAVE_WAIT_VAR_EVENT, 1,
1191                 ['wait_var_event' is available])
1192 ])
1193 ]) # LIBCFS_WAIT_VAR_EVENT
1194
1195 #
1196 # LIBCFS_CLEAR_AND_WAKE_UP_BIT
1197 #
1198 # Kernel version 4.17-rc2 commit 8236b0ae31c837d2b3a2565c5f8d77f637e824cc
1199 # added clear_and_wake_up_bit()
1200 #
1201 AC_DEFUN([LIBCFS_CLEAR_AND_WAKE_UP_BIT], [
1202 LB_CHECK_COMPILE([if 'clear_and_wake_up_bit' exist],
1203 clear_and_wake_up_bit, [
1204         #ifdef HAVE_WAIT_BIT_HEADER_H
1205         #include <linux/wait_bit.h>
1206         #endif
1207         #include <linux/wait.h>
1208 ],[
1209         clear_and_wake_up_bit(0, NULL);
1210 ],[
1211         AC_DEFINE(HAVE_CLEAR_AND_WAKE_UP_BIT, 1,
1212                 ['clear_and_wake_up_bit' is available])
1213 ])
1214 ]) # LIBCFS_CLEAR_AND_WAKE_UP_BIT
1215
1216 #
1217 # LIBCFS_PROG_LINUX
1218 #
1219 # LibCFS linux kernel checks
1220 #
1221 AC_DEFUN([LIBCFS_PROG_LINUX], [
1222 AC_MSG_NOTICE([LibCFS kernel checks
1223 ==============================================================================])
1224 LIBCFS_CONFIG_PANIC_DUMPLOG
1225
1226 # 2.6.32
1227 LIBCFS_STACKTRACE_OPS_HAVE_WALK_STACK
1228 LC_SHRINKER_WANT_SHRINK_PTR
1229 # 2.6.33
1230 LIBCFS_SYSCTL_CTLNAME
1231 # 2.6.36
1232 LIBCFS_MODULE_LOCKING
1233 # 2.6.38
1234 LIBCFS_KSTRTOUL
1235 # 2.6.39
1236 LIBCFS_DUMP_TRACE_ADDRESS
1237 # 2.6.40 fc15
1238 LC_SHRINK_CONTROL
1239 # 3.0
1240 LIBCFS_STACKTRACE_WARNING
1241 # 3.5
1242 LIBCFS_PROCESS_NAMESPACE
1243 LIBCFS_I_UID_READ
1244 # 3.8
1245 LIBCFS_HAVE_CRC32
1246 LIBCFS_ENABLE_CRC32_ACCEL
1247 # 3.10
1248 LIBCFS_ENABLE_CRC32C_ACCEL
1249 # 3.11
1250 LIBCFS_KTIME_GET_TS64
1251 # 3.12
1252 LIBCFS_PREPARE_TO_WAIT_EVENT
1253 LIBCFS_KERNEL_PARAM_OPS
1254 LIBCFS_KTIME_ADD
1255 LIBCFS_KTIME_AFTER
1256 LIBCFS_KTIME_BEFORE
1257 LIBCFS_KTIME_COMPARE
1258 LIBCFS_SHRINKER_COUNT
1259 # 3.17
1260 LIBCFS_HLIST_ADD_AFTER
1261 LIBCFS_TIMESPEC64
1262 LIBCFS_KTIME_GET_NS
1263 LIBCFS_KTIME_GET_REAL_TS64
1264 LIBCFS_KTIME_GET_REAL_SECONDS
1265 LIBCFS_KTIME_GET_REAL_NS
1266 LIBCFS_KTIME_TO_TIMESPEC64
1267 LIBCFS_TIMESPEC64_SUB
1268 LIBCFS_TIMESPEC64_TO_KTIME
1269 # 3.19
1270 LIBCFS_KTIME_GET_SECONDS
1271 # 4.0
1272 LIBCFS_KTIME_MS_DELTA
1273 # 4.1
1274 LIBCFS_KERNEL_PARAM_LOCK
1275 # 4.2
1276 LIBCFS_HAVE_TOPOLOGY_SIBLING_CPUMASK
1277 LIBCFS_FPU_API
1278 # 4.4
1279 LIBCFS_KSTRTOBOOL_FROM_USER
1280 # 4.5
1281 LIBCFS_CRYPTO_HASH_HELPERS
1282 LIBCFS_EXPORT_KSET_FIND_OBJ
1283 LIBCFS_RHASHTABLE_REPLACE
1284 # 4.6
1285 LIBCFS_BROKEN_HASH_64
1286 LIBCFS_STACKTRACE_OPS_ADDRESS_RETURN_INT
1287 LIBCFS_GET_USER_PAGES_6ARG
1288 LIBCFS_STRINGHASH
1289 # 4.7
1290 LIBCFS_RHASHTABLE_INSERT_FAST
1291 LIBCFS_RHASHTABLE_WALK_INIT_3ARG
1292 # 4.8
1293 LIBCFS_RHASHTABLE_LOOKUP
1294 LIBCFS_RHLTABLE
1295 LIBCFS_STACKTRACE_OPS
1296 # 4.9
1297 LIBCFS_GET_USER_PAGES_GUP_FLAGS
1298 LIBCFS_RHASHTABLE_WALK_ENTER
1299 # 4.10
1300 LIBCFS_HOTPLUG_STATE_MACHINE
1301 # 4.11
1302 LIBCFS_RHASHTABLE_LOOKUP_GET_INSERT_FAST
1303 LIBCFS_SCHED_HEADERS
1304 LIBCFS_RHT_BUCKET_VAR
1305 # 4.12
1306 LIBCFS_HAVE_PROCESSOR_HEADER
1307 LIBCFS_HAVE_WAIT_BIT_HEADER
1308 LIBCFS_WAIT_QUEUE_TASK_LIST_RENAME
1309 LIBCFS_UUID_T
1310 # 4.13
1311 LIBCFS_WAIT_QUEUE_ENTRY
1312 # 4.14
1313 LIBCFS_DEFINE_TIMER
1314 LIBCFS_NEW_KERNEL_WRITE
1315 LIBCFS_NEW_KERNEL_READ
1316 LIBCFS_EXPORT_SAVE_STACK_TRACE_TSK
1317 # 4.15
1318 LIBCFS_TIMER_SETUP
1319 # 4.16
1320 LIBCFS_WAIT_VAR_EVENT
1321 # 4.17
1322 LIBCFS_CLEAR_AND_WAKE_UP_BIT
1323 # 5.0
1324 LIBCFS_MM_TOTALRAM_PAGES_FUNC
1325 ]) # LIBCFS_PROG_LINUX
1326
1327 #
1328 # LIBCFS_PATH_DEFAULTS
1329 #
1330 # default paths for installed files
1331 #
1332 AC_DEFUN([LIBCFS_PATH_DEFAULTS], [
1333 ]) # LIBCFS_PATH_DEFAULTS
1334
1335 #
1336 # LIBCFS_CONFIGURE
1337 #
1338 # other configure checks
1339 #
1340 AC_DEFUN([LIBCFS_CONFIGURE], [
1341 AC_MSG_NOTICE([LibCFS core checks
1342 ==============================================================================])
1343
1344 # libcfs/libcfs/util/nidstrings.c
1345 AC_CHECK_HEADERS([netdb.h asm/types.h endian.h])
1346 AC_CHECK_FUNCS([gethostbyname])
1347
1348 # --------  Check for required packages  --------------
1349
1350 AC_MSG_NOTICE([LibCFS required packages checks
1351 ==============================================================================])
1352
1353 AC_MSG_CHECKING([whether to enable readline support])
1354 AC_ARG_ENABLE(readline,
1355         AC_HELP_STRING([--disable-readline],
1356                 [disable readline support]),
1357         [], [enable_readline="yes"])
1358 AC_MSG_RESULT([$enable_readline])
1359
1360 LIBREADLINE=""
1361 AS_IF([test "x$enable_readline" = xyes], [
1362         AC_CHECK_LIB([readline], [readline], [
1363                 LIBREADLINE="-lreadline"
1364                 AC_DEFINE(HAVE_LIBREADLINE, 1,
1365                         [readline library is available])
1366         ])
1367 ])
1368 AC_SUBST(LIBREADLINE)
1369
1370 AC_MSG_CHECKING([whether to use libpthread for libcfs library])
1371 AC_ARG_ENABLE([libpthread],
1372         AC_HELP_STRING([--disable-libpthread],
1373                 [disable libpthread]),
1374         [], [enable_libpthread="yes"])
1375 AC_MSG_RESULT([$enable_libpthread])
1376
1377 PTHREAD_LIBS=""
1378 AS_IF([test "x$enable_libpthread" = xyes], [
1379         AC_CHECK_LIB([pthread], [pthread_create], [
1380                 PTHREAD_LIBS="-lpthread"
1381                 AC_DEFINE([HAVE_LIBPTHREAD], 1,
1382                         [use libpthread for libcfs library])
1383         ])
1384 ], [
1385         AC_MSG_WARN([Using libpthread for libcfs library is disabled explicitly])
1386 ])
1387 AC_SUBST(PTHREAD_LIBS)
1388 ]) # LIBCFS_CONFIGURE
1389
1390 #
1391 # LIBCFS_CONDITIONALS
1392 #
1393 AC_DEFUN([LIBCFS_CONDITIONALS], [
1394 AM_CONDITIONAL(HAVE_CRC32, [test "x$have_crc32" = xyes])
1395 AM_CONDITIONAL(NEED_PCLMULQDQ_CRC32,  [test "x$have_crc32" = xyes -a "x$enable_crc32_crypto" = xyes])
1396 AM_CONDITIONAL(NEED_PCLMULQDQ_CRC32C, [test "x$enable_crc32c_crypto" = xyes])
1397 ]) # LIBCFS_CONDITIONALS
1398
1399 #
1400 # LIBCFS_CONFIG_FILES
1401 #
1402 # files that should be generated with AC_OUTPUT
1403 #
1404 AC_DEFUN([LIBCFS_CONFIG_FILES], [
1405 AC_CONFIG_FILES([
1406 libcfs/Makefile
1407 libcfs/autoMakefile
1408 libcfs/autoconf/Makefile
1409 libcfs/include/Makefile
1410 libcfs/include/libcfs/Makefile
1411 libcfs/include/libcfs/linux/Makefile
1412 libcfs/include/libcfs/util/Makefile
1413 libcfs/libcfs/Makefile
1414 libcfs/libcfs/autoMakefile
1415 libcfs/libcfs/linux/Makefile
1416 libcfs/libcfs/util/Makefile
1417 ])
1418 ]) # LIBCFS_CONFIG_FILES