libcfs/autoconf/lustre-libcfs.m4

   1 #
   2 # LIBCFS_CONFIG_CDEBUG
   3 #
   4 # whether to enable various libcfs debugs (CDEBUG, ENTRY/EXIT, LASSERT, etc.)
   5 #
   6 AC_DEFUN([LIBCFS_CONFIG_CDEBUG], [
   7 AC_MSG_CHECKING([whether to enable CDEBUG, CWARN])
   8 AC_ARG_ENABLE([libcfs_cdebug],
   9         AC_HELP_STRING([--disable-libcfs-cdebug],
  10                 [disable libcfs CDEBUG, CWARN]),
  11         [], [enable_libcfs_cdebug="yes"])
  12 AC_MSG_RESULT([$enable_libcfs_cdebug])
  13 AS_IF([test "x$enable_libcfs_cdebug" = xyes],
  14         [AC_DEFINE(CDEBUG_ENABLED, 1, [enable libcfs CDEBUG, CWARN])])
  15
  16 AC_MSG_CHECKING([whether to enable ENTRY/EXIT])
  17 AC_ARG_ENABLE([libcfs_trace],
  18         AC_HELP_STRING([--disable-libcfs-trace],
  19                 [disable libcfs ENTRY/EXIT]),
  20         [], [enable_libcfs_trace="yes"])
  21 AC_MSG_RESULT([$enable_libcfs_trace])
  22 AS_IF([test "x$enable_libcfs_trace" = xyes],
  23         [AC_DEFINE(CDEBUG_ENTRY_EXIT, 1, [enable libcfs ENTRY/EXIT])])
  24
  25 AC_MSG_CHECKING([whether to enable LASSERT, LASSERTF])
  26 AC_ARG_ENABLE([libcfs_assert],
  27         AC_HELP_STRING([--disable-libcfs-assert],
  28                 [disable libcfs LASSERT, LASSERTF]),
  29         [], [enable_libcfs_assert="yes"])
  30 AC_MSG_RESULT([$enable_libcfs_assert])
  31 AS_IF([test x$enable_libcfs_assert = xyes],
  32         [AC_DEFINE(LIBCFS_DEBUG, 1, [enable libcfs LASSERT, LASSERTF])])
  33 ]) # LIBCFS_CONFIG_CDEBUG
  34
  35 #
  36 # LIBCFS_CONFIG_PANIC_DUMPLOG
  37 #
  38 # check if tunable panic_dumplog is wanted
  39 #
  40 AC_DEFUN([LIBCFS_CONFIG_PANIC_DUMPLOG], [
  41 AC_MSG_CHECKING([whether to use tunable 'panic_dumplog' support])
  42 AC_ARG_ENABLE([panic_dumplog],
  43         AC_HELP_STRING([--enable-panic_dumplog],
  44                 [enable panic_dumplog]),
  45         [], [enable_panic_dumplog="no"])
  46 AC_MSG_RESULT([$enable_panic_dumplog])
  47 AS_IF([test "x$enable_panic_dumplog" = xyes],
  48         [AC_DEFINE(LNET_DUMP_ON_PANIC, 1, [use dumplog on panic])])
  49 ]) # LIBCFS_CONFIG_PANIC_DUMPLOG
  50
  51 #
  52 # LIBCFS_STACKTRACE_OPS_HAVE_WALK_STACK
  53 #
  54 # 2.6.32-30.el6 adds a new 'walk_stack' field in 'struct stacktrace_ops'
  55 #
  56 AC_DEFUN([LIBCFS_STACKTRACE_OPS_HAVE_WALK_STACK], [
  57 LB_CHECK_COMPILE([if 'struct stacktrace_ops' has 'walk_stack' field],
  58 stacktrace_ops_walk_stack, [
  59         #include <asm/stacktrace.h>
  60 ],[
  61         ((struct stacktrace_ops *)0)->walk_stack(NULL, NULL, 0, NULL, NULL, NULL, NULL);
  62 ],[
  63         AC_DEFINE(STACKTRACE_OPS_HAVE_WALK_STACK, 1,
  64                 ['struct stacktrace_ops' has 'walk_stack' field])
  65 ])
  66 ]) # LIBCFS_STACKTRACE_OPS_HAVE_WALK_STACK
  67
  68 #
  69 # LIBCFS_STACKTRACE_WARNING
  70 #
  71 # 3.0 removes stacktrace_ops warning* functions
  72 #
  73 AC_DEFUN([LIBCFS_STACKTRACE_WARNING], [
  74 LB_CHECK_COMPILE([if 'stacktrace_ops.warning' is exist],
  75 stacktrace_ops_warning, [
  76         struct task_struct;
  77         struct pt_regs;
  78         #include <asm/stacktrace.h>
  79 ],[
  80         ((struct stacktrace_ops *)0)->warning(NULL, NULL);
  81 ],[
  82         AC_DEFINE(HAVE_STACKTRACE_WARNING, 1,
  83                 [stacktrace_ops.warning is exist])
  84 ])
  85 ]) # LIBCFS_STACKTRACE_WARNING
  86
  87 #
  88 # LC_SHRINKER_WANT_SHRINK_PTR
  89 #
  90 # RHEL6/2.6.32 want to have pointer to shrinker self pointer in handler function
  91 #
  92 AC_DEFUN([LC_SHRINKER_WANT_SHRINK_PTR], [
  93 LB_CHECK_COMPILE([if 'shrinker' want self pointer in handler],
  94 shrink_self_pointer, [
  95         #include <linux/mm.h>
  96 ],[
  97         struct shrinker *tmp = NULL;
  98         tmp->shrink(tmp, 0, 0);
  99 ],[
 100         AC_DEFINE(HAVE_SHRINKER_WANT_SHRINK_PTR, 1,
 101                 [shrinker want self pointer in handler])
 102 ])
 103 ]) # LC_SHRINKER_WANT_SHRINK_PTR
 104
 105 #
 106 # LIBCFS_SYSCTL_CTLNAME
 107 #
 108 # 2.6.33 no longer has ctl_name & strategy field in struct ctl_table.
 109 #
 110 AC_DEFUN([LIBCFS_SYSCTL_CTLNAME], [
 111 LB_CHECK_COMPILE([if 'ctl_table' has a 'ctl_name' field],
 112 ctl_table_ctl_name, [
 113         #include <linux/sysctl.h>
 114 ],[
 115         struct ctl_table ct;
 116         ct.ctl_name = sizeof(ct);
 117 ],[
 118         AC_DEFINE(HAVE_SYSCTL_CTLNAME, 1,
 119                 [ctl_table has ctl_name field])
 120 ])
 121 ]) # LIBCFS_SYSCTL_CTLNAME
 122
 123 #
 124 # LIBCFS_KSTRTOUL
 125 #
 126 # 2.6.38 kstrtoul is added
 127 #
 128 AC_DEFUN([LIBCFS_KSTRTOUL], [
 129 LB_CHECK_COMPILE([if Linux kernel has 'kstrtoul'],
 130 kstrtoul, [
 131         #include <linux/kernel.h>
 132 ],[
 133         unsigned long result;
 134         return kstrtoul("12345", 0, &result);
 135 ],[
 136         AC_DEFINE(HAVE_KSTRTOUL, 1,
 137                 [kernel has kstrtoul])
 138 ])
 139 ]) # LIBCFS_KSTRTOUL
 140
 141 #
 142 # LIBCFS_DUMP_TRACE_ADDRESS
 143 #
 144 # 2.6.39 adds a base pointer address argument to dump_trace
 145 #
 146 AC_DEFUN([LIBCFS_DUMP_TRACE_ADDRESS], [
 147 LB_CHECK_COMPILE([if 'dump_trace' want address],
 148 dump_trace_address, [
 149         struct task_struct;
 150         struct pt_regs;
 151         #include <asm/stacktrace.h>
 152 ],[
 153         dump_trace(NULL, NULL, NULL, 0, NULL, NULL);
 154 ],[
 155         AC_DEFINE(HAVE_DUMP_TRACE_ADDRESS, 1,
 156                 [dump_trace want address argument])
 157 ])
 158 ]) # LIBCFS_DUMP_TRACE_ADDRESS
 159
 160 #
 161 # LC_SHRINK_CONTROL
 162 #
 163 # FC15 2.6.40-5 backported the "shrink_control" parameter to the memory
 164 # pressure shrinker from Linux 3.0
 165 #
 166 AC_DEFUN([LC_SHRINK_CONTROL], [
 167 LB_CHECK_COMPILE([if 'shrink_control' is present],
 168 shrink_control, [
 169         #include <linux/atomic.h>
 170         #include <linux/mm.h>
 171 ],[
 172         struct shrink_control tmp = {0};
 173         tmp.nr_to_scan = sizeof(tmp);
 174 ],[
 175         AC_DEFINE(HAVE_SHRINK_CONTROL, 1,
 176                 [shrink_control is present])
 177 ])
 178 ]) # LC_SHRINK_CONTROL
 179
 180 #
 181 # LIBCFS_PROCESS_NAMESPACE
 182 #
 183 # 3.5 introduced process namespace
 184 AC_DEFUN([LIBCFS_PROCESS_NAMESPACE], [
 185 LB_CHECK_LINUX_HEADER([linux/uidgid.h], [
 186         AC_DEFINE(HAVE_UIDGID_HEADER, 1,
 187                 [uidgid.h is present])])
 188 ]) # LIBCFS_PROCESS_NAMESPACE
 189
 190 #
 191 # LIBCFS_I_UID_READ
 192 #
 193 # 3.5 added helpers to read the new uid/gid types from VFS structures
 194 # SLE11 SP3 has uidgid.h but not the helpers
 195 #
 196 AC_DEFUN([LIBCFS_I_UID_READ], [
 197 LB_CHECK_COMPILE([if 'i_uid_read' is present],
 198 i_uid_read, [
 199         #include <linux/fs.h>
 200 ],[
 201         i_uid_read(NULL);
 202 ],[
 203         AC_DEFINE(HAVE_I_UID_READ, 1, [i_uid_read is present])
 204 ])
 205 ]) # LIBCFS_I_UID_READ
 206
 207 #
 208 # LIBCFS_SOCK_ALLOC_FILE
 209 #
 210 # FC18 3.7.2-201 unexport sock_map_fd() change to
 211 # use sock_alloc_file().
 212 # upstream commit 56b31d1c9f1e6a3ad92e7bfe252721e05d92b285
 213 #
 214 AC_DEFUN([LIBCFS_SOCK_ALLOC_FILE], [
 215 LB_CHECK_EXPORT([sock_alloc_file], [net/socket.c], [
 216         LB_CHECK_COMPILE([if 'sock_alloc_file' takes 3 arguments],
 217         sock_alloc_file_3args, [
 218                 #include <linux/net.h>
 219         ],[
 220                 sock_alloc_file(NULL, 0, NULL);
 221         ],[
 222                 AC_DEFINE(HAVE_SOCK_ALLOC_FILE_3ARGS, 1,
 223                         [sock_alloc_file takes 3 arguments])
 224         ],[
 225                 AC_DEFINE(HAVE_SOCK_ALLOC_FILE, 1,
 226                         [sock_alloc_file is exported])
 227         ])
 228 ])
 229 ]) # LIBCFS_SOCK_ALLOC_FILE
 230
 231 #
 232 # LIBCFS_HAVE_CRC32
 233 #
 234 AC_DEFUN([LIBCFS_HAVE_CRC32], [
 235 LB_CHECK_CONFIG_IM([CRC32],
 236         [have_crc32="yes"], [have_crc32="no"])
 237 AS_IF([test "x$have_crc32" = xyes],
 238         [AC_DEFINE(HAVE_CRC32, 1,
 239                 [kernel compiled with CRC32 functions])])
 240 ]) # LIBCFS_HAVE_CRC32
 241
 242 #
 243 # LIBCFS_ENABLE_CRC32_ACCEL
 244 #
 245 AC_DEFUN([LIBCFS_ENABLE_CRC32_ACCEL], [
 246 LB_CHECK_CONFIG_IM([CRYPTO_CRC32_PCLMUL],
 247         [enable_crc32_crypto="no"], [enable_crc32_crypto="yes"])
 248 AS_IF([test "x$have_crc32" = xyes -a "x$enable_crc32_crypto" = xyes], [
 249         AC_DEFINE(NEED_CRC32_ACCEL, 1, [need pclmulqdq based crc32])
 250         AC_MSG_WARN([No crc32 pclmulqdq crypto api found, enable internal pclmulqdq based crc32])])
 251 ]) # LIBCFS_ENABLE_CRC32_ACCEL
 252
 253 #
 254 # LIBCFS_ENABLE_CRC32C_ACCEL
 255 #
 256 AC_DEFUN([LIBCFS_ENABLE_CRC32C_ACCEL], [
 257 LB_CHECK_CONFIG_IM([CRYPTO_CRC32C_INTEL],
 258         [enable_crc32c_crypto="no"], [enable_crc32c_crypto="yes"])
 259 AS_IF([test "x$enable_crc32c_crypto" = xyes], [
 260         AC_DEFINE(NEED_CRC32C_ACCEL, 1, [need pclmulqdq based crc32c])
 261         AC_MSG_WARN([No crc32c pclmulqdq crypto api found, enable internal pclmulqdq based crc32c])])
 262 ]) # LIBCFS_ENABLE_CRC32C_ACCEL
 263
 264 #
 265 # Kernel version 3.11 introduced ktime_get_ts64
 266 #
 267 AC_DEFUN([LIBCFS_KTIME_GET_TS64],[
 268 LB_CHECK_COMPILE([does function 'ktime_get_ts64' exist],
 269 ktime_get_ts64, [
 270         #include <linux/ktime.h>
 271 ],[
 272         struct timespec64 *ts = NULL;
 273
 274         ktime_get_ts64(ts);
 275 ],[
 276         AC_DEFINE(HAVE_KTIME_GET_TS64, 1,
 277                 ['ktime_get_ts64' is available])
 278 ])
 279 ]) # LIBCFS_KTIME_GET_TS64
 280
 281 #
 282
 283 #
 284 # FC19 3.12 kernel struct shrinker change
 285 #
 286 AC_DEFUN([LIBCFS_SHRINKER_COUNT],[
 287 LB_CHECK_COMPILE([shrinker has 'count_objects'],
 288 shrinker_count_objects, [
 289         #include <linux/mmzone.h>
 290         #include <linux/shrinker.h>
 291 ],[
 292         ((struct shrinker*)0)->count_objects(NULL, NULL);
 293 ],[
 294         AC_DEFINE(HAVE_SHRINKER_COUNT, 1,
 295                 [shrinker has count_objects member])
 296 ])
 297 ]) # LIBCFS_SHRINKER_COUNT
 298
 299 #
 300 # Kernel version 3.17 changed hlist_add_after to
 301 # hlist_add_behind
 302 #
 303 AC_DEFUN([LIBCFS_HLIST_ADD_AFTER],[
 304 LB_CHECK_COMPILE([does function 'hlist_add_after' exist],
 305 hlist_add_after, [
 306         #include <linux/list.h>
 307 ],[
 308         hlist_add_after(NULL, NULL);
 309 ],[
 310         AC_DEFINE(HAVE_HLIST_ADD_AFTER, 1,
 311                 [hlist_add_after is available])
 312 ])
 313 ]) # LIBCFS_HLIST_ADD_AFTER
 314
 315 #
 316 # Kernel version 3.17 introduced struct timespec64
 317 #
 318 AC_DEFUN([LIBCFS_TIMESPEC64],[
 319 LB_CHECK_COMPILE([does 'struct timespec64' exist],
 320 timespec64, [
 321         #include <linux/time.h>
 322 ],[
 323         struct timespec64 ts;
 324
 325         ts.tv_sec = 0;
 326         ts.tv_nsec = 0;
 327 ],[
 328         AC_DEFINE(HAVE_TIMESPEC64, 1,
 329                 ['struct timespec64' is available])
 330 ])
 331 ]) # LIBCFS_TIMESPEC64
 332
 333 #
 334 # Kernel version 3.17 introduced ktime_get_real_ts64
 335 #
 336 AC_DEFUN([LIBCFS_KTIME_GET_REAL_TS64],[
 337 LB_CHECK_COMPILE([does function 'ktime_get_real_ts64' exist],
 338 ktime_get_real_ts64, [
 339         #include <linux/ktime.h>
 340 ],[
 341         struct timespec64 *ts = NULL;
 342
 343         ktime_get_real_ts64(ts);
 344 ],[
 345         AC_DEFINE(HAVE_KTIME_GET_REAL_TS64, 1,
 346                 ['ktime_get_real_ts64' is available])
 347 ])
 348 ]) # LIBCFS_KTIME_GET_REAL_TS64
 349
 350 #
 351 # Kernel version 3.17 introduced ktime_get_real_seconds
 352 #
 353 AC_DEFUN([LIBCFS_KTIME_GET_REAL_SECONDS],[
 354 LB_CHECK_COMPILE([does function 'ktime_get_real_seconds' exist],
 355 ktime_get_real_seconds, [
 356         #include <linux/ktime.h>
 357 ],[
 358         time64_t now;
 359
 360         now = ktime_get_real_seconds();
 361 ],[
 362         AC_DEFINE(HAVE_KTIME_GET_REAL_SECONDS, 1,
 363                 ['ktime_get_real_seconds' is available])
 364 ])
 365 ]) # LIBCFS_KTIME_GET_REAL_SECONDS
 366
 367 #
 368 # Kernel version 3.17 created ktime_get_real_ns wrapper
 369 #
 370 AC_DEFUN([LIBCFS_KTIME_GET_REAL_NS],[
 371 LB_CHECK_COMPILE([does function 'ktime_get_real_ns' exist],
 372 ktime_get_real_ns, [
 373         #include <linux/ktime.h>
 374 ],[
 375         u64 nanoseconds;
 376
 377         nanoseconds = ktime_get_real_ns();
 378 ],[],[
 379         AC_DEFINE(NEED_KTIME_GET_REAL_NS, 1,
 380                 ['ktime_get_real_ns' is not available])
 381 ])
 382 ]) # LIBCFS_KTIME_GET_REAL_NS
 383
 384 #
 385 # Kernel version 3.19 introduced ktime_get_seconds
 386 #
 387 AC_DEFUN([LIBCFS_KTIME_GET_SECONDS],[
 388 LB_CHECK_COMPILE([does function 'ktime_get_seconds' exist],
 389 ktime_get_seconds, [
 390         #include <linux/ktime.h>
 391 ],[
 392         time64_t now;
 393
 394         now = ktime_get_seconds();
 395 ],[
 396         AC_DEFINE(HAVE_KTIME_GET_SECONDS, 1,
 397                 ['ktime_get_seconds' is available])
 398 ])
 399 ]) # LIBCFS_KTIME_GET_SECONDS
 400
 401 #
 402 # Kernel version 4.2 changed topology_thread_cpumask
 403 # to topology_sibling_cpumask
 404 #
 405 AC_DEFUN([LIBCFS_HAVE_TOPOLOGY_SIBLING_CPUMASK],[
 406 LB_CHECK_COMPILE([does function 'topology_sibling_cpumask' exist],
 407 topology_sibling_cpumask, [
 408         #include <linux/topology.h>
 409 ],[
 410         const struct cpumask *mask;
 411
 412         mask = topology_sibling_cpumask(0);
 413 ],[
 414         AC_DEFINE(HAVE_TOPOLOGY_SIBLING_CPUMASK, 1,
 415                 [topology_sibling_cpumask is available])
 416 ])
 417 ]) # LIBCFS_HAVE_TOPOLOGY_SIBLING_CPUMASK
 418
 419 #
 420 # Kernel version 4.2 commit df6b35f409af0a8ff1ef62f552b8402f3fef8665
 421 # header file i387.h was renamed to fpu/api.h
 422 #
 423 AC_DEFUN([LIBCFS_FPU_API], [
 424 LB_CHECK_LINUX_HEADER([asm/fpu/api.h], [
 425         AC_DEFINE(HAVE_FPU_API_HEADER, 1,
 426                 [fpu/api.h is present])])
 427 ]) # LIBCFS_FPU_API
 428
 429 #
 430 # Kernel version 4.5-rc1 commit d12481bc58fba89427565f8592e88446ec084a24
 431 # added crypto hash helpers
 432 #
 433 AC_DEFUN([LIBCFS_CRYPTO_HASH_HELPERS], [
 434 LB_CHECK_COMPILE([does crypto hash helper functions exist],
 435 crypto_hash_helpers, [
 436         #include <crypto/hash.h>
 437 ],[
 438         crypto_ahash_alg_name(NULL);
 439         crypto_ahash_driver_name(NULL);
 440 ],[
 441         AC_DEFINE(HAVE_CRYPTO_HASH_HELPERS, 1,
 442                 [crypto hash helper functions are available])
 443 ])
 444 ]) # LIBCFS_CRYPTO_HASH_HELPERS
 445
 446 #
 447 # LIBCFS_STACKTRACE_OPS_ADDRESS_RETURN_INT
 448 #
 449 # linux 4.6 kernel changed stacktrace_ops address to return an int
 450 #
 451 AC_DEFUN([LIBCFS_STACKTRACE_OPS_ADDRESS_RETURN_INT], [
 452 LB_CHECK_COMPILE([if 'struct stacktrace_ops' address function returns an int],
 453 stacktrace_ops_address_return_int, [
 454         #include <asm/stacktrace.h>
 455 ],[
 456         int rc;
 457
 458         rc = ((struct stacktrace_ops *)0)->address(NULL, 0, 0);
 459 ],[
 460         AC_DEFINE(STACKTRACE_OPS_ADDRESS_RETURN_INT, 1,
 461                 ['struct stacktrace_ops' address function returns an int])
 462 ])
 463 ]) # LIBCFS_STACKTRACE_OPS_ADDRESS_RETURN_INT
 464
 465 #
 466 # Kernel version 4.6 removed both struct task_struct and struct mm_struct
 467 # arguments to get_user_pages
 468 #
 469 AC_DEFUN([LIBCFS_GET_USER_PAGES_6ARG], [
 470 LB_CHECK_COMPILE([if 'get_user_pages()' takes 6 arguments],
 471 get_user_pages_6arg, [
 472         #include <linux/mm.h>
 473 ],[
 474         int rc;
 475
 476         rc = get_user_pages(0, 0, 0, 0, NULL, NULL);
 477 ],[
 478         AC_DEFINE(HAVE_GET_USER_PAGES_6ARG, 1,
 479                 [get_user_pages takes 6 arguments])
 480 ])
 481 ]) # LIBCFS_GET_USER_PAGES_6ARG
 482
 483 #
 484 # LIBCFS_PROG_LINUX
 485 #
 486 # LibCFS linux kernel checks
 487 #
 488 AC_DEFUN([LIBCFS_PROG_LINUX], [
 489 AC_MSG_NOTICE([LibCFS kernel checks
 490 ==============================================================================])
 491 LIBCFS_CONFIG_PANIC_DUMPLOG
 492
 493 # 2.6.32
 494 LIBCFS_STACKTRACE_OPS_HAVE_WALK_STACK
 495 LC_SHRINKER_WANT_SHRINK_PTR
 496 # 2.6.33
 497 LIBCFS_SYSCTL_CTLNAME
 498 # 2.6.38
 499 LIBCFS_KSTRTOUL
 500 # 2.6.39
 501 LIBCFS_DUMP_TRACE_ADDRESS
 502 # 2.6.40 fc15
 503 LC_SHRINK_CONTROL
 504 # 3.0
 505 LIBCFS_STACKTRACE_WARNING
 506 # 3.5
 507 LIBCFS_PROCESS_NAMESPACE
 508 LIBCFS_I_UID_READ
 509 # 3.7
 510 LIBCFS_SOCK_ALLOC_FILE
 511 # 3.8
 512 LIBCFS_HAVE_CRC32
 513 LIBCFS_ENABLE_CRC32_ACCEL
 514 # 3.10
 515 LIBCFS_ENABLE_CRC32C_ACCEL
 516 # 3.11
 517 LIBCFS_KTIME_GET_TS64
 518 # 3.12
 519 LIBCFS_SHRINKER_COUNT
 520 # 3.17
 521 LIBCFS_HLIST_ADD_AFTER
 522 LIBCFS_TIMESPEC64
 523 LIBCFS_KTIME_GET_REAL_TS64
 524 LIBCFS_KTIME_GET_REAL_SECONDS
 525 LIBCFS_KTIME_GET_REAL_NS
 526 # 3.19
 527 LIBCFS_KTIME_GET_SECONDS
 528 # 4.2
 529 LIBCFS_HAVE_TOPOLOGY_SIBLING_CPUMASK
 530 LIBCFS_FPU_API
 531 # 4.5
 532 LIBCFS_CRYPTO_HASH_HELPERS
 533 # 4.6
 534 LIBCFS_STACKTRACE_OPS_ADDRESS_RETURN_INT
 535 LIBCFS_GET_USER_PAGES_6ARG
 536 ]) # LIBCFS_PROG_LINUX
 537
 538 #
 539 # LIBCFS_PATH_DEFAULTS
 540 #
 541 # default paths for installed files
 542 #
 543 AC_DEFUN([LIBCFS_PATH_DEFAULTS], [
 544 ]) # LIBCFS_PATH_DEFAULTS
 545
 546 #
 547 # LIBCFS_CONFIGURE
 548 #
 549 # other configure checks
 550 #
 551 AC_DEFUN([LIBCFS_CONFIGURE], [
 552 AC_MSG_NOTICE([LibCFS core checks
 553 ==============================================================================])
 554
 555 # lnet/utils/portals.c
 556 AC_CHECK_HEADERS([asm/types.h endian.h sys/ioctl.h])
 557
 558 # lnet/utils/debug.c
 559 AC_CHECK_HEADERS([linux/version.h])
 560
 561 AC_CHECK_TYPE([spinlock_t],
 562         [AC_DEFINE(HAVE_SPINLOCK_T, 1, [spinlock_t is defined])],
 563         [],
 564         [#include <linux/spinlock.h>])
 565
 566 # lnet/utils/wirecheck.c
 567 AC_CHECK_FUNCS([strnlen])
 568
 569 # lnet/libcfs/user-prim.c, missing for RHEL5 and earlier userspace
 570 AC_CHECK_FUNCS([strlcpy])
 571
 572 # libcfs/libcfs/user-prim.c, missing for RHEL5 and earlier userspace
 573 AC_CHECK_FUNCS([strlcat])
 574
 575 # libcfs/include/libcfs/linux/linux-prim.h, ...
 576 AC_CHECK_HEADERS([linux/types.h sys/types.h linux/unistd.h unistd.h])
 577
 578 # libcfs/include/libcfs/linux/linux-prim.h
 579 AC_CHECK_HEADERS([linux/random.h], [], [],
 580                  [#ifdef HAVE_LINUX_TYPES_H
 581                   #include <linux/types.h>
 582                   #endif
 583                  ])
 584
 585 # libcfs/include/libcfs/linux/libcfs.h
 586 # libcfs/include/libcfs/byteorder.h
 587 # libcfs/libcfs/util/nidstrings.c
 588 AC_CHECK_HEADERS([netdb.h asm/types.h endian.h])
 589 AC_CHECK_FUNCS([gethostbyname])
 590
 591 # --------  Check for required packages  --------------
 592
 593 AC_MSG_NOTICE([LibCFS required packages checks
 594 ==============================================================================])
 595
 596 AC_MSG_CHECKING([whether to enable readline support])
 597 AC_ARG_ENABLE(readline,
 598         AC_HELP_STRING([--disable-readline],
 599                 [disable readline support]),
 600         [], [enable_readline="yes"])
 601 AC_MSG_RESULT([$enable_readline])
 602
 603 LIBREADLINE=""
 604 AS_IF([test "x$enable_readline" = xyes], [
 605         AC_CHECK_LIB([readline], [readline], [
 606                 LIBREADLINE="-lreadline"
 607                 AC_DEFINE(HAVE_LIBREADLINE, 1,
 608                         [readline library is available])
 609         ])
 610 ])
 611 AC_SUBST(LIBREADLINE)
 612
 613 AC_MSG_CHECKING([whether to use libpthread for libcfs library])
 614 AC_ARG_ENABLE([libpthread],
 615         AC_HELP_STRING([--disable-libpthread],
 616                 [disable libpthread]),
 617         [], [enable_libpthread="yes"])
 618 AC_MSG_RESULT([$enable_libpthread])
 619
 620 PTHREAD_LIBS=""
 621 AS_IF([test "x$enable_libpthread" = xyes], [
 622         AC_CHECK_LIB([pthread], [pthread_create], [
 623                 PTHREAD_LIBS="-lpthread"
 624                 AC_DEFINE([HAVE_LIBPTHREAD], 1,
 625                         [use libpthread for libcfs library])
 626         ])
 627 ], [
 628         AC_MSG_WARN([Using libpthread for libcfs library is disabled explicitly])
 629 ])
 630 AC_SUBST(PTHREAD_LIBS)
 631 ]) # LIBCFS_CONFIGURE
 632
 633 #
 634 # LIBCFS_CONDITIONALS
 635 #
 636 AC_DEFUN([LIBCFS_CONDITIONALS], [
 637 AM_CONDITIONAL(HAVE_CRC32, [test "x$have_crc32" = xyes])
 638 AM_CONDITIONAL(NEED_PCLMULQDQ_CRC32,  [test "x$have_crc32" = xyes -a "x$enable_crc32_crypto" = xyes])
 639 AM_CONDITIONAL(NEED_PCLMULQDQ_CRC32C, [test "x$enable_crc32c_crypto" = xyes])
 640 ]) # LIBCFS_CONDITIONALS
 641
 642 #
 643 # LIBCFS_CONFIG_FILES
 644 #
 645 # files that should be generated with AC_OUTPUT
 646 #
 647 AC_DEFUN([LIBCFS_CONFIG_FILES], [
 648 AC_CONFIG_FILES([
 649 libcfs/Makefile
 650 libcfs/autoMakefile
 651 libcfs/autoconf/Makefile
 652 libcfs/include/Makefile
 653 libcfs/include/libcfs/Makefile
 654 libcfs/include/libcfs/linux/Makefile
 655 libcfs/include/libcfs/util/Makefile
 656 libcfs/libcfs/Makefile
 657 libcfs/libcfs/autoMakefile
 658 libcfs/libcfs/linux/Makefile
 659 libcfs/libcfs/util/Makefile
 660 ])
 661 ]) # LIBCFS_CONFIG_FILES