libcfs/autoconf/lustre-libcfs.m4

   1 #
   2 # LIBCFS_CONFIG_CDEBUG
   3 #
   4 # whether to enable various libcfs debugs (CDEBUG, ENTRY/EXIT, LASSERT, etc.)
   5 #
   6 AC_DEFUN([LIBCFS_CONFIG_CDEBUG], [
   7 AC_MSG_CHECKING([whether to enable CDEBUG, CWARN])
   8 AC_ARG_ENABLE([libcfs_cdebug],
   9         AC_HELP_STRING([--disable-libcfs-cdebug],
  10                 [disable libcfs CDEBUG, CWARN]),
  11         [], [enable_libcfs_cdebug="yes"])
  12 AC_MSG_RESULT([$enable_libcfs_cdebug])
  13 AS_IF([test "x$enable_libcfs_cdebug" = xyes],
  14         [AC_DEFINE(CDEBUG_ENABLED, 1, [enable libcfs CDEBUG, CWARN])])
  15
  16 AC_MSG_CHECKING([whether to enable ENTRY/EXIT])
  17 AC_ARG_ENABLE([libcfs_trace],
  18         AC_HELP_STRING([--disable-libcfs-trace],
  19                 [disable libcfs ENTRY/EXIT]),
  20         [], [enable_libcfs_trace="yes"])
  21 AC_MSG_RESULT([$enable_libcfs_trace])
  22 AS_IF([test "x$enable_libcfs_trace" = xyes],
  23         [AC_DEFINE(CDEBUG_ENTRY_EXIT, 1, [enable libcfs ENTRY/EXIT])])
  24
  25 AC_MSG_CHECKING([whether to enable LASSERT, LASSERTF])
  26 AC_ARG_ENABLE([libcfs_assert],
  27         AC_HELP_STRING([--disable-libcfs-assert],
  28                 [disable libcfs LASSERT, LASSERTF]),
  29         [], [enable_libcfs_assert="yes"])
  30 AC_MSG_RESULT([$enable_libcfs_assert])
  31 AS_IF([test x$enable_libcfs_assert = xyes],
  32         [AC_DEFINE(LIBCFS_DEBUG, 1, [enable libcfs LASSERT, LASSERTF])])
  33 ]) # LIBCFS_CONFIG_CDEBUG
  34
  35 #
  36 # LIBCFS_CONFIG_PANIC_DUMPLOG
  37 #
  38 # check if tunable panic_dumplog is wanted
  39 #
  40 AC_DEFUN([LIBCFS_CONFIG_PANIC_DUMPLOG], [
  41 AC_MSG_CHECKING([whether to use tunable 'panic_dumplog' support])
  42 AC_ARG_ENABLE([panic_dumplog],
  43         AC_HELP_STRING([--enable-panic_dumplog],
  44                 [enable panic_dumplog]),
  45         [], [enable_panic_dumplog="no"])
  46 AC_MSG_RESULT([$enable_panic_dumplog])
  47 AS_IF([test "x$enable_panic_dumplog" = xyes],
  48         [AC_DEFINE(LNET_DUMP_ON_PANIC, 1, [use dumplog on panic])])
  49 ]) # LIBCFS_CONFIG_PANIC_DUMPLOG
  50
  51 #
  52 # LIBCFS_STACKTRACE_OPS_HAVE_WALK_STACK
  53 #
  54 # 2.6.32-30.el6 adds a new 'walk_stack' field in 'struct stacktrace_ops'
  55 #
  56 AC_DEFUN([LIBCFS_STACKTRACE_OPS_HAVE_WALK_STACK], [
  57 LB_CHECK_COMPILE([if 'struct stacktrace_ops' has 'walk_stack' field],
  58 stacktrace_ops_walk_stack, [
  59         #include <asm/stacktrace.h>
  60 ],[
  61         ((struct stacktrace_ops *)0)->walk_stack(NULL, NULL, 0, NULL, NULL, NULL, NULL);
  62 ],[
  63         AC_DEFINE(STACKTRACE_OPS_HAVE_WALK_STACK, 1,
  64                 ['struct stacktrace_ops' has 'walk_stack' field])
  65 ])
  66 ]) # LIBCFS_STACKTRACE_OPS_HAVE_WALK_STACK
  67
  68 #
  69 # LIBCFS_STACKTRACE_WARNING
  70 #
  71 # 3.0 removes stacktrace_ops warning* functions
  72 #
  73 AC_DEFUN([LIBCFS_STACKTRACE_WARNING], [
  74 LB_CHECK_COMPILE([if 'stacktrace_ops.warning' is exist],
  75 stacktrace_ops_warning, [
  76         struct task_struct;
  77         struct pt_regs;
  78         #include <asm/stacktrace.h>
  79 ],[
  80         ((struct stacktrace_ops *)0)->warning(NULL, NULL);
  81 ],[
  82         AC_DEFINE(HAVE_STACKTRACE_WARNING, 1,
  83                 [stacktrace_ops.warning is exist])
  84 ])
  85 ]) # LIBCFS_STACKTRACE_WARNING
  86
  87 #
  88 # LC_SHRINKER_WANT_SHRINK_PTR
  89 #
  90 # RHEL6/2.6.32 want to have pointer to shrinker self pointer in handler function
  91 #
  92 AC_DEFUN([LC_SHRINKER_WANT_SHRINK_PTR], [
  93 LB_CHECK_COMPILE([if 'shrinker' want self pointer in handler],
  94 shrink_self_pointer, [
  95         #include <linux/mm.h>
  96 ],[
  97         struct shrinker *tmp = NULL;
  98         tmp->shrink(tmp, 0, 0);
  99 ],[
 100         AC_DEFINE(HAVE_SHRINKER_WANT_SHRINK_PTR, 1,
 101                 [shrinker want self pointer in handler])
 102 ])
 103 ]) # LC_SHRINKER_WANT_SHRINK_PTR
 104
 105 #
 106 # LIBCFS_SYSCTL_CTLNAME
 107 #
 108 # 2.6.33 no longer has ctl_name & strategy field in struct ctl_table.
 109 #
 110 AC_DEFUN([LIBCFS_SYSCTL_CTLNAME], [
 111 LB_CHECK_COMPILE([if 'ctl_table' has a 'ctl_name' field],
 112 ctl_table_ctl_name, [
 113         #include <linux/sysctl.h>
 114 ],[
 115         struct ctl_table ct;
 116         ct.ctl_name = sizeof(ct);
 117 ],[
 118         AC_DEFINE(HAVE_SYSCTL_CTLNAME, 1,
 119                 [ctl_table has ctl_name field])
 120 ])
 121 ]) # LIBCFS_SYSCTL_CTLNAME
 122
 123 #
 124 # LIBCFS_KSTRTOUL
 125 #
 126 # 2.6.38 kstrtoul is added
 127 #
 128 AC_DEFUN([LIBCFS_KSTRTOUL], [
 129 LB_CHECK_COMPILE([if Linux kernel has 'kstrtoul'],
 130 kstrtoul, [
 131         #include <linux/kernel.h>
 132 ],[
 133         unsigned long result;
 134         return kstrtoul("12345", 0, &result);
 135 ],[
 136         AC_DEFINE(HAVE_KSTRTOUL, 1,
 137                 [kernel has kstrtoul])
 138 ])
 139 ]) # LIBCFS_KSTRTOUL
 140
 141 #
 142 # LIBCFS_DUMP_TRACE_ADDRESS
 143 #
 144 # 2.6.39 adds a base pointer address argument to dump_trace
 145 #
 146 AC_DEFUN([LIBCFS_DUMP_TRACE_ADDRESS], [
 147 LB_CHECK_COMPILE([if 'dump_trace' want address],
 148 dump_trace_address, [
 149         struct task_struct;
 150         struct pt_regs;
 151         #include <asm/stacktrace.h>
 152 ],[
 153         dump_trace(NULL, NULL, NULL, 0, NULL, NULL);
 154 ],[
 155         AC_DEFINE(HAVE_DUMP_TRACE_ADDRESS, 1,
 156                 [dump_trace want address argument])
 157 ])
 158 ]) # LIBCFS_DUMP_TRACE_ADDRESS
 159
 160 #
 161 # LC_SHRINK_CONTROL
 162 #
 163 # FC15 2.6.40-5 backported the "shrink_control" parameter to the memory
 164 # pressure shrinker from Linux 3.0
 165 #
 166 AC_DEFUN([LC_SHRINK_CONTROL], [
 167 LB_CHECK_COMPILE([if 'shrink_control' is present],
 168 shrink_control, [
 169         #include <linux/atomic.h>
 170         #include <linux/mm.h>
 171 ],[
 172         struct shrink_control tmp = {0};
 173         tmp.nr_to_scan = sizeof(tmp);
 174 ],[
 175         AC_DEFINE(HAVE_SHRINK_CONTROL, 1,
 176                 [shrink_control is present])
 177 ])
 178 ]) # LC_SHRINK_CONTROL
 179
 180 #
 181 # LIBCFS_PROCESS_NAMESPACE
 182 #
 183 # 3.5 introduced process namespace
 184 AC_DEFUN([LIBCFS_PROCESS_NAMESPACE], [
 185 LB_CHECK_LINUX_HEADER([linux/uidgid.h], [
 186         AC_DEFINE(HAVE_UIDGID_HEADER, 1,
 187                 [uidgid.h is present])])
 188 ]) # LIBCFS_PROCESS_NAMESPACE
 189
 190 #
 191 # LIBCFS_I_UID_READ
 192 #
 193 # 3.5 added helpers to read the new uid/gid types from VFS structures
 194 # SLE11 SP3 has uidgid.h but not the helpers
 195 #
 196 AC_DEFUN([LIBCFS_I_UID_READ], [
 197 LB_CHECK_COMPILE([if 'i_uid_read' is present],
 198 i_uid_read, [
 199         #include <linux/fs.h>
 200 ],[
 201         i_uid_read(NULL);
 202 ],[
 203         AC_DEFINE(HAVE_I_UID_READ, 1, [i_uid_read is present])
 204 ])
 205 ]) # LIBCFS_I_UID_READ
 206
 207 #
 208 # LIBCFS_SOCK_ALLOC_FILE
 209 #
 210 # FC18 3.7.2-201 unexport sock_map_fd() change to
 211 # use sock_alloc_file().
 212 # upstream commit 56b31d1c9f1e6a3ad92e7bfe252721e05d92b285
 213 #
 214 AC_DEFUN([LIBCFS_SOCK_ALLOC_FILE], [
 215 LB_CHECK_EXPORT([sock_alloc_file], [net/socket.c], [
 216         LB_CHECK_COMPILE([if 'sock_alloc_file' takes 3 arguments],
 217         sock_alloc_file_3args, [
 218                 #include <linux/net.h>
 219         ],[
 220                 sock_alloc_file(NULL, 0, NULL);
 221         ],[
 222                 AC_DEFINE(HAVE_SOCK_ALLOC_FILE_3ARGS, 1,
 223                         [sock_alloc_file takes 3 arguments])
 224         ],[
 225                 AC_DEFINE(HAVE_SOCK_ALLOC_FILE, 1,
 226                         [sock_alloc_file is exported])
 227         ])
 228 ])
 229 ]) # LIBCFS_SOCK_ALLOC_FILE
 230
 231 #
 232 # LIBCFS_HAVE_CRC32
 233 #
 234 AC_DEFUN([LIBCFS_HAVE_CRC32], [
 235 LB_CHECK_CONFIG_IM([CRC32],
 236         [have_crc32="yes"], [have_crc32="no"])
 237 AS_IF([test "x$have_crc32" = xyes],
 238         [AC_DEFINE(HAVE_CRC32, 1,
 239                 [kernel compiled with CRC32 functions])])
 240 ]) # LIBCFS_HAVE_CRC32
 241
 242 #
 243 # LIBCFS_ENABLE_CRC32_ACCEL
 244 #
 245 AC_DEFUN([LIBCFS_ENABLE_CRC32_ACCEL], [
 246 LB_CHECK_CONFIG_IM([CRYPTO_CRC32_PCLMUL],
 247         [enable_crc32_crypto="no"], [enable_crc32_crypto="yes"])
 248 AS_IF([test "x$have_crc32" = xyes -a "x$enable_crc32_crypto" = xyes], [
 249         AC_DEFINE(NEED_CRC32_ACCEL, 1, [need pclmulqdq based crc32])
 250         AC_MSG_WARN([No crc32 pclmulqdq crypto api found, enable internal pclmulqdq based crc32])])
 251 ]) # LIBCFS_ENABLE_CRC32_ACCEL
 252
 253 #
 254 # LIBCFS_ENABLE_CRC32C_ACCEL
 255 #
 256 AC_DEFUN([LIBCFS_ENABLE_CRC32C_ACCEL], [
 257 LB_CHECK_CONFIG_IM([CRYPTO_CRC32C_INTEL],
 258         [enable_crc32c_crypto="no"], [enable_crc32c_crypto="yes"])
 259 AS_IF([test "x$enable_crc32c_crypto" = xyes], [
 260         AC_DEFINE(NEED_CRC32C_ACCEL, 1, [need pclmulqdq based crc32c])
 261         AC_MSG_WARN([No crc32c pclmulqdq crypto api found, enable internal pclmulqdq based crc32c])])
 262 ]) # LIBCFS_ENABLE_CRC32C_ACCEL
 263
 264 #
 265 # Kernel version 3.11 introduced ktime_get_ts64
 266 #
 267 AC_DEFUN([LIBCFS_KTIME_GET_TS64],[
 268 LB_CHECK_COMPILE([does function 'ktime_get_ts64' exist],
 269 ktime_get_ts64, [
 270         #include <linux/ktime.h>
 271 ],[
 272         struct timespec64 *ts = NULL;
 273
 274         ktime_get_ts64(ts);
 275 ],[
 276         AC_DEFINE(HAVE_KTIME_GET_TS64, 1,
 277                 ['ktime_get_ts64' is available])
 278 ])
 279 ]) # LIBCFS_KTIME_GET_TS64
 280
 281 #
 282
 283 #
 284 # FC19 3.12 kernel struct shrinker change
 285 #
 286 AC_DEFUN([LIBCFS_SHRINKER_COUNT],[
 287 LB_CHECK_COMPILE([shrinker has 'count_objects'],
 288 shrinker_count_objects, [
 289         #include <linux/mmzone.h>
 290         #include <linux/shrinker.h>
 291 ],[
 292         ((struct shrinker*)0)->count_objects(NULL, NULL);
 293 ],[
 294         AC_DEFINE(HAVE_SHRINKER_COUNT, 1,
 295                 [shrinker has count_objects member])
 296 ])
 297 ]) # LIBCFS_SHRINKER_COUNT
 298
 299 #
 300 # Kernel version 3.17 changed hlist_add_after to
 301 # hlist_add_behind
 302 #
 303 AC_DEFUN([LIBCFS_HLIST_ADD_AFTER],[
 304 LB_CHECK_COMPILE([does function 'hlist_add_after' exist],
 305 hlist_add_after, [
 306         #include <linux/list.h>
 307 ],[
 308         hlist_add_after(NULL, NULL);
 309 ],[
 310         AC_DEFINE(HAVE_HLIST_ADD_AFTER, 1,
 311                 [hlist_add_after is available])
 312 ])
 313 ]) # LIBCFS_HLIST_ADD_AFTER
 314
 315 #
 316 # Kernel version 3.17 introduced struct timespec64
 317 #
 318 AC_DEFUN([LIBCFS_TIMESPEC64],[
 319 LB_CHECK_COMPILE([does 'struct timespec64' exist],
 320 timespec64, [
 321         #include <linux/time.h>
 322 ],[
 323         struct timespec64 ts;
 324
 325         ts.tv_sec = 0;
 326         ts.tv_nsec = 0;
 327 ],[
 328         AC_DEFINE(HAVE_TIMESPEC64, 1,
 329                 ['struct timespec64' is available])
 330 ])
 331 ]) # LIBCFS_TIMESPEC64
 332
 333 #
 334 # Kernel version 3.17 introduced ktime_get_real_ts64
 335 #
 336 AC_DEFUN([LIBCFS_KTIME_GET_REAL_TS64],[
 337 LB_CHECK_COMPILE([does function 'ktime_get_real_ts64' exist],
 338 ktime_get_real_ts64, [
 339         #include <linux/ktime.h>
 340 ],[
 341         struct timespec64 *ts = NULL;
 342
 343         ktime_get_real_ts64(ts);
 344 ],[
 345         AC_DEFINE(HAVE_KTIME_GET_REAL_TS64, 1,
 346                 ['ktime_get_real_ts64' is available])
 347 ])
 348 ]) # LIBCFS_KTIME_GET_REAL_TS64
 349
 350 #
 351 # Kernel version 3.17 introduced ktime_get_real_seconds
 352 #
 353 AC_DEFUN([LIBCFS_KTIME_GET_REAL_SECONDS],[
 354 LB_CHECK_COMPILE([does function 'ktime_get_real_seconds' exist],
 355 ktime_get_real_seconds, [
 356         #include <linux/ktime.h>
 357 ],[
 358         time64_t now;
 359
 360         now = ktime_get_real_seconds();
 361 ],[
 362         AC_DEFINE(HAVE_KTIME_GET_REAL_SECONDS, 1,
 363                 ['ktime_get_real_seconds' is available])
 364 ])
 365 ]) # LIBCFS_KTIME_GET_REAL_SECONDS
 366
 367 #
 368 # Kernel version 3.19 introduced ktime_get_seconds
 369 #
 370 AC_DEFUN([LIBCFS_KTIME_GET_SECONDS],[
 371 LB_CHECK_COMPILE([does function 'ktime_get_seconds' exist],
 372 ktime_get_seconds, [
 373         #include <linux/ktime.h>
 374 ],[
 375         time64_t now;
 376
 377         now = ktime_get_seconds();
 378 ],[
 379         AC_DEFINE(HAVE_KTIME_GET_SECONDS, 1,
 380                 ['ktime_get_seconds' is available])
 381 ])
 382 ]) # LIBCFS_KTIME_GET_SECONDS
 383
 384 #
 385 # Kernel version 4.2 changed topology_thread_cpumask
 386 # to topology_sibling_cpumask
 387 #
 388 AC_DEFUN([LIBCFS_HAVE_TOPOLOGY_SIBLING_CPUMASK],[
 389 LB_CHECK_COMPILE([does function 'topology_sibling_cpumask' exist],
 390 topology_sibling_cpumask, [
 391         #include <linux/topology.h>
 392 ],[
 393         const struct cpumask *mask;
 394
 395         mask = topology_sibling_cpumask(0);
 396 ],[
 397         AC_DEFINE(HAVE_TOPOLOGY_SIBLING_CPUMASK, 1,
 398                 [topology_sibling_cpumask is available])
 399 ])
 400 ]) # LIBCFS_HAVE_TOPOLOGY_SIBLING_CPUMASK
 401
 402 #
 403 # Kernel version 4.2 commit df6b35f409af0a8ff1ef62f552b8402f3fef8665
 404 # header file i387.h was renamed to fpu/api.h
 405 #
 406 AC_DEFUN([LIBCFS_FPU_API], [
 407 LB_CHECK_LINUX_HEADER([asm/fpu/api.h], [
 408         AC_DEFINE(HAVE_FPU_API_HEADER, 1,
 409                 [fpu/api.h is present])])
 410 ]) # LIBCFS_FPU_API
 411
 412 #
 413 # Kernel version 4.5-rc1 commit d12481bc58fba89427565f8592e88446ec084a24
 414 # added crypto hash helpers
 415 #
 416 AC_DEFUN([LIBCFS_CRYPTO_HASH_HELPERS], [
 417 LB_CHECK_COMPILE([does crypto hash helper functions exist],
 418 crypto_hash_helpers, [
 419         #include <crypto/hash.h>
 420 ],[
 421         crypto_ahash_alg_name(NULL);
 422         crypto_ahash_driver_name(NULL);
 423 ],[
 424         AC_DEFINE(HAVE_CRYPTO_HASH_HELPERS, 1,
 425                 [crypto hash helper functions are available])
 426 ])
 427 ]) # LIBCFS_CRYPTO_HASH_HELPERS
 428
 429 #
 430 # LIBCFS_STACKTRACE_OPS_ADDRESS_RETURN_INT
 431 #
 432 # linux 4.6 kernel changed stacktrace_ops address to return an int
 433 #
 434 AC_DEFUN([LIBCFS_STACKTRACE_OPS_ADDRESS_RETURN_INT], [
 435 LB_CHECK_COMPILE([if 'struct stacktrace_ops' address function returns an int],
 436 stacktrace_ops_address_return_int, [
 437         #include <asm/stacktrace.h>
 438 ],[
 439         int rc;
 440
 441         rc = ((struct stacktrace_ops *)0)->address(NULL, 0, 0);
 442 ],[
 443         AC_DEFINE(STACKTRACE_OPS_ADDRESS_RETURN_INT, 1,
 444                 ['struct stacktrace_ops' address function returns an int])
 445 ])
 446 ]) # LIBCFS_STACKTRACE_OPS_ADDRESS_RETURN_INT
 447
 448 #
 449 # Kernel version 4.6 removed both struct task_struct and struct mm_struct
 450 # arguments to get_user_pages
 451 #
 452 AC_DEFUN([LIBCFS_GET_USER_PAGES_6ARG], [
 453 LB_CHECK_COMPILE([if 'get_user_pages()' takes 6 arguments],
 454 get_user_pages_6arg, [
 455         #include <linux/mm.h>
 456 ],[
 457         int rc;
 458
 459         rc = get_user_pages(0, 0, 0, 0, NULL, NULL);
 460 ],[
 461         AC_DEFINE(HAVE_GET_USER_PAGES_6ARG, 1,
 462                 [get_user_pages takes 6 arguments])
 463 ])
 464 ]) # LIBCFS_GET_USER_PAGES_6ARG
 465
 466 #
 467 # LIBCFS_PROG_LINUX
 468 #
 469 # LibCFS linux kernel checks
 470 #
 471 AC_DEFUN([LIBCFS_PROG_LINUX], [
 472 AC_MSG_NOTICE([LibCFS kernel checks
 473 ==============================================================================])
 474 LIBCFS_CONFIG_PANIC_DUMPLOG
 475
 476 # 2.6.32
 477 LIBCFS_STACKTRACE_OPS_HAVE_WALK_STACK
 478 LC_SHRINKER_WANT_SHRINK_PTR
 479 # 2.6.33
 480 LIBCFS_SYSCTL_CTLNAME
 481 # 2.6.38
 482 LIBCFS_KSTRTOUL
 483 # 2.6.39
 484 LIBCFS_DUMP_TRACE_ADDRESS
 485 # 2.6.40 fc15
 486 LC_SHRINK_CONTROL
 487 # 3.0
 488 LIBCFS_STACKTRACE_WARNING
 489 # 3.5
 490 LIBCFS_PROCESS_NAMESPACE
 491 LIBCFS_I_UID_READ
 492 # 3.7
 493 LIBCFS_SOCK_ALLOC_FILE
 494 # 3.8
 495 LIBCFS_HAVE_CRC32
 496 LIBCFS_ENABLE_CRC32_ACCEL
 497 # 3.10
 498 LIBCFS_ENABLE_CRC32C_ACCEL
 499 # 3.11
 500 LIBCFS_KTIME_GET_TS64
 501 # 3.12
 502 LIBCFS_SHRINKER_COUNT
 503 # 3.17
 504 LIBCFS_HLIST_ADD_AFTER
 505 LIBCFS_TIMESPEC64
 506 LIBCFS_KTIME_GET_REAL_TS64
 507 LIBCFS_KTIME_GET_REAL_SECONDS
 508 # 3.19
 509 LIBCFS_KTIME_GET_SECONDS
 510 # 4.2
 511 LIBCFS_HAVE_TOPOLOGY_SIBLING_CPUMASK
 512 LIBCFS_FPU_API
 513 # 4.5
 514 LIBCFS_CRYPTO_HASH_HELPERS
 515 # 4.6
 516 LIBCFS_STACKTRACE_OPS_ADDRESS_RETURN_INT
 517 LIBCFS_GET_USER_PAGES_6ARG
 518 ]) # LIBCFS_PROG_LINUX
 519
 520 #
 521 # LIBCFS_PATH_DEFAULTS
 522 #
 523 # default paths for installed files
 524 #
 525 AC_DEFUN([LIBCFS_PATH_DEFAULTS], [
 526 ]) # LIBCFS_PATH_DEFAULTS
 527
 528 #
 529 # LIBCFS_CONFIGURE
 530 #
 531 # other configure checks
 532 #
 533 AC_DEFUN([LIBCFS_CONFIGURE], [
 534 AC_MSG_NOTICE([LibCFS core checks
 535 ==============================================================================])
 536
 537 # lnet/utils/portals.c
 538 AC_CHECK_HEADERS([asm/types.h endian.h sys/ioctl.h])
 539
 540 # lnet/utils/debug.c
 541 AC_CHECK_HEADERS([linux/version.h])
 542
 543 AC_CHECK_TYPE([spinlock_t],
 544         [AC_DEFINE(HAVE_SPINLOCK_T, 1, [spinlock_t is defined])],
 545         [],
 546         [#include <linux/spinlock.h>])
 547
 548 # lnet/utils/wirecheck.c
 549 AC_CHECK_FUNCS([strnlen])
 550
 551 # lnet/libcfs/user-prim.c, missing for RHEL5 and earlier userspace
 552 AC_CHECK_FUNCS([strlcpy])
 553
 554 # libcfs/libcfs/user-prim.c, missing for RHEL5 and earlier userspace
 555 AC_CHECK_FUNCS([strlcat])
 556
 557 # libcfs/include/libcfs/linux/linux-prim.h, ...
 558 AC_CHECK_HEADERS([linux/types.h sys/types.h linux/unistd.h unistd.h])
 559
 560 # libcfs/include/libcfs/linux/linux-prim.h
 561 AC_CHECK_HEADERS([linux/random.h], [], [],
 562                  [#ifdef HAVE_LINUX_TYPES_H
 563                   #include <linux/types.h>
 564                   #endif
 565                  ])
 566
 567 # libcfs/include/libcfs/linux/libcfs.h
 568 # libcfs/include/libcfs/byteorder.h
 569 # libcfs/libcfs/util/nidstrings.c
 570 AC_CHECK_HEADERS([netdb.h asm/types.h endian.h])
 571 AC_CHECK_FUNCS([gethostbyname])
 572
 573 # --------  Check for required packages  --------------
 574
 575 AC_MSG_NOTICE([LibCFS required packages checks
 576 ==============================================================================])
 577
 578 AC_MSG_CHECKING([whether to enable readline support])
 579 AC_ARG_ENABLE(readline,
 580         AC_HELP_STRING([--disable-readline],
 581                 [disable readline support]),
 582         [], [enable_readline="yes"])
 583 AC_MSG_RESULT([$enable_readline])
 584
 585 LIBREADLINE=""
 586 AS_IF([test "x$enable_readline" = xyes], [
 587         AC_CHECK_LIB([readline], [readline], [
 588                 LIBREADLINE="-lreadline"
 589                 AC_DEFINE(HAVE_LIBREADLINE, 1,
 590                         [readline library is available])
 591         ])
 592 ])
 593 AC_SUBST(LIBREADLINE)
 594
 595 AC_MSG_CHECKING([whether to use libpthread for libcfs library])
 596 AC_ARG_ENABLE([libpthread],
 597         AC_HELP_STRING([--disable-libpthread],
 598                 [disable libpthread]),
 599         [], [enable_libpthread="yes"])
 600 AC_MSG_RESULT([$enable_libpthread])
 601
 602 PTHREAD_LIBS=""
 603 AS_IF([test "x$enable_libpthread" = xyes], [
 604         AC_CHECK_LIB([pthread], [pthread_create], [
 605                 PTHREAD_LIBS="-lpthread"
 606                 AC_DEFINE([HAVE_LIBPTHREAD], 1,
 607                         [use libpthread for libcfs library])
 608         ])
 609 ], [
 610         AC_MSG_WARN([Using libpthread for libcfs library is disabled explicitly])
 611 ])
 612 AC_SUBST(PTHREAD_LIBS)
 613 ]) # LIBCFS_CONFIGURE
 614
 615 #
 616 # LIBCFS_CONDITIONALS
 617 #
 618 AC_DEFUN([LIBCFS_CONDITIONALS], [
 619 AM_CONDITIONAL(HAVE_CRC32, [test "x$have_crc32" = xyes])
 620 AM_CONDITIONAL(NEED_PCLMULQDQ_CRC32,  [test "x$have_crc32" = xyes -a "x$enable_crc32_crypto" = xyes])
 621 AM_CONDITIONAL(NEED_PCLMULQDQ_CRC32C, [test "x$enable_crc32c_crypto" = xyes])
 622 ]) # LIBCFS_CONDITIONALS
 623
 624 #
 625 # LIBCFS_CONFIG_FILES
 626 #
 627 # files that should be generated with AC_OUTPUT
 628 #
 629 AC_DEFUN([LIBCFS_CONFIG_FILES], [
 630 AC_CONFIG_FILES([
 631 libcfs/Makefile
 632 libcfs/autoMakefile
 633 libcfs/autoconf/Makefile
 634 libcfs/include/Makefile
 635 libcfs/include/libcfs/Makefile
 636 libcfs/include/libcfs/linux/Makefile
 637 libcfs/include/libcfs/util/Makefile
 638 libcfs/libcfs/Makefile
 639 libcfs/libcfs/autoMakefile
 640 libcfs/libcfs/linux/Makefile
 641 libcfs/libcfs/util/Makefile
 642 ])
 643 ]) # LIBCFS_CONFIG_FILES