libcfs/autoconf/lustre-libcfs.m4

   1 #
   2 # LN_CONFIG_CDEBUG
   3 #
   4 # whether to enable various libcfs debugs (CDEBUG, ENTRY/EXIT, LASSERT, etc.)
   5 #
   6 AC_DEFUN([LN_CONFIG_CDEBUG],
   7 [
   8 AC_MSG_CHECKING([whether to enable CDEBUG, CWARN])
   9 AC_ARG_ENABLE([libcfs_cdebug],
  10         AC_HELP_STRING([--disable-libcfs-cdebug],
  11                         [disable libcfs CDEBUG, CWARN]),
  12         [],[enable_libcfs_cdebug='yes'])
  13 AC_MSG_RESULT([$enable_libcfs_cdebug])
  14 if test x$enable_libcfs_cdebug = xyes; then
  15    AC_DEFINE(CDEBUG_ENABLED, 1, [enable libcfs CDEBUG, CWARN])
  16 else
  17    AC_DEFINE(CDEBUG_ENABLED, 0, [disable libcfs CDEBUG, CWARN])
  18 fi
  19
  20 AC_MSG_CHECKING([whether to enable ENTRY/EXIT])
  21 AC_ARG_ENABLE([libcfs_trace],
  22         AC_HELP_STRING([--disable-libcfs-trace],
  23                         [disable libcfs ENTRY/EXIT]),
  24         [],[enable_libcfs_trace='yes'])
  25 AC_MSG_RESULT([$enable_libcfs_trace])
  26 if test x$enable_libcfs_trace = xyes; then
  27    AC_DEFINE(CDEBUG_ENTRY_EXIT, 1, [enable libcfs ENTRY/EXIT])
  28 else
  29    AC_DEFINE(CDEBUG_ENTRY_EXIT, 0, [disable libcfs ENTRY/EXIT])
  30 fi
  31
  32 AC_MSG_CHECKING([whether to enable LASSERT, LASSERTF])
  33 AC_ARG_ENABLE([libcfs_assert],
  34         AC_HELP_STRING([--disable-libcfs-assert],
  35                         [disable libcfs LASSERT, LASSERTF]),
  36         [],[enable_libcfs_assert='yes'])
  37 AC_MSG_RESULT([$enable_libcfs_assert])
  38 if test x$enable_libcfs_assert = xyes; then
  39    AC_DEFINE(LIBCFS_DEBUG, 1, [enable libcfs LASSERT, LASSERTF])
  40 fi
  41 ])
  42
  43 #
  44 # LIBCFS_CONFIG_PANIC_DUMPLOG
  45 #
  46 # check if tunable panic_dumplog is wanted
  47 #
  48 AC_DEFUN([LIBCFS_CONFIG_PANIC_DUMPLOG],
  49 [AC_MSG_CHECKING([for tunable panic_dumplog support])
  50 AC_ARG_ENABLE([panic_dumplog],
  51        AC_HELP_STRING([--enable-panic_dumplog],
  52                       [enable panic_dumplog]),
  53        [],[enable_panic_dumplog='no'])
  54 if test x$enable_panic_dumplog = xyes ; then
  55        AC_DEFINE(LNET_DUMP_ON_PANIC, 1, [use dumplog on panic])
  56        AC_MSG_RESULT([yes (by request)])
  57 else
  58        AC_MSG_RESULT([no])
  59 fi
  60 ])
  61
  62 # check kernel __u64 type
  63 AC_DEFUN([LIBCFS_U64_LONG_LONG_LINUX],
  64 [
  65 AC_MSG_CHECKING([kernel __u64 is long long type])
  66 tmp_flags="$EXTRA_KCFLAGS"
  67 EXTRA_KCFLAGS="$EXTRA_KCFLAGS -Werror"
  68 LB_LINUX_TRY_COMPILE([
  69         #include <linux/types.h>
  70         #include <linux/stddef.h>
  71 ],[
  72         unsigned long long *data;
  73
  74         data = (__u64*)sizeof(data);
  75 ],[
  76         AC_MSG_RESULT([yes])
  77         AC_DEFINE(HAVE_KERN__U64_LONG_LONG, 1,
  78                   [kernel __u64 is long long type])
  79 ],[
  80         AC_MSG_RESULT([no])
  81 ])
  82 EXTRA_KCFLAGS="$tmp_flags"
  83 ])
  84
  85 # 2.6.24 request not use real numbers for ctl_name
  86 AC_DEFUN([LIBCFS_SYSCTL_UNNUMBERED],
  87 [AC_MSG_CHECKING([for CTL_UNNUMBERED])
  88 LB_LINUX_TRY_COMPILE([
  89         #include <linux/sysctl.h>
  90 ],[
  91         #ifndef CTL_UNNUMBERED
  92         #error CTL_UNNUMBERED not exist in kernel
  93         #endif
  94 ],[
  95         AC_MSG_RESULT(yes)
  96         AC_DEFINE(HAVE_SYSCTL_UNNUMBERED, 1,
  97                   [sysctl has CTL_UNNUMBERED])
  98 ],[
  99         AC_MSG_RESULT(NO)
 100 ])
 101 ])
 102
 103 #
 104 # LIBCFS_STACKTRACE_OPS_HAVE_WALK_STACK
 105 #
 106 # 2.6.32-30.el6 adds a new 'walk_stack' field in 'struct stacktrace_ops'
 107 #
 108 AC_DEFUN([LIBCFS_STACKTRACE_OPS_HAVE_WALK_STACK],
 109 [AC_MSG_CHECKING([if 'struct stacktrace_ops' has 'walk_stack' field])
 110 LB_LINUX_TRY_COMPILE([
 111         #include <asm/stacktrace.h>
 112 ],[
 113         ((struct stacktrace_ops *)0)->walk_stack(NULL, NULL, 0, NULL, NULL, NULL, NULL);
 114 ],[
 115         AC_MSG_RESULT([yes])
 116         AC_DEFINE(STACKTRACE_OPS_HAVE_WALK_STACK, 1, ['struct stacktrace_ops' has 'walk_stack' field])
 117 ],[
 118         AC_MSG_RESULT([no])
 119 ])
 120 ])
 121
 122 #
 123 # RHEL6/2.6.32 want to have pointer to shrinker self pointer in handler function
 124 #
 125 AC_DEFUN([LC_SHRINKER_WANT_SHRINK_PTR],
 126 [AC_MSG_CHECKING([shrinker want self pointer in handler])
 127 LB_LINUX_TRY_COMPILE([
 128         #include <linux/mm.h>
 129 ],[
 130         struct shrinker *tmp = NULL;
 131         tmp->shrink(tmp, 0, 0);
 132 ],[
 133         AC_MSG_RESULT(yes)
 134         AC_DEFINE(HAVE_SHRINKER_WANT_SHRINK_PTR, 1,
 135                   [shrinker want self pointer in handler])
 136 ],[
 137         AC_MSG_RESULT(no)
 138 ])
 139 ])
 140
 141 #
 142 # 2.6.33 no longer has ctl_name & strategy field in struct ctl_table.
 143 #
 144 AC_DEFUN([LIBCFS_SYSCTL_CTLNAME],
 145 [AC_MSG_CHECKING([if ctl_table has a ctl_name field])
 146 LB_LINUX_TRY_COMPILE([
 147         #include <linux/sysctl.h>
 148 ],[
 149         struct ctl_table ct;
 150         ct.ctl_name = sizeof(ct);
 151 ],[
 152         AC_MSG_RESULT(yes)
 153         AC_DEFINE(HAVE_SYSCTL_CTLNAME, 1,
 154                   [ctl_table has ctl_name field])
 155 ],[
 156         AC_MSG_RESULT(no)
 157 ])
 158 ])
 159
 160 #
 161 # LIBCFS_ADD_WAIT_QUEUE_EXCLUSIVE
 162 #
 163 # 2.6.34 adds __add_wait_queue_exclusive
 164 #
 165 AC_DEFUN([LIBCFS_ADD_WAIT_QUEUE_EXCLUSIVE],
 166 [AC_MSG_CHECKING([if __add_wait_queue_exclusive exists])
 167 LB_LINUX_TRY_COMPILE([
 168         #include <linux/wait.h>
 169 ],[
 170         wait_queue_head_t queue;
 171         wait_queue_t      wait;
 172
 173         __add_wait_queue_exclusive(&queue, &wait);
 174 ],[
 175         AC_MSG_RESULT(yes)
 176         AC_DEFINE(HAVE___ADD_WAIT_QUEUE_EXCLUSIVE, 1,
 177                   [__add_wait_queue_exclusive exists])
 178 ],[
 179         AC_MSG_RESULT(no)
 180 ])
 181 ])
 182
 183 #
 184 # 2.6.35 kernel has sk_sleep function
 185 #
 186 AC_DEFUN([LC_SK_SLEEP],
 187 [AC_MSG_CHECKING([if kernel has sk_sleep])
 188 LB_LINUX_TRY_COMPILE([
 189         #include <net/sock.h>
 190 ],[
 191         sk_sleep(NULL);
 192 ],[
 193         AC_MSG_RESULT(yes)
 194         AC_DEFINE(HAVE_SK_SLEEP, 1, [kernel has sk_sleep])
 195 ],[
 196         AC_MSG_RESULT(no)
 197 ],[
 198 ])
 199 ])
 200
 201 # 2.6.39 adds a base pointer address argument to dump_trace
 202 AC_DEFUN([LIBCFS_DUMP_TRACE_ADDRESS],
 203 [AC_MSG_CHECKING([dump_trace want address])
 204 LB_LINUX_TRY_COMPILE([
 205         struct task_struct;
 206         struct pt_regs;
 207         #include <asm/stacktrace.h>
 208 ],[
 209         dump_trace(NULL, NULL, NULL, 0, NULL, NULL);
 210 ],[
 211         AC_MSG_RESULT(yes)
 212         AC_DEFINE(HAVE_DUMP_TRACE_ADDRESS, 1,
 213                 [dump_trace want address argument])
 214 ],[
 215         AC_MSG_RESULT(no)
 216 ],[
 217 ])
 218 ])
 219
 220 #
 221 # FC15 2.6.40-5 backported the "shrink_control" parameter to the memory
 222 # pressure shrinker from Linux 3.0
 223 #
 224 AC_DEFUN([LC_SHRINK_CONTROL],
 225 [AC_MSG_CHECKING([shrink_control is present])
 226 LB_LINUX_TRY_COMPILE([
 227         #include <linux/mm.h>
 228 ],[
 229         struct shrink_control tmp = {0};
 230         tmp.nr_to_scan = sizeof(tmp);
 231 ],[
 232         AC_MSG_RESULT(yes)
 233         AC_DEFINE(HAVE_SHRINK_CONTROL, 1,
 234                   [shrink_control is present])
 235 ],[
 236         AC_MSG_RESULT(no)
 237 ])
 238 ])
 239
 240 # 3.0 removes stacktrace_ops warning* functions
 241 AC_DEFUN([LIBCFS_STACKTRACE_WARNING],
 242 [AC_MSG_CHECKING([whether stacktrace_ops.warning is exist])
 243 LB_LINUX_TRY_COMPILE([
 244         struct task_struct;
 245         struct pt_regs;
 246         #include <asm/stacktrace.h>
 247 ],[
 248         ((struct stacktrace_ops *)0)->warning(NULL, NULL);
 249 ],[
 250         AC_MSG_RESULT(yes)
 251         AC_DEFINE(HAVE_STACKTRACE_WARNING, 1, [stacktrace_ops.warning is exist])
 252 ],[
 253         AC_MSG_RESULT(no)
 254 ],[
 255 ])
 256 ])
 257
 258 #
 259 # FC18 3.7.2-201 unexport sock_map_fd() change to
 260 # use sock_alloc_file().
 261 # upstream commit 56b31d1c9f1e6a3ad92e7bfe252721e05d92b285
 262 #
 263 AC_DEFUN([LIBCFS_SOCK_ALLOC_FILE],
 264 [AC_MSG_CHECKING([sock_alloc_file is exported])
 265 LB_CHECK_SYMBOL_EXPORT([sock_alloc_file], [net/socket.c],[
 266         LB_LINUX_TRY_COMPILE([
 267                 #include <linux/net.h>
 268         ],[
 269                 sock_alloc_file(NULL, 0, NULL);
 270         ],[
 271                 AC_MSG_RESULT(yes)
 272                 AC_DEFINE(HAVE_SOCK_ALLOC_FILE_3ARGS, 1,
 273                         [sock_alloc_file takes 3 arguments])
 274         ],[
 275                 AC_MSG_RESULT(yes)
 276                 AC_DEFINE(HAVE_SOCK_ALLOC_FILE, 1,
 277                         [sock_alloc_file is exported])
 278         ])
 279 ],[
 280 ])
 281 ])
 282
 283 AC_DEFUN([LIBCFS_HAVE_CRC32],
 284 [LB_LINUX_CONFIG_IM([CRC32],
 285         [have_crc32=true],[have_crc32=false])
 286 if test x$have_crc32 = xtrue; then
 287         AC_DEFINE(HAVE_CRC32, 1, [kernel compiled with CRC32 functions])
 288 fi
 289 ])
 290
 291 AC_DEFUN([LIBCFS_ENABLE_CRC32_ACCEL],
 292 [LB_LINUX_CONFIG_IM([CRYPTO_CRC32_PCLMUL],
 293         [enable_crc32_crypto=false],[enable_crc32_crypto=true])
 294 if test x$have_crc32 = xtrue -a x$enable_crc32_crypto = xtrue; then
 295         AC_DEFINE(NEED_CRC32_ACCEL, 1, [need pclmulqdq based crc32])
 296         AC_MSG_WARN([No crc32 pclmulqdq crypto api found,
 297                     enable internal pclmulqdq based crc32])
 298 fi
 299 ])
 300
 301 AC_DEFUN([LIBCFS_ENABLE_CRC32C_ACCEL],
 302 [LB_LINUX_CONFIG_IM([CRYPTO_CRC32C_INTEL],
 303         [enable_crc32c_crypto=false],[enable_crc32c_crypto=true])
 304 if test x$enable_crc32c_crypto = xtrue; then
 305         AC_DEFINE(NEED_CRC32C_ACCEL, 1, [need pclmulqdq based crc32c])
 306         AC_MSG_WARN([No crc32c pclmulqdq crypto api found,
 307                     enable internal pclmulqdq based crc32c])
 308 fi
 309 ])
 310
 311 #
 312 # LIBCFS_PROG_LINUX
 313 #
 314 # LNet linux kernel checks
 315 #
 316 AC_DEFUN([LIBCFS_PROG_LINUX],
 317 [
 318 LIBCFS_CONFIG_PANIC_DUMPLOG
 319
 320 LIBCFS_U64_LONG_LONG_LINUX
 321 # 2.6.24
 322 LIBCFS_SYSCTL_UNNUMBERED
 323 # 2.6.32
 324 LIBCFS_STACKTRACE_OPS_HAVE_WALK_STACK
 325 LC_SHRINKER_WANT_SHRINK_PTR
 326 # 2.6.33
 327 LIBCFS_SYSCTL_CTLNAME
 328 # 2.6.34
 329 LIBCFS_ADD_WAIT_QUEUE_EXCLUSIVE
 330 # 2.6.35
 331 LC_SK_SLEEP
 332 # 2.6.39
 333 LIBCFS_DUMP_TRACE_ADDRESS
 334 # 2.6.40 fc15
 335 LC_SHRINK_CONTROL
 336 # 3.0
 337 LIBCFS_STACKTRACE_WARNING
 338 # 3.7
 339 LIBCFS_SOCK_ALLOC_FILE
 340 # 3.8
 341 LIBCFS_HAVE_CRC32
 342 LIBCFS_ENABLE_CRC32_ACCEL
 343 # 3.10
 344 LIBCFS_ENABLE_CRC32C_ACCEL
 345 ])
 346
 347 #
 348 # LIBCFS_PROG_DARWIN
 349 #
 350 # Darwin checks
 351 #
 352 AC_DEFUN([LIBCFS_PROG_DARWIN],
 353 [LB_DARWIN_CHECK_FUNCS([get_preemption_level])
 354 ])
 355
 356 #
 357 # LIBCFS_PATH_DEFAULTS
 358 #
 359 # default paths for installed files
 360 #
 361 AC_DEFUN([LIBCFS_PATH_DEFAULTS],
 362 [
 363 ])
 364
 365 #
 366 # LIBCFS_CONFIGURE
 367 #
 368 # other configure checks
 369 #
 370 AC_DEFUN([LIBCFS_CONFIGURE],
 371 [# lnet/utils/portals.c
 372 AC_CHECK_HEADERS([asm/types.h endian.h sys/ioctl.h])
 373
 374 # lnet/utils/debug.c
 375 AC_CHECK_HEADERS([linux/version.h])
 376
 377 AC_CHECK_TYPE([spinlock_t],
 378         [AC_DEFINE(HAVE_SPINLOCK_T, 1, [spinlock_t is defined])],
 379         [],
 380         [#include <linux/spinlock.h>])
 381
 382 # lnet/utils/wirecheck.c
 383 AC_CHECK_FUNCS([strnlen])
 384
 385 # lnet/libcfs/user-prim.c, missing for RHEL5 and earlier userspace
 386 AC_CHECK_FUNCS([strlcpy])
 387
 388 # libcfs/libcfs/user-prim.c, missing for RHEL5 and earlier userspace
 389 AC_CHECK_FUNCS([strlcat])
 390
 391 AC_CHECK_TYPE([umode_t],
 392         [AC_DEFINE(HAVE_UMODE_T, 1, [umode_t is defined])],
 393         [],
 394         [#include <asm/types.h>])
 395
 396 AC_CHECK_TYPE([__s8],
 397         [AC_DEFINE(HAVE___S8, 1, [__s8 is defined])],
 398         [],
 399         [#include <asm/types.h>])
 400
 401 AC_CHECK_TYPE([__u8],
 402         [AC_DEFINE(HAVE___U8, 1, [__u8 is defined])],
 403         [],
 404         [#include <asm/types.h>])
 405
 406 AC_CHECK_TYPE([__s16],
 407         [AC_DEFINE(HAVE___S16, 1, [__s16 is defined])],
 408         [],
 409         [#include <asm/types.h>])
 410
 411 AC_CHECK_TYPE([__u16],
 412         [AC_DEFINE(HAVE___U16, 1, [__u16 is defined])],
 413         [],
 414         [#include <asm/types.h>])
 415
 416 AC_CHECK_TYPE([__s32],
 417         [AC_DEFINE(HAVE___S32, 1, [__s32 is defined])],
 418         [],
 419         [#include <asm/types.h>])
 420
 421 AC_CHECK_TYPE([__u32],
 422         [AC_DEFINE(HAVE___U32, 1, [__u32 is defined])],
 423         [],
 424         [#include <asm/types.h>])
 425
 426 AC_CHECK_TYPE([__u64],
 427         [AC_DEFINE(HAVE___U64, 1, [__u64 is defined])],
 428         [],
 429         [#include <asm/types.h>])
 430
 431 AC_CHECK_TYPE([__s64],
 432         [AC_DEFINE(HAVE___S64, 1, [__s64 is defined])],
 433         [],
 434         [#include <asm/types.h>])
 435
 436 # check userland __u64 type
 437 AC_MSG_CHECKING([userspace __u64 is long long type])
 438 tmp_flags="$CFLAGS"
 439 CFLAGS="$CFLAGS -Werror"
 440 AC_COMPILE_IFELSE([
 441         #include <stdio.h>
 442         #include <linux/types.h>
 443         #include <linux/stddef.h>
 444         int main(void) {
 445                 unsigned long long *data1;
 446                 __u64 *data2 = NULL;
 447
 448                 data1 = data2;
 449                 data2 = data1;
 450                 return 0;
 451         }
 452 ],[
 453         AC_MSG_RESULT([yes])
 454         AC_DEFINE(HAVE_USER__U64_LONG_LONG, 1,
 455                   [__u64 is long long type])
 456 ],[
 457         AC_MSG_RESULT([no])
 458 ])
 459 CFLAGS="$tmp_flags"
 460
 461 # --------  Check for required packages  --------------
 462
 463
 464 AC_MSG_CHECKING([if efence debugging support is requested])
 465 AC_ARG_ENABLE(efence,
 466         AC_HELP_STRING([--enable-efence],
 467                         [use efence library]),
 468         [],[enable_efence='no'])
 469 AC_MSG_RESULT([$enable_efence])
 470 if test "$enable_efence" = "yes" ; then
 471         LIBEFENCE="-lefence"
 472         AC_DEFINE(HAVE_LIBEFENCE, 1, [libefence support is requested])
 473 else
 474         LIBEFENCE=""
 475 fi
 476 AC_SUBST(LIBEFENCE)
 477
 478
 479 # -------- check for -lpthread support ----
 480 AC_MSG_CHECKING([whether to use libpthread for libcfs library])
 481 AC_ARG_ENABLE([libpthread],
 482         AC_HELP_STRING([--disable-libpthread],
 483                 [disable libpthread]),
 484         [],[enable_libpthread=yes])
 485 if test "$enable_libpthread" = "yes" ; then
 486         AC_CHECK_LIB([pthread], [pthread_create],
 487                 [ENABLE_LIBPTHREAD="yes"],
 488                 [ENABLE_LIBPTHREAD="no"])
 489         if test "$ENABLE_LIBPTHREAD" = "yes" ; then
 490                 AC_MSG_RESULT([$ENABLE_LIBPTHREAD])
 491                 PTHREAD_LIBS="-lpthread"
 492                 AC_DEFINE([HAVE_LIBPTHREAD], 1, [use libpthread])
 493         else
 494                 PTHREAD_LIBS=""
 495                 AC_MSG_RESULT([no libpthread is found])
 496         fi
 497         AC_SUBST(PTHREAD_LIBS)
 498 else
 499         AC_MSG_RESULT([no (disabled explicitly)])
 500         ENABLE_LIBPTHREAD="no"
 501 fi
 502 AC_SUBST(ENABLE_LIBPTHREAD)
 503
 504
 505 ])
 506
 507 #
 508 # LIBCFS_CONDITIONALS
 509 #
 510 # AM_CONDITOINAL defines for lnet
 511 #
 512 AC_DEFUN([LIBCFS_CONDITIONALS],
 513 [
 514 AM_CONDITIONAL(HAVE_CRC32, test x$have_crc32 = xtrue)
 515 AM_CONDITIONAL(NEED_PCLMULQDQ_CRC32,  test x$have_crc32 = xtrue -a x$enable_crc32_crypto = xtrue)
 516 AM_CONDITIONAL(NEED_PCLMULQDQ_CRC32C, test x$enable_crc32c_crypto = xtrue)
 517 ])
 518
 519 #
 520 # LIBCFS_CONFIG_FILES
 521 #
 522 # files that should be generated with AC_OUTPUT
 523 #
 524 AC_DEFUN([LIBCFS_CONFIG_FILES],
 525 [AC_CONFIG_FILES([
 526 libcfs/Kernelenv
 527 libcfs/Makefile
 528 libcfs/autoMakefile
 529 libcfs/autoconf/Makefile
 530 libcfs/include/Makefile
 531 libcfs/include/libcfs/Makefile
 532 libcfs/include/libcfs/linux/Makefile
 533 libcfs/include/libcfs/posix/Makefile
 534 libcfs/include/libcfs/util/Makefile
 535 libcfs/libcfs/Makefile
 536 libcfs/libcfs/autoMakefile
 537 libcfs/libcfs/linux/Makefile
 538 libcfs/libcfs/posix/Makefile
 539 libcfs/libcfs/util/Makefile
 540 libcfs/include/libcfs/darwin/Makefile
 541 libcfs/libcfs/darwin/Makefile
 542 ])
 543 ])