config/lustre-build.m4

   1 #
   2 # LB_CHECK_VERSION
   3 #
   4 # Verify that LUSTRE_VERSION was defined properly
   5 #
   6 AC_DEFUN([LB_CHECK_VERSION], [
   7 AS_IF([test "LUSTRE_VERSION" = "LUSTRE""_VERSION"],
   8         [AC_MSG_ERROR([This script was not built with a version number.])])
   9 ]) # LB_CHECK_VERSION
  10
  11 #
  12 # LB_CANONICAL_SYSTEM
  13 #
  14 # fixup $target_os for use in other places
  15 #
  16 AC_DEFUN([LB_CANONICAL_SYSTEM], [
  17 case $target_os in
  18         linux*)
  19                 lb_target_os="linux"
  20                 ;;
  21 esac
  22 AC_SUBST(lb_target_os)
  23 ]) # LB_CANONICAL_SYSTEM
  24
  25 #
  26 # LB_DOWNSTREAM_RELEASE
  27 #
  28 AC_DEFUN([LB_DOWNSTREAM_RELEASE],
  29 [AC_ARG_WITH([downstream-release],
  30         AC_HELP_STRING([--with-downstream-release=string],
  31                 [set a string in the BUILD_VERSION and RPM Release: (default is nothing)]),
  32         [DOWNSTREAM_RELEASE=$with_downstream_release],
  33         [ # if not specified, see if it's in the META file
  34         AS_IF([test -f META],
  35                 [DOWNSTREAM_RELEASE=$(sed -ne '/^LOCAL_VERSION =/s/.*= *//p' META)])
  36         ])
  37 AC_SUBST(DOWNSTREAM_RELEASE)
  38 ]) # LB_DOWNSTREAM_RELEASE
  39
  40 #
  41 # LB_BUILDID
  42 #
  43 # Check if the source is a GA release and if not, set a "BUILDID"
  44 #
  45 # Currently there are at least two ways/modes of/for doing this.  One
  46 # is if we are in a valid git repository, the other is if we are in a
  47 # non-git source tree of some form.  Building the latter from the former
  48 # will be handled here.
  49 AC_DEFUN([LB_BUILDID], [
  50 AC_CACHE_CHECK([for buildid], [lb_cv_buildid], [
  51 lb_cv_buildid=""
  52 AS_IF([git branch >/dev/null 2>&1], [
  53         ffw=0
  54         hash=""
  55         ver=$(git describe --match v[[0-9]]_*_[[0-9]]* --tags)
  56         if [[[ $ver = *-*-* ]]]; then
  57                 hash=${ver##*-}
  58                 ffw=${ver#*-}
  59                 ffw=${ffw%-*}
  60                 ver=${ver%%-*}
  61         fi
  62         # it's tempting to use [[ $ver =~ ^v([0-9]+_)+([0-9]+|RC[0-9]+)$ ]]
  63         # here but the portability of the regex on the right is dismal
  64         # (thanx suse)
  65         if echo "$ver" | egrep -q "^v([[0-9]]+_)+([[0-9]]+|RC[[0-9]]+)$"; then
  66                 ver=$(echo $ver | sed -e 's/^v\(.*\)/\1/' \
  67                                       -e 's/_RC[[0-9]].*$//' -e 's/_/./g')
  68         fi
  69
  70         # a "lustre fix" value of .0 should be truncated
  71         if [[[ $ver = *.*.*.0 ]]]; then
  72                 ver=${ver%.0}
  73         fi
  74         # ditto for a "lustre fix" value of _0
  75         if [[[ $ver = v*_*_*_0 ]]]; then
  76                 ver=${ver%_0}
  77         fi
  78         if [[[ $ver = v*_*_* ]]]; then
  79                 ver=${ver#v}
  80                 ver=${ver//_/.}
  81         fi
  82
  83         if test "$ver" != "$VERSION"; then
  84                 AC_MSG_WARN([most recent tag found: $ver does not match current version $VERSION.])
  85         fi
  86
  87         if test "$ffw" != "0"; then
  88                 lb_cv_buildid="$hash"
  89         fi
  90 ], [test -f META], [
  91         lb_cv_buildid=$(sed -ne '/^BUILDID =/s/.*= *//p' META)
  92 ])
  93 ])
  94 AS_IF([test -z "$lb_cv_buildid"], [
  95         AC_MSG_WARN([
  96
  97 FIXME: I don't know how to deal with source trees outside of git that
  98 don't have a META file. Not setting a buildid.
  99 ])
 100 ])
 101 BUILDID=$lb_cv_buildid
 102 AC_SUBST(BUILDID)
 103 ]) # LB_BUILDID
 104
 105 #
 106 # LB_CHECK_FILE
 107 #
 108 # Check for file existence even when cross compiling
 109 # $1 - file to check
 110 # $2 - do 'yes'
 111 # $3 - do 'no'
 112 #
 113 AC_DEFUN([LB_CHECK_FILE], [
 114 AS_VAR_PUSHDEF([lb_file], [lb_cv_file_$1])dnl
 115 AC_CACHE_CHECK([for $1], lb_file, [
 116 AS_IF([test -r "$1"],
 117         [AS_VAR_SET(lb_file, [yes])],
 118         [AS_VAR_SET(lb_file, [no])])
 119 ])
 120 AS_VAR_IF([lb_file], [yes], [$2], [$3])[]dnl
 121 AS_VAR_POPDEF([lb_file])dnl
 122 ]) # LB_CHECK_FILE
 123
 124 #
 125 # LB_ARG_LIBS_INCLUDES
 126 #
 127 # support for --with-foo, --with-foo-includes, and --with-foo-libs in
 128 # a single magical macro
 129 #
 130 AC_DEFUN([LB_ARG_LIBS_INCLUDES], [
 131 lb_pathvar="m4_bpatsubst([$2], -, _)"
 132 AC_MSG_CHECKING([for $1])
 133 AC_ARG_WITH([$2],
 134         AC_HELP_STRING([--with-$2=path],
 135                 [path to $1]),
 136         [], [withval=$4])
 137 AS_IF([test "x$withval" = xyes],
 138         [eval "$lb_pathvar='$3'"],
 139         [eval "$lb_pathvar='$withval'"])
 140 AC_MSG_RESULT([${!lb_pathvar:-no}])
 141
 142 AS_IF([test "x${!lb_pathvar}" != x -a "x${!lb_pathvar}" != xno], [
 143         AC_MSG_CHECKING([for $1 includes])
 144         AC_ARG_WITH([$2-includes],
 145                 AC_HELP_STRING([--with-$2-includes=path],
 146                         [path to $1 includes]),
 147                 [], [withval="yes"])
 148
 149         lb_includevar="${lb_pathvar}_includes"
 150         AS_IF([test "x$withval" = xyes],
 151                 [eval "${lb_includevar}='${!lb_pathvar}/include'"],
 152                 [eval "${lb_includevar}='$withval'"])
 153         AC_MSG_RESULT([${!lb_includevar}])
 154
 155         AC_MSG_CHECKING([for $1 libs])
 156         AC_ARG_WITH([$2-libs],
 157                 AC_HELP_STRING([--with-$2-libs=path],
 158                         [path to $1 libs]),
 159                 [], [withval="yes"])
 160
 161         lb_libvar="${lb_pathvar}_libs"
 162         AS_IF([test "x$withval" = xyes],
 163                 [eval "${lb_libvar}='${!lb_pathvar}/lib'"],
 164                 [eval "${lb_libvar}='$withval'"])
 165         AC_MSG_RESULT([${!lb_libvar}])
 166 ])
 167 ]) # LB_ARG_LIBS_INCLUDES
 168
 169 #
 170 # LB_PATH_LUSTREIOKIT
 171 #
 172 # We no longer handle external lustre-iokit
 173 #
 174 AC_DEFUN([LB_PATH_LUSTREIOKIT], [
 175 AC_MSG_CHECKING([whether to build iokit])
 176 AC_ARG_ENABLE([iokit],
 177         AC_HELP_STRING([--disable-iokit],
 178                 [disable iokit (default is enable)]),
 179         [], [enable_iokit="yes"])
 180 AC_MSG_RESULT([$enable_iokit])
 181 AS_IF([test "x$enable_iokit" = xyes],
 182         [LUSTREIOKIT_SUBDIR="lustre-iokit"],
 183         [LUSTREIOKIT_SUBDIR=""])
 184 AC_SUBST(LUSTREIOKIT_SUBDIR)
 185 AM_CONDITIONAL([BUILD_LUSTREIOKIT], [test "x$enable_iokit" = xyes])
 186 ]) # LB_PATH_LUSTREIOKIT
 187
 188 # Define no libcfs by default.
 189 AC_DEFUN([LB_LIBCFS_DIR], [
 190 AS_IF([test "x$libcfs_is_module" = xyes], [
 191                 LIBCFS_INCLUDE_DIR="libcfs/include"
 192                 LIBCFS_SUBDIR="libcfs"
 193         ], [
 194                 LIBCFS_INCLUDE_DIR="lnet/include"
 195                 LIBCFS_SUBDIR=""
 196         ])
 197 AC_SUBST(LIBCFS_INCLUDE_DIR)
 198 AC_SUBST(LIBCFS_SUBDIR)
 199 ]) # LB_LIBCFS_DIR
 200
 201 #
 202 # LB_PATH_SNMP
 203 #
 204 # check for in-tree snmp support
 205 #
 206 AC_DEFUN([LB_PATH_SNMP], [
 207 LB_CHECK_FILE([$srcdir/snmp/lustre-snmp.c], [SNMP_DIST_SUBDIR="snmp"])
 208 AC_SUBST(SNMP_DIST_SUBDIR)
 209 AC_SUBST(SNMP_SUBDIR)
 210 ]) # LB_PATH_SNMP
 211
 212 #
 213 # LB_CONFIG_MODULES
 214 #
 215 # Build kernel modules?
 216 #
 217 AC_DEFUN([LB_CONFIG_MODULES], [
 218 AC_MSG_CHECKING([whether to build Linux kernel modules])
 219 AC_ARG_ENABLE([modules],
 220         AC_HELP_STRING([--disable-modules],
 221                 [disable building of Lustre kernel modules]),
 222         [], [
 223                 LC_TARGET_SUPPORTED([enable_modules="yes"],
 224                                     [enable_modules="no"])
 225         ])
 226 AC_MSG_RESULT([$enable_modules ($target_os)])
 227
 228 AS_IF([test "x$enable_modules" = xyes], [
 229         AS_CASE([$target_os],
 230                 [linux*], [
 231                         LB_PROG_LINUX
 232                         LIBCFS_PROG_LINUX
 233                         LN_PROG_LINUX
 234                         AS_IF([test "x$enable_server" != xno], [LB_EXT4_SRC_DIR])
 235                         LC_PROG_LINUX
 236                 ], [*], [
 237                         # This is strange - Lustre supports a target we don't
 238                         AC_MSG_ERROR([Modules are not supported on $target_os])
 239                 ])
 240         ])
 241 ]) # LB_CONFIG_MODULES
 242
 243 #
 244 # LB_CONFIG_UTILS
 245 #
 246 # Build utils?
 247 #
 248 AC_DEFUN([LB_CONFIG_UTILS], [
 249 AC_MSG_CHECKING([whether to build Lustre utilities])
 250 AC_ARG_ENABLE([utils],
 251         AC_HELP_STRING([--disable-utils],
 252                 [disable building of Lustre utility programs]),
 253         [], [enable_utils="yes"])
 254 AC_MSG_RESULT([$enable_utils])
 255 ]) # LB_CONFIG_UTILS
 256
 257 #
 258 # LB_CONFIG_TESTS
 259 #
 260 # Build tests?
 261 #
 262 AC_DEFUN([LB_CONFIG_TESTS], [
 263 AC_MSG_CHECKING([whether to build Lustre tests])
 264 AC_ARG_ENABLE([tests],
 265         AC_HELP_STRING([--disable-tests],
 266                 [disable building of Lustre tests]),
 267         [], [enable_tests="yes"])
 268 AC_MSG_RESULT([$enable_tests])
 269 ]) # LB_CONFIG_TESTS
 270
 271 #
 272 # LB_CONFIG_DIST
 273 #
 274 # Just enough configure so that "make dist" is useful
 275 #
 276 # this simply re-adjusts some defaults, which of course can be overridden
 277 # on the configure line after the --for-dist option
 278 #
 279 AC_DEFUN([LB_CONFIG_DIST], [
 280 AC_MSG_CHECKING([whether to configure just enough for make dist])
 281 AC_ARG_ENABLE([dist],
 282         AC_HELP_STRING([--enable-dist],
 283                         [only configure enough for make dist]),
 284         [], [enable_dist="no"])
 285 AC_MSG_RESULT([$enable_dist])
 286 AS_IF([test "x$enable_dist" != xno], [
 287         enable_doc="no"
 288         enable_utils="no"
 289         enable_tests="no"
 290         enable_modules="no"
 291 ])
 292 ]) # LB_CONFIG_DIST
 293
 294 #
 295 # LB_CONFIG_DOCS
 296 #
 297 # Build docs?
 298 #
 299 AC_DEFUN([LB_CONFIG_DOCS], [
 300 AC_MSG_CHECKING([whether to build Lustre docs])
 301 AC_ARG_ENABLE([doc],
 302         AC_HELP_STRING([--disable-doc],
 303                         [skip creation of pdf documentation]),
 304         [], [enable_doc="no"])
 305 AC_MSG_RESULT([$enable_doc])
 306 AS_IF([test "x$enable_doc" = xyes],
 307         [ENABLE_DOC=1], [ENABLE_DOC=0])
 308 AC_SUBST(ENABLE_DOC)
 309 ]) # LB_CONFIG_DOCS
 310
 311 #
 312 # LB_CONFIG_HEADERS
 313 #
 314 # add -include config.h
 315 #
 316 AC_DEFUN([LB_CONFIG_HEADERS], [
 317 AC_CONFIG_HEADERS([config.h])
 318 CPPFLAGS="-include $PWD/config.h $CPPFLAGS"
 319 EXTRA_KCFLAGS="-include $PWD/config.h $EXTRA_KCFLAGS"
 320 AC_SUBST(EXTRA_KCFLAGS)
 321 ]) # LB_CONFIG_HEADERS
 322
 323 #
 324 # LB_INCLUDE_RULES
 325 #
 326 # defines for including the toplevel Rules
 327 #
 328 AC_DEFUN([LB_INCLUDE_RULES], [
 329 INCLUDE_RULES="include $PWD/Rules"
 330 AC_SUBST(INCLUDE_RULES)
 331 ]) # LB_INCLUDE_RULES
 332
 333 #
 334 # LB_PATH_DEFAULTS
 335 #
 336 # 'fixup' default paths
 337 #
 338 AC_DEFUN([LB_PATH_DEFAULTS], [
 339 # directories for binaries
 340 AC_PREFIX_DEFAULT([/usr])
 341
 342 sysconfdir='$(CROSS_PATH)/etc'
 343 AC_SUBST(sysconfdir)
 344
 345 # Directories for documentation and demos.
 346 docdir='$(datadir)/doc/$(PACKAGE)'
 347 AC_SUBST(docdir)
 348
 349 LIBCFS_PATH_DEFAULTS
 350 LN_PATH_DEFAULTS
 351 LC_PATH_DEFAULTS
 352 ]) # LB_PATH_DEFAULTS
 353
 354 #
 355 # LB_PROG_CC
 356 #
 357 # checks on the C compiler
 358 #
 359 AC_DEFUN([LB_PROG_CC], [
 360 AC_PROG_RANLIB
 361 AC_CHECK_TOOL(LD, [ld], [no])
 362 AC_CHECK_TOOL(OBJDUMP, [objdump], [no])
 363 AC_CHECK_TOOL(STRIP, [strip], [no])
 364
 365 # ---------  unsigned long long sane? -------
 366 AC_CHECK_SIZEOF(unsigned long long, 0)
 367 AS_IF([test $ac_cv_sizeof_unsigned_long_long != 8],
 368         [AC_MSG_ERROR([we assume that sizeof(unsigned long long) == 8.])])
 369
 370 AS_IF([test $target_cpu = powerpc64], [
 371         AC_MSG_WARN([set compiler with -m64])
 372         CFLAGS="$CFLAGS -m64"
 373         CC="$CC -m64"
 374 ])
 375
 376 CPPFLAGS="-I$PWD/$LIBCFS_INCLUDE_DIR -I$PWD/lnet/include -I$PWD/lustre/include $CPPFLAGS"
 377
 378 LLCPPFLAGS="-D_LARGEFILE64_SOURCE=1"
 379 AC_SUBST(LLCPPFLAGS)
 380
 381 # Add _GNU_SOURCE for strnlen on linux
 382 LLCFLAGS="-g -Wall -fPIC -D_GNU_SOURCE"
 383 AC_SUBST(LLCFLAGS)
 384
 385 CCASFLAGS="-Wall -fPIC -D_GNU_SOURCE"
 386 AC_SUBST(CCASFLAGS)
 387
 388 # everyone builds against lnet and lustre
 389 EXTRA_KCFLAGS="$EXTRA_KCFLAGS -g -I$PWD/$LIBCFS_INCLUDE_DIR -I$PWD/lnet/include -I$PWD/lustre/include"
 390 AC_SUBST(EXTRA_KCFLAGS)
 391 ]) # LB_PROG_CC
 392
 393 #
 394 # LB_CONDITIONALS
 395 #
 396 # AM_CONDITIONAL instances for everything
 397 # (so that portals/lustre can disable some if needed)
 398 #
 399 AC_DEFUN([LB_CONDITIONALS], [
 400 AM_CONDITIONAL([MODULES], [test x$enable_modules = xyes])
 401 AM_CONDITIONAL([UTILS], [test x$enable_utils = xyes])
 402 AM_CONDITIONAL([TESTS], [test x$enable_tests = xyes])
 403 AM_CONDITIONAL([DOC], [test x$ENABLE_DOC = x1])
 404 AM_CONDITIONAL([LINUX], [test x$lb_target_os = xlinux])
 405 AM_CONDITIONAL([USES_DPKG], [test x$uses_dpkg = xyes])
 406 AM_CONDITIONAL([USE_QUILT], [test x$use_quilt = xyes])
 407 AM_CONDITIONAL([RHEL], [test x$RHEL_KERNEL = xyes])
 408 AM_CONDITIONAL([SUSE], [test x$SUSE_KERNEL = xyes])
 409
 410 # Sanity check for PCLMULQDQ instruction availability
 411 # PCLMULQDQ instruction is a new instruction available beginning with
 412 # the all new Core processor family based on the 32nm microarchitecture
 413 # codename Westmere. So, $target_cpu = x86_64 should have this instruction
 414 # except MIC microarchitecture (k1om).
 415 AM_CONDITIONAL(HAVE_PCLMULQDQ, test x$target_cpu = "xx86_64" -a x$target_vendor != "xk1om")
 416 AS_IF([test x$target_cpu = "xx86_64" -a x$target_vendor != "xk1om"],
 417         [AC_DEFINE(HAVE_PCLMULQDQ, 1, [have PCLMULQDQ instruction])])
 418
 419 LIBCFS_CONDITIONALS
 420 LN_CONDITIONALS
 421 LC_CONDITIONALS
 422 ]) # LB_CONTITIONALS
 423
 424 #
 425 # LB_CONFIG_FILES
 426 #
 427 # build-specific config files
 428 #
 429 AC_DEFUN([LB_CONFIG_FILES], [
 430         AC_CONFIG_FILES([
 431                 Makefile
 432                 autoMakefile]
 433                 config/Makefile
 434                 [Rules:build/Rules.in]
 435                 AC_PACKAGE_TARNAME[.spec]
 436                 AC_PACKAGE_TARNAME[-dkms.spec]
 437                 contrib/Makefile
 438                 contrib/lbuild/Makefile
 439                 contrib/scripts/Makefile
 440                 ldiskfs/Makefile
 441                 ldiskfs/autoMakefile
 442                 lustre-iokit/Makefile
 443                 lustre-iokit/obdfilter-survey/Makefile
 444                 lustre-iokit/ost-survey/Makefile
 445                 lustre-iokit/sgpdd-survey/Makefile
 446                 lustre-iokit/mds-survey/Makefile
 447                 lustre-iokit/ior-survey/Makefile
 448                 lustre-iokit/stats-collect/Makefile
 449         )
 450 ])
 451
 452 #
 453 # LB_CONFIG_SERVERS
 454 #
 455 AC_DEFUN([LB_CONFIG_SERVERS], [
 456 AC_ARG_ENABLE([server],
 457         AC_HELP_STRING([--disable-server],
 458                         [disable Lustre server support]), [
 459                 AS_IF([test x$enable_server != xyes -a x$enable_server != xno],
 460                         [AC_MSG_ERROR([server valid options are "yes" or "no"])])
 461                 AS_IF([test x$enable_server = xyes -a x$enable_dist = xyes],
 462                         [AC_MSG_ERROR([--enable-server cannot be used with --enable-dist])])
 463         ], [
 464                 AS_IF([test x$enable_dist = xyes],
 465                         [enable_server=no], [enable_server=maybe])
 466         ])
 467
 468 # There are at least two good reasons why we should really run
 469 # LB_CONFIG_MODULES elsewhere before the call to LB_CONFIG_SERVERS:
 470 # LB_CONFIG_MODULES needs to be run for client support even when
 471 # servers are disabled, and because module support is actually a
 472 # prerequisite of server support.  However, some things under
 473 # LB_CONFIG_MODULES need us to already have checked for --disable-server,
 474 # before running, so until LB_CONFIG_MODULES can be reorganized, we
 475 # call it here.
 476 LB_CONFIG_MODULES
 477 AS_IF([test x$enable_modules = xno], [enable_server=no])
 478 LB_CONFIG_LDISKFS
 479 LB_CONFIG_ZFS
 480
 481 # If no backends were configured, and the user did not explicitly
 482 # require servers to be enabled, we just disable servers.
 483 AS_IF([test x$enable_ldiskfs = xno -a x$enable_zfs = xno], [
 484         AS_CASE([$enable_server],
 485                 [maybe], [enable_server=no],
 486                 [yes], [AC_MSG_ERROR([cannot enable servers, no backends were configured])])
 487         ], [
 488                 AS_IF([test x$enable_server = xmaybe], [enable_server=yes])
 489         ])
 490
 491 AC_MSG_CHECKING([whether to build Lustre server support])
 492 AC_MSG_RESULT([$enable_server])
 493 AS_IF([test x$enable_server = xyes],
 494         [AC_DEFINE(HAVE_SERVER_SUPPORT, 1, [support server])])
 495 ]) # LB_CONFIG_SERVERS
 496
 497 #
 498 # LB_CONFIG_RPMBUILD_OPTIONS
 499 #
 500 # The purpose of this function is to assemble command line options
 501 # for the rpmbuild command based on the options passed to the configure
 502 # script, and also upon the decisions that configure makes based on
 503 # the tests that it runs.
 504 # These strings can be passed to rpmbuild on the command line
 505 # in the Make targets named "rpms" and "srpm".
 506 #
 507 AC_DEFUN([LB_CONFIG_RPMBUILD_OPTIONS], [
 508 RPMBINARGS=
 509 RPMSRCARGS=
 510 CONFIGURE_ARGS=
 511 eval set -- $ac_configure_args
 512 for arg; do
 513         case $arg in
 514                 --*dir=* ) ;;
 515                 -C | --cache-file=* ) ;;
 516                 --prefix=* | --*-prefix=* ) ;;
 517                 --enable-dist ) ;;
 518                 --with-release=* ) ;;
 519                 --with-kmp-moddir=* ) ;;
 520                 --with-linux=* | --with-linux-obj=* ) ;;
 521                 --enable-ldiskfs | --disable-ldiskfs ) ;;
 522                 --enable-modules | --disable-modules ) ;;
 523                 --enable-server | --disable-server ) ;;
 524                 --enable-tests | --disable-tests ) ;;
 525                 --enable-utils | --disable-utils ) ;;
 526                 --enable-iokit | --disable-iokit ) ;;
 527                 --enable-dlc | --disable-dlc ) ;;
 528                 * ) CONFIGURE_ARGS="$CONFIGURE_ARGS '$arg'" ;;
 529         esac
 530 done
 531 if test -n "$CONFIGURE_ARGS" ; then
 532         RPMBINARGS="$RPMBINARGS --define \"configure_args $CONFIGURE_ARGS\""
 533 fi
 534 if test -n "$LINUX" ; then
 535         RPMBINARGS="$RPMBINARGS --define \"kdir $LINUX\""
 536         if test -n "$LINUX_OBJ" -a "$LINUX_OBJ" != x"$LINUX" ; then
 537                 RPMBINARGS="$RPMBINARGS --define \"kobjdir $LINUX_OBJ\""
 538         fi
 539 fi
 540 if test -n "$KMP_MODDIR" ; then
 541         RPMBINARGS="$RPMBINARGS --define \"kmoddir $KMP_MODDIR\""
 542 fi
 543 if test -n "$CROSS_PATH" ; then
 544         if test x$enable_server = xyes ; then
 545                 echo -e "\n"
 546                 "*** Don't support cross compilation for the Intel(R) Xeon Phi(TM) card.\n"
 547                 exit 1
 548         fi
 549         CROSS_SUFFIX="-mic"
 550         RPMBINARGS="$RPMBINARGS --define \"post_script build/gen_filelist.sh\""
 551         RPMBINARGS="$RPMBINARGS --define \"cross_path $CROSS_PATH\""
 552         RPMBINARGS="$RPMBINARGS --define \"rootdir %{cross_path}\""
 553         RPMBINARGS="$RPMBINARGS --define \"_prefix %{cross_path}/usr\""
 554         RPMBINARGS="$RPMBINARGS --define \"_mandir %{_prefix}/share/man\""
 555         RPMBINARGS="$RPMBINARGS --define \"_sysconfdir %{cross_path}/etc\""
 556         RPMBINARGS="$RPMBINARGS --define \"make_args $CROSS_VARS\""
 557         if test x$CC_TARGET_ARCH = x"x86_64-k1om-linux" ; then
 558                 RPMBINARGS="$RPMBINARGS --define \"cross_requires intel-mic-gpl\""
 559         fi
 560 fi
 561 if test x$enable_modules != xyes ; then
 562         RPMBINARGS="$RPMBINARGS --without lustre_modules"
 563 fi
 564 if test x$enable_tests != xyes ; then
 565         RPMBINARGS="$RPMBINARGS --without lustre_tests"
 566 fi
 567 if test x$enable_utils != xyes ; then
 568         RPMBINARGS="$RPMBINARGS --without lustre_utils"
 569 fi
 570 if test x$enable_server != xyes ; then
 571         RPMBINARGS="$RPMBINARGS --without servers"
 572         if test -n "$CROSS_SUFFIX" ; then
 573                 RPMBINARGS="$RPMBINARGS --define \"lustre_name lustre-client$CROSS_SUFFIX\""
 574         fi
 575 fi
 576 if test x$enable_ldiskfs != xyes ; then
 577         RPMBINARGS="$RPMBINARGS --without ldiskfs"
 578 fi
 579 if test x$enable_zfs = xyes ; then
 580         RPMBINARGS="$RPMBINARGS --with zfs"
 581 fi
 582 if test x$enable_iokit != xyes ; then
 583         RPMBINARGS="$RPMBINARGS --without lustre_iokit"
 584 fi
 585 if test x$USE_DLC = xyes ; then
 586         RPMBINARGS="$RPMBINARGS --with lnet_dlc"
 587 fi
 588
 589 RPMBUILD_BINARY_ARGS=$RPMBINARGS
 590 RPMBUILD_SOURCE_ARGS=$RPMSRCARGS
 591
 592 AC_SUBST(RPMBUILD_BINARY_ARGS)
 593 AC_SUBST(RPMBUILD_SOURCE_ARGS)
 594 ]) # LB_CONFIG_RPMBUILD_OPTIONS
 595
 596 #
 597 # LB_CONFIGURE
 598 #
 599 # main configure steps
 600 #
 601 AC_DEFUN([LB_CONFIGURE], [
 602 AC_MSG_NOTICE([Lustre base checks
 603 ==============================================================================])
 604 LB_CANONICAL_SYSTEM
 605
 606 LB_CONFIG_DIST
 607
 608 LB_DOWNSTREAM_RELEASE
 609 LB_USES_DPKG
 610 LB_BUILDID
 611
 612 LB_LIBCFS_DIR
 613
 614 LB_INCLUDE_RULES
 615
 616 LB_PATH_DEFAULTS
 617
 618 LB_PROG_CC
 619
 620 LC_OSD_ADDON
 621
 622 LB_CONFIG_DOCS
 623 LB_CONFIG_UTILS
 624 LB_CONFIG_TESTS
 625 LC_CONFIG_CLIENT
 626 LB_CONFIG_MPITESTS
 627 LB_CONFIG_SERVERS
 628
 629 AC_CHECK_PROGS(RST2MAN, [rst2man rst2man.py], [])
 630 if test "x$RST2MAN" = "x"; then
 631   AC_MSG_ERROR(
 632     [rst2man is needed to build the man pages. Install python-docutils.])
 633 fi
 634
 635 # Tests depends from utils (multiop from liblustreapi)
 636 AS_IF([test "x$enable_utils" = xno], [enable_tests="no"])
 637
 638 m4_ifdef([LC_NODEMAP_PROC_DEBUG], [LC_NODEMAP_PROC_DEBUG])
 639 LN_CONFIG_CDEBUG
 640 LC_QUOTA
 641
 642 LB_PATH_SNMP
 643 LB_PATH_LUSTREIOKIT
 644
 645 LB_DEFINE_E2FSPROGS_NAMES
 646
 647 LIBCFS_CONFIGURE
 648 LN_CONFIGURE
 649 LC_CONFIGURE
 650 AS_IF([test -n "$SNMP_DIST_SUBDIR"], [LS_CONFIGURE])
 651
 652 LB_CONDITIONALS
 653 LB_CONFIG_HEADERS
 654
 655 LIBCFS_CONFIG_FILES
 656 LB_CONFIG_FILES
 657 LN_CONFIG_FILES
 658 LC_CONFIG_FILES
 659 AS_IF([test -n "$SNMP_DIST_SUBDIR"], [LS_CONFIG_FILES])
 660
 661 AC_SUBST(ac_configure_args)
 662
 663 MOSTLYCLEANFILES='.*.cmd .*.flags *.o *.ko *.mod.c .depend .*.1.* Modules.symvers Module.symvers'
 664 AC_SUBST(MOSTLYCLEANFILES)
 665
 666 LB_CONFIG_RPMBUILD_OPTIONS
 667
 668 AC_OUTPUT
 669
 670 cat <<_ACEOF
 671
 672 CC:            $CC
 673 LD:            $LD
 674 CPPFLAGS:      $CPPFLAGS
 675 LLCPPFLAGS:    $LLCPPFLAGS
 676 CFLAGS:        $CFLAGS
 677 EXTRA_KCFLAGS: $EXTRA_KCFLAGS
 678 LLCFLAGS:      $LLCFLAGS
 679
 680 Type 'make' to build Lustre.
 681 _ACEOF
 682 ]) # LB_CONFIGURE