config/lustre-build.m4

   1 #
   2 # LB_CANONICAL_SYSTEM
   3 #
   4 # fixup $target_os for use in other places
   5 #
   6 AC_DEFUN([LB_CANONICAL_SYSTEM], [
   7 case $target_os in
   8         linux*)
   9                 lb_target_os="linux"
  10                 ;;
  11 esac
  12 AC_SUBST(lb_target_os)
  13 ]) # LB_CANONICAL_SYSTEM
  14
  15 #
  16 # LB_DOWNSTREAM_RELEASE (DEPRECATED)
  17 #
  18 AC_DEFUN([LB_DOWNSTREAM_RELEASE],
  19 [AC_ARG_WITH([downstream-release],,
  20         AC_MSG_ERROR([--downstream-release was deprecated.  Please read Documentation/versioning.txt.])
  21 )]) # LB_DOWNSTREAM_RELEASE
  22
  23 #
  24 # LB_CHECK_FILE
  25 #
  26 # Check for file existence even when cross compiling
  27 # $1 - file to check
  28 # $2 - do 'yes'
  29 # $3 - do 'no'
  30 #
  31 AC_DEFUN([LB_CHECK_FILE], [
  32 AS_VAR_PUSHDEF([lb_file], [lb_cv_file_$1])dnl
  33 AC_CACHE_CHECK([for $1], lb_file, [
  34 AS_IF([test -r "$1"],
  35         [AS_VAR_SET(lb_file, [yes])],
  36         [AS_VAR_SET(lb_file, [no])])
  37 ])
  38 AS_VAR_IF([lb_file], [yes], [$2], [$3])[]dnl
  39 AS_VAR_POPDEF([lb_file])dnl
  40 ]) # LB_CHECK_FILE
  41
  42 #
  43 # LB_ARG_LIBS_INCLUDES
  44 #
  45 # support for --with-foo, --with-foo-includes, and --with-foo-libs in
  46 # a single magical macro
  47 #
  48 AC_DEFUN([LB_ARG_LIBS_INCLUDES], [
  49 lb_pathvar="m4_bpatsubst([$2], -, _)"
  50 AC_MSG_CHECKING([for $1])
  51 AC_ARG_WITH([$2],
  52         AC_HELP_STRING([--with-$2=path],
  53                 [path to $1]),
  54         [], [withval=$4])
  55 AS_IF([test "x$withval" = xyes],
  56         [eval "$lb_pathvar='$3'"],
  57         [eval "$lb_pathvar='$withval'"])
  58 AC_MSG_RESULT([${!lb_pathvar:-no}])
  59
  60 AS_IF([test "x${!lb_pathvar}" != x -a "x${!lb_pathvar}" != xno], [
  61         AC_MSG_CHECKING([for $1 includes])
  62         AC_ARG_WITH([$2-includes],
  63                 AC_HELP_STRING([--with-$2-includes=path],
  64                         [path to $1 includes]),
  65                 [], [withval="yes"])
  66
  67         lb_includevar="${lb_pathvar}_includes"
  68         AS_IF([test "x$withval" = xyes],
  69                 [eval "${lb_includevar}='${!lb_pathvar}/include'"],
  70                 [eval "${lb_includevar}='$withval'"])
  71         AC_MSG_RESULT([${!lb_includevar}])
  72
  73         AC_MSG_CHECKING([for $1 libs])
  74         AC_ARG_WITH([$2-libs],
  75                 AC_HELP_STRING([--with-$2-libs=path],
  76                         [path to $1 libs]),
  77                 [], [withval="yes"])
  78
  79         lb_libvar="${lb_pathvar}_libs"
  80         AS_IF([test "x$withval" = xyes],
  81                 [eval "${lb_libvar}='${!lb_pathvar}/lib'"],
  82                 [eval "${lb_libvar}='$withval'"])
  83         AC_MSG_RESULT([${!lb_libvar}])
  84 ])
  85 ]) # LB_ARG_LIBS_INCLUDES
  86
  87 #
  88 # LB_PATH_LUSTREIOKIT
  89 #
  90 # We no longer handle external lustre-iokit
  91 #
  92 AC_DEFUN([LB_PATH_LUSTREIOKIT], [
  93 AC_MSG_CHECKING([whether to build iokit])
  94 AC_ARG_ENABLE([iokit],
  95         AC_HELP_STRING([--disable-iokit],
  96                 [disable iokit (default is enable)]),
  97         [], [enable_iokit="yes"])
  98 AC_MSG_RESULT([$enable_iokit])
  99 AS_IF([test "x$enable_iokit" = xyes],
 100         [LUSTREIOKIT_SUBDIR="lustre-iokit"],
 101         [LUSTREIOKIT_SUBDIR=""])
 102 AC_SUBST(LUSTREIOKIT_SUBDIR)
 103 AM_CONDITIONAL([BUILD_LUSTREIOKIT], [test "x$enable_iokit" = xyes])
 104 ]) # LB_PATH_LUSTREIOKIT
 105
 106 # Define no libcfs by default.
 107 AC_DEFUN([LB_LIBCFS_DIR], [
 108 AS_IF([test "x$libcfs_is_module" = xyes], [
 109                 LIBCFS_INCLUDE_DIR="libcfs/include"
 110                 LIBCFS_SUBDIR="libcfs"
 111         ], [
 112                 LIBCFS_INCLUDE_DIR="lnet/include"
 113                 LIBCFS_SUBDIR=""
 114         ])
 115 AC_SUBST(LIBCFS_INCLUDE_DIR)
 116 AC_SUBST(LIBCFS_SUBDIR)
 117 ]) # LB_LIBCFS_DIR
 118
 119 #
 120 # LB_LIBMOUNT
 121 #
 122 # Check whether build with libmount for mount.lustre.
 123 # libmount is part of the util-linux since v2.18.
 124 # We need it to manipulate utab file.
 125 #
 126 AC_DEFUN([LB_LIBMOUNT], [
 127 AC_CHECK_HEADER([libmount/libmount.h], [
 128         AC_CHECK_LIB([mount], [mnt_update_set_fs], [
 129                 LDLIBMOUNT="-lmount"
 130                 AC_SUBST(LDLIBMOUNT)
 131                 AC_DEFINE(HAVE_LIBMOUNT, 1, [build with libmount])
 132                 with_libmount="yes"
 133         ],[with_libmount="no"])
 134 ], [with_libmount="no"])
 135 AC_MSG_CHECKING([whether to build with libmount])
 136 AS_IF([test "x$with_libmount" = xyes], [
 137         AC_MSG_RESULT([yes])
 138 ], [
 139         AC_MSG_RESULT([no])
 140 ])
 141 ]) # LB_LIBMOUNT
 142
 143 #
 144 # LB_PATH_SNMP
 145 #
 146 # check for in-tree snmp support
 147 #
 148 AC_DEFUN([LB_PATH_SNMP], [
 149 LB_CHECK_FILE([$srcdir/snmp/lustre-snmp.c], [SNMP_DIST_SUBDIR="snmp"])
 150 AC_SUBST(SNMP_DIST_SUBDIR)
 151 AC_SUBST(SNMP_SUBDIR)
 152 ]) # LB_PATH_SNMP
 153
 154 #
 155 # LB_CONFIG_MODULES
 156 #
 157 # Build kernel modules?
 158 #
 159 AC_DEFUN([LB_CONFIG_MODULES], [
 160 AC_MSG_CHECKING([whether to build Linux kernel modules])
 161 AC_ARG_ENABLE([modules],
 162         AC_HELP_STRING([--disable-modules],
 163                 [disable building of Lustre kernel modules]),
 164         [], [
 165                 LC_TARGET_SUPPORTED([enable_modules="yes"],
 166                                     [enable_modules="no"])
 167         ])
 168 AC_MSG_RESULT([$enable_modules ($target_os)])
 169
 170 AS_IF([test "x$enable_modules" = xyes], [
 171         AS_CASE([$target_os],
 172                 [linux*], [
 173                         LB_PROG_LINUX
 174                         LIBCFS_PROG_LINUX
 175                         LN_PROG_LINUX
 176                         AS_IF([test "x$enable_server" != xno], [LB_EXT4_SRC_DIR])
 177                         LC_PROG_LINUX
 178                 ], [*], [
 179                         # This is strange - Lustre supports a target we don't
 180                         AC_MSG_ERROR([Modules are not supported on $target_os])
 181                 ])
 182         ])
 183 ]) # LB_CONFIG_MODULES
 184
 185 #
 186 # LB_CONFIG_UTILS
 187 #
 188 # Build utils?
 189 #
 190 AC_DEFUN([LB_CONFIG_UTILS], [
 191 AC_MSG_CHECKING([whether to build Lustre utilities])
 192 AC_ARG_ENABLE([utils],
 193         AC_HELP_STRING([--disable-utils],
 194                 [disable building of Lustre utility programs]),
 195         [], [enable_utils="yes"])
 196 AC_MSG_RESULT([$enable_utils])
 197 ]) # LB_CONFIG_UTILS
 198
 199 #
 200 # LB_CONFIG_TESTS
 201 #
 202 # Build tests?
 203 #
 204 AC_DEFUN([LB_CONFIG_TESTS], [
 205 AC_MSG_CHECKING([whether to build Lustre tests])
 206 AC_ARG_ENABLE([tests],
 207         AC_HELP_STRING([--disable-tests],
 208                 [disable building of Lustre tests]),
 209         [], [enable_tests="yes"])
 210 AC_MSG_RESULT([$enable_tests])
 211 ]) # LB_CONFIG_TESTS
 212
 213 #
 214 # LB_CONFIG_DIST
 215 #
 216 # Just enough configure so that "make dist" is useful
 217 #
 218 # this simply re-adjusts some defaults, which of course can be overridden
 219 # on the configure line after the --for-dist option
 220 #
 221 AC_DEFUN([LB_CONFIG_DIST], [
 222 AC_MSG_CHECKING([whether to configure just enough for make dist])
 223 AC_ARG_ENABLE([dist],
 224         AC_HELP_STRING([--enable-dist],
 225                         [only configure enough for make dist]),
 226         [], [enable_dist="no"])
 227 AC_MSG_RESULT([$enable_dist])
 228 AS_IF([test "x$enable_dist" != xno], [
 229         enable_doc="no"
 230         enable_utils="no"
 231         enable_tests="no"
 232         enable_modules="no"
 233 ])
 234 ]) # LB_CONFIG_DIST
 235
 236 #
 237 # LB_CONFIG_DOCS
 238 #
 239 # Build docs?
 240 #
 241 AC_DEFUN([LB_CONFIG_DOCS], [
 242 AC_MSG_CHECKING([whether to build Lustre docs])
 243 AC_ARG_ENABLE([doc],
 244         AC_HELP_STRING([--disable-doc],
 245                         [skip creation of pdf documentation]),
 246         [], [enable_doc="no"])
 247 AC_MSG_RESULT([$enable_doc])
 248 AS_IF([test "x$enable_doc" = xyes],
 249         [ENABLE_DOC=1], [ENABLE_DOC=0])
 250 AC_SUBST(ENABLE_DOC)
 251 ]) # LB_CONFIG_DOCS
 252
 253 #
 254 # LB_CONFIG_MANPAGES
 255 #
 256 # Build manpages?
 257 #
 258 AC_DEFUN([LB_CONFIG_MANPAGES], [
 259 AC_MSG_CHECKING([whether to build Lustre manpages])
 260 AC_ARG_ENABLE([manpages],
 261         AC_HELP_STRING([--disable-manpages],
 262                         [skip creation and inclusion of man pages (default is enable)]),
 263         [], [enable_manpages="yes"])
 264 AC_MSG_RESULT([$enable_manpages])
 265 ]) # LB_CONFIG_MANPAGES
 266
 267 #
 268 # LB_CONFIG_HEADERS
 269 #
 270 # add -include config.h
 271 #
 272 AC_DEFUN([LB_CONFIG_HEADERS], [
 273 AC_CONFIG_HEADERS([config.h])
 274 CPPFLAGS="-include $PWD/undef.h -include $PWD/config.h $CPPFLAGS"
 275 EXTRA_KCFLAGS="-include $PWD/undef.h -include $PWD/config.h $EXTRA_KCFLAGS"
 276 AC_SUBST(EXTRA_KCFLAGS)
 277 ]) # LB_CONFIG_HEADERS
 278
 279 #
 280 # LB_INCLUDE_RULES
 281 #
 282 # defines for including the toplevel Rules
 283 #
 284 AC_DEFUN([LB_INCLUDE_RULES], [
 285 INCLUDE_RULES="include $PWD/Rules"
 286 AC_SUBST(INCLUDE_RULES)
 287 ]) # LB_INCLUDE_RULES
 288
 289 #
 290 # LB_PATH_DEFAULTS
 291 #
 292 # 'fixup' default paths
 293 #
 294 AC_DEFUN([LB_PATH_DEFAULTS], [
 295 # directories for binaries
 296 AC_PREFIX_DEFAULT([/usr])
 297
 298 sysconfdir='/etc'
 299 AC_SUBST(sysconfdir)
 300
 301 # Directories for documentation and demos.
 302 docdir='${datadir}/doc/$(PACKAGE)'
 303 AC_SUBST(docdir)
 304
 305 LIBCFS_PATH_DEFAULTS
 306 LN_PATH_DEFAULTS
 307 LC_PATH_DEFAULTS
 308 ]) # LB_PATH_DEFAULTS
 309
 310 #
 311 # LB_PROG_CC
 312 #
 313 # checks on the C compiler
 314 #
 315 AC_DEFUN([LB_PROG_CC], [
 316 AC_PROG_RANLIB
 317 AC_CHECK_TOOL(LD, [ld], [no])
 318 AC_CHECK_TOOL(OBJDUMP, [objdump], [no])
 319 AC_CHECK_TOOL(STRIP, [strip], [no])
 320
 321 # ---------  unsigned long long sane? -------
 322 AC_CHECK_SIZEOF(unsigned long long, 0)
 323 AS_IF([test $ac_cv_sizeof_unsigned_long_long != 8],
 324         [AC_MSG_ERROR([we assume that sizeof(unsigned long long) == 8.])])
 325
 326 AS_IF([test $target_cpu = powerpc64], [
 327         AC_MSG_WARN([set compiler with -m64])
 328         CFLAGS="$CFLAGS -m64"
 329         CC="$CC -m64"
 330 ])
 331
 332 CPPFLAGS="-I$PWD/$LIBCFS_INCLUDE_DIR -I$PWD/lnet/include -I$PWD/lnet/include/uapi -I$PWD/lustre/include -I$PWD/lustre/include/uapi $CPPFLAGS"
 333
 334 CCASFLAGS="-Wall -fPIC -D_GNU_SOURCE"
 335 AC_SUBST(CCASFLAGS)
 336
 337 # everyone builds against lnet and lustre
 338 EXTRA_KCFLAGS="$EXTRA_KCFLAGS -g -I$PWD/$LIBCFS_INCLUDE_DIR -I$PWD/lnet/include -I$PWD/lustre/include"
 339 AC_SUBST(EXTRA_KCFLAGS)
 340 ]) # LB_PROG_CC
 341
 342 #
 343 # Check if gcc supports -Wno-format-truncation
 344 #
 345 # To supress many warnings with gcc7
 346 #
 347 AC_DEFUN([LB_CC_NO_FORMAT_TRUNCATION], [
 348         AC_MSG_CHECKING([for -Wno-format-truncation support])
 349
 350         saved_flags="$CFLAGS"
 351         CFLAGS="$CFLAGS -Wno-format-truncation"
 352
 353         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [])], [
 354                 EXTRA_KCFLAGS="$EXTRA_KCFLAGS -Wno-format-truncation"
 355                 AC_SUBST(EXTRA_KCFLAGS)
 356                 AC_MSG_RESULT([yes])
 357         ], [
 358                 AC_MSG_RESULT([no])
 359         ])
 360
 361         CFLAGS="$saved_flags"
 362 ])
 363
 364 #
 365 # Check if gcc supports -Wno-stringop-truncation
 366 #
 367 # To supress many warnings with gcc8
 368 #
 369 AC_DEFUN([LB_CC_NO_STRINGOP_TRUNCATION], [
 370         AC_MSG_CHECKING([for -Wno-stringop-truncation support])
 371
 372         saved_flags="$CFLAGS"
 373         CFLAGS="$CFLAGS -Wno-stringop-truncation"
 374
 375         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [])], [
 376                 EXTRA_KCFLAGS="$EXTRA_KCFLAGS -Wno-stringop-truncation"
 377                 AC_SUBST(EXTRA_KCFLAGS)
 378                 AC_MSG_RESULT([yes])
 379         ], [
 380                 AC_MSG_RESULT([no])
 381         ])
 382
 383         CFLAGS="$saved_flags"
 384 ])
 385
 386 #
 387 # Check if gcc supports -Wno-stringop-overflow
 388 #
 389 # To supress many warnings with gcc8
 390 #
 391 AC_DEFUN([LB_CC_NO_STRINGOP_OVERFLOW], [
 392         AC_MSG_CHECKING([for -Wno-stringop-overflow support])
 393
 394         saved_flags="$CFLAGS"
 395         CFLAGS="$CFLAGS -Wno-stringop-overflow"
 396
 397         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [])], [
 398                 EXTRA_KCFLAGS="$EXTRA_KCFLAGS -Wno-stringop-overflow"
 399                 AC_SUBST(EXTRA_KCFLAGS)
 400                 AC_MSG_RESULT([yes])
 401         ], [
 402                 AC_MSG_RESULT([no])
 403         ])
 404
 405         CFLAGS="$saved_flags"
 406 ])
 407
 408 #
 409 # LB_CONDITIONALS
 410 #
 411 # AM_CONDITIONAL instances for everything
 412 # (so that portals/lustre can disable some if needed)
 413 #
 414 AC_DEFUN([LB_CONDITIONALS], [
 415 AM_CONDITIONAL([PLUGINS], [test x$enable_shared = xyes])
 416 AM_CONDITIONAL([MODULES], [test x$enable_modules = xyes])
 417 AM_CONDITIONAL([UTILS], [test x$enable_utils = xyes])
 418 AM_CONDITIONAL([TESTS], [test x$enable_tests = xyes])
 419 AM_CONDITIONAL([DOC], [test x$ENABLE_DOC = x1])
 420 AM_CONDITIONAL([MANPAGES], [test x$enable_manpages = xyes])
 421 AM_CONDITIONAL([LINUX], [test x$lb_target_os = xlinux])
 422 AM_CONDITIONAL([USE_QUILT], [test x$use_quilt = xyes])
 423 AM_CONDITIONAL([RHEL], [test -f /etc/redhat-release])
 424 AM_CONDITIONAL([SUSE], [test -f /etc/SUSE-brand -o -f /etc/SuSE-release])
 425 AM_CONDITIONAL([UBUNTU], [test x$UBUNTU_KERNEL = xyes])
 426
 427 LN_CONDITIONALS
 428 LC_CONDITIONALS
 429 ]) # LB_CONDITIONALS
 430
 431 #
 432 # LB_CONFIG_FILES
 433 #
 434 # build-specific config files
 435 #
 436 AC_DEFUN([LB_CONFIG_FILES], [
 437         AC_CONFIG_FILES([
 438                 Makefile
 439                 autoMakefile]
 440                 config/Makefile
 441                 [Rules:build/Rules.in]
 442                 AC_PACKAGE_TARNAME[.spec]
 443                 AC_PACKAGE_TARNAME[-dkms.spec]
 444                 ldiskfs/Makefile
 445                 ldiskfs/autoMakefile
 446                 lustre-iokit/Makefile
 447                 lustre-iokit/obdfilter-survey/Makefile
 448                 lustre-iokit/ost-survey/Makefile
 449                 lustre-iokit/sgpdd-survey/Makefile
 450                 lustre-iokit/mds-survey/Makefile
 451                 lustre-iokit/ior-survey/Makefile
 452                 lustre-iokit/stats-collect/Makefile
 453         )
 454 ])
 455
 456 #
 457 # LB_CONFIG_SERVERS
 458 #
 459 AC_DEFUN([LB_CONFIG_SERVERS], [
 460 AC_ARG_ENABLE([server],
 461         AC_HELP_STRING([--disable-server],
 462                         [disable Lustre server support]), [
 463                 AS_IF([test x$enable_server != xyes -a x$enable_server != xno],
 464                         [AC_MSG_ERROR([server valid options are "yes" or "no"])])
 465                 AS_IF([test x$enable_server = xyes -a x$enable_dist = xyes],
 466                         [AC_MSG_ERROR([--enable-server cannot be used with --enable-dist])])
 467         ], [
 468                 AS_IF([test x$enable_dist = xyes],
 469                         [enable_server=no], [enable_server=maybe])
 470         ])
 471
 472 # There are at least two good reasons why we should really run
 473 # LB_CONFIG_MODULES elsewhere before the call to LB_CONFIG_SERVERS:
 474 # LB_CONFIG_MODULES needs to be run for client support even when
 475 # servers are disabled, and because module support is actually a
 476 # prerequisite of server support.  However, some things under
 477 # LB_CONFIG_MODULES need us to already have checked for --disable-server,
 478 # before running, so until LB_CONFIG_MODULES can be reorganized, we
 479 # call it here.
 480 LB_CONFIG_MODULES
 481 AS_IF([test x$enable_modules = xno], [enable_server=no])
 482 LB_CONFIG_LDISKFS
 483 LB_CONFIG_ZFS
 484
 485 # If no backends were configured, and the user did not explicitly
 486 # require servers to be enabled, we just disable servers.
 487 AS_IF([test x$enable_ldiskfs = xno -a x$enable_zfs = xno], [
 488         AS_CASE([$enable_server],
 489                 [maybe], [enable_server=no],
 490                 [yes], [AC_MSG_ERROR([cannot enable servers, no backends were configured])])
 491         ], [
 492                 AS_IF([test x$enable_server = xmaybe], [enable_server=yes])
 493         ])
 494
 495 AC_MSG_CHECKING([whether to build Lustre server support])
 496 AC_MSG_RESULT([$enable_server])
 497 AS_IF([test x$enable_server = xyes], [
 498         AC_DEFINE(HAVE_SERVER_SUPPORT, 1, [support server])
 499         AC_SUBST(ENABLE_SERVER, yes)
 500 ], [
 501         AC_SUBST(ENABLE_SERVER, no)
 502 ])
 503 ]) # LB_CONFIG_SERVERS
 504
 505 #
 506 # LB_CONFIG_RPMBUILD_OPTIONS
 507 #
 508 # The purpose of this function is to assemble command line options
 509 # for the rpmbuild command based on the options passed to the configure
 510 # script, and also upon the decisions that configure makes based on
 511 # the tests that it runs.
 512 # These strings can be passed to rpmbuild on the command line
 513 # in the Make targets named "rpms" and "srpm".
 514 #
 515 AC_DEFUN([LB_CONFIG_RPMBUILD_OPTIONS], [
 516 RPMBINARGS=
 517 CONFIGURE_ARGS=
 518 eval set -- $ac_configure_args
 519 for arg; do
 520         case $arg in
 521                 --*dir=* ) ;;
 522                 -C | --cache-file=* ) ;;
 523                 --prefix=* | --*-prefix=* ) ;;
 524                 --enable-dist ) ;;
 525                 --with-kmp-moddir=* ) ;;
 526                 --with-linux=* | --with-linux-obj=* ) ;;
 527                 --enable-shared | --disable-shared ) ;;
 528                 --enable-static | --disable-static ) ;;
 529                 --enable-ldiskfs | --disable-ldiskfs ) ;;
 530                 --enable-modules | --disable-modules ) ;;
 531                 --enable-server | --disable-server ) ;;
 532                 --enable-tests | --disable-tests ) ;;
 533                 --enable-utils | --disable-utils ) ;;
 534                 --enable-iokit | --disable-iokit ) ;;
 535                 --enable-manpages | --disable-manpages ) ;;
 536                 * ) CONFIGURE_ARGS="$CONFIGURE_ARGS '$arg'" ;;
 537         esac
 538 done
 539 if test -n "$CONFIGURE_ARGS" ; then
 540         RPMBINARGS="$RPMBINARGS --define \"configure_args $CONFIGURE_ARGS\""
 541 fi
 542 if test -n "$LINUX" ; then
 543         RPMBINARGS="$RPMBINARGS --define \"kdir $LINUX\""
 544         if test -n "$LINUX_OBJ" -a "$LINUX_OBJ" != x"$LINUX" ; then
 545                 RPMBINARGS="$RPMBINARGS --define \"kobjdir $LINUX_OBJ\""
 546         fi
 547 fi
 548 if test x$enable_modules != xyes ; then
 549         RPMBINARGS="$RPMBINARGS --without lustre_modules"
 550 fi
 551 if test x$enable_tests != xyes ; then
 552         RPMBINARGS="$RPMBINARGS --without lustre_tests"
 553 fi
 554 if test x$enable_utils != xyes ; then
 555         RPMBINARGS="$RPMBINARGS --without lustre_utils"
 556 fi
 557 if test x$enable_server != xyes ; then
 558         RPMBINARGS="$RPMBINARGS --without servers"
 559 fi
 560 if test x$enable_ldiskfs != xyes ; then
 561         RPMBINARGS="$RPMBINARGS --without ldiskfs"
 562 fi
 563 if test x$enable_zfs = xyes ; then
 564         RPMBINARGS="$RPMBINARGS --with zfs"
 565 fi
 566 if test x$enable_gss_keyring = xyes ; then
 567         RPMBINARGS="$RPMBINARGS --with gss_keyring --with gss"
 568 fi
 569 if test x$enable_gss = xyes ; then
 570         RPMBINARGS="$RPMBINARGS --with gss"
 571         AC_SUBST(ENABLE_GSS, yes)
 572 elif test x$enable_gss = xno ; then
 573         RPMBINARGS="$RPMBINARGS --without gss"
 574         AC_SUBST(ENABLE_GSS, no)
 575 fi
 576 if test x$enable_iokit != xyes ; then
 577         RPMBINARGS="$RPMBINARGS --without lustre_iokit"
 578 fi
 579 if test x$enable_snmp != xyes ; then
 580         RPMBINARGS="$RPMBINARGS --without snmp"
 581 fi
 582 if test x$enable_manpages != xyes ; then
 583         RPMBINARGS="$RPMBINARGS --without manpages"
 584 fi
 585 if test x$enable_shared != xyes ; then
 586         RPMBINARGS="$RPMBINARGS --without shared"
 587 fi
 588 if test x$enable_static != xyes ; then
 589         RPMBINARGS="$RPMBINARGS --without static"
 590 fi
 591
 592 RPMBUILD_BINARY_ARGS=$RPMBINARGS
 593
 594 AC_SUBST(RPMBUILD_BINARY_ARGS)
 595 ]) # LB_CONFIG_RPMBUILD_OPTIONS
 596
 597 #
 598 # LB_CONFIGURE
 599 #
 600 # main configure steps
 601 #
 602 AC_DEFUN([LB_CONFIGURE], [
 603 AC_MSG_NOTICE([Lustre base checks
 604 ==============================================================================])
 605 LB_CANONICAL_SYSTEM
 606
 607 LB_CONFIG_DIST
 608
 609 LB_DOWNSTREAM_RELEASE
 610 LB_USES_DPKG
 611
 612 LB_LIBCFS_DIR
 613
 614 LB_INCLUDE_RULES
 615
 616 LB_PATH_DEFAULTS
 617
 618 LB_PROG_CC
 619 LB_CC_NO_FORMAT_TRUNCATION
 620 LB_CC_NO_STRINGOP_TRUNCATION
 621 LB_CC_NO_STRINGOP_OVERFLOW
 622
 623 LC_OSD_ADDON
 624
 625 LB_CONFIG_DOCS
 626 LB_CONFIG_MANPAGES
 627 LB_CONFIG_UTILS
 628 LB_CONFIG_TESTS
 629 LC_CONFIG_CLIENT
 630 LB_CONFIG_MPITESTS
 631 LB_CONFIG_SERVERS
 632
 633 # Tests depends from utils (multiop from liblustreapi)
 634 AS_IF([test "x$enable_utils" = xno], [enable_tests="no"])
 635
 636 LIBCFS_CONFIG_CDEBUG
 637 LC_QUOTA
 638
 639 LB_LIBMOUNT
 640 LB_PATH_SNMP
 641 LB_PATH_LUSTREIOKIT
 642
 643 LB_DEFINE_E2FSPROGS_NAMES
 644
 645 LIBCFS_CONFIGURE
 646 LN_CONFIGURE
 647 LC_CONFIGURE
 648 AS_IF([test -n "$SNMP_DIST_SUBDIR"], [LS_CONFIGURE])
 649
 650 LB_CONDITIONALS
 651 LB_CONFIG_HEADERS
 652
 653 LIBCFS_CONFIG_FILES
 654 LB_CONFIG_FILES
 655 LN_CONFIG_FILES
 656 LC_CONFIG_FILES
 657 AS_IF([test -n "$SNMP_DIST_SUBDIR"], [LS_CONFIG_FILES])
 658
 659 AC_SUBST(ac_configure_args)
 660
 661 MOSTLYCLEANFILES='.*.cmd .*.flags *.o *.ko *.mod.c .depend .*.1.* Modules.symvers Module.symvers'
 662 AC_SUBST(MOSTLYCLEANFILES)
 663
 664 LB_CONFIG_RPMBUILD_OPTIONS
 665
 666 AC_OUTPUT
 667
 668 cat <<_ACEOF
 669
 670 CC:            $CC
 671 LD:            $LD
 672 CPPFLAGS:      $CPPFLAGS
 673 CFLAGS:        $CFLAGS
 674 EXTRA_KCFLAGS: $EXTRA_KCFLAGS
 675
 676 Type 'make' to build Lustre.
 677 _ACEOF
 678 ]) # LB_CONFIGURE