Whamcloud - gitweb
820b8bb0fa4485f0d69fda690a84b1a6b4b89bd7
[fs/lustre-release.git] / config / lustre-build.m4
1 #
2 # LB_CHECK_VERSION
3 #
4 # Verify that LUSTRE_VERSION was defined properly
5 #
6 AC_DEFUN([LB_CHECK_VERSION],
7 [if test "LUSTRE_VERSION" = "LUSTRE""_VERSION" ; then
8         AC_MSG_ERROR([This script was not built with a version number.])
9 fi
10 ])
11
12 #
13 # LB_CANONICAL_SYSTEM
14 #
15 # fixup $target_os for use in other places
16 #
17 AC_DEFUN([LB_CANONICAL_SYSTEM],
18 [case $target_os in
19         linux*)
20                 lb_target_os="linux"
21                 ;;
22         darwin*)
23                 lb_target_os="darwin"
24                 ;;
25         solaris*)
26                 lb_target_os="SunOS"
27                 ;;esac
28 AC_SUBST(lb_target_os)
29 ])
30
31 #
32 # LB_DOWNSTREAM_RELEASE
33 #
34 AC_DEFUN([LB_DOWNSTREAM_RELEASE],
35 [AC_ARG_WITH([downstream-release],
36         AC_HELP_STRING([--with-downstream-release=string],
37                        [set a string in the BUILD_VERSION and RPM Release: (default is nothing)]),
38         [DOWNSTREAM_RELEASE=$with_downstream_release],
39         [
40         # if not specified, see if it's in the META file
41         if test -f META; then
42                 DOWNSTREAM_RELEASE=$(sed -ne '/^LOCAL_VERSION =/s/.*= *//p' META)
43         fi
44         ])
45 AC_SUBST(DOWNSTREAM_RELEASE)
46 ])
47
48 #
49 # LB_BUILDID
50 #
51 # Check if the source is a GA release and if not, set a "BUILDID"
52 #
53 # Currently there are at least two ways/modes of/for doing this.  One
54 # is if we are in a valid git repository, the other is if we are in a
55 # non-git source tree of some form.  Building the latter from the former
56 # will be handled here.
57 AC_DEFUN([LB_BUILDID],
58 [
59 AC_MSG_CHECKING([for buildid])
60 BUILDID=""
61 if git branch >/dev/null 2>&1; then
62         ffw=0
63         hash=""
64         ver=$(git describe --match v[[0-9]]_*_[[0-9]]* --tags)
65         if [[[ $ver = *-*-* ]]]; then
66                 hash=${ver##*-}
67                 ffw=${ver#*-}
68                 ffw=${ffw%-*}
69                 ver=${ver%%-*}
70         fi
71         # it's tempting to use [[ $ver =~ ^v([0-9]+_)+([0-9]+|RC[0-9]+)$ ]]
72         # here but the portability of the regex on the right is dismal
73         # (thanx suse)
74         if echo "$ver" | egrep -q "^v([[0-9]]+_)+([[0-9]]+|RC[[0-9]]+)$"; then
75                 ver=$(echo $ver | sed -e 's/^v\(.*\)/\1/' \
76                                       -e 's/_RC[[0-9]].*$//' -e 's/_/./g')
77         fi
78
79         # a "lustre fix" value of .0 should be truncated
80         if [[[ $ver = *.*.*.0 ]]]; then
81                 ver=${ver%.0}
82         fi
83         # ditto for a "lustre fix" value of _0
84         if [[[ $ver = v*_*_*_0 ]]]; then
85                 ver=${ver%_0}
86         fi
87         if [[[ $ver = v*_*_* ]]]; then
88                 ver=${ver#v}
89                 ver=${ver//_/.}
90         fi
91
92         # only do this test for lustre (not ldiskfs)
93         if test "$PACKAGE" = "lustre" -a "$ver" != "$VERSION"; then
94                 AC_MSG_WARN([most recent tag found: $ver does not match current version $VERSION.])
95         fi
96
97         if test "$ffw" != "0"; then
98                 BUILDID="$hash"
99                 msg="$BUILDID (ahead by $ffw commits)"
100                 AC_MSG_RESULT([$msg])
101         else
102                 AC_MSG_RESULT([none... congratulations, you must be on a tag])
103         fi
104 elif test -f META; then
105         BUILDID=$(sed -ne '/^BUILDID =/s/.*= *//p' META)
106         msg="$BUILDID (from META file)"
107         AC_MSG_RESULT([$msg])
108 else
109         AC_MSG_WARN([FIXME: I don't know how to deal with source trees outside of git that don't have a META file.  Not setting a buildid.])
110 fi
111 AC_SUBST(BUILDID)
112 ])
113
114 #
115 # LB_CHECK_FILE
116 #
117 # Check for file existance even when cross compiling
118 #
119 AC_DEFUN([LB_CHECK_FILE],
120 [AS_VAR_PUSHDEF([lb_File], [lb_cv_file_$1])dnl
121 AC_CACHE_CHECK([for $1], lb_File,
122 [if test -r "$1"; then
123         AS_VAR_SET(lb_File, yes)
124 else
125         AS_VAR_SET(lb_File, no)
126 fi])
127 AS_IF([test AS_VAR_GET(lb_File) = yes], [$2], [$3])[]dnl
128 AS_VAR_POPDEF([lb_File])dnl
129 ])# LB_CHECK_FILE
130
131
132 #
133 # LB_ARG_LIBS_INCLUDES
134 #
135 # support for --with-foo, --with-foo-includes, and --with-foo-libs in
136 # a single magical macro
137 #
138 AC_DEFUN([LB_ARG_LIBS_INCLUDES],
139 [lb_pathvar="m4_bpatsubst([$2], -, _)"
140 AC_MSG_CHECKING([for $1])
141 AC_ARG_WITH([$2],
142         AC_HELP_STRING([--with-$2=path],
143                 [path to $1]),
144         [],[withval=$4])
145
146 if test x$withval = xyes ; then
147         eval "$lb_pathvar='$3'"
148 else
149         eval "$lb_pathvar='$withval'"
150 fi
151 AC_MSG_RESULT([${!lb_pathvar:-no}])
152
153 if test x${!lb_pathvar} != x -a x${!lb_pathvar} != xno ; then
154         AC_MSG_CHECKING([for $1 includes])
155         AC_ARG_WITH([$2-includes],
156                 AC_HELP_STRING([--with-$2-includes=path],
157                         [path to $1 includes]),
158                 [],[withval='yes'])
159
160         lb_includevar="${lb_pathvar}_includes"
161         if test x$withval = xyes ; then
162                 eval "${lb_includevar}='${!lb_pathvar}/include'"
163         else
164                 eval "${lb_includevar}='$withval'"
165         fi
166         AC_MSG_RESULT([${!lb_includevar}])
167
168         AC_MSG_CHECKING([for $1 libs])
169         AC_ARG_WITH([$2-libs],
170                 AC_HELP_STRING([--with-$2-libs=path],
171                         [path to $1 libs]),
172                 [],[withval='yes'])
173
174         lb_libvar="${lb_pathvar}_libs"
175         if test x$withval = xyes ; then
176                 eval "${lb_libvar}='${!lb_pathvar}/lib'"
177         else
178                 eval "${lb_libvar}='$withval'"
179         fi
180         AC_MSG_RESULT([${!lb_libvar}])
181 fi
182 ])
183 ])
184
185 #
186 # LB_PATH_LIBSYSIO
187 #
188 # Handle internal/external libsysio
189 #
190 AC_DEFUN([LB_PATH_LIBSYSIO],
191 [AC_ARG_WITH([sysio],
192         AC_HELP_STRING([--with-sysio=path],
193                         [set path to libsysio source (default is included libsysio)]),
194         [],[
195                 case $lb_target_os in
196                         linux)
197                                 with_sysio='yes'
198                                 ;;
199                         *)
200                                 with_sysio='no'
201                                 ;;
202                 esac
203         ])
204 AC_MSG_CHECKING([location of libsysio])
205 enable_sysio="$with_sysio"
206 case x$with_sysio in
207         xyes)
208                 AC_MSG_RESULT([internal])
209                 LB_CHECK_FILE([$srcdir/libsysio/src/rmdir.c],[],[
210                         AC_MSG_ERROR([A complete internal libsysio was not found.])
211                 ])
212                 LIBSYSIO_SUBDIR="libsysio"
213                 SYSIO="$PWD/libsysio"
214                 ;;
215         xno)
216                 AC_MSG_RESULT([disabled])
217                 ;;
218         *)
219                 AC_MSG_RESULT([$with_sysio])
220                 LB_CHECK_FILE([$with_sysio/lib/libsysio.a],[],[
221                         AC_MSG_ERROR([A complete (built) external libsysio was not found.])
222                 ])
223                 SYSIO=$with_sysio
224                 with_sysio="yes"
225                 ;;
226 esac
227
228 # We have to configure even if we don't build here for make dist to work
229 AC_CONFIG_SUBDIRS(libsysio)
230 ])
231
232 #
233 # LB_PATH_LUSTREIOKIT
234 #
235 # Handle internal/external lustre-iokit
236 #
237 AC_DEFUN([LB_PATH_LUSTREIOKIT],
238 [AC_ARG_WITH([lustre-iokit],
239         AC_HELP_STRING([--with-lustre-iokit=path],
240                         [set path to lustre-iokit source (default is included lustre-iokit)]),
241         [],[
242                         with_lustre_iokit='yes'
243         ])
244 AC_MSG_CHECKING([location of lustre-iokit])
245 enable_lustre_iokit="$with_lustre_iokit"
246 case x$with_lustre_iokit in
247         xyes)
248                 AC_MSG_RESULT([internal])
249                 LB_CHECK_FILE([$srcdir/lustre-iokit/ior-survey/ior-survey],[],[
250                         AC_MSG_ERROR([A complete internal lustre-iokit was not found.])
251                 ])
252                 LUSTREIOKIT_SUBDIR="lustre-iokit"
253                 LUSTREIOKIT="$PWD/lustre-iokit"
254                 ;;
255         xno)
256                 AC_MSG_RESULT([disabled])
257                 ;;
258         *)
259                 AC_MSG_RESULT([$with_lustre_iokit])
260                 LB_CHECK_FILE([$with_lustre_iokit/ior-survey/ior_survey],[],[
261                         AC_MSG_ERROR([A complete (built) external lustre-iokit was not found.])
262                 ])
263                 LUSTREIOKIT="$with_lustre_iokit"
264                 ;;
265 esac
266 AC_SUBST(LUSTREIOKIT_SUBDIR)
267 # We have to configure even if we don't build here for make dist to work
268 AC_CONFIG_SUBDIRS(lustre-iokit)
269 ])
270
271 # Define no libcfs by default.
272 AC_DEFUN([LB_LIBCFS_DIR],
273 [
274 case x$libcfs_is_module in
275         xyes)
276           LIBCFS_INCLUDE_DIR="libcfs/include"
277           LIBCFS_SUBDIR="libcfs"
278           ;;
279         x*)
280           LIBCFS_INCLUDE_DIR="lnet/include"
281           LIBCFS_SUBDIR=""
282           ;;
283 esac
284 AC_SUBST(LIBCFS_SUBDIR)
285 AC_SUBST(LIBCFS_INCLUDE_DIR)
286 ])
287
288 #
289 # LB_PATH_SNMP
290 #
291 # check for in-tree snmp support
292 #
293 AC_DEFUN([LB_PATH_SNMP],
294 [LB_CHECK_FILE([$srcdir/snmp/lustre-snmp.c],[SNMP_DIST_SUBDIR="snmp"])
295 AC_SUBST(SNMP_DIST_SUBDIR)
296 AC_SUBST(SNMP_SUBDIR)
297 ])
298
299 #
300 # LB_CONFIG_MODULES
301 #
302 # Build kernel modules?
303 #
304 AC_DEFUN([LB_CONFIG_MODULES],
305 [AC_MSG_CHECKING([whether to build kernel modules])
306 AC_ARG_ENABLE([modules],
307         AC_HELP_STRING([--disable-modules],
308                         [disable building of Lustre kernel modules]),
309         [],[
310                 LC_TARGET_SUPPORTED([
311                         enable_modules='yes'
312                 ],[
313                         enable_modules='no'
314                 ])
315         ])
316 AC_MSG_RESULT([$enable_modules ($target_os)])
317
318 if test x$enable_modules = xyes ; then
319         case $target_os in
320                 linux*)
321                         LB_PROG_LINUX
322                         LIBCFS_PROG_LINUX
323                         LN_PROG_LINUX
324                         LC_PROG_LINUX
325                         ;;
326                 darwin*)
327                         LB_PROG_DARWIN
328                         LIBCFS_PROG_DARWIN
329                         ;;
330                 *)
331                         # This is strange - Lustre supports a target we don't
332                         AC_MSG_ERROR([Modules are not supported on $target_os])
333                         ;;
334         esac
335 fi
336 ])
337
338 #
339 # LB_CONFIG_UTILS
340 #
341 # Build utils?
342 #
343 AC_DEFUN([LB_CONFIG_UTILS],
344 [AC_MSG_CHECKING([whether to build utilities])
345 AC_ARG_ENABLE([utils],
346         AC_HELP_STRING([--disable-utils],
347                         [disable building of Lustre utility programs]),
348         [],[enable_utils='yes'])
349 AC_MSG_RESULT([$enable_utils])
350 if test x$enable_utils = xyes ; then 
351         LB_CONFIG_INIT_SCRIPTS
352 fi
353 ])
354
355 #
356 # LB_CONFIG_TESTS
357 #
358 # Build tests?
359 #
360 AC_DEFUN([LB_CONFIG_TESTS],
361 [AC_MSG_CHECKING([whether to build Lustre tests])
362 AC_ARG_ENABLE([tests],
363         AC_HELP_STRING([--disable-tests],
364                         [disable building of Lustre tests]),
365         [],
366         [
367                 enable_tests='yes'
368         ])
369 AC_MSG_RESULT([$enable_tests])
370 ])
371
372 #
373 # LB_CONFIG_DIST
374 #
375 # Just enough configure so that "make dist" is useful
376 #
377 # this simply re-adjusts some defaults, which of course can be overridden
378 # on the configure line after the --for-dist option
379 #
380 AC_DEFUN([LB_CONFIG_DIST],
381 [AC_MSG_CHECKING([whether to configure just enough for make dist])
382 AC_ARG_ENABLE([dist],
383         AC_HELP_STRING([--enable-dist],
384                         [only configure enough for make dist]),
385         [enable_dist='yes'],[enable_dist='no'])
386 AC_MSG_RESULT([$enable_dist])
387 if test x$enable_dist != xno; then
388         enable_modules='no'
389         enable_utils='no'
390         enable_liblustre='no'
391         enable_doc='no'
392         enable_tests='no'
393 fi
394 ])
395
396 #
397 # LB_CONFIG_DOCS
398 #
399 # Build docs?
400 #
401 AC_DEFUN([LB_CONFIG_DOCS],
402 [AC_MSG_CHECKING([whether to build docs])
403 AC_ARG_ENABLE(doc,
404         AC_HELP_STRING([--disable-doc],
405                         [skip creation of pdf documentation]),
406         [
407                 if test x$enable_doc = xyes ; then
408                     ENABLE_DOC=1
409                 else
410                     ENABLE_DOC=0
411                 fi
412         ],[
413                 ENABLE_DOC=0
414                 enable_doc='no'
415         ])
416 AC_MSG_RESULT([$enable_doc])
417 AC_SUBST(ENABLE_DOC)
418 ])
419
420 #
421 # LB_CONFIG_INIT_SCRIPTS
422 #
423 # our init scripts only work on red hat linux
424 #
425 AC_DEFUN([LB_CONFIG_INIT_SCRIPTS],
426 [ENABLE_INIT_SCRIPTS=0
427 if test x$enable_utils = xyes ; then
428         AC_MSG_CHECKING([whether to install init scripts])
429         # our scripts only work on red hat systems
430         if test -f /etc/init.d/functions -a -f /etc/sysconfig/network ; then
431                 ENABLE_INIT_SCRIPTS=1
432                 AC_MSG_RESULT([yes])
433         else
434                 AC_MSG_RESULT([no])
435         fi
436 fi
437 AC_SUBST(ENABLE_INIT_SCRIPTS)
438 ])
439
440 #
441 # LB_CONFIG_HEADERS
442 #
443 # add -include config.h
444 #
445 AC_DEFUN([LB_CONFIG_HEADERS],[
446         AC_CONFIG_HEADERS([config.h])
447         CPPFLAGS="-include $PWD/config.h $CPPFLAGS"
448         EXTRA_KCFLAGS="-include $PWD/config.h $EXTRA_KCFLAGS"
449         AC_SUBST(EXTRA_KCFLAGS)
450 ])
451
452 #
453 # LB_INCLUDE_RULES
454 #
455 # defines for including the toplevel Rules
456 #
457 AC_DEFUN([LB_INCLUDE_RULES],[
458         INCLUDE_RULES="include $PWD/Rules"
459         AC_SUBST(INCLUDE_RULES)
460 ])
461
462 #
463 # LB_PATH_DEFAULTS
464 #
465 # 'fixup' default paths
466 #
467 AC_DEFUN([LB_PATH_DEFAULTS],
468 [# directories for binaries
469 AC_PREFIX_DEFAULT([/usr])
470
471 sysconfdir='/etc'
472 AC_SUBST(sysconfdir)
473
474 # Directories for documentation and demos.
475 docdir='${datadir}/doc/$(PACKAGE)'
476 AC_SUBST(docdir)
477
478 LIBCFS_PATH_DEFAULTS
479 LN_PATH_DEFAULTS
480 LC_PATH_DEFAULTS
481
482 ])
483
484 #
485 # LB_PROG_CC
486 #
487 # checks on the C compiler
488 #
489 AC_DEFUN([LB_PROG_CC],
490 [AC_PROG_RANLIB
491
492 # ---------  unsigned long long sane? -------
493 AC_CHECK_SIZEOF(unsigned long long, 0)
494 echo "---> size SIZEOF $SIZEOF_unsigned_long_long"
495 echo "---> size SIZEOF $ac_cv_sizeof_unsigned_long_long"
496 if test $ac_cv_sizeof_unsigned_long_long != 8 ; then
497         AC_MSG_ERROR([** we assume that sizeof(long long) == 8.])
498 fi
499
500 if test $target_cpu == "powerpc64"; then
501         AC_MSG_WARN([set compiler with -m64])
502         CFLAGS="$CFLAGS -m64"
503         CC="$CC -m64"
504 fi
505
506 CPPFLAGS="-I$PWD/$LIBCFS_INCLUDE_DIR -I$PWD/lnet/include -I$PWD/lustre/include $CPPFLAGS"
507
508 LLCPPFLAGS="-D__arch_lib__ -D_LARGEFILE64_SOURCE=1"
509 AC_SUBST(LLCPPFLAGS)
510
511 # Add _GNU_SOURCE for strnlen on linux
512 LLCFLAGS="-g -Wall -fPIC -D_GNU_SOURCE"
513 AC_SUBST(LLCFLAGS)
514
515 CCASFLAGS="-Wall -fPIC -D_GNU_SOURCE"
516 AC_SUBST(CCASFLAGS)
517
518 # everyone builds against lnet and lustre
519 EXTRA_KCFLAGS="$EXTRA_KCFLAGS -g -I$PWD/$LIBCFS_INCLUDE_DIR -I$PWD/lnet/include -I$PWD/lustre/include"
520 AC_SUBST(EXTRA_KCFLAGS)
521 ])
522
523 #
524 # LB_CONTITIONALS
525 #
526 # AM_CONDITIONAL instances for everything
527 # (so that portals/lustre can disable some if needed)
528 AC_DEFUN([LB_CONDITIONALS],
529 [AM_CONDITIONAL(MODULES, test x$enable_modules = xyes)
530 AM_CONDITIONAL(UTILS, test x$enable_utils = xyes)
531 AM_CONDITIONAL(TESTS, test x$enable_tests = xyes)
532 AM_CONDITIONAL(DOC, test x$ENABLE_DOC = x1)
533 AM_CONDITIONAL(INIT_SCRIPTS, test x$ENABLE_INIT_SCRIPTS = "x1")
534 AM_CONDITIONAL(LINUX, test x$lb_target_os = "xlinux")
535 AM_CONDITIONAL(DARWIN, test x$lb_target_os = "xdarwin")
536 AM_CONDITIONAL(SUNOS, test x$lb_target_os = "xSunOS")
537 AM_CONDITIONAL(USES_DPKG, test x$uses_dpkg = "xyes")
538 AM_CONDITIONAL(ARCH_x86, test x$target_cpu = "xx86_64" -o x$target_cpu = "xi686")
539
540 # this lets lustre cancel libsysio, per-branch or if liblustre is
541 # disabled
542 if test "x$LIBSYSIO_SUBDIR" = xlibsysio ; then
543         if test "x$with_sysio" != xyes ; then
544                 SYSIO=""
545                 LIBSYSIO_SUBDIR=""
546         fi
547 fi
548 AC_SUBST(LIBSYSIO_SUBDIR)
549 AC_SUBST(SYSIO)
550
551 LB_DARWIN_CONDITIONALS
552
553 LIBCFS_CONDITIONALS
554 LN_CONDITIONALS
555 LC_CONDITIONALS
556 ])
557
558 #
559 # LB_CONFIG_FILES
560 #
561 # build-specific config files
562 #
563 AC_DEFUN([LB_CONFIG_FILES],
564 [
565         AC_CONFIG_FILES([
566                 Makefile
567                 autoMakefile]
568                 config/Makefile
569                 [Rules:build/Rules.in]
570                 AC_PACKAGE_TARNAME[.spec]
571                 contrib/Makefile
572                 contrib/lbuild/Makefile
573                 contrib/scripts/Makefile
574         )
575 ])
576
577 #
578 # LB_CONFIGURE
579 #
580 # main configure steps
581 #
582 AC_DEFUN([LB_CONFIGURE],
583 [LB_CANONICAL_SYSTEM
584
585 LB_CONFIG_DIST
586
587 LB_DOWNSTREAM_RELEASE
588 LB_USES_DPKG
589 LB_BUILDID
590
591 LB_LIBCFS_DIR
592
593 LB_INCLUDE_RULES
594
595 LB_PATH_DEFAULTS
596
597 LB_PROG_CC
598
599 LC_OSD_ADDON
600
601 LB_CONFIG_DOCS
602 LB_CONFIG_UTILS
603 LB_CONFIG_TESTS
604 LC_CONFIG_CLIENT_SERVER
605
606 # two macros for cmd3
607 m4_ifdef([LC_CONFIG_SPLIT], [LC_CONFIG_SPLIT])
608 LN_CONFIG_CDEBUG
609 LC_QUOTA
610
611 LB_CONFIG_MODULES
612 LN_CONFIG_USERSPACE
613
614 LB_PATH_LIBSYSIO
615 LB_PATH_SNMP
616 LB_PATH_LDISKFS
617 LB_PATH_ZFS
618 LB_PATH_LUSTREIOKIT
619
620 LB_DEFINE_E2FSPROGS_NAMES
621
622 LC_CONFIG_LIBLUSTRE
623 LIBCFS_CONFIGURE
624 LN_CONFIGURE
625
626 LC_CONFIGURE
627
628 if test "$SNMP_DIST_SUBDIR" ; then
629         LS_CONFIGURE
630 fi
631
632
633 LB_CONDITIONALS
634 LB_CONFIG_HEADERS
635
636 LIBCFS_CONFIG_FILES
637 LB_CONFIG_FILES
638 LN_CONFIG_FILES
639 LC_CONFIG_FILES
640 if test "$SNMP_DIST_SUBDIR" ; then
641         LS_CONFIG_FILES
642 fi
643
644 AC_SUBST(ac_configure_args)
645
646 MOSTLYCLEANFILES='.*.cmd .*.flags *.o *.ko *.mod.c .depend .*.1.* Modules.symvers Module.symvers'
647 AC_SUBST(MOSTLYCLEANFILES)
648
649 AC_OUTPUT
650
651 cat <<_ACEOF
652
653 CC:            $CC
654 LD:            $LD
655 CPPFLAGS:      $CPPFLAGS
656 LLCPPFLAGS:    $LLCPPFLAGS
657 CFLAGS:        $CFLAGS
658 EXTRA_KCFLAGS: $EXTRA_KCFLAGS
659 LLCFLAGS:      $LLCFLAGS
660
661 Type 'make' to build Lustre.
662 _ACEOF
663 ])