config/lustre-build.m4

   1 #
   2 # LB_CANONICAL_SYSTEM
   3 #
   4 # fixup $target_os for use in other places
   5 #
   6 AC_DEFUN([LB_CANONICAL_SYSTEM], [
   7 case $target_os in
   8         linux*)
   9                 lb_target_os="linux"
  10                 ;;
  11 esac
  12 AC_SUBST(lb_target_os)
  13 ]) # LB_CANONICAL_SYSTEM
  14
  15 #
  16 # LB_DOWNSTREAM_RELEASE (DEPRECATED)
  17 #
  18 AC_DEFUN([LB_DOWNSTREAM_RELEASE],
  19 [AC_ARG_WITH([downstream-release],,
  20         AC_MSG_ERROR([--downstream-release was deprecated.  Please read Documentation/versioning.txt.])
  21 )]) # LB_DOWNSTREAM_RELEASE
  22
  23 #
  24 # LB_CHECK_FILE
  25 #
  26 # Check for file existence even when cross compiling
  27 # $1 - file to check
  28 # $2 - do 'yes'
  29 # $3 - do 'no'
  30 #
  31 AC_DEFUN([LB_CHECK_FILE], [
  32 AS_VAR_PUSHDEF([lb_file], [lb_cv_file_$1])dnl
  33 AC_CACHE_CHECK([for $1], lb_file, [
  34 AS_IF([test -r "$1"],
  35         [AS_VAR_SET(lb_file, [yes])],
  36         [AS_VAR_SET(lb_file, [no])])
  37 ])
  38 AS_VAR_IF([lb_file], [yes], [$2], [$3])[]dnl
  39 AS_VAR_POPDEF([lb_file])dnl
  40 ]) # LB_CHECK_FILE
  41
  42 #
  43 # LB_ARG_LIBS_INCLUDES
  44 #
  45 # support for --with-foo, --with-foo-includes, and --with-foo-libs in
  46 # a single magical macro
  47 #
  48 AC_DEFUN([LB_ARG_LIBS_INCLUDES], [
  49 lb_pathvar="m4_bpatsubst([$2], -, _)"
  50 AC_MSG_CHECKING([for $1])
  51 AC_ARG_WITH([$2],
  52         AC_HELP_STRING([--with-$2=path],
  53                 [path to $1]),
  54         [], [withval=$4])
  55 AS_IF([test "x$withval" = xyes],
  56         [eval "$lb_pathvar='$3'"],
  57         [eval "$lb_pathvar='$withval'"])
  58 AC_MSG_RESULT([${!lb_pathvar:-no}])
  59
  60 AS_IF([test "x${!lb_pathvar}" != x -a "x${!lb_pathvar}" != xno], [
  61         AC_MSG_CHECKING([for $1 includes])
  62         AC_ARG_WITH([$2-includes],
  63                 AC_HELP_STRING([--with-$2-includes=path],
  64                         [path to $1 includes]),
  65                 [], [withval="yes"])
  66
  67         lb_includevar="${lb_pathvar}_includes"
  68         AS_IF([test "x$withval" = xyes],
  69                 [eval "${lb_includevar}='${!lb_pathvar}/include'"],
  70                 [eval "${lb_includevar}='$withval'"])
  71         AC_MSG_RESULT([${!lb_includevar}])
  72
  73         AC_MSG_CHECKING([for $1 libs])
  74         AC_ARG_WITH([$2-libs],
  75                 AC_HELP_STRING([--with-$2-libs=path],
  76                         [path to $1 libs]),
  77                 [], [withval="yes"])
  78
  79         lb_libvar="${lb_pathvar}_libs"
  80         AS_IF([test "x$withval" = xyes],
  81                 [eval "${lb_libvar}='${!lb_pathvar}/lib'"],
  82                 [eval "${lb_libvar}='$withval'"])
  83         AC_MSG_RESULT([${!lb_libvar}])
  84 ])
  85 ]) # LB_ARG_LIBS_INCLUDES
  86
  87 #
  88 # LB_PATH_LUSTREIOKIT
  89 #
  90 # We no longer handle external lustre-iokit
  91 #
  92 AC_DEFUN([LB_PATH_LUSTREIOKIT], [
  93 AC_MSG_CHECKING([whether to build iokit])
  94 AC_ARG_ENABLE([iokit],
  95         AC_HELP_STRING([--disable-iokit],
  96                 [disable iokit (default is enable)]),
  97         [], [enable_iokit="yes"])
  98 AC_MSG_RESULT([$enable_iokit])
  99 AS_IF([test "x$enable_iokit" = xyes],
 100         [LUSTREIOKIT_SUBDIR="lustre-iokit"],
 101         [LUSTREIOKIT_SUBDIR=""])
 102 AC_SUBST(LUSTREIOKIT_SUBDIR)
 103 AM_CONDITIONAL([BUILD_LUSTREIOKIT], [test "x$enable_iokit" = xyes])
 104 ]) # LB_PATH_LUSTREIOKIT
 105
 106 # Define no libcfs by default.
 107 AC_DEFUN([LB_LIBCFS_DIR], [
 108 AS_IF([test "x$libcfs_is_module" = xyes], [
 109                 LIBCFS_INCLUDE_DIR="libcfs/include"
 110                 LIBCFS_SUBDIR="libcfs"
 111         ], [
 112                 LIBCFS_INCLUDE_DIR="lnet/include"
 113                 LIBCFS_SUBDIR=""
 114         ])
 115 AC_SUBST(LIBCFS_INCLUDE_DIR)
 116 AC_SUBST(LIBCFS_SUBDIR)
 117 ]) # LB_LIBCFS_DIR
 118
 119 #
 120 # LB_LIBMOUNT
 121 #
 122 # Check whether build with libmount for mount.lustre.
 123 # libmount is part of the util-linux since v2.18.
 124 # We need it to manipulate utab file.
 125 #
 126 AC_DEFUN([LB_LIBMOUNT], [
 127 AC_CHECK_HEADER([libmount/libmount.h], [
 128         AC_CHECK_LIB([mount], [mnt_update_set_fs], [
 129                 LDLIBMOUNT="-lmount"
 130                 AC_SUBST(LDLIBMOUNT)
 131                 AC_DEFINE(HAVE_LIBMOUNT, 1, [build with libmount])
 132                 with_libmount="yes"
 133         ],[with_libmount="no"])
 134 ], [with_libmount="no"])
 135 AC_MSG_CHECKING([whether to build with libmount])
 136 AS_IF([test "x$with_libmount" = xyes], [
 137         AC_MSG_RESULT([yes])
 138 ], [
 139         AC_MSG_RESULT([no])
 140 ])
 141 ]) # LB_LIBMOUNT
 142
 143 #
 144 # LB_PATH_SNMP
 145 #
 146 # check for in-tree snmp support
 147 #
 148 AC_DEFUN([LB_PATH_SNMP], [
 149 LB_CHECK_FILE([$srcdir/snmp/lustre-snmp.c], [SNMP_DIST_SUBDIR="snmp"])
 150 AC_SUBST(SNMP_DIST_SUBDIR)
 151 AC_SUBST(SNMP_SUBDIR)
 152 ]) # LB_PATH_SNMP
 153
 154 #
 155 # LB_CONFIG_MODULES
 156 #
 157 # Build kernel modules?
 158 #
 159 AC_DEFUN([LB_CONFIG_MODULES], [
 160 AC_MSG_CHECKING([whether to build Linux kernel modules])
 161 AC_ARG_ENABLE([modules],
 162         AC_HELP_STRING([--disable-modules],
 163                 [disable building of Lustre kernel modules]),
 164         [], [
 165                 LC_TARGET_SUPPORTED([enable_modules="yes"],
 166                                     [enable_modules="no"])
 167         ])
 168 AC_MSG_RESULT([$enable_modules ($target_os)])
 169
 170 AS_IF([test "x$enable_modules" = xyes], [
 171         AS_CASE([$target_os],
 172                 [linux*], [
 173                         LB_PROG_LINUX
 174                         LIBCFS_PROG_LINUX
 175                         LN_PROG_LINUX
 176                         AS_IF([test "x$enable_server" != xno], [LB_EXT4_SRC_DIR])
 177                         LC_PROG_LINUX
 178                 ], [*], [
 179                         # This is strange - Lustre supports a target we don't
 180                         AC_MSG_ERROR([Modules are not supported on $target_os])
 181                 ])
 182         ])
 183 ]) # LB_CONFIG_MODULES
 184
 185 #
 186 # LB_CONFIG_UTILS
 187 #
 188 # Build utils?
 189 #
 190 AC_DEFUN([LB_CONFIG_UTILS], [
 191 AC_MSG_CHECKING([whether to build Lustre utilities])
 192 AC_ARG_ENABLE([utils],
 193         AC_HELP_STRING([--disable-utils],
 194                 [disable building of Lustre utility programs]),
 195         [], [enable_utils="yes"])
 196 AC_MSG_RESULT([$enable_utils])
 197 ]) # LB_CONFIG_UTILS
 198
 199 #
 200 # LB_CONFIG_TESTS
 201 #
 202 # Build tests?
 203 #
 204 AC_DEFUN([LB_CONFIG_TESTS], [
 205 AC_MSG_CHECKING([whether to build Lustre tests])
 206 AC_ARG_ENABLE([tests],
 207         AC_HELP_STRING([--disable-tests],
 208                 [disable building of Lustre tests]),
 209         [], [enable_tests="yes"])
 210 AC_MSG_RESULT([$enable_tests])
 211 ]) # LB_CONFIG_TESTS
 212
 213 #
 214 # LB_CONFIG_DIST
 215 #
 216 # Just enough configure so that "make dist" is useful
 217 #
 218 # this simply re-adjusts some defaults, which of course can be overridden
 219 # on the configure line after the --for-dist option
 220 #
 221 AC_DEFUN([LB_CONFIG_DIST], [
 222 AC_MSG_CHECKING([whether to configure just enough for make dist])
 223 AC_ARG_ENABLE([dist],
 224         AC_HELP_STRING([--enable-dist],
 225                         [only configure enough for make dist]),
 226         [], [enable_dist="no"])
 227 AC_MSG_RESULT([$enable_dist])
 228 AS_IF([test "x$enable_dist" != xno], [
 229         enable_doc="no"
 230         enable_utils="no"
 231         enable_tests="no"
 232         enable_modules="no"
 233 ])
 234 ]) # LB_CONFIG_DIST
 235
 236 #
 237 # LB_CONFIG_DOCS
 238 #
 239 # Build docs?
 240 #
 241 AC_DEFUN([LB_CONFIG_DOCS], [
 242 AC_MSG_CHECKING([whether to build Lustre docs])
 243 AC_ARG_ENABLE([doc],
 244         AC_HELP_STRING([--disable-doc],
 245                         [skip creation of pdf documentation]),
 246         [], [enable_doc="no"])
 247 AC_MSG_RESULT([$enable_doc])
 248 AS_IF([test "x$enable_doc" = xyes],
 249         [ENABLE_DOC=1], [ENABLE_DOC=0])
 250 AC_SUBST(ENABLE_DOC)
 251 ]) # LB_CONFIG_DOCS
 252
 253 #
 254 # LB_CONFIG_MANPAGES
 255 #
 256 # Build manpages?
 257 #
 258 AC_DEFUN([LB_CONFIG_MANPAGES], [
 259 AC_MSG_CHECKING([whether to build Lustre manpages])
 260 AC_ARG_ENABLE([manpages],
 261         AC_HELP_STRING([--disable-manpages],
 262                         [skip creation and inclusion of man pages (default is enable)]),
 263         [], [enable_manpages="yes"])
 264 AC_MSG_RESULT([$enable_manpages])
 265 ]) # LB_CONFIG_MANPAGES
 266
 267 #
 268 # LB_CONFIG_HEADERS
 269 #
 270 # add -include config.h
 271 #
 272 AC_DEFUN([LB_CONFIG_HEADERS], [
 273 AC_CONFIG_HEADERS([config.h])
 274 CPPFLAGS="-include $PWD/undef.h -include $PWD/config.h $CPPFLAGS"
 275 EXTRA_KCFLAGS="-include $PWD/undef.h -include $PWD/config.h $EXTRA_KCFLAGS"
 276 AC_SUBST(EXTRA_KCFLAGS)
 277 ]) # LB_CONFIG_HEADERS
 278
 279 #
 280 # LB_INCLUDE_RULES
 281 #
 282 # defines for including the toplevel Rules
 283 #
 284 AC_DEFUN([LB_INCLUDE_RULES], [
 285 INCLUDE_RULES="include $PWD/Rules"
 286 AC_SUBST(INCLUDE_RULES)
 287 ]) # LB_INCLUDE_RULES
 288
 289 #
 290 # LB_PATH_DEFAULTS
 291 #
 292 # 'fixup' default paths
 293 #
 294 AC_DEFUN([LB_PATH_DEFAULTS], [
 295 # directories for binaries
 296 AC_PREFIX_DEFAULT([/usr])
 297
 298 sysconfdir='/etc'
 299 AC_SUBST(sysconfdir)
 300
 301 # Directories for documentation and demos.
 302 docdir='${datadir}/doc/$(PACKAGE)'
 303 AC_SUBST(docdir)
 304
 305 LIBCFS_PATH_DEFAULTS
 306 LN_PATH_DEFAULTS
 307 LC_PATH_DEFAULTS
 308 ]) # LB_PATH_DEFAULTS
 309
 310 #
 311 # LB_PROG_CC
 312 #
 313 # checks on the C compiler
 314 #
 315 AC_DEFUN([LB_PROG_CC], [
 316 AC_PROG_RANLIB
 317 AC_CHECK_TOOL(LD, [ld], [no])
 318 AC_CHECK_TOOL(OBJDUMP, [objdump], [no])
 319 AC_CHECK_TOOL(STRIP, [strip], [no])
 320
 321 # ---------  unsigned long long sane? -------
 322 AC_CHECK_SIZEOF(unsigned long long, 0)
 323 AS_IF([test $ac_cv_sizeof_unsigned_long_long != 8],
 324         [AC_MSG_ERROR([we assume that sizeof(unsigned long long) == 8.])])
 325
 326 AS_IF([test $target_cpu = powerpc64], [
 327         AC_MSG_WARN([set compiler with -m64])
 328         CFLAGS="$CFLAGS -m64"
 329         CC="$CC -m64"
 330 ])
 331
 332 CPPFLAGS="-I$PWD/$LIBCFS_INCLUDE_DIR -I$PWD/lnet/include -I$PWD/lustre/include -I$PWD/lustre/include/uapi $CPPFLAGS"
 333
 334 CCASFLAGS="-Wall -fPIC -D_GNU_SOURCE"
 335 AC_SUBST(CCASFLAGS)
 336
 337 # everyone builds against lnet and lustre
 338 EXTRA_KCFLAGS="$EXTRA_KCFLAGS -g -I$PWD/$LIBCFS_INCLUDE_DIR -I$PWD/lnet/include -I$PWD/lustre/include"
 339 AC_SUBST(EXTRA_KCFLAGS)
 340 ]) # LB_PROG_CC
 341
 342 #
 343 # LB_CONDITIONALS
 344 #
 345 # AM_CONDITIONAL instances for everything
 346 # (so that portals/lustre can disable some if needed)
 347 #
 348 AC_DEFUN([LB_CONDITIONALS], [
 349 AM_CONDITIONAL([MODULES], [test x$enable_modules = xyes])
 350 AM_CONDITIONAL([UTILS], [test x$enable_utils = xyes])
 351 AM_CONDITIONAL([TESTS], [test x$enable_tests = xyes])
 352 AM_CONDITIONAL([DOC], [test x$ENABLE_DOC = x1])
 353 AM_CONDITIONAL([MANPAGES], [test x$enable_manpages = xyes])
 354 AM_CONDITIONAL([LINUX], [test x$lb_target_os = xlinux])
 355 AM_CONDITIONAL([USES_DPKG], [test x$uses_dpkg = xyes])
 356 AM_CONDITIONAL([USE_QUILT], [test x$use_quilt = xyes])
 357 AM_CONDITIONAL([RHEL], [test x$RHEL_KERNEL = xyes])
 358 AM_CONDITIONAL([SUSE], [test x$SUSE_KERNEL = xyes])
 359
 360 # Sanity check for PCLMULQDQ instruction availability
 361 # PCLMULQDQ instruction is a new instruction available beginning with
 362 # the all new Core processor family based on the 32nm microarchitecture
 363 # codename Westmere. So, $target_cpu = x86_64 should have this instruction
 364 # except MIC microarchitecture (k1om).
 365 AM_CONDITIONAL(HAVE_PCLMULQDQ, test x$target_cpu = "xx86_64" -a x$target_vendor != "xk1om")
 366 AS_IF([test x$target_cpu = "xx86_64" -a x$target_vendor != "xk1om"],
 367         [AC_DEFINE(HAVE_PCLMULQDQ, 1, [have PCLMULQDQ instruction])])
 368
 369 LIBCFS_CONDITIONALS
 370 LN_CONDITIONALS
 371 LC_CONDITIONALS
 372 ]) # LB_CONDITIONALS
 373
 374 #
 375 # LB_CONFIG_FILES
 376 #
 377 # build-specific config files
 378 #
 379 AC_DEFUN([LB_CONFIG_FILES], [
 380         AC_CONFIG_FILES([
 381                 Makefile
 382                 autoMakefile]
 383                 config/Makefile
 384                 [Rules:build/Rules.in]
 385                 AC_PACKAGE_TARNAME[.spec]
 386                 AC_PACKAGE_TARNAME[-dkms.spec]
 387                 ldiskfs/Makefile
 388                 ldiskfs/autoMakefile
 389                 lustre-iokit/Makefile
 390                 lustre-iokit/obdfilter-survey/Makefile
 391                 lustre-iokit/ost-survey/Makefile
 392                 lustre-iokit/sgpdd-survey/Makefile
 393                 lustre-iokit/mds-survey/Makefile
 394                 lustre-iokit/ior-survey/Makefile
 395                 lustre-iokit/stats-collect/Makefile
 396         )
 397         AC_CONFIG_FILES([lustre/scripts/dkms.mkconf],
 398                         [chmod +x lustre/scripts/dkms.mkconf])
 399 ])
 400
 401 #
 402 # LB_CONFIG_SERVERS
 403 #
 404 AC_DEFUN([LB_CONFIG_SERVERS], [
 405 AC_ARG_ENABLE([server],
 406         AC_HELP_STRING([--disable-server],
 407                         [disable Lustre server support]), [
 408                 AS_IF([test x$enable_server != xyes -a x$enable_server != xno],
 409                         [AC_MSG_ERROR([server valid options are "yes" or "no"])])
 410                 AS_IF([test x$enable_server = xyes -a x$enable_dist = xyes],
 411                         [AC_MSG_ERROR([--enable-server cannot be used with --enable-dist])])
 412         ], [
 413                 AS_IF([test x$enable_dist = xyes],
 414                         [enable_server=no], [enable_server=maybe])
 415         ])
 416
 417 # There are at least two good reasons why we should really run
 418 # LB_CONFIG_MODULES elsewhere before the call to LB_CONFIG_SERVERS:
 419 # LB_CONFIG_MODULES needs to be run for client support even when
 420 # servers are disabled, and because module support is actually a
 421 # prerequisite of server support.  However, some things under
 422 # LB_CONFIG_MODULES need us to already have checked for --disable-server,
 423 # before running, so until LB_CONFIG_MODULES can be reorganized, we
 424 # call it here.
 425 LB_CONFIG_MODULES
 426 AS_IF([test x$enable_modules = xno], [enable_server=no])
 427 LB_CONFIG_LDISKFS
 428 LB_CONFIG_ZFS
 429
 430 # If no backends were configured, and the user did not explicitly
 431 # require servers to be enabled, we just disable servers.
 432 AS_IF([test x$enable_ldiskfs = xno -a x$enable_zfs = xno], [
 433         AS_CASE([$enable_server],
 434                 [maybe], [enable_server=no],
 435                 [yes], [AC_MSG_ERROR([cannot enable servers, no backends were configured])])
 436         ], [
 437                 AS_IF([test x$enable_server = xmaybe], [enable_server=yes])
 438         ])
 439
 440 AC_MSG_CHECKING([whether to build Lustre server support])
 441 AC_MSG_RESULT([$enable_server])
 442 AS_IF([test x$enable_server = xyes],
 443         [AC_DEFINE(HAVE_SERVER_SUPPORT, 1, [support server])])
 444 ]) # LB_CONFIG_SERVERS
 445
 446 #
 447 # LB_CONFIG_RPMBUILD_OPTIONS
 448 #
 449 # The purpose of this function is to assemble command line options
 450 # for the rpmbuild command based on the options passed to the configure
 451 # script, and also upon the decisions that configure makes based on
 452 # the tests that it runs.
 453 # These strings can be passed to rpmbuild on the command line
 454 # in the Make targets named "rpms" and "srpm".
 455 #
 456 AC_DEFUN([LB_CONFIG_RPMBUILD_OPTIONS], [
 457 RPMBINARGS=
 458 CONFIGURE_ARGS=
 459 eval set -- $ac_configure_args
 460 for arg; do
 461         case $arg in
 462                 --*dir=* ) ;;
 463                 -C | --cache-file=* ) ;;
 464                 --prefix=* | --*-prefix=* ) ;;
 465                 --enable-dist ) ;;
 466                 --with-kmp-moddir=* ) ;;
 467                 --with-linux=* | --with-linux-obj=* ) ;;
 468                 --enable-shared | --disable-shared ) ;;
 469                 --enable-static | --disable-static ) ;;
 470                 --enable-ldiskfs | --disable-ldiskfs ) ;;
 471                 --enable-modules | --disable-modules ) ;;
 472                 --enable-server | --disable-server ) ;;
 473                 --enable-tests | --disable-tests ) ;;
 474                 --enable-utils | --disable-utils ) ;;
 475                 --enable-iokit | --disable-iokit ) ;;
 476                 --enable-dlc | --disable-dlc ) ;;
 477                 --enable-manpages | --disable-manpages ) ;;
 478                 * ) CONFIGURE_ARGS="$CONFIGURE_ARGS '$arg'" ;;
 479         esac
 480 done
 481 if test -n "$CONFIGURE_ARGS" ; then
 482         RPMBINARGS="$RPMBINARGS --define \"configure_args $CONFIGURE_ARGS\""
 483 fi
 484 if test -n "$LINUX" ; then
 485         RPMBINARGS="$RPMBINARGS --define \"kdir $LINUX\""
 486         if test -n "$LINUX_OBJ" -a "$LINUX_OBJ" != x"$LINUX" ; then
 487                 RPMBINARGS="$RPMBINARGS --define \"kobjdir $LINUX_OBJ\""
 488         fi
 489 fi
 490 if test x$enable_modules != xyes ; then
 491         RPMBINARGS="$RPMBINARGS --without lustre_modules"
 492 fi
 493 if test x$enable_tests != xyes ; then
 494         RPMBINARGS="$RPMBINARGS --without lustre_tests"
 495 fi
 496 if test x$enable_utils != xyes ; then
 497         RPMBINARGS="$RPMBINARGS --without lustre_utils"
 498 fi
 499 if test x$enable_server != xyes ; then
 500         RPMBINARGS="$RPMBINARGS --without servers"
 501 fi
 502 if test x$enable_ldiskfs != xyes ; then
 503         RPMBINARGS="$RPMBINARGS --without ldiskfs"
 504 fi
 505 if test x$enable_zfs = xyes ; then
 506         RPMBINARGS="$RPMBINARGS --with zfs"
 507 fi
 508 if test x$enable_iokit != xyes ; then
 509         RPMBINARGS="$RPMBINARGS --without lustre_iokit"
 510 fi
 511 if test x$USE_DLC = xyes ; then
 512         RPMBINARGS="$RPMBINARGS --with lnet_dlc"
 513 fi
 514 if test x$enable_manpages != xyes ; then
 515         RPMBINARGS="$RPMBINARGS --without manpages"
 516 fi
 517 if test x$enable_shared != xyes ; then
 518         RPMBINARGS="$RPMBINARGS --without shared"
 519 fi
 520 if test x$enable_static != xyes ; then
 521         RPMBINARGS="$RPMBINARGS --without static"
 522 fi
 523
 524 RPMBUILD_BINARY_ARGS=$RPMBINARGS
 525
 526 AC_SUBST(RPMBUILD_BINARY_ARGS)
 527 ]) # LB_CONFIG_RPMBUILD_OPTIONS
 528
 529 #
 530 # LB_CONFIGURE
 531 #
 532 # main configure steps
 533 #
 534 AC_DEFUN([LB_CONFIGURE], [
 535 AC_MSG_NOTICE([Lustre base checks
 536 ==============================================================================])
 537 LB_CANONICAL_SYSTEM
 538
 539 LB_CONFIG_DIST
 540
 541 LB_DOWNSTREAM_RELEASE
 542 LB_USES_DPKG
 543
 544 LB_LIBCFS_DIR
 545
 546 LB_INCLUDE_RULES
 547
 548 LB_PATH_DEFAULTS
 549
 550 LB_PROG_CC
 551
 552 LC_OSD_ADDON
 553
 554 LB_CONFIG_DOCS
 555 LB_CONFIG_MANPAGES
 556 LB_CONFIG_UTILS
 557 LB_CONFIG_TESTS
 558 LC_CONFIG_CLIENT
 559 LB_CONFIG_MPITESTS
 560 LB_CONFIG_SERVERS
 561
 562 # Tests depends from utils (multiop from liblustreapi)
 563 AS_IF([test "x$enable_utils" = xno], [enable_tests="no"])
 564
 565 m4_ifdef([LC_NODEMAP_PROC_DEBUG], [LC_NODEMAP_PROC_DEBUG])
 566 LIBCFS_CONFIG_CDEBUG
 567 LC_QUOTA
 568
 569 LB_LIBMOUNT
 570 LB_PATH_SNMP
 571 LB_PATH_LUSTREIOKIT
 572
 573 LB_DEFINE_E2FSPROGS_NAMES
 574
 575 LIBCFS_CONFIGURE
 576 LN_CONFIGURE
 577 LC_CONFIGURE
 578 AS_IF([test -n "$SNMP_DIST_SUBDIR"], [LS_CONFIGURE])
 579
 580 LB_CONDITIONALS
 581 LB_CONFIG_HEADERS
 582
 583 LIBCFS_CONFIG_FILES
 584 LB_CONFIG_FILES
 585 LN_CONFIG_FILES
 586 LC_CONFIG_FILES
 587 AS_IF([test -n "$SNMP_DIST_SUBDIR"], [LS_CONFIG_FILES])
 588
 589 AC_SUBST(ac_configure_args)
 590
 591 MOSTLYCLEANFILES='.*.cmd .*.flags *.o *.ko *.mod.c .depend .*.1.* Modules.symvers Module.symvers'
 592 AC_SUBST(MOSTLYCLEANFILES)
 593
 594 LB_CONFIG_RPMBUILD_OPTIONS
 595
 596 AC_OUTPUT
 597
 598 cat <<_ACEOF
 599
 600 CC:            $CC
 601 LD:            $LD
 602 CPPFLAGS:      $CPPFLAGS
 603 CFLAGS:        $CFLAGS
 604 EXTRA_KCFLAGS: $EXTRA_KCFLAGS
 605
 606 Type 'make' to build Lustre.
 607 _ACEOF
 608 ]) # LB_CONFIGURE