config/lustre-build.m4

   1 #
   2 # LB_CHECK_VERSION
   3 #
   4 # Verify that LUSTRE_VERSION was defined properly
   5 #
   6 AC_DEFUN([LB_CHECK_VERSION],
   7 [if test "LUSTRE_VERSION" = "LUSTRE""_VERSION" ; then
   8         AC_MSG_ERROR([This script was not built with a version number.])
   9 fi
  10 ])
  11
  12 #
  13 # LB_CANONICAL_SYSTEM
  14 #
  15 # fixup $target_os for use in other places
  16 #
  17 AC_DEFUN([LB_CANONICAL_SYSTEM],
  18 [case $target_os in
  19         linux*)
  20                 lb_target_os="linux"
  21                 ;;
  22         darwin*)
  23                 lb_target_os="darwin"
  24                 ;;
  25         solaris*)
  26                 lb_target_os="SunOS"
  27                 ;;
  28 esac
  29 AC_SUBST(lb_target_os)
  30 ])
  31
  32 #
  33 # LB_DOWNSTREAM_RELEASE
  34 #
  35 AC_DEFUN([LB_DOWNSTREAM_RELEASE],
  36 [AC_ARG_WITH([downstream-release],
  37         AC_HELP_STRING([--with-downstream-release=string],
  38                        [set a string in the BUILD_VERSION and RPM Release: (default is nothing)]),
  39         [DOWNSTREAM_RELEASE=$with_downstream_release],
  40         [
  41         # if not specified, see if it's in the META file
  42         if test -f META; then
  43                 DOWNSTREAM_RELEASE=$(sed -ne '/^LOCAL_VERSION =/s/.*= *//p' META)
  44         fi
  45         ])
  46 AC_SUBST(DOWNSTREAM_RELEASE)
  47 ])
  48
  49 #
  50 # LB_BUILDID
  51 #
  52 # Check if the source is a GA release and if not, set a "BUILDID"
  53 #
  54 # Currently there are at least two ways/modes of/for doing this.  One
  55 # is if we are in a valid git repository, the other is if we are in a
  56 # non-git source tree of some form.  Building the latter from the former
  57 # will be handled here.
  58 AC_DEFUN([LB_BUILDID],
  59 [
  60 AC_MSG_CHECKING([for buildid])
  61 BUILDID=""
  62 if git branch >/dev/null 2>&1; then
  63         ffw=0
  64         hash=""
  65         ver=$(git describe --match v[[0-9]]_*_[[0-9]]* --tags)
  66         if [[[ $ver = *-*-* ]]]; then
  67                 hash=${ver##*-}
  68                 ffw=${ver#*-}
  69                 ffw=${ffw%-*}
  70                 ver=${ver%%-*}
  71         fi
  72         # it's tempting to use [[ $ver =~ ^v([0-9]+_)+([0-9]+|RC[0-9]+)$ ]]
  73         # here but the portability of the regex on the right is dismal
  74         # (thanx suse)
  75         if echo "$ver" | egrep -q "^v([[0-9]]+_)+([[0-9]]+|RC[[0-9]]+)$"; then
  76                 ver=$(echo $ver | sed -e 's/^v\(.*\)/\1/' \
  77                                       -e 's/_RC[[0-9]].*$//' -e 's/_/./g')
  78         fi
  79
  80         # a "lustre fix" value of .0 should be truncated
  81         if [[[ $ver = *.*.*.0 ]]]; then
  82                 ver=${ver%.0}
  83         fi
  84         # ditto for a "lustre fix" value of _0
  85         if [[[ $ver = v*_*_*_0 ]]]; then
  86                 ver=${ver%_0}
  87         fi
  88         if [[[ $ver = v*_*_* ]]]; then
  89                 ver=${ver#v}
  90                 ver=${ver//_/.}
  91         fi
  92
  93         if test "$ver" != "$VERSION"; then
  94                 AC_MSG_WARN([most recent tag found: $ver does not match current version $VERSION.])
  95         fi
  96
  97         if test "$ffw" != "0"; then
  98                 BUILDID="$hash"
  99                 msg="$BUILDID (ahead by $ffw commits)"
 100                 AC_MSG_RESULT([$msg])
 101         else
 102                 AC_MSG_RESULT([none... congratulations, you must be on a tag])
 103         fi
 104 elif test -f META; then
 105         BUILDID=$(sed -ne '/^BUILDID =/s/.*= *//p' META)
 106         msg="$BUILDID (from META file)"
 107         AC_MSG_RESULT([$msg])
 108 else
 109         AC_MSG_WARN([FIXME: I don't know how to deal with source trees outside of git that don't have a META file.  Not setting a buildid.])
 110 fi
 111 AC_SUBST(BUILDID)
 112 ])
 113
 114 #
 115 # LB_CHECK_FILE
 116 #
 117 # Check for file existance even when cross compiling
 118 #
 119 AC_DEFUN([LB_CHECK_FILE],
 120 [AS_VAR_PUSHDEF([lb_File], [lb_cv_file_$1])dnl
 121 AC_CACHE_CHECK([for $1], lb_File,
 122 [if test -r "$1"; then
 123         AS_VAR_SET(lb_File, yes)
 124 else
 125         AS_VAR_SET(lb_File, no)
 126 fi])
 127 AS_IF([test AS_VAR_GET(lb_File) = yes], [$2], [$3])[]dnl
 128 AS_VAR_POPDEF([lb_File])dnl
 129 ])# LB_CHECK_FILE
 130
 131
 132 #
 133 # LB_ARG_LIBS_INCLUDES
 134 #
 135 # support for --with-foo, --with-foo-includes, and --with-foo-libs in
 136 # a single magical macro
 137 #
 138 AC_DEFUN([LB_ARG_LIBS_INCLUDES],
 139 [lb_pathvar="m4_bpatsubst([$2], -, _)"
 140 AC_MSG_CHECKING([for $1])
 141 AC_ARG_WITH([$2],
 142         AC_HELP_STRING([--with-$2=path],
 143                 [path to $1]),
 144         [],[withval=$4])
 145
 146 if test x$withval = xyes ; then
 147         eval "$lb_pathvar='$3'"
 148 else
 149         eval "$lb_pathvar='$withval'"
 150 fi
 151 AC_MSG_RESULT([${!lb_pathvar:-no}])
 152
 153 if test x${!lb_pathvar} != x -a x${!lb_pathvar} != xno ; then
 154         AC_MSG_CHECKING([for $1 includes])
 155         AC_ARG_WITH([$2-includes],
 156                 AC_HELP_STRING([--with-$2-includes=path],
 157                         [path to $1 includes]),
 158                 [],[withval='yes'])
 159
 160         lb_includevar="${lb_pathvar}_includes"
 161         if test x$withval = xyes ; then
 162                 eval "${lb_includevar}='${!lb_pathvar}/include'"
 163         else
 164                 eval "${lb_includevar}='$withval'"
 165         fi
 166         AC_MSG_RESULT([${!lb_includevar}])
 167
 168         AC_MSG_CHECKING([for $1 libs])
 169         AC_ARG_WITH([$2-libs],
 170                 AC_HELP_STRING([--with-$2-libs=path],
 171                         [path to $1 libs]),
 172                 [],[withval='yes'])
 173
 174         lb_libvar="${lb_pathvar}_libs"
 175         if test x$withval = xyes ; then
 176                 eval "${lb_libvar}='${!lb_pathvar}/lib'"
 177         else
 178                 eval "${lb_libvar}='$withval'"
 179         fi
 180         AC_MSG_RESULT([${!lb_libvar}])
 181 fi
 182 ])
 183 ])
 184
 185 #
 186 # LB_PATH_LIBSYSIO
 187 #
 188 # Handle internal/external libsysio
 189 #
 190 AC_DEFUN([LB_PATH_LIBSYSIO],
 191 [AC_ARG_WITH([sysio],
 192         AC_HELP_STRING([--with-sysio=path],
 193                         [set path to libsysio source (default is included libsysio)]),
 194         [],[
 195                 case $lb_target_os in
 196                         linux)
 197                                 with_sysio='yes'
 198                                 ;;
 199                         *)
 200                                 with_sysio='no'
 201                                 ;;
 202                 esac
 203         ])
 204 AC_MSG_CHECKING([location of libsysio])
 205 enable_sysio="$with_sysio"
 206 case x$with_sysio in
 207         xyes)
 208                 AC_MSG_RESULT([internal])
 209                 LB_CHECK_FILE([$srcdir/libsysio/src/rmdir.c],[],[
 210                         AC_MSG_ERROR([A complete internal libsysio was not found.])
 211                 ])
 212                 LIBSYSIO_SUBDIR="libsysio"
 213                 SYSIO="$PWD/libsysio"
 214                 ;;
 215         xno)
 216                 AC_MSG_RESULT([disabled])
 217                 ;;
 218         *)
 219                 AC_MSG_RESULT([$with_sysio])
 220                 LB_CHECK_FILE([$with_sysio/lib/libsysio.a],[],[
 221                         AC_MSG_ERROR([A complete (built) external libsysio was not found.])
 222                 ])
 223                 SYSIO=$with_sysio
 224                 with_sysio="yes"
 225                 ;;
 226 esac
 227
 228 # We have to configure even if we don't build here for make dist to work
 229 AC_CONFIG_SUBDIRS([libsysio])
 230 ])
 231
 232 #
 233 # LB_PATH_LUSTREIOKIT
 234 #
 235 # We no longer handle external lustre-iokit
 236 #
 237 AC_DEFUN([LB_PATH_LUSTREIOKIT],
 238 [AC_ARG_ENABLE([iokit],
 239         AC_HELP_STRING([--disable-iokit],
 240                 [disable iokit (default is enable)]),
 241         [],[
 242                 enable_iokit='yes'
 243         ])
 244 AC_MSG_CHECKING([whether to build iokit])
 245 AC_MSG_RESULT([$enable_iokit])
 246 AS_IF([test "x$enable_iokit" = xyes], [LUSTREIOKIT_SUBDIR="lustre-iokit"], [LUSTREIOKIT_SUBDIR=""])[]dnl
 247 AC_SUBST(LUSTREIOKIT_SUBDIR)
 248 AM_CONDITIONAL(BUILD_LUSTREIOKIT, [test "x$enable_iokit" = xyes])
 249 ])
 250
 251 # Define no libcfs by default.
 252 AC_DEFUN([LB_LIBCFS_DIR],
 253 [
 254 case x$libcfs_is_module in
 255         xyes)
 256           LIBCFS_INCLUDE_DIR="libcfs/include"
 257           LIBCFS_SUBDIR="libcfs"
 258           ;;
 259         x*)
 260           LIBCFS_INCLUDE_DIR="lnet/include"
 261           LIBCFS_SUBDIR=""
 262           ;;
 263 esac
 264 AC_SUBST(LIBCFS_SUBDIR)
 265 AC_SUBST(LIBCFS_INCLUDE_DIR)
 266 ])
 267
 268 #
 269 # LB_PATH_SNMP
 270 #
 271 # check for in-tree snmp support
 272 #
 273 AC_DEFUN([LB_PATH_SNMP],
 274 [LB_CHECK_FILE([$srcdir/snmp/lustre-snmp.c],[SNMP_DIST_SUBDIR="snmp"])
 275 AC_SUBST(SNMP_DIST_SUBDIR)
 276 AC_SUBST(SNMP_SUBDIR)
 277 ])
 278
 279 #
 280 # LB_CONFIG_MODULES
 281 #
 282 # Build kernel modules?
 283 #
 284 AC_DEFUN([LB_CONFIG_MODULES],
 285 [AC_MSG_CHECKING([whether to build kernel modules])
 286 AC_ARG_ENABLE([modules],
 287         AC_HELP_STRING([--disable-modules],
 288                         [disable building of Lustre kernel modules]),
 289         [],[
 290                 LC_TARGET_SUPPORTED([
 291                         enable_modules='yes'
 292                 ],[
 293                         enable_modules='no'
 294                 ])
 295         ])
 296 AC_MSG_RESULT([$enable_modules ($target_os)])
 297
 298 if test x$enable_modules = xyes ; then
 299         case $target_os in
 300                 linux*)
 301                         LB_PROG_LINUX
 302                         LIBCFS_PROG_LINUX
 303                         LN_PROG_LINUX
 304                         LC_PROG_LINUX
 305                         ;;
 306                 darwin*)
 307                         LB_PROG_DARWIN
 308                         LIBCFS_PROG_DARWIN
 309                         ;;
 310                 *)
 311                         # This is strange - Lustre supports a target we don't
 312                         AC_MSG_ERROR([Modules are not supported on $target_os])
 313                         ;;
 314         esac
 315 fi
 316 ])
 317
 318 #
 319 # LB_CONFIG_UTILS
 320 #
 321 # Build utils?
 322 #
 323 AC_DEFUN([LB_CONFIG_UTILS],
 324 [AC_MSG_CHECKING([whether to build utilities])
 325 AC_ARG_ENABLE([utils],
 326         AC_HELP_STRING([--disable-utils],
 327                         [disable building of Lustre utility programs]),
 328         [],[enable_utils='yes'])
 329 AC_MSG_RESULT([$enable_utils])
 330 if test x$enable_utils = xyes ; then
 331         LB_CONFIG_INIT_SCRIPTS
 332 fi
 333 ])
 334
 335 #
 336 # LB_CONFIG_TESTS
 337 #
 338 # Build tests?
 339 #
 340 AC_DEFUN([LB_CONFIG_TESTS],
 341 [AC_MSG_CHECKING([whether to build Lustre tests])
 342 AC_ARG_ENABLE([tests],
 343         AC_HELP_STRING([--disable-tests],
 344                         [disable building of Lustre tests]),
 345         [],
 346         [
 347                 enable_tests='yes'
 348         ])
 349 AC_MSG_RESULT([$enable_tests])
 350 ])
 351
 352 #
 353 # LB_CONFIG_DIST
 354 #
 355 # Just enough configure so that "make dist" is useful
 356 #
 357 # this simply re-adjusts some defaults, which of course can be overridden
 358 # on the configure line after the --for-dist option
 359 #
 360 AC_DEFUN([LB_CONFIG_DIST],
 361 [AC_MSG_CHECKING([whether to configure just enough for make dist])
 362 AC_ARG_ENABLE([dist],
 363         AC_HELP_STRING([--enable-dist],
 364                         [only configure enough for make dist]),
 365         [enable_dist='yes'],[enable_dist='no'])
 366 AC_MSG_RESULT([$enable_dist])
 367 if test x$enable_dist != xno; then
 368         enable_modules='no'
 369         enable_utils='no'
 370         enable_liblustre='no'
 371         enable_doc='no'
 372         enable_tests='no'
 373 fi
 374 ])
 375
 376 #
 377 # LB_CONFIG_DOCS
 378 #
 379 # Build docs?
 380 #
 381 AC_DEFUN([LB_CONFIG_DOCS],
 382 [AC_MSG_CHECKING([whether to build docs])
 383 AC_ARG_ENABLE(doc,
 384         AC_HELP_STRING([--disable-doc],
 385                         [skip creation of pdf documentation]),
 386         [
 387                 if test x$enable_doc = xyes ; then
 388                     ENABLE_DOC=1
 389                 else
 390                     ENABLE_DOC=0
 391                 fi
 392         ],[
 393                 ENABLE_DOC=0
 394                 enable_doc='no'
 395         ])
 396 AC_MSG_RESULT([$enable_doc])
 397 AC_SUBST(ENABLE_DOC)
 398 ])
 399
 400 #
 401 # LB_CONFIG_INIT_SCRIPTS
 402 #
 403 # our init scripts only work on red hat linux
 404 #
 405 AC_DEFUN([LB_CONFIG_INIT_SCRIPTS],
 406 [ENABLE_INIT_SCRIPTS=0
 407 if test x$enable_utils = xyes ; then
 408         AC_MSG_CHECKING([whether to install init scripts])
 409         # our scripts only work on red hat systems
 410         if test -f /etc/init.d/functions -a -f /etc/sysconfig/network ; then
 411                 ENABLE_INIT_SCRIPTS=1
 412                 AC_MSG_RESULT([yes])
 413         else
 414                 AC_MSG_RESULT([no])
 415         fi
 416 fi
 417 AC_SUBST(ENABLE_INIT_SCRIPTS)
 418 ])
 419
 420 #
 421 # LB_CONFIG_HEADERS
 422 #
 423 # add -include config.h
 424 #
 425 AC_DEFUN([LB_CONFIG_HEADERS],[
 426         AC_CONFIG_HEADERS([config.h])
 427         CPPFLAGS="-include $PWD/config.h $CPPFLAGS"
 428         EXTRA_KCFLAGS="-include $PWD/config.h $EXTRA_KCFLAGS"
 429         AC_SUBST(EXTRA_KCFLAGS)
 430 ])
 431
 432 #
 433 # LB_INCLUDE_RULES
 434 #
 435 # defines for including the toplevel Rules
 436 #
 437 AC_DEFUN([LB_INCLUDE_RULES],[
 438         INCLUDE_RULES="include $PWD/Rules"
 439         AC_SUBST(INCLUDE_RULES)
 440 ])
 441
 442 #
 443 # LB_PATH_DEFAULTS
 444 #
 445 # 'fixup' default paths
 446 #
 447 AC_DEFUN([LB_PATH_DEFAULTS],
 448 [# directories for binaries
 449 AC_PREFIX_DEFAULT([/usr])
 450
 451 sysconfdir='$(CROSS_PATH)/etc'
 452 AC_SUBST(sysconfdir)
 453
 454 # Directories for documentation and demos.
 455 docdir='$(datadir)/doc/$(PACKAGE)'
 456 AC_SUBST(docdir)
 457
 458 LIBCFS_PATH_DEFAULTS
 459 LN_PATH_DEFAULTS
 460 LC_PATH_DEFAULTS
 461
 462 ])
 463
 464 #
 465 # LB_PROG_CC
 466 #
 467 # checks on the C compiler
 468 #
 469 AC_DEFUN([LB_PROG_CC],
 470 [AC_PROG_RANLIB
 471 AC_CHECK_TOOL(LD, ld, [no])
 472 AC_CHECK_TOOL(OBJDUMP, objdump, [no])
 473 AC_CHECK_TOOL(STRIP, strip, [no])
 474
 475 # ---------  unsigned long long sane? -------
 476 AC_CHECK_SIZEOF(unsigned long long, 0)
 477 echo "---> size SIZEOF $SIZEOF_unsigned_long_long"
 478 echo "---> size SIZEOF $ac_cv_sizeof_unsigned_long_long"
 479 if test $ac_cv_sizeof_unsigned_long_long != 8 ; then
 480         AC_MSG_ERROR([** we assume that sizeof(long long) == 8.])
 481 fi
 482
 483 if test $target_cpu == "powerpc64"; then
 484         AC_MSG_WARN([set compiler with -m64])
 485         CFLAGS="$CFLAGS -m64"
 486         CC="$CC -m64"
 487 fi
 488
 489 CPPFLAGS="-I$PWD/$LIBCFS_INCLUDE_DIR -I$PWD/lnet/include -I$PWD/lustre/include $CPPFLAGS"
 490
 491 LLCPPFLAGS="-D__arch_lib__ -D_LARGEFILE64_SOURCE=1"
 492 AC_SUBST(LLCPPFLAGS)
 493
 494 # Add _GNU_SOURCE for strnlen on linux
 495 LLCFLAGS="-g -Wall -fPIC -D_GNU_SOURCE"
 496 AC_SUBST(LLCFLAGS)
 497
 498 CCASFLAGS="-Wall -fPIC -D_GNU_SOURCE"
 499 AC_SUBST(CCASFLAGS)
 500
 501 # everyone builds against lnet and lustre
 502 EXTRA_KCFLAGS="$EXTRA_KCFLAGS -g -I$PWD/$LIBCFS_INCLUDE_DIR -I$PWD/lnet/include -I$PWD/lustre/include"
 503 AC_SUBST(EXTRA_KCFLAGS)
 504 ])
 505
 506 #
 507 # LB_CONTITIONALS
 508 #
 509 # AM_CONDITIONAL instances for everything
 510 # (so that portals/lustre can disable some if needed)
 511 AC_DEFUN([LB_CONDITIONALS],
 512 [AM_CONDITIONAL(MODULES, test x$enable_modules = xyes)
 513 AM_CONDITIONAL(UTILS, test x$enable_utils = xyes)
 514 AM_CONDITIONAL(TESTS, test x$enable_tests = xyes)
 515 AM_CONDITIONAL(DOC, test x$ENABLE_DOC = x1)
 516 AM_CONDITIONAL(INIT_SCRIPTS, test x$ENABLE_INIT_SCRIPTS = "x1")
 517 AM_CONDITIONAL(LINUX, test x$lb_target_os = "xlinux")
 518 AM_CONDITIONAL(DARWIN, test x$lb_target_os = "xdarwin")
 519 AM_CONDITIONAL(SUNOS, test x$lb_target_os = "xSunOS")
 520 AM_CONDITIONAL(USES_DPKG, test x$uses_dpkg = "xyes")
 521 AM_CONDITIONAL([USE_QUILT], [test x$use_quilt = xyes])
 522
 523 # Sanity check for PCLMULQDQ instruction availability
 524 # PCLMULQDQ instruction is a new instruction available beginning with
 525 # the all new Core processor family based on the 32nm microarchitecture
 526 # codename Westmere. So, $target_cpu = x86_64 should have this instruction
 527 # except MIC microarchitecture (k1om).
 528 AM_CONDITIONAL(HAVE_PCLMULQDQ, test x$target_cpu = "xx86_64" -a x$target_vendor != "xk1om")
 529 if test x$target_cpu = "xx86_64" -a x$target_vendor != "xk1om" ; then
 530         AC_DEFINE(HAVE_PCLMULQDQ, 1, [have PCLMULQDQ instruction])
 531 fi
 532
 533 # this lets lustre cancel libsysio, per-branch or if liblustre is
 534 # disabled
 535 if test "x$LIBSYSIO_SUBDIR" = xlibsysio ; then
 536         if test "x$with_sysio" != xyes ; then
 537                 SYSIO=""
 538                 LIBSYSIO_SUBDIR=""
 539         fi
 540 fi
 541 AC_SUBST(LIBSYSIO_SUBDIR)
 542 AC_SUBST(SYSIO)
 543
 544 LB_DARWIN_CONDITIONALS
 545
 546 LIBCFS_CONDITIONALS
 547 LN_CONDITIONALS
 548 LC_CONDITIONALS
 549 ])
 550
 551 #
 552 # LB_CONFIG_FILES
 553 #
 554 # build-specific config files
 555 #
 556 AC_DEFUN([LB_CONFIG_FILES],
 557 [
 558         AC_CONFIG_FILES([
 559                 Makefile
 560                 autoMakefile]
 561                 config/Makefile
 562                 [Rules:build/Rules.in]
 563                 AC_PACKAGE_TARNAME[.spec]
 564                 contrib/Makefile
 565                 contrib/lbuild/Makefile
 566                 contrib/scripts/Makefile
 567                 ldiskfs/Makefile
 568                 ldiskfs/autoMakefile
 569                 lustre-iokit/Makefile
 570                 lustre-iokit/obdfilter-survey/Makefile
 571                 lustre-iokit/ost-survey/Makefile
 572                 lustre-iokit/sgpdd-survey/Makefile
 573                 lustre-iokit/mds-survey/Makefile
 574                 lustre-iokit/ior-survey/Makefile
 575                 lustre-iokit/stats-collect/Makefile
 576         )
 577 ])
 578
 579 #
 580 # LB_CONFIG_SERVERS
 581 #
 582 AC_DEFUN([LB_CONFIG_SERVERS],
 583 [
 584 AC_ARG_ENABLE([server],
 585         AC_HELP_STRING([--disable-server],
 586                         [disable Lustre server support]),
 587         [AS_IF([test x$enable_server != xyes -a x$enable_server != xno],
 588                 [AC_MSG_ERROR([server valid options are "yes" or "no"])])
 589         AS_IF([test x$enable_server = xyes -a x$enable_dist = xyes],
 590                 [AC_MSG_ERROR([--enable-server cannot be used with --enable-dist])])
 591         ],
 592         [AS_IF([test x$enable_dist = xyes],
 593                      [enable_server=no],
 594                      [enable_server=maybe])
 595         ]
 596 )
 597
 598 # There are at least two good reasons why we should really run
 599 # LB_CONFIG_MODULES elsewhere before the call to LB_CONFIG_SERVERS:
 600 # LB_CONFIG_MODULES needs to be run for client support even when
 601 # servers are disabled, and because module support is actually a
 602 # prerequisite of server support.  However, some things under
 603 # LB_CONFIG_MODULES need us to already have checked for --disable-server,
 604 # before running, so until LB_CONFIG_MODULES can be reorganized, we
 605 # call it here.
 606 LB_CONFIG_MODULES
 607 AS_IF([test x$enable_modules = xno],[enable_server=no])
 608 LB_CONFIG_LDISKFS
 609 LB_CONFIG_ZFS
 610
 611 # If no backends were configured, and the user did not explicitly
 612 # require servers to be enabled, we just disable servers.
 613 AS_IF([test x$enable_ldiskfs = xno -a x$enable_zfs = xno],
 614         [AS_CASE([$enable_server],
 615                 [maybe], [enable_server=no],
 616                 [yes], [AC_MSG_ERROR([cannot enable servers, no backends were configured])])
 617         ],
 618         [AS_IF([test x$enable_server = xmaybe], [enable_server=yes])]
 619 )
 620
 621 AC_MSG_CHECKING([whether to build Lustre server support])
 622 AC_MSG_RESULT([$enable_server])
 623 AS_IF([test x$enable_server = xyes],
 624         [AC_DEFINE(HAVE_SERVER_SUPPORT, 1, [support server])]
 625 )
 626 ])
 627
 628 #
 629 # LB_CONFIGURE
 630 #
 631 # main configure steps
 632 #
 633 AC_DEFUN([LB_CONFIGURE],
 634 [LB_CANONICAL_SYSTEM
 635
 636 LB_CONFIG_DIST
 637
 638 LB_DOWNSTREAM_RELEASE
 639 LB_USES_DPKG
 640 LB_BUILDID
 641
 642 LB_LIBCFS_DIR
 643
 644 LB_INCLUDE_RULES
 645
 646 LB_PATH_DEFAULTS
 647
 648 LB_PROG_CC
 649
 650 LC_OSD_ADDON
 651
 652 LB_CONFIG_DOCS
 653 LB_CONFIG_UTILS
 654 LB_CONFIG_TESTS
 655 LC_CONFIG_CLIENT
 656 LB_CONFIG_SERVERS
 657
 658 # two macros for cmd3
 659 m4_ifdef([LC_CONFIG_SPLIT], [LC_CONFIG_SPLIT])
 660 LN_CONFIG_CDEBUG
 661 LC_QUOTA
 662
 663 LN_CONFIG_USERSPACE
 664
 665 LB_PATH_LIBSYSIO
 666 LB_PATH_SNMP
 667 LB_PATH_LUSTREIOKIT
 668
 669 LB_DEFINE_E2FSPROGS_NAMES
 670
 671 LC_CONFIG_LIBLUSTRE
 672 LIBCFS_CONFIGURE
 673 LN_CONFIGURE
 674
 675 LC_CONFIGURE
 676
 677 if test "$SNMP_DIST_SUBDIR" ; then
 678         LS_CONFIGURE
 679 fi
 680
 681
 682 LB_CONDITIONALS
 683 LB_CONFIG_HEADERS
 684
 685 LIBCFS_CONFIG_FILES
 686 LB_CONFIG_FILES
 687 LN_CONFIG_FILES
 688 LC_CONFIG_FILES
 689 if test "$SNMP_DIST_SUBDIR" ; then
 690         LS_CONFIG_FILES
 691 fi
 692
 693 AC_SUBST(ac_configure_args)
 694
 695 MOSTLYCLEANFILES='.*.cmd .*.flags *.o *.ko *.mod.c .depend .*.1.* Modules.symvers Module.symvers'
 696 AC_SUBST(MOSTLYCLEANFILES)
 697
 698 AC_OUTPUT
 699
 700 cat <<_ACEOF
 701
 702 CC:            $CC
 703 LD:            $LD
 704 CPPFLAGS:      $CPPFLAGS
 705 LLCPPFLAGS:    $LLCPPFLAGS
 706 CFLAGS:        $CFLAGS
 707 EXTRA_KCFLAGS: $EXTRA_KCFLAGS
 708 LLCFLAGS:      $LLCFLAGS
 709
 710 Type 'make' to build Lustre.
 711 _ACEOF
 712 ])