Whamcloud - gitweb
LU-6971 cleanup: not support remote client anymore
[fs/lustre-release.git] / config / lustre-build.m4
1 #
2 # LB_CANONICAL_SYSTEM
3 #
4 # fixup $target_os for use in other places
5 #
6 AC_DEFUN([LB_CANONICAL_SYSTEM], [
7 case $target_os in
8         linux*)
9                 lb_target_os="linux"
10                 ;;
11 esac
12 AC_SUBST(lb_target_os)
13 ]) # LB_CANONICAL_SYSTEM
14
15 #
16 # LB_DOWNSTREAM_RELEASE (DEPRECATED)
17 #
18 AC_DEFUN([LB_DOWNSTREAM_RELEASE],
19 [AC_ARG_WITH([downstream-release],,
20         AC_MSG_ERROR([--downstream-release was deprecated.  Please read Documentation/versioning.txt.])
21 )]) # LB_DOWNSTREAM_RELEASE
22
23 #
24 # LB_CHECK_FILE
25 #
26 # Check for file existence even when cross compiling
27 # $1 - file to check
28 # $2 - do 'yes'
29 # $3 - do 'no'
30 #
31 AC_DEFUN([LB_CHECK_FILE], [
32 AS_VAR_PUSHDEF([lb_file], [lb_cv_file_$1])dnl
33 AC_CACHE_CHECK([for $1], lb_file, [
34 AS_IF([test -r "$1"],
35         [AS_VAR_SET(lb_file, [yes])],
36         [AS_VAR_SET(lb_file, [no])])
37 ])
38 AS_VAR_IF([lb_file], [yes], [$2], [$3])[]dnl
39 AS_VAR_POPDEF([lb_file])dnl
40 ]) # LB_CHECK_FILE
41
42 #
43 # LB_ARG_LIBS_INCLUDES
44 #
45 # support for --with-foo, --with-foo-includes, and --with-foo-libs in
46 # a single magical macro
47 #
48 AC_DEFUN([LB_ARG_LIBS_INCLUDES], [
49 lb_pathvar="m4_bpatsubst([$2], -, _)"
50 AC_MSG_CHECKING([for $1])
51 AC_ARG_WITH([$2],
52         AC_HELP_STRING([--with-$2=path],
53                 [path to $1]),
54         [], [withval=$4])
55 AS_IF([test "x$withval" = xyes],
56         [eval "$lb_pathvar='$3'"],
57         [eval "$lb_pathvar='$withval'"])
58 AC_MSG_RESULT([${!lb_pathvar:-no}])
59
60 AS_IF([test "x${!lb_pathvar}" != x -a "x${!lb_pathvar}" != xno], [
61         AC_MSG_CHECKING([for $1 includes])
62         AC_ARG_WITH([$2-includes],
63                 AC_HELP_STRING([--with-$2-includes=path],
64                         [path to $1 includes]),
65                 [], [withval="yes"])
66
67         lb_includevar="${lb_pathvar}_includes"
68         AS_IF([test "x$withval" = xyes],
69                 [eval "${lb_includevar}='${!lb_pathvar}/include'"],
70                 [eval "${lb_includevar}='$withval'"])
71         AC_MSG_RESULT([${!lb_includevar}])
72
73         AC_MSG_CHECKING([for $1 libs])
74         AC_ARG_WITH([$2-libs],
75                 AC_HELP_STRING([--with-$2-libs=path],
76                         [path to $1 libs]),
77                 [], [withval="yes"])
78
79         lb_libvar="${lb_pathvar}_libs"
80         AS_IF([test "x$withval" = xyes],
81                 [eval "${lb_libvar}='${!lb_pathvar}/lib'"],
82                 [eval "${lb_libvar}='$withval'"])
83         AC_MSG_RESULT([${!lb_libvar}])
84 ])
85 ]) # LB_ARG_LIBS_INCLUDES
86
87 #
88 # LB_PATH_LUSTREIOKIT
89 #
90 # We no longer handle external lustre-iokit
91 #
92 AC_DEFUN([LB_PATH_LUSTREIOKIT], [
93 AC_MSG_CHECKING([whether to build iokit])
94 AC_ARG_ENABLE([iokit],
95         AC_HELP_STRING([--disable-iokit],
96                 [disable iokit (default is enable)]),
97         [], [enable_iokit="yes"])
98 AC_MSG_RESULT([$enable_iokit])
99 AS_IF([test "x$enable_iokit" = xyes],
100         [LUSTREIOKIT_SUBDIR="lustre-iokit"],
101         [LUSTREIOKIT_SUBDIR=""])
102 AC_SUBST(LUSTREIOKIT_SUBDIR)
103 AM_CONDITIONAL([BUILD_LUSTREIOKIT], [test "x$enable_iokit" = xyes])
104 ]) # LB_PATH_LUSTREIOKIT
105
106 # Define no libcfs by default.
107 AC_DEFUN([LB_LIBCFS_DIR], [
108 AS_IF([test "x$libcfs_is_module" = xyes], [
109                 LIBCFS_INCLUDE_DIR="libcfs/include"
110                 LIBCFS_SUBDIR="libcfs"
111         ], [
112                 LIBCFS_INCLUDE_DIR="lnet/include"
113                 LIBCFS_SUBDIR=""
114         ])
115 AC_SUBST(LIBCFS_INCLUDE_DIR)
116 AC_SUBST(LIBCFS_SUBDIR)
117 ]) # LB_LIBCFS_DIR
118
119 #
120 # LB_LIBMOUNT
121 #
122 # Check whether build with libmount for mount.lustre.
123 # libmount is part of the util-linux since v2.18.
124 # We need it to manipulate utab file.
125 #
126 AC_DEFUN([LB_LIBMOUNT], [
127 AC_MSG_CHECKING([whether build with libmount])
128 AC_CHECK_HEADER([libmount/libmount.h], [
129         AC_CHECK_LIB([mount], [mnt_update_set_fs], [
130                 LDLIBMOUNT="-lmount"
131                 AC_SUBST(LDLIBMOUNT)
132                 AC_DEFINE(HAVE_LIBMOUNT, 1, [build with libmount])
133                 AC_MSG_RESULT(yes)
134         ],[AC_MSG_RESULT(no)])
135 ], [AC_MSG_RESULT(no)])
136 ]) # LB_LIBMOUNT
137
138 #
139 # LB_PATH_SNMP
140 #
141 # check for in-tree snmp support
142 #
143 AC_DEFUN([LB_PATH_SNMP], [
144 LB_CHECK_FILE([$srcdir/snmp/lustre-snmp.c], [SNMP_DIST_SUBDIR="snmp"])
145 AC_SUBST(SNMP_DIST_SUBDIR)
146 AC_SUBST(SNMP_SUBDIR)
147 ]) # LB_PATH_SNMP
148
149 #
150 # LB_CONFIG_MODULES
151 #
152 # Build kernel modules?
153 #
154 AC_DEFUN([LB_CONFIG_MODULES], [
155 AC_MSG_CHECKING([whether to build Linux kernel modules])
156 AC_ARG_ENABLE([modules],
157         AC_HELP_STRING([--disable-modules],
158                 [disable building of Lustre kernel modules]),
159         [], [
160                 LC_TARGET_SUPPORTED([enable_modules="yes"],
161                                     [enable_modules="no"])
162         ])
163 AC_MSG_RESULT([$enable_modules ($target_os)])
164
165 AS_IF([test "x$enable_modules" = xyes], [
166         AS_CASE([$target_os],
167                 [linux*], [
168                         LB_PROG_LINUX
169                         LIBCFS_PROG_LINUX
170                         LN_PROG_LINUX
171                         AS_IF([test "x$enable_server" != xno], [LB_EXT4_SRC_DIR])
172                         LC_PROG_LINUX
173                 ], [*], [
174                         # This is strange - Lustre supports a target we don't
175                         AC_MSG_ERROR([Modules are not supported on $target_os])
176                 ])
177         ])
178 ]) # LB_CONFIG_MODULES
179
180 #
181 # LB_CONFIG_UTILS
182 #
183 # Build utils?
184 #
185 AC_DEFUN([LB_CONFIG_UTILS], [
186 AC_MSG_CHECKING([whether to build Lustre utilities])
187 AC_ARG_ENABLE([utils],
188         AC_HELP_STRING([--disable-utils],
189                 [disable building of Lustre utility programs]),
190         [], [enable_utils="yes"])
191 AC_MSG_RESULT([$enable_utils])
192 ]) # LB_CONFIG_UTILS
193
194 #
195 # LB_CONFIG_TESTS
196 #
197 # Build tests?
198 #
199 AC_DEFUN([LB_CONFIG_TESTS], [
200 AC_MSG_CHECKING([whether to build Lustre tests])
201 AC_ARG_ENABLE([tests],
202         AC_HELP_STRING([--disable-tests],
203                 [disable building of Lustre tests]),
204         [], [enable_tests="yes"])
205 AC_MSG_RESULT([$enable_tests])
206 ]) # LB_CONFIG_TESTS
207
208 #
209 # LB_CONFIG_DIST
210 #
211 # Just enough configure so that "make dist" is useful
212 #
213 # this simply re-adjusts some defaults, which of course can be overridden
214 # on the configure line after the --for-dist option
215 #
216 AC_DEFUN([LB_CONFIG_DIST], [
217 AC_MSG_CHECKING([whether to configure just enough for make dist])
218 AC_ARG_ENABLE([dist],
219         AC_HELP_STRING([--enable-dist],
220                         [only configure enough for make dist]),
221         [], [enable_dist="no"])
222 AC_MSG_RESULT([$enable_dist])
223 AS_IF([test "x$enable_dist" != xno], [
224         enable_doc="no"
225         enable_utils="no"
226         enable_tests="no"
227         enable_modules="no"
228 ])
229 ]) # LB_CONFIG_DIST
230
231 #
232 # LB_CONFIG_DOCS
233 #
234 # Build docs?
235 #
236 AC_DEFUN([LB_CONFIG_DOCS], [
237 AC_MSG_CHECKING([whether to build Lustre docs])
238 AC_ARG_ENABLE([doc],
239         AC_HELP_STRING([--disable-doc],
240                         [skip creation of pdf documentation]),
241         [], [enable_doc="no"])
242 AC_MSG_RESULT([$enable_doc])
243 AS_IF([test "x$enable_doc" = xyes],
244         [ENABLE_DOC=1], [ENABLE_DOC=0])
245 AC_SUBST(ENABLE_DOC)
246 ]) # LB_CONFIG_DOCS
247
248 #
249 # LB_CONFIG_MANPAGES
250 #
251 # Build manpages?
252 #
253 AC_DEFUN([LB_CONFIG_MANPAGES], [
254 AC_MSG_CHECKING([whether to build Lustre manpages])
255 AC_ARG_ENABLE([manpages],
256         AC_HELP_STRING([--disable-manpages],
257                         [skip creation and inclusion of man pages (default is enable)]),
258         [], [enable_manpages="yes"])
259 AC_MSG_RESULT([$enable_manpages])
260 ]) # LB_CONFIG_MANPAGES
261
262 #
263 # LB_CONFIG_HEADERS
264 #
265 # add -include config.h
266 #
267 AC_DEFUN([LB_CONFIG_HEADERS], [
268 AC_CONFIG_HEADERS([config.h])
269 CPPFLAGS="-include $PWD/undef.h -include $PWD/config.h $CPPFLAGS"
270 EXTRA_KCFLAGS="-include $PWD/undef.h -include $PWD/config.h $EXTRA_KCFLAGS"
271 AC_SUBST(EXTRA_KCFLAGS)
272 ]) # LB_CONFIG_HEADERS
273
274 #
275 # LB_INCLUDE_RULES
276 #
277 # defines for including the toplevel Rules
278 #
279 AC_DEFUN([LB_INCLUDE_RULES], [
280 INCLUDE_RULES="include $PWD/Rules"
281 AC_SUBST(INCLUDE_RULES)
282 ]) # LB_INCLUDE_RULES
283
284 #
285 # LB_PATH_DEFAULTS
286 #
287 # 'fixup' default paths
288 #
289 AC_DEFUN([LB_PATH_DEFAULTS], [
290 # directories for binaries
291 AC_PREFIX_DEFAULT([/usr])
292
293 sysconfdir='/etc'
294 AC_SUBST(sysconfdir)
295
296 # Directories for documentation and demos.
297 docdir='${datadir}/doc/$(PACKAGE)'
298 AC_SUBST(docdir)
299
300 LIBCFS_PATH_DEFAULTS
301 LN_PATH_DEFAULTS
302 LC_PATH_DEFAULTS
303 ]) # LB_PATH_DEFAULTS
304
305 #
306 # LB_PROG_CC
307 #
308 # checks on the C compiler
309 #
310 AC_DEFUN([LB_PROG_CC], [
311 AC_PROG_RANLIB
312 AC_CHECK_TOOL(LD, [ld], [no])
313 AC_CHECK_TOOL(OBJDUMP, [objdump], [no])
314 AC_CHECK_TOOL(STRIP, [strip], [no])
315
316 # ---------  unsigned long long sane? -------
317 AC_CHECK_SIZEOF(unsigned long long, 0)
318 AS_IF([test $ac_cv_sizeof_unsigned_long_long != 8],
319         [AC_MSG_ERROR([we assume that sizeof(unsigned long long) == 8.])])
320
321 AS_IF([test $target_cpu = powerpc64], [
322         AC_MSG_WARN([set compiler with -m64])
323         CFLAGS="$CFLAGS -m64"
324         CC="$CC -m64"
325 ])
326
327 CPPFLAGS="-I$PWD/$LIBCFS_INCLUDE_DIR -I$PWD/lnet/include -I$PWD/lustre/include $CPPFLAGS"
328
329 CCASFLAGS="-Wall -fPIC -D_GNU_SOURCE"
330 AC_SUBST(CCASFLAGS)
331
332 # everyone builds against lnet and lustre
333 EXTRA_KCFLAGS="$EXTRA_KCFLAGS -g -I$PWD/$LIBCFS_INCLUDE_DIR -I$PWD/lnet/include -I$PWD/lustre/include"
334 AC_SUBST(EXTRA_KCFLAGS)
335 ]) # LB_PROG_CC
336
337 #
338 # LB_CONDITIONALS
339 #
340 # AM_CONDITIONAL instances for everything
341 # (so that portals/lustre can disable some if needed)
342 #
343 AC_DEFUN([LB_CONDITIONALS], [
344 AM_CONDITIONAL([MODULES], [test x$enable_modules = xyes])
345 AM_CONDITIONAL([UTILS], [test x$enable_utils = xyes])
346 AM_CONDITIONAL([TESTS], [test x$enable_tests = xyes])
347 AM_CONDITIONAL([DOC], [test x$ENABLE_DOC = x1])
348 AM_CONDITIONAL([MANPAGES], [test x$enable_manpages = xyes])
349 AM_CONDITIONAL([LINUX], [test x$lb_target_os = xlinux])
350 AM_CONDITIONAL([USES_DPKG], [test x$uses_dpkg = xyes])
351 AM_CONDITIONAL([USE_QUILT], [test x$use_quilt = xyes])
352 AM_CONDITIONAL([RHEL], [test x$RHEL_KERNEL = xyes])
353 AM_CONDITIONAL([SUSE], [test x$SUSE_KERNEL = xyes])
354
355 # Sanity check for PCLMULQDQ instruction availability
356 # PCLMULQDQ instruction is a new instruction available beginning with
357 # the all new Core processor family based on the 32nm microarchitecture
358 # codename Westmere. So, $target_cpu = x86_64 should have this instruction
359 # except MIC microarchitecture (k1om).
360 AM_CONDITIONAL(HAVE_PCLMULQDQ, test x$target_cpu = "xx86_64" -a x$target_vendor != "xk1om")
361 AS_IF([test x$target_cpu = "xx86_64" -a x$target_vendor != "xk1om"],
362         [AC_DEFINE(HAVE_PCLMULQDQ, 1, [have PCLMULQDQ instruction])])
363
364 LIBCFS_CONDITIONALS
365 LN_CONDITIONALS
366 LC_CONDITIONALS
367 ]) # LB_CONDITIONALS
368
369 #
370 # LB_CONFIG_FILES
371 #
372 # build-specific config files
373 #
374 AC_DEFUN([LB_CONFIG_FILES], [
375         AC_CONFIG_FILES([
376                 Makefile
377                 autoMakefile]
378                 config/Makefile
379                 [Rules:build/Rules.in]
380                 AC_PACKAGE_TARNAME[.spec]
381                 AC_PACKAGE_TARNAME[-dkms.spec]
382                 ldiskfs/Makefile
383                 ldiskfs/autoMakefile
384                 lustre-iokit/Makefile
385                 lustre-iokit/obdfilter-survey/Makefile
386                 lustre-iokit/ost-survey/Makefile
387                 lustre-iokit/sgpdd-survey/Makefile
388                 lustre-iokit/mds-survey/Makefile
389                 lustre-iokit/ior-survey/Makefile
390                 lustre-iokit/stats-collect/Makefile
391         )
392         AC_CONFIG_FILES([lustre/scripts/dkms.mkconf],
393                         [chmod +x lustre/scripts/dkms.mkconf])
394 ])
395
396 #
397 # LB_CONFIG_SERVERS
398 #
399 AC_DEFUN([LB_CONFIG_SERVERS], [
400 AC_ARG_ENABLE([server],
401         AC_HELP_STRING([--disable-server],
402                         [disable Lustre server support]), [
403                 AS_IF([test x$enable_server != xyes -a x$enable_server != xno],
404                         [AC_MSG_ERROR([server valid options are "yes" or "no"])])
405                 AS_IF([test x$enable_server = xyes -a x$enable_dist = xyes],
406                         [AC_MSG_ERROR([--enable-server cannot be used with --enable-dist])])
407         ], [
408                 AS_IF([test x$enable_dist = xyes],
409                         [enable_server=no], [enable_server=maybe])
410         ])
411
412 # There are at least two good reasons why we should really run
413 # LB_CONFIG_MODULES elsewhere before the call to LB_CONFIG_SERVERS:
414 # LB_CONFIG_MODULES needs to be run for client support even when
415 # servers are disabled, and because module support is actually a
416 # prerequisite of server support.  However, some things under
417 # LB_CONFIG_MODULES need us to already have checked for --disable-server,
418 # before running, so until LB_CONFIG_MODULES can be reorganized, we
419 # call it here.
420 LB_CONFIG_MODULES
421 AS_IF([test x$enable_modules = xno], [enable_server=no])
422 LB_CONFIG_LDISKFS
423 LB_CONFIG_ZFS
424
425 # If no backends were configured, and the user did not explicitly
426 # require servers to be enabled, we just disable servers.
427 AS_IF([test x$enable_ldiskfs = xno -a x$enable_zfs = xno], [
428         AS_CASE([$enable_server],
429                 [maybe], [enable_server=no],
430                 [yes], [AC_MSG_ERROR([cannot enable servers, no backends were configured])])
431         ], [
432                 AS_IF([test x$enable_server = xmaybe], [enable_server=yes])
433         ])
434
435 AC_MSG_CHECKING([whether to build Lustre server support])
436 AC_MSG_RESULT([$enable_server])
437 AS_IF([test x$enable_server = xyes],
438         [AC_DEFINE(HAVE_SERVER_SUPPORT, 1, [support server])])
439 ]) # LB_CONFIG_SERVERS
440
441 #
442 # LB_CONFIG_RPMBUILD_OPTIONS
443 #
444 # The purpose of this function is to assemble command line options
445 # for the rpmbuild command based on the options passed to the configure
446 # script, and also upon the decisions that configure makes based on
447 # the tests that it runs.
448 # These strings can be passed to rpmbuild on the command line
449 # in the Make targets named "rpms" and "srpm".
450 #
451 AC_DEFUN([LB_CONFIG_RPMBUILD_OPTIONS], [
452 RPMBINARGS=
453 CONFIGURE_ARGS=
454 eval set -- $ac_configure_args
455 for arg; do
456         case $arg in
457                 --*dir=* ) ;;
458                 -C | --cache-file=* ) ;;
459                 --prefix=* | --*-prefix=* ) ;;
460                 --enable-dist ) ;;
461                 --with-release=* ) ;;
462                 --with-kmp-moddir=* ) ;;
463                 --with-linux=* | --with-linux-obj=* ) ;;
464                 --enable-shared | --disable-shared ) ;;
465                 --enable-static | --disable-static ) ;;
466                 --enable-ldiskfs | --disable-ldiskfs ) ;;
467                 --enable-modules | --disable-modules ) ;;
468                 --enable-server | --disable-server ) ;;
469                 --enable-tests | --disable-tests ) ;;
470                 --enable-utils | --disable-utils ) ;;
471                 --enable-iokit | --disable-iokit ) ;;
472                 --enable-dlc | --disable-dlc ) ;;
473                 --enable-manpages | --disable-manpages ) ;;
474                 * ) CONFIGURE_ARGS="$CONFIGURE_ARGS '$arg'" ;;
475         esac
476 done
477 if test -n "$CONFIGURE_ARGS" ; then
478         RPMBINARGS="$RPMBINARGS --define \"configure_args $CONFIGURE_ARGS\""
479 fi
480 if test -n "$LINUX" ; then
481         RPMBINARGS="$RPMBINARGS --define \"kdir $LINUX\""
482         if test -n "$LINUX_OBJ" -a "$LINUX_OBJ" != x"$LINUX" ; then
483                 RPMBINARGS="$RPMBINARGS --define \"kobjdir $LINUX_OBJ\""
484         fi
485 fi
486 if test -n "$KMP_MODDIR" ; then
487         RPMBINARGS="$RPMBINARGS --define \"kmoddir $KMP_MODDIR\""
488 fi
489 if test x$enable_modules != xyes ; then
490         RPMBINARGS="$RPMBINARGS --without lustre_modules"
491 fi
492 if test x$enable_tests != xyes ; then
493         RPMBINARGS="$RPMBINARGS --without lustre_tests"
494 fi
495 if test x$enable_utils != xyes ; then
496         RPMBINARGS="$RPMBINARGS --without lustre_utils"
497 fi
498 if test x$enable_server != xyes ; then
499         RPMBINARGS="$RPMBINARGS --without servers"
500 fi
501 if test x$enable_ldiskfs != xyes ; then
502         RPMBINARGS="$RPMBINARGS --without ldiskfs"
503 fi
504 if test x$enable_zfs = xyes ; then
505         RPMBINARGS="$RPMBINARGS --with zfs"
506 fi
507 if test x$enable_iokit != xyes ; then
508         RPMBINARGS="$RPMBINARGS --without lustre_iokit"
509 fi
510 if test x$USE_DLC = xyes ; then
511         RPMBINARGS="$RPMBINARGS --with lnet_dlc"
512 fi
513 if test x$enable_manpages != xyes ; then
514         RPMBINARGS="$RPMBINARGS --without manpages"
515 fi
516 if test x$enable_shared != xyes ; then
517         RPMBINARGS="$RPMBINARGS --without shared"
518 fi
519 if test x$enable_static != xyes ; then
520         RPMBINARGS="$RPMBINARGS --without static"
521 fi
522
523 RPMBUILD_BINARY_ARGS=$RPMBINARGS
524
525 AC_SUBST(RPMBUILD_BINARY_ARGS)
526 ]) # LB_CONFIG_RPMBUILD_OPTIONS
527
528 #
529 # LB_CONFIGURE
530 #
531 # main configure steps
532 #
533 AC_DEFUN([LB_CONFIGURE], [
534 AC_MSG_NOTICE([Lustre base checks
535 ==============================================================================])
536 LB_CANONICAL_SYSTEM
537
538 LB_CONFIG_DIST
539
540 LB_DOWNSTREAM_RELEASE
541 LB_USES_DPKG
542
543 LB_LIBCFS_DIR
544
545 LB_INCLUDE_RULES
546
547 LB_PATH_DEFAULTS
548
549 LB_PROG_CC
550
551 LC_OSD_ADDON
552
553 LB_CONFIG_DOCS
554 LB_CONFIG_MANPAGES
555 LB_CONFIG_UTILS
556 LB_CONFIG_TESTS
557 LC_CONFIG_CLIENT
558 LB_CONFIG_MPITESTS
559 LB_CONFIG_SERVERS
560
561 # Tests depends from utils (multiop from liblustreapi)
562 AS_IF([test "x$enable_utils" = xno], [enable_tests="no"])
563
564 m4_ifdef([LC_NODEMAP_PROC_DEBUG], [LC_NODEMAP_PROC_DEBUG])
565 LIBCFS_CONFIG_CDEBUG
566 LC_QUOTA
567
568 LB_LIBMOUNT
569 LB_PATH_SNMP
570 LB_PATH_LUSTREIOKIT
571
572 LB_DEFINE_E2FSPROGS_NAMES
573
574 LIBCFS_CONFIGURE
575 LN_CONFIGURE
576 LC_CONFIGURE
577 AS_IF([test -n "$SNMP_DIST_SUBDIR"], [LS_CONFIGURE])
578
579 LB_CONDITIONALS
580 LB_CONFIG_HEADERS
581
582 LIBCFS_CONFIG_FILES
583 LB_CONFIG_FILES
584 LN_CONFIG_FILES
585 LC_CONFIG_FILES
586 AS_IF([test -n "$SNMP_DIST_SUBDIR"], [LS_CONFIG_FILES])
587
588 AC_SUBST(ac_configure_args)
589
590 MOSTLYCLEANFILES='.*.cmd .*.flags *.o *.ko *.mod.c .depend .*.1.* Modules.symvers Module.symvers'
591 AC_SUBST(MOSTLYCLEANFILES)
592
593 LB_CONFIG_RPMBUILD_OPTIONS
594
595 AC_OUTPUT
596
597 cat <<_ACEOF
598
599 CC:            $CC
600 LD:            $LD
601 CPPFLAGS:      $CPPFLAGS
602 CFLAGS:        $CFLAGS
603 EXTRA_KCFLAGS: $EXTRA_KCFLAGS
604
605 Type 'make' to build Lustre.
606 _ACEOF
607 ]) # LB_CONFIGURE