config/lustre-build.m4

   1 #
   2 # LB_CHECK_VERSION
   3 #
   4 # Verify that LUSTRE_VERSION was defined properly
   5 #
   6 AC_DEFUN([LB_CHECK_VERSION], [
   7 AS_IF([test "LUSTRE_VERSION" = "LUSTRE""_VERSION"],
   8         [AC_MSG_ERROR([This script was not built with a version number.])])
   9 ]) # LB_CHECK_VERSION
  10
  11 #
  12 # LB_CANONICAL_SYSTEM
  13 #
  14 # fixup $target_os for use in other places
  15 #
  16 AC_DEFUN([LB_CANONICAL_SYSTEM], [
  17 case $target_os in
  18         linux*)
  19                 lb_target_os="linux"
  20                 ;;
  21 esac
  22 AC_SUBST(lb_target_os)
  23 ]) # LB_CANONICAL_SYSTEM
  24
  25 #
  26 # LB_DOWNSTREAM_RELEASE
  27 #
  28 AC_DEFUN([LB_DOWNSTREAM_RELEASE],
  29 [AC_ARG_WITH([downstream-release],
  30         AC_HELP_STRING([--with-downstream-release=string],
  31                 [set a string in the BUILD_VERSION and RPM Release: (default is nothing)]),
  32         [DOWNSTREAM_RELEASE=$with_downstream_release],
  33         [ # if not specified, see if it's in the META file
  34         AS_IF([test -f META],
  35                 [DOWNSTREAM_RELEASE=$(sed -ne '/^LOCAL_VERSION =/s/.*= *//p' META)])
  36         ])
  37 AC_SUBST(DOWNSTREAM_RELEASE)
  38 ]) # LB_DOWNSTREAM_RELEASE
  39
  40 #
  41 # LB_BUILDID
  42 #
  43 # Check if the source is a GA release and if not, set a "BUILDID"
  44 #
  45 # Currently there are at least two ways/modes of/for doing this.  One
  46 # is if we are in a valid git repository, the other is if we are in a
  47 # non-git source tree of some form.  Building the latter from the former
  48 # will be handled here.
  49 AC_DEFUN([LB_BUILDID], [
  50 AC_CACHE_CHECK([for buildid], [lb_cv_buildid], [
  51 lb_cv_buildid=""
  52 AS_IF([git branch >/dev/null 2>&1], [
  53         ffw=0
  54         hash=""
  55         ver=$(git describe --match v[[0-9]]_*_[[0-9]]* --tags)
  56         if [[[ $ver = *-*-* ]]]; then
  57                 hash=${ver##*-}
  58                 ffw=${ver#*-}
  59                 ffw=${ffw%-*}
  60                 ver=${ver%%-*}
  61         fi
  62         # it's tempting to use [[ $ver =~ ^v([0-9]+_)+([0-9]+|RC[0-9]+)$ ]]
  63         # here but the portability of the regex on the right is dismal
  64         # (thanx suse)
  65         if echo "$ver" | egrep -q "^v([[0-9]]+_)+([[0-9]]+|RC[[0-9]]+)$"; then
  66                 ver=$(echo $ver | sed -e 's/^v\(.*\)/\1/' \
  67                                       -e 's/_RC[[0-9]].*$//' -e 's/_/./g')
  68         fi
  69
  70         # a "lustre fix" value of .0 should be truncated
  71         if [[[ $ver = *.*.*.0 ]]]; then
  72                 ver=${ver%.0}
  73         fi
  74         # ditto for a "lustre fix" value of _0
  75         if [[[ $ver = v*_*_*_0 ]]]; then
  76                 ver=${ver%_0}
  77         fi
  78         if [[[ $ver = v*_*_* ]]]; then
  79                 ver=${ver#v}
  80                 ver=${ver//_/.}
  81         fi
  82
  83         if test "$ver" != "$VERSION"; then
  84                 AC_MSG_WARN([most recent tag found: $ver does not match current version $VERSION.])
  85         fi
  86
  87         if test "$ffw" != "0"; then
  88                 lb_cv_buildid="$hash"
  89         fi
  90 ], [test -f META], [
  91         lb_cv_buildid=$(sed -ne '/^BUILDID =/s/.*= *//p' META)
  92 ])
  93 ])
  94 AS_IF([test -z "$lb_cv_buildid"], [
  95         AC_MSG_WARN([
  96
  97 FIXME: I don't know how to deal with source trees outside of git that
  98 don't have a META file. Not setting a buildid.
  99 ])
 100 ])
 101 BUILDID=$lb_cv_buildid
 102 AC_SUBST(BUILDID)
 103 ]) # LB_BUILDID
 104
 105 #
 106 # LB_CHECK_FILE
 107 #
 108 # Check for file existence even when cross compiling
 109 # $1 - file to check
 110 # $2 - do 'yes'
 111 # $3 - do 'no'
 112 #
 113 AC_DEFUN([LB_CHECK_FILE], [
 114 AS_VAR_PUSHDEF([lb_file], [lb_cv_file_$1])dnl
 115 AC_CACHE_CHECK([for $1], lb_file, [
 116 AS_IF([test -r "$1"],
 117         [AS_VAR_SET(lb_file, [yes])],
 118         [AS_VAR_SET(lb_file, [no])])
 119 ])
 120 AS_VAR_IF([lb_file], [yes], [$2], [$3])[]dnl
 121 AS_VAR_POPDEF([lb_file])dnl
 122 ]) # LB_CHECK_FILE
 123
 124 #
 125 # LB_ARG_LIBS_INCLUDES
 126 #
 127 # support for --with-foo, --with-foo-includes, and --with-foo-libs in
 128 # a single magical macro
 129 #
 130 AC_DEFUN([LB_ARG_LIBS_INCLUDES], [
 131 lb_pathvar="m4_bpatsubst([$2], -, _)"
 132 AC_MSG_CHECKING([for $1])
 133 AC_ARG_WITH([$2],
 134         AC_HELP_STRING([--with-$2=path],
 135                 [path to $1]),
 136         [], [withval=$4])
 137 AS_IF([test "x$withval" = xyes],
 138         [eval "$lb_pathvar='$3'"],
 139         [eval "$lb_pathvar='$withval'"])
 140 AC_MSG_RESULT([${!lb_pathvar:-no}])
 141
 142 AS_IF([test "x${!lb_pathvar}" != x -a "x${!lb_pathvar}" != xno], [
 143         AC_MSG_CHECKING([for $1 includes])
 144         AC_ARG_WITH([$2-includes],
 145                 AC_HELP_STRING([--with-$2-includes=path],
 146                         [path to $1 includes]),
 147                 [], [withval="yes"])
 148
 149         lb_includevar="${lb_pathvar}_includes"
 150         AS_IF([test "x$withval" = xyes],
 151                 [eval "${lb_includevar}='${!lb_pathvar}/include'"],
 152                 [eval "${lb_includevar}='$withval'"])
 153         AC_MSG_RESULT([${!lb_includevar}])
 154
 155         AC_MSG_CHECKING([for $1 libs])
 156         AC_ARG_WITH([$2-libs],
 157                 AC_HELP_STRING([--with-$2-libs=path],
 158                         [path to $1 libs]),
 159                 [], [withval="yes"])
 160
 161         lb_libvar="${lb_pathvar}_libs"
 162         AS_IF([test "x$withval" = xyes],
 163                 [eval "${lb_libvar}='${!lb_pathvar}/lib'"],
 164                 [eval "${lb_libvar}='$withval'"])
 165         AC_MSG_RESULT([${!lb_libvar}])
 166 ])
 167 ]) # LB_ARG_LIBS_INCLUDES
 168
 169 #
 170 # LB_PATH_LUSTREIOKIT
 171 #
 172 # We no longer handle external lustre-iokit
 173 #
 174 AC_DEFUN([LB_PATH_LUSTREIOKIT], [
 175 AC_MSG_CHECKING([whether to build iokit])
 176 AC_ARG_ENABLE([iokit],
 177         AC_HELP_STRING([--disable-iokit],
 178                 [disable iokit (default is enable)]),
 179         [], [enable_iokit="yes"])
 180 AC_MSG_RESULT([$enable_iokit])
 181 AS_IF([test "x$enable_iokit" = xyes],
 182         [LUSTREIOKIT_SUBDIR="lustre-iokit"],
 183         [LUSTREIOKIT_SUBDIR=""])
 184 AC_SUBST(LUSTREIOKIT_SUBDIR)
 185 AM_CONDITIONAL([BUILD_LUSTREIOKIT], [test "x$enable_iokit" = xyes])
 186 ]) # LB_PATH_LUSTREIOKIT
 187
 188 # Define no libcfs by default.
 189 AC_DEFUN([LB_LIBCFS_DIR], [
 190 AS_IF([test "x$libcfs_is_module" = xyes], [
 191                 LIBCFS_INCLUDE_DIR="libcfs/include"
 192                 LIBCFS_SUBDIR="libcfs"
 193         ], [
 194                 LIBCFS_INCLUDE_DIR="lnet/include"
 195                 LIBCFS_SUBDIR=""
 196         ])
 197 AC_SUBST(LIBCFS_INCLUDE_DIR)
 198 AC_SUBST(LIBCFS_SUBDIR)
 199 ]) # LB_LIBCFS_DIR
 200
 201 #
 202 # LB_PATH_SNMP
 203 #
 204 # check for in-tree snmp support
 205 #
 206 AC_DEFUN([LB_PATH_SNMP], [
 207 LB_CHECK_FILE([$srcdir/snmp/lustre-snmp.c], [SNMP_DIST_SUBDIR="snmp"])
 208 AC_SUBST(SNMP_DIST_SUBDIR)
 209 AC_SUBST(SNMP_SUBDIR)
 210 ]) # LB_PATH_SNMP
 211
 212 #
 213 # LB_CONFIG_MODULES
 214 #
 215 # Build kernel modules?
 216 #
 217 AC_DEFUN([LB_CONFIG_MODULES], [
 218 AC_MSG_CHECKING([whether to build Linux kernel modules])
 219 AC_ARG_ENABLE([modules],
 220         AC_HELP_STRING([--disable-modules],
 221                 [disable building of Lustre kernel modules]),
 222         [], [
 223                 LC_TARGET_SUPPORTED([enable_modules="yes"],
 224                                     [enable_modules="no"])
 225         ])
 226 AC_MSG_RESULT([$enable_modules ($target_os)])
 227
 228 AS_IF([test "x$enable_modules" = xyes], [
 229         AS_CASE([$target_os],
 230                 [linux*], [
 231                         LB_PROG_LINUX
 232                         LIBCFS_PROG_LINUX
 233                         LN_PROG_LINUX
 234                         AS_IF([test "x$enable_server" != xno], [LB_EXT4_SRC_DIR])
 235                         LC_PROG_LINUX
 236                 ], [*], [
 237                         # This is strange - Lustre supports a target we don't
 238                         AC_MSG_ERROR([Modules are not supported on $target_os])
 239                 ])
 240         ])
 241 ]) # LB_CONFIG_MODULES
 242
 243 #
 244 # LB_CONFIG_UTILS
 245 #
 246 # Build utils?
 247 #
 248 AC_DEFUN([LB_CONFIG_UTILS], [
 249 AC_MSG_CHECKING([whether to build Lustre utilities])
 250 AC_ARG_ENABLE([utils],
 251         AC_HELP_STRING([--disable-utils],
 252                 [disable building of Lustre utility programs]),
 253         [], [enable_utils="yes"])
 254 AC_MSG_RESULT([$enable_utils])
 255 ]) # LB_CONFIG_UTILS
 256
 257 #
 258 # LB_CONFIG_TESTS
 259 #
 260 # Build tests?
 261 #
 262 AC_DEFUN([LB_CONFIG_TESTS], [
 263 AC_MSG_CHECKING([whether to build Lustre tests])
 264 AC_ARG_ENABLE([tests],
 265         AC_HELP_STRING([--disable-tests],
 266                 [disable building of Lustre tests]),
 267         [], [enable_tests="yes"])
 268 AC_MSG_RESULT([$enable_tests])
 269 ]) # LB_CONFIG_TESTS
 270
 271 #
 272 # LB_CONFIG_DIST
 273 #
 274 # Just enough configure so that "make dist" is useful
 275 #
 276 # this simply re-adjusts some defaults, which of course can be overridden
 277 # on the configure line after the --for-dist option
 278 #
 279 AC_DEFUN([LB_CONFIG_DIST], [
 280 AC_MSG_CHECKING([whether to configure just enough for make dist])
 281 AC_ARG_ENABLE([dist],
 282         AC_HELP_STRING([--enable-dist],
 283                         [only configure enough for make dist]),
 284         [], [enable_dist="no"])
 285 AC_MSG_RESULT([$enable_dist])
 286 AS_IF([test "x$enable_dist" != xno], [
 287         enable_doc="no"
 288         enable_utils="no"
 289         enable_tests="no"
 290         enable_modules="no"
 291 ])
 292 ]) # LB_CONFIG_DIST
 293
 294 #
 295 # LB_CONFIG_DOCS
 296 #
 297 # Build docs?
 298 #
 299 AC_DEFUN([LB_CONFIG_DOCS], [
 300 AC_MSG_CHECKING([whether to build Lustre docs])
 301 AC_ARG_ENABLE([doc],
 302         AC_HELP_STRING([--disable-doc],
 303                         [skip creation of pdf documentation]),
 304         [], [enable_doc="no"])
 305 AC_MSG_RESULT([$enable_doc])
 306 AS_IF([test "x$enable_doc" = xyes],
 307         [ENABLE_DOC=1], [ENABLE_DOC=0])
 308 AC_SUBST(ENABLE_DOC)
 309 ]) # LB_CONFIG_DOCS
 310
 311 #
 312 # LB_CONFIG_MANPAGES
 313 #
 314 # Build manpages?
 315 #
 316 AC_DEFUN([LB_CONFIG_MANPAGES], [
 317 AC_MSG_CHECKING([whether to build Lustre manpages])
 318 AC_ARG_ENABLE([manpages],
 319         AC_HELP_STRING([--disable-manpages],
 320                         [skip creation and inclusion of man pages (default is enable)]),
 321         [], [enable_manpages="yes"])
 322 AC_MSG_RESULT([$enable_manpages])
 323 ]) # LB_CONFIG_MANPAGES
 324
 325 #
 326 # LB_CONFIG_HEADERS
 327 #
 328 # add -include config.h
 329 #
 330 AC_DEFUN([LB_CONFIG_HEADERS], [
 331 AC_CONFIG_HEADERS([config.h])
 332 CPPFLAGS="-include $PWD/undef.h -include $PWD/config.h $CPPFLAGS"
 333 EXTRA_KCFLAGS="-include $PWD/undef.h -include $PWD/config.h $EXTRA_KCFLAGS"
 334 AC_SUBST(EXTRA_KCFLAGS)
 335 ]) # LB_CONFIG_HEADERS
 336
 337 #
 338 # LB_INCLUDE_RULES
 339 #
 340 # defines for including the toplevel Rules
 341 #
 342 AC_DEFUN([LB_INCLUDE_RULES], [
 343 INCLUDE_RULES="include $PWD/Rules"
 344 AC_SUBST(INCLUDE_RULES)
 345 ]) # LB_INCLUDE_RULES
 346
 347 #
 348 # LB_PATH_DEFAULTS
 349 #
 350 # 'fixup' default paths
 351 #
 352 AC_DEFUN([LB_PATH_DEFAULTS], [
 353 # directories for binaries
 354 AC_PREFIX_DEFAULT([/usr])
 355
 356 sysconfdir='/etc'
 357 AC_SUBST(sysconfdir)
 358
 359 # Directories for documentation and demos.
 360 docdir='${datadir}/doc/$(PACKAGE)'
 361 AC_SUBST(docdir)
 362
 363 LIBCFS_PATH_DEFAULTS
 364 LN_PATH_DEFAULTS
 365 LC_PATH_DEFAULTS
 366 ]) # LB_PATH_DEFAULTS
 367
 368 #
 369 # LB_PROG_CC
 370 #
 371 # checks on the C compiler
 372 #
 373 AC_DEFUN([LB_PROG_CC], [
 374 AC_PROG_RANLIB
 375 AC_CHECK_TOOL(LD, [ld], [no])
 376 AC_CHECK_TOOL(OBJDUMP, [objdump], [no])
 377 AC_CHECK_TOOL(STRIP, [strip], [no])
 378
 379 # ---------  unsigned long long sane? -------
 380 AC_CHECK_SIZEOF(unsigned long long, 0)
 381 AS_IF([test $ac_cv_sizeof_unsigned_long_long != 8],
 382         [AC_MSG_ERROR([we assume that sizeof(unsigned long long) == 8.])])
 383
 384 AS_IF([test $target_cpu = powerpc64], [
 385         AC_MSG_WARN([set compiler with -m64])
 386         CFLAGS="$CFLAGS -m64"
 387         CC="$CC -m64"
 388 ])
 389
 390 CPPFLAGS="-I$PWD/$LIBCFS_INCLUDE_DIR -I$PWD/lnet/include -I$PWD/lustre/include $CPPFLAGS"
 391
 392 CCASFLAGS="-Wall -fPIC -D_GNU_SOURCE"
 393 AC_SUBST(CCASFLAGS)
 394
 395 # everyone builds against lnet and lustre
 396 EXTRA_KCFLAGS="$EXTRA_KCFLAGS -g -I$PWD/$LIBCFS_INCLUDE_DIR -I$PWD/lnet/include -I$PWD/lustre/include"
 397 AC_SUBST(EXTRA_KCFLAGS)
 398 ]) # LB_PROG_CC
 399
 400 #
 401 # LB_CONDITIONALS
 402 #
 403 # AM_CONDITIONAL instances for everything
 404 # (so that portals/lustre can disable some if needed)
 405 #
 406 AC_DEFUN([LB_CONDITIONALS], [
 407 AM_CONDITIONAL([MODULES], [test x$enable_modules = xyes])
 408 AM_CONDITIONAL([UTILS], [test x$enable_utils = xyes])
 409 AM_CONDITIONAL([TESTS], [test x$enable_tests = xyes])
 410 AM_CONDITIONAL([DOC], [test x$ENABLE_DOC = x1])
 411 AM_CONDITIONAL([MANPAGES], [test x$enable_manpages = xyes])
 412 AM_CONDITIONAL([LINUX], [test x$lb_target_os = xlinux])
 413 AM_CONDITIONAL([USES_DPKG], [test x$uses_dpkg = xyes])
 414 AM_CONDITIONAL([USE_QUILT], [test x$use_quilt = xyes])
 415 AM_CONDITIONAL([RHEL], [test x$RHEL_KERNEL = xyes])
 416 AM_CONDITIONAL([SUSE], [test x$SUSE_KERNEL = xyes])
 417
 418 # Sanity check for PCLMULQDQ instruction availability
 419 # PCLMULQDQ instruction is a new instruction available beginning with
 420 # the all new Core processor family based on the 32nm microarchitecture
 421 # codename Westmere. So, $target_cpu = x86_64 should have this instruction
 422 # except MIC microarchitecture (k1om).
 423 AM_CONDITIONAL(HAVE_PCLMULQDQ, test x$target_cpu = "xx86_64" -a x$target_vendor != "xk1om")
 424 AS_IF([test x$target_cpu = "xx86_64" -a x$target_vendor != "xk1om"],
 425         [AC_DEFINE(HAVE_PCLMULQDQ, 1, [have PCLMULQDQ instruction])])
 426
 427 LIBCFS_CONDITIONALS
 428 LN_CONDITIONALS
 429 LC_CONDITIONALS
 430 ]) # LB_CONDITIONALS
 431
 432 #
 433 # LB_CONFIG_FILES
 434 #
 435 # build-specific config files
 436 #
 437 AC_DEFUN([LB_CONFIG_FILES], [
 438         AC_CONFIG_FILES([
 439                 Makefile
 440                 autoMakefile]
 441                 config/Makefile
 442                 [Rules:build/Rules.in]
 443                 AC_PACKAGE_TARNAME[.spec]
 444                 AC_PACKAGE_TARNAME[-dkms.spec]
 445                 contrib/Makefile
 446                 contrib/lbuild/Makefile
 447                 contrib/scripts/Makefile
 448                 ldiskfs/Makefile
 449                 ldiskfs/autoMakefile
 450                 lustre-iokit/Makefile
 451                 lustre-iokit/obdfilter-survey/Makefile
 452                 lustre-iokit/ost-survey/Makefile
 453                 lustre-iokit/sgpdd-survey/Makefile
 454                 lustre-iokit/mds-survey/Makefile
 455                 lustre-iokit/ior-survey/Makefile
 456                 lustre-iokit/stats-collect/Makefile
 457         )
 458         AC_CONFIG_FILES([lustre/scripts/dkms.mkconf],
 459                         [chmod +x lustre/scripts/dkms.mkconf])
 460 ])
 461
 462 #
 463 # LB_CONFIG_SERVERS
 464 #
 465 AC_DEFUN([LB_CONFIG_SERVERS], [
 466 AC_ARG_ENABLE([server],
 467         AC_HELP_STRING([--disable-server],
 468                         [disable Lustre server support]), [
 469                 AS_IF([test x$enable_server != xyes -a x$enable_server != xno],
 470                         [AC_MSG_ERROR([server valid options are "yes" or "no"])])
 471                 AS_IF([test x$enable_server = xyes -a x$enable_dist = xyes],
 472                         [AC_MSG_ERROR([--enable-server cannot be used with --enable-dist])])
 473         ], [
 474                 AS_IF([test x$enable_dist = xyes],
 475                         [enable_server=no], [enable_server=maybe])
 476         ])
 477
 478 # There are at least two good reasons why we should really run
 479 # LB_CONFIG_MODULES elsewhere before the call to LB_CONFIG_SERVERS:
 480 # LB_CONFIG_MODULES needs to be run for client support even when
 481 # servers are disabled, and because module support is actually a
 482 # prerequisite of server support.  However, some things under
 483 # LB_CONFIG_MODULES need us to already have checked for --disable-server,
 484 # before running, so until LB_CONFIG_MODULES can be reorganized, we
 485 # call it here.
 486 LB_CONFIG_MODULES
 487 AS_IF([test x$enable_modules = xno], [enable_server=no])
 488 LB_CONFIG_LDISKFS
 489 LB_CONFIG_ZFS
 490
 491 # If no backends were configured, and the user did not explicitly
 492 # require servers to be enabled, we just disable servers.
 493 AS_IF([test x$enable_ldiskfs = xno -a x$enable_zfs = xno], [
 494         AS_CASE([$enable_server],
 495                 [maybe], [enable_server=no],
 496                 [yes], [AC_MSG_ERROR([cannot enable servers, no backends were configured])])
 497         ], [
 498                 AS_IF([test x$enable_server = xmaybe], [enable_server=yes])
 499         ])
 500
 501 AC_MSG_CHECKING([whether to build Lustre server support])
 502 AC_MSG_RESULT([$enable_server])
 503 AS_IF([test x$enable_server = xyes],
 504         [AC_DEFINE(HAVE_SERVER_SUPPORT, 1, [support server])])
 505 ]) # LB_CONFIG_SERVERS
 506
 507 #
 508 # LB_CONFIG_RPMBUILD_OPTIONS
 509 #
 510 # The purpose of this function is to assemble command line options
 511 # for the rpmbuild command based on the options passed to the configure
 512 # script, and also upon the decisions that configure makes based on
 513 # the tests that it runs.
 514 # These strings can be passed to rpmbuild on the command line
 515 # in the Make targets named "rpms" and "srpm".
 516 #
 517 AC_DEFUN([LB_CONFIG_RPMBUILD_OPTIONS], [
 518 RPMBINARGS=
 519 CONFIGURE_ARGS=
 520 eval set -- $ac_configure_args
 521 for arg; do
 522         case $arg in
 523                 --*dir=* ) ;;
 524                 -C | --cache-file=* ) ;;
 525                 --prefix=* | --*-prefix=* ) ;;
 526                 --enable-dist ) ;;
 527                 --with-release=* ) ;;
 528                 --with-kmp-moddir=* ) ;;
 529                 --with-linux=* | --with-linux-obj=* ) ;;
 530                 --enable-shared | --disable-shared ) ;;
 531                 --enable-static | --disable-static ) ;;
 532                 --enable-ldiskfs | --disable-ldiskfs ) ;;
 533                 --enable-modules | --disable-modules ) ;;
 534                 --enable-server | --disable-server ) ;;
 535                 --enable-tests | --disable-tests ) ;;
 536                 --enable-utils | --disable-utils ) ;;
 537                 --enable-iokit | --disable-iokit ) ;;
 538                 --enable-dlc | --disable-dlc ) ;;
 539                 --enable-manpages | --disable-manpages ) ;;
 540                 * ) CONFIGURE_ARGS="$CONFIGURE_ARGS '$arg'" ;;
 541         esac
 542 done
 543 if test -n "$CONFIGURE_ARGS" ; then
 544         RPMBINARGS="$RPMBINARGS --define \"configure_args $CONFIGURE_ARGS\""
 545 fi
 546 if test -n "$LINUX" ; then
 547         RPMBINARGS="$RPMBINARGS --define \"kdir $LINUX\""
 548         if test -n "$LINUX_OBJ" -a "$LINUX_OBJ" != x"$LINUX" ; then
 549                 RPMBINARGS="$RPMBINARGS --define \"kobjdir $LINUX_OBJ\""
 550         fi
 551 fi
 552 if test -n "$KMP_MODDIR" ; then
 553         RPMBINARGS="$RPMBINARGS --define \"kmoddir $KMP_MODDIR\""
 554 fi
 555 if test x$enable_modules != xyes ; then
 556         RPMBINARGS="$RPMBINARGS --without lustre_modules"
 557 fi
 558 if test x$enable_tests != xyes ; then
 559         RPMBINARGS="$RPMBINARGS --without lustre_tests"
 560 fi
 561 if test x$enable_utils != xyes ; then
 562         RPMBINARGS="$RPMBINARGS --without lustre_utils"
 563 fi
 564 if test x$enable_server != xyes ; then
 565         RPMBINARGS="$RPMBINARGS --without servers"
 566 fi
 567 if test x$enable_ldiskfs != xyes ; then
 568         RPMBINARGS="$RPMBINARGS --without ldiskfs"
 569 fi
 570 if test x$enable_zfs = xyes ; then
 571         RPMBINARGS="$RPMBINARGS --with zfs"
 572 fi
 573 if test x$enable_iokit != xyes ; then
 574         RPMBINARGS="$RPMBINARGS --without lustre_iokit"
 575 fi
 576 if test x$USE_DLC = xyes ; then
 577         RPMBINARGS="$RPMBINARGS --with lnet_dlc"
 578 fi
 579 if test x$enable_manpages != xyes ; then
 580         RPMBINARGS="$RPMBINARGS --without manpages"
 581 fi
 582 if test x$enable_shared != xyes ; then
 583         RPMBINARGS="$RPMBINARGS --without shared"
 584 fi
 585 if test x$enable_static != xyes ; then
 586         RPMBINARGS="$RPMBINARGS --without static"
 587 fi
 588
 589 RPMBUILD_BINARY_ARGS=$RPMBINARGS
 590
 591 AC_SUBST(RPMBUILD_BINARY_ARGS)
 592 ]) # LB_CONFIG_RPMBUILD_OPTIONS
 593
 594 #
 595 # LB_CONFIGURE
 596 #
 597 # main configure steps
 598 #
 599 AC_DEFUN([LB_CONFIGURE], [
 600 AC_MSG_NOTICE([Lustre base checks
 601 ==============================================================================])
 602 LB_CANONICAL_SYSTEM
 603
 604 LB_CONFIG_DIST
 605
 606 LB_DOWNSTREAM_RELEASE
 607 LB_USES_DPKG
 608 LB_BUILDID
 609
 610 LB_LIBCFS_DIR
 611
 612 LB_INCLUDE_RULES
 613
 614 LB_PATH_DEFAULTS
 615
 616 LB_PROG_CC
 617
 618 LC_OSD_ADDON
 619
 620 LB_CONFIG_DOCS
 621 LB_CONFIG_MANPAGES
 622 LB_CONFIG_UTILS
 623 LB_CONFIG_TESTS
 624 LC_CONFIG_CLIENT
 625 LB_CONFIG_MPITESTS
 626 LB_CONFIG_SERVERS
 627
 628 # Tests depends from utils (multiop from liblustreapi)
 629 AS_IF([test "x$enable_utils" = xno], [enable_tests="no"])
 630
 631 m4_ifdef([LC_NODEMAP_PROC_DEBUG], [LC_NODEMAP_PROC_DEBUG])
 632 LIBCFS_CONFIG_CDEBUG
 633 LC_QUOTA
 634
 635 LB_PATH_SNMP
 636 LB_PATH_LUSTREIOKIT
 637
 638 LB_DEFINE_E2FSPROGS_NAMES
 639
 640 LIBCFS_CONFIGURE
 641 LN_CONFIGURE
 642 LC_CONFIGURE
 643 AS_IF([test -n "$SNMP_DIST_SUBDIR"], [LS_CONFIGURE])
 644
 645 LB_CONDITIONALS
 646 LB_CONFIG_HEADERS
 647
 648 LIBCFS_CONFIG_FILES
 649 LB_CONFIG_FILES
 650 LN_CONFIG_FILES
 651 LC_CONFIG_FILES
 652 AS_IF([test -n "$SNMP_DIST_SUBDIR"], [LS_CONFIG_FILES])
 653
 654 AC_SUBST(ac_configure_args)
 655
 656 MOSTLYCLEANFILES='.*.cmd .*.flags *.o *.ko *.mod.c .depend .*.1.* Modules.symvers Module.symvers'
 657 AC_SUBST(MOSTLYCLEANFILES)
 658
 659 LB_CONFIG_RPMBUILD_OPTIONS
 660
 661 AC_OUTPUT
 662
 663 cat <<_ACEOF
 664
 665 CC:            $CC
 666 LD:            $LD
 667 CPPFLAGS:      $CPPFLAGS
 668 CFLAGS:        $CFLAGS
 669 EXTRA_KCFLAGS: $EXTRA_KCFLAGS
 670
 671 Type 'make' to build Lustre.
 672 _ACEOF
 673 ]) # LB_CONFIGURE