config/lustre-build.m4

   1 #
   2 # LB_CHECK_VERSION
   3 #
   4 # Verify that LUSTRE_VERSION was defined properly
   5 #
   6 AC_DEFUN([LB_CHECK_VERSION], [
   7 AS_IF([test "LUSTRE_VERSION" = "LUSTRE""_VERSION"],
   8         [AC_MSG_ERROR([This script was not built with a version number.])])
   9 ]) # LB_CHECK_VERSION
  10
  11 #
  12 # LB_CANONICAL_SYSTEM
  13 #
  14 # fixup $target_os for use in other places
  15 #
  16 AC_DEFUN([LB_CANONICAL_SYSTEM], [
  17 case $target_os in
  18         linux*)
  19                 lb_target_os="linux"
  20                 ;;
  21 esac
  22 AC_SUBST(lb_target_os)
  23 ]) # LB_CANONICAL_SYSTEM
  24
  25 #
  26 # LB_DOWNSTREAM_RELEASE
  27 #
  28 AC_DEFUN([LB_DOWNSTREAM_RELEASE],
  29 [AC_ARG_WITH([downstream-release],
  30         AC_HELP_STRING([--with-downstream-release=string],
  31                 [set a string in the BUILD_VERSION and RPM Release: (default is nothing)]),
  32         [DOWNSTREAM_RELEASE=$with_downstream_release],
  33         [ # if not specified, see if it's in the META file
  34         AS_IF([test -f META],
  35                 [DOWNSTREAM_RELEASE=$(sed -ne '/^LOCAL_VERSION =/s/.*= *//p' META)])
  36         ])
  37 AC_SUBST(DOWNSTREAM_RELEASE)
  38 ]) # LB_DOWNSTREAM_RELEASE
  39
  40 #
  41 # LB_BUILDID
  42 #
  43 # Check if the source is a GA release and if not, set a "BUILDID"
  44 #
  45 # Currently there are at least two ways/modes of/for doing this.  One
  46 # is if we are in a valid git repository, the other is if we are in a
  47 # non-git source tree of some form.  Building the latter from the former
  48 # will be handled here.
  49 AC_DEFUN([LB_BUILDID], [
  50 AC_CACHE_CHECK([for buildid], [lb_cv_buildid], [
  51 lb_cv_buildid=""
  52 AS_IF([git branch >/dev/null 2>&1], [
  53         ffw=0
  54         hash=""
  55         ver=$(git describe --match v[[0-9]]_*_[[0-9]]* --tags)
  56         if [[[ $ver = *-*-* ]]]; then
  57                 hash=${ver##*-}
  58                 ffw=${ver#*-}
  59                 ffw=${ffw%-*}
  60                 ver=${ver%%-*}
  61         fi
  62         # it's tempting to use [[ $ver =~ ^v([0-9]+_)+([0-9]+|RC[0-9]+)$ ]]
  63         # here but the portability of the regex on the right is dismal
  64         # (thanx suse)
  65         if echo "$ver" | egrep -q "^v([[0-9]]+_)+([[0-9]]+|RC[[0-9]]+)$"; then
  66                 ver=$(echo $ver | sed -e 's/^v\(.*\)/\1/' \
  67                                       -e 's/_RC[[0-9]].*$//' -e 's/_/./g')
  68         fi
  69
  70         # a "lustre fix" value of .0 should be truncated
  71         if [[[ $ver = *.*.*.0 ]]]; then
  72                 ver=${ver%.0}
  73         fi
  74         # ditto for a "lustre fix" value of _0
  75         if [[[ $ver = v*_*_*_0 ]]]; then
  76                 ver=${ver%_0}
  77         fi
  78         if [[[ $ver = v*_*_* ]]]; then
  79                 ver=${ver#v}
  80                 ver=${ver//_/.}
  81         fi
  82
  83         if test "$ver" != "$VERSION"; then
  84                 AC_MSG_WARN([most recent tag found: $ver does not match current version $VERSION.])
  85         fi
  86
  87         if test "$ffw" != "0"; then
  88                 lb_cv_buildid="$hash"
  89         fi
  90 ], [test -f META], [
  91         lb_cv_buildid=$(sed -ne '/^BUILDID =/s/.*= *//p' META)
  92 ])
  93 ])
  94 AS_IF([test -z "$lb_cv_buildid"], [
  95         AC_MSG_WARN([
  96
  97 FIXME: I don't know how to deal with source trees outside of git that
  98 don't have a META file. Not setting a buildid.
  99 ])
 100 ])
 101 BUILDID=$lb_cv_buildid
 102 AC_SUBST(BUILDID)
 103 ]) # LB_BUILDID
 104
 105 #
 106 # LB_CHECK_FILE
 107 #
 108 # Check for file existence even when cross compiling
 109 # $1 - file to check
 110 # $2 - do 'yes'
 111 # $3 - do 'no'
 112 #
 113 AC_DEFUN([LB_CHECK_FILE], [
 114 AS_VAR_PUSHDEF([lb_file], [lb_cv_file_$1])dnl
 115 AC_CACHE_CHECK([for $1], lb_file, [
 116 AS_IF([test -r "$1"],
 117         [AS_VAR_SET(lb_file, [yes])],
 118         [AS_VAR_SET(lb_file, [no])])
 119 ])
 120 AS_VAR_IF([lb_file], [yes], [$2], [$3])[]dnl
 121 AS_VAR_POPDEF([lb_file])dnl
 122 ]) # LB_CHECK_FILE
 123
 124 #
 125 # LB_ARG_LIBS_INCLUDES
 126 #
 127 # support for --with-foo, --with-foo-includes, and --with-foo-libs in
 128 # a single magical macro
 129 #
 130 AC_DEFUN([LB_ARG_LIBS_INCLUDES], [
 131 lb_pathvar="m4_bpatsubst([$2], -, _)"
 132 AC_MSG_CHECKING([for $1])
 133 AC_ARG_WITH([$2],
 134         AC_HELP_STRING([--with-$2=path],
 135                 [path to $1]),
 136         [], [withval=$4])
 137 AS_IF([test "x$withval" = xyes],
 138         [eval "$lb_pathvar='$3'"],
 139         [eval "$lb_pathvar='$withval'"])
 140 AC_MSG_RESULT([${!lb_pathvar:-no}])
 141
 142 AS_IF([test "x${!lb_pathvar}" != x -a "x${!lb_pathvar}" != xno], [
 143         AC_MSG_CHECKING([for $1 includes])
 144         AC_ARG_WITH([$2-includes],
 145                 AC_HELP_STRING([--with-$2-includes=path],
 146                         [path to $1 includes]),
 147                 [], [withval="yes"])
 148
 149         lb_includevar="${lb_pathvar}_includes"
 150         AS_IF([test "x$withval" = xyes],
 151                 [eval "${lb_includevar}='${!lb_pathvar}/include'"],
 152                 [eval "${lb_includevar}='$withval'"])
 153         AC_MSG_RESULT([${!lb_includevar}])
 154
 155         AC_MSG_CHECKING([for $1 libs])
 156         AC_ARG_WITH([$2-libs],
 157                 AC_HELP_STRING([--with-$2-libs=path],
 158                         [path to $1 libs]),
 159                 [], [withval="yes"])
 160
 161         lb_libvar="${lb_pathvar}_libs"
 162         AS_IF([test "x$withval" = xyes],
 163                 [eval "${lb_libvar}='${!lb_pathvar}/lib'"],
 164                 [eval "${lb_libvar}='$withval'"])
 165         AC_MSG_RESULT([${!lb_libvar}])
 166 ])
 167 ]) # LB_ARG_LIBS_INCLUDES
 168
 169 #
 170 # LB_PATH_LUSTREIOKIT
 171 #
 172 # We no longer handle external lustre-iokit
 173 #
 174 AC_DEFUN([LB_PATH_LUSTREIOKIT], [
 175 AC_MSG_CHECKING([whether to build iokit])
 176 AC_ARG_ENABLE([iokit],
 177         AC_HELP_STRING([--disable-iokit],
 178                 [disable iokit (default is enable)]),
 179         [], [enable_iokit="yes"])
 180 AC_MSG_RESULT([$enable_iokit])
 181 AS_IF([test "x$enable_iokit" = xyes],
 182         [LUSTREIOKIT_SUBDIR="lustre-iokit"],
 183         [LUSTREIOKIT_SUBDIR=""])
 184 AC_SUBST(LUSTREIOKIT_SUBDIR)
 185 AM_CONDITIONAL([BUILD_LUSTREIOKIT], [test "x$enable_iokit" = xyes])
 186 ]) # LB_PATH_LUSTREIOKIT
 187
 188 # Define no libcfs by default.
 189 AC_DEFUN([LB_LIBCFS_DIR], [
 190 AS_IF([test "x$libcfs_is_module" = xyes], [
 191                 LIBCFS_INCLUDE_DIR="libcfs/include"
 192                 LIBCFS_SUBDIR="libcfs"
 193         ], [
 194                 LIBCFS_INCLUDE_DIR="lnet/include"
 195                 LIBCFS_SUBDIR=""
 196         ])
 197 AC_SUBST(LIBCFS_INCLUDE_DIR)
 198 AC_SUBST(LIBCFS_SUBDIR)
 199 ]) # LB_LIBCFS_DIR
 200
 201 #
 202 # LB_PATH_SNMP
 203 #
 204 # check for in-tree snmp support
 205 #
 206 AC_DEFUN([LB_PATH_SNMP], [
 207 LB_CHECK_FILE([$srcdir/snmp/lustre-snmp.c], [SNMP_DIST_SUBDIR="snmp"])
 208 AC_SUBST(SNMP_DIST_SUBDIR)
 209 AC_SUBST(SNMP_SUBDIR)
 210 ]) # LB_PATH_SNMP
 211
 212 #
 213 # LB_CONFIG_MODULES
 214 #
 215 # Build kernel modules?
 216 #
 217 AC_DEFUN([LB_CONFIG_MODULES], [
 218 AC_MSG_CHECKING([whether to build Linux kernel modules])
 219 AC_ARG_ENABLE([modules],
 220         AC_HELP_STRING([--disable-modules],
 221                 [disable building of Lustre kernel modules]),
 222         [], [
 223                 LC_TARGET_SUPPORTED([enable_modules="yes"],
 224                                     [enable_modules="no"])
 225         ])
 226 AC_MSG_RESULT([$enable_modules ($target_os)])
 227
 228 AS_IF([test "x$enable_modules" = xyes], [
 229         AS_CASE([$target_os],
 230                 [linux*], [
 231                         LB_PROG_LINUX
 232                         LIBCFS_PROG_LINUX
 233                         LN_PROG_LINUX
 234                         AS_IF([test "x$enable_server" != xno], [LB_EXT4_SRC_DIR])
 235                         LC_PROG_LINUX
 236                 ], [*], [
 237                         # This is strange - Lustre supports a target we don't
 238                         AC_MSG_ERROR([Modules are not supported on $target_os])
 239                 ])
 240         ])
 241 ]) # LB_CONFIG_MODULES
 242
 243 #
 244 # LB_CONFIG_UTILS
 245 #
 246 # Build utils?
 247 #
 248 AC_DEFUN([LB_CONFIG_UTILS], [
 249 AC_MSG_CHECKING([whether to build Lustre utilities])
 250 AC_ARG_ENABLE([utils],
 251         AC_HELP_STRING([--disable-utils],
 252                 [disable building of Lustre utility programs]),
 253         [], [enable_utils="yes"])
 254 AC_MSG_RESULT([$enable_utils])
 255 ]) # LB_CONFIG_UTILS
 256
 257 #
 258 # LB_CONFIG_TESTS
 259 #
 260 # Build tests?
 261 #
 262 AC_DEFUN([LB_CONFIG_TESTS], [
 263 AC_MSG_CHECKING([whether to build Lustre tests])
 264 AC_ARG_ENABLE([tests],
 265         AC_HELP_STRING([--disable-tests],
 266                 [disable building of Lustre tests]),
 267         [], [enable_tests="yes"])
 268 AC_MSG_RESULT([$enable_tests])
 269 ]) # LB_CONFIG_TESTS
 270
 271 #
 272 # LB_CONFIG_DIST
 273 #
 274 # Just enough configure so that "make dist" is useful
 275 #
 276 # this simply re-adjusts some defaults, which of course can be overridden
 277 # on the configure line after the --for-dist option
 278 #
 279 AC_DEFUN([LB_CONFIG_DIST], [
 280 AC_MSG_CHECKING([whether to configure just enough for make dist])
 281 AC_ARG_ENABLE([dist],
 282         AC_HELP_STRING([--enable-dist],
 283                         [only configure enough for make dist]),
 284         [], [enable_dist="no"])
 285 AC_MSG_RESULT([$enable_dist])
 286 AS_IF([test "x$enable_dist" != xno], [
 287         enable_doc="no"
 288         enable_utils="no"
 289         enable_tests="no"
 290         enable_modules="no"
 291 ])
 292 ]) # LB_CONFIG_DIST
 293
 294 #
 295 # LB_CONFIG_DOCS
 296 #
 297 # Build docs?
 298 #
 299 AC_DEFUN([LB_CONFIG_DOCS], [
 300 AC_MSG_CHECKING([whether to build Lustre docs])
 301 AC_ARG_ENABLE([doc],
 302         AC_HELP_STRING([--disable-doc],
 303                         [skip creation of pdf documentation]),
 304         [], [enable_doc="no"])
 305 AC_MSG_RESULT([$enable_doc])
 306 AS_IF([test "x$enable_doc" = xyes],
 307         [ENABLE_DOC=1], [ENABLE_DOC=0])
 308 AC_SUBST(ENABLE_DOC)
 309 ]) # LB_CONFIG_DOCS
 310
 311 #
 312 # LB_CONFIG_MANPAGES
 313 #
 314 # Build manpages?
 315 #
 316 AC_DEFUN([LB_CONFIG_MANPAGES], [
 317 AC_MSG_CHECKING([whether to build Lustre manpages])
 318 AC_ARG_ENABLE([manpages],
 319         AC_HELP_STRING([--disable-manpages],
 320                         [skip creation and inclusion of man pages (default is enable)]),
 321         [], [enable_manpages="yes"])
 322 AC_MSG_RESULT([$enable_manpages])
 323 AS_IF([test "x$enable_manpages" = xyes], [
 324 AC_CHECK_PROGS(RST2MAN, [rst2man rst2man.py], [])
 325   if test "x$RST2MAN" = "x"; then
 326     AC_MSG_ERROR(
 327       [rst2man is needed to build the man pages. Install python-docutils.])
 328 fi
 329 ])
 330 ]) # LB_CONFIG_MANPAGES
 331
 332 #
 333 # LB_CONFIG_HEADERS
 334 #
 335 # add -include config.h
 336 #
 337 AC_DEFUN([LB_CONFIG_HEADERS], [
 338 AC_CONFIG_HEADERS([config.h])
 339 CPPFLAGS="-include $PWD/undef.h -include $PWD/config.h $CPPFLAGS"
 340 EXTRA_KCFLAGS="-include $PWD/undef.h -include $PWD/config.h $EXTRA_KCFLAGS"
 341 AC_SUBST(EXTRA_KCFLAGS)
 342 ]) # LB_CONFIG_HEADERS
 343
 344 #
 345 # LB_INCLUDE_RULES
 346 #
 347 # defines for including the toplevel Rules
 348 #
 349 AC_DEFUN([LB_INCLUDE_RULES], [
 350 INCLUDE_RULES="include $PWD/Rules"
 351 AC_SUBST(INCLUDE_RULES)
 352 ]) # LB_INCLUDE_RULES
 353
 354 #
 355 # LB_PATH_DEFAULTS
 356 #
 357 # 'fixup' default paths
 358 #
 359 AC_DEFUN([LB_PATH_DEFAULTS], [
 360 # directories for binaries
 361 AC_PREFIX_DEFAULT([/usr])
 362
 363 sysconfdir='$(CROSS_PATH)/etc'
 364 AC_SUBST(sysconfdir)
 365
 366 # Directories for documentation and demos.
 367 docdir='$(datadir)/doc/$(PACKAGE)'
 368 AC_SUBST(docdir)
 369
 370 LIBCFS_PATH_DEFAULTS
 371 LN_PATH_DEFAULTS
 372 LC_PATH_DEFAULTS
 373 ]) # LB_PATH_DEFAULTS
 374
 375 #
 376 # LB_PROG_CC
 377 #
 378 # checks on the C compiler
 379 #
 380 AC_DEFUN([LB_PROG_CC], [
 381 AC_PROG_RANLIB
 382 AC_CHECK_TOOL(LD, [ld], [no])
 383 AC_CHECK_TOOL(OBJDUMP, [objdump], [no])
 384 AC_CHECK_TOOL(STRIP, [strip], [no])
 385
 386 # ---------  unsigned long long sane? -------
 387 AC_CHECK_SIZEOF(unsigned long long, 0)
 388 AS_IF([test $ac_cv_sizeof_unsigned_long_long != 8],
 389         [AC_MSG_ERROR([we assume that sizeof(unsigned long long) == 8.])])
 390
 391 AS_IF([test $target_cpu = powerpc64], [
 392         AC_MSG_WARN([set compiler with -m64])
 393         CFLAGS="$CFLAGS -m64"
 394         CC="$CC -m64"
 395 ])
 396
 397 CPPFLAGS="-I$PWD/$LIBCFS_INCLUDE_DIR -I$PWD/lnet/include -I$PWD/lustre/include $CPPFLAGS"
 398
 399 CCASFLAGS="-Wall -fPIC -D_GNU_SOURCE"
 400 AC_SUBST(CCASFLAGS)
 401
 402 # everyone builds against lnet and lustre
 403 EXTRA_KCFLAGS="$EXTRA_KCFLAGS -g -I$PWD/$LIBCFS_INCLUDE_DIR -I$PWD/lnet/include -I$PWD/lustre/include"
 404 AC_SUBST(EXTRA_KCFLAGS)
 405 ]) # LB_PROG_CC
 406
 407 #
 408 # LB_CONDITIONALS
 409 #
 410 # AM_CONDITIONAL instances for everything
 411 # (so that portals/lustre can disable some if needed)
 412 #
 413 AC_DEFUN([LB_CONDITIONALS], [
 414 AM_CONDITIONAL([MODULES], [test x$enable_modules = xyes])
 415 AM_CONDITIONAL([UTILS], [test x$enable_utils = xyes])
 416 AM_CONDITIONAL([TESTS], [test x$enable_tests = xyes])
 417 AM_CONDITIONAL([DOC], [test x$ENABLE_DOC = x1])
 418 AM_CONDITIONAL([MANPAGES], [test x$enable_manpages = xyes])
 419 AM_CONDITIONAL([LINUX], [test x$lb_target_os = xlinux])
 420 AM_CONDITIONAL([USES_DPKG], [test x$uses_dpkg = xyes])
 421 AM_CONDITIONAL([USE_QUILT], [test x$use_quilt = xyes])
 422 AM_CONDITIONAL([RHEL], [test x$RHEL_KERNEL = xyes])
 423 AM_CONDITIONAL([SUSE], [test x$SUSE_KERNEL = xyes])
 424
 425 # Sanity check for PCLMULQDQ instruction availability
 426 # PCLMULQDQ instruction is a new instruction available beginning with
 427 # the all new Core processor family based on the 32nm microarchitecture
 428 # codename Westmere. So, $target_cpu = x86_64 should have this instruction
 429 # except MIC microarchitecture (k1om).
 430 AM_CONDITIONAL(HAVE_PCLMULQDQ, test x$target_cpu = "xx86_64" -a x$target_vendor != "xk1om")
 431 AS_IF([test x$target_cpu = "xx86_64" -a x$target_vendor != "xk1om"],
 432         [AC_DEFINE(HAVE_PCLMULQDQ, 1, [have PCLMULQDQ instruction])])
 433
 434 LIBCFS_CONDITIONALS
 435 LN_CONDITIONALS
 436 LC_CONDITIONALS
 437 ]) # LB_CONDITIONALS
 438
 439 #
 440 # LB_CONFIG_FILES
 441 #
 442 # build-specific config files
 443 #
 444 AC_DEFUN([LB_CONFIG_FILES], [
 445         AC_CONFIG_FILES([
 446                 Makefile
 447                 autoMakefile]
 448                 config/Makefile
 449                 [Rules:build/Rules.in]
 450                 AC_PACKAGE_TARNAME[.spec]
 451                 AC_PACKAGE_TARNAME[-dkms.spec]
 452                 lustre/scripts/dkms.mkconf
 453                 contrib/Makefile
 454                 contrib/lbuild/Makefile
 455                 contrib/scripts/Makefile
 456                 ldiskfs/Makefile
 457                 ldiskfs/autoMakefile
 458                 lustre-iokit/Makefile
 459                 lustre-iokit/obdfilter-survey/Makefile
 460                 lustre-iokit/ost-survey/Makefile
 461                 lustre-iokit/sgpdd-survey/Makefile
 462                 lustre-iokit/mds-survey/Makefile
 463                 lustre-iokit/ior-survey/Makefile
 464                 lustre-iokit/stats-collect/Makefile,
 465                 [chmod +x lustre/scripts/dkms.mkconf]
 466         )
 467 ])
 468
 469 #
 470 # LB_CONFIG_SERVERS
 471 #
 472 AC_DEFUN([LB_CONFIG_SERVERS], [
 473 AC_ARG_ENABLE([server],
 474         AC_HELP_STRING([--disable-server],
 475                         [disable Lustre server support]), [
 476                 AS_IF([test x$enable_server != xyes -a x$enable_server != xno],
 477                         [AC_MSG_ERROR([server valid options are "yes" or "no"])])
 478                 AS_IF([test x$enable_server = xyes -a x$enable_dist = xyes],
 479                         [AC_MSG_ERROR([--enable-server cannot be used with --enable-dist])])
 480         ], [
 481                 AS_IF([test x$enable_dist = xyes],
 482                         [enable_server=no], [enable_server=maybe])
 483         ])
 484
 485 # There are at least two good reasons why we should really run
 486 # LB_CONFIG_MODULES elsewhere before the call to LB_CONFIG_SERVERS:
 487 # LB_CONFIG_MODULES needs to be run for client support even when
 488 # servers are disabled, and because module support is actually a
 489 # prerequisite of server support.  However, some things under
 490 # LB_CONFIG_MODULES need us to already have checked for --disable-server,
 491 # before running, so until LB_CONFIG_MODULES can be reorganized, we
 492 # call it here.
 493 LB_CONFIG_MODULES
 494 AS_IF([test x$enable_modules = xno], [enable_server=no])
 495 LB_CONFIG_LDISKFS
 496 LB_CONFIG_ZFS
 497
 498 # If no backends were configured, and the user did not explicitly
 499 # require servers to be enabled, we just disable servers.
 500 AS_IF([test x$enable_ldiskfs = xno -a x$enable_zfs = xno], [
 501         AS_CASE([$enable_server],
 502                 [maybe], [enable_server=no],
 503                 [yes], [AC_MSG_ERROR([cannot enable servers, no backends were configured])])
 504         ], [
 505                 AS_IF([test x$enable_server = xmaybe], [enable_server=yes])
 506         ])
 507
 508 AC_MSG_CHECKING([whether to build Lustre server support])
 509 AC_MSG_RESULT([$enable_server])
 510 AS_IF([test x$enable_server = xyes],
 511         [AC_DEFINE(HAVE_SERVER_SUPPORT, 1, [support server])])
 512 ]) # LB_CONFIG_SERVERS
 513
 514 #
 515 # LB_CONFIG_RPMBUILD_OPTIONS
 516 #
 517 # The purpose of this function is to assemble command line options
 518 # for the rpmbuild command based on the options passed to the configure
 519 # script, and also upon the decisions that configure makes based on
 520 # the tests that it runs.
 521 # These strings can be passed to rpmbuild on the command line
 522 # in the Make targets named "rpms" and "srpm".
 523 #
 524 AC_DEFUN([LB_CONFIG_RPMBUILD_OPTIONS], [
 525 RPMBINARGS=
 526 CONFIGURE_ARGS=
 527 eval set -- $ac_configure_args
 528 for arg; do
 529         case $arg in
 530                 --*dir=* ) ;;
 531                 -C | --cache-file=* ) ;;
 532                 --prefix=* | --*-prefix=* ) ;;
 533                 --enable-dist ) ;;
 534                 --with-release=* ) ;;
 535                 --with-kmp-moddir=* ) ;;
 536                 --with-linux=* | --with-linux-obj=* ) ;;
 537                 --enable-ldiskfs | --disable-ldiskfs ) ;;
 538                 --enable-modules | --disable-modules ) ;;
 539                 --enable-server | --disable-server ) ;;
 540                 --enable-tests | --disable-tests ) ;;
 541                 --enable-utils | --disable-utils ) ;;
 542                 --enable-iokit | --disable-iokit ) ;;
 543                 --enable-dlc | --disable-dlc ) ;;
 544                 --enable-manpages | --disable-manpages ) ;;
 545                 * ) CONFIGURE_ARGS="$CONFIGURE_ARGS '$arg'" ;;
 546         esac
 547 done
 548 if test -n "$CONFIGURE_ARGS" ; then
 549         RPMBINARGS="$RPMBINARGS --define \"configure_args $CONFIGURE_ARGS\""
 550 fi
 551 if test -n "$LINUX" ; then
 552         RPMBINARGS="$RPMBINARGS --define \"kdir $LINUX\""
 553         if test -n "$LINUX_OBJ" -a "$LINUX_OBJ" != x"$LINUX" ; then
 554                 RPMBINARGS="$RPMBINARGS --define \"kobjdir $LINUX_OBJ\""
 555         fi
 556 fi
 557 if test -n "$KMP_MODDIR" ; then
 558         RPMBINARGS="$RPMBINARGS --define \"kmoddir $KMP_MODDIR\""
 559 fi
 560 if test -n "$CROSS_PATH" ; then
 561         if test x$enable_server = xyes ; then
 562                 echo -e "\n"
 563                 "*** Don't support cross compilation for the Intel(R) Xeon Phi(TM) card.\n"
 564                 exit 1
 565         fi
 566         CROSS_SUFFIX="-mic"
 567         RPMBINARGS="$RPMBINARGS --define \"post_script build/gen_filelist.sh\""
 568         RPMBINARGS="$RPMBINARGS --define \"cross_path $CROSS_PATH\""
 569         RPMBINARGS="$RPMBINARGS --define \"rootdir %{cross_path}\""
 570         RPMBINARGS="$RPMBINARGS --define \"_prefix %{cross_path}/usr\""
 571         RPMBINARGS="$RPMBINARGS --define \"_mandir %{_prefix}/share/man\""
 572         RPMBINARGS="$RPMBINARGS --define \"_sysconfdir %{cross_path}/etc\""
 573         RPMBINARGS="$RPMBINARGS --define \"make_args $CROSS_VARS\""
 574         if test x$CC_TARGET_ARCH = x"x86_64-k1om-linux" ; then
 575                 RPMBINARGS="$RPMBINARGS --define \"cross_requires intel-mic-gpl\""
 576         fi
 577 fi
 578 if test x$enable_modules != xyes ; then
 579         RPMBINARGS="$RPMBINARGS --without lustre_modules"
 580 fi
 581 if test x$enable_tests != xyes ; then
 582         RPMBINARGS="$RPMBINARGS --without lustre_tests"
 583 fi
 584 if test x$enable_utils != xyes ; then
 585         RPMBINARGS="$RPMBINARGS --without lustre_utils"
 586 fi
 587 if test x$enable_server != xyes ; then
 588         RPMBINARGS="$RPMBINARGS --without servers"
 589         if test -n "$CROSS_SUFFIX" ; then
 590                 RPMBINARGS="$RPMBINARGS --define \"lustre_name lustre-client$CROSS_SUFFIX\""
 591         fi
 592 fi
 593 if test x$enable_ldiskfs != xyes ; then
 594         RPMBINARGS="$RPMBINARGS --without ldiskfs"
 595 fi
 596 if test x$enable_zfs = xyes ; then
 597         RPMBINARGS="$RPMBINARGS --with zfs"
 598 fi
 599 if test x$enable_iokit != xyes ; then
 600         RPMBINARGS="$RPMBINARGS --without lustre_iokit"
 601 fi
 602 if test x$USE_DLC = xyes ; then
 603         RPMBINARGS="$RPMBINARGS --with lnet_dlc"
 604 fi
 605 if test x$enable_manpages != xyes ; then
 606         RPMBINARGS="$RPMBINARGS --without manpages"
 607 fi
 608
 609 RPMBUILD_BINARY_ARGS=$RPMBINARGS
 610
 611 AC_SUBST(RPMBUILD_BINARY_ARGS)
 612 ]) # LB_CONFIG_RPMBUILD_OPTIONS
 613
 614 #
 615 # LB_CONFIGURE
 616 #
 617 # main configure steps
 618 #
 619 AC_DEFUN([LB_CONFIGURE], [
 620 AC_MSG_NOTICE([Lustre base checks
 621 ==============================================================================])
 622 LB_CANONICAL_SYSTEM
 623
 624 LB_CONFIG_DIST
 625
 626 LB_DOWNSTREAM_RELEASE
 627 LB_USES_DPKG
 628 LB_BUILDID
 629
 630 LB_LIBCFS_DIR
 631
 632 LB_INCLUDE_RULES
 633
 634 LB_PATH_DEFAULTS
 635
 636 LB_PROG_CC
 637
 638 LC_OSD_ADDON
 639
 640 LB_CONFIG_DOCS
 641 LB_CONFIG_MANPAGES
 642 LB_CONFIG_UTILS
 643 LB_CONFIG_TESTS
 644 LC_CONFIG_CLIENT
 645 LB_CONFIG_MPITESTS
 646 LB_CONFIG_SERVERS
 647
 648 # Tests depends from utils (multiop from liblustreapi)
 649 AS_IF([test "x$enable_utils" = xno], [enable_tests="no"])
 650
 651 m4_ifdef([LC_NODEMAP_PROC_DEBUG], [LC_NODEMAP_PROC_DEBUG])
 652 LIBCFS_CONFIG_CDEBUG
 653 LC_QUOTA
 654
 655 LB_PATH_SNMP
 656 LB_PATH_LUSTREIOKIT
 657
 658 LB_DEFINE_E2FSPROGS_NAMES
 659
 660 LIBCFS_CONFIGURE
 661 LN_CONFIGURE
 662 LC_CONFIGURE
 663 AS_IF([test -n "$SNMP_DIST_SUBDIR"], [LS_CONFIGURE])
 664
 665 LB_CONDITIONALS
 666 LB_CONFIG_HEADERS
 667
 668 LIBCFS_CONFIG_FILES
 669 LB_CONFIG_FILES
 670 LN_CONFIG_FILES
 671 LC_CONFIG_FILES
 672 AS_IF([test -n "$SNMP_DIST_SUBDIR"], [LS_CONFIG_FILES])
 673
 674 AC_SUBST(ac_configure_args)
 675
 676 MOSTLYCLEANFILES='.*.cmd .*.flags *.o *.ko *.mod.c .depend .*.1.* Modules.symvers Module.symvers'
 677 AC_SUBST(MOSTLYCLEANFILES)
 678
 679 LB_CONFIG_RPMBUILD_OPTIONS
 680
 681 AC_OUTPUT
 682
 683 cat <<_ACEOF
 684
 685 CC:            $CC
 686 LD:            $LD
 687 CPPFLAGS:      $CPPFLAGS
 688 CFLAGS:        $CFLAGS
 689 EXTRA_KCFLAGS: $EXTRA_KCFLAGS
 690
 691 Type 'make' to build Lustre.
 692 _ACEOF
 693 ]) # LB_CONFIGURE