config/lustre-build-linux.m4

   1 #
   2 # LB_LINUX_VERSION
   3 #
   4 # Set things accordingly for a linux kernel
   5 #
   6 AC_DEFUN([LB_LINUX_VERSION],[
   7 KMODEXT=".ko"
   8
   9 MODULE_TARGET="SUBDIRS"
  10 makerule="$PWD/build"
  11 AC_MSG_CHECKING([for external module build support])
  12 rm -f build/conftest.i
  13 LB_LINUX_TRY_MAKE([],[],
  14         [$makerule LUSTRE_KERNEL_TEST=conftest.i],
  15         [test -s build/conftest.i],
  16         [
  17                 AC_MSG_RESULT([no])
  18         ],[
  19                 makerule="_module_$makerule"
  20                 MODULE_TARGET="M"
  21                 LB_LINUX_TRY_MAKE([],[],
  22                         [$makerule LUSTRE_KERNEL_TEST=conftest.i],
  23                         [test -s build/conftest.i],
  24                         [
  25                                 AC_MSG_RESULT([yes])
  26                         ],[
  27                                 AC_MSG_ERROR([unknown; check config.log for details])
  28                         ])
  29         ])
  30
  31 AC_SUBST(MODULE_TARGET)
  32 AC_SUBST(KMODEXT)
  33 ])
  34
  35 #
  36 # LB_LINUX_RELEASE
  37 #
  38 # get the release version of linux
  39 #
  40 AC_DEFUN([LB_LINUX_RELEASE],
  41 [LINUXRELEASE=
  42 rm -f build/conftest.i
  43 AC_MSG_CHECKING([for Linux release])
  44 if test -s $LINUX_OBJ/include/$AUTOCONF_HDIR/utsrelease.h ; then
  45         LINUXRELEASEHEADER=$AUTOCONF_HDIR/utsrelease.h
  46 else
  47         LINUXRELEASEHEADER=linux/version.h
  48 fi
  49 LB_LINUX_TRY_MAKE([
  50         #include <$LINUXRELEASEHEADER>
  51 ],[
  52         char *LINUXRELEASE;
  53         LINUXRELEASE=UTS_RELEASE;
  54 ],[
  55         $makerule LUSTRE_KERNEL_TEST=conftest.i
  56 ],[
  57         test -s build/conftest.i
  58 ],[
  59         # LINUXRELEASE="UTS_RELEASE"
  60         eval $(grep "LINUXRELEASE=" build/conftest.i)
  61 ],[
  62         AC_MSG_RESULT([unknown])
  63         AC_MSG_ERROR([Could not preprocess test program.  Consult config.log for details.])
  64 ])
  65 rm -f build/conftest.i
  66 if test x$LINUXRELEASE = x ; then
  67         AC_MSG_RESULT([unknown])
  68         AC_MSG_ERROR([Could not determine Linux release version from linux/version.h.])
  69 fi
  70 AC_MSG_RESULT([$LINUXRELEASE])
  71 AC_SUBST(LINUXRELEASE)
  72
  73 moduledir='/lib/modules/'$LINUXRELEASE/updates/kernel
  74 AC_SUBST(moduledir)
  75
  76 modulefsdir='$(moduledir)/fs/$(PACKAGE)'
  77 AC_SUBST(modulefsdir)
  78
  79 modulenetdir='$(moduledir)/net/$(PACKAGE)'
  80 AC_SUBST(modulenetdir)
  81
  82 # ------------ RELEASE --------------------------------
  83 AC_MSG_CHECKING([for Lustre release])
  84 AC_ARG_WITH([release],
  85         AC_HELP_STRING([--with-release=string],
  86                        [set the release string (default=$kvers_YYYYMMDDhhmm)]),
  87         [RELEASE=$withval],
  88         RELEASE=""
  89         if test -n "$DOWNSTREAM_RELEASE"; then
  90                 RELEASE="${DOWNSTREAM_RELEASE}_"
  91         fi
  92         RELEASE="$RELEASE`echo ${LINUXRELEASE} | tr '-' '_'`_$BUILDID")
  93 AC_MSG_RESULT($RELEASE)
  94 AC_SUBST(RELEASE)
  95
  96 # check is redhat/suse kernels
  97 AC_MSG_CHECKING([that RedHat kernel])
  98 LB_LINUX_TRY_COMPILE([
  99                 #include <linux/version.h>
 100         ],[
 101                 #ifndef RHEL_RELEASE_CODE
 102                 #error "not redhat kernel"
 103                 #endif
 104         ],[
 105                 RHEL_KERNEL="yes"
 106                 AC_MSG_RESULT([yes])
 107         ],[
 108                 AC_MSG_RESULT([no])
 109 ])
 110
 111 LB_LINUX_CONFIG([SUSE_KERNEL],[SUSE_KERNEL="yes"],[])
 112
 113 ])
 114
 115 # LB_ARG_REPLACE_PATH(PACKAGE, PATH)
 116 AC_DEFUN([LB_ARG_REPLACE_PATH],[
 117         new_configure_args=
 118         eval "set x $ac_configure_args"
 119         shift
 120         for arg; do
 121                 case $arg in
 122                         --with-[$1]=*)
 123                                 arg=--with-[$1]=[$2]
 124                                 ;;
 125                         *\'*)
 126                                 arg=$(printf %s\n ["$arg"] | \
 127                                       sed "s/'/'\\\\\\\\''/g")
 128                                 ;;
 129                 esac
 130                 dnl AS_VAR_APPEND([new_configure_args], [" '$arg'"])
 131                 new_configure_args="$new_configure_args \"$arg\""
 132         done
 133         ac_configure_args=$new_configure_args
 134 ])
 135
 136 # this is the work-horse of the next function
 137 AC_DEFUN([__LB_ARG_CANON_PATH], [
 138         [$3]=$(readlink -f $with_$2)
 139         LB_ARG_REPLACE_PATH([$1], $[$3])
 140 ])
 141
 142 # a front-end for the above function that transforms - and . in the
 143 # PACKAGE portion of --with-PACKAGE into _ suitable for variable names
 144 AC_DEFUN([LB_ARG_CANON_PATH], [
 145         __LB_ARG_CANON_PATH([$1], m4_translit([$1], [-.], [__]), [$2])
 146 ])
 147
 148 #
 149 #
 150 # LB_LINUX_PATH
 151 #
 152 # Find paths for linux, handling kernel-source rpms
 153 #
 154 AC_DEFUN([LB_LINUX_PATH],
 155 [# prep some default values
 156 for DEFAULT_LINUX in /lib/modules/$(uname -r)/{source,build} /usr/src/linux; do
 157         if readlink -q -e $DEFAULT_LINUX; then
 158                 break
 159         fi
 160 done
 161 if test "$DEFAULT_LINUX" = "/lib/modules/$(uname -r)/source"; then
 162         PATHS="/lib/modules/$(uname -r)/build"
 163 fi
 164 PATHS+=" $DEFAULT_LINUX"
 165 for DEFAULT_LINUX_OBJ in $PATHS; do
 166         if readlink -q -e $DEFAULT_LINUX_OBJ; then
 167                 break
 168         fi
 169 done
 170 AC_MSG_CHECKING([for Linux sources])
 171 AC_ARG_WITH([linux],
 172         AC_HELP_STRING([--with-linux=path],
 173                        [set path to Linux source (default=/lib/modules/$(uname -r)/{source,build},/usr/src/linux)]),
 174         [LB_ARG_CANON_PATH([linux], [LINUX])
 175         DEFAULT_LINUX_OBJ=$LINUX],
 176         [LINUX=$DEFAULT_LINUX])
 177 AC_MSG_RESULT([$LINUX])
 178 AC_SUBST(LINUX)
 179
 180 # -------- check for linux --------
 181 LB_CHECK_FILE([$LINUX],[],
 182         [AC_MSG_ERROR([Kernel source $LINUX could not be found.])])
 183
 184 # -------- linux objects (for 2.6) --
 185 AC_MSG_CHECKING([for Linux objects dir])
 186 AC_ARG_WITH([linux-obj],
 187         AC_HELP_STRING([--with-linux-obj=path],
 188                         [set path to Linux objects dir (default=/lib/modules/$(uname -r)/build,/usr/src/linux)]),
 189         [LB_ARG_CANON_PATH([linux-obj], [LINUX_OBJ])],
 190         [LINUX_OBJ=$DEFAULT_LINUX_OBJ])
 191
 192 AC_MSG_RESULT([$LINUX_OBJ])
 193 AC_SUBST(LINUX_OBJ)
 194
 195 # -------- check for .config --------
 196 AC_ARG_WITH([linux-config],
 197         [AC_HELP_STRING([--with-linux-config=path],
 198                         [set path to Linux .conf (default=$LINUX_OBJ/.config)])],
 199         [LB_ARG_CANON_PATH([linux-config], [LINUX_CONFIG])],
 200         [LINUX_CONFIG=$LINUX_OBJ/.config])
 201 AC_SUBST(LINUX_CONFIG)
 202
 203 LB_CHECK_FILE([/boot/kernel.h],
 204         [KERNEL_SOURCE_HEADER='/boot/kernel.h'],
 205         [LB_CHECK_FILE([/var/adm/running-kernel.h],
 206                 [KERNEL_SOURCE_HEADER='/var/adm/running-kernel.h'])])
 207
 208 AC_ARG_WITH([kernel-source-header],
 209         AC_HELP_STRING([--with-kernel-source-header=path],
 210                         [Use a different kernel version header.  Consult build/README.kernel-source for details.]),
 211         [LB_ARG_CANON_PATH([kernel-source-header], [KERNEL_SOURCE_HEADER])])
 212
 213 # ------------ .config exists ----------------
 214 LB_CHECK_FILE([$LINUX_CONFIG],[],
 215         [AC_MSG_ERROR([Kernel config could not be found.  If you are building from a kernel-source rpm consult build/README.kernel-source])])
 216
 217 # ----------- make dep run? ------------------
 218 # at 2.6.19 # $LINUX/include/linux/config.h is removed
 219 # and at more old has only one line
 220 # include <autoconf.h>
 221 LB_CHECK_FILE([$LINUX_OBJ/include/generated/autoconf.h],[AUTOCONF_HDIR=generated],
 222         [LB_CHECK_FILE([$LINUX_OBJ/include/linux/autoconf.h],[AUTOCONF_HDIR=linux],
 223         [AC_MSG_ERROR([Run make config in $LINUX.])])])
 224         AC_SUBST(AUTOCONF_HDIR)
 225 LB_CHECK_FILE([$LINUX_OBJ/include/linux/version.h],[],
 226         [AC_MSG_ERROR([Run make config in $LINUX.])])
 227
 228 # ----------- kconfig.h exists ---------------
 229 # kernel 3.1, $LINUX/include/linux/kconfig.h is added
 230 # see kernel commit 2a11c8ea20bf850b3a2c60db8c2e7497d28aba99
 231 LB_CHECK_FILE([$LINUX_OBJ/include/linux/kconfig.h],
 232               [CONFIG_INCLUDE=include/linux/kconfig.h],
 233               [CONFIG_INCLUDE=include/$AUTOCONF_HDIR/autoconf.h])
 234         AC_SUBST(CONFIG_INCLUDE)
 235
 236 # ------------ rhconfig.h includes runtime-generated bits --
 237 # red hat kernel-source checks
 238
 239 # we know this exists after the check above.  if the user
 240 # tarred up the tree and ran make dep etc. in it, then
 241 # version.h gets overwritten with a standard linux one.
 242
 243 if grep rhconfig $LINUX_OBJ/include/linux/version.h >/dev/null ; then
 244         # This is a clean kernel-source tree, we need to
 245         # enable extensive workarounds to get this to build
 246         # modules
 247         LB_CHECK_FILE([$KERNEL_SOURCE_HEADER],
 248                 [if test $KERNEL_SOURCE_HEADER = '/boot/kernel.h' ; then
 249                         AC_MSG_WARN([Using /boot/kernel.h from RUNNING kernel.])
 250                         AC_MSG_WARN([If this is not what you want, use --with-kernel-source-header.])
 251                         AC_MSG_WARN([Consult build/README.kernel-source for details.])
 252                 fi],
 253                 [AC_MSG_ERROR([$KERNEL_SOURCE_HEADER not found.  Consult build/README.kernel-source for details.])])
 254         EXTRA_KCFLAGS="-include $KERNEL_SOURCE_HEADER $EXTRA_KCFLAGS"
 255 fi
 256
 257 # this is needed before we can build modules
 258 LB_LINUX_VERSION
 259
 260 # --- check that we can build modules at all
 261 AC_MSG_CHECKING([that modules can be built at all])
 262 LB_LINUX_TRY_COMPILE([],[],[
 263         AC_MSG_RESULT([yes])
 264 ],[
 265         AC_MSG_RESULT([no])
 266         AC_MSG_WARN([Consult config.log for details.])
 267         AC_MSG_WARN([If you are trying to build with a kernel-source rpm, consult build/README.kernel-source])
 268         AC_MSG_ERROR([Kernel modules cannot be built.])
 269 ])
 270
 271 LB_LINUX_RELEASE
 272 ]) # end of LB_LINUX_PATH
 273
 274 # LB_LINUX_SYMVERFILE
 275 # SLES 9 uses a different name for this file - unsure about vanilla kernels
 276 # around this version, but it matters for servers only.
 277 AC_DEFUN([LB_LINUX_SYMVERFILE],
 278         [AC_MSG_CHECKING([name of module symbol version file])
 279         if grep -q Modules.symvers $LINUX/scripts/Makefile.modpost ; then
 280                 SYMVERFILE=Modules.symvers
 281         else
 282                 SYMVERFILE=Module.symvers
 283         fi
 284         AC_MSG_RESULT($SYMVERFILE)
 285         AC_SUBST(SYMVERFILE)
 286 ])
 287
 288 # these are like AC_TRY_COMPILE, but try to build modules against the
 289 # kernel, inside the build directory
 290
 291 # LB_LANG_PROGRAM(C)([PROLOGUE], [BODY])
 292 # --------------------------------------
 293 m4_define([LB_LANG_PROGRAM],
 294 [
 295 #include <linux/kernel.h>
 296 $1
 297 int
 298 main (void)
 299 {
 300 dnl Do *not* indent the following line: there may be CPP directives.
 301 dnl Don't move the `;' right after for the same reason.
 302 $2
 303   ;
 304   return 0;
 305 }])
 306
 307 #
 308 # LB_LINUX_COMPILE_IFELSE
 309 #
 310 # like AC_COMPILE_IFELSE
 311 #
 312 AC_DEFUN([LB_LINUX_COMPILE_IFELSE],
 313 [m4_ifvaln([$1], [AC_LANG_CONFTEST([$1])])dnl
 314 rm -f build/conftest.o build/conftest.mod.c build/conftest.ko
 315 AS_IF([AC_TRY_COMMAND(cp conftest.c build && make -d [$2] ${LD:+"LD=$LD"} CC="$CC" -f $PWD/build/Makefile LUSTRE_LINUX_CONFIG=$LINUX_CONFIG LINUXINCLUDE="$EXTRA_LNET_INCLUDE -I$LINUX/arch/`echo $target_cpu|sed -e 's/powerpc64/powerpc/' -e 's/x86_64/x86/' -e 's/i.86/x86/'`/include -I$LINUX/arch/`echo $target_cpu|sed -e 's/ppc.*/powerpc/' -e 's/x86_64/x86/' -e 's/i.86/x86/'`/include/generated -I$LINUX_OBJ/include -I$LINUX/include -I$LINUX_OBJ/include2 -include $CONFIG_INCLUDE" -o tmp_include_depends -o scripts -o include/config/MARKER -C $LINUX_OBJ EXTRA_CFLAGS="-Werror-implicit-function-declaration $EXTRA_KCFLAGS" $MODULE_TARGET=$PWD/build) >/dev/null && AC_TRY_COMMAND([$3])],
 316         [$4],
 317         [_AC_MSG_LOG_CONFTEST
 318 m4_ifvaln([$5],[$5])dnl])
 319 rm -f build/conftest.o build/conftest.mod.c build/conftest.mod.o build/conftest.ko m4_ifval([$1], [build/conftest.c conftest.c])[]dnl
 320 ])
 321
 322 #
 323 # LB_LINUX_ARCH
 324 #
 325 # Determine the kernel's idea of the current architecture
 326 #
 327 AC_DEFUN([LB_LINUX_ARCH],
 328          [AC_MSG_CHECKING([Linux kernel architecture])
 329           AS_IF([rm -f $PWD/build/arch
 330                  make -s --no-print-directory echoarch -f $PWD/build/Makefile \
 331                      LUSTRE_LINUX_CONFIG=$LINUX_CONFIG -C $LINUX \
 332                      ARCHFILE=$PWD/build/arch && LINUX_ARCH=`cat $PWD/build/arch`],
 333                 [AC_MSG_RESULT([$LINUX_ARCH])],
 334                 [AC_MSG_ERROR([Could not determine the kernel architecture.])])
 335           rm -f build/arch])
 336
 337 #
 338 # LB_LINUX_TRY_COMPILE
 339 #
 340 # like AC_TRY_COMPILE
 341 #
 342 AC_DEFUN([LB_LINUX_TRY_COMPILE],
 343 [LB_LINUX_COMPILE_IFELSE(
 344         [AC_LANG_SOURCE([LB_LANG_PROGRAM([[$1]], [[$2]])])],
 345         [modules],
 346         [test -s build/conftest.o],
 347         [$3], [$4])])
 348
 349 #
 350 # LB_LINUX_CONFIG
 351 #
 352 # check if a given config option is defined
 353 #
 354 AC_DEFUN([LB_LINUX_CONFIG],[
 355         AC_MSG_CHECKING([if Linux was built with CONFIG_$1])
 356         LB_LINUX_TRY_COMPILE([
 357                 #include <$AUTOCONF_HDIR/autoconf.h>
 358         ],[
 359                 #ifndef CONFIG_$1
 360                 #error CONFIG_$1 not #defined
 361                 #endif
 362         ],[
 363                 AC_MSG_RESULT([yes])
 364                 $2
 365         ],[
 366                 AC_MSG_RESULT([no])
 367                 $3
 368         ])
 369 ])
 370
 371 #
 372 # LB_LINUX_CONFIG_IM
 373 #
 374 # check if a given config option is builtin or as module
 375 #
 376 AC_DEFUN([LB_LINUX_CONFIG_IM],[
 377         AC_MSG_CHECKING([if Linux was built with CONFIG_$1 in or as module])
 378         LB_LINUX_TRY_COMPILE([
 379                 #include <$AUTOCONF_HDIR/autoconf.h>
 380         ],[
 381                 #if !(defined(CONFIG_$1) || defined(CONFIG_$1_MODULE))
 382                 #error CONFIG_$1 and CONFIG_$1_MODULE not #defined
 383                 #endif
 384         ],[
 385                 AC_MSG_RESULT([yes])
 386                 $2
 387         ],[
 388                 AC_MSG_RESULT([no])
 389                 $3
 390         ])
 391 ])
 392
 393 #
 394 # LB_LINUX_TRY_MAKE
 395 #
 396 # like LB_LINUX_TRY_COMPILE, but with different arguments
 397 #
 398 AC_DEFUN([LB_LINUX_TRY_MAKE],
 399         [LB_LINUX_COMPILE_IFELSE(
 400                 [AC_LANG_SOURCE([LB_LANG_PROGRAM([[$1]], [[$2]])])],
 401                 [$3], [$4], [$5], [$6]
 402         )]
 403 )
 404
 405 #
 406 # LB_CONFIG_COMPAT_RDMA
 407 #
 408 AC_DEFUN([LB_CONFIG_COMPAT_RDMA],
 409 [AC_MSG_CHECKING([whether to use Compat RDMA])
 410 # set default
 411 AC_ARG_WITH([o2ib],
 412         AC_HELP_STRING([--with-o2ib=path],
 413                        [build o2iblnd against path]),
 414         [
 415                 case $with_o2ib in
 416                 yes)    O2IBPATHS="$LINUX $LINUX/drivers/infiniband"
 417                         ENABLEO2IB=2
 418                         ;;
 419                 no)     ENABLEO2IB=0
 420                         ;;
 421                 *)      O2IBPATHS=$with_o2ib
 422                         ENABLEO2IB=3
 423                         ;;
 424                 esac
 425         ],[
 426                 O2IBPATHS="$LINUX $LINUX/drivers/infiniband"
 427                 ENABLEO2IB=1
 428         ])
 429 if test $ENABLEO2IB -eq 0; then
 430         AC_MSG_RESULT([no])
 431 else
 432         o2ib_found=false
 433         for O2IBPATH in $O2IBPATHS; do
 434                 if test \( -f ${O2IBPATH}/include/rdma/rdma_cm.h -a \
 435                            -f ${O2IBPATH}/include/rdma/ib_cm.h -a \
 436                            -f ${O2IBPATH}/include/rdma/ib_verbs.h -a \
 437                            -f ${O2IBPATH}/include/rdma/ib_fmr_pool.h \); then
 438                         o2ib_found=true
 439                         break
 440                 fi
 441         done
 442         compatrdma_found=false
 443         if $o2ib_found; then
 444                 if test \( -f ${O2IBPATH}/include/linux/compat-2.6.h \); then
 445                         compatrdma_found=true
 446                         AC_MSG_RESULT([yes])
 447                         AC_DEFINE(HAVE_COMPAT_RDMA, 1, [compat rdma found])
 448                 else
 449                         AC_MSG_RESULT([no])
 450                 fi
 451         fi
 452 fi
 453 ])
 454
 455 #
 456 # LB_CONFIG_OFED_BACKPORTS
 457 #
 458 # include any OFED backport headers in all compile commands
 459 # NOTE: this does only include the backport paths, not the OFED headers
 460 #       adding the OFED headers is done in the lnet portion
 461 AC_DEFUN([LB_CONFIG_OFED_BACKPORTS],
 462 [AC_MSG_CHECKING([whether to use any OFED backport headers])
 463 if test $ENABLEO2IB -eq 0; then
 464         AC_MSG_RESULT([no])
 465 else
 466         if ! $o2ib_found; then
 467                 AC_MSG_RESULT([no])
 468                 case $ENABLEO2IB in
 469                         1) ;;
 470                         2) AC_MSG_ERROR([kernel OpenIB gen2 headers not present]);;
 471                         3) AC_MSG_ERROR([bad --with-o2ib path]);;
 472                         *) AC_MSG_ERROR([internal error]);;
 473                 esac
 474         else
 475                 if ! $compatrdma_found; then
 476                         if test -f $O2IBPATH/config.mk; then
 477                                 . $O2IBPATH/config.mk
 478                         elif test -f $O2IBPATH/ofed_patch.mk; then
 479                                 . $O2IBPATH/ofed_patch.mk
 480                         fi
 481                 fi
 482                 if test -n "$BACKPORT_INCLUDES"; then
 483                         OFED_BACKPORT_PATH="$O2IBPATH/${BACKPORT_INCLUDES/*\/kernel_addons/kernel_addons}/"
 484                         EXTRA_LNET_INCLUDE="-I$OFED_BACKPORT_PATH $EXTRA_LNET_INCLUDE"
 485                         AC_MSG_RESULT([yes])
 486                 else
 487                         AC_MSG_RESULT([no])
 488                 fi
 489         fi
 490 fi
 491 ])
 492
 493 # LC_MODULE_LOADING
 494 # after 2.6.28 CONFIG_KMOD is removed, and only CONFIG_MODULES remains
 495 # so we test if request_module is implemented or not
 496 AC_DEFUN([LC_MODULE_LOADING],
 497 [AC_MSG_CHECKING([if kernel module loading is possible])
 498 LB_LINUX_TRY_MAKE([
 499         #include <linux/kmod.h>
 500 ],[
 501         int myretval=ENOSYS ;
 502         return myretval;
 503 ],[
 504         $makerule LUSTRE_KERNEL_TEST=conftest.i
 505 ],[dnl
 506         grep request_module build/conftest.i |dnl
 507                 grep -v `grep "int myretval=" build/conftest.i |dnl
 508                         cut -d= -f2 | cut -d" "  -f1`dnl
 509                 >/dev/null dnl
 510 ],[
 511         AC_MSG_RESULT(yes)
 512         AC_DEFINE(HAVE_MODULE_LOADING_SUPPORT, 1,
 513                   [kernel module loading is possible])
 514 ],[
 515         AC_MSG_RESULT(no)
 516         AC_MSG_WARN([])
 517         AC_MSG_WARN([Kernel module loading support is highly recommended.])
 518         AC_MSG_WARN([])
 519 ])
 520 ])
 521
 522 #
 523 # LB_PROG_LINUX
 524 #
 525 # linux tests
 526 #
 527 AC_DEFUN([LB_PROG_LINUX],
 528 [LB_LINUX_PATH
 529 LB_LINUX_ARCH
 530 LB_LINUX_SYMVERFILE
 531
 532
 533 LB_LINUX_CONFIG([MODULES],[],[
 534         AC_MSG_ERROR([module support is required to build Lustre kernel modules.])
 535 ])
 536
 537 LB_LINUX_CONFIG([MODVERSIONS])
 538
 539 LB_LINUX_CONFIG([KALLSYMS],[],[
 540         AC_MSG_ERROR([Lustre requires that CONFIG_KALLSYMS is enabled in your kernel.])
 541 ])
 542
 543 # 2.6.28
 544 LC_MODULE_LOADING
 545
 546 LB_CONFIG_COMPAT_RDMA
 547
 548 # it's ugly to be doing anything with OFED outside of the lnet module, but
 549 # this has to be done here so that the backports path is set before all of
 550 # the LN_PROG_LINUX checks are done
 551 LB_CONFIG_OFED_BACKPORTS
 552 ])
 553
 554 #
 555 # LB_CHECK_SYMBOL_EXPORT
 556 # check symbol exported or not
 557 # $1 - symbol
 558 # $2 - file(s) for find.
 559 # $3 - do 'yes'
 560 # $4 - do 'no'
 561 #
 562 # 2.6 based kernels - put modversion info into $LINUX/Module.modvers
 563 # or check
 564 AC_DEFUN([LB_CHECK_SYMBOL_EXPORT],
 565 [AC_MSG_CHECKING([if Linux was built with symbol $1 exported])
 566 grep -q -E '[[[:space:]]]$1[[[:space:]]]' $LINUX/$SYMVERFILE 2>/dev/null
 567 rc=$?
 568 if test $rc -ne 0; then
 569         export=0
 570         for file in $2; do
 571                 grep -q -E "EXPORT_SYMBOL.*\($1\)" "$LINUX/$file" 2>/dev/null
 572                 rc=$?
 573                 if test $rc -eq 0; then
 574                         export=1
 575                         break;
 576                 fi
 577         done
 578         if test $export -eq 0; then
 579                 AC_MSG_RESULT([no])
 580                 $4
 581         else
 582                 AC_MSG_RESULT([yes])
 583                 $3
 584         fi
 585 else
 586         AC_MSG_RESULT([yes])
 587         $3
 588 fi
 589 ])
 590
 591 #
 592 # Like AC_CHECK_HEADER but checks for a kernel-space header
 593 #
 594 m4_define([LB_CHECK_LINUX_HEADER],
 595 [AS_VAR_PUSHDEF([ac_Header], [ac_cv_header_$1])dnl
 596 AC_CACHE_CHECK([for $1], ac_Header,
 597                [LB_LINUX_COMPILE_IFELSE([LB_LANG_PROGRAM([@%:@include <$1>])],
 598                                   [modules],
 599                                   [test -s build/conftest.o],
 600                                   [AS_VAR_SET(ac_Header, [yes])],
 601                                   [AS_VAR_SET(ac_Header, [no])])])
 602 AS_IF([test AS_VAR_GET(ac_Header) = yes], [$2], [$3])[]dnl
 603 AS_VAR_POPDEF([ac_Header])dnl
 604 ])
 605
 606 #
 607 # LB_USES_DPKG
 608 #
 609 # Determine if the target is a dpkg system or rpm
 610 #
 611 AC_DEFUN([LB_USES_DPKG],
 612 [
 613 AC_MSG_CHECKING([if this distro uses dpkg])
 614 case `lsb_release -i -s 2>/dev/null` in
 615         Ubuntu | Debian)
 616                 AC_MSG_RESULT([yes])
 617                 uses_dpkg=yes
 618                 ;;
 619         *)
 620                 AC_MSG_RESULT([no])
 621                 uses_dpkg=no
 622                 ;;
 623 esac
 624 ])