config/lustre-build-linux.m4

   1 #
   2 # LB_LINUX_VERSION
   3 #
   4 # Set things accordingly for a linux kernel
   5 #
   6 AC_DEFUN([LB_LINUX_VERSION], [
   7 KMODEXT=".ko"
   8 AC_SUBST(KMODEXT)
   9
  10 makerule="$PWD/build"
  11 AC_CACHE_CHECK([for external module build target], lb_cv_module_target, [
  12 lb_cv_module_target=""
  13 MODULE_TARGET="SUBDIRS"
  14 rm -f build/conftest.i
  15 LB_LINUX_TRY_MAKE([], [],
  16         [$makerule LUSTRE_KERNEL_TEST=conftest.i],
  17         [test -s build/conftest.i],
  18         [lb_cv_module_target="SUBDIRS"], [
  19                 MODULE_TARGET="M"
  20                 makerule="_module_$PWD/build"
  21                 LB_LINUX_TRY_MAKE([], [],
  22                         [$makerule LUSTRE_KERNEL_TEST=conftest.i],
  23                         [test -s build/conftest.i],
  24                         [lb_cv_module_target="M"], [
  25                                 AC_MSG_ERROR([unknown; check config.log for details])
  26                         ])
  27         ])
  28 ])
  29 AS_IF([test -z "$lb_cv_module_target"],
  30         [AC_MSG_ERROR([unknown external module build target])],
  31 [test "x$lb_cv_module_target" = "xM"],
  32         [makerule="_module_$PWD/build"])
  33 MODULE_TARGET=$lb_cv_module_target
  34 AC_SUBST(MODULE_TARGET)
  35 ])
  36
  37 #
  38 # LB_LINUX_UTSRELEASE
  39 #
  40 # Determine the Linux kernel version string from the utsrelease
  41 #
  42 AC_DEFUN([LB_LINUX_UTSRELEASE], [
  43 AC_CACHE_CHECK([for Linux kernel utsrelease], lb_cv_utsrelease, [
  44 lb_cv_utsrelease=""
  45 utsrelease1=$LINUX_OBJ/include/generated/utsrelease.h
  46 utsrelease2=$LINUX_OBJ/include/linux/utsrelease.h
  47 utsrelease3=$LINUX_OBJ/include/linux/version.h
  48 AS_IF([test -r $utsrelease1 && fgrep -q UTS_RELEASE $utsrelease1],
  49         [utsrelease=$utsrelease1],
  50 [test -r $utsrelease2 && fgrep -q UTS_RELEASE $utsrelease2],
  51         [utsrelease=$utsrelease2],
  52 [test -r $utsrelease3 && fgrep -q UTS_RELEASE $utsrelease3],
  53         [utsrelease=$utsrelease3])
  54 AS_IF([test -n "$utsrelease"],
  55         [lb_cv_utsrelease=$(awk -F \" '/ UTS_RELEASE / { print [$]2 }' $utsrelease)],
  56         [AC_MSG_ERROR([
  57
  58 Cannot find UTS_RELEASE definition.
  59
  60 This is often provided by the kernel-devel package.
  61 ])
  62         ])
  63 ])
  64 AS_IF([test -z "$lb_cv_utsrelease"],
  65         [AC_MSG_ERROR([Cannot determine Linux kernel version.])])
  66 LINUXRELEASE=$lb_cv_utsrelease
  67 AC_SUBST(LINUXRELEASE)
  68 ])
  69
  70 #
  71 # LB_LINUX_RELEASE
  72 #
  73 # get the release version of linux
  74 #
  75 AC_DEFUN([LB_LINUX_RELEASE], [
  76 LB_LINUX_UTSRELEASE
  77
  78 # ------------ RELEASE --------------------------------
  79 AC_MSG_CHECKING([for Lustre release])
  80 AC_ARG_WITH([release],
  81         AC_HELP_STRING([--with-release=string],
  82                 [set the release string (default=$kvers_YYYYMMDDhhmm)]),
  83         [RELEASE=$withval], [
  84         RELEASE=""
  85         AS_IF([test "$DOWNSTREAM_RELEASE"], [RELEASE="${DOWNSTREAM_RELEASE}_"])
  86         RELEASE="$RELEASE$(echo $LINUXRELEASE | tr '-' '_')_$BUILDID"])
  87 AC_MSG_RESULT($RELEASE)
  88 AC_SUBST(RELEASE)
  89
  90 # check if the kernel is one from RHEL or SUSE
  91 AC_CACHE_CHECK([for RedHat kernel release number], lb_cv_rhel_kernel_version, [
  92 lb_cv_rhel_kernel_version=""
  93 AS_IF([fgrep -q RHEL_RELEASE $LINUX_OBJ/include/$VERSION_HDIR/version.h], [
  94         lb_cv_rhel_kernel_version=$(awk '/ RHEL_MAJOR / { print [$]3 }' \
  95                 $LINUX_OBJ/include/$VERSION_HDIR/version.h)$(awk \
  96                 '/ RHEL_MINOR / { print [$]3 }' \
  97                 $LINUX_OBJ/include/$VERSION_HDIR/version.h)
  98 ])
  99 ])
 100 AS_IF([test -n "$lb_cv_rhel_kernel_version"], [
 101         RHEL_KERNEL="yes"
 102         RHEL_RELEASE_NO=$lb_cv_rhel_kernel_version
 103 ], [
 104         RHEL_KERNEL="no"
 105         LB_CHECK_CONFIG([SUSE_KERNEL], [SUSE_KERNEL="yes"], [SUSE_KERNEL="no"])
 106 ])
 107
 108 AC_MSG_CHECKING([for Linux kernel module package directory])
 109 AC_ARG_WITH([kmp-moddir],
 110         AC_HELP_STRING([--with-kmp-moddir=string],
 111                 [set the kmod updates or extra directory]),
 112         [KMP_MODDIR=$withval],[
 113         AS_IF([test x$RHEL_KERNEL = xyes], [KMP_MODDIR="extra"],
 114               [test x$SUSE_KERNEL = xyes], [KMP_MODDIR="updates"])])
 115 AC_MSG_RESULT($KMP_MODDIR)
 116 AC_SUBST(KMP_MODDIR)
 117
 118 moduledir='/lib/modules/$(LINUXRELEASE)/$(KMP_MODDIR)/kernel'
 119 AC_SUBST(moduledir)
 120
 121 modulefsdir='$(moduledir)/fs/$(PACKAGE)'
 122 AC_SUBST(modulefsdir)
 123
 124 modulenetdir='$(moduledir)/net/$(PACKAGE)'
 125 AC_SUBST(modulenetdir)
 126 ])
 127
 128 #
 129 # LB_LINUX_SYMVERFILE
 130 #
 131 # SLES 9 uses a different name for this file - unsure about vanilla kernels
 132 # around this version, but it matters for servers only.
 133 AC_DEFUN([LB_LINUX_SYMVERFILE], [
 134 AC_CACHE_CHECK([for the name of module symbol version file], lb_cv_module_symvers, [
 135 AS_IF([grep -q Modules.symvers $LINUX/scripts/Makefile.modpost],
 136         [lb_cv_module_symvers=Modules.symvers],
 137         [lb_cv_module_symvers=Module.symvers])
 138 ])
 139 SYMVERFILE=$lb_cv_module_symvers
 140 AC_SUBST(SYMVERFILE)
 141 ])
 142
 143 #
 144 # LB_ARG_REPLACE_PATH(PACKAGE, PATH)
 145 #
 146 AC_DEFUN([LB_ARG_REPLACE_PATH], [
 147 new_configure_args=
 148 eval set -- $ac_configure_args
 149 for arg; do
 150         case $arg in
 151                 --with-[$1]=*)
 152                         arg=--with-[$1]=[$2] ;;
 153                 *\'*)
 154                         arg=$(printf %s\n ["$arg"] | sed "s/'/'\\\\\\\\''/g") ;;
 155         esac
 156         dnl AS_VAR_APPEND([new_configure_args], [" '$arg'"])
 157         new_configure_args="$new_configure_args '$arg'"
 158 done
 159 ac_configure_args=$new_configure_args
 160 ])
 161
 162 #
 163 # __LB_ARG_CANON_PATH
 164 #
 165 # this is the work-horse of the next function
 166 #
 167 AC_DEFUN([__LB_ARG_CANON_PATH], [
 168         [$3]=$(readlink -f $with_$2)
 169         LB_ARG_REPLACE_PATH([$1], $[$3])
 170 ])
 171
 172 #
 173 # LB_ARG_CANON_PATH
 174 #
 175 # a front-end for the above function that transforms - and . in the
 176 # PACKAGE portion of --with-PACKAGE into _ suitable for variable names
 177 #
 178 AC_DEFUN([LB_ARG_CANON_PATH], [
 179         __LB_ARG_CANON_PATH([$1], m4_translit([$1], [-.], [__]), [$2])
 180 ])
 181
 182 #
 183 # LB_LINUX_PATH
 184 #
 185 # Find paths for linux, handling kernel-source rpms
 186 #
 187 AC_DEFUN([LB_LINUX_PATH], [
 188 for DEFAULT_LINUX in /lib/modules/$(uname -r)/{source,build} /usr/src/linux; do
 189         AS_IF([readlink -q -e $DEFAULT_LINUX >/dev/null], [break])
 190 done
 191 if test "$DEFAULT_LINUX" = "/lib/modules/$(uname -r)/source"; then
 192         PATHS="/lib/modules/$(uname -r)/build"
 193 fi
 194 PATHS+=" $DEFAULT_LINUX"
 195 for DEFAULT_LINUX_OBJ in $PATHS; do
 196         AS_IF([readlink -q -e $DEFAULT_LINUX_OBJ >/dev/null], [break])
 197 done
 198
 199 AC_MSG_CHECKING([for Linux sources])
 200 AC_ARG_WITH([linux],
 201         AC_HELP_STRING([--with-linux=path],
 202                        [set path to Linux source (default=/lib/modules/$(uname -r)/{source,build},/usr/src/linux)]),
 203         [LB_ARG_CANON_PATH([linux], [LINUX])
 204         DEFAULT_LINUX_OBJ=$LINUX],
 205         [LINUX=$DEFAULT_LINUX])
 206 AC_MSG_RESULT([$LINUX])
 207 AC_SUBST(LINUX)
 208
 209 # -------- check for linux --------
 210 LB_CHECK_FILE([$LINUX], [],
 211         [AC_MSG_ERROR([Kernel source $LINUX could not be found.])])
 212
 213 # -------- linux objects (for 2.6) --
 214 AC_MSG_CHECKING([for Linux objects])
 215 AC_ARG_WITH([linux-obj],
 216         AC_HELP_STRING([--with-linux-obj=path],
 217                         [set path to Linux objects (default=/lib/modules/$(uname -r)/build,/usr/src/linux)]),
 218         [LB_ARG_CANON_PATH([linux-obj], [LINUX_OBJ])],
 219         [LINUX_OBJ=$DEFAULT_LINUX_OBJ])
 220 AC_MSG_RESULT([$LINUX_OBJ])
 221 AC_SUBST(LINUX_OBJ)
 222
 223 # -------- check for .config --------
 224 AC_ARG_WITH([linux-config],
 225         [AC_HELP_STRING([--with-linux-config=path],
 226                         [set path to Linux .conf (default=$LINUX_OBJ/.config)])],
 227         [LB_ARG_CANON_PATH([linux-config], [LINUX_CONFIG])],
 228         [LINUX_CONFIG=$LINUX_OBJ/.config])
 229
 230 # -------- check if .config exists --
 231 LB_CHECK_FILE([$LINUX_CONFIG], [],
 232         [AC_MSG_ERROR([
 233
 234 Kernel config could not be found.
 235
 236 If you are building from a kernel-source rpm consult build/README.kernel-source
 237 ])
 238 ])
 239 AC_SUBST(LINUX_CONFIG)
 240
 241 LB_CHECK_FILE([/boot/kernel.h],
 242         [KERNEL_SOURCE_HEADER='/boot/kernel.h'],
 243         [LB_CHECK_FILE([/var/adm/running-kernel.h],
 244                 [KERNEL_SOURCE_HEADER='/var/adm/running-kernel.h'])])
 245
 246 AC_ARG_WITH([kernel-source-header],
 247         AC_HELP_STRING([--with-kernel-source-header=path],
 248                         [Use a different kernel version header.  Consult build/README.kernel-source for details.]),
 249         [LB_ARG_CANON_PATH([kernel-source-header], [KERNEL_SOURCE_HEADER])])
 250
 251 # ----------- make dep run? ------------------
 252 # at 2.6.19 # $LINUX/include/linux/config.h is removed
 253 # and at more old has only one line include <autoconf.h>
 254 #
 255 LB_CHECK_FILE([$LINUX_OBJ/include/generated/autoconf.h],
 256         [AUTOCONF_HDIR=generated],
 257         [LB_CHECK_FILE([$LINUX_OBJ/include/linux/autoconf.h],
 258                 [AUTOCONF_HDIR=linux],
 259                 [AC_MSG_ERROR([Run make config in $LINUX.])])])
 260 AC_SUBST(AUTOCONF_HDIR)
 261
 262 LB_CHECK_FILE([$LINUX_OBJ/include/linux/version.h],
 263         [VERSION_HDIR=linux],
 264         [LB_CHECK_FILE([$LINUX_OBJ/include/generated/uapi/linux/version.h],
 265                 [VERSION_HDIR=generated/uapi/linux],
 266                 [AC_MSG_ERROR([Run make config in $LINUX.])])])
 267 AC_SUBST(VERSION_HDIR)
 268
 269 # ----------- kconfig.h exists ---------------
 270 # kernel 3.1, $LINUX/include/linux/kconfig.h is added
 271 # see kernel commit 2a11c8ea20bf850b3a2c60db8c2e7497d28aba99
 272 #
 273 LB_CHECK_FILE([$LINUX/include/linux/kconfig.h],
 274               [CONFIG_INCLUDE=$LINUX/include/linux/kconfig.h],
 275               [CONFIG_INCLUDE=include/$AUTOCONF_HDIR/autoconf.h])
 276 AC_SUBST(CONFIG_INCLUDE)
 277
 278 # ------------ rhconfig.h includes runtime-generated bits --
 279 # RedHat kernel-source checks
 280
 281 # we know this exists after the check above.  if the user
 282 # tarred up the tree and ran make dep etc. in it, then
 283 # version.h gets overwritten with a standard linux one.
 284
 285 AS_IF([grep rhconfig $LINUX_OBJ/include/$VERSION_HDIR/version.h >/dev/null], [
 286         # This is a clean kernel-source tree, we need to
 287         # enable extensive workarounds to get this to build modules
 288         LB_CHECK_FILE([$KERNEL_SOURCE_HEADER], [
 289                 AS_IF([test $KERNEL_SOURCE_HEADER = '/boot/kernel.h'],
 290                         [AC_MSG_WARN([
 291
 292 Using /boot/kernel.h from RUNNING kernel.
 293
 294 If this is not what you want, use --with-kernel-source-header.
 295 Consult build/README.kernel-source for details.
 296 ])
 297                 ])],
 298                 [AC_MSG_ERROR([
 299
 300 $KERNEL_SOURCE_HEADER not found.
 301
 302 Consult build/README.kernel-source for details.
 303 ])
 304                 ])
 305         EXTRA_KCFLAGS="-include $KERNEL_SOURCE_HEADER $EXTRA_KCFLAGS"
 306 ])
 307
 308 # this is needed before we can build modules
 309 LB_LINUX_VERSION
 310
 311 # --- check that we can build modules at all
 312 LB_CHECK_COMPILE([that modules can be built at all], build_modules,
 313         [], [], [], [
 314         AC_MSG_ERROR([
 315
 316 Kernel modules cannot be built. Consult config.log for details.
 317
 318 If you are trying to build with a kernel-source rpm,
 319 consult build/README.kernel-source
 320 ])
 321 ])
 322
 323 LB_LINUX_RELEASE
 324 ]) # end of LB_LINUX_PATH
 325
 326 #
 327 # LC_MODULE_LOADING
 328 #
 329 # after 2.6.28 CONFIG_KMOD is removed, and only CONFIG_MODULES remains
 330 # so we test if request_module is implemented or not
 331 AC_DEFUN([LC_MODULE_LOADING], [
 332 AC_CACHE_CHECK([if Linux kernel module loading is possible], lb_cv_module_loading, [
 333 LB_LINUX_TRY_MAKE([
 334         #include <linux/kmod.h>
 335 ], [
 336         int myretval=ENOSYS ;
 337         return myretval;
 338 ], [
 339         $makerule LUSTRE_KERNEL_TEST=conftest.i
 340 ], [dnl
 341         grep request_module build/conftest.i |dnl
 342                 grep -v `grep "int myretval=" build/conftest.i |dnl
 343                         cut -d= -f2 | cut -d" "  -f1`dnl
 344                 >/dev/null dnl
 345 ], [lb_cv_module_loading="yes"], [lb_cv_module_loading="no"])
 346 ])
 347 AS_IF([test "$lb_cv_module_loading" = yes],
 348         [AC_DEFINE(HAVE_MODULE_LOADING_SUPPORT, 1,
 349                 [kernel module loading is possible])],
 350         [AC_MSG_WARN([
 351
 352 Kernel module loading support is highly recommended.
 353
 354 ])
 355         ])
 356 ])
 357
 358 #
 359 # LB_PROG_LINUX
 360 #
 361 # linux tests
 362 #
 363 AC_DEFUN([LB_PROG_LINUX], [
 364 LB_LINUX_PATH
 365 LB_LINUX_SYMVERFILE
 366
 367 LB_CHECK_CONFIG([MODULES], [], [
 368         AC_MSG_ERROR([
 369
 370 module support is required to build Lustre kernel modules.
 371 ])
 372         ])
 373
 374 LB_CHECK_CONFIG([MODVERSIONS])
 375
 376 LB_CHECK_CONFIG([KALLSYMS], [], [
 377         AC_MSG_ERROR([
 378
 379 Lustre requires that CONFIG_KALLSYMS is enabled in your kernel.
 380 ])
 381         ])
 382
 383 # 2.6.28
 384 LC_MODULE_LOADING
 385 ])
 386
 387 #
 388 # LB_USES_DPKG
 389 #
 390 # Determine if the target is a dpkg system or rpm
 391 #
 392 AC_DEFUN([LB_USES_DPKG], [
 393 AC_CACHE_CHECK([if this distro uses dpkg], lb_cv_uses_dpkg, [
 394 lb_cv_uses_dpkg="no"
 395 AS_CASE([$(lsb_release -i -s 2>/dev/null)],
 396         [Ubuntu | Debian], [lb_cv_uses_dpkg="yes"])
 397 ])
 398 uses_dpkg=$lb_cv_uses_dpkg
 399 ])
 400
 401 #
 402 # LB_CHECK_EXPORT
 403 #
 404 # check symbol exported or not
 405 # $1 - symbol
 406 # $2 - file(s) for find.
 407 # $3 - do 'yes'
 408 # $4 - do 'no'
 409 #
 410 # 2.6 based kernels - put modversion info into $LINUX/Module.modvers or check
 411 #
 412 AC_DEFUN([LB_CHECK_EXPORT], [
 413 AS_VAR_PUSHDEF([lb_export], [lb_cv_export_$1])dnl
 414 AC_CACHE_CHECK([if Linux kernel exports '$1'], lb_export, [
 415 AS_VAR_SET([lb_export], [no])
 416 AS_IF([grep -q -E '[[[:space:]]]$1[[[:space:]]]' $LINUX_OBJ/$SYMVERFILE 2>/dev/null],
 417         [AS_VAR_SET([lb_export], [yes])],
 418         [for file in $2; do
 419                 AS_IF([grep -q -E "EXPORT_SYMBOL.*\($1\)" "$LINUX/$file" 2>/dev/null], [
 420                         AS_VAR_SET([lb_export], [yes])
 421                         break
 422                 ])
 423         done])
 424 ])
 425 AS_VAR_IF([lb_export], [yes], [$3], [$4])[]dnl
 426 AS_VAR_POPDEF([lb_export])dnl
 427 ]) # LB_CHECK_EXPORT
 428
 429 #
 430 # LB_CHECK_CONFIG
 431 #
 432 # check if a given config option is defined
 433 # $1 - CONFIG_<name>
 434 # $2 - do 'yes'
 435 # $3 - do 'no'
 436 #
 437 AC_DEFUN([LB_CHECK_CONFIG], [
 438 LB_CHECK_COMPILE([if Linux kernel was built with CONFIG_$1],
 439 config_$1, [
 440         #include <$AUTOCONF_HDIR/autoconf.h>
 441 ], [
 442         #ifndef CONFIG_$1
 443         #error CONFIG_$1 not #defined
 444         #endif
 445 ], [$2], [$3])
 446 ]) # LB_CHECK_CONFIG
 447
 448 #
 449 # LB_CHECK_CONFIG_IM
 450 #
 451 # check if a given config option is builtin or as module
 452 # $1 - CONFIG_<name> or CONFIG_<name>_MODULE
 453 # $2 - do 'yes'
 454 # $3 - do 'no'
 455 #
 456 AC_DEFUN([LB_CHECK_CONFIG_IM], [
 457 LB_CHECK_COMPILE([if Linux kernel was built with CONFIG_$1 in or as module],
 458 config_im_$1, [
 459         #include <$AUTOCONF_HDIR/autoconf.h>
 460 ], [
 461         #if !(defined(CONFIG_$1) || defined(CONFIG_$1_MODULE))
 462         #error CONFIG_$1 and CONFIG_$1_MODULE not #defined
 463         #endif
 464 ], [$2], [$3])
 465 ]) # LB_CHECK_CONFIG_IM
 466
 467 #
 468 # these are like AC_TRY_COMPILE, but try to build modules against the
 469 # kernel, inside the build directory
 470 #
 471
 472 #
 473 # LB_LANG_PROGRAM(C)([PROLOGUE], [BODY])
 474 # --------------------------------------
 475 #
 476 m4_define([LB_LANG_PROGRAM],
 477 [
 478 #include <linux/kernel.h>
 479 $1
 480 int
 481 main (void)
 482 {
 483 dnl Do *not* indent the following line: there may be CPP directives.
 484 dnl Don't move the `;' right after for the same reason.
 485 $2
 486   ;
 487   return 0;
 488 }])
 489
 490 #
 491 # LB_LINUX_COMPILE_IFELSE
 492 #
 493 # like AC_COMPILE_IFELSE
 494 #
 495 # $1 - AC_LANG_SOURCE()
 496 # $2 - make target
 497 # $3 - check command
 498 # $4 - do 'yes'
 499 # $5 - do 'no'
 500 #
 501 AC_DEFUN([LB_LINUX_COMPILE_IFELSE],
 502 [m4_ifvaln([$1], [AC_LANG_CONFTEST([AC_LANG_SOURCE([$1])])])dnl
 503 rm -f build/conftest.o build/conftest.mod.c build/conftest.ko
 504 SUBARCH=$(echo $target_cpu | sed -e 's/powerpc64le/powerpc/' -e 's/powerpc64/powerpc/' -e 's/x86_64/x86/' -e 's/i.86/x86/' -e 's/k1om/x86/' -e 's/aarch64/arm64/')
 505 AS_IF([AC_TRY_COMMAND(cp conftest.c build && make -d [$2] ${LD:+"LD=$LD"} CC="$CC" -f $PWD/build/Makefile LUSTRE_LINUX_CONFIG=$LINUX_CONFIG LINUXINCLUDE="$EXTRA_OFED_INCLUDE -I$LINUX/arch/$SUBARCH/include -Iinclude -Iarch/$SUBARCH/include/generated -I$LINUX/include -Iinclude2 -I$LINUX/include/uapi -Iinclude/generated -I$LINUX/arch/$SUBARCH/include/uapi -Iarch/$SUBARCH/include/generated/uapi -I$LINUX/include/uapi -Iinclude/generated/uapi ${SPL_OBJ:+-include $SPL_OBJ/spl_config.h} ${ZFS_OBJ:+-include $ZFS_OBJ/zfs_config.h} ${SPL:+-I$SPL -I$SPL/include } ${ZFS:+-I$ZFS -I$ZFS/include} -include $CONFIG_INCLUDE" -o tmp_include_depends -o scripts -o include/config/MARKER -C $LINUX_OBJ EXTRA_CFLAGS="-Werror-implicit-function-declaration $EXTRA_KCFLAGS" $MODULE_TARGET=$PWD/build) >/dev/null && AC_TRY_COMMAND([$3])],
 506         [$4],
 507         [_AC_MSG_LOG_CONFTEST
 508 m4_ifvaln([$5],[$5])dnl])
 509 rm -f build/conftest.o build/conftest.mod.c build/conftest.mod.o build/conftest.ko m4_ifval([$1], [build/conftest.c conftest.c])[]dnl
 510 ])
 511
 512 #
 513 # LB_LINUX_TRY_COMPILE
 514 #
 515 # like AC_TRY_COMPILE
 516 #
 517 AC_DEFUN([LB_LINUX_TRY_COMPILE], [
 518 LB_LINUX_COMPILE_IFELSE(
 519         [AC_LANG_SOURCE([LB_LANG_PROGRAM([[$1]], [[$2]])])],
 520         [modules], [test -s build/conftest.o],
 521         [$3], [$4])
 522 ])
 523
 524 #
 525 # LB_LINUX_TRY_MAKE
 526 #
 527 # like LB_LINUX_TRY_COMPILE, but with different arguments
 528 #
 529 AC_DEFUN([LB_LINUX_TRY_MAKE], [
 530 LB_LINUX_COMPILE_IFELSE(
 531         [AC_LANG_SOURCE([LB_LANG_PROGRAM([[$1]], [[$2]])])],
 532         [$3], [$4], [$5], [$6])
 533 ])
 534
 535 #
 536 # LB_CHECK_COMPILE
 537 # $1 - checking message
 538 # $2 - variable name
 539 # $3 - header
 540 # $4 - body
 541 # $5 - do 'yes'
 542 # $6 - do 'no'
 543 #
 544 AC_DEFUN([LB_CHECK_COMPILE], [
 545 AS_VAR_PUSHDEF([lb_compile], [lb_cv_compile_$2])dnl
 546 AC_CACHE_CHECK([$1], lb_compile, [
 547         LB_LINUX_TRY_COMPILE([$3], [$4],
 548                 [AS_VAR_SET([lb_compile], [yes])],
 549                 [AS_VAR_SET([lb_compile], [no])])
 550 ])
 551 AS_VAR_IF([lb_compile], [yes], [$5], [$6])[]dnl
 552 AS_VAR_POPDEF([lb_compile])dnl
 553 ]) # LB_CHECK_COMPILE
 554
 555 #
 556 # LB_CHECK_LINUX_HEADER
 557 #
 558 # Like AC_CHECK_HEADER but checks for a kernel-space header
 559 #
 560 m4_define([LB_CHECK_LINUX_HEADER], [
 561 AS_VAR_PUSHDEF([lb_header], [lb_cv_header_$1])dnl
 562 AC_CACHE_CHECK([for $1], lb_header, [
 563         LB_LINUX_COMPILE_IFELSE([LB_LANG_PROGRAM([@%:@include <$1>])],
 564                 [modules], [test -s build/conftest.o],
 565                 [AS_VAR_SET([lb_header], [yes])],
 566                 [AS_VAR_SET([lb_header], [no])])
 567 ])
 568 AS_VAR_IF([lb_header], [yes], [$2], [$3])[]dnl
 569 AS_VAR_POPDEF([lb_header])dnl
 570 ]) # LB_CHECK_LINUX_HEADER