config/lustre-build-linux.m4

   1 #
   2 # LB_LINUX_VERSION
   3 #
   4 # Set things accordingly for a linux kernel
   5 #
   6 AC_DEFUN([LB_LINUX_VERSION],[
   7 KMODEXT=".ko"
   8
   9 MODULE_TARGET="SUBDIRS"
  10 makerule="$PWD/build"
  11 AC_MSG_CHECKING([for external module build support])
  12 rm -f build/conftest.i
  13 LB_LINUX_TRY_MAKE([],[],
  14         [$makerule LUSTRE_KERNEL_TEST=conftest.i],
  15         [test -s build/conftest.i],
  16         [
  17                 AC_MSG_RESULT([no])
  18         ],[
  19                 makerule="_module_$makerule"
  20                 MODULE_TARGET="M"
  21                 LB_LINUX_TRY_MAKE([],[],
  22                         [$makerule LUSTRE_KERNEL_TEST=conftest.i],
  23                         [test -s build/conftest.i],
  24                         [
  25                                 AC_MSG_RESULT([yes])
  26                         ],[
  27                                 AC_MSG_ERROR([unknown; check config.log for details])
  28                         ])
  29         ])
  30
  31 AC_SUBST(MODULE_TARGET)
  32 AC_SUBST(KMODEXT)
  33 ])
  34
  35 #
  36 # LB_LINUX_RELEASE
  37 #
  38 # get the release version of linux
  39 #
  40 AC_DEFUN([LB_LINUX_RELEASE],
  41 [LINUXRELEASE=
  42 rm -f build/conftest.i
  43 AC_MSG_CHECKING([for Linux release])
  44 if test -s $LINUX_OBJ/include/$AUTOCONF_HDIR/utsrelease.h ; then
  45         LINUXRELEASEHEADER=$AUTOCONF_HDIR/utsrelease.h
  46 else
  47         LINUXRELEASEHEADER=linux/version.h
  48 fi
  49 LB_LINUX_TRY_MAKE([
  50         #include <$LINUXRELEASEHEADER>
  51 ],[
  52         char *LINUXRELEASE;
  53         LINUXRELEASE=UTS_RELEASE;
  54 ],[
  55         $makerule LUSTRE_KERNEL_TEST=conftest.i
  56 ],[
  57         test -s build/conftest.i
  58 ],[
  59         # LINUXRELEASE="UTS_RELEASE"
  60         eval $(grep "LINUXRELEASE=" build/conftest.i)
  61 ],[
  62         AC_MSG_RESULT([unknown])
  63         AC_MSG_ERROR([Could not preprocess test program.  Consult config.log for details.])
  64 ])
  65 rm -f build/conftest.i
  66 if test x$LINUXRELEASE = x ; then
  67         AC_MSG_RESULT([unknown])
  68         AC_MSG_ERROR([Could not determine Linux release version from linux/version.h.])
  69 fi
  70 AC_MSG_RESULT([$LINUXRELEASE])
  71 AC_SUBST(LINUXRELEASE)
  72
  73 moduledir='/lib/modules/'$LINUXRELEASE/updates/kernel
  74 AC_SUBST(moduledir)
  75
  76 modulefsdir='$(moduledir)/fs/$(PACKAGE)'
  77 AC_SUBST(modulefsdir)
  78
  79 modulenetdir='$(moduledir)/net/$(PACKAGE)'
  80 AC_SUBST(modulenetdir)
  81
  82 # ------------ RELEASE --------------------------------
  83 AC_MSG_CHECKING([for Lustre release])
  84 AC_ARG_WITH([release],
  85         AC_HELP_STRING([--with-release=string],
  86                        [set the release string (default=$kvers_YYYYMMDDhhmm)]),
  87         [RELEASE=$withval],
  88         RELEASE=""
  89         if test -n "$DOWNSTREAM_RELEASE"; then
  90                 RELEASE="${DOWNSTREAM_RELEASE}_"
  91         fi
  92         RELEASE="$RELEASE`echo ${LINUXRELEASE} | tr '-' '_'`_$BUILDID")
  93 AC_MSG_RESULT($RELEASE)
  94 AC_SUBST(RELEASE)
  95
  96 # check is redhat/suse kernels
  97 AC_MSG_CHECKING([that RedHat kernel])
  98 LB_LINUX_TRY_COMPILE([
  99                 #include <linux/version.h>
 100         ],[
 101                 #ifndef RHEL_RELEASE_CODE
 102                 #error "not redhat kernel"
 103                 #endif
 104         ],[
 105                 RHEL_KERNEL="yes"
 106                 AC_MSG_RESULT([yes])
 107         ],[
 108                 AC_MSG_RESULT([no])
 109 ])
 110
 111 LB_LINUX_CONFIG([SUSE_KERNEL],[SUSE_KERNEL="yes"],[])
 112
 113 ])
 114
 115 # LB_ARG_REPLACE_PATH(PACKAGE, PATH)
 116 AC_DEFUN([LB_ARG_REPLACE_PATH],[
 117         new_configure_args=
 118         eval "set x $ac_configure_args"
 119         shift
 120         for arg; do
 121                 case $arg in
 122                         --with-[$1]=*)
 123                                 arg=--with-[$1]=[$2]
 124                                 ;;
 125                         *\'*)
 126                                 arg=$(printf %s\n ["$arg"] | \
 127                                       sed "s/'/'\\\\\\\\''/g")
 128                                 ;;
 129                 esac
 130                 dnl AS_VAR_APPEND([new_configure_args], [" '$arg'"])
 131                 new_configure_args="$new_configure_args \"$arg\""
 132         done
 133         ac_configure_args=$new_configure_args
 134 ])
 135
 136 # this is the work-horse of the next function
 137 AC_DEFUN([__LB_ARG_CANON_PATH], [
 138         [$3]=$(readlink -f $with_$2)
 139         LB_ARG_REPLACE_PATH([$1], $[$3])
 140 ])
 141
 142 # a front-end for the above function that transforms - and . in the
 143 # PACKAGE portion of --with-PACKAGE into _ suitable for variable names
 144 AC_DEFUN([LB_ARG_CANON_PATH], [
 145         __LB_ARG_CANON_PATH([$1], m4_translit([$1], [-.], [__]), [$2])
 146 ])
 147
 148 #
 149 #
 150 # LB_LINUX_PATH
 151 #
 152 # Find paths for linux, handling kernel-source rpms
 153 #
 154 AC_DEFUN([LB_LINUX_PATH],
 155 [# prep some default values
 156 for DEFAULT_LINUX in /lib/modules/$(uname -r)/{source,build} /usr/src/linux; do
 157         if readlink -q -e $DEFAULT_LINUX; then
 158                 break
 159         fi
 160 done
 161 if test "$DEFAULT_LINUX" = "/lib/modules/$(uname -r)/source"; then
 162         PATHS="/lib/modules/$(uname -r)/build"
 163 fi
 164 PATHS+=" $DEFAULT_LINUX"
 165 for DEFAULT_LINUX_OBJ in $PATHS; do
 166         if readlink -q -e $DEFAULT_LINUX_OBJ; then
 167                 break
 168         fi
 169 done
 170 AC_MSG_CHECKING([for Linux sources])
 171 AC_ARG_WITH([linux],
 172         AC_HELP_STRING([--with-linux=path],
 173                        [set path to Linux source (default=/lib/modules/$(uname -r)/{source,build},/usr/src/linux)]),
 174         [LB_ARG_CANON_PATH([linux], [LINUX])
 175         DEFAULT_LINUX_OBJ=$LINUX],
 176         [LINUX=$DEFAULT_LINUX])
 177 AC_MSG_RESULT([$LINUX])
 178 AC_SUBST(LINUX)
 179
 180 # -------- check for linux --------
 181 LB_CHECK_FILE([$LINUX],[],
 182         [AC_MSG_ERROR([Kernel source $LINUX could not be found.])])
 183
 184 # -------- linux objects (for 2.6) --
 185 AC_MSG_CHECKING([for Linux objects dir])
 186 AC_ARG_WITH([linux-obj],
 187         AC_HELP_STRING([--with-linux-obj=path],
 188                         [set path to Linux objects dir (default=/lib/modules/$(uname -r)/build,/usr/src/linux)]),
 189         [LB_ARG_CANON_PATH([linux-obj], [LINUX_OBJ])],
 190         [LINUX_OBJ=$DEFAULT_LINUX_OBJ])
 191
 192 AC_MSG_RESULT([$LINUX_OBJ])
 193 AC_SUBST(LINUX_OBJ)
 194
 195 # -------- check for .config --------
 196 AC_ARG_WITH([linux-config],
 197         [AC_HELP_STRING([--with-linux-config=path],
 198                         [set path to Linux .conf (default=$LINUX_OBJ/.config)])],
 199         [LB_ARG_CANON_PATH([linux-config], [LINUX_CONFIG])],
 200         [LINUX_CONFIG=$LINUX_OBJ/.config])
 201 AC_SUBST(LINUX_CONFIG)
 202
 203 LB_CHECK_FILE([/boot/kernel.h],
 204         [KERNEL_SOURCE_HEADER='/boot/kernel.h'],
 205         [LB_CHECK_FILE([/var/adm/running-kernel.h],
 206                 [KERNEL_SOURCE_HEADER='/var/adm/running-kernel.h'])])
 207
 208 AC_ARG_WITH([kernel-source-header],
 209         AC_HELP_STRING([--with-kernel-source-header=path],
 210                         [Use a different kernel version header.  Consult build/README.kernel-source for details.]),
 211         [LB_ARG_CANON_PATH([kernel-source-header], [KERNEL_SOURCE_HEADER])])
 212
 213 # ------------ .config exists ----------------
 214 LB_CHECK_FILE([$LINUX_CONFIG],[],
 215         [AC_MSG_ERROR([Kernel config could not be found.  If you are building from a kernel-source rpm consult build/README.kernel-source])])
 216
 217 # ----------- make dep run? ------------------
 218 # at 2.6.19 # $LINUX/include/linux/config.h is removed
 219 # and at more old has only one line
 220 # include <autoconf.h>
 221 LB_CHECK_FILE([$LINUX_OBJ/include/generated/autoconf.h],[AUTOCONF_HDIR=generated],
 222         [LB_CHECK_FILE([$LINUX_OBJ/include/linux/autoconf.h],[AUTOCONF_HDIR=linux],
 223         [AC_MSG_ERROR([Run make config in $LINUX.])])])
 224         AC_SUBST(AUTOCONF_HDIR)
 225 LB_CHECK_FILE([$LINUX_OBJ/include/linux/version.h],[],
 226         [AC_MSG_ERROR([Run make config in $LINUX.])])
 227
 228 # ----------- kconfig.h exists ---------------
 229 # kernel 3.1, $LINUX/include/linux/kconfig.h is added
 230 # see kernel commit 2a11c8ea20bf850b3a2c60db8c2e7497d28aba99
 231 LB_CHECK_FILE([$LINUX_OBJ/include/linux/kconfig.h],
 232               [CONFIG_INCLUDE=include/linux/kconfig.h],
 233               [CONFIG_INCLUDE=include/$AUTOCONF_HDIR/autoconf.h])
 234         AC_SUBST(CONFIG_INCLUDE)
 235
 236 # ------------ rhconfig.h includes runtime-generated bits --
 237 # red hat kernel-source checks
 238
 239 # we know this exists after the check above.  if the user
 240 # tarred up the tree and ran make dep etc. in it, then
 241 # version.h gets overwritten with a standard linux one.
 242
 243 if grep rhconfig $LINUX_OBJ/include/linux/version.h >/dev/null ; then
 244         # This is a clean kernel-source tree, we need to
 245         # enable extensive workarounds to get this to build
 246         # modules
 247         LB_CHECK_FILE([$KERNEL_SOURCE_HEADER],
 248                 [if test $KERNEL_SOURCE_HEADER = '/boot/kernel.h' ; then
 249                         AC_MSG_WARN([Using /boot/kernel.h from RUNNING kernel.])
 250                         AC_MSG_WARN([If this is not what you want, use --with-kernel-source-header.])
 251                         AC_MSG_WARN([Consult build/README.kernel-source for details.])
 252                 fi],
 253                 [AC_MSG_ERROR([$KERNEL_SOURCE_HEADER not found.  Consult build/README.kernel-source for details.])])
 254         EXTRA_KCFLAGS="-include $KERNEL_SOURCE_HEADER $EXTRA_KCFLAGS"
 255 fi
 256
 257 # this is needed before we can build modules
 258 LB_LINUX_CROSS
 259 LB_LINUX_VERSION
 260
 261 # --- check that we can build modules at all
 262 AC_MSG_CHECKING([that modules can be built at all])
 263 LB_LINUX_TRY_COMPILE([],[],[
 264         AC_MSG_RESULT([yes])
 265 ],[
 266         AC_MSG_RESULT([no])
 267         AC_MSG_WARN([Consult config.log for details.])
 268         AC_MSG_WARN([If you are trying to build with a kernel-source rpm, consult build/README.kernel-source])
 269         AC_MSG_ERROR([Kernel modules cannot be built.])
 270 ])
 271
 272 LB_LINUX_RELEASE
 273 ]) # end of LB_LINUX_PATH
 274
 275 # LB_LINUX_SYMVERFILE
 276 # SLES 9 uses a different name for this file - unsure about vanilla kernels
 277 # around this version, but it matters for servers only.
 278 AC_DEFUN([LB_LINUX_SYMVERFILE],
 279         [AC_MSG_CHECKING([name of module symbol version file])
 280         if grep -q Modules.symvers $LINUX/scripts/Makefile.modpost ; then
 281                 SYMVERFILE=Modules.symvers
 282         else
 283                 SYMVERFILE=Module.symvers
 284         fi
 285         AC_MSG_RESULT($SYMVERFILE)
 286         AC_SUBST(SYMVERFILE)
 287 ])
 288
 289 #
 290 # LB_LINUX_CROSS
 291 #
 292 # check for cross compilation
 293 #
 294 AC_DEFUN([LB_LINUX_CROSS],
 295         [AC_MSG_CHECKING([for cross compilation])
 296 CROSS_VARS=
 297 case $target_vendor in
 298         # The K1OM architecture is an extension of the x86 architecture.
 299         # So, the $target_arch is x86_64.
 300         k1om)
 301                 AC_MSG_RESULT([Intel(R) Xeon Phi(TM)])
 302                 CC_TARGET_ARCH=`$CC -v 2>&1 | grep Target: | sed -e 's/Target: //'`
 303                 if test $CC_TARGET_ARCH != x86_64-$target_vendor-linux ; then
 304                         AC_MSG_ERROR([Cross compiler not found in PATH.])
 305                 fi
 306                 CROSS_VARS="ARCH=$target_vendor CROSS_COMPILE=x86_64-$target_vendor-linux-"
 307                 CCAS=$CC
 308                 if test x$enable_server = xyes ; then
 309                         AC_MSG_WARN([Disabling server (not supported for x86_64-$target_vendor-linux).])
 310                         enable_server='no'
 311                 fi
 312                 ;;
 313         *)
 314                 AC_MSG_RESULT([no])
 315                 ;;
 316 esac
 317 AC_SUBST(CROSS_VARS)
 318 ])
 319
 320 # these are like AC_TRY_COMPILE, but try to build modules against the
 321 # kernel, inside the build directory
 322
 323 # LB_LANG_PROGRAM(C)([PROLOGUE], [BODY])
 324 # --------------------------------------
 325 m4_define([LB_LANG_PROGRAM],
 326 [
 327 #include <linux/kernel.h>
 328 $1
 329 int
 330 main (void)
 331 {
 332 dnl Do *not* indent the following line: there may be CPP directives.
 333 dnl Don't move the `;' right after for the same reason.
 334 $2
 335   ;
 336   return 0;
 337 }])
 338
 339 #
 340 # LB_LINUX_COMPILE_IFELSE
 341 #
 342 # like AC_COMPILE_IFELSE
 343 #
 344 AC_DEFUN([LB_LINUX_COMPILE_IFELSE],
 345 [m4_ifvaln([$1], [AC_LANG_CONFTEST([$1])])dnl
 346 rm -f build/conftest.o build/conftest.mod.c build/conftest.ko
 347 AS_IF([AC_TRY_COMMAND(cp conftest.c build && make -d [$2] ${LD:+"LD=$LD"} CC="$CC" -f $PWD/build/Makefile LUSTRE_LINUX_CONFIG=$LINUX_CONFIG LINUXINCLUDE="$EXTRA_LNET_INCLUDE -I$LINUX/arch/`echo $target_cpu|sed -e 's/powerpc64/powerpc/' -e 's/x86_64/x86/' -e 's/i.86/x86/'`/include -I$LINUX/arch/`echo $target_cpu|sed -e 's/ppc.*/powerpc/' -e 's/x86_64/x86/' -e 's/i.86/x86/'`/include/generated -I$LINUX_OBJ/include -I$LINUX/include -I$LINUX_OBJ/include2 -include $CONFIG_INCLUDE" -o tmp_include_depends -o scripts -o include/config/MARKER -C $LINUX_OBJ EXTRA_CFLAGS="-Werror-implicit-function-declaration $EXTRA_KCFLAGS" $CROSS_VARS $MODULE_TARGET=$PWD/build) >/dev/null && AC_TRY_COMMAND([$3])],
 348         [$4],
 349         [_AC_MSG_LOG_CONFTEST
 350 m4_ifvaln([$5],[$5])dnl])
 351 rm -f build/conftest.o build/conftest.mod.c build/conftest.mod.o build/conftest.ko m4_ifval([$1], [build/conftest.c conftest.c])[]dnl
 352 ])
 353
 354 #
 355 # LB_LINUX_ARCH
 356 #
 357 # Determine the kernel's idea of the current architecture
 358 #
 359 AC_DEFUN([LB_LINUX_ARCH],
 360          [AC_MSG_CHECKING([Linux kernel architecture])
 361           AS_IF([rm -f $PWD/build/arch
 362                  make -s --no-print-directory echoarch -f $PWD/build/Makefile \
 363                      LUSTRE_LINUX_CONFIG=$LINUX_CONFIG -C $LINUX $CROSS_VARS  \
 364                      ARCHFILE=$PWD/build/arch && LINUX_ARCH=`cat $PWD/build/arch`],
 365                 [AC_MSG_RESULT([$LINUX_ARCH])],
 366                 [AC_MSG_ERROR([Could not determine the kernel architecture.])])
 367           rm -f build/arch])
 368
 369 #
 370 # LB_LINUX_TRY_COMPILE
 371 #
 372 # like AC_TRY_COMPILE
 373 #
 374 AC_DEFUN([LB_LINUX_TRY_COMPILE],
 375 [LB_LINUX_COMPILE_IFELSE(
 376         [AC_LANG_SOURCE([LB_LANG_PROGRAM([[$1]], [[$2]])])],
 377         [modules],
 378         [test -s build/conftest.o],
 379         [$3], [$4])])
 380
 381 #
 382 # LB_LINUX_CONFIG
 383 #
 384 # check if a given config option is defined
 385 #
 386 AC_DEFUN([LB_LINUX_CONFIG],[
 387         AC_MSG_CHECKING([if Linux was built with CONFIG_$1])
 388         LB_LINUX_TRY_COMPILE([
 389                 #include <$AUTOCONF_HDIR/autoconf.h>
 390         ],[
 391                 #ifndef CONFIG_$1
 392                 #error CONFIG_$1 not #defined
 393                 #endif
 394         ],[
 395                 AC_MSG_RESULT([yes])
 396                 $2
 397         ],[
 398                 AC_MSG_RESULT([no])
 399                 $3
 400         ])
 401 ])
 402
 403 #
 404 # LB_LINUX_CONFIG_IM
 405 #
 406 # check if a given config option is builtin or as module
 407 #
 408 AC_DEFUN([LB_LINUX_CONFIG_IM],[
 409         AC_MSG_CHECKING([if Linux was built with CONFIG_$1 in or as module])
 410         LB_LINUX_TRY_COMPILE([
 411                 #include <$AUTOCONF_HDIR/autoconf.h>
 412         ],[
 413                 #if !(defined(CONFIG_$1) || defined(CONFIG_$1_MODULE))
 414                 #error CONFIG_$1 and CONFIG_$1_MODULE not #defined
 415                 #endif
 416         ],[
 417                 AC_MSG_RESULT([yes])
 418                 $2
 419         ],[
 420                 AC_MSG_RESULT([no])
 421                 $3
 422         ])
 423 ])
 424
 425 #
 426 # LB_LINUX_TRY_MAKE
 427 #
 428 # like LB_LINUX_TRY_COMPILE, but with different arguments
 429 #
 430 AC_DEFUN([LB_LINUX_TRY_MAKE],
 431         [LB_LINUX_COMPILE_IFELSE(
 432                 [AC_LANG_SOURCE([LB_LANG_PROGRAM([[$1]], [[$2]])])],
 433                 [$3], [$4], [$5], [$6]
 434         )]
 435 )
 436
 437 #
 438 # LB_CONFIG_COMPAT_RDMA
 439 #
 440 AC_DEFUN([LB_CONFIG_COMPAT_RDMA],
 441 [AC_MSG_CHECKING([whether to use Compat RDMA])
 442 # set default
 443 AC_ARG_WITH([o2ib],
 444         AC_HELP_STRING([--with-o2ib=path],
 445                        [build o2iblnd against path]),
 446         [
 447                 case $with_o2ib in
 448                 yes)    O2IBPATHS="$LINUX $LINUX/drivers/infiniband"
 449                         ENABLEO2IB=2
 450                         ;;
 451                 no)     ENABLEO2IB=0
 452                         ;;
 453                 *)      O2IBPATHS=$with_o2ib
 454                         ENABLEO2IB=3
 455                         ;;
 456                 esac
 457         ],[
 458                 O2IBPATHS="$LINUX $LINUX/drivers/infiniband"
 459                 ENABLEO2IB=1
 460         ])
 461 if test $ENABLEO2IB -eq 0; then
 462         AC_MSG_RESULT([no])
 463 else
 464         o2ib_found=false
 465         for O2IBPATH in $O2IBPATHS; do
 466                 if test \( -f ${O2IBPATH}/include/rdma/rdma_cm.h -a \
 467                            -f ${O2IBPATH}/include/rdma/ib_cm.h -a \
 468                            -f ${O2IBPATH}/include/rdma/ib_verbs.h -a \
 469                            -f ${O2IBPATH}/include/rdma/ib_fmr_pool.h \); then
 470                         o2ib_found=true
 471                         break
 472                 fi
 473         done
 474         compatrdma_found=false
 475         if $o2ib_found; then
 476                 if test \( -f ${O2IBPATH}/include/linux/compat-2.6.h \); then
 477                         compatrdma_found=true
 478                         AC_MSG_RESULT([yes])
 479                         AC_DEFINE(HAVE_COMPAT_RDMA, 1, [compat rdma found])
 480                 else
 481                         AC_MSG_RESULT([no])
 482                 fi
 483         fi
 484 fi
 485 ])
 486
 487 #
 488 # LB_CONFIG_OFED_BACKPORTS
 489 #
 490 # include any OFED backport headers in all compile commands
 491 # NOTE: this does only include the backport paths, not the OFED headers
 492 #       adding the OFED headers is done in the lnet portion
 493 AC_DEFUN([LB_CONFIG_OFED_BACKPORTS],
 494 [AC_MSG_CHECKING([whether to use any OFED backport headers])
 495 if test $ENABLEO2IB -eq 0; then
 496         AC_MSG_RESULT([no])
 497 else
 498         if ! $o2ib_found; then
 499                 AC_MSG_RESULT([no])
 500                 case $ENABLEO2IB in
 501                         1) ;;
 502                         2) AC_MSG_ERROR([kernel OpenIB gen2 headers not present]);;
 503                         3) AC_MSG_ERROR([bad --with-o2ib path]);;
 504                         *) AC_MSG_ERROR([internal error]);;
 505                 esac
 506         else
 507                 if ! $compatrdma_found; then
 508                         if test -f $O2IBPATH/config.mk; then
 509                                 . $O2IBPATH/config.mk
 510                         elif test -f $O2IBPATH/ofed_patch.mk; then
 511                                 . $O2IBPATH/ofed_patch.mk
 512                         fi
 513                 fi
 514                 if test -n "$BACKPORT_INCLUDES"; then
 515                         OFED_BACKPORT_PATH="$O2IBPATH/${BACKPORT_INCLUDES/*\/kernel_addons/kernel_addons}/"
 516                         EXTRA_LNET_INCLUDE="-I$OFED_BACKPORT_PATH $EXTRA_LNET_INCLUDE"
 517                         AC_MSG_RESULT([yes])
 518                 else
 519                         AC_MSG_RESULT([no])
 520                 fi
 521         fi
 522 fi
 523 ])
 524
 525 # LC_MODULE_LOADING
 526 # after 2.6.28 CONFIG_KMOD is removed, and only CONFIG_MODULES remains
 527 # so we test if request_module is implemented or not
 528 AC_DEFUN([LC_MODULE_LOADING],
 529 [AC_MSG_CHECKING([if kernel module loading is possible])
 530 LB_LINUX_TRY_MAKE([
 531         #include <linux/kmod.h>
 532 ],[
 533         int myretval=ENOSYS ;
 534         return myretval;
 535 ],[
 536         $makerule LUSTRE_KERNEL_TEST=conftest.i
 537 ],[dnl
 538         grep request_module build/conftest.i |dnl
 539                 grep -v `grep "int myretval=" build/conftest.i |dnl
 540                         cut -d= -f2 | cut -d" "  -f1`dnl
 541                 >/dev/null dnl
 542 ],[
 543         AC_MSG_RESULT(yes)
 544         AC_DEFINE(HAVE_MODULE_LOADING_SUPPORT, 1,
 545                   [kernel module loading is possible])
 546 ],[
 547         AC_MSG_RESULT(no)
 548         AC_MSG_WARN([])
 549         AC_MSG_WARN([Kernel module loading support is highly recommended.])
 550         AC_MSG_WARN([])
 551 ])
 552 ])
 553
 554 #
 555 # LB_PROG_LINUX
 556 #
 557 # linux tests
 558 #
 559 AC_DEFUN([LB_PROG_LINUX],
 560 [LB_LINUX_PATH
 561 LB_LINUX_ARCH
 562 LB_LINUX_SYMVERFILE
 563
 564
 565 LB_LINUX_CONFIG([MODULES],[],[
 566         AC_MSG_ERROR([module support is required to build Lustre kernel modules.])
 567 ])
 568
 569 LB_LINUX_CONFIG([MODVERSIONS])
 570
 571 LB_LINUX_CONFIG([KALLSYMS],[],[
 572         AC_MSG_ERROR([Lustre requires that CONFIG_KALLSYMS is enabled in your kernel.])
 573 ])
 574
 575 # 2.6.28
 576 LC_MODULE_LOADING
 577
 578 LB_CONFIG_COMPAT_RDMA
 579
 580 # it's ugly to be doing anything with OFED outside of the lnet module, but
 581 # this has to be done here so that the backports path is set before all of
 582 # the LN_PROG_LINUX checks are done
 583 LB_CONFIG_OFED_BACKPORTS
 584 ])
 585
 586 #
 587 # LB_CHECK_SYMBOL_EXPORT
 588 # check symbol exported or not
 589 # $1 - symbol
 590 # $2 - file(s) for find.
 591 # $3 - do 'yes'
 592 # $4 - do 'no'
 593 #
 594 # 2.6 based kernels - put modversion info into $LINUX/Module.modvers
 595 # or check
 596 AC_DEFUN([LB_CHECK_SYMBOL_EXPORT],
 597 [AC_MSG_CHECKING([if Linux was built with symbol $1 exported])
 598 grep -q -E '[[[:space:]]]$1[[[:space:]]]' $LINUX/$SYMVERFILE 2>/dev/null
 599 rc=$?
 600 if test $rc -ne 0; then
 601         export=0
 602         for file in $2; do
 603                 grep -q -E "EXPORT_SYMBOL.*\($1\)" "$LINUX/$file" 2>/dev/null
 604                 rc=$?
 605                 if test $rc -eq 0; then
 606                         export=1
 607                         break;
 608                 fi
 609         done
 610         if test $export -eq 0; then
 611                 AC_MSG_RESULT([no])
 612                 $4
 613         else
 614                 AC_MSG_RESULT([yes])
 615                 $3
 616         fi
 617 else
 618         AC_MSG_RESULT([yes])
 619         $3
 620 fi
 621 ])
 622
 623 #
 624 # Like AC_CHECK_HEADER but checks for a kernel-space header
 625 #
 626 m4_define([LB_CHECK_LINUX_HEADER],
 627 [AS_VAR_PUSHDEF([ac_Header], [ac_cv_header_$1])dnl
 628 AC_CACHE_CHECK([for $1], ac_Header,
 629                [LB_LINUX_COMPILE_IFELSE([LB_LANG_PROGRAM([@%:@include <$1>])],
 630                                   [modules],
 631                                   [test -s build/conftest.o],
 632                                   [AS_VAR_SET(ac_Header, [yes])],
 633                                   [AS_VAR_SET(ac_Header, [no])])])
 634 AS_IF([test AS_VAR_GET(ac_Header) = yes], [$2], [$3])[]dnl
 635 AS_VAR_POPDEF([ac_Header])dnl
 636 ])
 637
 638 #
 639 # LB_USES_DPKG
 640 #
 641 # Determine if the target is a dpkg system or rpm
 642 #
 643 AC_DEFUN([LB_USES_DPKG],
 644 [
 645 AC_MSG_CHECKING([if this distro uses dpkg])
 646 case `lsb_release -i -s 2>/dev/null` in
 647         Ubuntu | Debian)
 648                 AC_MSG_RESULT([yes])
 649                 uses_dpkg=yes
 650                 ;;
 651         *)
 652                 AC_MSG_RESULT([no])
 653                 uses_dpkg=no
 654                 ;;
 655 esac
 656 ])