config/lustre-build-linux.m4

   1 #
   2 # LB_LINUX_VERSION
   3 #
   4 # Set things accordingly for a linux kernel
   5 #
   6 AC_DEFUN([LB_LINUX_VERSION], [
   7 KMODEXT=".ko"
   8 AC_SUBST(KMODEXT)
   9
  10 makerule="$PWD/build"
  11 AC_CACHE_CHECK([for external module build target], lb_cv_module_target, [
  12 lb_cv_module_target=""
  13 MODULE_TARGET="SUBDIRS"
  14 rm -f build/conftest.i
  15 LB_LINUX_TRY_MAKE([], [],
  16         [$makerule LUSTRE_KERNEL_TEST=conftest.i],
  17         [test -s build/conftest.i],
  18         [lb_cv_module_target="SUBDIRS"], [
  19                 MODULE_TARGET="M"
  20                 makerule="_module_$PWD/build"
  21                 LB_LINUX_TRY_MAKE([], [],
  22                         [$makerule LUSTRE_KERNEL_TEST=conftest.i],
  23                         [test -s build/conftest.i],
  24                         [lb_cv_module_target="M"], [
  25                                 AC_MSG_ERROR([unknown; check config.log for details])
  26                         ])
  27         ])
  28 ])
  29 AS_IF([test -z "$lb_cv_module_target"],
  30         [AC_MSG_ERROR([unknown external module build target])],
  31 [test "x$lb_cv_module_target" = "xM"],
  32         [makerule="_module_$PWD/build"])
  33 MODULE_TARGET=$lb_cv_module_target
  34 AC_SUBST(MODULE_TARGET)
  35 ])
  36
  37 #
  38 # LB_LINUX_UTSRELEASE
  39 #
  40 # Determine the Linux kernel version string from the utsrelease
  41 #
  42 AC_DEFUN([LB_LINUX_UTSRELEASE], [
  43 AC_CACHE_CHECK([for Linux kernel utsrelease], lb_cv_utsrelease, [
  44 lb_cv_utsrelease=""
  45 utsrelease1=$LINUX_OBJ/include/generated/utsrelease.h
  46 utsrelease2=$LINUX_OBJ/include/linux/utsrelease.h
  47 utsrelease3=$LINUX_OBJ/include/linux/version.h
  48 AS_IF([test -r $utsrelease1 && fgrep -q UTS_RELEASE $utsrelease1],
  49         [utsrelease=$utsrelease1],
  50 [test -r $utsrelease2 && fgrep -q UTS_RELEASE $utsrelease2],
  51         [utsrelease=$utsrelease2],
  52 [test -r $utsrelease3 && fgrep -q UTS_RELEASE $utsrelease3],
  53         [utsrelease=$utsrelease3])
  54 AS_IF([test -n "$utsrelease"],
  55         [lb_cv_utsrelease=$(awk -F \" '/ UTS_RELEASE / { print [$]2 }' $utsrelease)],
  56         [AC_MSG_ERROR([
  57
  58 Cannot find UTS_RELEASE definition.
  59
  60 This is often provided by the kernel-devel package.
  61 ])
  62         ])
  63 ])
  64 AS_IF([test -z "$lb_cv_utsrelease"],
  65         [AC_MSG_ERROR([Cannot determine Linux kernel version.])])
  66 LINUXRELEASE=$lb_cv_utsrelease
  67 AC_SUBST(LINUXRELEASE)
  68 ])
  69
  70 #
  71 # LB_LINUX_RELEASE
  72 #
  73 # get the release version of linux
  74 #
  75 AC_DEFUN([LB_LINUX_RELEASE], [
  76 LB_LINUX_UTSRELEASE
  77
  78 # ------------ RELEASE --------------------------------
  79 AC_MSG_CHECKING([for Lustre release])
  80 AC_ARG_WITH([release],
  81         AC_HELP_STRING([--with-release=string],
  82                 [set the release string (default=$kvers_YYYYMMDDhhmm)]),
  83         [RELEASE=$withval], [
  84         RELEASE=""
  85         AS_IF([test "$DOWNSTREAM_RELEASE"], [RELEASE="${DOWNSTREAM_RELEASE}_"])
  86         RELEASE="$RELEASE$(echo $LINUXRELEASE | tr '-' '_')_$BUILDID"])
  87 AC_MSG_RESULT($RELEASE)
  88 AC_SUBST(RELEASE)
  89
  90 # check if the kernel is one from RHEL or SUSE
  91 AC_CACHE_CHECK([for RedHat kernel version], lb_cv_rhel_kernel_version, [
  92 lb_cv_rhel_kernel_version=""
  93 AS_IF([fgrep -q RHEL_RELEASE $LINUX_OBJ/include/$VERSION_HDIR/version.h],
  94         [RHEL_RELEASE=$(expr 0$(awk -F \" '/ RHEL_RELEASE / { print [$]2 }' \
  95                        $LINUX_OBJ/include/$VERSION_HDIR/version.h) + 1)
  96         KERNEL_VERSION=$(sed -e 's/\(@<:@23@:>@\.@<:@0-9@:>@*\.@<:@0-9@:>@*\).*/\1/' <<< $LINUXRELEASE)
  97         lb_cv_rhel_kernel_version=${KERNEL_VERSION}-${RHEL_RELEASE}])
  98 ])
  99 AS_IF([test -n "$lb_cv_rhel_kernel_version"], [
 100         RHEL_KERNEL="yes"
 101         RHEL_KERNEL_VERSION=$lb_cv_rhel_kernel_version
 102 ], [
 103         RHEL_KERNEL="no"
 104         LB_CHECK_CONFIG([SUSE_KERNEL], [SUSE_KERNEL="yes"], [SUSE_KERNEL="no"])
 105 ])
 106
 107 AC_MSG_CHECKING([for Linux kernel module package directory])
 108 AC_ARG_WITH([kmp-moddir],
 109         AC_HELP_STRING([--with-kmp-moddir=string],
 110                 [set the kmod updates or extra directory]),
 111         [KMP_MODDIR=$withval],[
 112         AS_IF([test x$RHEL_KERNEL = xyes], [KMP_MODDIR="extra"],
 113               [test x$SUSE_KERNEL = xyes], [KMP_MODDIR="updates"])])
 114 AC_MSG_RESULT($KMP_MODDIR)
 115 AC_SUBST(KMP_MODDIR)
 116
 117 moduledir='$(CROSS_PATH)/lib/modules/$(LINUXRELEASE)/$(KMP_MODDIR)/kernel'
 118 AC_SUBST(moduledir)
 119
 120 modulefsdir='$(moduledir)/fs/$(PACKAGE)'
 121 AC_SUBST(modulefsdir)
 122
 123 modulenetdir='$(moduledir)/net/$(PACKAGE)'
 124 AC_SUBST(modulenetdir)
 125 ])
 126
 127 #
 128 # LB_LINUX_SYMVERFILE
 129 #
 130 # SLES 9 uses a different name for this file - unsure about vanilla kernels
 131 # around this version, but it matters for servers only.
 132 AC_DEFUN([LB_LINUX_SYMVERFILE], [
 133 AC_CACHE_CHECK([for the name of module symbol version file], lb_cv_module_symvers, [
 134 AS_IF([grep -q Modules.symvers $LINUX/scripts/Makefile.modpost],
 135         [lb_cv_module_symvers=Modules.symvers],
 136         [lb_cv_module_symvers=Module.symvers])
 137 ])
 138 SYMVERFILE=$lb_cv_module_symvers
 139 AC_SUBST(SYMVERFILE)
 140 ])
 141
 142 #
 143 # LB_LINUX_CROSS
 144 #
 145 # check for cross compilation
 146 #
 147 AC_DEFUN([LB_LINUX_CROSS], [
 148 AC_CACHE_CHECK([for cross compilation], lb_cv_cross, [
 149 lb_cv_cross="no"
 150 AS_IF([test "x$cross_compiling" = xyes],
 151         [AS_CASE([$host_vendor],
 152                 [k1om | mpss], [
 153                         # The K1OM architecture is an extension of the x86 architecture
 154                         # and in MPSS 2.1 it's defined in $host_vendor. But in MPSS 3.x
 155                         # it's defined in $host_arch. So, try to support both case.
 156                         lb_cv_cross=$($CC -v 2>&1 | grep Target: | sed -e 's/Target: //')
 157                         AS_IF([test "$lb_cv_cross" != x86_64-k1om-linux -a \
 158                                     "$lb_cv_cross" != k1om-mpss-linux], [
 159                                 AC_MSG_ERROR([Cross compiler not found in PATH.])
 160                         ])
 161                 ])
 162         ])
 163 ])
 164 AS_IF([test "$lb_cv_cross" = x86_64-k1om-linux -o \
 165             "$lb_cv_cross" = k1om-mpss-linux], [
 166         CROSS_VARS="ARCH=k1om CROSS_COMPILE=${lb_cv_cross}-"
 167         CROSS_PATH="${CROSS_PATH:=/opt/lustre/$VERSION/$lb_cv_cross}"
 168         CCAS=$CC
 169         # need to produce special section for debuginfo extraction
 170         LDFLAGS="$LDFLAGS -Wl,--build-id"
 171         EXTRA_KLDFLAGS="$EXTRA_KLDFLAGS -Wl,--build-id"
 172         AS_IF([test "x$enable_server" != xno], [
 173                 AC_MSG_WARN([Disabling server (not supported for $lb_cv_cross).])
 174                 enable_server="no"
 175         ])
 176         AS_IF([test "x$enable_mpitests" != xno], [
 177                 AC_MSG_WARN([Disabling MPI tests (not supported for $lb_cv_cross).])
 178                 enable_mpitests="no"
 179         ])
 180 ])
 181 AC_SUBST(CROSS_VARS)
 182 AC_SUBST(CROSS_PATH)
 183 ])
 184
 185 #
 186 # LB_ARG_REPLACE_PATH(PACKAGE, PATH)
 187 #
 188 AC_DEFUN([LB_ARG_REPLACE_PATH], [
 189 new_configure_args=
 190 eval set -- $ac_configure_args
 191 for arg; do
 192         case $arg in
 193                 --with-[$1]=*)
 194                         arg=--with-[$1]=[$2] ;;
 195                 *\'*)
 196                         arg=$(printf %s\n ["$arg"] | sed "s/'/'\\\\\\\\''/g") ;;
 197         esac
 198         dnl AS_VAR_APPEND([new_configure_args], [" '$arg'"])
 199         new_configure_args="$new_configure_args '$arg'"
 200 done
 201 ac_configure_args=$new_configure_args
 202 ])
 203
 204 #
 205 # __LB_ARG_CANON_PATH
 206 #
 207 # this is the work-horse of the next function
 208 #
 209 AC_DEFUN([__LB_ARG_CANON_PATH], [
 210         [$3]=$(readlink -f $with_$2)
 211         LB_ARG_REPLACE_PATH([$1], $[$3])
 212 ])
 213
 214 #
 215 # LB_ARG_CANON_PATH
 216 #
 217 # a front-end for the above function that transforms - and . in the
 218 # PACKAGE portion of --with-PACKAGE into _ suitable for variable names
 219 #
 220 AC_DEFUN([LB_ARG_CANON_PATH], [
 221         __LB_ARG_CANON_PATH([$1], m4_translit([$1], [-.], [__]), [$2])
 222 ])
 223
 224 #
 225 # LB_LINUX_PATH
 226 #
 227 # Find paths for linux, handling kernel-source rpms
 228 #
 229 AC_DEFUN([LB_LINUX_PATH], [
 230 for DEFAULT_LINUX in /lib/modules/$(uname -r)/{source,build} /usr/src/linux; do
 231         AS_IF([readlink -q -e $DEFAULT_LINUX >/dev/null], [break])
 232 done
 233 if test "$DEFAULT_LINUX" = "/lib/modules/$(uname -r)/source"; then
 234         PATHS="/lib/modules/$(uname -r)/build"
 235 fi
 236 PATHS+=" $DEFAULT_LINUX"
 237 for DEFAULT_LINUX_OBJ in $PATHS; do
 238         AS_IF([readlink -q -e $DEFAULT_LINUX_OBJ >/dev/null], [break])
 239 done
 240
 241 AC_MSG_CHECKING([for Linux sources])
 242 AC_ARG_WITH([linux],
 243         AC_HELP_STRING([--with-linux=path],
 244                        [set path to Linux source (default=/lib/modules/$(uname -r)/{source,build},/usr/src/linux)]),
 245         [LB_ARG_CANON_PATH([linux], [LINUX])
 246         DEFAULT_LINUX_OBJ=$LINUX],
 247         [LINUX=$DEFAULT_LINUX])
 248 AC_MSG_RESULT([$LINUX])
 249 AC_SUBST(LINUX)
 250
 251 # -------- check for linux --------
 252 LB_CHECK_FILE([$LINUX], [],
 253         [AC_MSG_ERROR([Kernel source $LINUX could not be found.])])
 254
 255 # -------- linux objects (for 2.6) --
 256 AC_MSG_CHECKING([for Linux objects])
 257 AC_ARG_WITH([linux-obj],
 258         AC_HELP_STRING([--with-linux-obj=path],
 259                         [set path to Linux objects (default=/lib/modules/$(uname -r)/build,/usr/src/linux)]),
 260         [LB_ARG_CANON_PATH([linux-obj], [LINUX_OBJ])],
 261         [LINUX_OBJ=$DEFAULT_LINUX_OBJ])
 262 AC_MSG_RESULT([$LINUX_OBJ])
 263 AC_SUBST(LINUX_OBJ)
 264
 265 # -------- check for .config --------
 266 AC_ARG_WITH([linux-config],
 267         [AC_HELP_STRING([--with-linux-config=path],
 268                         [set path to Linux .conf (default=$LINUX_OBJ/.config)])],
 269         [LB_ARG_CANON_PATH([linux-config], [LINUX_CONFIG])],
 270         [LINUX_CONFIG=$LINUX_OBJ/.config])
 271
 272 # -------- check if .config exists --
 273 LB_CHECK_FILE([$LINUX_CONFIG], [],
 274         [AC_MSG_ERROR([
 275
 276 Kernel config could not be found.
 277
 278 If you are building from a kernel-source rpm consult build/README.kernel-source
 279 ])
 280 ])
 281 AC_SUBST(LINUX_CONFIG)
 282
 283 LB_CHECK_FILE([/boot/kernel.h],
 284         [KERNEL_SOURCE_HEADER='/boot/kernel.h'],
 285         [LB_CHECK_FILE([/var/adm/running-kernel.h],
 286                 [KERNEL_SOURCE_HEADER='/var/adm/running-kernel.h'])])
 287
 288 AC_ARG_WITH([kernel-source-header],
 289         AC_HELP_STRING([--with-kernel-source-header=path],
 290                         [Use a different kernel version header.  Consult build/README.kernel-source for details.]),
 291         [LB_ARG_CANON_PATH([kernel-source-header], [KERNEL_SOURCE_HEADER])])
 292
 293 # ----------- make dep run? ------------------
 294 # at 2.6.19 # $LINUX/include/linux/config.h is removed
 295 # and at more old has only one line include <autoconf.h>
 296 #
 297 LB_CHECK_FILE([$LINUX_OBJ/include/generated/autoconf.h],
 298         [AUTOCONF_HDIR=generated],
 299         [LB_CHECK_FILE([$LINUX_OBJ/include/linux/autoconf.h],
 300                 [AUTOCONF_HDIR=linux],
 301                 [AC_MSG_ERROR([Run make config in $LINUX.])])])
 302 AC_SUBST(AUTOCONF_HDIR)
 303
 304 LB_CHECK_FILE([$LINUX_OBJ/include/linux/version.h],
 305         [VERSION_HDIR=linux],
 306         [LB_CHECK_FILE([$LINUX_OBJ/include/generated/uapi/linux/version.h],
 307                 [VERSION_HDIR=generated/uapi/linux],
 308                 [AC_MSG_ERROR([Run make config in $LINUX.])])])
 309 AC_SUBST(VERSION_HDIR)
 310
 311 # ----------- kconfig.h exists ---------------
 312 # kernel 3.1, $LINUX/include/linux/kconfig.h is added
 313 # see kernel commit 2a11c8ea20bf850b3a2c60db8c2e7497d28aba99
 314 #
 315 LB_CHECK_FILE([$LINUX/include/linux/kconfig.h],
 316               [CONFIG_INCLUDE=$LINUX/include/linux/kconfig.h],
 317               [CONFIG_INCLUDE=include/$AUTOCONF_HDIR/autoconf.h])
 318 AC_SUBST(CONFIG_INCLUDE)
 319
 320 # ------------ rhconfig.h includes runtime-generated bits --
 321 # RedHat kernel-source checks
 322
 323 # we know this exists after the check above.  if the user
 324 # tarred up the tree and ran make dep etc. in it, then
 325 # version.h gets overwritten with a standard linux one.
 326
 327 AS_IF([grep rhconfig $LINUX_OBJ/include/$VERSION_HDIR/version.h >/dev/null], [
 328         # This is a clean kernel-source tree, we need to
 329         # enable extensive workarounds to get this to build modules
 330         LB_CHECK_FILE([$KERNEL_SOURCE_HEADER], [
 331                 AS_IF([test $KERNEL_SOURCE_HEADER = '/boot/kernel.h'],
 332                         [AC_MSG_WARN([
 333
 334 Using /boot/kernel.h from RUNNING kernel.
 335
 336 If this is not what you want, use --with-kernel-source-header.
 337 Consult build/README.kernel-source for details.
 338 ])
 339                 ])],
 340                 [AC_MSG_ERROR([
 341
 342 $KERNEL_SOURCE_HEADER not found.
 343
 344 Consult build/README.kernel-source for details.
 345 ])
 346                 ])
 347         EXTRA_KCFLAGS="-include $KERNEL_SOURCE_HEADER $EXTRA_KCFLAGS"
 348 ])
 349
 350 # this is needed before we can build modules
 351 LB_LINUX_CROSS
 352 LB_LINUX_VERSION
 353
 354 # --- check that we can build modules at all
 355 LB_CHECK_COMPILE([that modules can be built at all], build_modules,
 356         [], [], [], [
 357         AC_MSG_ERROR([
 358
 359 Kernel modules cannot be built. Consult config.log for details.
 360
 361 If you are trying to build with a kernel-source rpm,
 362 consult build/README.kernel-source
 363 ])
 364 ])
 365
 366 LB_LINUX_RELEASE
 367 ]) # end of LB_LINUX_PATH
 368
 369 #
 370 # LC_MODULE_LOADING
 371 #
 372 # after 2.6.28 CONFIG_KMOD is removed, and only CONFIG_MODULES remains
 373 # so we test if request_module is implemented or not
 374 AC_DEFUN([LC_MODULE_LOADING], [
 375 AC_CACHE_CHECK([if Linux kernel module loading is possible], lb_cv_module_loading, [
 376 LB_LINUX_TRY_MAKE([
 377         #include <linux/kmod.h>
 378 ], [
 379         int myretval=ENOSYS ;
 380         return myretval;
 381 ], [
 382         $makerule LUSTRE_KERNEL_TEST=conftest.i
 383 ], [dnl
 384         grep request_module build/conftest.i |dnl
 385                 grep -v `grep "int myretval=" build/conftest.i |dnl
 386                         cut -d= -f2 | cut -d" "  -f1`dnl
 387                 >/dev/null dnl
 388 ], [lb_cv_module_loading="yes"], [lb_cv_module_loading="no"])
 389 ])
 390 AS_IF([test "$lb_cv_module_loading" = yes],
 391         [AC_DEFINE(HAVE_MODULE_LOADING_SUPPORT, 1,
 392                 [kernel module loading is possible])],
 393         [AC_MSG_WARN([
 394
 395 Kernel module loading support is highly recommended.
 396
 397 ])
 398         ])
 399 ])
 400
 401 #
 402 # LB_PROG_LINUX
 403 #
 404 # linux tests
 405 #
 406 AC_DEFUN([LB_PROG_LINUX], [
 407 LB_LINUX_PATH
 408 LB_LINUX_SYMVERFILE
 409
 410 LB_CHECK_CONFIG([MODULES], [], [
 411         AC_MSG_ERROR([
 412
 413 module support is required to build Lustre kernel modules.
 414 ])
 415         ])
 416
 417 LB_CHECK_CONFIG([MODVERSIONS])
 418
 419 LB_CHECK_CONFIG([KALLSYMS], [], [
 420         AC_MSG_ERROR([
 421
 422 Lustre requires that CONFIG_KALLSYMS is enabled in your kernel.
 423 ])
 424         ])
 425
 426 # 2.6.28
 427 LC_MODULE_LOADING
 428 ])
 429
 430 #
 431 # LB_USES_DPKG
 432 #
 433 # Determine if the target is a dpkg system or rpm
 434 #
 435 AC_DEFUN([LB_USES_DPKG], [
 436 AC_CACHE_CHECK([if this distro uses dpkg], lb_cv_uses_dpkg, [
 437 lb_cv_uses_dpkg="no"
 438 AS_CASE([$(lsb_release -i -s 2>/dev/null)],
 439         [Ubuntu | Debian], [lb_cv_uses_dpkg="yes"])
 440 ])
 441 uses_dpkg=$lb_cv_uses_dpkg
 442 ])
 443
 444 #
 445 # LB_CHECK_EXPORT
 446 #
 447 # check symbol exported or not
 448 # $1 - symbol
 449 # $2 - file(s) for find.
 450 # $3 - do 'yes'
 451 # $4 - do 'no'
 452 #
 453 # 2.6 based kernels - put modversion info into $LINUX/Module.modvers or check
 454 #
 455 AC_DEFUN([LB_CHECK_EXPORT], [
 456 AS_VAR_PUSHDEF([lb_export], [lb_cv_export_$1])dnl
 457 AC_CACHE_CHECK([if Linux kernel exports '$1'], lb_export, [
 458 AS_VAR_SET([lb_export], [no])
 459 AS_IF([grep -q -E '[[[:space:]]]$1[[[:space:]]]' $LINUX_OBJ/$SYMVERFILE 2>/dev/null],
 460         [AS_VAR_SET([lb_export], [yes])],
 461         [for file in $2; do
 462                 AS_IF([grep -q -E "EXPORT_SYMBOL.*\($1\)" "$LINUX/$file" 2>/dev/null], [
 463                         AS_VAR_SET([lb_export], [yes])
 464                         break
 465                 ])
 466         done])
 467 ])
 468 AS_VAR_IF([lb_export], [yes], [$3], [$4])[]dnl
 469 AS_VAR_POPDEF([lb_export])dnl
 470 ]) # LB_CHECK_EXPORT
 471
 472 #
 473 # LB_CHECK_CONFIG
 474 #
 475 # check if a given config option is defined
 476 # $1 - CONFIG_<name>
 477 # $2 - do 'yes'
 478 # $3 - do 'no'
 479 #
 480 AC_DEFUN([LB_CHECK_CONFIG], [
 481 LB_CHECK_COMPILE([if Linux kernel was built with CONFIG_$1],
 482 config_$1, [
 483         #include <$AUTOCONF_HDIR/autoconf.h>
 484 ], [
 485         #ifndef CONFIG_$1
 486         #error CONFIG_$1 not #defined
 487         #endif
 488 ], [$2], [$3])
 489 ]) # LB_CHECK_CONFIG
 490
 491 #
 492 # LB_CHECK_CONFIG_IM
 493 #
 494 # check if a given config option is builtin or as module
 495 # $1 - CONFIG_<name> or CONFIG_<name>_MODULE
 496 # $2 - do 'yes'
 497 # $3 - do 'no'
 498 #
 499 AC_DEFUN([LB_CHECK_CONFIG_IM], [
 500 LB_CHECK_COMPILE([if Linux kernel was built with CONFIG_$1 in or as module],
 501 config_im_$1, [
 502         #include <$AUTOCONF_HDIR/autoconf.h>
 503 ], [
 504         #if !(defined(CONFIG_$1) || defined(CONFIG_$1_MODULE))
 505         #error CONFIG_$1 and CONFIG_$1_MODULE not #defined
 506         #endif
 507 ], [$2], [$3])
 508 ]) # LB_CHECK_CONFIG_IM
 509
 510 #
 511 # these are like AC_TRY_COMPILE, but try to build modules against the
 512 # kernel, inside the build directory
 513 #
 514
 515 #
 516 # LB_LANG_PROGRAM(C)([PROLOGUE], [BODY])
 517 # --------------------------------------
 518 #
 519 m4_define([LB_LANG_PROGRAM],
 520 [
 521 #include <linux/kernel.h>
 522 $1
 523 int
 524 main (void)
 525 {
 526 dnl Do *not* indent the following line: there may be CPP directives.
 527 dnl Don't move the `;' right after for the same reason.
 528 $2
 529   ;
 530   return 0;
 531 }])
 532
 533 #
 534 # LB_LINUX_COMPILE_IFELSE
 535 #
 536 # like AC_COMPILE_IFELSE
 537 #
 538 # $1 - AC_LANG_SOURCE()
 539 # $2 - make target
 540 # $3 - check command
 541 # $4 - do 'yes'
 542 # $5 - do 'no'
 543 #
 544 AC_DEFUN([LB_LINUX_COMPILE_IFELSE],
 545 [m4_ifvaln([$1], [AC_LANG_CONFTEST([AC_LANG_SOURCE([$1])])])dnl
 546 rm -f build/conftest.o build/conftest.mod.c build/conftest.ko
 547 SUBARCH=$(echo $target_cpu | sed -e 's/powerpc64/powerpc/' -e 's/x86_64/x86/' -e 's/i.86/x86/' -e 's/k1om/x86/')
 548 AS_IF([AC_TRY_COMMAND(cp conftest.c build && make -d [$2] ${LD:+"LD=$LD"} CC="$CC" -f $PWD/build/Makefile LUSTRE_LINUX_CONFIG=$LINUX_CONFIG LINUXINCLUDE="$EXTRA_OFED_INCLUDE -I$LINUX/arch/$SUBARCH/include -Iinclude -Iarch/$SUBARCH/include/generated -I$LINUX/include -Iinclude2 -I$LINUX/include/uapi -Iinclude/generated -I$LINUX/arch/$SUBARCH/include/uapi -Iarch/$SUBARCH/include/generated/uapi -I$LINUX/include/uapi -Iinclude/generated/uapi ${SPL_OBJ:+-include $SPL_OBJ/spl_config.h} ${ZFS_OBJ:+-include $ZFS_OBJ/zfs_config.h} ${SPL:+-I$SPL -I$SPL/include } ${ZFS:+-I$ZFS -I$ZFS/include} -include $CONFIG_INCLUDE" -o tmp_include_depends -o scripts -o include/config/MARKER -C $LINUX_OBJ EXTRA_CFLAGS="-Werror-implicit-function-declaration $EXTRA_KCFLAGS" $CROSS_VARS $MODULE_TARGET=$PWD/build) >/dev/null && AC_TRY_COMMAND([$3])],
 549         [$4],
 550         [_AC_MSG_LOG_CONFTEST
 551 m4_ifvaln([$5],[$5])dnl])
 552 rm -f build/conftest.o build/conftest.mod.c build/conftest.mod.o build/conftest.ko m4_ifval([$1], [build/conftest.c conftest.c])[]dnl
 553 ])
 554
 555 #
 556 # LB_LINUX_TRY_COMPILE
 557 #
 558 # like AC_TRY_COMPILE
 559 #
 560 AC_DEFUN([LB_LINUX_TRY_COMPILE], [
 561 LB_LINUX_COMPILE_IFELSE(
 562         [AC_LANG_SOURCE([LB_LANG_PROGRAM([[$1]], [[$2]])])],
 563         [modules], [test -s build/conftest.o],
 564         [$3], [$4])
 565 ])
 566
 567 #
 568 # LB_LINUX_TRY_MAKE
 569 #
 570 # like LB_LINUX_TRY_COMPILE, but with different arguments
 571 #
 572 AC_DEFUN([LB_LINUX_TRY_MAKE], [
 573 LB_LINUX_COMPILE_IFELSE(
 574         [AC_LANG_SOURCE([LB_LANG_PROGRAM([[$1]], [[$2]])])],
 575         [$3], [$4], [$5], [$6])
 576 ])
 577
 578 #
 579 # LB_CHECK_COMPILE
 580 # $1 - checking message
 581 # $2 - variable name
 582 # $3 - header
 583 # $4 - body
 584 # $5 - do 'yes'
 585 # $6 - do 'no'
 586 #
 587 AC_DEFUN([LB_CHECK_COMPILE], [
 588 AS_VAR_PUSHDEF([lb_compile], [lb_cv_compile_$2])dnl
 589 AC_CACHE_CHECK([$1], lb_compile, [
 590         LB_LINUX_TRY_COMPILE([$3], [$4],
 591                 [AS_VAR_SET([lb_compile], [yes])],
 592                 [AS_VAR_SET([lb_compile], [no])])
 593 ])
 594 AS_VAR_IF([lb_compile], [yes], [$5], [$6])[]dnl
 595 AS_VAR_POPDEF([lb_compile])dnl
 596 ]) # LB_CHECK_COMPILE
 597
 598 #
 599 # LB_CHECK_LINUX_HEADER
 600 #
 601 # Like AC_CHECK_HEADER but checks for a kernel-space header
 602 #
 603 m4_define([LB_CHECK_LINUX_HEADER], [
 604 AS_VAR_PUSHDEF([lb_header], [lb_cv_header_$1])dnl
 605 AC_CACHE_CHECK([for $1], lb_header, [
 606         LB_LINUX_COMPILE_IFELSE([LB_LANG_PROGRAM([@%:@include <$1>])],
 607                 [modules], [test -s build/conftest.o],
 608                 [AS_VAR_SET([lb_header], [yes])],
 609                 [AS_VAR_SET([lb_header], [no])])
 610 ])
 611 AS_VAR_IF([lb_header], [yes], [$2], [$3])[]dnl
 612 AS_VAR_POPDEF([lb_header])dnl
 613 ]) # LB_CHECK_LINUX_HEADER