config/lustre-build-linux.m4

   1 #
   2 # LB_LINUX_VERSION
   3 #
   4 # Set things accordingly for a linux kernel
   5 #
   6 AC_DEFUN([LB_LINUX_VERSION], [
   7 KMODEXT=".ko"
   8 AC_SUBST(KMODEXT)
   9
  10 makerule="$PWD/build"
  11 AC_CACHE_CHECK([for external module build target], lb_cv_module_target, [
  12 lb_cv_module_target=""
  13 MODULE_TARGET="SUBDIRS"
  14 rm -f build/conftest.i
  15 LB_LINUX_TRY_MAKE([], [],
  16         [$makerule LUSTRE_KERNEL_TEST=conftest.i],
  17         [test -s build/conftest.i],
  18         [lb_cv_module_target="SUBDIRS"], [
  19                 MODULE_TARGET="M"
  20                 makerule="_module_$PWD/build"
  21                 LB_LINUX_TRY_MAKE([], [],
  22                         [$makerule LUSTRE_KERNEL_TEST=conftest.i],
  23                         [test -s build/conftest.i],
  24                         [lb_cv_module_target="M"], [
  25                                 AC_MSG_ERROR([unknown; check config.log for details])
  26                         ])
  27         ])
  28 ])
  29 AS_IF([test -z "$lb_cv_module_target"],
  30         [AC_MSG_ERROR([unknown external module build target])],
  31 [test "x$lb_cv_module_target" = "xM"],
  32         [makerule="_module_$PWD/build"])
  33 MODULE_TARGET=$lb_cv_module_target
  34 AC_SUBST(MODULE_TARGET)
  35 ])
  36
  37 #
  38 # LB_LINUX_UTSRELEASE
  39 #
  40 # Determine the Linux kernel version string from the utsrelease
  41 #
  42 AC_DEFUN([LB_LINUX_UTSRELEASE], [
  43 AC_CACHE_CHECK([for Linux kernel utsrelease], lb_cv_utsrelease, [
  44 lb_cv_utsrelease=""
  45 utsrelease1=$LINUX_OBJ/include/generated/utsrelease.h
  46 utsrelease2=$LINUX_OBJ/include/linux/utsrelease.h
  47 utsrelease3=$LINUX_OBJ/include/linux/version.h
  48 AS_IF([test -r $utsrelease1 && fgrep -q UTS_RELEASE $utsrelease1],
  49         [utsrelease=$utsrelease1],
  50 [test -r $utsrelease2 && fgrep -q UTS_RELEASE $utsrelease2],
  51         [utsrelease=$utsrelease2],
  52 [test -r $utsrelease3 && fgrep -q UTS_RELEASE $utsrelease3],
  53         [utsrelease=$utsrelease3])
  54 AS_IF([test -n "$utsrelease"],
  55         [lb_cv_utsrelease=$(awk -F \" '/ UTS_RELEASE / { print [$]2 }' $utsrelease)],
  56         [AC_MSG_ERROR([
  57
  58 Cannot find UTS_RELEASE definition.
  59
  60 This is often provided by the kernel-devel package.
  61 ])
  62         ])
  63 ])
  64 AS_IF([test -z "$lb_cv_utsrelease"],
  65         [AC_MSG_ERROR([Cannot determine Linux kernel version.])])
  66 LINUXRELEASE=$lb_cv_utsrelease
  67 AC_SUBST(LINUXRELEASE)
  68 ])
  69
  70 #
  71 # LB_LINUX_RELEASE
  72 #
  73 # get the release version of linux
  74 #
  75 AC_DEFUN([LB_LINUX_RELEASE], [
  76         LB_LINUX_UTSRELEASE
  77
  78         # Define default states
  79         RHEL_KERNEL="no"
  80         SUSE_KERNEL="no"
  81         UBUNTU_KERNEL="no"
  82         # And if any of the above kernels has been detected yet
  83         KERNEL_FOUND="no"
  84
  85         # Check for RedHat first (no need to check KERNEL_FOUND
  86         AC_CACHE_CHECK([for RedHat kernel release number], lb_cv_rhel_kernel_version, [
  87                 lb_cv_rhel_kernel_version=""
  88                 AS_IF([fgrep -q RHEL_RELEASE $LINUX_OBJ/include/$VERSION_HDIR/version.h], [
  89                         lb_cv_rhel_kernel_version=$(awk '/ RHEL_MAJOR / { print [$]3 }' \
  90                                 $LINUX_OBJ/include/$VERSION_HDIR/version.h)$(awk \
  91                                 '/ RHEL_MINOR / { print [$]3 }' \
  92                                 $LINUX_OBJ/include/$VERSION_HDIR/version.h)
  93                 ])
  94         ])
  95         AS_IF([test -n "$lb_cv_rhel_kernel_version"], [
  96                 RHEL_KERNEL="yes"
  97                 KERNEL_FOUND="yes"
  98                 RHEL_RELEASE_NO=$lb_cv_rhel_kernel_version
  99         ])
 100
 101         # Check for SuSE
 102         AS_IF([test "x$KERNEL_FOUND" = "xno"], [
 103                 LB_CHECK_CONFIG([SUSE_KERNEL], [
 104                         SUSE_KERNEL="yes"
 105                         KERNEL_FOUND="yes"
 106                 ], [])
 107         ])
 108
 109         # Check for Ubuntu
 110         AS_IF([test "x$KERNEL_FOUND" = "xno"], [
 111                 AC_CACHE_CHECK([for Ubuntu kernel signature], lb_cv_ubuntu_kernel_sig, [
 112                         lb_cv_ubuntu_kernel_sig="no"
 113                         AS_IF([fgrep -q "CONFIG_VERSION_SIGNATURE \"Ubuntu" $LINUX_OBJ/include/generated/autoconf.h], [
 114                                 lb_cv_ubuntu_kernel_sig="yes"
 115                         ])
 116                 ])
 117                 AS_IF([test "x$lb_cv_ubuntu_kernel_sig" = "xyes"], [
 118                         UBUNTU_KERNEL="yes"
 119                         KERNEL_FOUND="yes"
 120                 ])
 121         ])
 122
 123         # If still no kernel was found, a warning is issued
 124         AS_IF([test "x$KERNEL_FOUND" = "xno"], [
 125                 AC_MSG_WARN([Kernel Distro seems to be neither RedHat, SuSE nor Ubuntu])
 126         ])
 127
 128         AC_MSG_CHECKING([for Linux kernel module package directory])
 129         AC_ARG_WITH([kmp-moddir],
 130                 AC_HELP_STRING([--with-kmp-moddir=string],
 131                         [set the kmod updates or extra directory]),
 132                 [KMP_MODDIR=$withval
 133                  IN_KERNEL=''],[
 134                 AS_IF([test x$RHEL_KERNEL = xyes], [KMP_MODDIR="extra/kernel"],
 135                           [test x$SUSE_KERNEL = xyes], [KMP_MODDIR="updates/kernel"],
 136                           [test x$UBUNTU_KERNEL = xyes], [KMP_MODDIR="updates/kernel"],
 137                           [AC_MSG_WARN([Kernel Distro seems to be neither RedHat, SuSE nor Ubuntu])]
 138                 )
 139                 IN_KERNEL="${PACKAGE}"])
 140         AC_MSG_RESULT($KMP_MODDIR)
 141
 142         moduledir="/lib/modules/${LINUXRELEASE}/${KMP_MODDIR}"
 143
 144         modulefsdir="${moduledir}/fs/${IN_KERNEL}"
 145         AC_SUBST(modulefsdir)
 146
 147         modulenetdir="${moduledir}/net/${IN_KERNEL}"
 148         AC_SUBST(modulenetdir)
 149
 150         AC_SUBST(KMP_MODDIR)
 151 ])
 152
 153 #
 154 # LB_LINUX_SYMVERFILE
 155 #
 156 # SLES 9 uses a different name for this file - unsure about vanilla kernels
 157 # around this version, but it matters for servers only.
 158 AC_DEFUN([LB_LINUX_SYMVERFILE], [
 159 AC_CACHE_CHECK([for the name of module symbol version file], lb_cv_module_symvers, [
 160 AS_IF([grep -q Modules.symvers $LINUX/scripts/Makefile.modpost],
 161         [lb_cv_module_symvers=Modules.symvers],
 162         [lb_cv_module_symvers=Module.symvers])
 163 ])
 164 SYMVERFILE=$lb_cv_module_symvers
 165 AC_SUBST(SYMVERFILE)
 166 ])
 167
 168 #
 169 # LB_ARG_REPLACE_PATH(PACKAGE, PATH)
 170 #
 171 AC_DEFUN([LB_ARG_REPLACE_PATH], [
 172 new_configure_args=
 173 eval set -- $ac_configure_args
 174 for arg; do
 175         case $arg in
 176                 --with-[$1]=*)
 177                         arg=--with-[$1]=[$2] ;;
 178                 *\'*)
 179                         arg=$(printf %s\n ["$arg"] | sed "s/'/'\\\\\\\\''/g") ;;
 180         esac
 181         dnl AS_VAR_APPEND([new_configure_args], [" '$arg'"])
 182         new_configure_args="$new_configure_args '$arg'"
 183 done
 184 ac_configure_args=$new_configure_args
 185 ])
 186
 187 #
 188 # __LB_ARG_CANON_PATH
 189 #
 190 # this is the work-horse of the next function
 191 #
 192 AC_DEFUN([__LB_ARG_CANON_PATH], [
 193         [$3]=$(readlink -f $with_$2)
 194         LB_ARG_REPLACE_PATH([$1], $[$3])
 195 ])
 196
 197 #
 198 # LB_ARG_CANON_PATH
 199 #
 200 # a front-end for the above function that transforms - and . in the
 201 # PACKAGE portion of --with-PACKAGE into _ suitable for variable names
 202 #
 203 AC_DEFUN([LB_ARG_CANON_PATH], [
 204         __LB_ARG_CANON_PATH([$1], m4_translit([$1], [-.], [__]), [$2])
 205 ])
 206
 207 #
 208 # LB_LINUX_PATH
 209 #
 210 # Find paths for linux, handling kernel-source rpms
 211 #
 212 AC_DEFUN([LB_LINUX_PATH], [
 213 for DEFAULT_LINUX in /lib/modules/$(uname -r)/{source,build} /usr/src/linux $(find /usr/src/kernels/ -maxdepth 1 -name @<:@0-9@:>@\* | xargs -r ls -d | tail -n 1); do
 214         AS_IF([readlink -q -e $DEFAULT_LINUX >/dev/null], [break])
 215 done
 216 if test "$DEFAULT_LINUX" = "/lib/modules/$(uname -r)/source"; then
 217         PATHS="/lib/modules/$(uname -r)/build"
 218 fi
 219 PATHS+=" $DEFAULT_LINUX"
 220 for DEFAULT_LINUX_OBJ in $PATHS; do
 221         AS_IF([readlink -q -e $DEFAULT_LINUX_OBJ >/dev/null], [break])
 222 done
 223
 224 AC_MSG_CHECKING([for Linux sources])
 225 AC_ARG_WITH([linux],
 226         AC_HELP_STRING([--with-linux=path],
 227                        [set path to Linux source (default=/lib/modules/$(uname -r)/{source,build},/usr/src/linux)]),
 228         [LB_ARG_CANON_PATH([linux], [LINUX])
 229         DEFAULT_LINUX_OBJ=$LINUX],
 230         [LINUX=$DEFAULT_LINUX])
 231 AC_MSG_RESULT([$LINUX])
 232 AC_SUBST(LINUX)
 233
 234 # -------- check for linux --------
 235 LB_CHECK_FILE([$LINUX], [],
 236         [AC_MSG_ERROR([Kernel source $LINUX could not be found.])])
 237
 238 # -------- linux objects (for 2.6) --
 239 AC_MSG_CHECKING([for Linux objects])
 240 AC_ARG_WITH([linux-obj],
 241         AC_HELP_STRING([--with-linux-obj=path],
 242                         [set path to Linux objects (default=/lib/modules/$(uname -r)/build,/usr/src/linux)]),
 243         [LB_ARG_CANON_PATH([linux-obj], [LINUX_OBJ])],
 244         [LINUX_OBJ=$DEFAULT_LINUX_OBJ])
 245 AC_MSG_RESULT([$LINUX_OBJ])
 246 AC_SUBST(LINUX_OBJ)
 247
 248 # -------- check for .config --------
 249 AC_ARG_WITH([linux-config],
 250         [AC_HELP_STRING([--with-linux-config=path],
 251                         [set path to Linux .conf (default=$LINUX_OBJ/.config)])],
 252         [LB_ARG_CANON_PATH([linux-config], [LINUX_CONFIG])],
 253         [LINUX_CONFIG=$LINUX_OBJ/.config])
 254
 255 # -------- check if .config exists --
 256 LB_CHECK_FILE([$LINUX_CONFIG], [],
 257         [AC_MSG_ERROR([
 258
 259 Kernel config could not be found.
 260
 261 If you are building from a kernel-source rpm consult build/README.kernel-source
 262 ])
 263 ])
 264 AC_SUBST(LINUX_CONFIG)
 265
 266 LB_CHECK_FILE([/boot/kernel.h],
 267         [KERNEL_SOURCE_HEADER='/boot/kernel.h'],
 268         [LB_CHECK_FILE([/var/adm/running-kernel.h],
 269                 [KERNEL_SOURCE_HEADER='/var/adm/running-kernel.h'])])
 270
 271 AC_ARG_WITH([kernel-source-header],
 272         AC_HELP_STRING([--with-kernel-source-header=path],
 273                         [Use a different kernel version header.  Consult build/README.kernel-source for details.]),
 274         [LB_ARG_CANON_PATH([kernel-source-header], [KERNEL_SOURCE_HEADER])])
 275
 276 # ----------- make dep run? ------------------
 277 # at 2.6.19 # $LINUX/include/linux/config.h is removed
 278 # and at more old has only one line include <autoconf.h>
 279 #
 280 LB_CHECK_FILE([$LINUX_OBJ/include/generated/autoconf.h],
 281         [AUTOCONF_HDIR=generated],
 282         [LB_CHECK_FILE([$LINUX_OBJ/include/linux/autoconf.h],
 283                 [AUTOCONF_HDIR=linux],
 284                 [AC_MSG_ERROR([Run make config in $LINUX.])])])
 285 AC_SUBST(AUTOCONF_HDIR)
 286
 287 LB_CHECK_FILE([$LINUX_OBJ/include/linux/version.h],
 288         [VERSION_HDIR=linux],
 289         [LB_CHECK_FILE([$LINUX_OBJ/include/generated/uapi/linux/version.h],
 290                 [VERSION_HDIR=generated/uapi/linux],
 291                 [AC_MSG_ERROR([Run make config in $LINUX.])])])
 292 AC_SUBST(VERSION_HDIR)
 293
 294 # ----------- kconfig.h exists ---------------
 295 # kernel 3.1, $LINUX/include/linux/kconfig.h is added
 296 # see kernel commit 2a11c8ea20bf850b3a2c60db8c2e7497d28aba99
 297 #
 298 LB_CHECK_FILE([$LINUX/include/linux/kconfig.h],
 299               [CONFIG_INCLUDE=$LINUX/include/linux/kconfig.h],
 300               [CONFIG_INCLUDE=include/$AUTOCONF_HDIR/autoconf.h])
 301 AC_SUBST(CONFIG_INCLUDE)
 302
 303 # ------------ rhconfig.h includes runtime-generated bits --
 304 # RedHat kernel-source checks
 305
 306 # we know this exists after the check above.  if the user
 307 # tarred up the tree and ran make dep etc. in it, then
 308 # version.h gets overwritten with a standard linux one.
 309
 310 AS_IF([grep rhconfig $LINUX_OBJ/include/$VERSION_HDIR/version.h >/dev/null], [
 311         # This is a clean kernel-source tree, we need to
 312         # enable extensive workarounds to get this to build modules
 313         LB_CHECK_FILE([$KERNEL_SOURCE_HEADER], [
 314                 AS_IF([test $KERNEL_SOURCE_HEADER = '/boot/kernel.h'],
 315                         [AC_MSG_WARN([
 316
 317 Using /boot/kernel.h from RUNNING kernel.
 318
 319 If this is not what you want, use --with-kernel-source-header.
 320 Consult build/README.kernel-source for details.
 321 ])
 322                 ])],
 323                 [AC_MSG_ERROR([
 324
 325 $KERNEL_SOURCE_HEADER not found.
 326
 327 Consult build/README.kernel-source for details.
 328 ])
 329                 ])
 330         EXTRA_KCFLAGS="-include $KERNEL_SOURCE_HEADER $EXTRA_KCFLAGS"
 331 ])
 332
 333 # this is needed before we can build modules
 334 LB_LINUX_VERSION
 335
 336 # --- check that we can build modules at all
 337 LB_CHECK_COMPILE([that modules can be built at all], build_modules,
 338         [], [], [], [
 339         AC_MSG_ERROR([
 340
 341 Kernel modules cannot be built. Consult config.log for details.
 342
 343 If you are trying to build with a kernel-source rpm,
 344 consult build/README.kernel-source
 345 ])
 346 ])
 347
 348 LB_LINUX_RELEASE
 349 ]) # end of LB_LINUX_PATH
 350
 351 #
 352 # LC_MODULE_LOADING
 353 #
 354 # after 2.6.28 CONFIG_KMOD is removed, and only CONFIG_MODULES remains
 355 # so we test if request_module is implemented or not
 356 AC_DEFUN([LC_MODULE_LOADING], [
 357 AC_CACHE_CHECK([if Linux kernel module loading is possible], lb_cv_module_loading, [
 358 LB_LINUX_TRY_MAKE([
 359         #include <linux/kmod.h>
 360 ], [
 361         int myretval=ENOSYS ;
 362         return myretval;
 363 ], [
 364         $makerule LUSTRE_KERNEL_TEST=conftest.i
 365 ], [dnl
 366         grep request_module build/conftest.i |dnl
 367                 grep -v `grep "int myretval=" build/conftest.i |dnl
 368                         cut -d= -f2 | cut -d" "  -f1`dnl
 369                 >/dev/null dnl
 370 ], [lb_cv_module_loading="yes"], [lb_cv_module_loading="no"])
 371 ])
 372 AS_IF([test "$lb_cv_module_loading" = yes],
 373         [AC_DEFINE(HAVE_MODULE_LOADING_SUPPORT, 1,
 374                 [kernel module loading is possible])],
 375         [AC_MSG_WARN([
 376
 377 Kernel module loading support is highly recommended.
 378
 379 ])
 380         ])
 381 ])
 382
 383 #
 384 # LB_PROG_LINUX
 385 #
 386 # linux tests
 387 #
 388 AC_DEFUN([LB_PROG_LINUX], [
 389 LB_LINUX_PATH
 390 LB_LINUX_SYMVERFILE
 391
 392 LB_CHECK_CONFIG([MODULES], [], [
 393         AC_MSG_ERROR([
 394
 395 module support is required to build Lustre kernel modules.
 396 ])
 397         ])
 398
 399 LB_CHECK_CONFIG([MODVERSIONS])
 400
 401 LB_CHECK_CONFIG([KALLSYMS], [], [
 402         AC_MSG_ERROR([
 403
 404 Lustre requires that CONFIG_KALLSYMS is enabled in your kernel.
 405 ])
 406         ])
 407
 408 # 2.6.28
 409 LC_MODULE_LOADING
 410 ])
 411
 412 #
 413 # LB_USES_DPKG
 414 #
 415 # Determine if the target is a dpkg system or rpm
 416 #
 417 AC_DEFUN([LB_USES_DPKG], [
 418 AC_CACHE_CHECK([if this distro uses dpkg], lb_cv_uses_dpkg, [
 419 lb_cv_uses_dpkg="no"
 420 AS_CASE([$(lsb_release -i -s 2>/dev/null)],
 421         [Ubuntu | Debian], [lb_cv_uses_dpkg="yes"])
 422 ])
 423 uses_dpkg=$lb_cv_uses_dpkg
 424 ])
 425
 426 #
 427 # LB_CHECK_EXPORT
 428 #
 429 # check symbol exported or not
 430 # $1 - symbol
 431 # $2 - file(s) for find.
 432 # $3 - do 'yes'
 433 # $4 - do 'no'
 434 #
 435 # 2.6 based kernels - put modversion info into $LINUX/Module.modvers or check
 436 #
 437 AC_DEFUN([LB_CHECK_EXPORT], [
 438 AS_VAR_PUSHDEF([lb_export], [lb_cv_export_$1])dnl
 439 AC_CACHE_CHECK([if Linux kernel exports '$1'], lb_export, [
 440 AS_VAR_SET([lb_export], [no])
 441 AS_IF([grep -q -E '[[[:space:]]]$1[[[:space:]]]' $LINUX_OBJ/$SYMVERFILE 2>/dev/null],
 442         [AS_VAR_SET([lb_export], [yes])],
 443         [for file in $2; do
 444                 AS_IF([grep -q -E "EXPORT_SYMBOL.*\($1\)" "$LINUX/$file" 2>/dev/null], [
 445                         AS_VAR_SET([lb_export], [yes])
 446                         break
 447                 ])
 448         done])
 449 ])
 450 AS_VAR_IF([lb_export], [yes], [$3], [$4])[]dnl
 451 AS_VAR_POPDEF([lb_export])dnl
 452 ]) # LB_CHECK_EXPORT
 453
 454 #
 455 # LB_CHECK_CONFIG
 456 #
 457 # check if a given config option is defined
 458 # $1 - CONFIG_<name>
 459 # $2 - do 'yes'
 460 # $3 - do 'no'
 461 #
 462 AC_DEFUN([LB_CHECK_CONFIG], [
 463 LB_CHECK_COMPILE([if Linux kernel was built with CONFIG_$1],
 464 config_$1, [
 465         #include <$AUTOCONF_HDIR/autoconf.h>
 466 ], [
 467         #ifndef CONFIG_$1
 468         #error CONFIG_$1 not #defined
 469         #endif
 470 ], [$2], [$3])
 471 ]) # LB_CHECK_CONFIG
 472
 473 #
 474 # LB_CHECK_CONFIG_IM
 475 #
 476 # check if a given config option is builtin or as module
 477 # $1 - CONFIG_<name> or CONFIG_<name>_MODULE
 478 # $2 - do 'yes'
 479 # $3 - do 'no'
 480 #
 481 AC_DEFUN([LB_CHECK_CONFIG_IM], [
 482 LB_CHECK_COMPILE([if Linux kernel was built with CONFIG_$1 in or as module],
 483 config_im_$1, [
 484         #include <$AUTOCONF_HDIR/autoconf.h>
 485 ], [
 486         #if !(defined(CONFIG_$1) || defined(CONFIG_$1_MODULE))
 487         #error CONFIG_$1 and CONFIG_$1_MODULE not #defined
 488         #endif
 489 ], [$2], [$3])
 490 ]) # LB_CHECK_CONFIG_IM
 491
 492 #
 493 # these are like AC_TRY_COMPILE, but try to build modules against the
 494 # kernel, inside the build directory
 495 #
 496
 497 #
 498 # LB_LANG_PROGRAM(C)([PROLOGUE], [BODY])
 499 # --------------------------------------
 500 #
 501 m4_define([LB_LANG_PROGRAM],
 502 [
 503 #include <linux/kernel.h>
 504 $1
 505 int
 506 main (void)
 507 {
 508 dnl Do *not* indent the following line: there may be CPP directives.
 509 dnl Don't move the `;' right after for the same reason.
 510 $2
 511   ;
 512   return 0;
 513 }])
 514
 515 #
 516 # LB_LINUX_COMPILE_IFELSE
 517 #
 518 # like AC_COMPILE_IFELSE
 519 #
 520 # $1 - AC_LANG_SOURCE()
 521 # $2 - make target
 522 # $3 - check command
 523 # $4 - do 'yes'
 524 # $5 - do 'no'
 525 #
 526 AC_DEFUN([LB_LINUX_COMPILE_IFELSE],
 527 [m4_ifvaln([$1], [AC_LANG_CONFTEST([AC_LANG_SOURCE([$1])])])dnl
 528 rm -f build/conftest.o build/conftest.mod.c build/conftest.ko
 529 SUBARCH=$(echo $target_cpu | sed -e 's/powerpc.*/powerpc/' -e 's/ppc.*/powerpc/' -e 's/x86_64/x86/' -e 's/i.86/x86/' -e 's/k1om/x86/' -e 's/aarch64.*/arm64/')
 530 AS_IF([AC_TRY_COMMAND(cp conftest.c build && make -d [$2] LDFLAGS= ${LD:+LD="$LD"} CC="$CC" -f $PWD/build/Makefile LUSTRE_LINUX_CONFIG=$LINUX_CONFIG LINUXINCLUDE="$EXTRA_CHECK_INCLUDE -I$LINUX/arch/$SUBARCH/include -Iinclude -Iarch/$SUBARCH/include/generated -I$LINUX/include -Iinclude2 -I$LINUX/include/uapi -Iinclude/generated -I$LINUX/arch/$SUBARCH/include/uapi -Iarch/$SUBARCH/include/generated/uapi -I$LINUX/include/uapi -Iinclude/generated/uapi ${SPL_OBJ:+-include $SPL_OBJ/spl_config.h} ${ZFS_OBJ:+-include $ZFS_OBJ/zfs_config.h} ${SPL:+-I$SPL -I$SPL/include } ${ZFS:+-I$ZFS -I$ZFS/include} -include $CONFIG_INCLUDE" -o tmp_include_depends -o scripts -o include/config/MARKER -C $LINUX_OBJ EXTRA_CFLAGS="-Werror-implicit-function-declaration $EXTRA_KCFLAGS" $MODULE_TARGET=$PWD/build) >/dev/null && AC_TRY_COMMAND([$3])],
 531         [$4],
 532         [_AC_MSG_LOG_CONFTEST
 533 m4_ifvaln([$5],[$5])dnl])
 534 rm -f build/conftest.o build/conftest.mod.c build/conftest.mod.o build/conftest.ko m4_ifval([$1], [build/conftest.c conftest.c])[]dnl
 535 ])
 536
 537 #
 538 # LB_LINUX_TRY_COMPILE
 539 #
 540 # like AC_TRY_COMPILE
 541 #
 542 AC_DEFUN([LB_LINUX_TRY_COMPILE], [
 543 LB_LINUX_COMPILE_IFELSE(
 544         [AC_LANG_SOURCE([LB_LANG_PROGRAM([[$1]], [[$2]])])],
 545         [modules], [test -s build/conftest.o],
 546         [$3], [$4])
 547 ])
 548
 549 #
 550 # LB_LINUX_TRY_MAKE
 551 #
 552 # like LB_LINUX_TRY_COMPILE, but with different arguments
 553 #
 554 AC_DEFUN([LB_LINUX_TRY_MAKE], [
 555 LB_LINUX_COMPILE_IFELSE(
 556         [AC_LANG_SOURCE([LB_LANG_PROGRAM([[$1]], [[$2]])])],
 557         [$3], [$4], [$5], [$6])
 558 ])
 559
 560 #
 561 # LB_CHECK_COMPILE
 562 # $1 - checking message
 563 # $2 - variable name
 564 # $3 - header
 565 # $4 - body
 566 # $5 - do 'yes'
 567 # $6 - do 'no'
 568 #
 569 AC_DEFUN([LB_CHECK_COMPILE], [
 570 AS_VAR_PUSHDEF([lb_compile], [lb_cv_compile_$2])dnl
 571 AC_CACHE_CHECK([$1], lb_compile, [
 572         LB_LINUX_TRY_COMPILE([$3], [$4],
 573                 [AS_VAR_SET([lb_compile], [yes])],
 574                 [AS_VAR_SET([lb_compile], [no])])
 575 ])
 576 AS_VAR_IF([lb_compile], [yes], [$5], [$6])[]dnl
 577 AS_VAR_POPDEF([lb_compile])dnl
 578 ]) # LB_CHECK_COMPILE
 579
 580 #
 581 # LB_CHECK_LINUX_HEADER
 582 #
 583 # Like AC_CHECK_HEADER but checks for a kernel-space header
 584 #
 585 m4_define([LB_CHECK_LINUX_HEADER], [
 586 AS_VAR_PUSHDEF([lb_header], [lb_cv_header_$1])dnl
 587 AC_CACHE_CHECK([for $1], lb_header, [
 588         LB_LINUX_COMPILE_IFELSE([LB_LANG_PROGRAM([@%:@include <$1>])],
 589                 [modules], [test -s build/conftest.o],
 590                 [AS_VAR_SET([lb_header], [yes])],
 591                 [AS_VAR_SET([lb_header], [no])])
 592 ])
 593 AS_VAR_IF([lb_header], [yes], [$2], [$3])[]dnl
 594 AS_VAR_POPDEF([lb_header])dnl
 595 ]) # LB_CHECK_LINUX_HEADER