config/lustre-build-linux.m4

   1 #
   2 # LB_LINUX_VERSION
   3 #
   4 # Set things accordingly for a linux kernel
   5 #
   6 AC_DEFUN([LB_LINUX_VERSION], [
   7 KMODEXT=".ko"
   8 AC_SUBST(KMODEXT)
   9
  10 makerule="$PWD/build"
  11 AC_CACHE_CHECK([for external module build target], lb_cv_module_target, [
  12 lb_cv_module_target=""
  13 MODULE_TARGET="SUBDIRS"
  14 rm -f build/conftest.i
  15 LB_LINUX_TRY_MAKE([], [],
  16         [$makerule LUSTRE_KERNEL_TEST=conftest.i],
  17         [test -s build/conftest.i],
  18         [lb_cv_module_target="SUBDIRS"], [
  19                 MODULE_TARGET="M"
  20                 makerule="_module_$PWD/build"
  21                 LB_LINUX_TRY_MAKE([], [],
  22                         [$makerule LUSTRE_KERNEL_TEST=conftest.i],
  23                         [test -s build/conftest.i],
  24                         [lb_cv_module_target="M"], [
  25                                 AC_MSG_ERROR([unknown; check config.log for details])
  26                         ])
  27         ])
  28 ])
  29 AS_IF([test -z "$lb_cv_module_target"],
  30         [AC_MSG_ERROR([unknown external module build target])],
  31 [test "x$lb_cv_module_target" = "xM"],
  32         [makerule="_module_$PWD/build"])
  33 MODULE_TARGET=$lb_cv_module_target
  34 AC_SUBST(MODULE_TARGET)
  35 ])
  36
  37 #
  38 # LB_LINUX_UTSRELEASE
  39 #
  40 # Determine the Linux kernel version string from the utsrelease
  41 #
  42 AC_DEFUN([LB_LINUX_UTSRELEASE], [
  43 AC_CACHE_CHECK([for Linux kernel utsrelease], lb_cv_utsrelease, [
  44 lb_cv_utsrelease=""
  45 utsrelease1=$LINUX_OBJ/include/generated/utsrelease.h
  46 utsrelease2=$LINUX_OBJ/include/linux/utsrelease.h
  47 utsrelease3=$LINUX_OBJ/include/linux/version.h
  48 AS_IF([test -r $utsrelease1 && fgrep -q UTS_RELEASE $utsrelease1],
  49         [utsrelease=$utsrelease1],
  50 [test -r $utsrelease2 && fgrep -q UTS_RELEASE $utsrelease2],
  51         [utsrelease=$utsrelease2],
  52 [test -r $utsrelease3 && fgrep -q UTS_RELEASE $utsrelease3],
  53         [utsrelease=$utsrelease3])
  54 AS_IF([test -n "$utsrelease"],
  55         [lb_cv_utsrelease=$(awk -F \" '/ UTS_RELEASE / { print [$]2 }' $utsrelease)],
  56         [AC_MSG_ERROR([
  57
  58 Cannot find UTS_RELEASE definition.
  59
  60 This is often provided by the kernel-devel package.
  61 ])
  62         ])
  63 ])
  64 AS_IF([test -z "$lb_cv_utsrelease"],
  65         [AC_MSG_ERROR([Cannot determine Linux kernel version.])])
  66 LINUXRELEASE=$lb_cv_utsrelease
  67 AC_SUBST(LINUXRELEASE)
  68 ])
  69
  70 #
  71 # LB_LINUX_RELEASE
  72 #
  73 # get the release version of linux
  74 #
  75 AC_DEFUN([LB_LINUX_RELEASE], [
  76         LB_LINUX_UTSRELEASE
  77
  78         # Define default states
  79         RHEL_KERNEL="no"
  80         SUSE_KERNEL="no"
  81         UBUNTU_KERNEL="no"
  82         DEBIAN_KERNEL="no"
  83         # And if any of the above kernels has been detected yet
  84         KERNEL_FOUND="no"
  85
  86         # Check for RedHat first (no need to check KERNEL_FOUND
  87         AC_CACHE_CHECK([for RedHat kernel release number], lb_cv_rhel_kernel_version, [
  88                 lb_cv_rhel_kernel_version=""
  89                 AS_IF([fgrep -q RHEL_RELEASE $LINUX_OBJ/include/$VERSION_HDIR/version.h], [
  90                         lb_cv_rhel_kernel_version=$(awk '/ RHEL_MAJOR / { print [$]3 }' \
  91                                 $LINUX_OBJ/include/$VERSION_HDIR/version.h)$(awk \
  92                                 '/ RHEL_MINOR / { print [$]3 }' \
  93                                 $LINUX_OBJ/include/$VERSION_HDIR/version.h)
  94                 ])
  95         ])
  96         AS_IF([test -n "$lb_cv_rhel_kernel_version"], [
  97                 RHEL_KERNEL="yes"
  98                 KERNEL_FOUND="yes"
  99                 RHEL_RELEASE_NO=$lb_cv_rhel_kernel_version
 100         ])
 101
 102         # Check for SuSE
 103         AS_IF([test "x$KERNEL_FOUND" = "xno"], [
 104                 LB_CHECK_CONFIG([SUSE_KERNEL], [
 105                         SUSE_KERNEL="yes"
 106                         KERNEL_FOUND="yes"
 107                 ], [])
 108         ])
 109
 110         # Check for Ubuntu
 111         AS_IF([test "x$KERNEL_FOUND" = "xno"], [
 112                 AC_CACHE_CHECK([for Ubuntu kernel signature], lb_cv_ubuntu_kernel_sig, [
 113                         lb_cv_ubuntu_kernel_sig="no"
 114                         AS_IF([fgrep -q "CONFIG_VERSION_SIGNATURE \"Ubuntu" $LINUX_OBJ/include/generated/autoconf.h], [
 115                                 lb_cv_ubuntu_kernel_sig="yes"
 116                         ])
 117                 ])
 118                 AS_IF([test "x$lb_cv_ubuntu_kernel_sig" = "xyes"], [
 119                         UBUNTU_KERNEL="yes"
 120                         KERNEL_FOUND="yes"
 121                 ])
 122         ])
 123
 124         # Check for Debian
 125         AS_IF([test "x$KERNEL_FOUND" = "xno"], [
 126                 AC_CACHE_CHECK([for Debian kernel signature], lb_cv_debian_kernel_sig, [
 127                         lb_cv_debian_kernel_sig="no"
 128                         AS_IF([grep -q "LINUX_PACKAGE_ID\s*\"\s*Debian" $LINUX_OBJ/include/generated/package.h], [
 129                                 lb_cv_debian_kernel_sig="yes"
 130                         ])
 131                 ])
 132                 AS_IF([test "x$lb_cv_debian_kernel_sig" = "xyes"], [
 133                         DEBIAN_KERNEL="yes"
 134                         KERNEL_FOUND="yes"
 135                 ])
 136         ])
 137
 138         # If still no kernel was found, a warning is issued
 139         AS_IF([test "x$KERNEL_FOUND" = "xno"], [
 140                 AC_MSG_WARN([Kernel Distro seems to be neither RedHat, SuSE, Ubuntu nor Debian])
 141         ])
 142
 143         AC_MSG_CHECKING([for Linux kernel module package directory])
 144         AC_ARG_WITH([kmp-moddir],
 145                 AC_HELP_STRING([--with-kmp-moddir=string],
 146                         [set the kmod updates or extra directory]),
 147                 [KMP_MODDIR=$withval
 148                  IN_KERNEL=''],[
 149                 AS_IF([test x$RHEL_KERNEL = xyes], [KMP_MODDIR="extra/kernel"],
 150                           [test x$SUSE_KERNEL = xyes], [KMP_MODDIR="updates/kernel"],
 151                           [test x$UBUNTU_KERNEL = xyes], [KMP_MODDIR="updates/kernel"],
 152                           [test x$DEBIAN_KERNEL = xyes], [KMP_MODDIR="updates/kernel"],
 153                           [AC_MSG_WARN([Kernel Distro seems to be neither RedHat, SuSE, Ubuntu nor Debian])]
 154                 )
 155                 IN_KERNEL="${PACKAGE}"])
 156         AC_MSG_RESULT($KMP_MODDIR)
 157
 158         moduledir="/lib/modules/${LINUXRELEASE}/${KMP_MODDIR}"
 159
 160         modulefsdir="${moduledir}/fs/${IN_KERNEL}"
 161         AC_SUBST(modulefsdir)
 162
 163         modulenetdir="${moduledir}/net/${IN_KERNEL}"
 164         AC_SUBST(modulenetdir)
 165
 166         AC_SUBST(KMP_MODDIR)
 167 ])
 168
 169 #
 170 # LB_LINUX_SYMVERFILE
 171 #
 172 # SLES 9 uses a different name for this file - unsure about vanilla kernels
 173 # around this version, but it matters for servers only.
 174 AC_DEFUN([LB_LINUX_SYMVERFILE], [
 175 AC_CACHE_CHECK([for the name of module symbol version file], lb_cv_module_symvers, [
 176 AS_IF([grep -q Modules.symvers $LINUX/scripts/Makefile.modpost],
 177         [lb_cv_module_symvers=Modules.symvers],
 178         [lb_cv_module_symvers=Module.symvers])
 179 ])
 180 SYMVERFILE=$lb_cv_module_symvers
 181 AC_SUBST(SYMVERFILE)
 182 ])
 183
 184 #
 185 # LB_ARG_REPLACE_PATH(PACKAGE, PATH)
 186 #
 187 AC_DEFUN([LB_ARG_REPLACE_PATH], [
 188 new_configure_args=
 189 eval set -- $ac_configure_args
 190 for arg; do
 191         case $arg in
 192                 --with-[$1]=*)
 193                         arg=--with-[$1]=[$2] ;;
 194                 *\'*)
 195                         arg=$(printf %s\n ["$arg"] | sed "s/'/'\\\\\\\\''/g") ;;
 196         esac
 197         dnl AS_VAR_APPEND([new_configure_args], [" '$arg'"])
 198         new_configure_args="$new_configure_args '$arg'"
 199 done
 200 ac_configure_args=$new_configure_args
 201 ])
 202
 203 #
 204 # __LB_ARG_CANON_PATH
 205 #
 206 # this is the work-horse of the next function
 207 #
 208 AC_DEFUN([__LB_ARG_CANON_PATH], [
 209         [$3]=$(readlink -f $with_$2)
 210         LB_ARG_REPLACE_PATH([$1], $[$3])
 211 ])
 212
 213 #
 214 # LB_ARG_CANON_PATH
 215 #
 216 # a front-end for the above function that transforms - and . in the
 217 # PACKAGE portion of --with-PACKAGE into _ suitable for variable names
 218 #
 219 AC_DEFUN([LB_ARG_CANON_PATH], [
 220         __LB_ARG_CANON_PATH([$1], m4_translit([$1], [-.], [__]), [$2])
 221 ])
 222
 223 #
 224 # LB_LINUX_PATH
 225 #
 226 # Find paths for linux, handling kernel-source rpms
 227 #
 228 AC_DEFUN([LB_LINUX_PATH], [
 229 for DEFAULT_LINUX in /usr/src/linux-source-* /lib/modules/$(uname -r)/{source,build} /usr/src/linux $(find /usr/src/kernels/ -maxdepth 1 -name @<:@0-9@:>@\* | xargs -r ls -d | tail -n 1); do
 230         AS_IF([readlink -q -e $DEFAULT_LINUX >/dev/null], [break])
 231 done
 232 if test "$DEFAULT_LINUX" = "/lib/modules/$(uname -r)/source"; then
 233         PATHS="/lib/modules/$(uname -r)/build"
 234 else
 235         PATHS="/usr/src/linux-headers-$(uname -r)"
 236 fi
 237 PATHS+=" $DEFAULT_LINUX"
 238 for DEFAULT_LINUX_OBJ in $PATHS; do
 239         AS_IF([readlink -q -e $DEFAULT_LINUX_OBJ >/dev/null], [break])
 240 done
 241
 242 AC_MSG_CHECKING([for Linux sources])
 243 AC_ARG_WITH([linux],
 244         AC_HELP_STRING([--with-linux=path],
 245                        [set path to Linux source (default=/lib/modules/$(uname -r)/{source,build},/usr/src/linux)]),
 246         [LB_ARG_CANON_PATH([linux], [LINUX])
 247         DEFAULT_LINUX_OBJ=$LINUX],
 248         [LINUX=$DEFAULT_LINUX])
 249 AC_MSG_RESULT([$LINUX])
 250 AC_SUBST(LINUX)
 251
 252 # -------- check for linux --------
 253 LB_CHECK_FILE([$LINUX], [],
 254         [AC_MSG_ERROR([Kernel source $LINUX could not be found.])])
 255
 256 # -------- linux objects (for 2.6) --
 257 AC_MSG_CHECKING([for Linux objects])
 258 AC_ARG_WITH([linux-obj],
 259         AC_HELP_STRING([--with-linux-obj=path],
 260                         [set path to Linux objects (default=/lib/modules/$(uname -r)/build,/usr/src/linux)]),
 261         [LB_ARG_CANON_PATH([linux-obj], [LINUX_OBJ])],
 262         [LINUX_OBJ=$DEFAULT_LINUX_OBJ])
 263 AC_MSG_RESULT([$LINUX_OBJ])
 264 AC_SUBST(LINUX_OBJ)
 265
 266 # -------- check for .config --------
 267 AC_ARG_WITH([linux-config],
 268         [AC_HELP_STRING([--with-linux-config=path],
 269                         [set path to Linux .conf (default=$LINUX_OBJ/.config)])],
 270         [LB_ARG_CANON_PATH([linux-config], [LINUX_CONFIG])],
 271         [LINUX_CONFIG=$LINUX_OBJ/.config])
 272
 273 # -------- check if .config exists --
 274 LB_CHECK_FILE([$LINUX_CONFIG], [],
 275         [AC_MSG_ERROR([
 276
 277 Kernel config could not be found.
 278
 279 If you are building from a kernel-source rpm consult build/README.kernel-source
 280 ])
 281 ])
 282 AC_SUBST(LINUX_CONFIG)
 283
 284 LB_CHECK_FILE([/boot/kernel.h],
 285         [KERNEL_SOURCE_HEADER='/boot/kernel.h'],
 286         [LB_CHECK_FILE([/var/adm/running-kernel.h],
 287                 [KERNEL_SOURCE_HEADER='/var/adm/running-kernel.h'])])
 288
 289 AC_ARG_WITH([kernel-source-header],
 290         AC_HELP_STRING([--with-kernel-source-header=path],
 291                         [Use a different kernel version header.  Consult build/README.kernel-source for details.]),
 292         [LB_ARG_CANON_PATH([kernel-source-header], [KERNEL_SOURCE_HEADER])])
 293
 294 # ----------- make dep run? ------------------
 295 # at 2.6.19 # $LINUX/include/linux/config.h is removed
 296 # and at more old has only one line include <autoconf.h>
 297 #
 298 LB_CHECK_FILE([$LINUX_OBJ/include/generated/autoconf.h],
 299         [AUTOCONF_HDIR=generated],
 300         [LB_CHECK_FILE([$LINUX_OBJ/include/linux/autoconf.h],
 301                 [AUTOCONF_HDIR=linux],
 302                 [AC_MSG_ERROR([Run make config in $LINUX.])])])
 303 AC_SUBST(AUTOCONF_HDIR)
 304
 305 LB_CHECK_FILE([$LINUX_OBJ/include/linux/version.h],
 306         [VERSION_HDIR=linux],
 307         [LB_CHECK_FILE([$LINUX_OBJ/include/generated/uapi/linux/version.h],
 308                 [VERSION_HDIR=generated/uapi/linux],
 309                 [AC_MSG_ERROR([Run make config in $LINUX.])])])
 310 AC_SUBST(VERSION_HDIR)
 311
 312 # ----------- kconfig.h exists ---------------
 313 # kernel 3.1, $LINUX/include/linux/kconfig.h is added
 314 # see kernel commit 2a11c8ea20bf850b3a2c60db8c2e7497d28aba99
 315 #
 316 LB_CHECK_FILE([$LINUX/include/linux/kconfig.h],
 317               [CONFIG_INCLUDE=$LINUX/include/linux/kconfig.h],
 318               [CONFIG_INCLUDE=include/$AUTOCONF_HDIR/autoconf.h])
 319 AC_SUBST(CONFIG_INCLUDE)
 320
 321 # ------------ rhconfig.h includes runtime-generated bits --
 322 # RedHat kernel-source checks
 323
 324 # we know this exists after the check above.  if the user
 325 # tarred up the tree and ran make dep etc. in it, then
 326 # version.h gets overwritten with a standard linux one.
 327
 328 AS_IF([grep rhconfig $LINUX_OBJ/include/$VERSION_HDIR/version.h >/dev/null], [
 329         # This is a clean kernel-source tree, we need to
 330         # enable extensive workarounds to get this to build modules
 331         LB_CHECK_FILE([$KERNEL_SOURCE_HEADER], [
 332                 AS_IF([test $KERNEL_SOURCE_HEADER = '/boot/kernel.h'],
 333                         [AC_MSG_WARN([
 334
 335 Using /boot/kernel.h from RUNNING kernel.
 336
 337 If this is not what you want, use --with-kernel-source-header.
 338 Consult build/README.kernel-source for details.
 339 ])
 340                 ])],
 341                 [AC_MSG_ERROR([
 342
 343 $KERNEL_SOURCE_HEADER not found.
 344
 345 Consult build/README.kernel-source for details.
 346 ])
 347                 ])
 348         EXTRA_KCFLAGS="-include $KERNEL_SOURCE_HEADER $EXTRA_KCFLAGS"
 349 ])
 350
 351 # this is needed before we can build modules
 352 LB_LINUX_VERSION
 353
 354 # --- check that we can build modules at all
 355 LB_CHECK_COMPILE([that modules can be built at all], build_modules,
 356         [], [], [], [
 357         AC_MSG_ERROR([
 358
 359 Kernel modules cannot be built. Consult config.log for details.
 360
 361 If you are trying to build with a kernel-source rpm,
 362 consult build/README.kernel-source
 363 ])
 364 ])
 365
 366 LB_LINUX_RELEASE
 367 ]) # end of LB_LINUX_PATH
 368
 369 #
 370 # LC_MODULE_LOADING
 371 #
 372 # after 2.6.28 CONFIG_KMOD is removed, and only CONFIG_MODULES remains
 373 # so we test if request_module is implemented or not
 374 AC_DEFUN([LC_MODULE_LOADING], [
 375 AC_CACHE_CHECK([if Linux kernel module loading is possible], lb_cv_module_loading, [
 376 LB_LINUX_TRY_MAKE([
 377         #include <linux/kmod.h>
 378 ], [
 379         int myretval=ENOSYS ;
 380         return myretval;
 381 ], [
 382         $makerule LUSTRE_KERNEL_TEST=conftest.i
 383 ], [dnl
 384         grep request_module build/conftest.i |dnl
 385                 grep -v `grep "int myretval=" build/conftest.i |dnl
 386                         cut -d= -f2 | cut -d" "  -f1`dnl
 387                 >/dev/null dnl
 388 ], [lb_cv_module_loading="yes"], [lb_cv_module_loading="no"])
 389 ])
 390 AS_IF([test "$lb_cv_module_loading" = yes],
 391         [AC_DEFINE(HAVE_MODULE_LOADING_SUPPORT, 1,
 392                 [kernel module loading is possible])],
 393         [AC_MSG_WARN([
 394
 395 Kernel module loading support is highly recommended.
 396
 397 ])
 398         ])
 399 ])
 400
 401 #
 402 # LB_PROG_LINUX
 403 #
 404 # linux tests
 405 #
 406 AC_DEFUN([LB_PROG_LINUX], [
 407 LB_LINUX_PATH
 408 LB_LINUX_SYMVERFILE
 409
 410 LB_CHECK_CONFIG([MODULES], [], [
 411         AC_MSG_ERROR([
 412
 413 module support is required to build Lustre kernel modules.
 414 ])
 415         ])
 416
 417 LB_CHECK_CONFIG([MODVERSIONS])
 418
 419 LB_CHECK_CONFIG([KALLSYMS], [], [
 420         AC_MSG_ERROR([
 421
 422 Lustre requires that CONFIG_KALLSYMS is enabled in your kernel.
 423 ])
 424         ])
 425
 426 # 2.6.28
 427 LC_MODULE_LOADING
 428 ])
 429
 430 #
 431 # LB_USES_DPKG
 432 #
 433 # Determine if the target is a dpkg system or rpm
 434 #
 435 AC_DEFUN([LB_USES_DPKG], [
 436 AC_CACHE_CHECK([if this distro uses dpkg], lb_cv_uses_dpkg, [
 437 lb_cv_uses_dpkg="no"
 438 AS_CASE([$(which dpkg 2>/dev/null)],[*/dpkg], [lb_cv_uses_dpkg="yes"])
 439 ])
 440 uses_dpkg=$lb_cv_uses_dpkg
 441 ])
 442
 443 #
 444 # LB_CHECK_EXPORT
 445 #
 446 # check symbol exported or not
 447 # $1 - symbol
 448 # $2 - file(s) for find.
 449 # $3 - do 'yes'
 450 # $4 - do 'no'
 451 #
 452 # 2.6 based kernels - put modversion info into $LINUX/Module.modvers or check
 453 #
 454 AC_DEFUN([LB_CHECK_EXPORT], [
 455 AS_VAR_PUSHDEF([lb_export], [lb_cv_export_$1])dnl
 456 AC_CACHE_CHECK([if Linux kernel exports '$1'], lb_export, [
 457 AS_VAR_SET([lb_export], [no])
 458 AS_IF([grep -q -E '[[[:space:]]]$1[[[:space:]]]' $LINUX_OBJ/$SYMVERFILE 2>/dev/null],
 459         [AS_VAR_SET([lb_export], [yes])],
 460         [for file in $2; do
 461                 AS_IF([grep -q -E "EXPORT_SYMBOL.*\($1\)" "$LINUX/$file" 2>/dev/null], [
 462                         AS_VAR_SET([lb_export], [yes])
 463                         break
 464                 ])
 465         done])
 466 ])
 467 AS_VAR_IF([lb_export], [yes], [$3], [$4])[]dnl
 468 AS_VAR_POPDEF([lb_export])dnl
 469 ]) # LB_CHECK_EXPORT
 470
 471 #
 472 # LB_CHECK_CONFIG
 473 #
 474 # check if a given config option is defined
 475 # $1 - CONFIG_<name>
 476 # $2 - do 'yes'
 477 # $3 - do 'no'
 478 #
 479 AC_DEFUN([LB_CHECK_CONFIG], [
 480 LB_CHECK_COMPILE([if Linux kernel was built with CONFIG_$1],
 481 config_$1, [
 482         #include <$AUTOCONF_HDIR/autoconf.h>
 483 ], [
 484         #ifndef CONFIG_$1
 485         #error CONFIG_$1 not #defined
 486         #endif
 487 ], [$2], [$3])
 488 ]) # LB_CHECK_CONFIG
 489
 490 #
 491 # LB_CHECK_CONFIG_IM
 492 #
 493 # check if a given config option is builtin or as module
 494 # $1 - CONFIG_<name> or CONFIG_<name>_MODULE
 495 # $2 - do 'yes'
 496 # $3 - do 'no'
 497 #
 498 AC_DEFUN([LB_CHECK_CONFIG_IM], [
 499 LB_CHECK_COMPILE([if Linux kernel was built with CONFIG_$1 in or as module],
 500 config_im_$1, [
 501         #include <$AUTOCONF_HDIR/autoconf.h>
 502 ], [
 503         #if !(defined(CONFIG_$1) || defined(CONFIG_$1_MODULE))
 504         #error CONFIG_$1 and CONFIG_$1_MODULE not #defined
 505         #endif
 506 ], [$2], [$3])
 507 ]) # LB_CHECK_CONFIG_IM
 508
 509 #
 510 # these are like AC_TRY_COMPILE, but try to build modules against the
 511 # kernel, inside the build directory
 512 #
 513
 514 #
 515 # LB_LANG_PROGRAM(C)([PROLOGUE], [BODY])
 516 # --------------------------------------
 517 #
 518 m4_define([LB_LANG_PROGRAM],
 519 [
 520 #include <linux/kernel.h>
 521 #include <linux/module.h>
 522 $1
 523 int
 524 main (void)
 525 {
 526 dnl Do *not* indent the following line: there may be CPP directives.
 527 dnl Don't move the `;' right after for the same reason.
 528 $2
 529   ;
 530   return 0;
 531 };
 532 MODULE_LICENSE("GPL");])
 533
 534 #
 535 # LB_LINUX_COMPILE_IFELSE
 536 #
 537 # like AC_COMPILE_IFELSE
 538 #
 539 # $1 - AC_LANG_SOURCE()
 540 # $2 - make target
 541 # $3 - check command
 542 # $4 - do 'yes'
 543 # $5 - do 'no'
 544 #
 545 AC_DEFUN([LB_LINUX_COMPILE_IFELSE],
 546 [m4_ifvaln([$1], [AC_LANG_CONFTEST([AC_LANG_SOURCE([$1])])])dnl
 547 rm -f build/conftest.o build/conftest.mod.c build/conftest.ko
 548 SUBARCH=$(echo $target_cpu | sed -e 's/powerpc.*/powerpc/' -e 's/ppc.*/powerpc/' -e 's/x86_64/x86/' -e 's/i.86/x86/' -e 's/k1om/x86/' -e 's/aarch64.*/arm64/' -e 's/armv7.*/arm/')
 549 AS_IF([AC_TRY_COMMAND(cp conftest.c build && make -d [$2] LDFLAGS= ${LD:+LD="$LD"} CC="$CC" -f $PWD/build/Makefile LUSTRE_LINUX_CONFIG=$LINUX_CONFIG LINUXINCLUDE="$EXTRA_CHECK_INCLUDE -I$LINUX/arch/$SUBARCH/include -Iinclude -Iarch/$SUBARCH/include/generated -I$LINUX/include -Iinclude2 -I$LINUX/include/uapi -Iinclude/generated -I$LINUX/arch/$SUBARCH/include/uapi -Iarch/$SUBARCH/include/generated/uapi -I$LINUX/include/uapi -Iinclude/generated/uapi ${SPL_OBJ:+-include $SPL_OBJ/spl_config.h} ${ZFS_OBJ:+-include $ZFS_OBJ/zfs_config.h} ${SPL:+-I$SPL -I$SPL/include } ${ZFS:+-I$ZFS -I$ZFS/include} -include $CONFIG_INCLUDE" -o tmp_include_depends -o scripts -o include/config/MARKER -C $LINUX_OBJ EXTRA_CFLAGS="-Werror-implicit-function-declaration $EXTRA_KCFLAGS" $MODULE_TARGET=$PWD/build) >/dev/null && AC_TRY_COMMAND([$3])],
 550         [$4],
 551         [_AC_MSG_LOG_CONFTEST
 552 m4_ifvaln([$5],[$5])dnl])
 553 rm -f build/conftest.o build/conftest.mod.c build/conftest.mod.o build/conftest.ko m4_ifval([$1], [build/conftest.c conftest.c])[]dnl
 554 ])
 555
 556 #
 557 # LB_LINUX_TRY_COMPILE
 558 #
 559 # like AC_TRY_COMPILE
 560 #
 561 AC_DEFUN([LB_LINUX_TRY_COMPILE], [
 562 LB_LINUX_COMPILE_IFELSE(
 563         [AC_LANG_SOURCE([LB_LANG_PROGRAM([[$1]], [[$2]])])],
 564         [modules], [test -s build/conftest.o],
 565         [$3], [$4])
 566 ])
 567
 568 #
 569 # LB_LINUX_TRY_MAKE
 570 #
 571 # like LB_LINUX_TRY_COMPILE, but with different arguments
 572 #
 573 AC_DEFUN([LB_LINUX_TRY_MAKE], [
 574 LB_LINUX_COMPILE_IFELSE(
 575         [AC_LANG_SOURCE([LB_LANG_PROGRAM([[$1]], [[$2]])])],
 576         [$3], [$4], [$5], [$6])
 577 ])
 578
 579 #
 580 # LB_CHECK_COMPILE
 581 # $1 - checking message
 582 # $2 - variable name
 583 # $3 - header
 584 # $4 - body
 585 # $5 - do 'yes'
 586 # $6 - do 'no'
 587 #
 588 AC_DEFUN([LB_CHECK_COMPILE], [
 589 AS_VAR_PUSHDEF([lb_compile], [lb_cv_compile_$2])dnl
 590 AC_CACHE_CHECK([$1], lb_compile, [
 591         LB_LINUX_TRY_COMPILE([$3], [$4],
 592                 [AS_VAR_SET([lb_compile], [yes])],
 593                 [AS_VAR_SET([lb_compile], [no])])
 594 ])
 595 AS_VAR_IF([lb_compile], [yes], [$5], [$6])[]dnl
 596 AS_VAR_POPDEF([lb_compile])dnl
 597 ]) # LB_CHECK_COMPILE
 598
 599 #
 600 # LB_CHECK_LINUX_HEADER
 601 #
 602 # Like AC_CHECK_HEADER but checks for a kernel-space header
 603 #
 604 m4_define([LB_CHECK_LINUX_HEADER], [
 605 AS_VAR_PUSHDEF([lb_header], [lb_cv_header_$1])dnl
 606 AC_CACHE_CHECK([for $1], lb_header, [
 607         LB_LINUX_COMPILE_IFELSE([LB_LANG_PROGRAM([@%:@include <$1>])],
 608                 [modules], [test -s build/conftest.o],
 609                 [AS_VAR_SET([lb_header], [yes])],
 610                 [AS_VAR_SET([lb_header], [no])])
 611 ])
 612 AS_VAR_IF([lb_header], [yes], [$2], [$3])[]dnl
 613 AS_VAR_POPDEF([lb_header])dnl
 614 ]) # LB_CHECK_LINUX_HEADER