config/lustre-build-linux.m4

   1 #
   2 # LB_LINUX_VERSION
   3 #
   4 # Set things accordingly for a linux kernel
   5 #
   6 AC_DEFUN([LB_LINUX_VERSION], [
   7 KMODEXT=".ko"
   8 AC_SUBST(KMODEXT)
   9
  10 makerule="$PWD/build"
  11 AC_CACHE_CHECK([for external module build target], lb_cv_module_target, [
  12 lb_cv_module_target=""
  13 MODULE_TARGET="SUBDIRS"
  14 rm -f build/conftest.i
  15 LB_LINUX_TRY_MAKE([], [],
  16         [$makerule LUSTRE_KERNEL_TEST=conftest.i],
  17         [test -s build/conftest.i],
  18         [lb_cv_module_target="SUBDIRS"], [
  19                 MODULE_TARGET="M"
  20                 makerule="_module_$PWD/build"
  21                 LB_LINUX_TRY_MAKE([], [],
  22                         [$makerule LUSTRE_KERNEL_TEST=conftest.i],
  23                         [test -s build/conftest.i],
  24                         [lb_cv_module_target="M"], [
  25                                 AC_MSG_ERROR([unknown; check config.log for details])
  26                         ])
  27         ])
  28 ])
  29 AS_IF([test -z "$lb_cv_module_target"],
  30         [AC_MSG_ERROR([unknown external module build target])],
  31 [test "x$lb_cv_module_target" = "xM"],
  32         [makerule="_module_$PWD/build"])
  33 MODULE_TARGET=$lb_cv_module_target
  34 AC_SUBST(MODULE_TARGET)
  35 ])
  36
  37 #
  38 # LB_LINUX_UTSRELEASE
  39 #
  40 # Determine the Linux kernel version string from the utsrelease
  41 #
  42 AC_DEFUN([LB_LINUX_UTSRELEASE], [
  43 AC_CACHE_CHECK([for Linux kernel utsrelease], lb_cv_utsrelease, [
  44 lb_cv_utsrelease=""
  45 utsrelease1=$LINUX_OBJ/include/generated/utsrelease.h
  46 utsrelease2=$LINUX_OBJ/include/linux/utsrelease.h
  47 utsrelease3=$LINUX_OBJ/include/linux/version.h
  48 AS_IF([test -r $utsrelease1 && fgrep -q UTS_RELEASE $utsrelease1],
  49         [utsrelease=$utsrelease1],
  50 [test -r $utsrelease2 && fgrep -q UTS_RELEASE $utsrelease2],
  51         [utsrelease=$utsrelease2],
  52 [test -r $utsrelease3 && fgrep -q UTS_RELEASE $utsrelease3],
  53         [utsrelease=$utsrelease3])
  54 AS_IF([test -n "$utsrelease"],
  55         [lb_cv_utsrelease=$(awk -F \" '/ UTS_RELEASE / { print [$]2 }' $utsrelease)],
  56         [AC_MSG_ERROR([
  57
  58 Cannot find UTS_RELEASE definition.
  59
  60 This is often provided by the kernel-devel package.
  61 ])
  62         ])
  63 ])
  64 AS_IF([test -z "$lb_cv_utsrelease"],
  65         [AC_MSG_ERROR([Cannot determine Linux kernel version.])])
  66 LINUXRELEASE=$lb_cv_utsrelease
  67 AC_SUBST(LINUXRELEASE)
  68 ])
  69
  70 #
  71 # LB_LINUX_RELEASE
  72 #
  73 # get the release version of linux
  74 #
  75 AC_DEFUN([LB_LINUX_RELEASE], [
  76 LB_LINUX_UTSRELEASE
  77
  78 # ------------ RELEASE --------------------------------
  79 AC_MSG_CHECKING([for Lustre release])
  80 AC_ARG_WITH([release],
  81         AC_HELP_STRING([--with-release=string],
  82                 [set the release string (default=$kvers_YYYYMMDDhhmm)]),
  83         [RELEASE=$withval], [
  84         RELEASE=""
  85         AS_IF([test "$DOWNSTREAM_RELEASE"], [RELEASE="${DOWNSTREAM_RELEASE}_"])
  86         RELEASE="$RELEASE$(echo $LINUXRELEASE | tr '-' '_')_$BUILDID"])
  87 AC_MSG_RESULT($RELEASE)
  88 AC_SUBST(RELEASE)
  89
  90 # check if the kernel is one from RHEL or SUSE
  91 AC_CACHE_CHECK([for RedHat kernel release number], lb_cv_rhel_kernel_version, [
  92 lb_cv_rhel_kernel_version=""
  93 AS_IF([fgrep -q RHEL_RELEASE $LINUX_OBJ/include/$VERSION_HDIR/version.h], [
  94         lb_cv_rhel_kernel_version=$(awk '/ RHEL_MAJOR / { print [$]3 }' \
  95                 $LINUX_OBJ/include/$VERSION_HDIR/version.h)$(awk \
  96                 '/ RHEL_MINOR / { print [$]3 }' \
  97                 $LINUX_OBJ/include/$VERSION_HDIR/version.h)
  98 ])
  99 ])
 100 AS_IF([test -n "$lb_cv_rhel_kernel_version"], [
 101         RHEL_KERNEL="yes"
 102         RHEL_RELEASE_NO=$lb_cv_rhel_kernel_version
 103 ], [
 104         RHEL_KERNEL="no"
 105         LB_CHECK_CONFIG([SUSE_KERNEL], [SUSE_KERNEL="yes"], [SUSE_KERNEL="no"])
 106 ])
 107
 108 AC_MSG_CHECKING([for Linux kernel module package directory])
 109 AC_ARG_WITH([kmp-moddir],
 110         AC_HELP_STRING([--with-kmp-moddir=string],
 111                 [set the kmod updates or extra directory]),
 112         [KMP_MODDIR=$withval],[
 113         AS_IF([test x$RHEL_KERNEL = xyes], [KMP_MODDIR="extra"],
 114               [test x$SUSE_KERNEL = xyes], [KMP_MODDIR="updates"])])
 115 AC_MSG_RESULT($KMP_MODDIR)
 116 AC_SUBST(KMP_MODDIR)
 117
 118 moduledir='$(CROSS_PATH)/lib/modules/$(LINUXRELEASE)/$(KMP_MODDIR)/kernel'
 119 AC_SUBST(moduledir)
 120
 121 modulefsdir='$(moduledir)/fs/$(PACKAGE)'
 122 AC_SUBST(modulefsdir)
 123
 124 modulenetdir='$(moduledir)/net/$(PACKAGE)'
 125 AC_SUBST(modulenetdir)
 126 ])
 127
 128 #
 129 # LB_LINUX_SYMVERFILE
 130 #
 131 # SLES 9 uses a different name for this file - unsure about vanilla kernels
 132 # around this version, but it matters for servers only.
 133 AC_DEFUN([LB_LINUX_SYMVERFILE], [
 134 AC_CACHE_CHECK([for the name of module symbol version file], lb_cv_module_symvers, [
 135 AS_IF([grep -q Modules.symvers $LINUX/scripts/Makefile.modpost],
 136         [lb_cv_module_symvers=Modules.symvers],
 137         [lb_cv_module_symvers=Module.symvers])
 138 ])
 139 SYMVERFILE=$lb_cv_module_symvers
 140 AC_SUBST(SYMVERFILE)
 141 ])
 142
 143 #
 144 # LB_LINUX_CROSS
 145 #
 146 # check for cross compilation
 147 #
 148 AC_DEFUN([LB_LINUX_CROSS], [
 149 AC_CACHE_CHECK([for cross compilation], lb_cv_cross, [
 150 lb_cv_cross="no"
 151 AS_IF([test "x$cross_compiling" = xyes],
 152         [AS_CASE([$host_vendor],
 153                 [k1om | mpss], [
 154                         # The K1OM architecture is an extension of the x86 architecture
 155                         # and in MPSS 2.1 it's defined in $host_vendor. But in MPSS 3.x
 156                         # it's defined in $host_arch. So, try to support both case.
 157                         lb_cv_cross=$($CC -v 2>&1 | grep Target: | sed -e 's/Target: //')
 158                         AS_IF([test "$lb_cv_cross" != x86_64-k1om-linux -a \
 159                                     "$lb_cv_cross" != k1om-mpss-linux], [
 160                                 AC_MSG_ERROR([Cross compiler not found in PATH.])
 161                         ])
 162                 ])
 163         ])
 164 ])
 165 AS_IF([test "$lb_cv_cross" = x86_64-k1om-linux -o \
 166             "$lb_cv_cross" = k1om-mpss-linux], [
 167         CROSS_VARS="ARCH=k1om CROSS_COMPILE=${lb_cv_cross}-"
 168         CROSS_PATH="${CROSS_PATH:=/opt/lustre/$VERSION/$lb_cv_cross}"
 169         CCAS=$CC
 170         # need to produce special section for debuginfo extraction
 171         LDFLAGS="$LDFLAGS -Wl,--build-id"
 172         EXTRA_KLDFLAGS="$EXTRA_KLDFLAGS -Wl,--build-id"
 173         AS_IF([test "x$enable_server" != xno], [
 174                 AC_MSG_WARN([Disabling server (not supported for $lb_cv_cross).])
 175                 enable_server="no"
 176         ])
 177         AS_IF([test "x$enable_mpitests" != xno], [
 178                 AC_MSG_WARN([Disabling MPI tests (not supported for $lb_cv_cross).])
 179                 enable_mpitests="no"
 180         ])
 181 ])
 182 AC_SUBST(CROSS_VARS)
 183 AC_SUBST(CROSS_PATH)
 184 ])
 185
 186 #
 187 # LB_ARG_REPLACE_PATH(PACKAGE, PATH)
 188 #
 189 AC_DEFUN([LB_ARG_REPLACE_PATH], [
 190 new_configure_args=
 191 eval set -- $ac_configure_args
 192 for arg; do
 193         case $arg in
 194                 --with-[$1]=*)
 195                         arg=--with-[$1]=[$2] ;;
 196                 *\'*)
 197                         arg=$(printf %s\n ["$arg"] | sed "s/'/'\\\\\\\\''/g") ;;
 198         esac
 199         dnl AS_VAR_APPEND([new_configure_args], [" '$arg'"])
 200         new_configure_args="$new_configure_args '$arg'"
 201 done
 202 ac_configure_args=$new_configure_args
 203 ])
 204
 205 #
 206 # __LB_ARG_CANON_PATH
 207 #
 208 # this is the work-horse of the next function
 209 #
 210 AC_DEFUN([__LB_ARG_CANON_PATH], [
 211         [$3]=$(readlink -f $with_$2)
 212         LB_ARG_REPLACE_PATH([$1], $[$3])
 213 ])
 214
 215 #
 216 # LB_ARG_CANON_PATH
 217 #
 218 # a front-end for the above function that transforms - and . in the
 219 # PACKAGE portion of --with-PACKAGE into _ suitable for variable names
 220 #
 221 AC_DEFUN([LB_ARG_CANON_PATH], [
 222         __LB_ARG_CANON_PATH([$1], m4_translit([$1], [-.], [__]), [$2])
 223 ])
 224
 225 #
 226 # LB_LINUX_PATH
 227 #
 228 # Find paths for linux, handling kernel-source rpms
 229 #
 230 AC_DEFUN([LB_LINUX_PATH], [
 231 for DEFAULT_LINUX in /lib/modules/$(uname -r)/{source,build} /usr/src/linux; do
 232         AS_IF([readlink -q -e $DEFAULT_LINUX >/dev/null], [break])
 233 done
 234 if test "$DEFAULT_LINUX" = "/lib/modules/$(uname -r)/source"; then
 235         PATHS="/lib/modules/$(uname -r)/build"
 236 fi
 237 PATHS+=" $DEFAULT_LINUX"
 238 for DEFAULT_LINUX_OBJ in $PATHS; do
 239         AS_IF([readlink -q -e $DEFAULT_LINUX_OBJ >/dev/null], [break])
 240 done
 241
 242 AC_MSG_CHECKING([for Linux sources])
 243 AC_ARG_WITH([linux],
 244         AC_HELP_STRING([--with-linux=path],
 245                        [set path to Linux source (default=/lib/modules/$(uname -r)/{source,build},/usr/src/linux)]),
 246         [LB_ARG_CANON_PATH([linux], [LINUX])
 247         DEFAULT_LINUX_OBJ=$LINUX],
 248         [LINUX=$DEFAULT_LINUX])
 249 AC_MSG_RESULT([$LINUX])
 250 AC_SUBST(LINUX)
 251
 252 # -------- check for linux --------
 253 LB_CHECK_FILE([$LINUX], [],
 254         [AC_MSG_ERROR([Kernel source $LINUX could not be found.])])
 255
 256 # -------- linux objects (for 2.6) --
 257 AC_MSG_CHECKING([for Linux objects])
 258 AC_ARG_WITH([linux-obj],
 259         AC_HELP_STRING([--with-linux-obj=path],
 260                         [set path to Linux objects (default=/lib/modules/$(uname -r)/build,/usr/src/linux)]),
 261         [LB_ARG_CANON_PATH([linux-obj], [LINUX_OBJ])],
 262         [LINUX_OBJ=$DEFAULT_LINUX_OBJ])
 263 AC_MSG_RESULT([$LINUX_OBJ])
 264 AC_SUBST(LINUX_OBJ)
 265
 266 # -------- check for .config --------
 267 AC_ARG_WITH([linux-config],
 268         [AC_HELP_STRING([--with-linux-config=path],
 269                         [set path to Linux .conf (default=$LINUX_OBJ/.config)])],
 270         [LB_ARG_CANON_PATH([linux-config], [LINUX_CONFIG])],
 271         [LINUX_CONFIG=$LINUX_OBJ/.config])
 272
 273 # -------- check if .config exists --
 274 LB_CHECK_FILE([$LINUX_CONFIG], [],
 275         [AC_MSG_ERROR([
 276
 277 Kernel config could not be found.
 278
 279 If you are building from a kernel-source rpm consult build/README.kernel-source
 280 ])
 281 ])
 282 AC_SUBST(LINUX_CONFIG)
 283
 284 LB_CHECK_FILE([/boot/kernel.h],
 285         [KERNEL_SOURCE_HEADER='/boot/kernel.h'],
 286         [LB_CHECK_FILE([/var/adm/running-kernel.h],
 287                 [KERNEL_SOURCE_HEADER='/var/adm/running-kernel.h'])])
 288
 289 AC_ARG_WITH([kernel-source-header],
 290         AC_HELP_STRING([--with-kernel-source-header=path],
 291                         [Use a different kernel version header.  Consult build/README.kernel-source for details.]),
 292         [LB_ARG_CANON_PATH([kernel-source-header], [KERNEL_SOURCE_HEADER])])
 293
 294 # ----------- make dep run? ------------------
 295 # at 2.6.19 # $LINUX/include/linux/config.h is removed
 296 # and at more old has only one line include <autoconf.h>
 297 #
 298 LB_CHECK_FILE([$LINUX_OBJ/include/generated/autoconf.h],
 299         [AUTOCONF_HDIR=generated],
 300         [LB_CHECK_FILE([$LINUX_OBJ/include/linux/autoconf.h],
 301                 [AUTOCONF_HDIR=linux],
 302                 [AC_MSG_ERROR([Run make config in $LINUX.])])])
 303 AC_SUBST(AUTOCONF_HDIR)
 304
 305 LB_CHECK_FILE([$LINUX_OBJ/include/linux/version.h],
 306         [VERSION_HDIR=linux],
 307         [LB_CHECK_FILE([$LINUX_OBJ/include/generated/uapi/linux/version.h],
 308                 [VERSION_HDIR=generated/uapi/linux],
 309                 [AC_MSG_ERROR([Run make config in $LINUX.])])])
 310 AC_SUBST(VERSION_HDIR)
 311
 312 # ----------- kconfig.h exists ---------------
 313 # kernel 3.1, $LINUX/include/linux/kconfig.h is added
 314 # see kernel commit 2a11c8ea20bf850b3a2c60db8c2e7497d28aba99
 315 #
 316 LB_CHECK_FILE([$LINUX/include/linux/kconfig.h],
 317               [CONFIG_INCLUDE=$LINUX/include/linux/kconfig.h],
 318               [CONFIG_INCLUDE=include/$AUTOCONF_HDIR/autoconf.h])
 319 AC_SUBST(CONFIG_INCLUDE)
 320
 321 # ------------ rhconfig.h includes runtime-generated bits --
 322 # RedHat kernel-source checks
 323
 324 # we know this exists after the check above.  if the user
 325 # tarred up the tree and ran make dep etc. in it, then
 326 # version.h gets overwritten with a standard linux one.
 327
 328 AS_IF([grep rhconfig $LINUX_OBJ/include/$VERSION_HDIR/version.h >/dev/null], [
 329         # This is a clean kernel-source tree, we need to
 330         # enable extensive workarounds to get this to build modules
 331         LB_CHECK_FILE([$KERNEL_SOURCE_HEADER], [
 332                 AS_IF([test $KERNEL_SOURCE_HEADER = '/boot/kernel.h'],
 333                         [AC_MSG_WARN([
 334
 335 Using /boot/kernel.h from RUNNING kernel.
 336
 337 If this is not what you want, use --with-kernel-source-header.
 338 Consult build/README.kernel-source for details.
 339 ])
 340                 ])],
 341                 [AC_MSG_ERROR([
 342
 343 $KERNEL_SOURCE_HEADER not found.
 344
 345 Consult build/README.kernel-source for details.
 346 ])
 347                 ])
 348         EXTRA_KCFLAGS="-include $KERNEL_SOURCE_HEADER $EXTRA_KCFLAGS"
 349 ])
 350
 351 # this is needed before we can build modules
 352 LB_LINUX_CROSS
 353 LB_LINUX_VERSION
 354
 355 # --- check that we can build modules at all
 356 LB_CHECK_COMPILE([that modules can be built at all], build_modules,
 357         [], [], [], [
 358         AC_MSG_ERROR([
 359
 360 Kernel modules cannot be built. Consult config.log for details.
 361
 362 If you are trying to build with a kernel-source rpm,
 363 consult build/README.kernel-source
 364 ])
 365 ])
 366
 367 LB_LINUX_RELEASE
 368 ]) # end of LB_LINUX_PATH
 369
 370 #
 371 # LC_MODULE_LOADING
 372 #
 373 # after 2.6.28 CONFIG_KMOD is removed, and only CONFIG_MODULES remains
 374 # so we test if request_module is implemented or not
 375 AC_DEFUN([LC_MODULE_LOADING], [
 376 AC_CACHE_CHECK([if Linux kernel module loading is possible], lb_cv_module_loading, [
 377 LB_LINUX_TRY_MAKE([
 378         #include <linux/kmod.h>
 379 ], [
 380         int myretval=ENOSYS ;
 381         return myretval;
 382 ], [
 383         $makerule LUSTRE_KERNEL_TEST=conftest.i
 384 ], [dnl
 385         grep request_module build/conftest.i |dnl
 386                 grep -v `grep "int myretval=" build/conftest.i |dnl
 387                         cut -d= -f2 | cut -d" "  -f1`dnl
 388                 >/dev/null dnl
 389 ], [lb_cv_module_loading="yes"], [lb_cv_module_loading="no"])
 390 ])
 391 AS_IF([test "$lb_cv_module_loading" = yes],
 392         [AC_DEFINE(HAVE_MODULE_LOADING_SUPPORT, 1,
 393                 [kernel module loading is possible])],
 394         [AC_MSG_WARN([
 395
 396 Kernel module loading support is highly recommended.
 397
 398 ])
 399         ])
 400 ])
 401
 402 #
 403 # LB_PROG_LINUX
 404 #
 405 # linux tests
 406 #
 407 AC_DEFUN([LB_PROG_LINUX], [
 408 LB_LINUX_PATH
 409 LB_LINUX_SYMVERFILE
 410
 411 LB_CHECK_CONFIG([MODULES], [], [
 412         AC_MSG_ERROR([
 413
 414 module support is required to build Lustre kernel modules.
 415 ])
 416         ])
 417
 418 LB_CHECK_CONFIG([MODVERSIONS])
 419
 420 LB_CHECK_CONFIG([KALLSYMS], [], [
 421         AC_MSG_ERROR([
 422
 423 Lustre requires that CONFIG_KALLSYMS is enabled in your kernel.
 424 ])
 425         ])
 426
 427 # 2.6.28
 428 LC_MODULE_LOADING
 429 ])
 430
 431 #
 432 # LB_USES_DPKG
 433 #
 434 # Determine if the target is a dpkg system or rpm
 435 #
 436 AC_DEFUN([LB_USES_DPKG], [
 437 AC_CACHE_CHECK([if this distro uses dpkg], lb_cv_uses_dpkg, [
 438 lb_cv_uses_dpkg="no"
 439 AS_CASE([$(lsb_release -i -s 2>/dev/null)],
 440         [Ubuntu | Debian], [lb_cv_uses_dpkg="yes"])
 441 ])
 442 uses_dpkg=$lb_cv_uses_dpkg
 443 ])
 444
 445 #
 446 # LB_CHECK_EXPORT
 447 #
 448 # check symbol exported or not
 449 # $1 - symbol
 450 # $2 - file(s) for find.
 451 # $3 - do 'yes'
 452 # $4 - do 'no'
 453 #
 454 # 2.6 based kernels - put modversion info into $LINUX/Module.modvers or check
 455 #
 456 AC_DEFUN([LB_CHECK_EXPORT], [
 457 AS_VAR_PUSHDEF([lb_export], [lb_cv_export_$1])dnl
 458 AC_CACHE_CHECK([if Linux kernel exports '$1'], lb_export, [
 459 AS_VAR_SET([lb_export], [no])
 460 AS_IF([grep -q -E '[[[:space:]]]$1[[[:space:]]]' $LINUX_OBJ/$SYMVERFILE 2>/dev/null],
 461         [AS_VAR_SET([lb_export], [yes])],
 462         [for file in $2; do
 463                 AS_IF([grep -q -E "EXPORT_SYMBOL.*\($1\)" "$LINUX/$file" 2>/dev/null], [
 464                         AS_VAR_SET([lb_export], [yes])
 465                         break
 466                 ])
 467         done])
 468 ])
 469 AS_VAR_IF([lb_export], [yes], [$3], [$4])[]dnl
 470 AS_VAR_POPDEF([lb_export])dnl
 471 ]) # LB_CHECK_EXPORT
 472
 473 #
 474 # LB_CHECK_CONFIG
 475 #
 476 # check if a given config option is defined
 477 # $1 - CONFIG_<name>
 478 # $2 - do 'yes'
 479 # $3 - do 'no'
 480 #
 481 AC_DEFUN([LB_CHECK_CONFIG], [
 482 LB_CHECK_COMPILE([if Linux kernel was built with CONFIG_$1],
 483 config_$1, [
 484         #include <$AUTOCONF_HDIR/autoconf.h>
 485 ], [
 486         #ifndef CONFIG_$1
 487         #error CONFIG_$1 not #defined
 488         #endif
 489 ], [$2], [$3])
 490 ]) # LB_CHECK_CONFIG
 491
 492 #
 493 # LB_CHECK_CONFIG_IM
 494 #
 495 # check if a given config option is builtin or as module
 496 # $1 - CONFIG_<name> or CONFIG_<name>_MODULE
 497 # $2 - do 'yes'
 498 # $3 - do 'no'
 499 #
 500 AC_DEFUN([LB_CHECK_CONFIG_IM], [
 501 LB_CHECK_COMPILE([if Linux kernel was built with CONFIG_$1 in or as module],
 502 config_im_$1, [
 503         #include <$AUTOCONF_HDIR/autoconf.h>
 504 ], [
 505         #if !(defined(CONFIG_$1) || defined(CONFIG_$1_MODULE))
 506         #error CONFIG_$1 and CONFIG_$1_MODULE not #defined
 507         #endif
 508 ], [$2], [$3])
 509 ]) # LB_CHECK_CONFIG_IM
 510
 511 #
 512 # these are like AC_TRY_COMPILE, but try to build modules against the
 513 # kernel, inside the build directory
 514 #
 515
 516 #
 517 # LB_LANG_PROGRAM(C)([PROLOGUE], [BODY])
 518 # --------------------------------------
 519 #
 520 m4_define([LB_LANG_PROGRAM],
 521 [
 522 #include <linux/kernel.h>
 523 $1
 524 int
 525 main (void)
 526 {
 527 dnl Do *not* indent the following line: there may be CPP directives.
 528 dnl Don't move the `;' right after for the same reason.
 529 $2
 530   ;
 531   return 0;
 532 }])
 533
 534 #
 535 # LB_LINUX_COMPILE_IFELSE
 536 #
 537 # like AC_COMPILE_IFELSE
 538 #
 539 # $1 - AC_LANG_SOURCE()
 540 # $2 - make target
 541 # $3 - check command
 542 # $4 - do 'yes'
 543 # $5 - do 'no'
 544 #
 545 AC_DEFUN([LB_LINUX_COMPILE_IFELSE],
 546 [m4_ifvaln([$1], [AC_LANG_CONFTEST([AC_LANG_SOURCE([$1])])])dnl
 547 rm -f build/conftest.o build/conftest.mod.c build/conftest.ko
 548 SUBARCH=$(echo $target_cpu | sed -e 's/powerpc64le/powerpc/' -e 's/powerpc64/powerpc/' -e 's/x86_64/x86/' -e 's/i.86/x86/' -e 's/k1om/x86/')
 549 AS_IF([AC_TRY_COMMAND(cp conftest.c build && make -d [$2] ${LD:+"LD=$LD"} CC="$CC" -f $PWD/build/Makefile LUSTRE_LINUX_CONFIG=$LINUX_CONFIG LINUXINCLUDE="$EXTRA_OFED_INCLUDE -I$LINUX/arch/$SUBARCH/include -Iinclude -Iarch/$SUBARCH/include/generated -I$LINUX/include -Iinclude2 -I$LINUX/include/uapi -Iinclude/generated -I$LINUX/arch/$SUBARCH/include/uapi -Iarch/$SUBARCH/include/generated/uapi -I$LINUX/include/uapi -Iinclude/generated/uapi ${SPL_OBJ:+-include $SPL_OBJ/spl_config.h} ${ZFS_OBJ:+-include $ZFS_OBJ/zfs_config.h} ${SPL:+-I$SPL -I$SPL/include } ${ZFS:+-I$ZFS -I$ZFS/include} -include $CONFIG_INCLUDE" -o tmp_include_depends -o scripts -o include/config/MARKER -C $LINUX_OBJ EXTRA_CFLAGS="-Werror-implicit-function-declaration $EXTRA_KCFLAGS" $CROSS_VARS $MODULE_TARGET=$PWD/build) >/dev/null && AC_TRY_COMMAND([$3])],
 550         [$4],
 551         [_AC_MSG_LOG_CONFTEST
 552 m4_ifvaln([$5],[$5])dnl])
 553 rm -f build/conftest.o build/conftest.mod.c build/conftest.mod.o build/conftest.ko m4_ifval([$1], [build/conftest.c conftest.c])[]dnl
 554 ])
 555
 556 #
 557 # LB_LINUX_TRY_COMPILE
 558 #
 559 # like AC_TRY_COMPILE
 560 #
 561 AC_DEFUN([LB_LINUX_TRY_COMPILE], [
 562 LB_LINUX_COMPILE_IFELSE(
 563         [AC_LANG_SOURCE([LB_LANG_PROGRAM([[$1]], [[$2]])])],
 564         [modules], [test -s build/conftest.o],
 565         [$3], [$4])
 566 ])
 567
 568 #
 569 # LB_LINUX_TRY_MAKE
 570 #
 571 # like LB_LINUX_TRY_COMPILE, but with different arguments
 572 #
 573 AC_DEFUN([LB_LINUX_TRY_MAKE], [
 574 LB_LINUX_COMPILE_IFELSE(
 575         [AC_LANG_SOURCE([LB_LANG_PROGRAM([[$1]], [[$2]])])],
 576         [$3], [$4], [$5], [$6])
 577 ])
 578
 579 #
 580 # LB_CHECK_COMPILE
 581 # $1 - checking message
 582 # $2 - variable name
 583 # $3 - header
 584 # $4 - body
 585 # $5 - do 'yes'
 586 # $6 - do 'no'
 587 #
 588 AC_DEFUN([LB_CHECK_COMPILE], [
 589 AS_VAR_PUSHDEF([lb_compile], [lb_cv_compile_$2])dnl
 590 AC_CACHE_CHECK([$1], lb_compile, [
 591         LB_LINUX_TRY_COMPILE([$3], [$4],
 592                 [AS_VAR_SET([lb_compile], [yes])],
 593                 [AS_VAR_SET([lb_compile], [no])])
 594 ])
 595 AS_VAR_IF([lb_compile], [yes], [$5], [$6])[]dnl
 596 AS_VAR_POPDEF([lb_compile])dnl
 597 ]) # LB_CHECK_COMPILE
 598
 599 #
 600 # LB_CHECK_LINUX_HEADER
 601 #
 602 # Like AC_CHECK_HEADER but checks for a kernel-space header
 603 #
 604 m4_define([LB_CHECK_LINUX_HEADER], [
 605 AS_VAR_PUSHDEF([lb_header], [lb_cv_header_$1])dnl
 606 AC_CACHE_CHECK([for $1], lb_header, [
 607         LB_LINUX_COMPILE_IFELSE([LB_LANG_PROGRAM([@%:@include <$1>])],
 608                 [modules], [test -s build/conftest.o],
 609                 [AS_VAR_SET([lb_header], [yes])],
 610                 [AS_VAR_SET([lb_header], [no])])
 611 ])
 612 AS_VAR_IF([lb_header], [yes], [$2], [$3])[]dnl
 613 AS_VAR_POPDEF([lb_header])dnl
 614 ]) # LB_CHECK_LINUX_HEADER