config/lustre-build-ldiskfs.m4

   1 #
   2 # LDISKFS_LINUX_SERIES
   3 #
   4 AC_DEFUN([LDISKFS_LINUX_SERIES], [
   5 LDISKFS_SERIES=
   6 AC_MSG_CHECKING([which ldiskfs series to use])
   7 AS_IF([test x$RHEL_KERNEL = xyes], [
   8         AS_VERSION_COMPARE([$RHEL_KERNEL_VERSION],[2.6.32-431],[
   9         AS_VERSION_COMPARE([$RHEL_KERNEL_VERSION],[2.6.32-343],[
  10         AS_VERSION_COMPARE([$RHEL_KERNEL_VERSION],[2.6.32],[],
  11         [LDISKFS_SERIES="2.6-rhel6.series"],  [LDISKFS_SERIES="2.6-rhel6.series"])],
  12         [LDISKFS_SERIES="2.6-rhel6.4.series"],[LDISKFS_SERIES="2.6-rhel6.4.series"])],
  13         [LDISKFS_SERIES="2.6-rhel6.5.series"],[LDISKFS_SERIES="2.6-rhel6.5.series"])
  14 ], [test x$SUSE_KERNEL = xyes], [
  15         AS_VERSION_COMPARE([$LINUXRELEASE],[3.0.0],[
  16         AS_VERSION_COMPARE([$LINUXRELEASE],[2.6.32], [],
  17         [LDISKFS_SERIES="2.6-sles11.series"],[LDISKFS_SERIES="2.6-sles11.series"])],
  18         [LDISKFS_SERIES="3.0-sles11.series"],[
  19                 PLEV=$(grep PATCHLEVEL /etc/SuSE-release | sed -e 's/.*= *//')
  20                 case $PLEV in
  21                 2) LDISKFS_SERIES="3.0-sles11.series"
  22                         ;;
  23                 3) LDISKFS_SERIES="3.0-sles11sp3.series"
  24                         ;;
  25                 esac
  26         ])
  27 ])
  28 AS_IF([test -z "$LDISKFS_SERIES"],
  29         [AC_MSG_WARN([Unknown kernel version $LDISKFS_VERSIONRELEASE])])
  30 AC_MSG_RESULT([$LDISKFS_SERIES])
  31 AC_SUBST(LDISKFS_SERIES)
  32 ]) # LDISKFS_LINUX_SERIES
  33
  34 #
  35 # LB_EXT_FREE_BLOCKS_WITH_BUFFER_HEAD
  36 #
  37 # 2.6.32-rc7 ext4_free_blocks requires struct buffer_head
  38 # Note that RHEL6 is pre 2.6.32-rc7 so this check is still needed.
  39 #
  40 AC_DEFUN([LB_EXT_FREE_BLOCKS_WITH_BUFFER_HEAD], [
  41 LB_CHECK_COMPILE([if 'ext4_free_blocks' needs 'struct buffer_head'],
  42 ext4_free_blocks_with_buffer_head, [
  43         #include <linux/fs.h>
  44         #include "$EXT4_SRC_DIR/ext4.h"
  45 ],[
  46         ext4_free_blocks(NULL, NULL, NULL, 0, 0, 0);
  47 ],[
  48         AC_DEFINE(HAVE_EXT_FREE_BLOCK_WITH_BUFFER_HEAD, 1,
  49                 [ext4_free_blocks do not require struct buffer_head])
  50 ])
  51 ]) # LB_EXT_FREE_BLOCKS_WITH_BUFFER_HEAD
  52
  53 #
  54 # LB_EXT_PBLOCK
  55 #
  56 # 2.6.35 renamed ext_pblock to ext4_ext_pblock(ex)
  57 #
  58 AC_DEFUN([LB_EXT_PBLOCK], [
  59 LB_CHECK_COMPILE([if Linux kernel has 'ext_pblock'],
  60 ext_pblock, [
  61         #include <linux/fs.h>
  62         #include "$EXT4_SRC_DIR/ext4_extents.h"
  63 ],[
  64         ext_pblock(NULL);
  65 ],[
  66         AC_DEFINE(HAVE_EXT_PBLOCK, 1, [Linux kernel has ext_pblock])
  67 ])
  68 ]) # LB_EXT_PBLOCK
  69
  70 #
  71 # LDISKFS_AC_PATCH_PROGRAM
  72 #
  73 # Determine which program should be used to apply the patches to
  74 # the ext4 source code to produce the ldiskfs source code.
  75 #
  76 AC_DEFUN([LDISKFS_AC_PATCH_PROGRAM], [
  77         AC_ARG_ENABLE([quilt],
  78                 [AC_HELP_STRING([--disable-quilt],
  79                         [disable use of quilt for ldiskfs])],
  80                 [AS_IF([test "x$enableval" = xno],
  81                         [use_quilt=no],
  82                         [use_quilt=maybe])],
  83                 [use_quilt=maybe]
  84         )
  85
  86         AS_IF([test x$use_quilt = xmaybe], [
  87                 AC_PATH_PROG([quilt_avail], [quilt], [no])
  88                 AS_IF([test x$quilt_avail = xno], [
  89                         use_quilt=no
  90                 ], [
  91                         use_quilt=yes
  92                 ])
  93         ])
  94
  95         AS_IF([test x$use_quilt = xno], [
  96                 AC_PATH_PROG([patch_avail], [patch], [no])
  97                 AS_IF([test x$patch_avail = xno], [
  98                         AC_MSG_ERROR([*** Need "quilt" or "patch" command])
  99                 ])
 100         ])
 101 ]) # LDISKFS_AC_PATCH_PROGRAM
 102
 103 #
 104 # LB_CONFIG_LDISKFS
 105 #
 106 AC_DEFUN([LB_CONFIG_LDISKFS], [
 107 # --with-ldiskfs is deprecated now that ldiskfs is fully merged with lustre.
 108 # However we continue to support this option through Lustre 2.5.
 109 AC_ARG_WITH([ldiskfs],
 110         [],
 111         [AC_MSG_WARN([--with-ldiskfs is deprecated, please use --enable-ldiskfs])
 112         AS_IF([test x$withval != xyes -a x$withval != xno],
 113                 [AC_MSG_ERROR([
 114
 115 The ldiskfs option is deprecated,
 116 and no longer supports paths to external ldiskfs source
 117 ])])
 118 ])
 119
 120 AC_ARG_ENABLE([ldiskfs],
 121         [AS_HELP_STRING([--disable-ldiskfs],
 122                 [disable ldiskfs osd (default is enable)])],
 123         [AS_IF([test x$enable_ldiskfs != xyes -a x$enable_ldiskfs != xno],
 124                 [AC_MSG_ERROR([ldiskfs valid options are "yes" or "no"])])],
 125         [AS_IF([test "${with_ldiskfs+set}" = set],
 126                 [enable_ldiskfs=$with_ldiskfs],
 127                 [enable_ldiskfs=maybe])
 128 ])
 129
 130 AS_IF([test x$enable_server = xno],
 131         [AS_CASE([$enable_ldiskfs],
 132                 [maybe], [enable_ldiskfs=no],
 133                 [yes], [AC_MSG_ERROR([cannot build ldiskfs when servers are disabled])]
 134         )])
 135
 136 AS_IF([test x$enable_ldiskfs != xno],[
 137         # In the future, we chould change enable_ldiskfs from maybe to
 138         # either yes or no based on additional tests, e.g.  whether a patch
 139         # set is available for the detected kernel.  For now, we just always
 140         # set it to "yes".
 141         AS_IF([test x$enable_ldiskfs = xmaybe], [enable_ldiskfs=yes])
 142
 143         LDISKFS_LINUX_SERIES
 144         LDISKFS_AC_PATCH_PROGRAM
 145         LB_EXT_FREE_BLOCKS_WITH_BUFFER_HEAD
 146         LB_EXT_PBLOCK
 147         AC_DEFINE(CONFIG_LDISKFS_FS_POSIX_ACL, 1, [posix acls for ldiskfs])
 148         AC_DEFINE(CONFIG_LDISKFS_FS_SECURITY, 1, [fs security for ldiskfs])
 149         AC_DEFINE(CONFIG_LDISKFS_FS_XATTR, 1, [extened attributes for ldiskfs])
 150         AC_DEFINE(CONFIG_LDISKFS_FS_RW, 1, [enable rw access for ldiskfs])
 151         AC_SUBST(LDISKFS_SUBDIR, ldiskfs)
 152         AC_DEFINE(HAVE_LDISKFS_OSD, 1, Enable ldiskfs osd)
 153 ])
 154
 155 AC_MSG_CHECKING([whether to build ldiskfs])
 156 AC_MSG_RESULT([$enable_ldiskfs])
 157
 158 AM_CONDITIONAL([LDISKFS_ENABLED], [test x$enable_ldiskfs = xyes])
 159 ]) # LB_CONFIG_LDISKFS
 160
 161 #
 162 # LB_VALIDATE_EXT4_SRC_DIR
 163 #
 164 # Spot check the existance of several source files common to ext4.
 165 # Detecting this at configure time allows us to avoid a potential build
 166 # failure and provide a useful error message to explain what is wrong.
 167 #
 168 AC_DEFUN([LB_VALIDATE_EXT4_SRC_DIR], [
 169 enable_ldiskfs_build="no"
 170 AS_IF([test -n "$EXT4_SRC_DIR"], [
 171         enable_ldiskfs_build="yes"
 172         LB_CHECK_FILE([$EXT4_SRC_DIR/dir.c], [], [
 173                 enable_ldiskfs_build="no"
 174                 AC_MSG_WARN([ext4 must exist for ldiskfs build])
 175         ])
 176         LB_CHECK_FILE([$EXT4_SRC_DIR/file.c], [], [
 177                 enable_ldiskfs_build="no"
 178                 AC_MSG_WARN([ext4 must exist for ldiskfs build])
 179         ])
 180         LB_CHECK_FILE([$EXT4_SRC_DIR/inode.c], [], [
 181                 enable_ldiskfs_build="no"
 182                 AC_MSG_WARN([ext4 must exist for ldiskfs build])
 183         ])
 184         LB_CHECK_FILE([$EXT4_SRC_DIR/super.c], [], [
 185                 enable_ldiskfs_build="no"
 186                 AC_MSG_WARN([ext4 must exist for ldiskfs build])
 187         ])
 188 ])
 189
 190 AS_IF([test "x$enable_ldiskfs_build" = xno], [
 191         enable_ldiskfs="no"
 192
 193         AC_MSG_WARN([
 194
 195 Disabling ldiskfs support because complete ext4 source does not exist.
 196
 197 If you are building using kernel-devel packages and require ldiskfs
 198 server support then ensure that the matching kernel-debuginfo-common
 199 and kernel-debuginfo-common-<arch> packages are installed.
 200 ])
 201 ])
 202 ]) # LB_VALIDATE_EXT4_SRC_DIR
 203
 204 #
 205 # LB_EXT4_SRC_DIR
 206 #
 207 # Determine the location of the ext4 source code.  It it required
 208 # for several configure tests and to build ldiskfs.
 209 #
 210 AC_DEFUN([LB_EXT4_SRC_DIR], [
 211 AC_MSG_CHECKING([ext4 source directory])
 212 # Kernel ext source located with devel headers
 213 linux_src=$LINUX
 214 AS_IF([test -e "$linux_src/fs/ext4/super.c"], [
 215         EXT4_SRC_DIR="$linux_src/fs/ext4"
 216 ], [
 217         # Kernel ext source provided by kernel-debuginfo-common package
 218         linux_src=$(ls -1d /usr/src/debug/*/linux-$LINUXRELEASE \
 219                 2>/dev/null | tail -1)
 220         AS_IF([test -e "$linux_src/fs/ext4/super.c"],
 221                 [EXT4_SRC_DIR="$linux_src/fs/ext4"],
 222                 [EXT4_SRC_DIR=""])
 223 ])
 224 AC_MSG_RESULT([$EXT4_SRC_DIR])
 225 AC_SUBST(EXT4_SRC_DIR)
 226
 227 LB_VALIDATE_EXT4_SRC_DIR
 228 ]) # LB_EXT4_SRC_DIR
 229
 230 #
 231 # LB_DEFINE_E2FSPROGS_NAMES
 232 #
 233 # Enable the use of alternate naming of ldiskfs-enabled e2fsprogs package.
 234 #
 235 AC_DEFUN([LB_DEFINE_E2FSPROGS_NAMES], [
 236 AC_MSG_CHECKING([whether to use alternate names for e2fsprogs])
 237 AC_ARG_WITH([ldiskfsprogs],
 238         AC_HELP_STRING([--with-ldiskfsprogs],
 239                 [use alternate names for ldiskfs-enabled e2fsprogs]),
 240         [], [withval="no"])
 241
 242 AS_IF([test "x$withval" = xyes], [
 243         AC_MSG_RESULT([enabled])
 244         AC_DEFINE(HAVE_LDISKFSPROGS, 1, [enable use of ldiskfsprogs package])
 245         E2FSPROGS="ldiskfsprogs"
 246         MKE2FS="mkfs.ldiskfs"
 247         DEBUGFS="debugfs.ldiskfs"
 248         TUNE2FS="tunefs.ldiskfs"
 249         E2LABEL="label.ldiskfs"
 250         DUMPE2FS="dumpfs.ldiskfs"
 251         E2FSCK="fsck.ldiskfs"
 252         PFSCK="pfsck.ldiskfs"
 253 ], [
 254         AC_MSG_RESULT([disabled])
 255         E2FSPROGS="e2fsprogs"
 256         MKE2FS="mke2fs"
 257         DEBUGFS="debugfs"
 258         TUNE2FS="tune2fs"
 259         E2LABEL="e2label"
 260         DUMPE2FS="dumpe2fs"
 261         E2FSCK="e2fsck"
 262         PFSCK="fsck"
 263 ])
 264
 265 AC_DEFINE_UNQUOTED(E2FSPROGS, "$E2FSPROGS", [name of ldiskfs e2fsprogs package])
 266 AC_DEFINE_UNQUOTED(MKE2FS, "$MKE2FS", [name of ldiskfs mkfs program])
 267 AC_DEFINE_UNQUOTED(DEBUGFS, "$DEBUGFS", [name of ldiskfs debug program])
 268 AC_DEFINE_UNQUOTED(TUNE2FS, "$TUNE2FS", [name of ldiskfs tune program])
 269 AC_DEFINE_UNQUOTED(E2LABEL, "$E2LABEL", [name of ldiskfs label program])
 270 AC_DEFINE_UNQUOTED(DUMPE2FS,"$DUMPE2FS", [name of ldiskfs dump program])
 271 AC_DEFINE_UNQUOTED(E2FSCK, "$E2FSCK", [name of ldiskfs fsck program])
 272 AC_DEFINE_UNQUOTED(PFSCK, "$PFSCK", [name of parallel fsck program])
 273
 274 AC_SUBST([E2FSPROGS], [$E2FSPROGS])
 275 AC_SUBST([MKE2FS], [$MKE2FS])
 276 AC_SUBST([DEBUGFS], [$DEBUGFS])
 277 AC_SUBST([TUNE2FS], [$TUNE2FS])
 278 AC_SUBST([E2LABEL], [$E2LABEL])
 279 AC_SUBST([DUMPE2FS], [$DUMPE2FS])
 280 AC_SUBST([E2FSCK], [$E2FSCK])
 281 AC_SUBST([PFSCK], [$PFSCK])
 282 ]) # LB_DEFINE_E2FSPROGS_NAMES