config/lustre-build-ldiskfs.m4

   1 AC_DEFUN([LDISKFS_LINUX_SERIES],
   2 [
   3 LDISKFS_SERIES=
   4 AC_MSG_CHECKING([which ldiskfs series to use])
   5
   6 SER=
   7 AS_IF([test x$RHEL_KERNEL = xyes], [
   8         AS_VERSION_COMPARE([$RHEL_KERNEL_VERSION],[2.6.32-431],[
   9         AS_VERSION_COMPARE([$RHEL_KERNEL_VERSION],[2.6.32-343],[
  10         AS_VERSION_COMPARE([$RHEL_KERNEL_VERSION],[2.6.32],[],
  11         [SER="2.6-rhel6.series"],[SER="2.6-rhel6.series"])],
  12         [SER="2.6-rhel6.4.series"],[SER="2.6-rhel6.4.series"])],
  13         [SER="2.6-rhel6.5.series"],[SER="2.6-rhel6.5.series"])
  14 ], [test x$SUSE_KERNEL = xyes], [
  15         AS_VERSION_COMPARE([$LINUXRELEASE],[3.0.0],[
  16         AS_VERSION_COMPARE([$LINUXRELEASE],[2.6.32],[],
  17         [SER="2.6-sles11.series"],[SER="2.6-sles11.series"])],
  18         [SER="3.0-sles11.series"],[
  19                 PLEV=$(grep PATCHLEVEL /etc/SuSE-release | sed -e 's/.*= *//')
  20                 case $PLEV in
  21                 2) SER="3.0-sles11.series"
  22                         ;;
  23                 3) SER="3.0-sles11sp3.series"
  24                         ;;
  25                 esac
  26         ])
  27 ])
  28 LDISKFS_SERIES=$SER
  29
  30 AS_IF([test -z "$LDISKFS_SERIES"],
  31         [AC_MSG_WARN([Unknown kernel version $LDISKFS_VERSIONRELEASE])])
  32 AC_MSG_RESULT([$LDISKFS_SERIES])
  33
  34 AC_SUBST(LDISKFS_SERIES)
  35 ])
  36
  37 #
  38 # 2.6.32-rc7 ext4_free_blocks requires struct buffer_head
  39 #
  40 AC_DEFUN([LB_EXT_FREE_BLOCKS_WITH_BUFFER_HEAD],
  41 [AC_MSG_CHECKING([if ext4_free_blocks needs struct buffer_head])
  42  LB_LINUX_TRY_COMPILE([
  43         #include <linux/fs.h>
  44         #include "$EXT4_SRC_DIR/ext4.h"
  45 ],[
  46         ext4_free_blocks(NULL, NULL, NULL, 0, 0, 0);
  47 ],[
  48         AC_MSG_RESULT([yes])
  49         AC_DEFINE(HAVE_EXT_FREE_BLOCK_WITH_BUFFER_HEAD, 1,
  50                   [ext4_free_blocks do not require struct buffer_head])
  51 ],[
  52         AC_MSG_RESULT([no])
  53 ])
  54 ])
  55
  56 #
  57 # 2.6.35 renamed ext_pblock to ext4_ext_pblock(ex)
  58 #
  59 AC_DEFUN([LB_EXT_PBLOCK],
  60 [AC_MSG_CHECKING([if kernel has ext_pblocks])
  61  LB_LINUX_TRY_COMPILE([
  62         #include <linux/fs.h>
  63         #include "$EXT4_SRC_DIR/ext4_extents.h"
  64 ],[
  65         ext_pblock(NULL);
  66 ],[
  67         AC_MSG_RESULT([yes])
  68         AC_DEFINE(HAVE_EXT_PBLOCK, 1,
  69                   [kernel has ext_pblocks])
  70 ],[
  71         AC_MSG_RESULT([no])
  72 ])
  73 ])
  74
  75 #
  76 # LDISKFS_AC_PATCH_PROGRAM
  77 #
  78 # Determine which program should be used to apply the patches to
  79 # the ext4 source code to produce the ldiskfs source code.
  80 #
  81 AC_DEFUN([LDISKFS_AC_PATCH_PROGRAM], [
  82         AC_ARG_ENABLE([quilt],
  83                 [AC_HELP_STRING([--disable-quilt],
  84                         [disable use of quilt for ldiskfs])],
  85                 [AS_IF([test "x$enableval" = xno],
  86                         [use_quilt=no],
  87                         [use_quilt=maybe])],
  88                 [use_quilt=maybe]
  89         )
  90
  91         AS_IF([test x$use_quilt = xmaybe], [
  92                 AC_PATH_PROG([quilt_avail], [quilt], [no])
  93                 AS_IF([test x$quilt_avail = xno], [
  94                         use_quilt=no
  95                 ], [
  96                         use_quilt=yes
  97                 ])
  98         ])
  99
 100         AS_IF([test x$use_quilt = xno], [
 101                 AC_PATH_PROG([patch_avail], [patch], [no])
 102                 AS_IF([test x$patch_avail = xno], [
 103                         AC_MSG_ERROR([*** Need "quilt" or "patch" command])
 104                 ])
 105         ])
 106 ])
 107
 108 #
 109 # LB_CONDITIONAL_LDISKFS
 110 #
 111 AC_DEFUN([LB_CONFIG_LDISKFS],
 112 [
 113 # --with-ldiskfs is deprecated now that ldiskfs is fully merged with lustre.
 114 # However we continue to support this option through Lustre 2.5.
 115 AC_ARG_WITH([ldiskfs],
 116         [],
 117         [AC_MSG_WARN([--with-ldiskfs is deprecated, please use --enable-ldiskfs])
 118         AS_IF([test x$withval != xyes -a x$withval != xno],
 119                 [AC_MSG_ERROR([the ldiskfs option is deprecated, and
 120                         no longer supports paths to external ldiskfs source])])
 121         ]
 122 )
 123
 124 AC_ARG_ENABLE([ldiskfs],
 125         [AS_HELP_STRING([--disable-ldiskfs],
 126                 [disable ldiskfs osd (default is enable)])],
 127         [AS_IF([test x$enable_ldiskfs != xyes -a x$enable_ldiskfs != xno],
 128                 [AC_MSG_ERROR([ldiskfs valid options are "yes" or "no"])])],
 129         [AS_IF([test "${with_ldiskfs+set}" = set],
 130                 [enable_ldiskfs=$with_ldiskfs],
 131                 [enable_ldiskfs=maybe])
 132         ]
 133 )
 134
 135 AS_IF([test x$enable_server = xno],
 136         [AS_CASE([$enable_ldiskfs],
 137                 [maybe], [enable_ldiskfs=no],
 138                 [yes], [AC_MSG_ERROR([cannot build ldiskfs when servers are disabled])]
 139         )]
 140 )
 141
 142 AS_IF([test x$enable_ldiskfs != xno],[
 143         # In the future, we chould change enable_ldiskfs from maybe to
 144         # either yes or no based on additional tests, e.g.  whether a patch
 145         # set is available for the detected kernel.  For now, we just always
 146         # set it to "yes".
 147         AS_IF([test x$enable_ldiskfs = xmaybe], [enable_ldiskfs=yes])
 148
 149         LDISKFS_LINUX_SERIES
 150         LDISKFS_AC_PATCH_PROGRAM
 151         LB_EXT_FREE_BLOCKS_WITH_BUFFER_HEAD
 152         LB_EXT_PBLOCK
 153         AC_DEFINE(CONFIG_LDISKFS_FS_POSIX_ACL, 1, [posix acls for ldiskfs])
 154         AC_DEFINE(CONFIG_LDISKFS_FS_SECURITY, 1, [fs security for ldiskfs])
 155         AC_DEFINE(CONFIG_LDISKFS_FS_XATTR, 1, [extened attributes for ldiskfs])
 156         AC_DEFINE(CONFIG_LDISKFS_FS_RW, 1, [enable rw access for ldiskfs])
 157         AC_SUBST(LDISKFS_SUBDIR, ldiskfs)
 158         AC_DEFINE(HAVE_LDISKFS_OSD, 1, Enable ldiskfs osd)
 159 ])
 160
 161 AC_MSG_CHECKING([whether to build ldiskfs])
 162 AC_MSG_RESULT([$enable_ldiskfs])
 163
 164 AM_CONDITIONAL([LDISKFS_ENABLED], [test x$enable_ldiskfs = xyes])
 165 ])
 166
 167 #
 168 # LB_VALIDATE_EXT4_SRC_DIR
 169 #
 170 # Spot check the existance of several source files common to ext4.
 171 # Detecting this at configure time allows us to avoid a potential build
 172 # failure and provide a useful error message to explain what is wrong.
 173 #
 174 AC_DEFUN([LB_VALIDATE_EXT4_SRC_DIR],
 175 [
 176 if test x$EXT4_SRC_DIR = x; then
 177         enable_ldiskfs_build='no'
 178 else
 179         LB_CHECK_FILE([$EXT4_SRC_DIR/dir.c], [], [
 180                 enable_ldiskfs_build='no'
 181                 AC_MSG_WARN([ext4 must exist for ldiskfs build])])
 182         LB_CHECK_FILE([$EXT4_SRC_DIR/file.c], [], [
 183                 enable_ldiskfs_build='no'
 184                 AC_MSG_WARN([ext4 must exist for ldiskfs build])])
 185         LB_CHECK_FILE([$EXT4_SRC_DIR/inode.c], [], [
 186                 enable_ldiskfs_build='no'
 187                 AC_MSG_WARN([ext4 must exist for ldiskfs build])])
 188         LB_CHECK_FILE([$EXT4_SRC_DIR/super.c], [], [
 189                 enable_ldiskfs_build='no'
 190                 AC_MSG_WARN([ext4 must exist for ldiskfs build])])
 191 fi
 192
 193 if test x$enable_ldiskfs_build = xno; then
 194         enable_ldiskfs='no'
 195
 196         AC_MSG_WARN([
 197
 198 Disabling ldiskfs support because complete ext4 source does not exist.
 199
 200 If you are building using kernel-devel packages and require ldiskfs
 201 server support then ensure that the matching kernel-debuginfo-common
 202 and kernel-debuginfo-common-<arch> packages are installed.
 203
 204 ])
 205
 206 fi
 207 ])
 208
 209 #
 210 # LB_EXT4_SRC_DIR
 211 #
 212 # Determine the location of the ext4 source code.  It it required
 213 # for several configure tests and to build ldiskfs.
 214 #
 215 AC_DEFUN([LB_EXT4_SRC_DIR],
 216 [
 217 # Kernel ext source located with devel headers
 218 linux_src=$LINUX
 219 if test -e "$linux_src/fs/ext4/super.c"; then
 220         EXT4_SRC_DIR=$linux_src/fs/ext4
 221 else
 222         # Kernel ext source provided by kernel-debuginfo-common package
 223         linux_src=$(ls -1d /usr/src/debug/*/linux-$LINUXRELEASE \
 224                 2>/dev/null | tail -1)
 225         if test -e "$linux_src/fs/ext4/super.c"; then
 226                 EXT4_SRC_DIR=$linux_src/fs/ext4
 227         else
 228                 EXT4_SRC_DIR=
 229         fi
 230 fi
 231
 232 AC_MSG_CHECKING([ext4 source directory])
 233 AC_MSG_RESULT([$EXT4_SRC_DIR])
 234 AC_SUBST(EXT4_SRC_DIR)
 235
 236 LB_VALIDATE_EXT4_SRC_DIR
 237 ])
 238
 239 #
 240 # LB_DEFINE_E2FSPROGS_NAMES
 241 #
 242 # Enable the use of alternate naming of ldiskfs-enabled e2fsprogs package.
 243 #
 244 AC_DEFUN([LB_DEFINE_E2FSPROGS_NAMES],
 245 [
 246 AC_ARG_WITH([ldiskfsprogs],
 247         AC_HELP_STRING([--with-ldiskfsprogs],
 248                        [use alternate names for ldiskfs-enabled e2fsprogs]),
 249         [],[withval='no'])
 250
 251 AC_MSG_CHECKING([whether to use alternate names for e2fsprogs])
 252 if test x$withval = xyes ; then
 253         AC_DEFINE(HAVE_LDISKFSPROGS, 1, [enable use of ldiskfsprogs package])
 254         E2FSPROGS="ldiskfsprogs"
 255         MKE2FS="mkfs.ldiskfs"
 256         DEBUGFS="debugfs.ldiskfs"
 257         TUNE2FS="tunefs.ldiskfs"
 258         E2LABEL="label.ldiskfs"
 259         DUMPE2FS="dumpfs.ldiskfs"
 260         E2FSCK="fsck.ldiskfs"
 261         PFSCK="pfsck.ldiskfs"
 262         AC_MSG_RESULT([enabled])
 263 else
 264         E2FSPROGS="e2fsprogs"
 265         MKE2FS="mke2fs"
 266         DEBUGFS="debugfs"
 267         TUNE2FS="tune2fs"
 268         E2LABEL="e2label"
 269         DUMPE2FS="dumpe2fs"
 270         E2FSCK="e2fsck"
 271         PFSCK="fsck"
 272         AC_MSG_RESULT([disabled])
 273 fi
 274
 275 AC_DEFINE_UNQUOTED(E2FSPROGS, "$E2FSPROGS", [name of ldiskfs e2fsprogs package])
 276 AC_DEFINE_UNQUOTED(MKE2FS, "$MKE2FS", [name of ldiskfs mkfs program])
 277 AC_DEFINE_UNQUOTED(DEBUGFS, "$DEBUGFS", [name of ldiskfs debug program])
 278 AC_DEFINE_UNQUOTED(TUNE2FS, "$TUNE2FS", [name of ldiskfs tune program])
 279 AC_DEFINE_UNQUOTED(E2LABEL, "$E2LABEL", [name of ldiskfs label program])
 280 AC_DEFINE_UNQUOTED(DUMPE2FS,"$DUMPE2FS", [name of ldiskfs dump program])
 281 AC_DEFINE_UNQUOTED(E2FSCK, "$E2FSCK", [name of ldiskfs fsck program])
 282 AC_DEFINE_UNQUOTED(PFSCK, "$PFSCK", [name of parallel fsck program])
 283
 284 AC_SUBST([E2FSPROGS], [$E2FSPROGS])
 285 AC_SUBST([MKE2FS], [$MKE2FS])
 286 AC_SUBST([DEBUGFS], [$DEBUGFS])
 287 AC_SUBST([TUNE2FS], [$TUNE2FS])
 288 AC_SUBST([E2LABEL], [$E2LABEL])
 289 AC_SUBST([DUMPE2FS], [$DUMPE2FS])
 290 AC_SUBST([E2FSCK], [$E2FSCK])
 291 AC_SUBST([PFSCK], [$PFSCK])
 292 ])