config/lustre-build-ldiskfs.m4

   1 #
   2 # LDISKFS_LINUX_SERIES
   3 #
   4 AC_DEFUN([LDISKFS_LINUX_SERIES], [
   5 AC_MSG_CHECKING([which ldiskfs series to use])
   6 case x$LDISKFS_SERIES in
   7         x)                      # not set
   8                 ;;
   9         *.series)               # set externally
  10                 ;;
  11         *) LDISKFS_SERIES=
  12 esac
  13 AS_IF([test -z "$LDISKFS_SERIES"], [
  14 AS_IF([test x$RHEL_KERNEL = xyes], [
  15         case $RHEL_RELEASE_NO in
  16         80)     LDISKFS_SERIES="4.18-rhel8.series"      ;;
  17         77)     LDISKFS_SERIES="3.10-rhel7.7.series"    ;;
  18         76)     LDISKFS_SERIES="3.10-rhel7.6.series"    ;;
  19         75)     LDISKFS_SERIES="3.10-rhel7.5.series"    ;;
  20         74)     LDISKFS_SERIES="3.10-rhel7.4.series"    ;;
  21         73)     LDISKFS_SERIES="3.10-rhel7.3.series"    ;;
  22         72)     LDISKFS_SERIES="3.10-rhel7.2.series"    ;;
  23         71)     LDISKFS_SERIES="3.10-rhel7.series"      ;;
  24         69)     LDISKFS_SERIES="2.6-rhel6.9.series"     ;;
  25         68)     LDISKFS_SERIES="2.6-rhel6.8.series"     ;;
  26         67)     LDISKFS_SERIES="2.6-rhel6.7.series"     ;;
  27         66)     LDISKFS_SERIES="2.6-rhel6.6.series"     ;;
  28         65)     LDISKFS_SERIES="2.6-rhel6.5.series"     ;;
  29         64)     LDISKFS_SERIES="2.6-rhel6.4.series"     ;;
  30         6[0-3]) LDISKFS_SERIES="2.6-rhel6.series"       ;;
  31         esac
  32 ], [test x$SUSE_KERNEL = xyes], [
  33         AS_VERSION_COMPARE([$LINUXRELEASE],[4.4.82],[
  34         AS_VERSION_COMPARE([$LINUXRELEASE],[4.4.0],[
  35         AS_VERSION_COMPARE([$LINUXRELEASE],[3.12.0],[
  36         AS_VERSION_COMPARE([$LINUXRELEASE],[3.0.0],[
  37         AS_VERSION_COMPARE([$LINUXRELEASE],[2.6.32], [],
  38         [LDISKFS_SERIES="2.6-sles11.series"],[LDISKFS_SERIES="2.6-sles11.series"])],
  39         [LDISKFS_SERIES="3.0-sles11.series"],[
  40                 PLEV=$(grep PATCHLEVEL /etc/SuSE-release | sed -e 's/.*= *//')
  41                 case $PLEV in
  42                 2) LDISKFS_SERIES="3.0-sles11.series"
  43                         ;;
  44                 3) LDISKFS_SERIES="3.0-sles11sp3.series"
  45                         ;;
  46                 4) LDISKFS_SERIES="3.0-sles11sp4.series"
  47                         ;;
  48                 esac
  49         ])],[LDISKFS_SERIES="3.12-sles12.series"],[
  50                 PLEV=$(grep PATCHLEVEL /etc/SuSE-release | sed -e 's/.*= *//')
  51                 case $PLEV in
  52                 1) LDISKFS_SERIES="3.12-sles12sp1.series"
  53                         ;;
  54                 *) LDISKFS_SERIES="3.12-sles12.series"
  55                         ;;
  56                 esac
  57         ])],[LDISKFS_SERIES="4.4-sles12sp2.series"],
  58             [LDISKFS_SERIES="4.4-sles12sp2.series"]
  59         )], [LDISKFS_SERIES="4.4-sles12sp3.series"],
  60             [LDISKFS_SERIES="4.4-sles12sp3.series"])
  61 ], [test x$UBUNTU_KERNEL = xyes], [
  62         AS_VERSION_COMPARE([$LINUXRELEASE],[5.0.0],[
  63         AS_VERSION_COMPARE([$LINUXRELEASE],[4.15.0],[
  64         AS_VERSION_COMPARE([$LINUXRELEASE],[4.4.0], [],
  65         [
  66                 KPLEV=$(echo $LINUXRELEASE | sed -n 's/.*-\([0-9]\+\).*/\1/p')
  67                 AS_IF(
  68                         [test -z "$KPLEV"], [
  69                                 AC_MSG_WARN([Failed to determine Kernel patch level. Assume latest.])
  70                                 LDISKFS_SERIES="4.4.0-73-ubuntu14+16.series"
  71                         ],
  72                         [test $KPLEV -ge 73], [LDISKFS_SERIES="4.4.0-73-ubuntu14+16.series"],
  73                         [test $KPLEV -ge 62], [LDISKFS_SERIES="4.4.0-62-ubuntu14+16.series"],
  74                         [test $KPLEV -ge 49], [LDISKFS_SERIES="4.4.0-49-ubuntu14+16.series"],
  75                         [LDISKFS_SERIES="4.4.0-45-ubuntu14+16.series"]
  76                 )
  77         ],
  78         [LDISKFS_SERIES="4.4.0-73-ubuntu14+16.series"])],
  79         [
  80                 KPLEV=$(echo $LINUXRELEASE | sed -n 's/.*-\([0-9]\+\).*/\1/p')
  81                 AS_IF(
  82                         [test -z "$KPLEV"], [
  83                                 AC_MSG_WARN([Failed to determine Kernel patch level. Assume latest.])
  84                                 LDISKFS_SERIES="4.15.0-24-ubuntu18.series"
  85                         ],
  86                         [test $KPLEV -ge 24], [LDISKFS_SERIES="4.15.0-24-ubuntu18.series"],
  87                         [test $KPLEV -ge 20], [LDISKFS_SERIES="4.15.0-20-ubuntu18.series"]
  88                 )
  89         ],
  90         [LDISKFS_SERIES="4.15.0-24-ubuntu18.series"])],
  91         [LDISKFS_SERIES="5.0.0-13-ubuntu19.series"],
  92         [LDISKFS_SERIES="5.0.0-13-ubuntu19.series"])
  93 ])
  94 ])
  95 AS_IF([test -z "$LDISKFS_SERIES"],
  96         [AC_MSG_RESULT([failed to identify series])],
  97         [AC_MSG_RESULT([$LDISKFS_SERIES])])
  98 AC_SUBST(LDISKFS_SERIES)
  99 ]) # LDISKFS_LINUX_SERIES
 100
 101 #
 102 # LB_EXT_FREE_BLOCKS_WITH_BUFFER_HEAD
 103 #
 104 # 2.6.32-rc7 ext4_free_blocks requires struct buffer_head
 105 # Note that RHEL6 is pre 2.6.32-rc7 so this check is still needed.
 106 #
 107 AC_DEFUN([LB_EXT_FREE_BLOCKS_WITH_BUFFER_HEAD], [
 108 LB_CHECK_COMPILE([if 'ext4_free_blocks' needs 'struct buffer_head'],
 109 ext4_free_blocks_with_buffer_head, [
 110         #include <linux/fs.h>
 111         #include "$EXT4_SRC_DIR/ext4.h"
 112 ],[
 113         ext4_free_blocks(NULL, NULL, NULL, 0, 0, 0);
 114 ],[
 115         AC_DEFINE(HAVE_EXT_FREE_BLOCK_WITH_BUFFER_HEAD, 1,
 116                 [ext4_free_blocks do not require struct buffer_head])
 117 ])
 118 ]) # LB_EXT_FREE_BLOCKS_WITH_BUFFER_HEAD
 119
 120 #
 121 # LB_EXT4_JOURNAL_START_3ARGS
 122 #
 123 # 3.9 added a type argument to ext4_journal_start and friends
 124 #
 125 AC_DEFUN([LB_EXT4_JOURNAL_START_3ARGS], [
 126 LB_CHECK_COMPILE([if ext4_journal_start takes 3 arguments],
 127 ext4_journal_start, [
 128         #include <linux/fs.h>
 129         #include "$EXT4_SRC_DIR/ext4_jbd2.h"
 130 ],[
 131         ext4_journal_start(NULL, 0, 0);
 132 ],[
 133         AC_DEFINE(JOURNAL_START_HAS_3ARGS, 1, [ext4_journal_start takes 3 arguments])
 134 ])
 135 ]) # LB_EXT4_JOURNAL_START_3ARGS
 136
 137 #
 138 # LB_EXT4_BREAD_4ARGS
 139 #
 140 # 3.18 ext4_bread has 4 arguments
 141 #
 142 AC_DEFUN([LB_EXT4_BREAD_4ARGS], [
 143 LB_CHECK_COMPILE([if ext4_bread takes 4 arguments],
 144 ext4_bread, [
 145         #include <linux/fs.h>
 146         #include "$EXT4_SRC_DIR/ext4.h"
 147 ],[
 148         ext4_bread(NULL, NULL, 0, 0);
 149 ],[
 150         AC_DEFINE(HAVE_EXT4_BREAD_4ARGS, 1, [ext4_bread takes 4 arguments])
 151 ])
 152 ]) # LB_EXT4_BREAD_4ARGS
 153
 154 #
 155 # LB_EXT4_HAVE_INFO_DQUOT
 156 #
 157 # in linux 4.4 i_dqout is in ext4_inode_info, not in struct inode
 158 #
 159 AC_DEFUN([LB_EXT4_HAVE_INFO_DQUOT], [
 160 LB_CHECK_COMPILE([if i_dquot is in ext4_inode_info],
 161 ext4_info_dquot, [
 162         #include <linux/fs.h>
 163         #include <linux/quota.h>
 164         #include "$EXT4_SRC_DIR/ext4.h"
 165 ],[
 166         struct ext4_inode_info in;
 167         struct dquot *dq;
 168
 169         dq = in.i_dquot[0];
 170 ],[
 171         AC_DEFINE(HAVE_EXT4_INFO_DQUOT, 1, [i_dquot is in ext4_inode_info])
 172 ])
 173 ]) # LB_EXT4_HAVE_INFO_DQUOT
 174
 175 #
 176 # LB_EXT4_HAVE_I_CRYPT_INFO
 177 #
 178 # in linux 4.8 i_crypt_info moved from ext4_inode_info to struct inode
 179 #
 180 # Determine if we need to enable CONFIG_LDISKFS_FS_ENCRYPTION.
 181 # If we have i_crypt_info in ext4_inode_info, the config option
 182 # should be enabled to make the ldiskfs module compilation happy.
 183 # Otherwise i_crypy_info is in struct inode, we need to check kernel
 184 # config option to determine that.
 185 #
 186 AC_DEFUN([LB_EXT4_HAVE_I_CRYPT_INFO], [
 187 LB_CHECK_COMPILE([if i_crypt_info is in ext4_inode_info],
 188 ext4_i_crypt_info, [
 189         #define CONFIG_EXT4_FS_ENCRYPTION 1
 190         #include <linux/fs.h>
 191         #include "$EXT4_SRC_DIR/ext4.h"
 192 ],[
 193         struct ext4_inode_info in;
 194
 195         in.i_crypt_info = NULL;
 196 ],[
 197         AC_DEFINE(
 198                 CONFIG_LDISKFS_FS_ENCRYPTION, 1,
 199                 [enable encryption for ldiskfs]
 200         )
 201 ],[
 202         LB_CHECK_CONFIG([EXT4_FS_ENCRYPTION],[
 203                 AC_DEFINE(
 204                         CONFIG_LDISKFS_FS_ENCRYPTION, 1,
 205                         [enable encryption for ldiskfs]
 206                 )
 207         ])
 208 ])
 209 ]) # LB_EXT4_HAVE_I_CRYPT_INFO
 210
 211 #
 212 # LB_LDISKFS_IGET_HAS_FLAGS_ARG
 213 #
 214 # kernel 4.19 commit 8a363970d1dc38c4ec4ad575c862f776f468d057
 215 # ext4_iget changed to a macro with 3 args was function with 2 args
 216 #
 217 AC_DEFUN([LB_LDISKFS_IGET_HAS_FLAGS_ARG], [
 218 tmp_flags="$EXTRA_KCFLAGS"
 219 EXTRA_KCFLAGS="-Werror"
 220 LB_CHECK_COMPILE([if ldiskfs_iget takes a flags argument],
 221 ext4_iget_3args, [
 222         #include <linux/fs.h>
 223         #include "$EXT4_SRC_DIR/ext4.h"
 224 ],[
 225         int f = EXT4_IGET_SPECIAL;
 226         (void)f;
 227 ],[
 228         AC_DEFINE(HAVE_LDISKFS_IGET_WITH_FLAGS, 1,
 229                 [if ldiskfs_iget takes a flags argument])
 230 ])
 231 EXTRA_KCFLAGS="$tmp_flags"
 232 ]) # LB_LDISKFS_IGET_HAS_FLAGS_ARG
 233
 234 #
 235 # LDISKFS_AC_PATCH_PROGRAM
 236 #
 237 # Determine which program should be used to apply the patches to
 238 # the ext4 source code to produce the ldiskfs source code.
 239 #
 240 AC_DEFUN([LDISKFS_AC_PATCH_PROGRAM], [
 241         AC_ARG_ENABLE([quilt],
 242                 [AC_HELP_STRING([--disable-quilt],
 243                         [disable use of quilt for ldiskfs])],
 244                 [AS_IF([test "x$enableval" = xno],
 245                         [use_quilt=no],
 246                         [use_quilt=maybe])],
 247                 [use_quilt=maybe]
 248         )
 249
 250         AS_IF([test x$use_quilt = xmaybe], [
 251                 AC_PATH_PROG([quilt_avail], [quilt], [no])
 252                 AS_IF([test x$quilt_avail = xno], [
 253                         use_quilt=no
 254                 ], [
 255                         use_quilt=yes
 256                 ])
 257         ])
 258
 259         AS_IF([test x$use_quilt = xno], [
 260                 AC_PATH_PROG([patch_avail], [patch], [no])
 261                 AS_IF([test x$patch_avail = xno], [
 262                         AC_MSG_ERROR([*** Need "quilt" or "patch" command])
 263                 ])
 264         ])
 265 ]) # LDISKFS_AC_PATCH_PROGRAM
 266
 267 #
 268 # LB_HAVE_BVEC_ITER_ALL
 269 #
 270 # kernel 5.1 commit 6dc4f100c175dd0511ae8674786e7c9006cdfbfa
 271 # block: allow bio_for_each_segment_all() to iterate over multi-page bvec
 272 #
 273 AC_DEFUN([LB_HAVE_BVEC_ITER_ALL], [
 274 tmp_flags="$EXTRA_KCFLAGS"
 275 EXTRA_KCFLAGS="-Werror"
 276 LB_CHECK_COMPILE([if bvec_iter_all exists for multi-page bvec iternation],
 277 ext4fs_dirhash, [
 278         #include <linux/bvec.h>
 279 ],[
 280         struct bvec_iter_all iter;
 281         (void)iter;
 282 ],[
 283         AC_DEFINE(HAVE_BVEC_ITER_ALL, 1,
 284                 [if bvec_iter_all exists for multi-page bvec iternation])
 285 ])
 286 EXTRA_KCFLAGS="$tmp_flags"
 287 ]) # LB_HAVE_BVEC_ITER_ALL
 288
 289 #
 290 # LB_CONFIG_LDISKFS
 291 #
 292 AC_DEFUN([LB_CONFIG_LDISKFS], [
 293 # --with-ldiskfs is deprecated now that ldiskfs is fully merged with lustre.
 294 # However we continue to support this option through Lustre 2.5.
 295 AC_ARG_WITH([ldiskfs],
 296         [],
 297         [AC_MSG_WARN([--with-ldiskfs is deprecated, please use --enable-ldiskfs])
 298         AS_IF([test x$withval != xyes -a x$withval != xno],
 299                 [AC_MSG_ERROR([
 300
 301 The ldiskfs option is deprecated,
 302 and no longer supports paths to external ldiskfs source
 303 ])])
 304 ])
 305
 306 AC_ARG_ENABLE([ldiskfs],
 307         [AS_HELP_STRING([--disable-ldiskfs],
 308                 [disable ldiskfs osd (default is enable)])],
 309         [AS_IF([test x$enable_ldiskfs != xyes -a x$enable_ldiskfs != xno],
 310                 [AC_MSG_ERROR([ldiskfs valid options are "yes" or "no"])])],
 311         [AS_IF([test "${with_ldiskfs+set}" = set],
 312                 [enable_ldiskfs=$with_ldiskfs],
 313                 [enable_ldiskfs=maybe])
 314 ])
 315
 316 AS_IF([test x$enable_server = xno],
 317         [AS_CASE([$enable_ldiskfs],
 318                 [maybe], [enable_ldiskfs=no],
 319                 [yes], [AC_MSG_ERROR([cannot build ldiskfs when servers are disabled])]
 320         )])
 321
 322 AS_IF([test x$enable_ldiskfs != xno],[
 323         # In the future, we chould change enable_ldiskfs from maybe to
 324         # either yes or no based on additional tests, e.g.  whether a patch
 325         # set is available for the detected kernel.  For now, we just always
 326         # set it to "yes".
 327         AS_IF([test x$enable_ldiskfs = xmaybe], [enable_ldiskfs=yes])
 328         AC_SUBST(ENABLE_LDISKFS, yes)
 329
 330         LDISKFS_LINUX_SERIES
 331         LDISKFS_AC_PATCH_PROGRAM
 332         LB_EXT_FREE_BLOCKS_WITH_BUFFER_HEAD
 333         LB_EXT4_JOURNAL_START_3ARGS
 334         LB_EXT4_BREAD_4ARGS
 335         LB_EXT4_HAVE_INFO_DQUOT
 336         LB_EXT4_HAVE_I_CRYPT_INFO
 337         LB_LDISKFS_IGET_HAS_FLAGS_ARG
 338         LB_HAVE_BVEC_ITER_ALL
 339         AC_DEFINE(CONFIG_LDISKFS_FS_POSIX_ACL, 1, [posix acls for ldiskfs])
 340         AC_DEFINE(CONFIG_LDISKFS_FS_SECURITY, 1, [fs security for ldiskfs])
 341         AC_DEFINE(CONFIG_LDISKFS_FS_XATTR, 1, [extened attributes for ldiskfs])
 342         AC_DEFINE(CONFIG_LDISKFS_FS_RW, 1, [enable rw access for ldiskfs])
 343         AC_SUBST(LDISKFS_SUBDIR, ldiskfs)
 344         AC_DEFINE(HAVE_LDISKFS_OSD, 1, Enable ldiskfs osd)
 345 ], [
 346         AC_SUBST(ENABLE_LDISKFS, no)
 347 ])
 348
 349 AC_MSG_CHECKING([whether to build ldiskfs])
 350 AC_MSG_RESULT([$enable_ldiskfs])
 351
 352 AM_CONDITIONAL([LDISKFS_ENABLED], [test x$enable_ldiskfs = xyes])
 353 ]) # LB_CONFIG_LDISKFS
 354
 355 #
 356 # LB_VALIDATE_EXT4_SRC_DIR
 357 #
 358 # Spot check the existence of several source files common to ext4.
 359 # Detecting this at configure time allows us to avoid a potential build
 360 # failure and provide a useful error message to explain what is wrong.
 361 #
 362 AC_DEFUN([LB_VALIDATE_EXT4_SRC_DIR], [
 363 enable_ldiskfs_build="no"
 364 AS_IF([test -n "$EXT4_SRC_DIR"], [
 365         enable_ldiskfs_build="yes"
 366         LB_CHECK_FILE([$EXT4_SRC_DIR/dir.c], [], [
 367                 enable_ldiskfs_build="no"
 368                 AC_MSG_WARN([ext4 must exist for ldiskfs build])
 369         ])
 370         LB_CHECK_FILE([$EXT4_SRC_DIR/file.c], [], [
 371                 enable_ldiskfs_build="no"
 372                 AC_MSG_WARN([ext4 must exist for ldiskfs build])
 373         ])
 374         LB_CHECK_FILE([$EXT4_SRC_DIR/inode.c], [], [
 375                 enable_ldiskfs_build="no"
 376                 AC_MSG_WARN([ext4 must exist for ldiskfs build])
 377         ])
 378         LB_CHECK_FILE([$EXT4_SRC_DIR/super.c], [], [
 379                 enable_ldiskfs_build="no"
 380                 AC_MSG_WARN([ext4 must exist for ldiskfs build])
 381         ])
 382 ])
 383
 384 AS_IF([test "x$enable_ldiskfs_build" = xno], [
 385         enable_ldiskfs="no"
 386
 387         AC_MSG_WARN([
 388
 389 Disabling ldiskfs support because complete ext4 source does not exist.
 390
 391 If you are building using kernel-devel packages and require ldiskfs
 392 server support then ensure that the matching kernel-debuginfo-common
 393 and kernel-debuginfo-common-<arch> packages are installed.
 394 ])
 395 ])
 396 ]) # LB_VALIDATE_EXT4_SRC_DIR
 397
 398 #
 399 # LB_EXT4_SRC_DIR
 400 #
 401 # Determine the location of the ext4 source code.  It it required
 402 # for several configure tests and to build ldiskfs.
 403 #
 404 AC_DEFUN([LB_EXT4_SRC_DIR], [
 405 AC_MSG_CHECKING([ext4 source directory])
 406 # Kernel ext source located with devel headers
 407 linux_src=$LINUX
 408 AS_IF([test -e "$linux_src/fs/ext4/super.c"], [
 409         EXT4_SRC_DIR="$linux_src/fs/ext4"
 410 ], [
 411         # Kernel ext source provided by kernel-debuginfo-common package
 412         # that extracted to $LINUX
 413         linux_src=$(ls -1d $linux_src/../../debug/*/linux-${LINUXRELEASE%.*}* \
 414                 2>/dev/null | tail -1)
 415         AS_IF([test -e "$linux_src/fs/ext4/super.c"], [
 416                 EXT4_SRC_DIR="$linux_src/fs/ext4"
 417         ], [
 418                 # Kernel ext source provided by kernel-debuginfo-common package
 419                 linux_src=$(ls -1d /usr/src/debug/*/linux-${LINUXRELEASE%.*}* \
 420                         2>/dev/null | tail -1)
 421                 AS_IF([test -e "$linux_src/fs/ext4/super.c"], [
 422                         EXT4_SRC_DIR="$linux_src/fs/ext4"
 423                 ], [
 424                         EXT4_SRC_DIR=""
 425                 ])
 426         ])
 427 ])
 428 AC_MSG_RESULT([$EXT4_SRC_DIR])
 429 AC_SUBST(EXT4_SRC_DIR)
 430
 431 LB_VALIDATE_EXT4_SRC_DIR
 432 ]) # LB_EXT4_SRC_DIR
 433
 434 #
 435 # LB_DEFINE_E2FSPROGS_NAMES
 436 #
 437 # Enable the use of alternate naming of ldiskfs-enabled e2fsprogs package.
 438 #
 439 AC_DEFUN([LB_DEFINE_E2FSPROGS_NAMES], [
 440 AC_MSG_CHECKING([whether to use alternate names for e2fsprogs])
 441 AC_ARG_WITH([ldiskfsprogs],
 442         AC_HELP_STRING([--with-ldiskfsprogs],
 443                 [use alternate names for ldiskfs-enabled e2fsprogs]),
 444         [], [withval="no"])
 445
 446 AS_IF([test "x$withval" = xyes], [
 447         AC_MSG_RESULT([enabled])
 448         AC_DEFINE(HAVE_LDISKFSPROGS, 1, [enable use of ldiskfsprogs package])
 449         E2FSPROGS="ldiskfsprogs"
 450         MKE2FS="mkfs.ldiskfs"
 451         DEBUGFS="debugfs.ldiskfs"
 452         TUNE2FS="tunefs.ldiskfs"
 453         E2LABEL="label.ldiskfs"
 454         DUMPE2FS="dumpfs.ldiskfs"
 455         E2FSCK="fsck.ldiskfs"
 456         PFSCK="pfsck.ldiskfs"
 457 ], [
 458         AC_MSG_RESULT([disabled])
 459         E2FSPROGS="e2fsprogs"
 460         MKE2FS="mke2fs"
 461         DEBUGFS="debugfs"
 462         TUNE2FS="tune2fs"
 463         E2LABEL="e2label"
 464         DUMPE2FS="dumpe2fs"
 465         E2FSCK="e2fsck"
 466         PFSCK="fsck"
 467 ])
 468
 469 AC_DEFINE_UNQUOTED(E2FSPROGS, "$E2FSPROGS", [name of ldiskfs e2fsprogs package])
 470 AC_DEFINE_UNQUOTED(MKE2FS, "$MKE2FS", [name of ldiskfs mkfs program])
 471 AC_DEFINE_UNQUOTED(DEBUGFS, "$DEBUGFS", [name of ldiskfs debug program])
 472 AC_DEFINE_UNQUOTED(TUNE2FS, "$TUNE2FS", [name of ldiskfs tune program])
 473 AC_DEFINE_UNQUOTED(E2LABEL, "$E2LABEL", [name of ldiskfs label program])
 474 AC_DEFINE_UNQUOTED(DUMPE2FS,"$DUMPE2FS", [name of ldiskfs dump program])
 475 AC_DEFINE_UNQUOTED(E2FSCK, "$E2FSCK", [name of ldiskfs fsck program])
 476 AC_DEFINE_UNQUOTED(PFSCK, "$PFSCK", [name of parallel fsck program])
 477
 478 AC_SUBST([E2FSPROGS], [$E2FSPROGS])
 479 AC_SUBST([MKE2FS], [$MKE2FS])
 480 AC_SUBST([DEBUGFS], [$DEBUGFS])
 481 AC_SUBST([TUNE2FS], [$TUNE2FS])
 482 AC_SUBST([E2LABEL], [$E2LABEL])
 483 AC_SUBST([DUMPE2FS], [$DUMPE2FS])
 484 AC_SUBST([E2FSCK], [$E2FSCK])
 485 AC_SUBST([PFSCK], [$PFSCK])
 486 ]) # LB_DEFINE_E2FSPROGS_NAMES