config/lustre-build-ldiskfs.m4

   1 #
   2 # LB_PATH_LDISKFS
   3 #
   4 # --without-ldiskfs   - Disable ldiskfs support.
   5 # --with-ldiskfs=no
   6 #
   7 # --with-ldiskfs      - Enable ldiskfs support and attempt to autodetect the
   8 # --with-ldiskfs=yes    headers in one of the following places in this order:
   9 #                       * ./ldiskfs
  10 #                       * /usr/src/ldiskfs-*/$LINUXRELEASE
  11 #                       * ../ldiskfs
  12 #
  13 # --with-ldiskfs=path - Enable ldiskfs support and use the headers in the
  14 #                       provided path.  No autodetection is performed.
  15 #
  16 # --with-ldiskfs-obj  - When ldiskfs support is enabled the object directory
  17 #                       will be based on the --with-ldiskfs directory.  If
  18 #                       this is detected incorrectly it can be explicitly
  19 #                       specified using this option.
  20 #
  21 # NOTE: As with all external packages ldiskfs is expected to already be
  22 # configured and built.  However, if the ldiskfs tree is located in-tree
  23 # (./ldiskfs) then it will be configured and built recursively as part of
  24 # the lustre build system.
  25 #
  26 # NOTE: The lustre and in-tree ldiskfs build systems both make use these
  27 # macros.  This is undesirable and confusing at best, it is potentially
  28 # danagerous at worst.  The ldiskfs build system should be entirely stand
  29 # alone without dependency on the lustre build system.
  30 #
  31 AC_DEFUN([LB_PATH_LDISKFS],
  32 [
  33 AC_ARG_WITH([ldiskfs],
  34         AC_HELP_STRING([--with-ldiskfs=path], [set path to ldiskfs source]),
  35         [],[
  36                 if test x$enable_server = xyes && test x$enable_dist = xno; then
  37                         with_ldiskfs='yes'
  38                 else
  39                         with_ldiskfs='no'
  40                 fi
  41         ])
  42
  43 case x$with_ldiskfs in
  44         xno)
  45                 LDISKFS_DIR=
  46                 ;;
  47         xyes)
  48                 LDISKFS_DIR=
  49
  50                 # Check ./ldiskfs
  51                 ldiskfs_src=$PWD/ldiskfs
  52                 if test -e "$ldiskfs_src"; then
  53                         LDISKFS_DIR=$(readlink -f $ldiskfs_src)
  54                 else
  55                         # Check /usr/src/ldiskfs-*/$LINUXRELEASE
  56                         ldiskfs_src=$(ls -1d \
  57                                 /usr/src/ldiskfs-*/$LINUXRELEASE \
  58                                 2>/dev/null | tail -1)
  59                         if test -e "$ldiskfs_src"; then
  60                                 LDISKFS_DIR=$(readlink -f $ldiskfs_src)
  61                         else
  62                                 # Check ../ldiskfs
  63                                 ldiskfs_src=$PWD/../ldiskfs
  64                                 if test -e "$ldiskfs_src"; then
  65                                         LDISKFS_DIR=$(readlink -f $ldiskfs_src)
  66                                 else
  67                                         # Disable ldiskfs failed to detect
  68                                         with_ldiskfs='no'
  69                                 fi
  70                         fi
  71                 fi
  72
  73                 ;;
  74         *)
  75                 LDISKFS_DIR=$(readlink -f $with_ldiskfs)
  76                 with_ldiskfs='yes'
  77                 ;;
  78 esac
  79
  80 AC_MSG_CHECKING([whether to enable ldiskfs])
  81 AC_MSG_RESULT([$with_ldiskfs])
  82
  83 AC_ARG_WITH([ldiskfs-obj],
  84         AC_HELP_STRING([--with-ldiskfs-obj=path],[set path to ldiskfs objects]),
  85         [
  86                 if test x$with_ldiskfs = xyes; then
  87                         LDISKFS_OBJ="$withval"
  88                 fi
  89         ],[
  90                 if test x$with_ldiskfs = xyes; then
  91                         LDISKFS_OBJ=$LDISKFS_DIR
  92                 fi
  93         ])
  94
  95 if test x$with_ldiskfs = xyes; then
  96         AC_MSG_CHECKING([ldiskfs source directory])
  97         AC_MSG_RESULT([$LDISKFS_DIR])
  98         AC_SUBST(LDISKFS_DIR)
  99
 100         AC_MSG_CHECKING([ldiskfs object directory])
 101         AC_MSG_RESULT([$LDISKFS_OBJ])
 102         AC_SUBST(LDISKFS_OBJ)
 103
 104         LB_LDISKFS_SYMVERS
 105         LB_LDISKFS_RELEASE
 106         LB_LDISKFS_EXT_DIR
 107         LB_LDISKFS_BUILD
 108         AC_DEFINE(HAVE_LDISKFS_OSD, 1, Enable ldiskfs osd)
 109 fi
 110
 111 #
 112 # LDISKFS_DEVEL is required because when using the ldiskfs-devel package the
 113 # ext4 source will be fully patched to ldiskfs.  When building with the
 114 # in-tree ldiskfs this patching this will occur after the configure step.
 115 # We needed a way to determine if we should check the patched or unpatched
 116 # source files.
 117 #
 118 # Longer term this could be removed by moving the ldiskfs patching in to
 119 # the configure phase.  Or better yet ldiskfs could be updated to generate
 120 # a ldiskfs_config.h which clearly defines how it was built.  This can
 121 # then be directly included by Lustre to avoid all the autoconf guess work.
 122 # For an example of this behavior consult the lustre/zfs build integration.
 123 #
 124 AM_CONDITIONAL(LDISKFS_DEVEL, \
 125         test x$LDISKFS_DIR = x$(readlink -f $PWD/ldiskfs) || \
 126         test x$LDISKFS_DIR = x$(readlink -f $PWD/../ldiskfs))
 127
 128 AM_CONDITIONAL(LDISKFS_BUILD, test x$enable_ldiskfs_build = xyes)
 129 AM_CONDITIONAL(LDISKFS_ENABLED, test x$with_ldiskfs = xyes)
 130
 131 if test -e "$PWD/ldiskfs"; then
 132         LDISKFS_DIST_SUBDIR="ldiskfs"
 133         AC_SUBST(LDISKFS_DIST_SUBDIR)
 134         AC_CONFIG_SUBDIRS("ldiskfs")
 135 fi
 136 ])
 137
 138 #
 139 # LB_LDISKFS_EXT_DIR
 140 #
 141 # Determine the location of the ext4 source code.  It it required
 142 # for several configure tests and to build ldiskfs.
 143 #
 144 AC_DEFUN([LB_LDISKFS_EXT_DIR],
 145 [
 146 # Kernel ext source located with devel headers
 147 linux_src=$LINUX
 148 if test -e "$linux_src/fs/ext4/super.c"; then
 149         EXT_DIR=$linux_src/fs/ext4
 150 else
 151         # Kernel ext source provided by kernel-debuginfo-common package
 152         linux_src=$(ls -1d /usr/src/debug/*/linux-$LINUXRELEASE \
 153                 2>/dev/null | tail -1)
 154         if test -e "$linux_src/fs/ext4/super.c"; then
 155                 EXT_DIR=$linux_src/fs/ext4
 156         else
 157                 EXT_DIR=
 158         fi
 159 fi
 160
 161 AC_MSG_CHECKING([ext4 source directory])
 162 AC_MSG_RESULT([$EXT_DIR])
 163 AC_SUBST(EXT_DIR)
 164 ])
 165
 166 #
 167 # LB_LDISKFS_EXT_SOURCE
 168 #
 169 # Spot check the existance of several source files common to ext4.
 170 # Detecting this at configure time allows us to avoid a potential build
 171 # failure and provide a useful error message to explain what is wrong.
 172 #
 173 AC_DEFUN([LB_LDISKFS_EXT_SOURCE],
 174 [
 175 if test x$EXT_DIR = x; then
 176         enable_ldiskfs_build='no'
 177 else
 178         LB_CHECK_FILE([$EXT_DIR/dir.c], [], [
 179                 enable_ldiskfs_build='no'
 180                 AC_MSG_WARN([ext4 must exist for ldiskfs build])])
 181         LB_CHECK_FILE([$EXT_DIR/file.c], [], [
 182                 enable_ldiskfs_build='no'
 183                 AC_MSG_WARN([ext4 must exist for ldiskfs build])])
 184         LB_CHECK_FILE([$EXT_DIR/inode.c], [], [
 185                 enable_ldiskfs_build='no'
 186                 AC_MSG_WARN([ext4 must exist for ldiskfs build])])
 187         LB_CHECK_FILE([$EXT_DIR/super.c], [], [
 188                 enable_ldiskfs_build='no'
 189                 AC_MSG_WARN([ext4 must exist for ldiskfs build])])
 190 fi
 191
 192 if test x$enable_ldiskfs_build = xno; then
 193         enable_server='no'
 194         enable_ldiskfs_build='no'
 195         with_ldiskfs='no'
 196         LDISKFS_SUBDIR=
 197
 198         AC_MSG_WARN([
 199
 200 Disabling server because complete ext4 source does not exist.
 201
 202 If you are building using kernel-devel packages and require ldiskfs
 203 server support then ensure that the matching kernel-debuginfo-common
 204 and kernel-debuginfo-common-<arch> packages are installed.
 205
 206 ])
 207
 208 fi
 209 ])
 210
 211 #
 212 # Optionally configure/make the ldiskfs sources.  If the sources are
 213 # determined to reside in-tree this feature will automatically be
 214 # enabled.  If the sources are not in-tree it will be disabled.
 215 # Use --enable-ldiskfs-build or --disable-ldiskfs-build if you need
 216 # to override this behavior.
 217 #
 218 AC_DEFUN([LB_LDISKFS_BUILD],
 219 [
 220 AC_ARG_ENABLE([ldiskfs-build],
 221         AC_HELP_STRING([--enable-ldiskfs-build],
 222                 [enable ldiskfs configure/make]),
 223         [], [
 224                 LDISKFS_DIR_INTREE=$(readlink -f $PWD/ldiskfs)
 225                 if test x$LDISKFS_DIR = x$LDISKFS_DIR_INTREE; then
 226                         enable_ldiskfs_build='yes'
 227                 else
 228                         enable_ldiskfs_build='no'
 229                 fi
 230         ])
 231
 232 AC_MSG_CHECKING([whether to build ldiskfs])
 233 if test x$enable_ldiskfs_build = xyes; then
 234         AC_MSG_RESULT([$enable_ldiskfs_build])
 235         LDISKFS_SUBDIR="ldiskfs"
 236
 237         LB_CHECK_FILE([$LDISKFS_DIR/configure], [], [
 238                 AC_MSG_ERROR([Complete ldiskfs build system must exist])])
 239         LB_LDISKFS_EXT_SOURCE
 240
 241         AC_SUBST(LDISKFS_SUBDIR)
 242 else
 243         enable_ldiskfs_build='no'
 244         AC_MSG_RESULT([$enable_ldiskfs_build])
 245 fi
 246 ])
 247
 248 AC_DEFUN([LB_LDISKFS_SYMVERS],
 249 [
 250 AC_MSG_CHECKING([ldiskfs module symbols])
 251 if test -r $LDISKFS_OBJ/Module.symvers; then
 252         LDISKFS_SYMBOLS=Module.symvers
 253 elif test -r $LDISKFS_OBJ/Modules.symvers; then
 254         LDISKFS_SYMBOLS=Modules.symvers
 255 elif test -r $LDISKFS_OBJ/ldiskfs/Module.symvers; then
 256         LDISKFS_SYMBOLS=Module.symvers
 257 elif test -r $LDISKFS_OBJ/ldiskfs/Modules.symvers; then
 258         LDISKFS_SYMBOLS=Modules.symvers
 259 else
 260         LDISKFS_SYMBOLS=$SYMVERFILE
 261 fi
 262
 263 AC_MSG_RESULT([$LDISKFS_SYMBOLS])
 264 AC_SUBST(LDISKFS_SYMBOLS)
 265 ])
 266
 267 AC_DEFUN([LB_LDISKFS_RELEASE],
 268 [
 269 AC_MSG_CHECKING([ldiskfs source release])
 270 if test -r $LDISKFS_OBJ/config.h; then
 271         tmp_flags="$EXTRA_KCFLAGS"
 272         EXTRA_KCFLAGS="-I$LDISKFS_DIR $EXTRA_KCFLAGS"
 273         LB_LINUX_TRY_MAKE([
 274                 #undef PACKAGE_NAME
 275                 #undef PACKAGE_TARNAME
 276                 #undef PACKAGE_VERSION
 277                 #undef PACKAGE_STRING
 278                 #undef PACKAGE_BUGREPORT
 279                 #undef PACKAGE
 280                 #undef VERSION
 281                 #undef STDC_HEADERS
 282
 283                 #include <$LDISKFS_OBJ/config.h>
 284         ],[
 285                 char *LDISKFS_RELEASE;
 286                 LDISKFS_RELEASE=VERSION;
 287         ],[
 288                 $makerule LUSTRE_KERNEL_TEST=conftest.i
 289         ],[
 290                 test -s build/conftest.i
 291         ],[
 292                 eval $(grep "LDISKFS_RELEASE=" build/conftest.i)
 293         ],[
 294                 AC_MSG_RESULT([unknown])
 295                 AC_MSG_ERROR([Could not preprocess test program.])
 296         ])
 297         EXTRA_KCFLAGS="$tmp_flags"
 298         rm build/conftest.i
 299 elif test -r $LDISKFS_DIR/configure.ac; then
 300         LDISKFS_RELEASE=$(awk '/AC\_INIT/ { print [$]3 }' \
 301                  $LDISKFS_DIR/configure.ac | tr ',' '\n')
 302 else
 303         AC_MSG_RESULT([unknown])
 304         AC_MSG_ERROR([Could not locate config.h, META, or configure.ac to check release.])
 305 fi
 306
 307 if test x$LDISKFS_RELEASE = x; then
 308         AC_MSG_RESULT([unknown])
 309         AC_MSG_ERROR([Could not determine ldiskfs release.])
 310 fi
 311
 312 AC_MSG_RESULT([$LDISKFS_RELEASE])
 313 AC_SUBST(LDISKFS_RELEASE)
 314 ])
 315
 316 #
 317 # LB_DEFINE_E2FSPROGS_NAMES
 318 #
 319 # Enable the use of alternate naming of ldiskfs-enabled e2fsprogs package.
 320 #
 321 AC_DEFUN([LB_DEFINE_E2FSPROGS_NAMES],
 322 [
 323 AC_ARG_WITH([ldiskfsprogs],
 324         AC_HELP_STRING([--with-ldiskfsprogs],
 325                        [use alternate names for ldiskfs-enabled e2fsprogs]),
 326         [],[withval='no'])
 327
 328 AC_MSG_CHECKING([whether to use alternate names for e2fsprogs])
 329 if test x$withval = xyes ; then
 330         AC_DEFINE(HAVE_LDISKFSPROGS, 1, [enable use of ldiskfsprogs package])
 331         E2FSPROGS="ldiskfsprogs"
 332         MKE2FS="mkfs.ldiskfs"
 333         DEBUGFS="debugfs.ldiskfs"
 334         TUNE2FS="tunefs.ldiskfs"
 335         E2LABEL="label.ldiskfs"
 336         DUMPE2FS="dumpfs.ldiskfs"
 337         E2FSCK="fsck.ldiskfs"
 338         PFSCK="pfsck.ldiskfs"
 339         AC_MSG_RESULT([enabled])
 340 else
 341         E2FSPROGS="e2fsprogs"
 342         MKE2FS="mke2fs"
 343         DEBUGFS="debugfs"
 344         TUNE2FS="tune2fs"
 345         E2LABEL="e2label"
 346         DUMPE2FS="dumpe2fs"
 347         E2FSCK="e2fsck"
 348         PFSCK="fsck"
 349         AC_MSG_RESULT([disabled])
 350 fi
 351
 352 AC_DEFINE_UNQUOTED(E2FSPROGS, "$E2FSPROGS", [name of ldiskfs e2fsprogs package])
 353 AC_DEFINE_UNQUOTED(MKE2FS, "$MKE2FS", [name of ldiskfs mkfs program])
 354 AC_DEFINE_UNQUOTED(DEBUGFS, "$DEBUGFS", [name of ldiskfs debug program])
 355 AC_DEFINE_UNQUOTED(TUNE2FS, "$TUNE2FS", [name of ldiskfs tune program])
 356 AC_DEFINE_UNQUOTED(E2LABEL, "$E2LABEL", [name of ldiskfs label program])
 357 AC_DEFINE_UNQUOTED(DUMPE2FS,"$DUMPE2FS", [name of ldiskfs dump program])
 358 AC_DEFINE_UNQUOTED(E2FSCK, "$E2FSCK", [name of ldiskfs fsck program])
 359 AC_DEFINE_UNQUOTED(PFSCK, "$PFSCK", [name of parallel fsck program])
 360
 361 AC_SUBST([E2FSPROGS], [$E2FSPROGS])
 362 AC_SUBST([MKE2FS], [$MKE2FS])
 363 AC_SUBST([DEBUGFS], [$DEBUGFS])
 364 AC_SUBST([TUNE2FS], [$TUNE2FS])
 365 AC_SUBST([E2LABEL], [$E2LABEL])
 366 AC_SUBST([DUMPE2FS], [$DUMPE2FS])
 367 AC_SUBST([E2FSCK], [$E2FSCK])
 368 AC_SUBST([PFSCK], [$PFSCK])
 369 ])