config/lustre-build-ldiskfs.m4

   1 #
   2 # LDISKFS_LINUX_SERIES
   3 #
   4 AC_DEFUN([LDISKFS_LINUX_SERIES], [
   5 AC_MSG_CHECKING([which ldiskfs series to use])
   6 case x$LDISKFS_SERIES in
   7         x)                      # not set
   8                 ;;
   9         *.series)               # set externally
  10                 ;;
  11         *) LDISKFS_SERIES=
  12 esac
  13 AS_IF([test -z "$LDISKFS_SERIES"], [
  14 AS_IF([test x$RHEL_KERNEL = xyes], [
  15         case $RHEL_RELEASE_NO in
  16         81)     LDISKFS_SERIES="4.18-rhel8.1.series"    ;;
  17         80)     LDISKFS_SERIES="4.18-rhel8.series"      ;;
  18         77)     LDISKFS_SERIES="3.10-rhel7.7.series"    ;;
  19         76)     LDISKFS_SERIES="3.10-rhel7.6.series"    ;;
  20         esac
  21 ], [test x$SUSE_KERNEL = xyes], [
  22         AS_VERSION_COMPARE([$LINUXRELEASE],[5.3.18],[
  23         AS_VERSION_COMPARE([$LINUXRELEASE],[4.12.14],[
  24         AS_VERSION_COMPARE([$LINUXRELEASE],[4.4.82],[
  25         AS_VERSION_COMPARE([$LINUXRELEASE],[4.4.0],[
  26         AS_VERSION_COMPARE([$LINUXRELEASE],[3.12.0],[],
  27         [LDISKFS_SERIES="3.12-sles12.series"],[
  28                 PLEV=$(grep PATCHLEVEL /etc/SuSE-release | sed -e 's/.*= *//')
  29                 case $PLEV in
  30                 1) LDISKFS_SERIES="3.12-sles12sp1.series"
  31                         ;;
  32                 *) LDISKFS_SERIES="3.12-sles12.series"
  33                         ;;
  34                 esac
  35         ])],[LDISKFS_SERIES="4.4-sles12sp2.series"],
  36             [LDISKFS_SERIES="4.4-sles12sp2.series"]
  37         )], [LDISKFS_SERIES="4.4-sles12sp3.series"],
  38             [LDISKFS_SERIES="4.4-sles12sp3.series"]
  39         )], [LDISKFS_SERIES="4.12-sles15.series"],
  40             [LDISKFS_SERIES="4.12-sles15.series"]
  41         )], [LDISKFS_SERIES="5.4.0-ml.series"],
  42             [LDISKFS_SERIES="5.4.0-ml.series"])
  43 ], [test x$UBUNTU_KERNEL = xyes], [
  44         AS_VERSION_COMPARE([$LINUXRELEASE],[5.3.0],[
  45         AS_VERSION_COMPARE([$LINUXRELEASE],[5.0.0],[
  46         AS_VERSION_COMPARE([$LINUXRELEASE],[4.15.0],[
  47         AS_VERSION_COMPARE([$LINUXRELEASE],[4.4.0], [],
  48         [
  49                 KPLEV=$(echo $LINUXRELEASE | sed -n 's/.*-\([0-9]\+\).*/\1/p')
  50                 AS_IF(
  51                         [test -z "$KPLEV"], [
  52                                 AC_MSG_WARN([Failed to determine Kernel patch level. Assume latest.])
  53                                 LDISKFS_SERIES="4.4.0-73-ubuntu14+16.series"
  54                         ],
  55                         [test $KPLEV -ge 73], [LDISKFS_SERIES="4.4.0-73-ubuntu14+16.series"],
  56                         [test $KPLEV -ge 62], [LDISKFS_SERIES="4.4.0-62-ubuntu14+16.series"],
  57                         [test $KPLEV -ge 49], [LDISKFS_SERIES="4.4.0-49-ubuntu14+16.series"],
  58                         [LDISKFS_SERIES="4.4.0-45-ubuntu14+16.series"]
  59                 )
  60         ],
  61         [LDISKFS_SERIES="4.4.0-73-ubuntu14+16.series"])],
  62         [
  63                 KPLEV=$(echo $LINUXRELEASE | sed -n 's/.*-\([0-9]\+\).*/\1/p')
  64                 AS_IF(
  65                         [test -z "$KPLEV"], [
  66                                 AC_MSG_WARN([Failed to determine Kernel patch level. Assume latest.])
  67                                 LDISKFS_SERIES="4.15.0-24-ubuntu18.series"
  68                         ],
  69                         [test $KPLEV -ge 24], [LDISKFS_SERIES="4.15.0-24-ubuntu18.series"],
  70                         [test $KPLEV -ge 20], [LDISKFS_SERIES="4.15.0-20-ubuntu18.series"]
  71                 )
  72         ],
  73         [LDISKFS_SERIES="4.15.0-24-ubuntu18.series"])],
  74         [LDISKFS_SERIES="5.0.0-13-ubuntu19.series"],
  75         [LDISKFS_SERIES="5.0.0-13-ubuntu19.series"])],
  76         [LDISKFS_SERIES="5.4.0-ml.series"],
  77         [LDISKFS_SERIES="5.4.0-ml.series"])
  78 ])
  79 ])
  80 # Not RHEL/SLES or Ubuntu .. probably mainline
  81 AS_IF([test -z "$LDISKFS_SERIES"],
  82         [
  83         AS_VERSION_COMPARE([$LINUXRELEASE],[5.4.0],[],
  84         [LDISKFS_SERIES="5.4.0-ml.series"],[
  85         AS_VERSION_COMPARE([$LINUXRELEASE],[5.4.0],
  86                 [LDISKFS_SERIES="5.4.0-ml.series"], # lt
  87                 [LDISKFS_SERIES="5.4.0-ml.series"], # eq
  88                 [LDISKFS_SERIES="5.4.0-ml.series"]  # gt
  89                 )])
  90         ],
  91 [])
  92 AS_IF([test -z "$LDISKFS_SERIES"],
  93         [AC_MSG_RESULT([failed to identify series])],
  94         [AC_MSG_RESULT([$LDISKFS_SERIES for $LINUXRELEASE])])
  95 AC_SUBST(LDISKFS_SERIES)
  96 ]) # LDISKFS_LINUX_SERIES
  97
  98 #
  99 # LB_EXT_FREE_BLOCKS_WITH_BUFFER_HEAD
 100 #
 101 # 2.6.32-rc7 ext4_free_blocks requires struct buffer_head
 102 # Note that RHEL6 is pre 2.6.32-rc7 so this check is still needed.
 103 #
 104 AC_DEFUN([LB_EXT_FREE_BLOCKS_WITH_BUFFER_HEAD], [
 105 LB_CHECK_COMPILE([if 'ext4_free_blocks' needs 'struct buffer_head'],
 106 ext4_free_blocks_with_buffer_head, [
 107         #include <linux/fs.h>
 108         #include "$EXT4_SRC_DIR/ext4.h"
 109 ],[
 110         ext4_free_blocks(NULL, NULL, NULL, 0, 0, 0);
 111 ],[
 112         AC_DEFINE(HAVE_EXT_FREE_BLOCK_WITH_BUFFER_HEAD, 1,
 113                 [ext4_free_blocks do not require struct buffer_head])
 114 ])
 115 ]) # LB_EXT_FREE_BLOCKS_WITH_BUFFER_HEAD
 116
 117 #
 118 # LB_EXT4_JOURNAL_START_3ARGS
 119 #
 120 # 3.9 added a type argument to ext4_journal_start and friends
 121 #
 122 AC_DEFUN([LB_EXT4_JOURNAL_START_3ARGS], [
 123 LB_CHECK_COMPILE([if ext4_journal_start takes 3 arguments],
 124 ext4_journal_start, [
 125         #include <linux/fs.h>
 126         #include "$EXT4_SRC_DIR/ext4_jbd2.h"
 127 ],[
 128         ext4_journal_start(NULL, 0, 0);
 129 ],[
 130         AC_DEFINE(JOURNAL_START_HAS_3ARGS, 1, [ext4_journal_start takes 3 arguments])
 131 ])
 132 ]) # LB_EXT4_JOURNAL_START_3ARGS
 133
 134 #
 135 # LB_EXT4_BREAD_4ARGS
 136 #
 137 # 3.18 ext4_bread has 4 arguments
 138 # NOTE: It may not be exported for modules, use a positive compiler test here.
 139 #
 140 AC_DEFUN([LB_EXT4_BREAD_4ARGS], [
 141 LB_CHECK_COMPILE([if ext4_bread takes 4 arguments],
 142 ext4_bread, [
 143         #include <linux/fs.h>
 144         #include "$EXT4_SRC_DIR/ext4.h"
 145
 146         struct buffer_head *ext4_bread(handle_t *handle, struct inode *inode,
 147                                        ext4_lblk_t block, int map_flags)
 148         {
 149                 struct buffer_head *bh = NULL;
 150                 (void)handle;
 151                 (void)inode;
 152                 (void)block;
 153                 (void)map_flags;
 154                 return bh;
 155         }
 156 ],[
 157         ext4_bread(NULL, NULL, 0, 0);
 158 ],[
 159         AC_DEFINE(HAVE_EXT4_BREAD_4ARGS, 1, [ext4_bread takes 4 arguments])
 160 ])
 161 ]) # LB_EXT4_BREAD_4ARGS
 162
 163 #
 164 # LB_EXT4_HAVE_INFO_DQUOT
 165 #
 166 # in linux 4.4 i_dqout is in ext4_inode_info, not in struct inode
 167 #
 168 AC_DEFUN([LB_EXT4_HAVE_INFO_DQUOT], [
 169 LB_CHECK_COMPILE([if i_dquot is in ext4_inode_info],
 170 ext4_info_dquot, [
 171         #include <linux/fs.h>
 172         #include <linux/quota.h>
 173         #include "$EXT4_SRC_DIR/ext4.h"
 174 ],[
 175         struct ext4_inode_info in;
 176         struct dquot *dq;
 177
 178         dq = in.i_dquot[0];
 179 ],[
 180         AC_DEFINE(HAVE_EXT4_INFO_DQUOT, 1, [i_dquot is in ext4_inode_info])
 181 ])
 182 ]) # LB_EXT4_HAVE_INFO_DQUOT
 183
 184 #
 185 # LB_EXT4_HAVE_I_CRYPT_INFO
 186 #
 187 # in linux 4.8 i_crypt_info moved from ext4_inode_info to struct inode
 188 #
 189 # Determine if we need to enable CONFIG_LDISKFS_FS_ENCRYPTION.
 190 # If we have i_crypt_info in ext4_inode_info, the config option
 191 # should be enabled to make the ldiskfs module compilation happy.
 192 # Otherwise i_crypy_info is in struct inode, we need to check kernel
 193 # config option to determine that.
 194 #
 195 AC_DEFUN([LB_EXT4_HAVE_I_CRYPT_INFO], [
 196 LB_CHECK_COMPILE([if i_crypt_info is in ext4_inode_info],
 197 ext4_i_crypt_info, [
 198         #define CONFIG_EXT4_FS_ENCRYPTION 1
 199         #include <linux/fs.h>
 200         #include "$EXT4_SRC_DIR/ext4.h"
 201 ],[
 202         struct ext4_inode_info in;
 203
 204         in.i_crypt_info = NULL;
 205 ],[
 206         AC_DEFINE(
 207                 CONFIG_LDISKFS_FS_ENCRYPTION, 1,
 208                 [enable encryption for ldiskfs]
 209         )
 210 ],[
 211         LB_CHECK_CONFIG([EXT4_FS_ENCRYPTION],[
 212                 AC_DEFINE(
 213                         CONFIG_LDISKFS_FS_ENCRYPTION, 1,
 214                         [enable encryption for ldiskfs]
 215                 )
 216         ])
 217 ])
 218 ]) # LB_EXT4_HAVE_I_CRYPT_INFO
 219
 220 #
 221 # LB_LDISKFS_IGET_HAS_FLAGS_ARG
 222 #
 223 # kernel 4.19 commit 8a363970d1dc38c4ec4ad575c862f776f468d057
 224 # ext4_iget changed to a macro with 3 args was function with 2 args
 225 #
 226 AC_DEFUN([LB_LDISKFS_IGET_HAS_FLAGS_ARG], [
 227 tmp_flags="$EXTRA_KCFLAGS"
 228 EXTRA_KCFLAGS="-Werror"
 229 LB_CHECK_COMPILE([if ldiskfs_iget takes a flags argument],
 230 ext4_iget_3args, [
 231         #include <linux/fs.h>
 232         #include "$EXT4_SRC_DIR/ext4.h"
 233 ],[
 234         int f = EXT4_IGET_SPECIAL;
 235         (void)f;
 236 ],[
 237         AC_DEFINE(HAVE_LDISKFS_IGET_WITH_FLAGS, 1,
 238                 [if ldiskfs_iget takes a flags argument])
 239 ])
 240 EXTRA_KCFLAGS="$tmp_flags"
 241 ]) # LB_LDISKFS_IGET_HAS_FLAGS_ARG
 242
 243 #
 244 # LDISKFS_AC_PATCH_PROGRAM
 245 #
 246 # Determine which program should be used to apply the patches to
 247 # the ext4 source code to produce the ldiskfs source code.
 248 #
 249 AC_DEFUN([LDISKFS_AC_PATCH_PROGRAM], [
 250         AC_ARG_ENABLE([quilt],
 251                 [AC_HELP_STRING([--disable-quilt],
 252                         [disable use of quilt for ldiskfs])],
 253                 [AS_IF([test "x$enableval" = xno],
 254                         [use_quilt=no],
 255                         [use_quilt=maybe])],
 256                 [use_quilt=maybe]
 257         )
 258
 259         AS_IF([test x$use_quilt = xmaybe], [
 260                 AC_PATH_PROG([quilt_avail], [quilt], [no])
 261                 AS_IF([test x$quilt_avail = xno], [
 262                         use_quilt=no
 263                 ], [
 264                         use_quilt=yes
 265                 ])
 266         ])
 267
 268         AS_IF([test x$use_quilt = xno], [
 269                 AC_PATH_PROG([patch_avail], [patch], [no])
 270                 AS_IF([test x$patch_avail = xno], [
 271                         AC_MSG_ERROR([*** Need "quilt" or "patch" command])
 272                 ])
 273         ])
 274 ]) # LDISKFS_AC_PATCH_PROGRAM
 275
 276 #
 277 # LB_HAVE_BVEC_ITER_ALL
 278 #
 279 # kernel 5.1 commit 6dc4f100c175dd0511ae8674786e7c9006cdfbfa
 280 # block: allow bio_for_each_segment_all() to iterate over multi-page bvec
 281 #
 282 AC_DEFUN([LB_HAVE_BVEC_ITER_ALL], [
 283 tmp_flags="$EXTRA_KCFLAGS"
 284 EXTRA_KCFLAGS="-Werror"
 285 LB_CHECK_COMPILE([if bvec_iter_all exists for multi-page bvec iternation],
 286 ext4fs_dirhash, [
 287         #include <linux/bvec.h>
 288 ],[
 289         struct bvec_iter_all iter;
 290         (void)iter;
 291 ],[
 292         AC_DEFINE(HAVE_BVEC_ITER_ALL, 1,
 293                 [if bvec_iter_all exists for multi-page bvec iternation])
 294 ])
 295 EXTRA_KCFLAGS="$tmp_flags"
 296 ]) # LB_HAVE_BVEC_ITER_ALL
 297
 298 #
 299 # LB_LDISKFS_FIND_ENTRY_LOCKED_EXISTS
 300 #
 301 # kernel 5.2 commit 8a363970d1dc38c4ec4ad575c862f776f468d057
 302 # ext4: avoid declaring fs inconsistent due to invalid file handles
 303 # __ext4_find_entry became a helper function for ext4_find_entry
 304 # conflicting with previous ldiskfs patches.
 305 # ldiskfs patches map ext4_find_entry to ldiskfs_find_entry_locked to
 306 # avoid conflicting with __ext4_find_entry
 307 #
 308 # When the following check succeeds __ext4_find_entry helper is not
 309 # used.
 310 #
 311 AC_DEFUN([LB_LDISKFS_FIND_ENTRY_LOCKED_EXISTS], [
 312 tmp_flags="$EXTRA_KCFLAGS"
 313 EXTRA_KCFLAGS="-Werror"
 314 LB_CHECK_COMPILE([if __ldiskfs_find_entry is available],
 315 ldiskfs_find_entry_locked, [
 316         #include <linux/fs.h>
 317         #include "$EXT4_SRC_DIR/ext4.h"
 318         #include "$EXT4_SRC_DIR/namei.c"
 319
 320         static int __ext4_find_entry(void) { return 0; }
 321 ],[
 322         int x = __ext4_find_entry();
 323         (void)x;
 324 ],[
 325         AC_DEFINE(HAVE___LDISKFS_FIND_ENTRY, 1,
 326                 [if __ldiskfs_find_entry is available])
 327 ])
 328 EXTRA_KCFLAGS="$tmp_flags"
 329 ]) # LB_LDISKFS_FIND_ENTRY_LOCKED_EXISTS
 330
 331 #
 332 # LB_LDISKFSFS_DIRHASH_WANTS_DIR
 333 #
 334 # kernel 5.2 commit 8a363970d1dc38c4ec4ad575c862f776f468d057
 335 # ext4fs_dirhash UNICODE support
 336 #
 337 AC_DEFUN([LB_LDISKFSFS_DIRHASH_WANTS_DIR], [
 338 tmp_flags="$EXTRA_KCFLAGS"
 339 EXTRA_KCFLAGS="-Werror"
 340 LB_CHECK_COMPILE([if ldiskfsfs_dirhash takes an inode argument],
 341 ext4fs_dirhash, [
 342         #include <linux/fs.h>
 343         #include "$EXT4_SRC_DIR/ext4.h"
 344
 345         int ext4fs_dirhash(const struct inode *dir, const char *name, int len,
 346                           struct dx_hash_info *hinfo)
 347         {
 348                 (void)dir;
 349                 (void)name;
 350                 (void)len;
 351                 (void)hinfo;
 352                 return 0;
 353         }
 354 ],[
 355         int f = ext4fs_dirhash(NULL, NULL, 0, NULL);
 356         (void)f;
 357 ],[
 358         AC_DEFINE(HAVE_LDISKFSFS_GETHASH_INODE_ARG, 1,
 359                 [if ldiskfsfs_dirhash takes an inode argument])
 360 ])
 361 EXTRA_KCFLAGS="$tmp_flags"
 362 ]) # LB_LDISKFSFS_DIRHASH_WANTS_DIR
 363
 364 #
 365 # LB_CONFIG_LDISKFS
 366 #
 367 AC_DEFUN([LB_CONFIG_LDISKFS], [
 368 # --with-ldiskfs is deprecated now that ldiskfs is fully merged with lustre.
 369 # However we continue to support this option through Lustre 2.5.
 370 AC_ARG_WITH([ldiskfs],
 371         [],
 372         [AC_MSG_WARN([--with-ldiskfs is deprecated, please use --enable-ldiskfs])
 373         AS_IF([test x$withval != xyes -a x$withval != xno],
 374                 [AC_MSG_ERROR([
 375
 376 The ldiskfs option is deprecated,
 377 and no longer supports paths to external ldiskfs source
 378 ])])
 379 ])
 380
 381 AC_ARG_ENABLE([ldiskfs],
 382         [AS_HELP_STRING([--disable-ldiskfs],
 383                 [disable ldiskfs osd (default is enable)])],
 384         [AS_IF([test x$enable_ldiskfs != xyes -a x$enable_ldiskfs != xno],
 385                 [AC_MSG_ERROR([ldiskfs valid options are "yes" or "no"])])],
 386         [AS_IF([test "${with_ldiskfs+set}" = set],
 387                 [enable_ldiskfs=$with_ldiskfs],
 388                 [enable_ldiskfs=maybe])
 389 ])
 390
 391 AS_IF([test x$enable_server = xno],
 392         [AS_CASE([$enable_ldiskfs],
 393                 [maybe], [enable_ldiskfs=no],
 394                 [yes], [AC_MSG_ERROR([cannot build ldiskfs when servers are disabled])]
 395         )])
 396
 397 AS_IF([test x$enable_ldiskfs != xno],[
 398         # In the future, we chould change enable_ldiskfs from maybe to
 399         # either yes or no based on additional tests, e.g.  whether a patch
 400         # set is available for the detected kernel.  For now, we just always
 401         # set it to "yes".
 402         AS_IF([test x$enable_ldiskfs = xmaybe], [enable_ldiskfs=yes])
 403         AC_SUBST(ENABLE_LDISKFS, yes)
 404
 405         LDISKFS_LINUX_SERIES
 406         LDISKFS_AC_PATCH_PROGRAM
 407         LB_EXT_FREE_BLOCKS_WITH_BUFFER_HEAD
 408         LB_EXT4_JOURNAL_START_3ARGS
 409         LB_EXT4_BREAD_4ARGS
 410         LB_EXT4_HAVE_INFO_DQUOT
 411         LB_EXT4_HAVE_I_CRYPT_INFO
 412         LB_LDISKFS_IGET_HAS_FLAGS_ARG
 413         LB_HAVE_BVEC_ITER_ALL
 414         LB_LDISKFS_FIND_ENTRY_LOCKED_EXISTS
 415         LB_LDISKFSFS_DIRHASH_WANTS_DIR
 416         AC_DEFINE(CONFIG_LDISKFS_FS_POSIX_ACL, 1, [posix acls for ldiskfs])
 417         AC_DEFINE(CONFIG_LDISKFS_FS_SECURITY, 1, [fs security for ldiskfs])
 418         AC_DEFINE(CONFIG_LDISKFS_FS_XATTR, 1, [extened attributes for ldiskfs])
 419         AC_DEFINE(CONFIG_LDISKFS_FS_RW, 1, [enable rw access for ldiskfs])
 420         AC_SUBST(LDISKFS_SUBDIR, ldiskfs)
 421         AC_DEFINE(HAVE_LDISKFS_OSD, 1, Enable ldiskfs osd)
 422 ], [
 423         AC_SUBST(ENABLE_LDISKFS, no)
 424 ])
 425
 426 AC_MSG_CHECKING([whether to build ldiskfs])
 427 AC_MSG_RESULT([$enable_ldiskfs])
 428
 429 AM_CONDITIONAL([LDISKFS_ENABLED], [test x$enable_ldiskfs = xyes])
 430 ]) # LB_CONFIG_LDISKFS
 431
 432 #
 433 # LB_VALIDATE_EXT4_SRC_DIR
 434 #
 435 # Spot check the existence of several source files common to ext4.
 436 # Detecting this at configure time allows us to avoid a potential build
 437 # failure and provide a useful error message to explain what is wrong.
 438 #
 439 AC_DEFUN([LB_VALIDATE_EXT4_SRC_DIR], [
 440 enable_ldiskfs_build="no"
 441 AS_IF([test -n "$EXT4_SRC_DIR"], [
 442         enable_ldiskfs_build="yes"
 443         LB_CHECK_FILE([$EXT4_SRC_DIR/dir.c], [], [
 444                 enable_ldiskfs_build="no"
 445                 AC_MSG_WARN([ext4 must exist for ldiskfs build])
 446         ])
 447         LB_CHECK_FILE([$EXT4_SRC_DIR/file.c], [], [
 448                 enable_ldiskfs_build="no"
 449                 AC_MSG_WARN([ext4 must exist for ldiskfs build])
 450         ])
 451         LB_CHECK_FILE([$EXT4_SRC_DIR/inode.c], [], [
 452                 enable_ldiskfs_build="no"
 453                 AC_MSG_WARN([ext4 must exist for ldiskfs build])
 454         ])
 455         LB_CHECK_FILE([$EXT4_SRC_DIR/super.c], [], [
 456                 enable_ldiskfs_build="no"
 457                 AC_MSG_WARN([ext4 must exist for ldiskfs build])
 458         ])
 459 ])
 460
 461 AS_IF([test "x$enable_ldiskfs_build" = xno], [
 462         enable_ldiskfs="no"
 463
 464         AC_MSG_WARN([
 465
 466 Disabling ldiskfs support because complete ext4 source does not exist.
 467
 468 If you are building using kernel-devel packages and require ldiskfs
 469 server support then ensure that the matching kernel-debuginfo-common
 470 and kernel-debuginfo-common-<arch> packages are installed.
 471 ])
 472 ])
 473 ]) # LB_VALIDATE_EXT4_SRC_DIR
 474
 475 #
 476 # LB_EXT4_SRC_DIR
 477 #
 478 # Determine the location of the ext4 source code.  It it required
 479 # for several configure tests and to build ldiskfs.
 480 #
 481 AC_DEFUN([LB_EXT4_SRC_DIR], [
 482 AC_MSG_CHECKING([ext4 source directory])
 483 # Kernel ext source located with devel headers
 484 linux_src=$LINUX
 485 AS_IF([test -e "$linux_src/fs/ext4/super.c"], [
 486         EXT4_SRC_DIR="$linux_src/fs/ext4"
 487 ], [
 488         # Kernel ext source provided by kernel-debuginfo-common package
 489         # that extracted to $LINUX
 490         linux_src=$(ls -1d $linux_src/../../debug/*/linux-${LINUXRELEASE%.*}* \
 491                 2>/dev/null | tail -1)
 492         AS_IF([test -e "$linux_src/fs/ext4/super.c"], [
 493                 EXT4_SRC_DIR="$linux_src/fs/ext4"
 494         ], [
 495                 # Kernel ext source provided by kernel-debuginfo-common package
 496                 linux_src=$(ls -1d /usr/src/debug/*/linux-${LINUXRELEASE%.*}* \
 497                         2>/dev/null | tail -1)
 498                 AS_IF([test -e "$linux_src/fs/ext4/super.c"], [
 499                         EXT4_SRC_DIR="$linux_src/fs/ext4"
 500                 ], [
 501                         EXT4_SRC_DIR=""
 502                 ])
 503         ])
 504 ])
 505 AC_MSG_RESULT([$EXT4_SRC_DIR])
 506 AC_SUBST(EXT4_SRC_DIR)
 507
 508 LB_VALIDATE_EXT4_SRC_DIR
 509 ]) # LB_EXT4_SRC_DIR
 510
 511 #
 512 # LB_DEFINE_E2FSPROGS_NAMES
 513 #
 514 # Enable the use of alternate naming of ldiskfs-enabled e2fsprogs package.
 515 #
 516 AC_DEFUN([LB_DEFINE_E2FSPROGS_NAMES], [
 517 AC_MSG_CHECKING([whether to use alternate names for e2fsprogs])
 518 AC_ARG_WITH([ldiskfsprogs],
 519         AC_HELP_STRING([--with-ldiskfsprogs],
 520                 [use alternate names for ldiskfs-enabled e2fsprogs]),
 521         [], [withval="no"])
 522
 523 AS_IF([test "x$withval" = xyes], [
 524         AC_MSG_RESULT([enabled])
 525         AC_DEFINE(HAVE_LDISKFSPROGS, 1, [enable use of ldiskfsprogs package])
 526         E2FSPROGS="ldiskfsprogs"
 527         MKE2FS="mkfs.ldiskfs"
 528         DEBUGFS="debugfs.ldiskfs"
 529         TUNE2FS="tunefs.ldiskfs"
 530         E2LABEL="label.ldiskfs"
 531         DUMPE2FS="dumpfs.ldiskfs"
 532         E2FSCK="fsck.ldiskfs"
 533         PFSCK="pfsck.ldiskfs"
 534 ], [
 535         AC_MSG_RESULT([disabled])
 536         E2FSPROGS="e2fsprogs"
 537         MKE2FS="mke2fs"
 538         DEBUGFS="debugfs"
 539         TUNE2FS="tune2fs"
 540         E2LABEL="e2label"
 541         DUMPE2FS="dumpe2fs"
 542         E2FSCK="e2fsck"
 543         PFSCK="fsck"
 544 ])
 545
 546 AC_DEFINE_UNQUOTED(E2FSPROGS, "$E2FSPROGS", [name of ldiskfs e2fsprogs package])
 547 AC_DEFINE_UNQUOTED(MKE2FS, "$MKE2FS", [name of ldiskfs mkfs program])
 548 AC_DEFINE_UNQUOTED(DEBUGFS, "$DEBUGFS", [name of ldiskfs debug program])
 549 AC_DEFINE_UNQUOTED(TUNE2FS, "$TUNE2FS", [name of ldiskfs tune program])
 550 AC_DEFINE_UNQUOTED(E2LABEL, "$E2LABEL", [name of ldiskfs label program])
 551 AC_DEFINE_UNQUOTED(DUMPE2FS,"$DUMPE2FS", [name of ldiskfs dump program])
 552 AC_DEFINE_UNQUOTED(E2FSCK, "$E2FSCK", [name of ldiskfs fsck program])
 553 AC_DEFINE_UNQUOTED(PFSCK, "$PFSCK", [name of parallel fsck program])
 554
 555 AC_SUBST([E2FSPROGS], [$E2FSPROGS])
 556 AC_SUBST([MKE2FS], [$MKE2FS])
 557 AC_SUBST([DEBUGFS], [$DEBUGFS])
 558 AC_SUBST([TUNE2FS], [$TUNE2FS])
 559 AC_SUBST([E2LABEL], [$E2LABEL])
 560 AC_SUBST([DUMPE2FS], [$DUMPE2FS])
 561 AC_SUBST([E2FSCK], [$E2FSCK])
 562 AC_SUBST([PFSCK], [$PFSCK])
 563 ]) # LB_DEFINE_E2FSPROGS_NAMES