build/autoconf/lustre-build.m4

   1 #
   2 # LB_CHECK_VERSION
   3 #
   4 # Verify that LUSTRE_VERSION was defined properly
   5 #
   6 AC_DEFUN([LB_CHECK_VERSION],
   7 [if test "LUSTRE_VERSION" = "LUSTRE""_VERSION" ; then
   8         AC_MSG_ERROR([This script was not built with a version number.])
   9 fi
  10 ])
  11
  12 #
  13 # LB_CANONICAL_SYSTEM
  14 #
  15 # fixup $target_os for use in other places
  16 #
  17 AC_DEFUN([LB_CANONICAL_SYSTEM],
  18 [case $target_os in
  19         linux*)
  20                 lb_target_os="linux"
  21                 ;;
  22         darwin*)
  23                 lb_target_os="darwin"
  24                 ;;
  25         solaris*)
  26                 lb_target_os="SunOS"
  27                 ;;esac
  28 AC_SUBST(lb_target_os)
  29 ])
  30
  31 #
  32 # LB_CHECK_FILE
  33 #
  34 # Check for file existance even when cross compiling
  35 #
  36 AC_DEFUN([LB_CHECK_FILE],
  37 [AS_VAR_PUSHDEF([lb_File], [lb_cv_file_$1])dnl
  38 AC_CACHE_CHECK([for $1], lb_File,
  39 [if test -r "$1"; then
  40   AS_VAR_SET(lb_File, yes)
  41 else
  42   AS_VAR_SET(lb_File, no)
  43 fi])
  44 AS_IF([test AS_VAR_GET(lb_File) = yes], [$2], [$3])[]dnl
  45 AS_VAR_POPDEF([lb_File])dnl
  46 ])# LB_CHECK_FILE
  47
  48
  49 #
  50 # LB_ARG_LIBS_INCLUDES
  51 #
  52 # support for --with-foo, --with-foo-includes, and --with-foo-libs in
  53 # a single magical macro
  54 #
  55 AC_DEFUN([LB_ARG_LIBS_INCLUDES],
  56 [lb_pathvar="m4_bpatsubst([$2], -, _)"
  57 AC_MSG_CHECKING([for $1])
  58 AC_ARG_WITH([$2],
  59         AC_HELP_STRING([--with-$2=path],
  60                 [path to $1]),
  61         [],[withval=$4])
  62
  63 if test x$withval = xyes ; then
  64         eval "$lb_pathvar='$3'"
  65 else
  66         eval "$lb_pathvar='$withval'"
  67 fi
  68 AC_MSG_RESULT([${!lb_pathvar:-no}])
  69
  70 if test x${!lb_pathvar} != x -a x${!lb_pathvar} != xno ; then
  71         AC_MSG_CHECKING([for $1 includes])
  72         AC_ARG_WITH([$2-includes],
  73                 AC_HELP_STRING([--with-$2-includes=path],
  74                         [path to $1 includes]),
  75                 [],[withval='yes'])
  76
  77         lb_includevar="${lb_pathvar}_includes"
  78         if test x$withval = xyes ; then
  79                 eval "${lb_includevar}='${!lb_pathvar}/include'"
  80         else
  81                 eval "${lb_includevar}='$withval'"
  82         fi
  83         AC_MSG_RESULT([${!lb_includevar}])
  84
  85         AC_MSG_CHECKING([for $1 libs])
  86         AC_ARG_WITH([$2-libs],
  87                 AC_HELP_STRING([--with-$2-libs=path],
  88                         [path to $1 libs]),
  89                 [],[withval='yes'])
  90
  91         lb_libvar="${lb_pathvar}_libs"
  92         if test x$withval = xyes ; then
  93                 eval "${lb_libvar}='${!lb_pathvar}/lib'"
  94         else
  95                 eval "${lb_libvar}='$withval'"
  96         fi
  97         AC_MSG_RESULT([${!lb_libvar}])
  98 fi
  99 ])
 100 ])
 101
 102 #
 103 # LB_PATH_LIBSYSIO
 104 #
 105 # Handle internal/external libsysio
 106 #
 107 AC_DEFUN([LB_PATH_LIBSYSIO],
 108 [AC_ARG_WITH([sysio],
 109         AC_HELP_STRING([--with-sysio=path],
 110                         [set path to libsysio source (default is included libsysio)]),
 111         [],[
 112                 case $lb_target_os in
 113                         linux)
 114                                 with_sysio='yes'
 115                                 ;;
 116                         *)
 117                                 with_sysio='no'
 118                                 ;;
 119                 esac
 120         ])
 121 AC_MSG_CHECKING([location of libsysio])
 122 enable_sysio="$with_sysio"
 123 case x$with_sysio in
 124         xyes)
 125                 AC_MSG_RESULT([internal])
 126                 LB_CHECK_FILE([$srcdir/libsysio/src/rmdir.c],[],[
 127                         AC_MSG_ERROR([A complete internal libsysio was not found.])
 128                 ])
 129                 LIBSYSIO_SUBDIR="libsysio"
 130                 SYSIO="$PWD/libsysio"
 131                 ;;
 132         xno)
 133                 AC_MSG_RESULT([disabled])
 134                 ;;
 135         *)
 136                 AC_MSG_RESULT([$with_sysio])
 137                 LB_CHECK_FILE([$with_sysio/lib/libsysio.a],[],[
 138                         AC_MSG_ERROR([A complete (built) external libsysio was not found.])
 139                 ])
 140                 SYSIO=$with_sysio
 141                 with_sysio="yes"
 142                 ;;
 143 esac
 144
 145 # We have to configure even if we don't build here for make dist to work
 146 AC_CONFIG_SUBDIRS(libsysio)
 147 ])
 148
 149 #
 150 # LB_PATH_LUSTREIOKIT
 151 #
 152 # Handle internal/external lustre-iokit
 153 #
 154 AC_DEFUN([LB_PATH_LUSTREIOKIT],
 155 [AC_ARG_WITH([lustre-iokit],
 156         AC_HELP_STRING([--with-lustre-iokit=path],
 157                         [set path to lustre-iokit source (default is included lustre-iokit)]),
 158         [],[
 159                         with_lustre_iokit='yes'
 160         ])
 161 AC_MSG_CHECKING([location of lustre-iokit])
 162 enable_lustre_iokit="$with_lustre_iokit"
 163 case x$with_lustre_iokit in
 164         xyes)
 165                 AC_MSG_RESULT([internal])
 166                 LB_CHECK_FILE([$srcdir/lustre-iokit/ior-survey/ior-survey],[],[
 167                         AC_MSG_ERROR([A complete internal lustre-iokit was not found.])
 168                 ])
 169                 LUSTREIOKIT_SUBDIR="lustre-iokit"
 170                 LUSTREIOKIT="$PWD/lustre-iokit"
 171                 ;;
 172         xno)
 173                 AC_MSG_RESULT([disabled])
 174                 ;;
 175         *)
 176                 AC_MSG_RESULT([$with_lustre_iokit])
 177                 LB_CHECK_FILE([$with_lustre_iokit/ior-survey/ior_survey],[],[
 178                         AC_MSG_ERROR([A complete (built) external lustre-iokit was not found.])
 179                 ])
 180                 LUSTREIOKIT="$with_lustre_iokit"
 181                 with_lustre_iokit="yes"
 182                 ;;
 183 esac
 184 AC_SUBST(LUSTREIOKIT_SUBDIR)
 185 # We have to configure even if we don't build here for make dist to work
 186 AC_CONFIG_SUBDIRS(lustre-iokit)
 187 ])
 188
 189 #
 190 # LB_PATH_LDISKFS
 191 #
 192 # Handle internal/external ldiskfs
 193 #
 194 AC_DEFUN([LB_PATH_LDISKFS],
 195 [AC_ARG_WITH([ldiskfs],
 196         AC_HELP_STRING([--with-ldiskfs=path],
 197                         [set path to ldiskfs source (default is included ldiskfs)]),
 198         [],[
 199                 if test x$linux25$enable_server = xyesyes ; then
 200                         with_ldiskfs=yes
 201                 else
 202                         with_ldiskfs=no
 203                 fi
 204         ])
 205 AC_ARG_WITH([ldiskfs-inkernel],
 206         AC_HELP_STRING([--with-ldiskfs-inkernel],
 207                         [use ldiskfs built in to the kernel]),
 208         [with_ldiskfs=inkernel], [])
 209 AC_MSG_CHECKING([location of ldiskfs])
 210 case x$with_ldiskfs in
 211         xyes)
 212                 AC_MSG_RESULT([internal])
 213                 LB_CHECK_FILE([$srcdir/ldiskfs/lustre-ldiskfs.spec.in],[],[
 214                         AC_MSG_ERROR([A complete internal ldiskfs was not found.])
 215                 ])
 216                 LDISKFS_SUBDIR="ldiskfs"
 217                 LDISKFS_DIR="$PWD/ldiskfs"
 218                 ;;
 219         xno)
 220                 AC_MSG_RESULT([disabled])
 221                 ;;
 222         xinkernel)
 223                 AC_MSG_RESULT([inkernel])
 224                 LB_CHECK_FILE([$LINUX/include/linux/ldiskfs_fs.h],[],[
 225                         AC_MSG_ERROR([ldiskfs was not found in $LINUX/include/linux/ldiskfs_fs.h])
 226                 ])
 227                 ;;
 228         *)
 229                 AC_MSG_RESULT([$with_ldiskfs])
 230                 LB_CHECK_FILE([$with_ldiskfs/ldiskfs/linux/ldiskfs_fs.h],[],[
 231                         AC_MSG_ERROR([A complete (built) external ldiskfs was not found.])
 232                 ])
 233                 LDISKFS_DIR=$with_ldiskfs
 234                 ;;
 235 esac
 236 AC_SUBST(LDISKFS_DIR)
 237 AC_SUBST(LDISKFS_SUBDIR)
 238 AM_CONDITIONAL(LDISKFS_ENABLED, test x$with_ldiskfs != xno)
 239 AM_CONDITIONAL(LDISKFS_IN_KERNEL, test x$with_ldiskfs = xinkernel)
 240
 241 if test x$enable_ext4 = xyes ; then
 242         AC_DEFINE(HAVE_EXT4_LDISKFS, 1, [build ext4 based ldiskfs])
 243 fi
 244
 245 # We have to configure even if we don't build here for make dist to work
 246 AC_CONFIG_SUBDIRS(ldiskfs)
 247 ])
 248
 249 AC_DEFUN([LC_KERNEL_WITH_EXT4],
 250 [if test -f $LINUX/fs/ext4/ext4.h ; then
 251 $1
 252 else
 253 $2
 254 fi
 255 ])
 256
 257 #
 258 # LB_HAVE_EXT4_ENABLED
 259 #
 260 AC_DEFUN([LB_HAVE_EXT4_ENABLED],
 261 [
 262 if test x$RHEL_KERNEL = xyes; then
 263         AC_ARG_ENABLE([ext4],
 264                  AC_HELP_STRING([--enable-ext4],
 265                                 [enable building of ldiskfs based on ext4]),
 266                 [],
 267                 [
 268                         if test x$ldiskfs_is_ext4 = xyes; then
 269                                 enable_ext4=yes
 270                         else
 271                                 enable_ext4=no
 272                         fi
 273                 ])
 274 else
 275         case $LINUXRELEASE in
 276         # ext4 was in 2.6.22-2.6.26 but not stable enough to use
 277         2.6.2[[0-9]]*) enable_ext4='no' ;;
 278         *)  LC_KERNEL_WITH_EXT4([enable_ext4='yes'],
 279                                 [enable_ext4='no']) ;;
 280         esac
 281 fi
 282 if test x$enable_ext4 = xyes; then
 283          ac_configure_args="$ac_configure_args --enable-ext4"
 284 fi
 285 AC_MSG_CHECKING([whether to build ldiskfs based on ext4])
 286 AC_MSG_RESULT([$enable_ext4])
 287 ])
 288
 289 # Define no libcfs by default.
 290 AC_DEFUN([LB_LIBCFS_DIR],
 291 [
 292 case x$libcfs_is_module in
 293         xyes)
 294           LIBCFS_INCLUDE_DIR="libcfs/include"
 295           LIBCFS_SUBDIR="libcfs"
 296           ;;
 297         x*)
 298           LIBCFS_INCLUDE_DIR="lnet/include"
 299           LIBCFS_SUBDIR=""
 300           ;;
 301 esac
 302 AC_SUBST(LIBCFS_SUBDIR)
 303 AC_SUBST(LIBCFS_INCLUDE_DIR)
 304 ])
 305
 306 #
 307 # LB_DEFINE_LDISKFS_OPTIONS
 308 #
 309 # Enable config options related to ldiskfs.  These are used both by ldiskfs
 310 # and lvfs (which includes ldiskfs headers.)
 311 #
 312 AC_DEFUN([LB_DEFINE_LDISKFS_OPTIONS],
 313 [
 314         AC_DEFINE(CONFIG_LDISKFS_FS_MODULE, 1, [build ldiskfs as a module])
 315         AC_DEFINE(CONFIG_LDISKFS_FS_XATTR, 1, [enable extended attributes for ldiskfs])
 316         AC_DEFINE(CONFIG_LDISKFS_FS_POSIX_ACL, 1, [enable posix acls for ldiskfs])
 317         AC_DEFINE(CONFIG_LDISKFS_FS_SECURITY, 1, [enable fs security for ldiskfs])
 318         AC_DEFINE(CONFIG_LDISKFSDEV_FS_POSIX_ACL, 1, [enable posix acls for ldiskfs])
 319         AC_DEFINE(CONFIG_LDISKFSDEV_FS_XATTR, 1, [enable extented attributes for ldiskfs])
 320         AC_DEFINE(CONFIG_LDISKFSDEV_FS_SECURITY, 1, [enable fs security for ldiskfs])
 321 ])
 322
 323 #
 324 # LB_DEFINE_E2FSPROGS_NAMES
 325 #
 326 # Enable the use of alternate naming of ldiskfs-enabled e2fsprogs package.
 327 #
 328 AC_DEFUN([LB_DEFINE_E2FSPROGS_NAMES],
 329 [AC_ARG_WITH([ldiskfsprogs],
 330         AC_HELP_STRING([--with-ldiskfsprogs],
 331                        [use alternate names for ldiskfs-enabled e2fsprogs]),
 332         [],[withval='no'])
 333
 334 if test x$withval = xyes ; then
 335         AC_DEFINE(HAVE_LDISKFSPROGS, 1, [enable use of ldiskfsprogs package])
 336         E2FSPROGS="ldiskfsprogs"
 337         MKE2FS="mkfs.ldiskfs"
 338         DEBUGFS="debug.ldiskfs"
 339         TUNE2FS="tune.ldiskfs"
 340         E2LABEL="label.ldiskfs"
 341         DUMPE2FS="dump.ldiskfs"
 342         E2FSCK="fsck.ldiskfs"
 343         AC_MSG_RESULT([enabled])
 344 else
 345         E2FSPROGS="e2fsprogs"
 346         MKE2FS="mke2fs"
 347         DEBUGFS="debugfs"
 348         TUNE2FS="tune2fs"
 349         E2LABEL="e2label"
 350         DUMPE2FS="dumpe2fs"
 351         E2FSCK="e2fsck"
 352         AC_MSG_RESULT([disabled])
 353 fi
 354         AC_DEFINE_UNQUOTED(E2FSPROGS, "$E2FSPROGS", [name of ldiskfs e2fsprogs package])
 355         AC_DEFINE_UNQUOTED(MKE2FS, "$MKE2FS", [name of ldiskfs mkfs program])
 356         AC_DEFINE_UNQUOTED(DEBUGFS, "$DEBUGFS", [name of ldiskfs debug program])
 357         AC_DEFINE_UNQUOTED(TUNE2FS, "$TUNE2FS", [name of ldiskfs tune program])
 358         AC_DEFINE_UNQUOTED(E2LABEL, "$E2LABEL", [name of ldiskfs label program])
 359         AC_DEFINE_UNQUOTED(DUMPE2FS,"$DUMPE2FS", [name of ldiskfs dump program])
 360         AC_DEFINE_UNQUOTED(E2FSCK, "$E2FSCK", [name of ldiskfs fsck program])
 361 ])
 362
 363 #
 364 # LB_DEFINE_E2FSPROGS_NAMES
 365 #
 366 # Enable the use of alternate naming of ldiskfs-enabled e2fsprogs package.
 367 #
 368 AC_DEFUN([LB_DEFINE_E2FSPROGS_NAMES],
 369 [AC_ARG_WITH([ldiskfsprogs],
 370         AC_HELP_STRING([--with-ldiskfsprogs],
 371                        [use alternate names for ldiskfs-enabled e2fsprogs]),
 372         [],[withval='no'])
 373
 374 if test x$withval = xyes ; then
 375         AC_DEFINE(HAVE_LDISKFSPROGS, 1, [enable use of ldiskfsprogs package])
 376         E2FSPROGS="ldiskfsprogs"
 377         MKE2FS="mkfs.ldiskfs"
 378         DEBUGFS="debug.ldiskfs"
 379         TUNE2FS="tune.ldiskfs"
 380         E2LABEL="label.ldiskfs"
 381         DUMPE2FS="dump.ldiskfs"
 382         E2FSCK="fsck.ldiskfs"
 383         AC_MSG_RESULT([enabled])
 384 else
 385         E2FSPROGS="e2fsprogs"
 386         MKE2FS="mke2fs"
 387         DEBUGFS="debugfs"
 388         TUNE2FS="tune2fs"
 389         E2LABEL="e2label"
 390         DUMPE2FS="dumpe2fs"
 391         E2FSCK="e2fsck"
 392         AC_MSG_RESULT([disabled])
 393 fi
 394         AC_DEFINE_UNQUOTED(E2FSPROGS, "$E2FSPROGS", [name of ldiskfs e2fsprogs package])
 395         AC_DEFINE_UNQUOTED(MKE2FS, "$MKE2FS", [name of ldiskfs mkfs program])
 396         AC_DEFINE_UNQUOTED(DEBUGFS, "$DEBUGFS", [name of ldiskfs debug program])
 397         AC_DEFINE_UNQUOTED(TUNE2FS, "$TUNE2FS", [name of ldiskfs tune program])
 398         AC_DEFINE_UNQUOTED(E2LABEL, "$E2LABEL", [name of ldiskfs label program])
 399         AC_DEFINE_UNQUOTED(DUMPE2FS,"$DUMPE2FS", [name of ldiskfs dump program])
 400         AC_DEFINE_UNQUOTED(E2FSCK, "$E2FSCK", [name of ldiskfs fsck program])
 401 ])
 402
 403 #
 404 # LB_DEFINE_E2FSPROGS_NAMES
 405 #
 406 # Enable the use of alternate naming of ldiskfs-enabled e2fsprogs package.
 407 #
 408 AC_DEFUN([LB_DEFINE_E2FSPROGS_NAMES],
 409 [AC_ARG_WITH([ldiskfsprogs],
 410         AC_HELP_STRING([--with-ldiskfsprogs],
 411                        [use alternate names for ldiskfs-enabled e2fsprogs]),
 412         [],[withval='no'])
 413
 414 if test x$withval = xyes ; then
 415         AC_DEFINE(HAVE_LDISKFSPROGS, 1, [enable use of ldiskfsprogs package])
 416         E2FSPROGS="ldiskfsprogs"
 417         MKE2FS="mkfs.ldiskfs"
 418         DEBUGFS="debug.ldiskfs"
 419         TUNE2FS="tune.ldiskfs"
 420         E2LABEL="label.ldiskfs"
 421         DUMPE2FS="dump.ldiskfs"
 422         E2FSCK="fsck.ldiskfs"
 423         AC_MSG_RESULT([enabled])
 424 else
 425         E2FSPROGS="e2fsprogs"
 426         MKE2FS="mke2fs"
 427         DEBUGFS="debugfs"
 428         TUNE2FS="tune2fs"
 429         E2LABEL="e2label"
 430         DUMPE2FS="dumpe2fs"
 431         E2FSCK="e2fsck"
 432         AC_MSG_RESULT([disabled])
 433 fi
 434         AC_DEFINE_UNQUOTED(E2FSPROGS, "$E2FSPROGS", [name of ldiskfs e2fsprogs package])
 435         AC_DEFINE_UNQUOTED(MKE2FS, "$MKE2FS", [name of ldiskfs mkfs program])
 436         AC_DEFINE_UNQUOTED(DEBUGFS, "$DEBUGFS", [name of ldiskfs debug program])
 437         AC_DEFINE_UNQUOTED(TUNE2FS, "$TUNE2FS", [name of ldiskfs tune program])
 438         AC_DEFINE_UNQUOTED(E2LABEL, "$E2LABEL", [name of ldiskfs label program])
 439         AC_DEFINE_UNQUOTED(DUMPE2FS,"$DUMPE2FS", [name of ldiskfs dump program])
 440         AC_DEFINE_UNQUOTED(E2FSCK, "$E2FSCK", [name of ldiskfs fsck program])
 441 ])
 442
 443 #
 444 # LB_CONFIG_CRAY_XT3
 445 #
 446 # Enable Cray XT3 features
 447 #
 448 AC_DEFUN([LB_CONFIG_CRAY_XT3],
 449 [AC_MSG_CHECKING([whether to build Cray XT3 features])
 450 AC_ARG_ENABLE([cray_xt3],
 451         AC_HELP_STRING([--enable-cray-xt3],
 452                         [enable building of Cray XT3 features]),
 453         [enable_cray_xt3='yes'],[enable_cray_xt3='no'])
 454 AC_MSG_RESULT([$enable_cray_xt3])
 455 if test x$enable_cray_xt3 != xno; then
 456         AC_DEFINE(CRAY_XT3, 1, Enable Cray XT3 Features)
 457 fi
 458 ])
 459
 460 #
 461 # LB_CONFIG_BGL
 462 #
 463 # Enable BGL features
 464 #
 465 AC_DEFUN([LB_CONFIG_BGL],
 466 [AC_MSG_CHECKING([whether to build BGL features])
 467 AC_ARG_ENABLE([bgl],
 468         AC_HELP_STRING([--enable-bgl],
 469                         [enable building of BGL features]),
 470         [enable_bgl='yes'],[enable_bgl='no'])
 471 AC_MSG_RESULT([$enable_bgl])
 472 if test x$enable_bgl != xno; then
 473         AC_DEFINE(HAVE_BGL_SUPPORT, 1, Enable BGL Features)
 474         enable_doc='no'
 475         enable_tests='no'
 476         enable_server='no'
 477         enable_liblustre='no'
 478         enable_libreadline='no'
 479 fi
 480 ])
 481
 482 #
 483 # Support for --enable-uoss
 484 #
 485 AC_DEFUN([LB_UOSS],
 486 [AC_MSG_CHECKING([whether to enable uoss])
 487 AC_ARG_ENABLE([uoss],
 488         AC_HELP_STRING([--enable-uoss],
 489                         [enable userspace OSS]),
 490         [enable_uoss='yes'],[enable_uoss='no'])
 491 AC_MSG_RESULT([$enable_uoss])
 492 if test x$enable_uoss = xyes; then
 493         AC_DEFINE(UOSS_SUPPORT, 1, Enable user-level OSS)
 494         AC_DEFINE(LUSTRE_ULEVEL_MT, 1, Multi-threaded user-level lustre port)
 495         enable_uoss='yes'
 496         enable_ulevel_mt='yes'
 497         enable_modules='no'
 498         enable_client='no'
 499         enable_tests='no'
 500         enable_liblustre='no'
 501         with_ldiskfs='no'
 502 fi
 503 AC_SUBST(enable_uoss)
 504 ])
 505
 506 #
 507 # Support for --enable-posix-osd
 508 #
 509 AC_DEFUN([LB_POSIX_OSD],
 510 [AC_MSG_CHECKING([whether to enable posix osd])
 511 AC_ARG_ENABLE([posix-osd],
 512         AC_HELP_STRING([--enable-posix-osd],
 513                         [enable using of posix osd]),
 514         [enable_posix_osd='yes'],[enable_posix_osd='no'])
 515 AC_MSG_RESULT([$enable_posix_osd])
 516 if test x$enable_uoss = xyes -a x$enable_posix_osd = xyes ; then
 517         AC_DEFINE(POSIX_OSD, 1, Enable POSIX OSD)
 518         posix_osd='yes'
 519 fi
 520 AM_CONDITIONAL(POSIX_OSD_ENABLED, test x$posix_osd = xyes)
 521 ])
 522
 523 #
 524 # LB_PATH_DMU
 525 #
 526 AC_DEFUN([LB_PATH_DMU],
 527 [AC_ARG_ENABLE([dmu],
 528         AC_HELP_STRING([--enable-dmu],
 529                        [enable the DMU backend]),
 530         [],[with_dmu='default'])
 531 AC_MSG_CHECKING([whether to enable DMU])
 532 case x$with_dmu in
 533         xyes)
 534                 dmu_osd='yes'
 535                 ;;
 536         xno)
 537                 dmu_osd='no'
 538                 ;;
 539         xdefault)
 540                 if test x$enable_uoss = xyes -a x$posix_osd != xyes; then
 541                         # Enable the DMU if we're configuring a userspace server
 542                         dmu_osd='yes'
 543                 else
 544                         # Enable the DMU by default on the b_hd_kdmu branch
 545                         if test -d $PWD/zfs -a x$linux25$enable_server = xyesyes; then
 546                                 dmu_osd='yes'
 547                         else
 548                                 dmu_osd='no'
 549                         fi
 550                 fi
 551                 ;;
 552         *)
 553                 dmu_osd='yes'
 554                 ;;
 555 esac
 556 AC_MSG_RESULT([$dmu_osd])
 557 if test x$dmu_osd = xyes; then
 558         AC_DEFINE(DMU_OSD, 1, Enable DMU OSD)
 559         if test x$enable_uoss = xyes; then
 560                 # Userspace DMU
 561                 DMU_SRC="$PWD/lustre/zfs-lustre"
 562                 AC_SUBST(DMU_SRC)
 563                 LB_CHECK_FILE([$DMU_SRC/src/.patched],[],[
 564                         AC_MSG_ERROR([A complete (patched) DMU tree was not found.])
 565                 ])
 566                 AC_CONFIG_SUBDIRS(lustre/zfs-lustre)
 567         else
 568                 # Kernel DMU
 569                 SPL_SUBDIR="spl"
 570                 ZFS_SUBDIR="zfs"
 571
 572                 SPL_DIR="$PWD/$SPL_SUBDIR"
 573                 ZFS_DIR="$PWD/$ZFS_SUBDIR"
 574
 575                 LB_CHECK_FILE([$SPL_DIR/module/spl/spl-generic.c],[],[
 576                         AC_MSG_ERROR([A complete SPL tree was not found in $SPL_DIR.])
 577                 ])
 578
 579                 LB_CHECK_FILE([$ZFS_DIR/module/zfs/dmu.c],[],[
 580                         AC_MSG_ERROR([A complete kernel DMU tree was not found in $ZFS_DIR.])
 581                 ])
 582
 583                 AC_CONFIG_SUBDIRS(spl)
 584                 ac_configure_args="$ac_configure_args --with-spl=$SPL_DIR"
 585                 AC_CONFIG_SUBDIRS(zfs)
 586         fi
 587 fi
 588 AC_SUBST(SPL_SUBDIR)
 589 AC_SUBST(ZFS_SUBDIR)
 590 AC_SUBST(SPL_DIR)
 591 AC_SUBST(ZFS_DIR)
 592 AM_CONDITIONAL(DMU_OSD_ENABLED, test x$dmu_osd = xyes)
 593 AM_CONDITIONAL(KDMU, test x$dmu_osd$enable_uoss = xyesno)
 594 ])
 595
 596 #
 597 # LB_PATH_SNMP
 598 #
 599 # check for in-tree snmp support
 600 #
 601 AC_DEFUN([LB_PATH_SNMP],
 602 [LB_CHECK_FILE([$srcdir/snmp/lustre-snmp.c],[SNMP_DIST_SUBDIR="snmp"])
 603 AC_SUBST(SNMP_DIST_SUBDIR)
 604 AC_SUBST(SNMP_SUBDIR)
 605 ])
 606
 607 #
 608 # LB_CONFIG_MODULES
 609 #
 610 # Build kernel modules?
 611 #
 612 AC_DEFUN([LB_CONFIG_MODULES],
 613 [AC_MSG_CHECKING([whether to build kernel modules])
 614 AC_ARG_ENABLE([modules],
 615         AC_HELP_STRING([--disable-modules],
 616                         [disable building of Lustre kernel modules]),
 617         [],[
 618                 LC_TARGET_SUPPORTED([
 619                         enable_modules='yes'
 620                 ],[
 621                         enable_modules='no'
 622                 ])
 623         ])
 624 AC_MSG_RESULT([$enable_modules ($target_os)])
 625
 626 if test x$enable_modules = xyes ; then
 627         case $target_os in
 628                 linux*)
 629                         LB_PROG_LINUX
 630                         LIBCFS_PROG_LINUX
 631                         LN_PROG_LINUX
 632                         LC_PROG_LINUX
 633                         ;;
 634                 darwin*)
 635                         LB_PROG_DARWIN
 636                         LIBCFS_PROG_DARWIN
 637                         ;;
 638                 *)
 639                         # This is strange - Lustre supports a target we don't
 640                         AC_MSG_ERROR([Modules are not supported on $target_os])
 641                         ;;
 642         esac
 643 fi
 644 ])
 645
 646 #
 647 # LB_CONFIG_UTILS
 648 #
 649 # Build utils?
 650 #
 651 AC_DEFUN([LB_CONFIG_UTILS],
 652 [AC_MSG_CHECKING([whether to build utilities])
 653 AC_ARG_ENABLE([utils],
 654         AC_HELP_STRING([--disable-utils],
 655                         [disable building of Lustre utility programs]),
 656         [],[enable_utils='yes'])
 657 AC_MSG_RESULT([$enable_utils])
 658 if test x$enable_utils = xyes ; then
 659         LB_CONFIG_INIT_SCRIPTS
 660 fi
 661 ])
 662
 663 #
 664 # LB_CONFIG_TESTS
 665 #
 666 # Build tests?
 667 #
 668 AC_DEFUN([LB_CONFIG_TESTS],
 669 [AC_MSG_CHECKING([whether to build Lustre tests])
 670 AC_ARG_ENABLE([tests],
 671         AC_HELP_STRING([--disable-tests],
 672                         [disable building of Lustre tests]),
 673         [],
 674         [
 675                 enable_tests='yes'
 676         ])
 677 AC_MSG_RESULT([$enable_tests])
 678 ])
 679
 680 #
 681 # LB_CONFIG_DOCS
 682 #
 683 # Build docs?
 684 #
 685 AC_DEFUN([LB_CONFIG_DOCS],
 686 [AC_MSG_CHECKING([whether to build docs])
 687 AC_ARG_ENABLE(doc,
 688         AC_HELP_STRING([--disable-doc],
 689                         [skip creation of pdf documentation]),
 690         [
 691                 if test x$enable_doc = xyes ; then
 692                     ENABLE_DOC=1
 693                 else
 694                     ENABLE_DOC=0
 695                 fi
 696         ],[
 697                 ENABLE_DOC=0
 698                 enable_doc='no'
 699         ])
 700 AC_MSG_RESULT([$enable_doc])
 701 AC_SUBST(ENABLE_DOC)
 702 ])
 703
 704 #
 705 # LB_CONFIG_INIT_SCRIPTS
 706 #
 707 # our init scripts only work on red hat linux
 708 #
 709 AC_DEFUN([LB_CONFIG_INIT_SCRIPTS],
 710 [ENABLE_INIT_SCRIPTS=0
 711 if test x$enable_utils = xyes ; then
 712         AC_MSG_CHECKING([whether to install init scripts])
 713         # our scripts only work on red hat systems
 714         if test -f /etc/init.d/functions -a -f /etc/sysconfig/network ; then
 715                 ENABLE_INIT_SCRIPTS=1
 716                 AC_MSG_RESULT([yes])
 717         else
 718                 AC_MSG_RESULT([no])
 719         fi
 720 fi
 721 AC_SUBST(ENABLE_INIT_SCRIPTS)
 722 ])
 723
 724 #
 725 # LB_CONFIG_HEADERS
 726 #
 727 # add -include config.h
 728 #
 729 AC_DEFUN([LB_CONFIG_HEADERS],
 730 [AC_CONFIG_HEADERS([config.h])
 731 CPPFLAGS="-include $PWD/config.h $CPPFLAGS"
 732 EXTRA_KCFLAGS="-include $PWD/config.h $EXTRA_KCFLAGS"
 733 AC_SUBST(EXTRA_KCFLAGS)
 734 ])
 735
 736 #
 737 # LB_INCLUDE_RULES
 738 #
 739 # defines for including the toplevel Rules
 740 #
 741 AC_DEFUN([LB_INCLUDE_RULES],
 742 [INCLUDE_RULES="include $PWD/Rules"
 743 AC_SUBST(INCLUDE_RULES)
 744 ])
 745
 746 #
 747 # LB_PATH_DEFAULTS
 748 #
 749 # 'fixup' default paths
 750 #
 751 AC_DEFUN([LB_PATH_DEFAULTS],
 752 [# directories for binaries
 753 AC_PREFIX_DEFAULT([/usr])
 754
 755 sysconfdir='/etc'
 756 AC_SUBST(sysconfdir)
 757
 758 # Directories for documentation and demos.
 759 docdir='${datadir}/doc/$(PACKAGE)'
 760 AC_SUBST(docdir)
 761
 762 LIBCFS_PATH_DEFAULTS
 763 LN_PATH_DEFAULTS
 764 LC_PATH_DEFAULTS
 765
 766 ])
 767
 768 #
 769 # LB_PROG_CC
 770 #
 771 # checks on the C compiler
 772 #
 773 AC_DEFUN([LB_PROG_CC],
 774 [AC_PROG_RANLIB
 775 AC_MSG_CHECKING([for buggy compiler])
 776 CC_VERSION=`$CC -v 2>&1 | grep "^gcc version"`
 777 bad_cc() {
 778         AC_MSG_RESULT([buggy compiler found!])
 779         echo
 780         echo "   '$CC_VERSION'"
 781         echo "  has been known to generate bad code, "
 782         echo "  please get an updated compiler."
 783         AC_MSG_ERROR([sorry])
 784 }
 785 case "$CC_VERSION" in
 786         "gcc version 2.95"*)
 787                 bad_cc
 788                 ;;
 789         # ost_pack_niobuf putting 64bit NTOH temporaries on the stack
 790         # without "sub    $0xc,%esp" to protect the stack from being
 791         # stomped on by interrupts (bug 606)
 792         "gcc version 2.96 20000731 (Red Hat Linux 7.1 2.96-98)")
 793                 bad_cc
 794                 ;;
 795         # mandrake's similar sub 0xc compiler bug
 796         # http://marc.theaimsgroup.com/?l=linux-kernel&m=104748366226348&w=2
 797         "gcc version 2.96 20000731 (Mandrake Linux 8.1 2.96-0.62mdk)")
 798                 bad_cc
 799                 ;;
 800         *)
 801                 AC_MSG_RESULT([no known problems])
 802                 ;;
 803 esac
 804
 805 # ---------  unsigned long long sane? -------
 806 AC_CHECK_SIZEOF(unsigned long long, 0)
 807 echo "---> size SIZEOF $SIZEOF_unsigned_long_long"
 808 echo "---> size SIZEOF $ac_cv_sizeof_unsigned_long_long"
 809 if test $ac_cv_sizeof_unsigned_long_long != 8 ; then
 810         AC_MSG_ERROR([** we assume that sizeof(long long) == 8.  Tell phil@clusterfs.com])
 811 fi
 812
 813 if test $target_cpu == "powerpc64"; then
 814         AC_MSG_WARN([set compiler with -m64])
 815         CFLAGS="$CFLAGS -m64"
 816         CC="$CC -m64"
 817 fi
 818
 819 CPPFLAGS="-I$PWD/$LIBCFS_INCLUDE_DIR -I$PWD/lnet/include -I$PWD/lustre/include $CPPFLAGS"
 820
 821 LLCPPFLAGS="-D__arch_lib__ -D_LARGEFILE64_SOURCE=1"
 822 AC_SUBST(LLCPPFLAGS)
 823
 824 # Add _GNU_SOURCE for strnlen on linux
 825 LLCFLAGS="-g -Wall -fPIC -D_GNU_SOURCE"
 826 AC_SUBST(LLCFLAGS)
 827
 828 # everyone builds against lnet and lustre
 829 EXTRA_KCFLAGS="$EXTRA_KCFLAGS -g -I$PWD/$LIBCFS_INCLUDE_DIR -I$PWD/lnet/include -I$PWD/lustre/include"
 830 AC_SUBST(EXTRA_KCFLAGS)
 831 ])
 832
 833 #
 834 # LB_CONTITIONALS
 835 #
 836 # AM_CONDITIONAL instances for everything
 837 # (so that portals/lustre can disable some if needed)
 838 AC_DEFUN([LB_CONDITIONALS],
 839 [AM_CONDITIONAL(MODULES, test x$enable_modules = xyes)
 840 AM_CONDITIONAL(UTILS, test x$enable_utils = xyes)
 841 AM_CONDITIONAL(TESTS, test x$enable_tests = xyes)
 842 AM_CONDITIONAL(DOC, test x$ENABLE_DOC = x1)
 843 AM_CONDITIONAL(INIT_SCRIPTS, test x$ENABLE_INIT_SCRIPTS = "x1")
 844 AM_CONDITIONAL(LINUX, test x$lb_target_os = "xlinux")
 845 AM_CONDITIONAL(DARWIN, test x$lb_target_os = "xdarwin")
 846 AM_CONDITIONAL(CRAY_XT3, test x$enable_cray_xt3 = "xyes")
 847 AM_CONDITIONAL(SUNOS, test x$lb_target_os = "xSunOS")
 848
 849 # this lets lustre cancel libsysio, per-branch or if liblustre is
 850 # disabled
 851 if test "x$LIBSYSIO_SUBDIR" = xlibsysio ; then
 852         if test "x$with_sysio" != xyes ; then
 853                 SYSIO=""
 854                 LIBSYSIO_SUBDIR=""
 855         fi
 856 fi
 857 AC_SUBST(LIBSYSIO_SUBDIR)
 858 AC_SUBST(SYSIO)
 859
 860 LB_LINUX_CONDITIONALS
 861 LB_DARWIN_CONDITIONALS
 862
 863 LIBCFS_CONDITIONALS
 864 LN_CONDITIONALS
 865 LC_CONDITIONALS
 866 ])
 867
 868 #
 869 # LB_CONFIG_FILES
 870 #
 871 # build-specific config files
 872 #
 873 AC_DEFUN([LB_CONFIG_FILES],
 874 [
 875 AC_CONFIG_FILES(
 876 [Makefile
 877 autoMakefile
 878 ]
 879 [Rules:build/Rules.in]
 880 AC_PACKAGE_TARNAME[.spec]
 881 )
 882 ])
 883
 884 #
 885 # LB_CONFIGURE
 886 #
 887 # main configure steps
 888 #
 889 AC_DEFUN([LB_CONFIGURE],
 890 [LB_CANONICAL_SYSTEM
 891
 892 LB_LIBCFS_DIR
 893
 894 LB_INCLUDE_RULES
 895
 896 LB_CONFIG_CRAY_XT3
 897 LB_CONFIG_BGL
 898 LB_PATH_DEFAULTS
 899
 900 LB_PROG_CC
 901
 902 LB_UOSS
 903 LB_POSIX_OSD
 904
 905 LB_CONFIG_DOCS
 906 LB_CONFIG_UTILS
 907 LB_CONFIG_TESTS
 908 LC_CONFIG_CLIENT_SERVER
 909
 910 # two macros for cmd3
 911 m4_ifdef([LC_CONFIG_SPLIT], [LC_CONFIG_SPLIT])
 912 LN_CONFIG_CDEBUG
 913 LC_QUOTA
 914
 915 LB_CONFIG_MODULES
 916 LN_CONFIG_USERSPACE
 917 LB_HAVE_EXT4_ENABLED
 918
 919 LB_PATH_DMU
 920 LB_PATH_LIBSYSIO
 921 LB_PATH_SNMP
 922 LB_PATH_LDISKFS
 923 LB_PATH_LUSTREIOKIT
 924
 925 LB_DEFINE_E2FSPROGS_NAMES
 926
 927 LB_DEFINE_E2FSPROGS_NAMES
 928
 929 LB_DEFINE_E2FSPROGS_NAMES
 930
 931 LC_CONFIG_LIBLUSTRE
 932 LIBCFS_CONFIGURE
 933 LN_CONFIGURE
 934
 935 LC_CONFIGURE
 936
 937 if test "$SNMP_DIST_SUBDIR" ; then
 938         LS_CONFIGURE
 939 fi
 940
 941
 942 LB_CONDITIONALS
 943 LB_CONFIG_HEADERS
 944
 945 LIBCFS_CONFIG_FILES
 946 LB_CONFIG_FILES
 947 LN_CONFIG_FILES
 948 LC_CONFIG_FILES
 949 if test "$SNMP_DIST_SUBDIR" ; then
 950         LS_CONFIG_FILES
 951 fi
 952
 953 AC_SUBST(ac_configure_args)
 954
 955 MOSTLYCLEANFILES='.*.cmd .*.flags *.o *.ko *.mod.c .depend .*.1.* Modules.symvers Module.symvers'
 956 AC_SUBST(MOSTLYCLEANFILES)
 957
 958 AC_OUTPUT
 959
 960 cat <<_ACEOF
 961
 962 CC:            $CC
 963 LD:            $LD
 964 CPPFLAGS:      $CPPFLAGS
 965 LLCPPFLAGS:    $LLCPPFLAGS
 966 CFLAGS:        $CFLAGS
 967 EXTRA_KCFLAGS: $EXTRA_KCFLAGS
 968 LLCFLAGS:      $LLCFLAGS
 969
 970 Type 'make' to build Lustre.
 971 _ACEOF
 972 ])