build/autoconf/lustre-build.m4

   1 #
   2 # LB_CHECK_VERSION
   3 #
   4 # Verify that LUSTRE_VERSION was defined properly
   5 #
   6 AC_DEFUN([LB_CHECK_VERSION],
   7 [if test "LUSTRE_VERSION" = "LUSTRE""_VERSION" ; then
   8         AC_MSG_ERROR([This script was not built with a version number.])
   9 fi
  10 ])
  11
  12 #
  13 # LB_CANONICAL_SYSTEM
  14 #
  15 # fixup $target_os for use in other places
  16 #
  17 AC_DEFUN([LB_CANONICAL_SYSTEM],
  18 [case $target_os in
  19         linux*)
  20                 lb_target_os="linux"
  21                 ;;
  22         darwin*)
  23                 lb_target_os="darwin"
  24                 ;;
  25         solaris*)
  26                 lb_target_os="SunOS"
  27                 ;;esac
  28 AC_SUBST(lb_target_os)
  29 ])
  30
  31 #
  32 # LB_CHECK_FILE
  33 #
  34 # Check for file existance even when cross compiling
  35 #
  36 AC_DEFUN([LB_CHECK_FILE],
  37 [AS_VAR_PUSHDEF([lb_File], [lb_cv_file_$1])dnl
  38 AC_CACHE_CHECK([for $1], lb_File,
  39 [if test -r "$1"; then
  40   AS_VAR_SET(lb_File, yes)
  41 else
  42   AS_VAR_SET(lb_File, no)
  43 fi])
  44 AS_IF([test AS_VAR_GET(lb_File) = yes], [$2], [$3])[]dnl
  45 AS_VAR_POPDEF([lb_File])dnl
  46 ])# LB_CHECK_FILE
  47
  48 #
  49 # LB_CHECK_FILES
  50 #
  51 # LB_CHECK_FILE over multiple files
  52 #
  53 AC_DEFUN([LB_CHECK_FILES],
  54 [AC_FOREACH([AC_FILE_NAME], [$1],
  55   [LB_CHECK_FILE(AC_FILE_NAME,
  56                  [AC_DEFINE_UNQUOTED(AS_TR_CPP(HAVE_[]AC_FILE_NAME), 1,
  57                                     [Define to 1 if you have the
  58                                      file `]AC_File['.])
  59 $2],
  60                  [$3])])])
  61
  62 #
  63 # LB_ARG_LIBS_INCLUDES
  64 #
  65 # support for --with-foo, --with-foo-includes, and --with-foo-libs in
  66 # a single magical macro
  67 #
  68 AC_DEFUN([LB_ARG_LIBS_INCLUDES],
  69 [lb_pathvar="m4_bpatsubst([$2], -, _)"
  70 AC_MSG_CHECKING([for $1])
  71 AC_ARG_WITH([$2],
  72         AC_HELP_STRING([--with-$2=path],
  73                 [path to $1]),
  74         [],[withval=$4])
  75
  76 if test x$withval = xyes ; then
  77         eval "$lb_pathvar='$3'"
  78 else
  79         eval "$lb_pathvar='$withval'"
  80 fi
  81 AC_MSG_RESULT([${!lb_pathvar:-no}])
  82
  83 if test x${!lb_pathvar} != x -a x${!lb_pathvar} != xno ; then
  84         AC_MSG_CHECKING([for $1 includes])
  85         AC_ARG_WITH([$2-includes],
  86                 AC_HELP_STRING([--with-$2-includes=path],
  87                         [path to $1 includes]),
  88                 [],[withval='yes'])
  89
  90         lb_includevar="${lb_pathvar}_includes"
  91         if test x$withval = xyes ; then
  92                 eval "${lb_includevar}='${!lb_pathvar}/include'"
  93         else
  94                 eval "${lb_includevar}='$withval'"
  95         fi
  96         AC_MSG_RESULT([${!lb_includevar}])
  97
  98         AC_MSG_CHECKING([for $1 libs])
  99         AC_ARG_WITH([$2-libs],
 100                 AC_HELP_STRING([--with-$2-libs=path],
 101                         [path to $1 libs]),
 102                 [],[withval='yes'])
 103
 104         lb_libvar="${lb_pathvar}_libs"
 105         if test x$withval = xyes ; then
 106                 eval "${lb_libvar}='${!lb_pathvar}/lib'"
 107         else
 108                 eval "${lb_libvar}='$withval'"
 109         fi
 110         AC_MSG_RESULT([${!lb_libvar}])
 111 fi
 112 ])
 113 ])
 114
 115 #
 116 # LB_PATH_LIBSYSIO
 117 #
 118 # Handle internal/external libsysio
 119 #
 120 AC_DEFUN([LB_PATH_LIBSYSIO],
 121 [AC_ARG_WITH([sysio],
 122         AC_HELP_STRING([--with-sysio=path],
 123                         [set path to libsysio source (default is included libsysio)]),
 124         [],[
 125                 case $lb_target_os in
 126                         linux)
 127                                 with_sysio='yes'
 128                                 ;;
 129                         *)
 130                                 with_sysio='no'
 131                                 ;;
 132                 esac
 133         ])
 134 AC_MSG_CHECKING([location of libsysio])
 135 enable_sysio="$with_sysio"
 136 case x$with_sysio in
 137         xyes)
 138                 AC_MSG_RESULT([internal])
 139                 LB_CHECK_FILE([$srcdir/libsysio/src/rmdir.c],[],[
 140                         AC_MSG_ERROR([A complete internal libsysio was not found.])
 141                 ])
 142                 LIBSYSIO_SUBDIR="libsysio"
 143                 SYSIO="$PWD/libsysio"
 144                 ;;
 145         xno)
 146                 AC_MSG_RESULT([disabled])
 147                 ;;
 148         *)
 149                 AC_MSG_RESULT([$with_sysio])
 150                 LB_CHECK_FILE([$with_sysio/lib/libsysio.a],[],[
 151                         AC_MSG_ERROR([A complete (built) external libsysio was not found.])
 152                 ])
 153                 SYSIO=$with_sysio
 154                 with_sysio="yes"
 155                 ;;
 156 esac
 157
 158 # We have to configure even if we don't build here for make dist to work
 159 AC_CONFIG_SUBDIRS(libsysio)
 160 ])
 161
 162 #
 163 # LB_PATH_LDISKFS
 164 #
 165 # Handle internal/external ldiskfs
 166 #
 167 AC_DEFUN([LB_PATH_LDISKFS],
 168 [AC_ARG_WITH([ldiskfs],
 169         AC_HELP_STRING([--with-ldiskfs=path],
 170                         [set path to ldiskfs source (default is included ldiskfs)]),
 171         [],[
 172                 if test x$linux25$enable_server = xyesyes ; then
 173                         with_ldiskfs=yes
 174                 else
 175                         with_ldiskfs=no
 176                 fi
 177         ])
 178 AC_MSG_CHECKING([location of ldiskfs])
 179 case x$with_ldiskfs in
 180         xyes)
 181                 AC_MSG_RESULT([internal])
 182                 LB_CHECK_FILE([$srcdir/ldiskfs/lustre-ldiskfs.spec.in],[],[
 183                         AC_MSG_ERROR([A complete internal ldiskfs was not found.])
 184                 ])
 185                 LDISKFS_SUBDIR="ldiskfs"
 186                 LDISKFS_DIR="$PWD/ldiskfs"
 187                 ;;
 188         xno)
 189                 AC_MSG_RESULT([disabled])
 190                 ;;
 191         *)
 192                 AC_MSG_RESULT([$with_ldiskfs])
 193                 LB_CHECK_FILE([$with_ldiskfs/ldiskfs/linux/ldiskfs_fs.h],[],[
 194                         AC_MSG_ERROR([A complete (built) external ldiskfs was not found.])
 195                 ])
 196                 LDISKFS_DIR=$with_ldiskfs
 197                 ;;
 198 esac
 199 AC_SUBST(LDISKFS_DIR)
 200 AC_SUBST(LDISKFS_SUBDIR)
 201 AM_CONDITIONAL(LDISKFS_ENABLED, test x$with_ldiskfs != xno)
 202
 203 # We have to configure even if we don't build here for make dist to work
 204 AC_CONFIG_SUBDIRS(ldiskfs)
 205 ])
 206
 207 #
 208 # LB_DEFINE_LDISKFS_OPTIONS
 209 #
 210 # Enable config options related to ldiskfs.  These are used both by ldiskfs
 211 # and lvfs (which includes ldiskfs headers.)
 212 #
 213 AC_DEFUN([LB_DEFINE_LDISKFS_OPTIONS],
 214 [
 215         AC_DEFINE(CONFIG_LDISKFS_FS_MODULE, 1, [build ldiskfs as a module])
 216         AC_DEFINE(CONFIG_LDISKFS_FS_XATTR, 1, [enable extended attributes for ldiskfs])
 217         AC_DEFINE(CONFIG_LDISKFS_FS_POSIX_ACL, 1, [enable posix acls for ldiskfs])
 218         AC_DEFINE(CONFIG_LDISKFS_FS_SECURITY, 1, [enable fs security for ldiskfs])
 219 ])
 220
 221 #
 222 # LB_CONFIG_CRAY_XT3
 223 #
 224 # Enable Cray XT3 features
 225 #
 226 AC_DEFUN([LB_CONFIG_CRAY_XT3],
 227 [AC_MSG_CHECKING([whether to build Cray XT3 features])
 228 AC_ARG_ENABLE([cray_xt3],
 229         AC_HELP_STRING([--enable-cray-xt3],
 230                         [enable building of Cray XT3 features]),
 231         [enable_cray_xt3='yes'],[enable_cray_xt3='no'])
 232 AC_MSG_RESULT([$enable_cray_xt3])
 233 if test x$enable_cray_xt3 != xno; then
 234         AC_DEFINE(CRAY_XT3, 1, Enable Cray XT3 Features)
 235 fi
 236 ])
 237
 238 #
 239 # LB_CONFIG_BGL
 240 #
 241 # Enable BGL features
 242 #
 243 AC_DEFUN([LB_CONFIG_BGL],
 244 [AC_MSG_CHECKING([whether to build BGL features])
 245 AC_ARG_ENABLE([bgl],
 246         AC_HELP_STRING([--enable-bgl],
 247                         [enable building of BGL features]),
 248         [enable_bgl='yes'],[enable_bgl='no'])
 249 AC_MSG_RESULT([$enable_bgl])
 250 if test x$enable_bgl != xno; then
 251         AC_DEFINE(BGL_SUPPORT, 1, Enable BGL Features)
 252         enable_doc='no'
 253         enable_tests='no'
 254         enable_server='no'
 255         enable_liblustre='no'
 256         enable_libreadline='no'
 257 fi
 258 ])
 259
 260
 261 #
 262 # LB_PATH_DMU
 263 # Support for --with-dmu
 264 #
 265 AC_DEFUN([LB_PATH_DMU],
 266 [AC_ARG_WITH([dmu],
 267         AC_HELP_STRING([--with-dmu=path],
 268                        [set path to a built dmu]),
 269         [
 270                 DMU_SRC=$with_dmu
 271                 enable_dmu_osd=yes
 272         ],
 273         [
 274                 enable_dmu_osd=no
 275                 DMU_SRC=""
 276         ])
 277 AC_MSG_RESULT([$dmu])
 278 if test x$enable_dmu_osd != xno; then
 279         AC_DEFINE(ENABLE_DMU, 1, Enable DMU OSD)
 280         AC_DEFINE(DMU_OSD, 1, Enable DMU OSD)
 281         AC_DEFINE(UOSS_SUPPORT, 1, Enable user-level OSS)
 282         AC_DEFINE(LUSTRE_ULEVEL_MT, 1, Multi-threaded user-level lustre port)
 283         enable_uoss='yes'
 284         enable_ulevel_mt='yes'
 285         enable_modules='no'
 286         enable_client='no'
 287         enable_tests='no'
 288         enable_liblustre='no'
 289         with_ldiskfs=no
 290 fi
 291 AC_SUBST(DMU_SRC)
 292 ])
 293
 294 #
 295 # Support for --enable-posix-dmu
 296 #
 297 AC_DEFUN([LB_POSIX_OSD],
 298 [AC_MSG_CHECKING([whether to posix osd])
 299 AC_ARG_ENABLE([posix-osd],
 300         AC_HELP_STRING([--enable-posix-osd],
 301                         [enable using of posix osd]),
 302         [enable_posix_osd='yes'],[enable_posix_osd='no'])
 303 AC_MSG_RESULT([$enable_posix_osd])
 304 if test x$enable_posix_osd != xno; then
 305         AC_DEFINE(POSIX_OSD, 1, Enable POSIX OSD)
 306         AC_DEFINE(UOSS_SUPPORT, 1, Enable user-level OSS)
 307         AC_DEFINE(LUSTRE_ULEVEL_MT, 1, Multi-threaded user-level lustre port)
 308         enable_uoss='yes'
 309         enable_ulevel_mt='yes'
 310         enable_modules='no'
 311         enable_client='no'
 312         enable_tests='no'
 313         enable_liblustre='no'
 314         with_ldiskfs=no
 315 fi
 316 ])
 317
 318 #
 319 # LB_PATH_SNMP
 320 #
 321 # check for in-tree snmp support
 322 #
 323 AC_DEFUN([LB_PATH_SNMP],
 324 [LB_CHECK_FILE([$srcdir/snmp/lustre-snmp.c],[SNMP_DIST_SUBDIR="snmp"])
 325 AC_SUBST(SNMP_DIST_SUBDIR)
 326 AC_SUBST(SNMP_SUBDIR)
 327 ])
 328
 329 #
 330 # LB_CONFIG_MODULES
 331 #
 332 # Build kernel modules?
 333 #
 334 AC_DEFUN([LB_CONFIG_MODULES],
 335 [AC_MSG_CHECKING([whether to build kernel modules])
 336 AC_ARG_ENABLE([modules],
 337         AC_HELP_STRING([--disable-modules],
 338                         [disable building of Lustre kernel modules]),
 339         [],[
 340                 LC_TARGET_SUPPORTED([
 341                         enable_modules='yes'
 342                 ],[
 343                         enable_modules='no'
 344                 ])
 345         ])
 346 AC_MSG_RESULT([$enable_modules ($target_os)])
 347
 348 if test x$enable_modules = xyes ; then
 349         case $target_os in
 350                 linux*)
 351                         LB_PROG_LINUX
 352                         LN_PROG_LINUX
 353                         LC_PROG_LINUX
 354                         ;;
 355                 darwin*)
 356                         LB_PROG_DARWIN
 357                         ;;
 358                 *)
 359                         # This is strange - Lustre supports a target we don't
 360                         AC_MSG_ERROR([Modules are not supported on $target_os])
 361                         ;;
 362         esac
 363 fi
 364 ])
 365
 366 #
 367 # LB_CONFIG_UTILS
 368 #
 369 # Build utils?
 370 #
 371 AC_DEFUN([LB_CONFIG_UTILS],
 372 [AC_MSG_CHECKING([whether to build utilities])
 373 AC_ARG_ENABLE([utils],
 374         AC_HELP_STRING([--disable-utils],
 375                         [disable building of Lustre utility programs]),
 376         [],[enable_utils='yes'])
 377 AC_MSG_RESULT([$enable_utils])
 378 if test x$enable_utils = xyes ; then
 379         LB_CONFIG_INIT_SCRIPTS
 380 fi
 381 ])
 382
 383 #
 384 # LB_CONFIG_TESTS
 385 #
 386 # Build tests?
 387 #
 388 AC_DEFUN([LB_CONFIG_TESTS],
 389 [AC_MSG_CHECKING([whether to build Lustre tests])
 390 AC_ARG_ENABLE([tests],
 391         AC_HELP_STRING([--disable-tests],
 392                         [disable building of Lustre tests]),
 393         [],
 394         [
 395                 enable_tests='yes'
 396         ])
 397 AC_MSG_RESULT([$enable_tests])
 398 ])
 399
 400 #
 401 # LB_CONFIG_DOCS
 402 #
 403 # Build docs?
 404 #
 405 AC_DEFUN([LB_CONFIG_DOCS],
 406 [AC_MSG_CHECKING([whether to build docs])
 407 AC_ARG_ENABLE(doc,
 408         AC_HELP_STRING([--disable-doc],
 409                         [skip creation of pdf documentation]),
 410         [
 411                 if test x$enable_doc = xyes ; then
 412                     ENABLE_DOC=1
 413                 else
 414                     ENABLE_DOC=0
 415                 fi
 416         ],[
 417                 ENABLE_DOC=0
 418                 enable_doc='no'
 419         ])
 420 AC_MSG_RESULT([$enable_doc])
 421 AC_SUBST(ENABLE_DOC)
 422 ])
 423
 424 #
 425 # LB_CONFIG_INIT_SCRIPTS
 426 #
 427 # our init scripts only work on red hat linux
 428 #
 429 AC_DEFUN([LB_CONFIG_INIT_SCRIPTS],
 430 [ENABLE_INIT_SCRIPTS=0
 431 if test x$enable_utils = xyes ; then
 432         AC_MSG_CHECKING([whether to install init scripts])
 433         # our scripts only work on red hat systems
 434         if test -f /etc/init.d/functions -a -f /etc/sysconfig/network ; then
 435                 ENABLE_INIT_SCRIPTS=1
 436                 AC_MSG_RESULT([yes])
 437         else
 438                 AC_MSG_RESULT([no])
 439         fi
 440 fi
 441 AC_SUBST(ENABLE_INIT_SCRIPTS)
 442 ])
 443
 444 #
 445 # LB_CONFIG_HEADERS
 446 #
 447 # add -include config.h
 448 #
 449 AC_DEFUN([LB_CONFIG_HEADERS],
 450 [AC_CONFIG_HEADERS([config.h])
 451 CPPFLAGS="-include \$(top_builddir)/config.h $CPPFLAGS"
 452 EXTRA_KCFLAGS="-include $PWD/config.h $EXTRA_KCFLAGS"
 453 AC_SUBST(EXTRA_KCFLAGS)
 454 ])
 455
 456 #
 457 # LB_INCLUDE_RULES
 458 #
 459 # defines for including the toplevel Rules
 460 #
 461 AC_DEFUN([LB_INCLUDE_RULES],
 462 [INCLUDE_RULES="include $PWD/Rules"
 463 AC_SUBST(INCLUDE_RULES)
 464 ])
 465
 466 #
 467 # LB_PATH_DEFAULTS
 468 #
 469 # 'fixup' default paths
 470 #
 471 AC_DEFUN([LB_PATH_DEFAULTS],
 472 [# directories for binaries
 473 AC_PREFIX_DEFAULT([/usr])
 474
 475 sysconfdir='/etc'
 476 AC_SUBST(sysconfdir)
 477
 478 # Directories for documentation and demos.
 479 docdir='${datadir}/doc/$(PACKAGE)'
 480 AC_SUBST(docdir)
 481
 482 LN_PATH_DEFAULTS
 483 LC_PATH_DEFAULTS
 484
 485 ])
 486
 487 #
 488 # LB_PROG_CC
 489 #
 490 # checks on the C compiler
 491 #
 492 AC_DEFUN([LB_PROG_CC],
 493 [AC_PROG_RANLIB
 494 AC_MSG_CHECKING([for buggy compiler])
 495 CC_VERSION=`$CC -v 2>&1 | grep "^gcc version"`
 496 bad_cc() {
 497         AC_MSG_RESULT([buggy compiler found!])
 498         echo
 499         echo "   '$CC_VERSION'"
 500         echo "  has been known to generate bad code, "
 501         echo "  please get an updated compiler."
 502         AC_MSG_ERROR([sorry])
 503 }
 504 case "$CC_VERSION" in
 505         "gcc version 2.95"*)
 506                 bad_cc
 507                 ;;
 508         # ost_pack_niobuf putting 64bit NTOH temporaries on the stack
 509         # without "sub    $0xc,%esp" to protect the stack from being
 510         # stomped on by interrupts (bug 606)
 511         "gcc version 2.96 20000731 (Red Hat Linux 7.1 2.96-98)")
 512                 bad_cc
 513                 ;;
 514         # mandrake's similar sub 0xc compiler bug
 515         # http://marc.theaimsgroup.com/?l=linux-kernel&m=104748366226348&w=2
 516         "gcc version 2.96 20000731 (Mandrake Linux 8.1 2.96-0.62mdk)")
 517                 bad_cc
 518                 ;;
 519         *)
 520                 AC_MSG_RESULT([no known problems])
 521                 ;;
 522 esac
 523
 524 # ---------  unsigned long long sane? -------
 525 AC_CHECK_SIZEOF(unsigned long long, 0)
 526 echo "---> size SIZEOF $SIZEOF_unsigned_long_long"
 527 echo "---> size SIZEOF $ac_cv_sizeof_unsigned_long_long"
 528 if test $ac_cv_sizeof_unsigned_long_long != 8 ; then
 529         AC_MSG_ERROR([** we assume that sizeof(long long) == 8.  Tell phil@clusterfs.com])
 530 fi
 531
 532 # FIXME
 533 AC_CHECK_DECL([__i386__], [], [
 534
 535 if test x$enable_bgl != xyes; then
 536 AC_MSG_CHECKING([if $CC accepts -m64])
 537 CC_save="$CC"
 538 CC="$CC -m64"
 539 AC_TRY_COMPILE([],[],[
 540         AC_MSG_RESULT([yes])
 541 ],[
 542         AC_MSG_RESULT([no])
 543         CC="$CC_save"
 544 ])
 545 fi
 546
 547 ])
 548
 549 CPPFLAGS="-I\$(top_builddir)/lnet/include -I\$(top_srcdir)/lnet/include -I\$(top_builddir)/lustre/include -I\$(top_srcdir)/lustre/include $CPPFLAGS"
 550
 551 LLCPPFLAGS="-D__arch_lib__ -D_LARGEFILE64_SOURCE=1"
 552 AC_SUBST(LLCPPFLAGS)
 553
 554 LLCFLAGS="-g -Wall -fPIC"
 555 AC_SUBST(LLCFLAGS)
 556
 557 # everyone builds against lnet and lustre
 558 EXTRA_KCFLAGS="$EXTRA_KCFLAGS -g -I$PWD/lnet/include -I$PWD/lustre/include"
 559 AC_SUBST(EXTRA_KCFLAGS)
 560 ])
 561
 562 #
 563 # LB_CONTITIONALS
 564 #
 565 # AM_CONDITIONAL instances for everything
 566 # (so that portals/lustre can disable some if needed)
 567 AC_DEFUN([LB_CONDITIONALS],
 568 [AM_CONDITIONAL(MODULES, test x$enable_modules = xyes)
 569 AM_CONDITIONAL(UTILS, test x$enable_utils = xyes)
 570 AM_CONDITIONAL(TESTS, test x$enable_tests = xyes)
 571 AM_CONDITIONAL(DOC, test x$ENABLE_DOC = x1)
 572 AM_CONDITIONAL(INIT_SCRIPTS, test x$ENABLE_INIT_SCRIPTS = "x1")
 573 AM_CONDITIONAL(LINUX, test x$lb_target_os = "xlinux")
 574 AM_CONDITIONAL(DARWIN, test x$lb_target_os = "xdarwin")
 575 AM_CONDITIONAL(CRAY_XT3, test x$enable_cray_xt3 = "xyes")
 576 AM_CONDITIONAL(SUNOS, test x$lb_target_os = "xSunOS")
 577
 578 # this lets lustre cancel libsysio, per-branch or if liblustre is
 579 # disabled
 580 if test "x$LIBSYSIO_SUBDIR" = xlibsysio ; then
 581         if test "x$with_sysio" != xyes ; then
 582                 SYSIO=""
 583                 LIBSYSIO_SUBDIR=""
 584         fi
 585 fi
 586 AC_SUBST(LIBSYSIO_SUBDIR)
 587 AC_SUBST(SYSIO)
 588
 589 LB_LINUX_CONDITIONALS
 590 LB_DARWIN_CONDITIONALS
 591
 592 LN_CONDITIONALS
 593 LC_CONDITIONALS
 594 ])
 595
 596 #
 597 # LB_CONFIG_FILES
 598 #
 599 # build-specific config files
 600 #
 601 AC_DEFUN([LB_CONFIG_FILES],
 602 [
 603 AC_CONFIG_FILES(
 604 [Makefile
 605 autoMakefile
 606 ]
 607 [Rules:build/Rules.in]
 608 AC_PACKAGE_TARNAME[.spec]
 609 )
 610 ])
 611
 612 #
 613 # LB_CONFIGURE
 614 #
 615 # main configure steps
 616 #
 617 AC_DEFUN([LB_CONFIGURE],
 618 [LB_CANONICAL_SYSTEM
 619
 620 LB_INCLUDE_RULES
 621
 622 LB_CONFIG_CRAY_XT3
 623 LB_CONFIG_BGL
 624 LB_PATH_DEFAULTS
 625
 626 LB_PROG_CC
 627
 628 LB_PATH_DMU
 629 LB_POSIX_OSD
 630
 631 LB_CONFIG_DOCS
 632 LB_CONFIG_UTILS
 633 LB_CONFIG_TESTS
 634 LC_CONFIG_CLIENT_SERVER
 635
 636 # three macros for cmd3
 637 LC_CONFIG_SPLIT
 638 LC_CONFIG_LDISKFS
 639 LN_CONFIG_CDEBUG
 640
 641 LB_CONFIG_MODULES
 642
 643 LB_PATH_LIBSYSIO
 644 LB_PATH_SNMP
 645 LB_PATH_LDISKFS
 646
 647 LC_CONFIG_LIBLUSTRE
 648 LN_CONFIGURE
 649
 650 LC_CONFIGURE
 651
 652 if test "$SNMP_DIST_SUBDIR" ; then
 653         LS_CONFIGURE
 654 fi
 655
 656 LB_CONDITIONALS
 657 LB_CONFIG_HEADERS
 658
 659 LB_CONFIG_FILES
 660 LN_CONFIG_FILES
 661 LC_CONFIG_FILES
 662 if test "$SNMP_DIST_SUBDIR" ; then
 663         LS_CONFIG_FILES
 664 fi
 665
 666 AC_SUBST(ac_configure_args)
 667
 668 MOSTLYCLEANFILES='.*.cmd .*.flags *.o *.ko *.mod.c .depend .*.1.* Modules.symvers Module.symvers'
 669 AC_SUBST(MOSTLYCLEANFILES)
 670
 671 AC_OUTPUT
 672
 673 cat <<_ACEOF
 674
 675 CC:            $CC
 676 LD:            $LD
 677 CPPFLAGS:      $CPPFLAGS
 678 LLCPPFLAGS:    $LLCPPFLAGS
 679 CFLAGS:        $CFLAGS
 680 EXTRA_KCFLAGS: $EXTRA_KCFLAGS
 681 LLCFLAGS:      $LLCFLAGS
 682
 683 Type 'make' to build Lustre.
 684 _ACEOF
 685 ])