build/autoconf/lustre-build.m4

   1 #
   2 # LB_CHECK_VERSION
   3 #
   4 # Verify that LUSTRE_VERSION was defined properly
   5 #
   6 AC_DEFUN([LB_CHECK_VERSION],
   7 [if test "LUSTRE_VERSION" = "LUSTRE""_VERSION" ; then
   8         AC_MSG_ERROR([This script was not built with a version number.])
   9 fi
  10 ])
  11
  12 #
  13 # LB_CANONICAL_SYSTEM
  14 #
  15 # fixup $target_os for use in other places
  16 #
  17 AC_DEFUN([LB_CANONICAL_SYSTEM],
  18 [case $target_os in
  19         linux*)
  20                 lb_target_os="linux"
  21                 ;;
  22         darwin*)
  23                 lb_target_os="darwin"
  24                 ;;
  25         solaris*)
  26                 lb_target_os="SunOS"
  27                 ;;esac
  28 AC_SUBST(lb_target_os)
  29 ])
  30
  31 #
  32 # LB_DOWNSTREAM_RELEASE
  33 #
  34 AC_DEFUN([LB_DOWNSTREAM_RELEASE],
  35 [AC_ARG_WITH([downstream-release],
  36         AC_HELP_STRING([--with-downstream-release=string],
  37                        [set a string in the BUILD_VERSION and RPM Release: (default is nothing)]),
  38         [DOWNSTREAM_RELEASE=$with_downstream_release],
  39         [
  40         # if not specified, see if it's in the META file
  41         if test -f META; then
  42                 DOWNSTREAM_RELEASE=$(sed -ne '/^LOCAL_VERSION =/s/.*= *//p' META)
  43         fi
  44         ])
  45 AC_SUBST(DOWNSTREAM_RELEASE)
  46 ])
  47
  48 #
  49 # LB_BUILDID
  50 #
  51 # Check if the source is a GA release and if not, set a "BUILDID"
  52 #
  53 # Currently there are at least two ways/modes of/for doing this.  One
  54 # is if we are in a valid git repository, the other is if we are in a
  55 # non-git source tree of some form.  Building the latter from the former
  56 # will be handled here.
  57 AC_DEFUN([LB_BUILDID],
  58 [
  59 AC_MSG_CHECKING([for buildid])
  60 BUILDID=""
  61 if git branch >/dev/null 2>&1; then
  62         ffw=0
  63         hash=""
  64         ver=$(git describe --match v[[0-9]]_*_[[0-9]]* --tags)
  65         if [[[ $ver = *-*-* ]]]; then
  66                 hash=${ver##*-}
  67                 ffw=${ver#*-}
  68                 ffw=${ffw%-*}
  69                 ver=${ver%%-*}
  70         fi
  71         # it's tempting to use [[ $ver =~ ^v([0-9]+_)+([0-9]+|RC[0-9]+)$ ]]
  72         # here but the portability of the regex on the right is dismal
  73         # (thanx suse)
  74         if echo "$ver" | egrep -q "^v([[0-9]]+_)+([[0-9]]+|RC[[0-9]]+)$"; then
  75                 ver=$(echo $ver | sed -e 's/^v\(.*\)/\1/' \
  76                                       -e 's/_RC[[0-9]].*$//' -e 's/_/./g')
  77         fi
  78
  79         # a "lustre fix" value of .0 should be truncated
  80         if [[[ $ver = *.*.*.0 ]]]; then
  81                 ver=${ver%.0}
  82         fi
  83         # ditto for a "lustre fix" value of _0
  84         if [[[ $ver = v*_*_*_0 ]]]; then
  85                 ver=${ver%_0}
  86         fi
  87         if [[[ $ver = v*_*_* ]]]; then
  88                 ver=${ver#v}
  89                 ver=${ver//_/.}
  90         fi
  91
  92         # only do this test for lustre (not ldiskfs)
  93         if test "$PACKAGE" = "lustre" -a "$ver" != "$VERSION"; then
  94                 AC_MSG_WARN([most recent tag found: $ver does not match current version $VERSION.])
  95         fi
  96
  97         if test "$ffw" != "0"; then
  98                 BUILDID="$hash"
  99                 msg="$BUILDID (ahead by $ffw commits)"
 100                 AC_MSG_RESULT([$msg])
 101         else
 102                 AC_MSG_RESULT([none... congratulations, you must be on a tag])
 103         fi
 104 elif test -f META; then
 105         BUILDID=$(sed -ne '/^BUILDID =/s/.*= *//p' META)
 106         msg="$BUILDID (from META file)"
 107         AC_MSG_RESULT([$msg])
 108 else
 109         AC_MSG_WARN([FIXME: I don't know how to deal with source trees outside of git that don't have a META file.  Not setting a buildid.])
 110 fi
 111 AC_SUBST(BUILDID)
 112 ])
 113
 114 #
 115 # LB_CHECK_FILE
 116 #
 117 # Check for file existance even when cross compiling
 118 #
 119 AC_DEFUN([LB_CHECK_FILE],
 120 [AS_VAR_PUSHDEF([lb_File], [lb_cv_file_$1])dnl
 121 AC_CACHE_CHECK([for $1], lb_File,
 122 [if test -r "$1"; then
 123         AS_VAR_SET(lb_File, yes)
 124 else
 125         AS_VAR_SET(lb_File, no)
 126 fi])
 127 AS_IF([test AS_VAR_GET(lb_File) = yes], [$2], [$3])[]dnl
 128 AS_VAR_POPDEF([lb_File])dnl
 129 ])# LB_CHECK_FILE
 130
 131
 132 #
 133 # LB_ARG_LIBS_INCLUDES
 134 #
 135 # support for --with-foo, --with-foo-includes, and --with-foo-libs in
 136 # a single magical macro
 137 #
 138 AC_DEFUN([LB_ARG_LIBS_INCLUDES],
 139 [lb_pathvar="m4_bpatsubst([$2], -, _)"
 140 AC_MSG_CHECKING([for $1])
 141 AC_ARG_WITH([$2],
 142         AC_HELP_STRING([--with-$2=path],
 143                 [path to $1]),
 144         [],[withval=$4])
 145
 146 if test x$withval = xyes ; then
 147         eval "$lb_pathvar='$3'"
 148 else
 149         eval "$lb_pathvar='$withval'"
 150 fi
 151 AC_MSG_RESULT([${!lb_pathvar:-no}])
 152
 153 if test x${!lb_pathvar} != x -a x${!lb_pathvar} != xno ; then
 154         AC_MSG_CHECKING([for $1 includes])
 155         AC_ARG_WITH([$2-includes],
 156                 AC_HELP_STRING([--with-$2-includes=path],
 157                         [path to $1 includes]),
 158                 [],[withval='yes'])
 159
 160         lb_includevar="${lb_pathvar}_includes"
 161         if test x$withval = xyes ; then
 162                 eval "${lb_includevar}='${!lb_pathvar}/include'"
 163         else
 164                 eval "${lb_includevar}='$withval'"
 165         fi
 166         AC_MSG_RESULT([${!lb_includevar}])
 167
 168         AC_MSG_CHECKING([for $1 libs])
 169         AC_ARG_WITH([$2-libs],
 170                 AC_HELP_STRING([--with-$2-libs=path],
 171                         [path to $1 libs]),
 172                 [],[withval='yes'])
 173
 174         lb_libvar="${lb_pathvar}_libs"
 175         if test x$withval = xyes ; then
 176                 eval "${lb_libvar}='${!lb_pathvar}/lib'"
 177         else
 178                 eval "${lb_libvar}='$withval'"
 179         fi
 180         AC_MSG_RESULT([${!lb_libvar}])
 181 fi
 182 ])
 183 ])
 184
 185 #
 186 # LB_PATH_LIBSYSIO
 187 #
 188 # Handle internal/external libsysio
 189 #
 190 AC_DEFUN([LB_PATH_LIBSYSIO],
 191 [AC_ARG_WITH([sysio],
 192         AC_HELP_STRING([--with-sysio=path],
 193                         [set path to libsysio source (default is included libsysio)]),
 194         [],[
 195                 case $lb_target_os in
 196                         linux)
 197                                 with_sysio='yes'
 198                                 ;;
 199                         *)
 200                                 with_sysio='no'
 201                                 ;;
 202                 esac
 203         ])
 204 AC_MSG_CHECKING([location of libsysio])
 205 enable_sysio="$with_sysio"
 206 case x$with_sysio in
 207         xyes)
 208                 AC_MSG_RESULT([internal])
 209                 LB_CHECK_FILE([$srcdir/libsysio/src/rmdir.c],[],[
 210                         AC_MSG_ERROR([A complete internal libsysio was not found.])
 211                 ])
 212                 LIBSYSIO_SUBDIR="libsysio"
 213                 SYSIO="$PWD/libsysio"
 214                 ;;
 215         xno)
 216                 AC_MSG_RESULT([disabled])
 217                 ;;
 218         *)
 219                 AC_MSG_RESULT([$with_sysio])
 220                 LB_CHECK_FILE([$with_sysio/lib/libsysio.a],[],[
 221                         AC_MSG_ERROR([A complete (built) external libsysio was not found.])
 222                 ])
 223                 SYSIO=$with_sysio
 224                 with_sysio="yes"
 225                 ;;
 226 esac
 227
 228 # We have to configure even if we don't build here for make dist to work
 229 AC_CONFIG_SUBDIRS(libsysio)
 230 ])
 231
 232 #
 233 # LB_PATH_LUSTREIOKIT
 234 #
 235 # Handle internal/external lustre-iokit
 236 #
 237 AC_DEFUN([LB_PATH_LUSTREIOKIT],
 238 [AC_ARG_WITH([lustre-iokit],
 239         AC_HELP_STRING([--with-lustre-iokit=path],
 240                         [set path to lustre-iokit source (default is included lustre-iokit)]),
 241         [],[
 242                         with_lustre_iokit='yes'
 243         ])
 244 AC_MSG_CHECKING([location of lustre-iokit])
 245 enable_lustre_iokit="$with_lustre_iokit"
 246 case x$with_lustre_iokit in
 247         xyes)
 248                 AC_MSG_RESULT([internal])
 249                 LB_CHECK_FILE([$srcdir/lustre-iokit/ior-survey/ior-survey],[],[
 250                         AC_MSG_ERROR([A complete internal lustre-iokit was not found.])
 251                 ])
 252                 LUSTREIOKIT_SUBDIR="lustre-iokit"
 253                 LUSTREIOKIT="$PWD/lustre-iokit"
 254                 ;;
 255         xno)
 256                 AC_MSG_RESULT([disabled])
 257                 ;;
 258         *)
 259                 AC_MSG_RESULT([$with_lustre_iokit])
 260                 LB_CHECK_FILE([$with_lustre_iokit/ior-survey/ior_survey],[],[
 261                         AC_MSG_ERROR([A complete (built) external lustre-iokit was not found.])
 262                 ])
 263                 LUSTREIOKIT="$with_lustre_iokit"
 264                 ;;
 265 esac
 266 AC_SUBST(LUSTREIOKIT_SUBDIR)
 267 # We have to configure even if we don't build here for make dist to work
 268 AC_CONFIG_SUBDIRS(lustre-iokit)
 269 ])
 270
 271 # Define no libcfs by default.
 272 AC_DEFUN([LB_LIBCFS_DIR],
 273 [
 274 case x$libcfs_is_module in
 275         xyes)
 276           LIBCFS_INCLUDE_DIR="libcfs/include"
 277           LIBCFS_SUBDIR="libcfs"
 278           ;;
 279         x*)
 280           LIBCFS_INCLUDE_DIR="lnet/include"
 281           LIBCFS_SUBDIR=""
 282           ;;
 283 esac
 284 AC_SUBST(LIBCFS_SUBDIR)
 285 AC_SUBST(LIBCFS_INCLUDE_DIR)
 286 ])
 287
 288 #
 289 # LB_CONFIG_BGL
 290 #
 291 # Enable BGL features
 292 #
 293 AC_DEFUN([LB_CONFIG_BGL],
 294 [AC_MSG_CHECKING([whether to build BGL features])
 295 AC_ARG_ENABLE([bgl],
 296         AC_HELP_STRING([--enable-bgl],
 297                         [enable building of BGL features]),
 298         [enable_bgl='yes'],[enable_bgl='no'])
 299 AC_MSG_RESULT([$enable_bgl])
 300 if test x$enable_bgl != xno; then
 301         AC_DEFINE(HAVE_BGL_SUPPORT, 1, Enable BGL Features)
 302         enable_doc='no'
 303         enable_tests='no'
 304         enable_server='no'
 305         enable_liblustre='no'
 306         enable_libreadline='no'
 307 fi
 308 ])
 309
 310 #
 311 # LB_PATH_SNMP
 312 #
 313 # check for in-tree snmp support
 314 #
 315 AC_DEFUN([LB_PATH_SNMP],
 316 [LB_CHECK_FILE([$srcdir/snmp/lustre-snmp.c],[SNMP_DIST_SUBDIR="snmp"])
 317 AC_SUBST(SNMP_DIST_SUBDIR)
 318 AC_SUBST(SNMP_SUBDIR)
 319 ])
 320
 321 #
 322 # LB_CONFIG_MODULES
 323 #
 324 # Build kernel modules?
 325 #
 326 AC_DEFUN([LB_CONFIG_MODULES],
 327 [AC_MSG_CHECKING([whether to build kernel modules])
 328 AC_ARG_ENABLE([modules],
 329         AC_HELP_STRING([--disable-modules],
 330                         [disable building of Lustre kernel modules]),
 331         [],[
 332                 LC_TARGET_SUPPORTED([
 333                         enable_modules='yes'
 334                 ],[
 335                         enable_modules='no'
 336                 ])
 337         ])
 338 AC_MSG_RESULT([$enable_modules ($target_os)])
 339
 340 if test x$enable_modules = xyes ; then
 341         case $target_os in
 342                 linux*)
 343                         LB_PROG_LINUX
 344                         LIBCFS_PROG_LINUX
 345                         LN_PROG_LINUX
 346                         LC_PROG_LINUX
 347                         ;;
 348                 darwin*)
 349                         LB_PROG_DARWIN
 350                         LIBCFS_PROG_DARWIN
 351                         ;;
 352                 *)
 353                         # This is strange - Lustre supports a target we don't
 354                         AC_MSG_ERROR([Modules are not supported on $target_os])
 355                         ;;
 356         esac
 357 fi
 358 ])
 359
 360 #
 361 # LB_CONFIG_UTILS
 362 #
 363 # Build utils?
 364 #
 365 AC_DEFUN([LB_CONFIG_UTILS],
 366 [AC_MSG_CHECKING([whether to build utilities])
 367 AC_ARG_ENABLE([utils],
 368         AC_HELP_STRING([--disable-utils],
 369                         [disable building of Lustre utility programs]),
 370         [],[enable_utils='yes'])
 371 AC_MSG_RESULT([$enable_utils])
 372 if test x$enable_utils = xyes ; then
 373         LB_CONFIG_INIT_SCRIPTS
 374 fi
 375 ])
 376
 377 #
 378 # LB_CONFIG_TESTS
 379 #
 380 # Build tests?
 381 #
 382 AC_DEFUN([LB_CONFIG_TESTS],
 383 [AC_MSG_CHECKING([whether to build Lustre tests])
 384 AC_ARG_ENABLE([tests],
 385         AC_HELP_STRING([--disable-tests],
 386                         [disable building of Lustre tests]),
 387         [],
 388         [
 389                 enable_tests='yes'
 390         ])
 391 AC_MSG_RESULT([$enable_tests])
 392 ])
 393
 394 #
 395 # LB_CONFIG_DIST
 396 #
 397 # Just enough configure so that "make dist" is useful
 398 #
 399 # this simply re-adjusts some defaults, which of course can be overridden
 400 # on the configure line after the --for-dist option
 401 #
 402 AC_DEFUN([LB_CONFIG_DIST],
 403 [AC_MSG_CHECKING([whether to configure just enough for make dist])
 404 AC_ARG_ENABLE([dist],
 405         AC_HELP_STRING([--enable-dist],
 406                         [only configure enough for make dist]),
 407         [enable_dist='yes'],[enable_dist='no'])
 408 AC_MSG_RESULT([$enable_dist])
 409 if test x$enable_dist != xno; then
 410         enable_modules='no'
 411         enable_utils='no'
 412         enable_liblustre='no'
 413         enable_doc='no'
 414         enable_tests='no'
 415 fi
 416 ])
 417
 418 #
 419 # LB_CONFIG_DOCS
 420 #
 421 # Build docs?
 422 #
 423 AC_DEFUN([LB_CONFIG_DOCS],
 424 [AC_MSG_CHECKING([whether to build docs])
 425 AC_ARG_ENABLE(doc,
 426         AC_HELP_STRING([--disable-doc],
 427                         [skip creation of pdf documentation]),
 428         [
 429                 if test x$enable_doc = xyes ; then
 430                     ENABLE_DOC=1
 431                 else
 432                     ENABLE_DOC=0
 433                 fi
 434         ],[
 435                 ENABLE_DOC=0
 436                 enable_doc='no'
 437         ])
 438 AC_MSG_RESULT([$enable_doc])
 439 AC_SUBST(ENABLE_DOC)
 440 ])
 441
 442 #
 443 # LB_CONFIG_INIT_SCRIPTS
 444 #
 445 # our init scripts only work on red hat linux
 446 #
 447 AC_DEFUN([LB_CONFIG_INIT_SCRIPTS],
 448 [ENABLE_INIT_SCRIPTS=0
 449 if test x$enable_utils = xyes ; then
 450         AC_MSG_CHECKING([whether to install init scripts])
 451         # our scripts only work on red hat systems
 452         if test -f /etc/init.d/functions -a -f /etc/sysconfig/network ; then
 453                 ENABLE_INIT_SCRIPTS=1
 454                 AC_MSG_RESULT([yes])
 455         else
 456                 AC_MSG_RESULT([no])
 457         fi
 458 fi
 459 AC_SUBST(ENABLE_INIT_SCRIPTS)
 460 ])
 461
 462 #
 463 # LB_CONFIG_HEADERS
 464 #
 465 # add -include config.h
 466 #
 467 AC_DEFUN([LB_CONFIG_HEADERS],[
 468         AC_CONFIG_HEADERS([config.h])
 469         CPPFLAGS="-include $PWD/config.h $CPPFLAGS"
 470         EXTRA_KCFLAGS="-include $PWD/config.h $EXTRA_KCFLAGS"
 471         AC_SUBST(EXTRA_KCFLAGS)
 472 ])
 473
 474 #
 475 # LB_INCLUDE_RULES
 476 #
 477 # defines for including the toplevel Rules
 478 #
 479 AC_DEFUN([LB_INCLUDE_RULES],[
 480         INCLUDE_RULES="include $PWD/Rules"
 481         AC_SUBST(INCLUDE_RULES)
 482 ])
 483
 484 #
 485 # LB_PATH_DEFAULTS
 486 #
 487 # 'fixup' default paths
 488 #
 489 AC_DEFUN([LB_PATH_DEFAULTS],
 490 [# directories for binaries
 491 AC_PREFIX_DEFAULT([/usr])
 492
 493 sysconfdir='/etc'
 494 AC_SUBST(sysconfdir)
 495
 496 # Directories for documentation and demos.
 497 docdir='${datadir}/doc/$(PACKAGE)'
 498 AC_SUBST(docdir)
 499
 500 LIBCFS_PATH_DEFAULTS
 501 LN_PATH_DEFAULTS
 502 LC_PATH_DEFAULTS
 503
 504 ])
 505
 506 #
 507 # LB_PROG_CC
 508 #
 509 # checks on the C compiler
 510 #
 511 AC_DEFUN([LB_PROG_CC],
 512 [AC_PROG_RANLIB
 513
 514 # ---------  unsigned long long sane? -------
 515 AC_CHECK_SIZEOF(unsigned long long, 0)
 516 echo "---> size SIZEOF $SIZEOF_unsigned_long_long"
 517 echo "---> size SIZEOF $ac_cv_sizeof_unsigned_long_long"
 518 if test $ac_cv_sizeof_unsigned_long_long != 8 ; then
 519         AC_MSG_ERROR([** we assume that sizeof(long long) == 8.])
 520 fi
 521
 522 if test $target_cpu == "powerpc64"; then
 523         AC_MSG_WARN([set compiler with -m64])
 524         CFLAGS="$CFLAGS -m64"
 525         CC="$CC -m64"
 526 fi
 527
 528 CPPFLAGS="-I$PWD/$LIBCFS_INCLUDE_DIR -I$PWD/lnet/include -I$PWD/lustre/include $CPPFLAGS"
 529
 530 LLCPPFLAGS="-D__arch_lib__ -D_LARGEFILE64_SOURCE=1"
 531 AC_SUBST(LLCPPFLAGS)
 532
 533 # Add _GNU_SOURCE for strnlen on linux
 534 LLCFLAGS="-g -Wall -fPIC -D_GNU_SOURCE"
 535 AC_SUBST(LLCFLAGS)
 536
 537 CCASFLAGS="-Wall -fPIC -D_GNU_SOURCE"
 538 AC_SUBST(CCASFLAGS)
 539
 540 # everyone builds against lnet and lustre
 541 EXTRA_KCFLAGS="$EXTRA_KCFLAGS -g -I$PWD/$LIBCFS_INCLUDE_DIR -I$PWD/lnet/include -I$PWD/lustre/include"
 542 AC_SUBST(EXTRA_KCFLAGS)
 543 ])
 544
 545 #
 546 # LB_CONTITIONALS
 547 #
 548 # AM_CONDITIONAL instances for everything
 549 # (so that portals/lustre can disable some if needed)
 550 AC_DEFUN([LB_CONDITIONALS],
 551 [AM_CONDITIONAL(MODULES, test x$enable_modules = xyes)
 552 AM_CONDITIONAL(UTILS, test x$enable_utils = xyes)
 553 AM_CONDITIONAL(TESTS, test x$enable_tests = xyes)
 554 AM_CONDITIONAL(DOC, test x$ENABLE_DOC = x1)
 555 AM_CONDITIONAL(INIT_SCRIPTS, test x$ENABLE_INIT_SCRIPTS = "x1")
 556 AM_CONDITIONAL(LINUX, test x$lb_target_os = "xlinux")
 557 AM_CONDITIONAL(DARWIN, test x$lb_target_os = "xdarwin")
 558 AM_CONDITIONAL(SUNOS, test x$lb_target_os = "xSunOS")
 559 AM_CONDITIONAL(USES_DPKG, test x$uses_dpkg = "xyes")
 560 AM_CONDITIONAL(ARCH_x86, test x$target_cpu = "xx86_64" -o x$target_cpu = "xi686")
 561
 562 # this lets lustre cancel libsysio, per-branch or if liblustre is
 563 # disabled
 564 if test "x$LIBSYSIO_SUBDIR" = xlibsysio ; then
 565         if test "x$with_sysio" != xyes ; then
 566                 SYSIO=""
 567                 LIBSYSIO_SUBDIR=""
 568         fi
 569 fi
 570 AC_SUBST(LIBSYSIO_SUBDIR)
 571 AC_SUBST(SYSIO)
 572
 573 LB_DARWIN_CONDITIONALS
 574
 575 LIBCFS_CONDITIONALS
 576 LN_CONDITIONALS
 577 LC_CONDITIONALS
 578 ])
 579
 580 #
 581 # LB_CONFIG_FILES
 582 #
 583 # build-specific config files
 584 #
 585 AC_DEFUN([LB_CONFIG_FILES],
 586 [
 587         AC_CONFIG_FILES([
 588                 Makefile
 589                 autoMakefile]
 590                 [Rules:build/Rules.in]
 591                 AC_PACKAGE_TARNAME[.spec]
 592         )
 593 ])
 594
 595 #
 596 # LB_CONFIGURE
 597 #
 598 # main configure steps
 599 #
 600 AC_DEFUN([LB_CONFIGURE],
 601 [LB_CANONICAL_SYSTEM
 602
 603 LB_CONFIG_DIST
 604
 605 LB_DOWNSTREAM_RELEASE
 606 LB_USES_DPKG
 607 LB_BUILDID
 608
 609 LB_LIBCFS_DIR
 610
 611 LB_INCLUDE_RULES
 612
 613 LB_CONFIG_BGL
 614 LB_PATH_DEFAULTS
 615
 616 LB_PROG_CC
 617
 618 LC_OSD_ADDON
 619
 620 LB_CONFIG_DOCS
 621 LB_CONFIG_UTILS
 622 LB_CONFIG_TESTS
 623 LC_CONFIG_CLIENT_SERVER
 624
 625 # two macros for cmd3
 626 m4_ifdef([LC_CONFIG_SPLIT], [LC_CONFIG_SPLIT])
 627 LN_CONFIG_CDEBUG
 628 LC_QUOTA
 629
 630 LB_CONFIG_MODULES
 631 LN_CONFIG_USERSPACE
 632
 633 LB_PATH_LIBSYSIO
 634 LB_PATH_SNMP
 635 LB_PATH_LDISKFS
 636 LB_PATH_ZFS
 637 LB_PATH_LUSTREIOKIT
 638
 639 LB_DEFINE_E2FSPROGS_NAMES
 640
 641 LC_CONFIG_LIBLUSTRE
 642 LIBCFS_CONFIGURE
 643 LN_CONFIGURE
 644
 645 LC_CONFIGURE
 646
 647 if test "$SNMP_DIST_SUBDIR" ; then
 648         LS_CONFIGURE
 649 fi
 650
 651
 652 LB_CONDITIONALS
 653 LB_CONFIG_HEADERS
 654
 655 LIBCFS_CONFIG_FILES
 656 LB_CONFIG_FILES
 657 LN_CONFIG_FILES
 658 LC_CONFIG_FILES
 659 if test "$SNMP_DIST_SUBDIR" ; then
 660         LS_CONFIG_FILES
 661 fi
 662
 663 AC_SUBST(ac_configure_args)
 664
 665 MOSTLYCLEANFILES='.*.cmd .*.flags *.o *.ko *.mod.c .depend .*.1.* Modules.symvers Module.symvers'
 666 AC_SUBST(MOSTLYCLEANFILES)
 667
 668 AC_OUTPUT
 669
 670 cat <<_ACEOF
 671
 672 CC:            $CC
 673 LD:            $LD
 674 CPPFLAGS:      $CPPFLAGS
 675 LLCPPFLAGS:    $LLCPPFLAGS
 676 CFLAGS:        $CFLAGS
 677 EXTRA_KCFLAGS: $EXTRA_KCFLAGS
 678 LLCFLAGS:      $LLCFLAGS
 679
 680 Type 'make' to build Lustre.
 681 _ACEOF
 682 ])