build/autoconf/lustre-build.m4

   1 #
   2 # LB_CHECK_VERSION
   3 #
   4 # Verify that LUSTRE_VERSION was defined properly
   5 #
   6 AC_DEFUN([LB_CHECK_VERSION],
   7 [if test "LUSTRE_VERSION" = "LUSTRE""_VERSION" ; then
   8         AC_MSG_ERROR([This script was not built with a version number.])
   9 fi
  10 ])
  11
  12 #
  13 # LB_CANONICAL_SYSTEM
  14 #
  15 # fixup $target_os for use in other places
  16 #
  17 AC_DEFUN([LB_CANONICAL_SYSTEM],
  18 [case $target_os in
  19         linux*)
  20                 lb_target_os="linux"
  21                 ;;
  22         darwin*)
  23                 lb_target_os="darwin"
  24                 ;;
  25         solaris*)
  26                 lb_target_os="SunOS"
  27                 ;;esac
  28 AC_SUBST(lb_target_os)
  29 ])
  30
  31 #
  32 # LB_CHECK_FILE
  33 #
  34 # Check for file existance even when cross compiling
  35 #
  36 AC_DEFUN([LB_CHECK_FILE],
  37 [AS_VAR_PUSHDEF([lb_File], [lb_cv_file_$1])dnl
  38 AC_CACHE_CHECK([for $1], lb_File,
  39 [if test -r "$1"; then
  40   AS_VAR_SET(lb_File, yes)
  41 else
  42   AS_VAR_SET(lb_File, no)
  43 fi])
  44 AS_IF([test AS_VAR_GET(lb_File) = yes], [$2], [$3])[]dnl
  45 AS_VAR_POPDEF([lb_File])dnl
  46 ])# LB_CHECK_FILE
  47
  48 #
  49 # LB_CHECK_FILES
  50 #
  51 # LB_CHECK_FILE over multiple files
  52 #
  53 AC_DEFUN([LB_CHECK_FILES],
  54 [AC_FOREACH([AC_FILE_NAME], [$1],
  55   [LB_CHECK_FILE(AC_FILE_NAME,
  56                  [AC_DEFINE_UNQUOTED([AS_TR_CPP(HAVE_[]AC_FILE_NAME)], 1,
  57                                     [Define to 1 if you have the
  58                                      file `]AC_File['.])
  59 $2],
  60                  [$3])])])
  61
  62 #
  63 # LB_ARG_LIBS_INCLUDES
  64 #
  65 # support for --with-foo, --with-foo-includes, and --with-foo-libs in
  66 # a single magical macro
  67 #
  68 AC_DEFUN([LB_ARG_LIBS_INCLUDES],
  69 [lb_pathvar="m4_bpatsubst([$2], -, _)"
  70 AC_MSG_CHECKING([for $1])
  71 AC_ARG_WITH([$2],
  72         AC_HELP_STRING([--with-$2=path],
  73                 [path to $1]),
  74         [],[withval=$4])
  75
  76 if test x$withval = xyes ; then
  77         eval "$lb_pathvar='$3'"
  78 else
  79         eval "$lb_pathvar='$withval'"
  80 fi
  81 AC_MSG_RESULT([${!lb_pathvar:-no}])
  82
  83 if test x${!lb_pathvar} != x -a x${!lb_pathvar} != xno ; then
  84         AC_MSG_CHECKING([for $1 includes])
  85         AC_ARG_WITH([$2-includes],
  86                 AC_HELP_STRING([--with-$2-includes=path],
  87                         [path to $1 includes]),
  88                 [],[withval='yes'])
  89
  90         lb_includevar="${lb_pathvar}_includes"
  91         if test x$withval = xyes ; then
  92                 eval "${lb_includevar}='${!lb_pathvar}/include'"
  93         else
  94                 eval "${lb_includevar}='$withval'"
  95         fi
  96         AC_MSG_RESULT([${!lb_includevar}])
  97
  98         AC_MSG_CHECKING([for $1 libs])
  99         AC_ARG_WITH([$2-libs],
 100                 AC_HELP_STRING([--with-$2-libs=path],
 101                         [path to $1 libs]),
 102                 [],[withval='yes'])
 103
 104         lb_libvar="${lb_pathvar}_libs"
 105         if test x$withval = xyes ; then
 106                 eval "${lb_libvar}='${!lb_pathvar}/lib'"
 107         else
 108                 eval "${lb_libvar}='$withval'"
 109         fi
 110         AC_MSG_RESULT([${!lb_libvar}])
 111 fi
 112 ])
 113 ])
 114
 115 #
 116 # LB_PATH_LIBSYSIO
 117 #
 118 # Handle internal/external libsysio
 119 #
 120 AC_DEFUN([LB_PATH_LIBSYSIO],
 121 [AC_ARG_WITH([sysio],
 122         AC_HELP_STRING([--with-sysio=path],
 123                         [set path to libsysio source (default is included libsysio)]),
 124         [],[
 125                 case $lb_target_os in
 126                         linux)
 127                                 with_sysio='yes'
 128                                 ;;
 129                         *)
 130                                 with_sysio='no'
 131                                 ;;
 132                 esac
 133         ])
 134 AC_MSG_CHECKING([location of libsysio])
 135 enable_sysio="$with_sysio"
 136 case x$with_sysio in
 137         xyes)
 138                 AC_MSG_RESULT([internal])
 139                 LB_CHECK_FILE([$srcdir/libsysio/src/rmdir.c],[],[
 140                         AC_MSG_ERROR([A complete internal libsysio was not found.])
 141                 ])
 142                 LIBSYSIO_SUBDIR="libsysio"
 143                 SYSIO="$PWD/libsysio"
 144                 ;;
 145         xno)
 146                 AC_MSG_RESULT([disabled])
 147                 ;;
 148         *)
 149                 AC_MSG_RESULT([$with_sysio])
 150                 LB_CHECK_FILE([$with_sysio/lib/libsysio.a],[],[
 151                         AC_MSG_ERROR([A complete (built) external libsysio was not found.])
 152                 ])
 153                 SYSIO=$with_sysio
 154                 with_sysio="yes"
 155                 ;;
 156 esac
 157
 158 # We have to configure even if we don't build here for make dist to work
 159 AC_CONFIG_SUBDIRS(libsysio)
 160 ])
 161
 162 #
 163 # LB_PATH_LUSTREIOKIT
 164 #
 165 # Handle internal/external lustre-iokit
 166 #
 167 AC_DEFUN([LB_PATH_LUSTREIOKIT],
 168 [AC_ARG_WITH([],
 169         AC_HELP_STRING([--with-lustre-iokit=path],
 170                         [set path to lustre-iokit source (default is included lustre-iokit)]),
 171         [],[
 172                         with_lustre_iokit='yes'
 173         ])
 174 AC_MSG_CHECKING([location of lustre-iokit])
 175 enable_lustre_iokit="$with_lustre_iokit"
 176 case x$with_lustre_iokit in
 177         xyes)
 178                 AC_MSG_RESULT([internal])
 179                 LB_CHECK_FILE([$srcdir/lustre-iokit/ior-survey/ior-survey],[],[
 180                         AC_MSG_ERROR([A complete internal lustre-iokit was not found.])
 181                 ])
 182                 LUSTREIOKIT_SUBDIR="lustre-iokit"
 183                 LUSTREIOKIT="$PWD/lustre-iokit"
 184                 ;;
 185         xno)
 186                 AC_MSG_RESULT([disabled])
 187                 ;;
 188         *)
 189                 AC_MSG_RESULT([$with_lustre_iokit])
 190                 LB_CHECK_FILE([$with_lustre_iokit/ior-survey/ior_survey],[],[
 191                         AC_MSG_ERROR([A complete (built) external lustre-iokit was not found.])
 192                 ])
 193                 LUSTREIOKIT="$with_lustre_iokit"
 194                 with_lustre_iokit="yes"
 195                 ;;
 196 esac
 197 AC_SUBST(LUSTREIOKIT_SUBDIR)
 198 # We have to configure even if we don't build here for make dist to work
 199 AC_CONFIG_SUBDIRS(lustre-iokit)
 200 ])
 201
 202 #
 203 # LB_PATH_LDISKFS
 204 #
 205 # Handle internal/external ldiskfs
 206 #
 207 AC_DEFUN([LB_PATH_LDISKFS],
 208 [AC_ARG_WITH([ldiskfs],
 209         AC_HELP_STRING([--with-ldiskfs=path],
 210                         [set path to ldiskfs source (default is included ldiskfs)]),
 211         [],[
 212                 if test x$linux25$enable_server = xyesyes ; then
 213                         with_ldiskfs=yes
 214                 else
 215                         with_ldiskfs=no
 216                 fi
 217         ])
 218 AC_MSG_CHECKING([location of ldiskfs])
 219 case x$with_ldiskfs in
 220         xyes)
 221                 AC_MSG_RESULT([internal])
 222                 LB_CHECK_FILE([$srcdir/ldiskfs/lustre-ldiskfs.spec.in],[],[
 223                         AC_MSG_ERROR([A complete internal ldiskfs was not found.])
 224                 ])
 225                 LDISKFS_SUBDIR="ldiskfs"
 226                 LDISKFS_DIR="$PWD/ldiskfs"
 227                 ;;
 228         xno)
 229                 AC_MSG_RESULT([disabled])
 230                 ;;
 231         *)
 232                 AC_MSG_RESULT([$with_ldiskfs])
 233                 LB_CHECK_FILE([$with_ldiskfs/ldiskfs/linux/ldiskfs_fs.h],[],[
 234                         AC_MSG_ERROR([A complete (built) external ldiskfs was not found.])
 235                 ])
 236                 LDISKFS_DIR=$with_ldiskfs
 237                 ;;
 238 esac
 239 AC_SUBST(LDISKFS_DIR)
 240 AC_SUBST(LDISKFS_SUBDIR)
 241 AM_CONDITIONAL(LDISKFS_ENABLED, test x$with_ldiskfs != xno)
 242
 243 # We have to configure even if we don't build here for make dist to work
 244 AC_CONFIG_SUBDIRS(ldiskfs)
 245 ])
 246
 247 # Define no libcfs by default.
 248 AC_DEFUN([LB_LIBCFS_DIR],
 249 [
 250 case x$libcfs_is_module in
 251         xyes)
 252           LIBCFS_INCLUDE_DIR="libcfs/include"
 253           LIBCFS_SUBDIR="libcfs"
 254           ;;
 255         x*)
 256           LIBCFS_INCLUDE_DIR="lnet/include"
 257           LIBCFS_SUBDIR=""
 258           ;;
 259 esac
 260 AC_SUBST(LIBCFS_SUBDIR)
 261 AC_SUBST(LIBCFS_INCLUDE_DIR)
 262 ])
 263
 264 #
 265 # LB_DEFINE_LDISKFS_OPTIONS
 266 #
 267 # Enable config options related to ldiskfs.  These are used both by ldiskfs
 268 # and lvfs (which includes ldiskfs headers.)
 269 #
 270 AC_DEFUN([LB_DEFINE_LDISKFS_OPTIONS],
 271 [
 272         AC_DEFINE(CONFIG_LDISKFS_FS_MODULE, 1, [build ldiskfs as a module])
 273         AC_DEFINE(CONFIG_LDISKFS_FS_XATTR, 1, [enable extended attributes for ldiskfs])
 274         AC_DEFINE(CONFIG_LDISKFS_FS_POSIX_ACL, 1, [enable posix acls for ldiskfs])
 275         AC_DEFINE(CONFIG_LDISKFS_FS_SECURITY, 1, [enable fs security for ldiskfs])
 276         AC_DEFINE(CONFIG_LDISKFSDEV_FS_POSIX_ACL, 1, [enable posix acls for ldiskfs])
 277         AC_DEFINE(CONFIG_LDISKFSDEV_FS_XATTR, 1, [enable extented attributes for ldiskfs])
 278         AC_DEFINE(CONFIG_LDISKFSDEV_FS_SECURITY, 1, [enable fs security for ldiskfs])
 279 ])
 280
 281 #
 282 # LB_DEFINE_E2FSPROGS_NAMES
 283 #
 284 # Enable the use of alternate naming of ldiskfs-enabled e2fsprogs package.
 285 #
 286 AC_DEFUN([LB_DEFINE_E2FSPROGS_NAMES],
 287 [AC_ARG_WITH([ldiskfsprogs],
 288         AC_HELP_STRING([--with-ldiskfsprogs],
 289                        [use alternate names for ldiskfs-enabled e2fsprogs]),
 290         [],[withval='no'])
 291
 292 if test x$withval = xyes ; then
 293         AC_DEFINE(HAVE_LDISKFSPROGS, 1, [enable use of ldiskfsprogs package])
 294         E2FSPROGS="ldiskfsprogs"
 295         MKE2FS="mkfs.ldiskfs"
 296         DEBUGFS="debug.ldiskfs"
 297         TUNE2FS="tune.ldiskfs"
 298         E2LABEL="label.ldiskfs"
 299         DUMPE2FS="dump.ldiskfs"
 300         E2FSCK="fsck.ldiskfs"
 301         AC_MSG_RESULT([enabled])
 302 else
 303         E2FSPROGS="e2fsprogs"
 304         MKE2FS="mke2fs"
 305         DEBUGFS="debugfs"
 306         TUNE2FS="tune2fs"
 307         E2LABEL="e2label"
 308         DUMPE2FS="dumpe2fs"
 309         E2FSCK="e2fsck"
 310         AC_MSG_RESULT([disabled])
 311 fi
 312         AC_DEFINE_UNQUOTED(E2FSPROGS, "$E2FSPROGS", [name of ldiskfs e2fsprogs package])
 313         AC_DEFINE_UNQUOTED(MKE2FS, "$MKE2FS", [name of ldiskfs mkfs program])
 314         AC_DEFINE_UNQUOTED(DEBUGFS, "$DEBUGFS", [name of ldiskfs debug program])
 315         AC_DEFINE_UNQUOTED(TUNE2FS, "$TUNE2FS", [name of ldiskfs tune program])
 316         AC_DEFINE_UNQUOTED(E2LABEL, "$E2LABEL", [name of ldiskfs label program])
 317         AC_DEFINE_UNQUOTED(DUMPE2FS,"$DUMPE2FS", [name of ldiskfs dump program])
 318         AC_DEFINE_UNQUOTED(E2FSCK, "$E2FSCK", [name of ldiskfs fsck program])
 319 ])
 320
 321 #
 322 # LB_DEFINE_E2FSPROGS_NAMES
 323 #
 324 # Enable the use of alternate naming of ldiskfs-enabled e2fsprogs package.
 325 #
 326 AC_DEFUN([LB_DEFINE_E2FSPROGS_NAMES],
 327 [AC_ARG_WITH([ldiskfsprogs],
 328         AC_HELP_STRING([--with-ldiskfsprogs],
 329                        [use alternate names for ldiskfs-enabled e2fsprogs]),
 330         [],[withval='no'])
 331
 332 if test x$withval = xyes ; then
 333         AC_DEFINE(HAVE_LDISKFSPROGS, 1, [enable use of ldiskfsprogs package])
 334         E2FSPROGS="ldiskfsprogs"
 335         MKE2FS="mkfs.ldiskfs"
 336         DEBUGFS="debug.ldiskfs"
 337         TUNE2FS="tune.ldiskfs"
 338         E2LABEL="label.ldiskfs"
 339         DUMPE2FS="dump.ldiskfs"
 340         E2FSCK="fsck.ldiskfs"
 341         AC_MSG_RESULT([enabled])
 342 else
 343         E2FSPROGS="e2fsprogs"
 344         MKE2FS="mke2fs"
 345         DEBUGFS="debugfs"
 346         TUNE2FS="tune2fs"
 347         E2LABEL="e2label"
 348         DUMPE2FS="dumpe2fs"
 349         E2FSCK="e2fsck"
 350         AC_MSG_RESULT([disabled])
 351 fi
 352         AC_DEFINE_UNQUOTED(E2FSPROGS, "$E2FSPROGS", [name of ldiskfs e2fsprogs package])
 353         AC_DEFINE_UNQUOTED(MKE2FS, "$MKE2FS", [name of ldiskfs mkfs program])
 354         AC_DEFINE_UNQUOTED(DEBUGFS, "$DEBUGFS", [name of ldiskfs debug program])
 355         AC_DEFINE_UNQUOTED(TUNE2FS, "$TUNE2FS", [name of ldiskfs tune program])
 356         AC_DEFINE_UNQUOTED(E2LABEL, "$E2LABEL", [name of ldiskfs label program])
 357         AC_DEFINE_UNQUOTED(DUMPE2FS,"$DUMPE2FS", [name of ldiskfs dump program])
 358         AC_DEFINE_UNQUOTED(E2FSCK, "$E2FSCK", [name of ldiskfs fsck program])
 359 ])
 360
 361 #
 362 # LB_DEFINE_E2FSPROGS_NAMES
 363 #
 364 # Enable the use of alternate naming of ldiskfs-enabled e2fsprogs package.
 365 #
 366 AC_DEFUN([LB_DEFINE_E2FSPROGS_NAMES],
 367 [AC_ARG_WITH([ldiskfsprogs],
 368         AC_HELP_STRING([--with-ldiskfsprogs],
 369                        [use alternate names for ldiskfs-enabled e2fsprogs]),
 370         [],[withval='no'])
 371
 372 if test x$withval = xyes ; then
 373         AC_DEFINE(HAVE_LDISKFSPROGS, 1, [enable use of ldiskfsprogs package])
 374         E2FSPROGS="ldiskfsprogs"
 375         MKE2FS="mkfs.ldiskfs"
 376         DEBUGFS="debug.ldiskfs"
 377         TUNE2FS="tune.ldiskfs"
 378         E2LABEL="label.ldiskfs"
 379         DUMPE2FS="dump.ldiskfs"
 380         E2FSCK="fsck.ldiskfs"
 381         AC_MSG_RESULT([enabled])
 382 else
 383         E2FSPROGS="e2fsprogs"
 384         MKE2FS="mke2fs"
 385         DEBUGFS="debugfs"
 386         TUNE2FS="tune2fs"
 387         E2LABEL="e2label"
 388         DUMPE2FS="dumpe2fs"
 389         E2FSCK="e2fsck"
 390         AC_MSG_RESULT([disabled])
 391 fi
 392         AC_DEFINE_UNQUOTED(E2FSPROGS, "$E2FSPROGS", [name of ldiskfs e2fsprogs package])
 393         AC_DEFINE_UNQUOTED(MKE2FS, "$MKE2FS", [name of ldiskfs mkfs program])
 394         AC_DEFINE_UNQUOTED(DEBUGFS, "$DEBUGFS", [name of ldiskfs debug program])
 395         AC_DEFINE_UNQUOTED(TUNE2FS, "$TUNE2FS", [name of ldiskfs tune program])
 396         AC_DEFINE_UNQUOTED(E2LABEL, "$E2LABEL", [name of ldiskfs label program])
 397         AC_DEFINE_UNQUOTED(DUMPE2FS,"$DUMPE2FS", [name of ldiskfs dump program])
 398         AC_DEFINE_UNQUOTED(E2FSCK, "$E2FSCK", [name of ldiskfs fsck program])
 399 ])
 400
 401 #
 402 # LB_CONFIG_CRAY_XT3
 403 #
 404 # Enable Cray XT3 features
 405 #
 406 AC_DEFUN([LB_CONFIG_CRAY_XT3],
 407 [AC_MSG_CHECKING([whether to build Cray XT3 features])
 408 AC_ARG_ENABLE([cray_xt3],
 409         AC_HELP_STRING([--enable-cray-xt3],
 410                         [enable building of Cray XT3 features]),
 411         [enable_cray_xt3='yes'],[enable_cray_xt3='no'])
 412 AC_MSG_RESULT([$enable_cray_xt3])
 413 if test x$enable_cray_xt3 != xno; then
 414         AC_DEFINE(CRAY_XT3, 1, Enable Cray XT3 Features)
 415 fi
 416 ])
 417
 418 #
 419 # LB_CONFIG_BGL
 420 #
 421 # Enable BGL features
 422 #
 423 AC_DEFUN([LB_CONFIG_BGL],
 424 [AC_MSG_CHECKING([whether to build BGL features])
 425 AC_ARG_ENABLE([bgl],
 426         AC_HELP_STRING([--enable-bgl],
 427                         [enable building of BGL features]),
 428         [enable_bgl='yes'],[enable_bgl='no'])
 429 AC_MSG_RESULT([$enable_bgl])
 430 if test x$enable_bgl != xno; then
 431         AC_DEFINE(HAVE_BGL_SUPPORT, 1, Enable BGL Features)
 432         enable_doc='no'
 433         enable_tests='no'
 434         enable_server='no'
 435         enable_liblustre='no'
 436         enable_libreadline='no'
 437 fi
 438 ])
 439
 440 #
 441 # Support for --enable-uoss
 442 #
 443 AC_DEFUN([LB_UOSS],
 444 [AC_MSG_CHECKING([whether to enable uoss])
 445 AC_ARG_ENABLE([uoss],
 446         AC_HELP_STRING([--enable-uoss],
 447                         [enable userspace OSS]),
 448         [enable_uoss='yes'],[enable_uoss='no'])
 449 AC_MSG_RESULT([$enable_uoss])
 450 if test x$enable_uoss = xyes; then
 451         AC_DEFINE(UOSS_SUPPORT, 1, Enable user-level OSS)
 452         AC_DEFINE(LUSTRE_ULEVEL_MT, 1, Multi-threaded user-level lustre port)
 453         enable_uoss='yes'
 454         enable_ulevel_mt='yes'
 455         enable_modules='no'
 456         enable_client='no'
 457         enable_tests='no'
 458         enable_liblustre='no'
 459         with_ldiskfs='no'
 460 fi
 461 AC_SUBST(enable_uoss)
 462 ])
 463
 464 #
 465 # Support for --enable-posix-osd
 466 #
 467 AC_DEFUN([LB_POSIX_OSD],
 468 [AC_MSG_CHECKING([whether to enable posix osd])
 469 AC_ARG_ENABLE([posix-osd],
 470         AC_HELP_STRING([--enable-posix-osd],
 471                         [enable using of posix osd]),
 472         [enable_posix_osd='yes'],[enable_posix_osd='no'])
 473 AC_MSG_RESULT([$enable_posix_osd])
 474 if test x$enable_uoss = xyes -a x$enable_posix_osd = xyes ; then
 475         AC_DEFINE(POSIX_OSD, 1, Enable POSIX OSD)
 476         posix_osd='yes'
 477 fi
 478 AM_CONDITIONAL(POSIX_OSD_ENABLED, test x$posix_osd = xyes)
 479 ])
 480
 481 #
 482 # LB_PATH_DMU
 483 #
 484 AC_DEFUN([LB_PATH_DMU],
 485 [AC_ARG_ENABLE([dmu],
 486         AC_HELP_STRING([--enable-dmu],
 487                        [enable the DMU backend]),
 488         [],[with_dmu='default'])
 489 AC_MSG_CHECKING([whether to enable DMU])
 490 case x$with_dmu in
 491         xyes)
 492                 dmu_osd='yes'
 493                 ;;
 494         xno)
 495                 dmu_osd='no'
 496                 ;;
 497         xdefault)
 498                 if test x$enable_uoss = xyes -a x$posix_osd != xyes; then
 499                         # Enable the DMU if we're configuring a userspace server
 500                         dmu_osd='yes'
 501                 else
 502                         # Enable the DMU by default on the b_hd_kdmu branch
 503                         if test -d $PWD/zfs -a x$linux25$enable_server = xyesyes; then
 504                                 dmu_osd='yes'
 505                         else
 506                                 dmu_osd='no'
 507                         fi
 508                 fi
 509                 ;;
 510         *)
 511                 dmu_osd='yes'
 512                 ;;
 513 esac
 514 AC_MSG_RESULT([$dmu_osd])
 515 if test x$dmu_osd = xyes; then
 516         AC_DEFINE(DMU_OSD, 1, Enable DMU OSD)
 517         if test x$enable_uoss = xyes; then
 518                 # Userspace DMU
 519                 DMU_SRC="$PWD/lustre/zfs-lustre"
 520                 AC_SUBST(DMU_SRC)
 521                 LB_CHECK_FILE([$DMU_SRC/src/.patched],[],[
 522                         AC_MSG_ERROR([A complete (patched) DMU tree was not found.])
 523                 ])
 524                 AC_CONFIG_SUBDIRS(lustre/zfs-lustre)
 525         else
 526                 # Kernel DMU
 527                 SPL_SUBDIR="spl"
 528                 ZFS_SUBDIR="zfs"
 529
 530                 SPL_DIR="$PWD/$SPL_SUBDIR"
 531                 ZFS_DIR="$PWD/$ZFS_SUBDIR"
 532
 533                 LB_CHECK_FILE([$SPL_DIR/module/spl/spl-generic.c],[],[
 534                         AC_MSG_ERROR([A complete SPL tree was not found in $SPL_DIR.])
 535                 ])
 536
 537                 LB_CHECK_FILE([$ZFS_DIR/module/zfs/dmu.c],[],[
 538                         AC_MSG_ERROR([A complete kernel DMU tree was not found in $ZFS_DIR.])
 539                 ])
 540
 541                 AC_CONFIG_SUBDIRS(spl)
 542                 ac_configure_args="$ac_configure_args --with-spl=$SPL_DIR"
 543                 AC_CONFIG_SUBDIRS(zfs)
 544         fi
 545 fi
 546 AC_SUBST(SPL_SUBDIR)
 547 AC_SUBST(ZFS_SUBDIR)
 548 AC_SUBST(SPL_DIR)
 549 AC_SUBST(ZFS_DIR)
 550 AM_CONDITIONAL(DMU_OSD_ENABLED, test x$dmu_osd = xyes)
 551 AM_CONDITIONAL(KDMU, test x$dmu_osd$enable_uoss = xyesno)
 552 ])
 553
 554 #
 555 # LB_PATH_SNMP
 556 #
 557 # check for in-tree snmp support
 558 #
 559 AC_DEFUN([LB_PATH_SNMP],
 560 [LB_CHECK_FILE([$srcdir/snmp/lustre-snmp.c],[SNMP_DIST_SUBDIR="snmp"])
 561 AC_SUBST(SNMP_DIST_SUBDIR)
 562 AC_SUBST(SNMP_SUBDIR)
 563 ])
 564
 565 #
 566 # LB_CONFIG_MODULES
 567 #
 568 # Build kernel modules?
 569 #
 570 AC_DEFUN([LB_CONFIG_MODULES],
 571 [AC_MSG_CHECKING([whether to build kernel modules])
 572 AC_ARG_ENABLE([modules],
 573         AC_HELP_STRING([--disable-modules],
 574                         [disable building of Lustre kernel modules]),
 575         [],[
 576                 LC_TARGET_SUPPORTED([
 577                         enable_modules='yes'
 578                 ],[
 579                         enable_modules='no'
 580                 ])
 581         ])
 582 AC_MSG_RESULT([$enable_modules ($target_os)])
 583
 584 if test x$enable_modules = xyes ; then
 585         case $target_os in
 586                 linux*)
 587                         LB_PROG_LINUX
 588                         LIBCFS_PROG_LINUX
 589                         LN_PROG_LINUX
 590                         LC_PROG_LINUX
 591                         ;;
 592                 darwin*)
 593                         LB_PROG_DARWIN
 594                         LIBCFS_PROG_DARWIN
 595                         ;;
 596                 *)
 597                         # This is strange - Lustre supports a target we don't
 598                         AC_MSG_ERROR([Modules are not supported on $target_os])
 599                         ;;
 600         esac
 601 fi
 602 ])
 603
 604 #
 605 # LB_CONFIG_UTILS
 606 #
 607 # Build utils?
 608 #
 609 AC_DEFUN([LB_CONFIG_UTILS],
 610 [AC_MSG_CHECKING([whether to build utilities])
 611 AC_ARG_ENABLE([utils],
 612         AC_HELP_STRING([--disable-utils],
 613                         [disable building of Lustre utility programs]),
 614         [],[enable_utils='yes'])
 615 AC_MSG_RESULT([$enable_utils])
 616 if test x$enable_utils = xyes ; then
 617         LB_CONFIG_INIT_SCRIPTS
 618 fi
 619 ])
 620
 621 #
 622 # LB_CONFIG_TESTS
 623 #
 624 # Build tests?
 625 #
 626 AC_DEFUN([LB_CONFIG_TESTS],
 627 [AC_MSG_CHECKING([whether to build Lustre tests])
 628 AC_ARG_ENABLE([tests],
 629         AC_HELP_STRING([--disable-tests],
 630                         [disable building of Lustre tests]),
 631         [],
 632         [
 633                 enable_tests='yes'
 634         ])
 635 AC_MSG_RESULT([$enable_tests])
 636 ])
 637
 638 #
 639 # LB_CONFIG_DOCS
 640 #
 641 # Build docs?
 642 #
 643 AC_DEFUN([LB_CONFIG_DOCS],
 644 [AC_MSG_CHECKING([whether to build docs])
 645 AC_ARG_ENABLE(doc,
 646         AC_HELP_STRING([--disable-doc],
 647                         [skip creation of pdf documentation]),
 648         [
 649                 if test x$enable_doc = xyes ; then
 650                     ENABLE_DOC=1
 651                 else
 652                     ENABLE_DOC=0
 653                 fi
 654         ],[
 655                 ENABLE_DOC=0
 656                 enable_doc='no'
 657         ])
 658 AC_MSG_RESULT([$enable_doc])
 659 AC_SUBST(ENABLE_DOC)
 660 ])
 661
 662 #
 663 # LB_CONFIG_INIT_SCRIPTS
 664 #
 665 # our init scripts only work on red hat linux
 666 #
 667 AC_DEFUN([LB_CONFIG_INIT_SCRIPTS],
 668 [ENABLE_INIT_SCRIPTS=0
 669 if test x$enable_utils = xyes ; then
 670         AC_MSG_CHECKING([whether to install init scripts])
 671         # our scripts only work on red hat systems
 672         if test -f /etc/init.d/functions -a -f /etc/sysconfig/network ; then
 673                 ENABLE_INIT_SCRIPTS=1
 674                 AC_MSG_RESULT([yes])
 675         else
 676                 AC_MSG_RESULT([no])
 677         fi
 678 fi
 679 AC_SUBST(ENABLE_INIT_SCRIPTS)
 680 ])
 681
 682 #
 683 # LB_CONFIG_HEADERS
 684 #
 685 # add -include config.h
 686 #
 687 AC_DEFUN([LB_CONFIG_HEADERS],
 688 [AC_CONFIG_HEADERS([config.h])
 689 CPPFLAGS="-include \$(top_builddir)/config.h $CPPFLAGS"
 690 EXTRA_KCFLAGS="-include $PWD/config.h $EXTRA_KCFLAGS"
 691 AC_SUBST(EXTRA_KCFLAGS)
 692 ])
 693
 694 #
 695 # LB_INCLUDE_RULES
 696 #
 697 # defines for including the toplevel Rules
 698 #
 699 AC_DEFUN([LB_INCLUDE_RULES],
 700 [INCLUDE_RULES="include $PWD/Rules"
 701 AC_SUBST(INCLUDE_RULES)
 702 ])
 703
 704 #
 705 # LB_PATH_DEFAULTS
 706 #
 707 # 'fixup' default paths
 708 #
 709 AC_DEFUN([LB_PATH_DEFAULTS],
 710 [# directories for binaries
 711 AC_PREFIX_DEFAULT([/usr])
 712
 713 sysconfdir='/etc'
 714 AC_SUBST(sysconfdir)
 715
 716 # Directories for documentation and demos.
 717 docdir='${datadir}/doc/$(PACKAGE)'
 718 AC_SUBST(docdir)
 719
 720 LIBCFS_PATH_DEFAULTS
 721 LN_PATH_DEFAULTS
 722 LC_PATH_DEFAULTS
 723
 724 ])
 725
 726 #
 727 # LB_PROG_CC
 728 #
 729 # checks on the C compiler
 730 #
 731 AC_DEFUN([LB_PROG_CC],
 732 [AC_PROG_RANLIB
 733 AC_MSG_CHECKING([for buggy compiler])
 734 CC_VERSION=`$CC -v 2>&1 | grep "^gcc version"`
 735 bad_cc() {
 736         AC_MSG_RESULT([buggy compiler found!])
 737         echo
 738         echo "   '$CC_VERSION'"
 739         echo "  has been known to generate bad code, "
 740         echo "  please get an updated compiler."
 741         AC_MSG_ERROR([sorry])
 742 }
 743 case "$CC_VERSION" in
 744         "gcc version 2.95"*)
 745                 bad_cc
 746                 ;;
 747         # ost_pack_niobuf putting 64bit NTOH temporaries on the stack
 748         # without "sub    $0xc,%esp" to protect the stack from being
 749         # stomped on by interrupts (bug 606)
 750         "gcc version 2.96 20000731 (Red Hat Linux 7.1 2.96-98)")
 751                 bad_cc
 752                 ;;
 753         # mandrake's similar sub 0xc compiler bug
 754         # http://marc.theaimsgroup.com/?l=linux-kernel&m=104748366226348&w=2
 755         "gcc version 2.96 20000731 (Mandrake Linux 8.1 2.96-0.62mdk)")
 756                 bad_cc
 757                 ;;
 758         *)
 759                 AC_MSG_RESULT([no known problems])
 760                 ;;
 761 esac
 762
 763 # ---------  unsigned long long sane? -------
 764 AC_CHECK_SIZEOF(unsigned long long, 0)
 765 echo "---> size SIZEOF $SIZEOF_unsigned_long_long"
 766 echo "---> size SIZEOF $ac_cv_sizeof_unsigned_long_long"
 767 if test $ac_cv_sizeof_unsigned_long_long != 8 ; then
 768         AC_MSG_ERROR([** we assume that sizeof(long long) == 8.  Tell phil@clusterfs.com])
 769 fi
 770
 771 if test $target_cpu == "powerpc64"; then
 772         AC_MSG_WARN([set compiler with -m64])
 773         CFLAGS="$CFLAGS -m64"
 774         CC="$CC -m64"
 775 fi
 776
 777 CPPFLAGS="-I\$(top_builddir)/$LIBCFS_INCLUDE_DIR -I\$(top_srcdir)/$LIBCFS_INCLUDE_DIR-I\$(top_builddir)/lnet/include -I\$(top_srcdir)/lnet/include -I\$(top_builddir)/lustre/include -I\$(top_srcdir)/lustre/include $CPPFLAGS"
 778
 779 LLCPPFLAGS="-D__arch_lib__ -D_LARGEFILE64_SOURCE=1"
 780 AC_SUBST(LLCPPFLAGS)
 781
 782 # Add _GNU_SOURCE for strnlen on linux
 783 LLCFLAGS="-g -Wall -fPIC -D_GNU_SOURCE"
 784 AC_SUBST(LLCFLAGS)
 785
 786 # everyone builds against lnet and lustre
 787 EXTRA_KCFLAGS="$EXTRA_KCFLAGS -g -I$PWD/$LIBCFS_INCLUDE_DIR -I$PWD/lnet/include -I$PWD/lustre/include"
 788 AC_SUBST(EXTRA_KCFLAGS)
 789 ])
 790
 791 #
 792 # LB_CONTITIONALS
 793 #
 794 # AM_CONDITIONAL instances for everything
 795 # (so that portals/lustre can disable some if needed)
 796 AC_DEFUN([LB_CONDITIONALS],
 797 [AM_CONDITIONAL(MODULES, test x$enable_modules = xyes)
 798 AM_CONDITIONAL(UTILS, test x$enable_utils = xyes)
 799 AM_CONDITIONAL(TESTS, test x$enable_tests = xyes)
 800 AM_CONDITIONAL(DOC, test x$ENABLE_DOC = x1)
 801 AM_CONDITIONAL(INIT_SCRIPTS, test x$ENABLE_INIT_SCRIPTS = "x1")
 802 AM_CONDITIONAL(LINUX, test x$lb_target_os = "xlinux")
 803 AM_CONDITIONAL(DARWIN, test x$lb_target_os = "xdarwin")
 804 AM_CONDITIONAL(CRAY_XT3, test x$enable_cray_xt3 = "xyes")
 805 AM_CONDITIONAL(SUNOS, test x$lb_target_os = "xSunOS")
 806
 807 # this lets lustre cancel libsysio, per-branch or if liblustre is
 808 # disabled
 809 if test "x$LIBSYSIO_SUBDIR" = xlibsysio ; then
 810         if test "x$with_sysio" != xyes ; then
 811                 SYSIO=""
 812                 LIBSYSIO_SUBDIR=""
 813         fi
 814 fi
 815 AC_SUBST(LIBSYSIO_SUBDIR)
 816 AC_SUBST(SYSIO)
 817
 818 LB_LINUX_CONDITIONALS
 819 LB_DARWIN_CONDITIONALS
 820
 821 LIBCFS_CONDITIONALS
 822 LN_CONDITIONALS
 823 LC_CONDITIONALS
 824 ])
 825
 826 #
 827 # LB_CONFIG_FILES
 828 #
 829 # build-specific config files
 830 #
 831 AC_DEFUN([LB_CONFIG_FILES],
 832 [
 833 AC_CONFIG_FILES(
 834 [Makefile
 835 autoMakefile
 836 ]
 837 [Rules:build/Rules.in]
 838 AC_PACKAGE_TARNAME[.spec]
 839 )
 840 ])
 841
 842 #
 843 # LB_CONFIGURE
 844 #
 845 # main configure steps
 846 #
 847 AC_DEFUN([LB_CONFIGURE],
 848 [LB_CANONICAL_SYSTEM
 849
 850 LB_LIBCFS_DIR
 851
 852 LB_INCLUDE_RULES
 853
 854 LB_CONFIG_CRAY_XT3
 855 LB_CONFIG_BGL
 856 LB_PATH_DEFAULTS
 857
 858 LB_PROG_CC
 859
 860 LB_UOSS
 861 LB_POSIX_OSD
 862
 863 LB_CONFIG_DOCS
 864 LB_CONFIG_UTILS
 865 LB_CONFIG_TESTS
 866 LC_CONFIG_CLIENT_SERVER
 867
 868 # two macros for cmd3
 869 m4_ifdef([LC_CONFIG_SPLIT], [LC_CONFIG_SPLIT])
 870 LN_CONFIG_CDEBUG
 871 LC_QUOTA
 872
 873 LB_CONFIG_MODULES
 874
 875 LB_PATH_DMU
 876 LB_PATH_LIBSYSIO
 877 LB_PATH_SNMP
 878 LB_PATH_LDISKFS
 879 LB_PATH_LUSTREIOKIT
 880
 881 LB_DEFINE_E2FSPROGS_NAMES
 882
 883 LB_DEFINE_E2FSPROGS_NAMES
 884
 885 LB_DEFINE_E2FSPROGS_NAMES
 886
 887 LC_CONFIG_LIBLUSTRE
 888 LIBCFS_CONFIGURE
 889 LN_CONFIGURE
 890
 891 LC_CONFIGURE
 892
 893 if test "$SNMP_DIST_SUBDIR" ; then
 894         LS_CONFIGURE
 895 fi
 896
 897
 898 LB_CONDITIONALS
 899 LB_CONFIG_HEADERS
 900
 901 LIBCFS_CONFIG_FILES
 902 LB_CONFIG_FILES
 903 LN_CONFIG_FILES
 904 LC_CONFIG_FILES
 905 if test "$SNMP_DIST_SUBDIR" ; then
 906         LS_CONFIG_FILES
 907 fi
 908
 909 AC_SUBST(ac_configure_args)
 910
 911 MOSTLYCLEANFILES='.*.cmd .*.flags *.o *.ko *.mod.c .depend .*.1.* Modules.symvers Module.symvers'
 912 AC_SUBST(MOSTLYCLEANFILES)
 913
 914 AC_OUTPUT
 915
 916 cat <<_ACEOF
 917
 918 CC:            $CC
 919 LD:            $LD
 920 CPPFLAGS:      $CPPFLAGS
 921 LLCPPFLAGS:    $LLCPPFLAGS
 922 CFLAGS:        $CFLAGS
 923 EXTRA_KCFLAGS: $EXTRA_KCFLAGS
 924 LLCFLAGS:      $LLCFLAGS
 925
 926 Type 'make' to build Lustre.
 927 _ACEOF
 928 ])