build/autoconf/lustre-build.m4

   1 #
   2 # LB_CHECK_VERSION
   3 #
   4 # Verify that LUSTRE_VERSION was defined properly
   5 #
   6 AC_DEFUN([LB_CHECK_VERSION],
   7 [if test "LUSTRE_VERSION" = "LUSTRE""_VERSION" ; then
   8         AC_MSG_ERROR([This script was not built with a version number.])
   9 fi
  10 ])
  11
  12 #
  13 # LB_CANONICAL_SYSTEM
  14 #
  15 # fixup $target_os for use in other places
  16 #
  17 AC_DEFUN([LB_CANONICAL_SYSTEM],
  18 [case $target_os in
  19         linux*)
  20                 lb_target_os="linux"
  21                 ;;
  22         darwin*)
  23                 lb_target_os="darwin"
  24                 ;;
  25 esac
  26 AC_SUBST(lb_target_os)
  27 ])
  28
  29 #
  30 # LB_CHECK_FILE
  31 #
  32 # Check for file existance even when cross compiling
  33 #
  34 AC_DEFUN([LB_CHECK_FILE],
  35 [AS_VAR_PUSHDEF([lb_File], [lb_cv_file_$1])dnl
  36 AC_CACHE_CHECK([for $1], lb_File,
  37 [if test -r "$1"; then
  38   AS_VAR_SET(lb_File, yes)
  39 else
  40   AS_VAR_SET(lb_File, no)
  41 fi])
  42 AS_IF([test AS_VAR_GET(lb_File) = yes], [$2], [$3])[]dnl
  43 AS_VAR_POPDEF([lb_File])dnl
  44 ])# LB_CHECK_FILE
  45
  46 #
  47 # LB_CHECK_FILES
  48 #
  49 # LB_CHECK_FILE over multiple files
  50 #
  51 AC_DEFUN([LB_CHECK_FILES],
  52 [AC_FOREACH([AC_FILE_NAME], [$1],
  53   [LB_CHECK_FILE(AC_FILE_NAME,
  54                  [AC_DEFINE_UNQUOTED(AS_TR_CPP(HAVE_[]AC_FILE_NAME), 1,
  55                                     [Define to 1 if you have the
  56                                      file `]AC_File['.])
  57 $2],
  58                  [$3])])])
  59
  60 #
  61 # LB_ARG_LIBS_INCLUDES
  62 #
  63 # support for --with-foo, --with-foo-includes, and --with-foo-libs in
  64 # a single magical macro
  65 #
  66 AC_DEFUN([LB_ARG_LIBS_INCLUDES],
  67 [lb_pathvar="m4_bpatsubst([$2], -, _)"
  68 AC_MSG_CHECKING([for $1])
  69 AC_ARG_WITH([$2],
  70         AC_HELP_STRING([--with-$2=path],
  71                 [path to $1]),
  72         [],[withval=$4])
  73
  74 if test x$withval = xyes ; then
  75         eval "$lb_pathvar='$3'"
  76 else
  77         eval "$lb_pathvar='$withval'"
  78 fi
  79 AC_MSG_RESULT([${!lb_pathvar:-no}])
  80
  81 if test x${!lb_pathvar} != x -a x${!lb_pathvar} != xno ; then
  82         AC_MSG_CHECKING([for $1 includes])
  83         AC_ARG_WITH([$2-includes],
  84                 AC_HELP_STRING([--with-$2-includes=path],
  85                         [path to $1 includes]),
  86                 [],[withval='yes'])
  87
  88         lb_includevar="${lb_pathvar}_includes"
  89         if test x$withval = xyes ; then
  90                 eval "${lb_includevar}='${!lb_pathvar}/include'"
  91         else
  92                 eval "${lb_includevar}='$withval'"
  93         fi
  94         AC_MSG_RESULT([${!lb_includevar}])
  95
  96         AC_MSG_CHECKING([for $1 libs])
  97         AC_ARG_WITH([$2-libs],
  98                 AC_HELP_STRING([--with-$2-libs=path],
  99                         [path to $1 libs]),
 100                 [],[withval='yes'])
 101
 102         lb_libvar="${lb_pathvar}_libs"
 103         if test x$withval = xyes ; then
 104                 eval "${lb_libvar}='${!lb_pathvar}/lib'"
 105         else
 106                 eval "${lb_libvar}='$withval'"
 107         fi
 108         AC_MSG_RESULT([${!lb_libvar}])
 109 fi
 110 ])
 111 ])
 112
 113 #
 114 # LB_PATH_LIBSYSIO
 115 #
 116 # Handle internal/external libsysio
 117 #
 118 AC_DEFUN([LB_PATH_LIBSYSIO],
 119 [AC_ARG_WITH([sysio],
 120         AC_HELP_STRING([--with-sysio=path],
 121                         [set path to libsysio source (default is included libsysio)]),
 122         [],[
 123                 case $lb_target_os in
 124                         linux)
 125                                 with_sysio='yes'
 126                                 ;;
 127                         *)
 128                                 with_sysio='no'
 129                                 ;;
 130                 esac
 131         ])
 132 AC_MSG_CHECKING([location of libsysio])
 133 enable_sysio="$with_sysio"
 134 case x$with_sysio in
 135         xyes)
 136                 AC_MSG_RESULT([internal])
 137                 LB_CHECK_FILE([$srcdir/libsysio/src/rmdir.c],[],[
 138                         AC_MSG_ERROR([A complete internal libsysio was not found.])
 139                 ])
 140                 LIBSYSIO_SUBDIR="libsysio"
 141                 SYSIO="$PWD/libsysio"
 142                 ;;
 143         xno)
 144                 AC_MSG_RESULT([disabled])
 145                 ;;
 146         *)
 147                 AC_MSG_RESULT([$with_sysio])
 148                 LB_CHECK_FILE([$with_sysio/lib/libsysio.a],[],[
 149                         AC_MSG_ERROR([A complete (built) external libsysio was not found.])
 150                 ])
 151                 SYSIO=$with_sysio
 152                 with_sysio="yes"
 153                 ;;
 154 esac
 155
 156 # We have to configure even if we don't build here for make dist to
 157 # work
 158 AC_CONFIG_SUBDIRS(libsysio)
 159 ])
 160
 161 #
 162 # LB_PATH_CRAY_PORTALS
 163 #
 164 # Support for external Cray portals
 165 #
 166 AC_DEFUN([LB_PATH_CRAY_PORTALS],
 167 [LB_ARG_LIBS_INCLUDES([Cray Portals],[cray-portals])
 168
 169 if test x$cray_portals_includes != x ; then
 170         if test ! -r $cray_portals_includes/portals/api.h ; then
 171                 AC_MSG_ERROR([Cray portals headers were not found in $cray_portals_includes.  Please check the paths passed to --with-cray-portals or --with-cray-portals-includes.])
 172         fi
 173 fi
 174 if test x$cray_portals_libs != x ; then
 175         if test ! -r $cray_portals_libs/libportals.a ; then
 176                 AC_MSG_ERROR([Cray portals libraries were not found in $cray_portals_libs.  Please check the paths passed to --with-cray-portals or --with-cray-portals-libs.])
 177         fi
 178 fi
 179
 180 if test x$cray_portals_includes != x -a x$cray_portals_libs != x ; then
 181         cray_portals=yes
 182         AC_DEFINE(CRAY_PORTALS, 1, [Building with Cray Portals])
 183         CPPFLAGS="-I$cray_portals_includes $CPPFLAGS"
 184         EXTRA_KCFLAGS="-I$cray_portals_includes $EXTRA_KCFLAGS"
 185         # for liblustre + b_cray
 186         CRAY_PORTALS_LIBS="$cray_portals_libs"
 187         AC_SUBST(CRAY_PORTALS_LIBS)
 188 else
 189         cray_portals=no
 190 fi
 191 ])
 192
 193 #
 194 # LB_PATH_SNMP
 195 #
 196 # check for in-tree snmp support
 197 #
 198 AC_DEFUN([LB_PATH_SNMP],
 199 [LB_CHECK_FILE([$srcdir/snmp/lustre-snmp.c],[SNMP_DIST_SUBDIR="snmp"])
 200 AC_SUBST(SNMP_DIST_SUBDIR)
 201 ])
 202
 203 #
 204 # LB_CONFIG_MODULES
 205 #
 206 # Build kernel modules?
 207 #
 208 AC_DEFUN([LB_CONFIG_MODULES],
 209 [AC_MSG_CHECKING([whether to build kernel modules])
 210 AC_ARG_ENABLE([modules],
 211         AC_HELP_STRING([--disable-modules],
 212                         [disable building of Lustre kernel modules]),
 213         [],[
 214                 LC_TARGET_SUPPORTED([
 215                         enable_modules='yes'
 216                 ],[
 217                         enable_modules='no'
 218                 ])
 219         ])
 220 AC_MSG_RESULT([$enable_modules ($target_os)])
 221
 222 if test x$enable_modules = xyes ; then
 223         case $target_os in
 224                 linux*)
 225                         LB_PROG_LINUX
 226                         ;;
 227                 darwin*)
 228                         LB_PROG_DARWIN
 229                         ;;
 230                 *)
 231                         # This is strange - Lustre supports a target we don't
 232                         AC_MSG_ERROR([Modules are not supported on $target_os])
 233                         ;;
 234         esac
 235 fi
 236 ])
 237
 238 #
 239 # LB_CONFIG_UTILS
 240 #
 241 # Build utils?
 242 #
 243 AC_DEFUN([LB_CONFIG_UTILS],
 244 [AC_MSG_CHECKING([whether to build utilities])
 245 AC_ARG_ENABLE([utils],
 246         AC_HELP_STRING([--disable-utils],
 247                         [disable building of Lustre utility programs]),
 248         [],[enable_utils='yes'])
 249 AC_MSG_RESULT([$enable_utils])
 250 if test x$enable_utils = xyes ; then
 251         LB_CONFIG_INIT_SCRIPTS
 252 fi
 253 ])
 254
 255 #
 256 # LB_CONFIG_TESTS
 257 #
 258 # Build tests?
 259 #
 260 AC_DEFUN([LB_CONFIG_TESTS],
 261 [AC_MSG_CHECKING([whether to build Lustre tests])
 262 AC_ARG_ENABLE([tests],
 263         AC_HELP_STRING([--disable-tests],
 264                         [disable building of Lustre tests]),
 265         [],[enable_tests='yes'])
 266 if test x$cray_portals = xyes ; then
 267         enable_tests='no'
 268 fi
 269 AC_MSG_RESULT([$enable_tests])
 270 ])
 271
 272 #
 273 # LB_CONFIG_DOCS
 274 #
 275 # Build docs?
 276 #
 277 AC_DEFUN([LB_CONFIG_DOCS],
 278 [AC_MSG_CHECKING([whether to build docs])
 279 AC_ARG_ENABLE(doc,
 280         AC_HELP_STRING([--disable-doc],
 281                         [skip creation of pdf documentation]),
 282         [
 283                 if test x$enable_doc = xyes ; then
 284                     ENABLE_DOC=1
 285                 else
 286                     ENABLE_DOC=0
 287                 fi
 288         ],[
 289                 ENABLE_DOC=0
 290                 enable_doc='no'
 291         ])
 292 AC_MSG_RESULT([$enable_doc])
 293 AC_SUBST(ENABLE_DOC)
 294 ])
 295
 296 #
 297 # LB_CONFIG_INIT_SCRIPTS
 298 #
 299 # our init scripts only work on red hat linux
 300 #
 301 AC_DEFUN([LB_CONFIG_INIT_SCRIPTS],
 302 [ENABLE_INIT_SCRIPTS=0
 303 if test x$enable_utils = xyes ; then
 304         AC_MSG_CHECKING([whether to install init scripts])
 305         # our scripts only work on red hat systems
 306         if test -f /etc/init.d/functions -a -f /etc/sysconfig/network ; then
 307                 ENABLE_INIT_SCRIPTS=1
 308                 AC_MSG_RESULT([yes])
 309         else
 310                 AC_MSG_RESULT([no])
 311         fi
 312 fi
 313 AC_SUBST(ENABLE_INIT_SCRIPTS)
 314 ])
 315
 316 #
 317 # LB_CONFIG_HEADERS
 318 #
 319 # add -include config.h
 320 #
 321 AC_DEFUN([LB_CONFIG_HEADERS],
 322 [AC_CONFIG_HEADERS([config.h])
 323 CPPFLAGS="-include \$(top_builddir)/config.h $CPPFLAGS"
 324 EXTRA_KCFLAGS="-include $PWD/config.h $EXTRA_KCFLAGS"
 325 AC_SUBST(EXTRA_KCFLAGS)
 326 ])
 327
 328 #
 329 # LB_INCLUDE_RULES
 330 #
 331 # defines for including the toplevel Rules
 332 #
 333 AC_DEFUN([LB_INCLUDE_RULES],
 334 [INCLUDE_RULES="include $PWD/build/Rules"
 335 AC_SUBST(INCLUDE_RULES)
 336 ])
 337
 338 #
 339 # LB_PATH_DEFAULTS
 340 #
 341 # 'fixup' default paths
 342 #
 343 AC_DEFUN([LB_PATH_DEFAULTS],
 344 [# directories for binaries
 345 AC_PREFIX_DEFAULT([/usr])
 346
 347 sysconfdir='/etc'
 348 AC_SUBST(sysconfdir)
 349
 350 # Directories for documentation and demos.
 351 docdir='${datadir}/doc/$(PACKAGE)'
 352 AC_SUBST(docdir)
 353
 354 LP_PATH_DEFAULTS
 355 LC_PATH_DEFAULTS
 356 ])
 357
 358 #
 359 # LB_PROG_CC
 360 #
 361 # checks on the C compiler
 362 #
 363 AC_DEFUN([LB_PROG_CC],
 364 [AC_PROG_RANLIB
 365 AC_MSG_CHECKING([for buggy compiler])
 366 CC_VERSION=`$CC -v 2>&1 | grep "^gcc version"`
 367 bad_cc() {
 368         AC_MSG_RESULT([buggy compiler found!])
 369         echo
 370         echo "   '$CC_VERSION'"
 371         echo "  has been known to generate bad code, "
 372         echo "  please get an updated compiler."
 373         AC_MSG_ERROR([sorry])
 374 }
 375 case "$CC_VERSION" in
 376         "gcc version 2.95"*)
 377                 bad_cc
 378                 ;;
 379         # ost_pack_niobuf putting 64bit NTOH temporaries on the stack
 380         # without "sub    $0xc,%esp" to protect the stack from being
 381         # stomped on by interrupts (bug 606)
 382         "gcc version 2.96 20000731 (Red Hat Linux 7.1 2.96-98)")
 383                 bad_cc
 384                 ;;
 385         # mandrake's similar sub 0xc compiler bug
 386         # http://marc.theaimsgroup.com/?l=linux-kernel&m=104748366226348&w=2
 387         "gcc version 2.96 20000731 (Mandrake Linux 8.1 2.96-0.62mdk)")
 388                 bad_cc
 389                 ;;
 390         *)
 391                 AC_MSG_RESULT([no known problems])
 392                 ;;
 393 esac
 394
 395 # ---------  unsigned long long sane? -------
 396 AC_CHECK_SIZEOF(unsigned long long, 0)
 397 echo "---> size SIZEOF $SIZEOF_unsigned_long_long"
 398 echo "---> size SIZEOF $ac_cv_sizeof_unsigned_long_long"
 399 if test $ac_cv_sizeof_unsigned_long_long != 8 ; then
 400         AC_MSG_ERROR([** we assume that sizeof(long long) == 8.  Tell phil@clusterfs.com])
 401 fi
 402
 403 AC_MSG_CHECKING([if $CC accepts -m64])
 404 CC_save="$CC"
 405 CC="$CC -m64"
 406 AC_TRY_COMPILE([],[],[
 407         AC_MSG_RESULT([yes])
 408 ],[
 409         AC_MSG_RESULT([no])
 410         CC="$CC_save"
 411 ])
 412
 413 CPPFLAGS="-I\$(top_builddir)/portals/include -I\$(top_srcdir)/portals/include -I\$(top_builddir)/lustre/include -I\$(top_srcdir)/lustre/include $CPPFLAGS"
 414
 415 LLCPPFLAGS="-D__arch_lib__ -D_LARGEFILE64_SOURCE=1"
 416 AC_SUBST(LLCPPFLAGS)
 417
 418 LLCFLAGS="-g -Wall -fPIC"
 419 AC_SUBST(LLCFLAGS)
 420
 421 # everyone builds against portals and lustre
 422 EXTRA_KCFLAGS="$EXTRA_KCFLAGS -g -I$PWD/portals/include -I$PWD/lustre/include"
 423 AC_SUBST(EXTRA_KCFLAGS)
 424 ])
 425
 426 #
 427 # LB_CONTITIONALS
 428 #
 429 # AM_CONDITIONAL instances for everything
 430 # (so that portals/lustre can disable some if needed)
 431 AC_DEFUN([LB_CONDITIONALS],
 432 [AM_CONDITIONAL(MODULES, test x$enable_modules = xyes)
 433 AM_CONDITIONAL(UTILS, test x$enable_utils = xyes)
 434 AM_CONDITIONAL(TESTS, test x$enable_tests = xyes)
 435 AM_CONDITIONAL(DOC, test x$ENABLE_DOC = x1)
 436 AM_CONDITIONAL(CRAY_PORTALS, test x$cray_portals != xno)
 437 AM_CONDITIONAL(INIT_SCRIPTS, test x$ENABLE_INIT_SCRIPTS = "x1")
 438 AM_CONDITIONAL(LINUX, test x$lb_target_os = "xlinux")
 439 AM_CONDITIONAL(DARWIN, test x$lb_target_os = "xdarwin")
 440
 441 # this lets lustre cancel libsysio, per-branch or if liblustre is
 442 # disabled
 443 if test "x$LIBSYSIO_SUBDIR" = xlibsysio ; then
 444         if test "x$with_sysio" != xyes ; then
 445                 SYSIO=""
 446                 LIBSYSIO_SUBDIR=""
 447         fi
 448 fi
 449 AC_SUBST(LIBSYSIO_SUBDIR)
 450 AC_SUBST(SYSIO)
 451
 452 LB_LINUX_CONDITIONALS
 453 LB_DARWIN_CONDITIONALS
 454
 455 LP_CONDITIONALS
 456 LC_CONDITIONALS
 457 ])
 458
 459 #
 460 # LB_CONFIGURE
 461 #
 462 # main configure steps
 463 #
 464 AC_DEFUN([LB_CONFIGURE],
 465 [LB_CANONICAL_SYSTEM
 466
 467 LB_INCLUDE_RULES
 468
 469 LB_PATH_DEFAULTS
 470
 471 LB_PROG_CC
 472
 473 LB_PATH_LIBSYSIO
 474 LB_PATH_CRAY_PORTALS
 475 LB_PATH_SNMP
 476
 477 LB_CONFIG_DOCS
 478 LB_CONFIG_UTILS
 479 LB_CONFIG_TESTS
 480 LC_CONFIG_CLIENT_SERVER
 481
 482 LB_CONFIG_MODULES
 483
 484 LC_CONFIG_LIBLUSTRE
 485
 486 LP_CONFIGURE
 487 LC_CONFIGURE
 488 if test "$SNMP_DIST_SUBDIR" ; then
 489         LS_CONFIGURE
 490 fi
 491
 492 LB_CONDITIONALS
 493 LB_CONFIG_HEADERS
 494
 495 AC_CONFIG_FILES(
 496 [Makefile:build/Makefile.in.toplevel]
 497 [autoMakefile
 498 build/autoMakefile
 499 build/autoconf/Makefile
 500 build/Rules
 501 build/lustre.spec
 502 ])
 503
 504 LP_CONFIG_FILES
 505 LC_CONFIG_FILES
 506 if test "$SNMP_DIST_SUBDIR" ; then
 507         LS_CONFIG_FILES
 508 fi
 509
 510 AC_SUBST(ac_configure_args)
 511
 512 MOSTLYCLEANFILES='.*.cmd .*.flags *.o *.ko *.mod.c .depend .*.1.*'
 513 AC_SUBST(MOSTLYCLEANFILES)
 514
 515 AC_OUTPUT
 516
 517 cat <<_ACEOF
 518
 519 CC:            $CC
 520 LD:            $LD
 521 CPPFLAGS:      $CPPFLAGS
 522 LLCPPFLAGS:    $LLCPPFLAGS
 523 CFLAGS:        $CFLAGS
 524 EXTRA_KCFLAGS: $EXTRA_KCFLAGS
 525 LLCFLAGS:      $LLCFLAGS
 526
 527 Type 'make' to build Lustre.
 528 _ACEOF
 529 ])