build/autoconf/lustre-build.m4

   1 #
   2 # LB_CHECK_VERSION
   3 #
   4 # Verify that LUSTRE_VERSION was defined properly
   5 #
   6 AC_DEFUN([LB_CHECK_VERSION],
   7 [if test "LUSTRE_VERSION" = "LUSTRE""_VERSION" ; then
   8         AC_MSG_ERROR([This script was not built with a version number.])
   9 fi
  10 ])
  11
  12 #
  13 # LB_CANONICAL_SYSTEM
  14 #
  15 # fixup $target_os for use in other places
  16 #
  17 AC_DEFUN([LB_CANONICAL_SYSTEM],
  18 [case $target_os in
  19         linux*)
  20                 lb_target_os="linux"
  21                 ;;
  22         darwin*)
  23                 lb_target_os="darwin"
  24                 ;;
  25         solaris*)
  26                 lb_target_os="SunOS"
  27                 ;;esac
  28 AC_SUBST(lb_target_os)
  29 ])
  30
  31 #
  32 # LB_CHECK_FILE
  33 #
  34 # Check for file existance even when cross compiling
  35 #
  36 AC_DEFUN([LB_CHECK_FILE],
  37 [AS_VAR_PUSHDEF([lb_File], [lb_cv_file_$1])dnl
  38 AC_CACHE_CHECK([for $1], lb_File,
  39 [if test -r "$1"; then
  40   AS_VAR_SET(lb_File, yes)
  41 else
  42   AS_VAR_SET(lb_File, no)
  43 fi])
  44 AS_IF([test AS_VAR_GET(lb_File) = yes], [$2], [$3])[]dnl
  45 AS_VAR_POPDEF([lb_File])dnl
  46 ])# LB_CHECK_FILE
  47
  48 #
  49 # LB_CHECK_FILES
  50 #
  51 # LB_CHECK_FILE over multiple files
  52 #
  53 AC_DEFUN([LB_CHECK_FILES],
  54 [AC_FOREACH([AC_FILE_NAME], [$1],
  55   [LB_CHECK_FILE(AC_FILE_NAME,
  56                  [AC_DEFINE_UNQUOTED(AS_TR_CPP(HAVE_[]AC_FILE_NAME), 1,
  57                                     [Define to 1 if you have the
  58                                      file `]AC_File['.])
  59 $2],
  60                  [$3])])])
  61
  62 #
  63 # LB_ARG_LIBS_INCLUDES
  64 #
  65 # support for --with-foo, --with-foo-includes, and --with-foo-libs in
  66 # a single magical macro
  67 #
  68 AC_DEFUN([LB_ARG_LIBS_INCLUDES],
  69 [lb_pathvar="m4_bpatsubst([$2], -, _)"
  70 AC_MSG_CHECKING([for $1])
  71 AC_ARG_WITH([$2],
  72         AC_HELP_STRING([--with-$2=path],
  73                 [path to $1]),
  74         [],[withval=$4])
  75
  76 if test x$withval = xyes ; then
  77         eval "$lb_pathvar='$3'"
  78 else
  79         eval "$lb_pathvar='$withval'"
  80 fi
  81 AC_MSG_RESULT([${!lb_pathvar:-no}])
  82
  83 if test x${!lb_pathvar} != x -a x${!lb_pathvar} != xno ; then
  84         AC_MSG_CHECKING([for $1 includes])
  85         AC_ARG_WITH([$2-includes],
  86                 AC_HELP_STRING([--with-$2-includes=path],
  87                         [path to $1 includes]),
  88                 [],[withval='yes'])
  89
  90         lb_includevar="${lb_pathvar}_includes"
  91         if test x$withval = xyes ; then
  92                 eval "${lb_includevar}='${!lb_pathvar}/include'"
  93         else
  94                 eval "${lb_includevar}='$withval'"
  95         fi
  96         AC_MSG_RESULT([${!lb_includevar}])
  97
  98         AC_MSG_CHECKING([for $1 libs])
  99         AC_ARG_WITH([$2-libs],
 100                 AC_HELP_STRING([--with-$2-libs=path],
 101                         [path to $1 libs]),
 102                 [],[withval='yes'])
 103
 104         lb_libvar="${lb_pathvar}_libs"
 105         if test x$withval = xyes ; then
 106                 eval "${lb_libvar}='${!lb_pathvar}/lib'"
 107         else
 108                 eval "${lb_libvar}='$withval'"
 109         fi
 110         AC_MSG_RESULT([${!lb_libvar}])
 111 fi
 112 ])
 113 ])
 114
 115 #
 116 # LB_PATH_LIBSYSIO
 117 #
 118 # Handle internal/external libsysio
 119 #
 120 AC_DEFUN([LB_PATH_LIBSYSIO],
 121 [AC_ARG_WITH([sysio],
 122         AC_HELP_STRING([--with-sysio=path],
 123                         [set path to libsysio source (default is included libsysio)]),
 124         [],[
 125                 case $lb_target_os in
 126                         linux)
 127                                 with_sysio='yes'
 128                                 ;;
 129                         *)
 130                                 with_sysio='no'
 131                                 ;;
 132                 esac
 133         ])
 134 AC_MSG_CHECKING([location of libsysio])
 135 enable_sysio="$with_sysio"
 136 case x$with_sysio in
 137         xyes)
 138                 AC_MSG_RESULT([internal])
 139                 LB_CHECK_FILE([$srcdir/libsysio/src/rmdir.c],[],[
 140                         AC_MSG_ERROR([A complete internal libsysio was not found.])
 141                 ])
 142                 LIBSYSIO_SUBDIR="libsysio"
 143                 SYSIO="$PWD/libsysio"
 144                 ;;
 145         xno)
 146                 AC_MSG_RESULT([disabled])
 147                 ;;
 148         *)
 149                 AC_MSG_RESULT([$with_sysio])
 150                 LB_CHECK_FILE([$with_sysio/lib/libsysio.a],[],[
 151                         AC_MSG_ERROR([A complete (built) external libsysio was not found.])
 152                 ])
 153                 SYSIO=$with_sysio
 154                 with_sysio="yes"
 155                 ;;
 156 esac
 157
 158 # We have to configure even if we don't build here for make dist to work
 159 AC_CONFIG_SUBDIRS(libsysio)
 160 ])
 161
 162 #
 163 # LB_PATH_LUSTREIOKIT
 164 #
 165 # Handle internal/external lustre-iokit
 166 #
 167 AC_DEFUN([LB_PATH_LUSTREIOKIT],
 168 [AC_ARG_WITH([],
 169         AC_HELP_STRING([--with-lustre-iokit=path],
 170                         [set path to lustre-iokit source (default is included lustre-iokit)]),
 171         [],[
 172                         with_lustre_iokit='yes'
 173         ])
 174 AC_MSG_CHECKING([location of lustre-iokit])
 175 enable_lustre_iokit="$with_lustre_iokit"
 176 case x$with_lustre_iokit in
 177         xyes)
 178                 AC_MSG_RESULT([internal])
 179                 LB_CHECK_FILE([$srcdir/lustre-iokit/ior-survey/ior-survey],[],[
 180                         AC_MSG_ERROR([A complete internal lustre-iokit was not found.])
 181                 ])
 182                 LUSTREIOKIT_SUBDIR="lustre-iokit"
 183                 LUSTREIOKIT="$PWD/lustre-iokit"
 184                 ;;
 185         xno)
 186                 AC_MSG_RESULT([disabled])
 187                 ;;
 188         *)
 189                 AC_MSG_RESULT([$with_lustre_iokit])
 190                 LB_CHECK_FILE([$with_lustre_iokit/ior-survey/ior_survey],[],[
 191                         AC_MSG_ERROR([A complete (built) external lustre-iokit was not found.])
 192                 ])
 193                 LUSTREIOKIT="$with_lustre_iokit"
 194                 with_lustre_iokit="yes"
 195                 ;;
 196 esac
 197 AC_SUBST(LUSTREIOKIT_SUBDIR)
 198 # We have to configure even if we don't build here for make dist to work
 199 AC_CONFIG_SUBDIRS(lustre-iokit)
 200 ])
 201
 202 #
 203 # LB_PATH_LDISKFS
 204 #
 205 # Handle internal/external ldiskfs
 206 #
 207 AC_DEFUN([LB_PATH_LDISKFS],
 208 [AC_ARG_WITH([ldiskfs],
 209         AC_HELP_STRING([--with-ldiskfs=path],
 210                         [set path to ldiskfs source (default is included ldiskfs)]),
 211         [],[
 212                 if test x$linux25$enable_server = xyesyes ; then
 213                         with_ldiskfs=yes
 214                 else
 215                         with_ldiskfs=no
 216                 fi
 217         ])
 218 AC_MSG_CHECKING([location of ldiskfs])
 219 case x$with_ldiskfs in
 220         xyes)
 221                 AC_MSG_RESULT([internal])
 222                 LB_CHECK_FILE([$srcdir/ldiskfs/lustre-ldiskfs.spec.in],[],[
 223                         AC_MSG_ERROR([A complete internal ldiskfs was not found.])
 224                 ])
 225                 LDISKFS_SUBDIR="ldiskfs"
 226                 LDISKFS_DIR="$PWD/ldiskfs"
 227                 ;;
 228         xno)
 229                 AC_MSG_RESULT([disabled])
 230                 ;;
 231         *)
 232                 AC_MSG_RESULT([$with_ldiskfs])
 233                 LB_CHECK_FILE([$with_ldiskfs/ldiskfs/linux/ldiskfs_fs.h],[],[
 234                         AC_MSG_ERROR([A complete (built) external ldiskfs was not found.])
 235                 ])
 236                 LDISKFS_DIR=$with_ldiskfs
 237                 ;;
 238 esac
 239 AC_SUBST(LDISKFS_DIR)
 240 AC_SUBST(LDISKFS_SUBDIR)
 241 AM_CONDITIONAL(LDISKFS_ENABLED, test x$with_ldiskfs != xno)
 242
 243 # We have to configure even if we don't build here for make dist to work
 244 AC_CONFIG_SUBDIRS(ldiskfs)
 245 ])
 246
 247 # Define no libcfs by default.
 248 AC_DEFUN([LB_LIBCFS_DIR],
 249 [
 250 case x$libcfs_is_module in
 251         xyes)
 252           LIBCFS_INCLUDE_DIR="libcfs/include"
 253           LIBCFS_SUBDIR="libcfs"
 254           ;;
 255         x*)
 256           LIBCFS_INCLUDE_DIR="lnet/include"
 257           LIBCFS_SUBDIR=""
 258           ;;
 259 esac
 260 AC_SUBST(LIBCFS_SUBDIR)
 261 AC_SUBST(LIBCFS_INCLUDE_DIR)
 262 ])
 263
 264 #
 265 # LB_DEFINE_LDISKFS_OPTIONS
 266 #
 267 # Enable config options related to ldiskfs.  These are used both by ldiskfs
 268 # and lvfs (which includes ldiskfs headers.)
 269 #
 270 AC_DEFUN([LB_DEFINE_LDISKFS_OPTIONS],
 271 [
 272         AC_DEFINE(CONFIG_LDISKFS_FS_MODULE, 1, [build ldiskfs as a module])
 273         AC_DEFINE(CONFIG_LDISKFS_FS_XATTR, 1, [enable extended attributes for ldiskfs])
 274         AC_DEFINE(CONFIG_LDISKFS_FS_POSIX_ACL, 1, [enable posix acls for ldiskfs])
 275         AC_DEFINE(CONFIG_LDISKFS_FS_SECURITY, 1, [enable fs security for ldiskfs])
 276 ])
 277
 278 #
 279 # LB_DEFINE_E2FSPROGS_NAMES
 280 #
 281 # Enable the use of alternate naming of ldiskfs-enabled e2fsprogs package.
 282 #
 283 AC_DEFUN([LB_DEFINE_E2FSPROGS_NAMES],
 284 [AC_ARG_WITH([ldiskfsprogs],
 285         AC_HELP_STRING([--with-ldiskfsprogs],
 286                        [use alternate names for ldiskfs-enabled e2fsprogs]),
 287         [],[withval='no'])
 288
 289 if test x$withval = xyes ; then
 290         AC_DEFINE(HAVE_LDISKFSPROGS, 1, [enable use of ldiskfsprogs package])
 291         E2FSPROGS="ldiskfsprogs"
 292         MKE2FS="mkfs.ldiskfs"
 293         DEBUGFS="debug.ldiskfs"
 294         TUNE2FS="tune.ldiskfs"
 295         E2LABEL="label.ldiskfs"
 296         DUMPE2FS="dump.ldiskfs"
 297         E2FSCK="fsck.ldiskfs"
 298         AC_MSG_RESULT([enabled])
 299 else
 300         E2FSPROGS="e2fsprogs"
 301         MKE2FS="mke2fs"
 302         DEBUGFS="debugfs"
 303         TUNE2FS="tune2fs"
 304         E2LABEL="e2label"
 305         DUMPE2FS="dumpe2fs"
 306         E2FSCK="e2fsck"
 307         AC_MSG_RESULT([disabled])
 308 fi
 309         AC_DEFINE_UNQUOTED(E2FSPROGS, "$E2FSPROGS", [name of ldiskfs e2fsprogs package])
 310         AC_DEFINE_UNQUOTED(MKE2FS, "$MKE2FS", [name of ldiskfs mkfs program])
 311         AC_DEFINE_UNQUOTED(DEBUGFS, "$DEBUGFS", [name of ldiskfs debug program])
 312         AC_DEFINE_UNQUOTED(TUNE2FS, "$TUNE2FS", [name of ldiskfs tune program])
 313         AC_DEFINE_UNQUOTED(E2LABEL, "$E2LABEL", [name of ldiskfs label program])
 314         AC_DEFINE_UNQUOTED(DUMPE2FS,"$DUMPE2FS", [name of ldiskfs dump program])
 315         AC_DEFINE_UNQUOTED(E2FSCK, "$E2FSCK", [name of ldiskfs fsck program])
 316 ])
 317
 318 #
 319 # LB_CONFIG_CRAY_XT3
 320 #
 321 # Enable Cray XT3 features
 322 #
 323 AC_DEFUN([LB_CONFIG_CRAY_XT3],
 324 [AC_MSG_CHECKING([whether to build Cray XT3 features])
 325 AC_ARG_ENABLE([cray_xt3],
 326         AC_HELP_STRING([--enable-cray-xt3],
 327                         [enable building of Cray XT3 features]),
 328         [enable_cray_xt3='yes'],[enable_cray_xt3='no'])
 329 AC_MSG_RESULT([$enable_cray_xt3])
 330 if test x$enable_cray_xt3 != xno; then
 331         AC_DEFINE(CRAY_XT3, 1, Enable Cray XT3 Features)
 332 fi
 333 ])
 334
 335 #
 336 # LB_CONFIG_BGL
 337 #
 338 # Enable BGL features
 339 #
 340 AC_DEFUN([LB_CONFIG_BGL],
 341 [AC_MSG_CHECKING([whether to build BGL features])
 342 AC_ARG_ENABLE([bgl],
 343         AC_HELP_STRING([--enable-bgl],
 344                         [enable building of BGL features]),
 345         [enable_bgl='yes'],[enable_bgl='no'])
 346 AC_MSG_RESULT([$enable_bgl])
 347 if test x$enable_bgl != xno; then
 348         AC_DEFINE(HAVE_BGL_SUPPORT, 1, Enable BGL Features)
 349         enable_doc='no'
 350         enable_tests='no'
 351         enable_server='no'
 352         enable_liblustre='no'
 353         enable_libreadline='no'
 354 fi
 355 ])
 356
 357 #
 358 # Support for --enable-uoss
 359 #
 360 AC_DEFUN([LB_UOSS],
 361 [AC_MSG_CHECKING([whether to enable uoss])
 362 AC_ARG_ENABLE([uoss],
 363         AC_HELP_STRING([--enable-uoss],
 364                         [enable userspace OSS]),
 365         [enable_uoss='yes'],[enable_uoss='no'])
 366 AC_MSG_RESULT([$enable_uoss])
 367 if test x$enable_uoss = xyes; then
 368         AC_DEFINE(UOSS_SUPPORT, 1, Enable user-level OSS)
 369         AC_DEFINE(LUSTRE_ULEVEL_MT, 1, Multi-threaded user-level lustre port)
 370         enable_uoss='yes'
 371         enable_ulevel_mt='yes'
 372         enable_modules='no'
 373         enable_client='no'
 374         enable_tests='no'
 375         enable_liblustre='no'
 376         with_ldiskfs='no'
 377 fi
 378 AC_SUBST(enable_uoss)
 379 ])
 380
 381 #
 382 # Support for --enable-posix-osd
 383 #
 384 AC_DEFUN([LB_POSIX_OSD],
 385 [AC_MSG_CHECKING([whether to enable posix osd])
 386 AC_ARG_ENABLE([posix-osd],
 387         AC_HELP_STRING([--enable-posix-osd],
 388                         [enable using of posix osd]),
 389         [enable_posix_osd='yes'],[enable_posix_osd='no'])
 390 AC_MSG_RESULT([$enable_posix_osd])
 391 if test x$enable_uoss = xyes -a x$enable_posix_osd = xyes ; then
 392         AC_DEFINE(POSIX_OSD, 1, Enable POSIX OSD)
 393         posix_osd='yes'
 394 fi
 395 AM_CONDITIONAL(POSIX_OSD_ENABLED, test x$posix_osd = xyes)
 396 ])
 397
 398 #
 399 # LB_PATH_DMU
 400 #
 401 AC_DEFUN([LB_PATH_DMU],
 402 [AC_ARG_ENABLE([dmu],
 403         AC_HELP_STRING([--enable-dmu],
 404                        [enable the DMU backend]),
 405         [],[with_dmu='default'])
 406 AC_MSG_CHECKING([whether to enable DMU])
 407 case x$with_dmu in
 408         xyes)
 409                 dmu_osd='yes'
 410                 ;;
 411         xno)
 412                 dmu_osd='no'
 413                 ;;
 414         xdefault)
 415                 if test x$enable_uoss = xyes -a x$posix_osd != xyes; then
 416                         # Enable the DMU if we're configuring a userspace server
 417                         dmu_osd='yes'
 418                 else
 419                         # Enable the DMU by default on the b_hd_kdmu branch
 420                         if test -d $PWD/zfs -a x$linux25$enable_server = xyesyes; then
 421                                 dmu_osd='yes'
 422                         else
 423                                 dmu_osd='no'
 424                         fi
 425                 fi
 426                 ;;
 427         *)
 428                 dmu_osd='yes'
 429                 ;;
 430 esac
 431 AC_MSG_RESULT([$dmu_osd])
 432 if test x$dmu_osd = xyes; then
 433         AC_DEFINE(DMU_OSD, 1, Enable DMU OSD)
 434         if test x$enable_uoss = xyes; then
 435                 # Userspace DMU
 436                 DMU_SRC="$PWD/lustre/zfs-lustre"
 437                 AC_SUBST(DMU_SRC)
 438                 LB_CHECK_FILE([$DMU_SRC/src/.patched],[],[
 439                         AC_MSG_ERROR([A complete (patched) DMU tree was not found.])
 440                 ])
 441                 AC_CONFIG_SUBDIRS(lustre/zfs-lustre)
 442         else
 443                 # Kernel DMU
 444                 SPL_DIR="$PWD/spl"
 445                 ZFS_DIR="$PWD/zfs"
 446                 AC_SUBST(SPL_DIR)
 447                 AC_SUBST(ZFS_DIR)
 448
 449                 AC_SUBST(spl_src)
 450
 451                 LB_CHECK_FILE([$SPL_DIR/modules/spl/spl-generic.c],[],[
 452                         AC_MSG_ERROR([A complete SPL tree was not found in $SPL_DIR.])
 453                 ])
 454
 455                 LB_CHECK_FILE([$ZFS_DIR/zfs/lib/libzpool/dmu.c],[],[
 456                         AC_MSG_ERROR([A complete kernel DMU tree was not found in $ZFS_DIR.])
 457                 ])
 458
 459                 AC_CONFIG_SUBDIRS(spl)
 460                 ac_configure_args="$ac_configure_args --with-spl=$SPL_DIR"
 461                 AC_CONFIG_SUBDIRS(zfs)
 462         fi
 463 fi
 464 AM_CONDITIONAL(DMU_OSD_ENABLED, test x$dmu_osd = xyes)
 465 AM_CONDITIONAL(KDMU, test x$dmu_osd$enable_uoss = xyesno)
 466 ])
 467
 468 #
 469 # LB_PATH_SNMP
 470 #
 471 # check for in-tree snmp support
 472 #
 473 AC_DEFUN([LB_PATH_SNMP],
 474 [LB_CHECK_FILE([$srcdir/snmp/lustre-snmp.c],[SNMP_DIST_SUBDIR="snmp"])
 475 AC_SUBST(SNMP_DIST_SUBDIR)
 476 AC_SUBST(SNMP_SUBDIR)
 477 ])
 478
 479 #
 480 # LB_CONFIG_MODULES
 481 #
 482 # Build kernel modules?
 483 #
 484 AC_DEFUN([LB_CONFIG_MODULES],
 485 [AC_MSG_CHECKING([whether to build kernel modules])
 486 AC_ARG_ENABLE([modules],
 487         AC_HELP_STRING([--disable-modules],
 488                         [disable building of Lustre kernel modules]),
 489         [],[
 490                 LC_TARGET_SUPPORTED([
 491                         enable_modules='yes'
 492                 ],[
 493                         enable_modules='no'
 494                 ])
 495         ])
 496 AC_MSG_RESULT([$enable_modules ($target_os)])
 497
 498 if test x$enable_modules = xyes ; then
 499         case $target_os in
 500                 linux*)
 501                         LB_PROG_LINUX
 502                         LIBCFS_PROG_LINUX
 503                         LN_PROG_LINUX
 504                         LC_PROG_LINUX
 505                         ;;
 506                 darwin*)
 507                         LB_PROG_DARWIN
 508                         LIBCFS_PROG_DARWIN
 509                         ;;
 510                 *)
 511                         # This is strange - Lustre supports a target we don't
 512                         AC_MSG_ERROR([Modules are not supported on $target_os])
 513                         ;;
 514         esac
 515 fi
 516 ])
 517
 518 #
 519 # LB_CONFIG_UTILS
 520 #
 521 # Build utils?
 522 #
 523 AC_DEFUN([LB_CONFIG_UTILS],
 524 [AC_MSG_CHECKING([whether to build utilities])
 525 AC_ARG_ENABLE([utils],
 526         AC_HELP_STRING([--disable-utils],
 527                         [disable building of Lustre utility programs]),
 528         [],[enable_utils='yes'])
 529 AC_MSG_RESULT([$enable_utils])
 530 if test x$enable_utils = xyes ; then
 531         LB_CONFIG_INIT_SCRIPTS
 532 fi
 533 ])
 534
 535 #
 536 # LB_CONFIG_TESTS
 537 #
 538 # Build tests?
 539 #
 540 AC_DEFUN([LB_CONFIG_TESTS],
 541 [AC_MSG_CHECKING([whether to build Lustre tests])
 542 AC_ARG_ENABLE([tests],
 543         AC_HELP_STRING([--disable-tests],
 544                         [disable building of Lustre tests]),
 545         [],
 546         [
 547                 enable_tests='yes'
 548         ])
 549 AC_MSG_RESULT([$enable_tests])
 550 ])
 551
 552 #
 553 # LB_CONFIG_DOCS
 554 #
 555 # Build docs?
 556 #
 557 AC_DEFUN([LB_CONFIG_DOCS],
 558 [AC_MSG_CHECKING([whether to build docs])
 559 AC_ARG_ENABLE(doc,
 560         AC_HELP_STRING([--disable-doc],
 561                         [skip creation of pdf documentation]),
 562         [
 563                 if test x$enable_doc = xyes ; then
 564                     ENABLE_DOC=1
 565                 else
 566                     ENABLE_DOC=0
 567                 fi
 568         ],[
 569                 ENABLE_DOC=0
 570                 enable_doc='no'
 571         ])
 572 AC_MSG_RESULT([$enable_doc])
 573 AC_SUBST(ENABLE_DOC)
 574 ])
 575
 576 #
 577 # LB_CONFIG_INIT_SCRIPTS
 578 #
 579 # our init scripts only work on red hat linux
 580 #
 581 AC_DEFUN([LB_CONFIG_INIT_SCRIPTS],
 582 [ENABLE_INIT_SCRIPTS=0
 583 if test x$enable_utils = xyes ; then
 584         AC_MSG_CHECKING([whether to install init scripts])
 585         # our scripts only work on red hat systems
 586         if test -f /etc/init.d/functions -a -f /etc/sysconfig/network ; then
 587                 ENABLE_INIT_SCRIPTS=1
 588                 AC_MSG_RESULT([yes])
 589         else
 590                 AC_MSG_RESULT([no])
 591         fi
 592 fi
 593 AC_SUBST(ENABLE_INIT_SCRIPTS)
 594 ])
 595
 596 #
 597 # LB_CONFIG_HEADERS
 598 #
 599 # add -include config.h
 600 #
 601 AC_DEFUN([LB_CONFIG_HEADERS],
 602 [AC_CONFIG_HEADERS([config.h])
 603 CPPFLAGS="-include \$(top_builddir)/config.h $CPPFLAGS"
 604 EXTRA_KCFLAGS="-include $PWD/config.h $EXTRA_KCFLAGS"
 605 AC_SUBST(EXTRA_KCFLAGS)
 606 ])
 607
 608 #
 609 # LB_INCLUDE_RULES
 610 #
 611 # defines for including the toplevel Rules
 612 #
 613 AC_DEFUN([LB_INCLUDE_RULES],
 614 [INCLUDE_RULES="include $PWD/Rules"
 615 AC_SUBST(INCLUDE_RULES)
 616 ])
 617
 618 #
 619 # LB_PATH_DEFAULTS
 620 #
 621 # 'fixup' default paths
 622 #
 623 AC_DEFUN([LB_PATH_DEFAULTS],
 624 [# directories for binaries
 625 AC_PREFIX_DEFAULT([/usr])
 626
 627 sysconfdir='/etc'
 628 AC_SUBST(sysconfdir)
 629
 630 # Directories for documentation and demos.
 631 docdir='${datadir}/doc/$(PACKAGE)'
 632 AC_SUBST(docdir)
 633
 634 LIBCFS_PATH_DEFAULTS
 635 LN_PATH_DEFAULTS
 636 LC_PATH_DEFAULTS
 637
 638 ])
 639
 640 #
 641 # LB_PROG_CC
 642 #
 643 # checks on the C compiler
 644 #
 645 AC_DEFUN([LB_PROG_CC],
 646 [AC_PROG_RANLIB
 647 AC_MSG_CHECKING([for buggy compiler])
 648 CC_VERSION=`$CC -v 2>&1 | grep "^gcc version"`
 649 bad_cc() {
 650         AC_MSG_RESULT([buggy compiler found!])
 651         echo
 652         echo "   '$CC_VERSION'"
 653         echo "  has been known to generate bad code, "
 654         echo "  please get an updated compiler."
 655         AC_MSG_ERROR([sorry])
 656 }
 657 case "$CC_VERSION" in
 658         "gcc version 2.95"*)
 659                 bad_cc
 660                 ;;
 661         # ost_pack_niobuf putting 64bit NTOH temporaries on the stack
 662         # without "sub    $0xc,%esp" to protect the stack from being
 663         # stomped on by interrupts (bug 606)
 664         "gcc version 2.96 20000731 (Red Hat Linux 7.1 2.96-98)")
 665                 bad_cc
 666                 ;;
 667         # mandrake's similar sub 0xc compiler bug
 668         # http://marc.theaimsgroup.com/?l=linux-kernel&m=104748366226348&w=2
 669         "gcc version 2.96 20000731 (Mandrake Linux 8.1 2.96-0.62mdk)")
 670                 bad_cc
 671                 ;;
 672         *)
 673                 AC_MSG_RESULT([no known problems])
 674                 ;;
 675 esac
 676
 677 # ---------  unsigned long long sane? -------
 678 AC_CHECK_SIZEOF(unsigned long long, 0)
 679 echo "---> size SIZEOF $SIZEOF_unsigned_long_long"
 680 echo "---> size SIZEOF $ac_cv_sizeof_unsigned_long_long"
 681 if test $ac_cv_sizeof_unsigned_long_long != 8 ; then
 682         AC_MSG_ERROR([** we assume that sizeof(long long) == 8.  Tell phil@clusterfs.com])
 683 fi
 684
 685 if test $target_cpu == "powerpc64"; then
 686         AC_MSG_WARN([set compiler with -m64])
 687         CFLAGS="$CFLAGS -m64"
 688         CC="$CC -m64"
 689 fi
 690
 691 CPPFLAGS="-I\$(top_builddir)/$LIBCFS_INCLUDE_DIR -I\$(top_srcdir)/$LIBCFS_INCLUDE_DIR-I\$(top_builddir)/lnet/include -I\$(top_srcdir)/lnet/include -I\$(top_builddir)/lustre/include -I\$(top_srcdir)/lustre/include $CPPFLAGS"
 692
 693 LLCPPFLAGS="-D__arch_lib__ -D_LARGEFILE64_SOURCE=1"
 694 AC_SUBST(LLCPPFLAGS)
 695
 696 # Add _GNU_SOURCE for strnlen on linux
 697 LLCFLAGS="-g -Wall -fPIC -D_GNU_SOURCE"
 698 AC_SUBST(LLCFLAGS)
 699
 700 # everyone builds against lnet and lustre
 701 EXTRA_KCFLAGS="$EXTRA_KCFLAGS -g -I$PWD/$LIBCFS_INCLUDE_DIR -I$PWD/lnet/include -I$PWD/lustre/include"
 702 AC_SUBST(EXTRA_KCFLAGS)
 703 ])
 704
 705 #
 706 # LB_CONTITIONALS
 707 #
 708 # AM_CONDITIONAL instances for everything
 709 # (so that portals/lustre can disable some if needed)
 710 AC_DEFUN([LB_CONDITIONALS],
 711 [AM_CONDITIONAL(MODULES, test x$enable_modules = xyes)
 712 AM_CONDITIONAL(UTILS, test x$enable_utils = xyes)
 713 AM_CONDITIONAL(TESTS, test x$enable_tests = xyes)
 714 AM_CONDITIONAL(DOC, test x$ENABLE_DOC = x1)
 715 AM_CONDITIONAL(INIT_SCRIPTS, test x$ENABLE_INIT_SCRIPTS = "x1")
 716 AM_CONDITIONAL(LINUX, test x$lb_target_os = "xlinux")
 717 AM_CONDITIONAL(DARWIN, test x$lb_target_os = "xdarwin")
 718 AM_CONDITIONAL(CRAY_XT3, test x$enable_cray_xt3 = "xyes")
 719 AM_CONDITIONAL(SUNOS, test x$lb_target_os = "xSunOS")
 720
 721 # this lets lustre cancel libsysio, per-branch or if liblustre is
 722 # disabled
 723 if test "x$LIBSYSIO_SUBDIR" = xlibsysio ; then
 724         if test "x$with_sysio" != xyes ; then
 725                 SYSIO=""
 726                 LIBSYSIO_SUBDIR=""
 727         fi
 728 fi
 729 AC_SUBST(LIBSYSIO_SUBDIR)
 730 AC_SUBST(SYSIO)
 731
 732 LB_LINUX_CONDITIONALS
 733 LB_DARWIN_CONDITIONALS
 734
 735 LIBCFS_CONDITIONALS
 736 LN_CONDITIONALS
 737 LC_CONDITIONALS
 738 ])
 739
 740 #
 741 # LB_CONFIG_FILES
 742 #
 743 # build-specific config files
 744 #
 745 AC_DEFUN([LB_CONFIG_FILES],
 746 [
 747 AC_CONFIG_FILES(
 748 [Makefile
 749 autoMakefile
 750 ]
 751 [Rules:build/Rules.in]
 752 AC_PACKAGE_TARNAME[.spec]
 753 )
 754 ])
 755
 756 #
 757 # LB_CONFIGURE
 758 #
 759 # main configure steps
 760 #
 761 AC_DEFUN([LB_CONFIGURE],
 762 [LB_CANONICAL_SYSTEM
 763
 764 LB_LIBCFS_DIR
 765
 766 LB_INCLUDE_RULES
 767
 768 LB_CONFIG_CRAY_XT3
 769 LB_CONFIG_BGL
 770 LB_PATH_DEFAULTS
 771
 772 LB_PROG_CC
 773
 774 LB_UOSS
 775 LB_POSIX_OSD
 776
 777 LB_CONFIG_DOCS
 778 LB_CONFIG_UTILS
 779 LB_CONFIG_TESTS
 780 LC_CONFIG_CLIENT_SERVER
 781
 782 # two macros for cmd3
 783 m4_ifdef([LC_CONFIG_SPLIT], [LC_CONFIG_SPLIT])
 784 LN_CONFIG_CDEBUG
 785 LC_QUOTA
 786
 787 LB_CONFIG_MODULES
 788
 789 LB_PATH_DMU
 790 LB_PATH_LIBSYSIO
 791 LB_PATH_SNMP
 792 LB_PATH_LDISKFS
 793 LB_PATH_LUSTREIOKIT
 794
 795 LB_DEFINE_E2FSPROGS_NAMES
 796
 797 LC_CONFIG_LIBLUSTRE
 798 LIBCFS_CONFIGURE
 799 LN_CONFIGURE
 800
 801 LC_CONFIGURE
 802
 803 if test "$SNMP_DIST_SUBDIR" ; then
 804         LS_CONFIGURE
 805 fi
 806
 807
 808 LB_CONDITIONALS
 809 LB_CONFIG_HEADERS
 810
 811 LIBCFS_CONFIG_FILES
 812 LB_CONFIG_FILES
 813 LN_CONFIG_FILES
 814 LC_CONFIG_FILES
 815 if test "$SNMP_DIST_SUBDIR" ; then
 816         LS_CONFIG_FILES
 817 fi
 818
 819 AC_SUBST(ac_configure_args)
 820
 821 MOSTLYCLEANFILES='.*.cmd .*.flags *.o *.ko *.mod.c .depend .*.1.* Modules.symvers Module.symvers'
 822 AC_SUBST(MOSTLYCLEANFILES)
 823
 824 AC_OUTPUT
 825
 826 cat <<_ACEOF
 827
 828 CC:            $CC
 829 LD:            $LD
 830 CPPFLAGS:      $CPPFLAGS
 831 LLCPPFLAGS:    $LLCPPFLAGS
 832 CFLAGS:        $CFLAGS
 833 EXTRA_KCFLAGS: $EXTRA_KCFLAGS
 834 LLCFLAGS:      $LLCFLAGS
 835
 836 Type 'make' to build Lustre.
 837 _ACEOF
 838 ])