build/autoconf/lustre-build.m4

   1 #
   2 # LB_CHECK_VERSION
   3 #
   4 # Verify that LUSTRE_VERSION was defined properly
   5 #
   6 AC_DEFUN([LB_CHECK_VERSION],
   7 [if test "LUSTRE_VERSION" = "LUSTRE""_VERSION" ; then
   8         AC_MSG_ERROR([This script was not built with a version number.])
   9 fi
  10 ])
  11
  12 #
  13 # LB_CANONICAL_SYSTEM
  14 #
  15 # fixup $target_os for use in other places
  16 #
  17 AC_DEFUN([LB_CANONICAL_SYSTEM],
  18 [case $target_os in
  19         linux*)
  20                 lb_target_os="linux"
  21                 ;;
  22         darwin*)
  23                 lb_target_os="darwin"
  24                 ;;
  25         solaris*)
  26                 lb_target_os="SunOS"
  27                 ;;esac
  28 AC_SUBST(lb_target_os)
  29 ])
  30
  31 #
  32 # LB_CHECK_FILE
  33 #
  34 # Check for file existance even when cross compiling
  35 #
  36 AC_DEFUN([LB_CHECK_FILE],
  37 [AS_VAR_PUSHDEF([lb_File], [lb_cv_file_$1])dnl
  38 AC_CACHE_CHECK([for $1], lb_File,
  39 [if test -r "$1"; then
  40   AS_VAR_SET(lb_File, yes)
  41 else
  42   AS_VAR_SET(lb_File, no)
  43 fi])
  44 AS_IF([test AS_VAR_GET(lb_File) = yes], [$2], [$3])[]dnl
  45 AS_VAR_POPDEF([lb_File])dnl
  46 ])# LB_CHECK_FILE
  47
  48 #
  49 # LB_CHECK_FILES
  50 #
  51 # LB_CHECK_FILE over multiple files
  52 #
  53 AC_DEFUN([LB_CHECK_FILES],
  54 [AC_FOREACH([AC_FILE_NAME], [$1],
  55   [LB_CHECK_FILE(AC_FILE_NAME,
  56                  [AC_DEFINE_UNQUOTED(AS_TR_CPP(HAVE_[]AC_FILE_NAME), 1,
  57                                     [Define to 1 if you have the
  58                                      file `]AC_File['.])
  59 $2],
  60                  [$3])])])
  61
  62 #
  63 # LB_ARG_LIBS_INCLUDES
  64 #
  65 # support for --with-foo, --with-foo-includes, and --with-foo-libs in
  66 # a single magical macro
  67 #
  68 AC_DEFUN([LB_ARG_LIBS_INCLUDES],
  69 [lb_pathvar="m4_bpatsubst([$2], -, _)"
  70 AC_MSG_CHECKING([for $1])
  71 AC_ARG_WITH([$2],
  72         AC_HELP_STRING([--with-$2=path],
  73                 [path to $1]),
  74         [],[withval=$4])
  75
  76 if test x$withval = xyes ; then
  77         eval "$lb_pathvar='$3'"
  78 else
  79         eval "$lb_pathvar='$withval'"
  80 fi
  81 AC_MSG_RESULT([${!lb_pathvar:-no}])
  82
  83 if test x${!lb_pathvar} != x -a x${!lb_pathvar} != xno ; then
  84         AC_MSG_CHECKING([for $1 includes])
  85         AC_ARG_WITH([$2-includes],
  86                 AC_HELP_STRING([--with-$2-includes=path],
  87                         [path to $1 includes]),
  88                 [],[withval='yes'])
  89
  90         lb_includevar="${lb_pathvar}_includes"
  91         if test x$withval = xyes ; then
  92                 eval "${lb_includevar}='${!lb_pathvar}/include'"
  93         else
  94                 eval "${lb_includevar}='$withval'"
  95         fi
  96         AC_MSG_RESULT([${!lb_includevar}])
  97
  98         AC_MSG_CHECKING([for $1 libs])
  99         AC_ARG_WITH([$2-libs],
 100                 AC_HELP_STRING([--with-$2-libs=path],
 101                         [path to $1 libs]),
 102                 [],[withval='yes'])
 103
 104         lb_libvar="${lb_pathvar}_libs"
 105         if test x$withval = xyes ; then
 106                 eval "${lb_libvar}='${!lb_pathvar}/lib'"
 107         else
 108                 eval "${lb_libvar}='$withval'"
 109         fi
 110         AC_MSG_RESULT([${!lb_libvar}])
 111 fi
 112 ])
 113 ])
 114
 115 #
 116 # LB_PATH_LIBSYSIO
 117 #
 118 # Handle internal/external libsysio
 119 #
 120 AC_DEFUN([LB_PATH_LIBSYSIO],
 121 [AC_ARG_WITH([sysio],
 122         AC_HELP_STRING([--with-sysio=path],
 123                         [set path to libsysio source (default is included libsysio)]),
 124         [],[
 125                 case $lb_target_os in
 126                         linux)
 127                                 with_sysio='yes'
 128                                 ;;
 129                         *)
 130                                 with_sysio='no'
 131                                 ;;
 132                 esac
 133         ])
 134 AC_MSG_CHECKING([location of libsysio])
 135 enable_sysio="$with_sysio"
 136 case x$with_sysio in
 137         xyes)
 138                 AC_MSG_RESULT([internal])
 139                 LB_CHECK_FILE([$srcdir/libsysio/src/rmdir.c],[],[
 140                         AC_MSG_ERROR([A complete internal libsysio was not found.])
 141                 ])
 142                 LIBSYSIO_SUBDIR="libsysio"
 143                 SYSIO="$PWD/libsysio"
 144                 ;;
 145         xno)
 146                 AC_MSG_RESULT([disabled])
 147                 ;;
 148         *)
 149                 AC_MSG_RESULT([$with_sysio])
 150                 LB_CHECK_FILE([$with_sysio/lib/libsysio.a],[],[
 151                         AC_MSG_ERROR([A complete (built) external libsysio was not found.])
 152                 ])
 153                 SYSIO=$with_sysio
 154                 with_sysio="yes"
 155                 ;;
 156 esac
 157
 158 # We have to configure even if we don't build here for make dist to work
 159 AC_CONFIG_SUBDIRS(libsysio)
 160 ])
 161
 162 #
 163 # LB_PATH_LDISKFS
 164 #
 165 # Handle internal/external ldiskfs
 166 #
 167 AC_DEFUN([LB_PATH_LDISKFS],
 168 [AC_ARG_WITH([ldiskfs],
 169         AC_HELP_STRING([--with-ldiskfs=path],
 170                         [set path to ldiskfs source (default is included ldiskfs)]),
 171         [],[
 172                 if test x$linux25$enable_server = xyesyes ; then
 173                         with_ldiskfs=yes
 174                 else
 175                         with_ldiskfs=no
 176                 fi
 177         ])
 178 AC_MSG_CHECKING([location of ldiskfs])
 179 case x$with_ldiskfs in
 180         xyes)
 181                 AC_MSG_RESULT([internal])
 182                 LB_CHECK_FILE([$srcdir/ldiskfs/lustre-ldiskfs.spec.in],[],[
 183                         AC_MSG_ERROR([A complete internal ldiskfs was not found.])
 184                 ])
 185                 LDISKFS_SUBDIR="ldiskfs"
 186                 LDISKFS_DIR="$PWD/ldiskfs"
 187                 ;;
 188         xno)
 189                 AC_MSG_RESULT([disabled])
 190                 ;;
 191         *)
 192                 AC_MSG_RESULT([$with_ldiskfs])
 193                 LB_CHECK_FILE([$with_ldiskfs/ldiskfs/linux/ldiskfs_fs.h],[],[
 194                         AC_MSG_ERROR([A complete (built) external ldiskfs was not found.])
 195                 ])
 196                 LDISKFS_DIR=$with_ldiskfs
 197                 ;;
 198 esac
 199 AC_SUBST(LDISKFS_DIR)
 200 AC_SUBST(LDISKFS_SUBDIR)
 201 AM_CONDITIONAL(LDISKFS_ENABLED, test x$with_ldiskfs != xno)
 202
 203 # We have to configure even if we don't build here for make dist to work
 204 AC_CONFIG_SUBDIRS(ldiskfs)
 205 ])
 206
 207 #
 208 # LB_DEFINE_LDISKFS_OPTIONS
 209 #
 210 # Enable config options related to ldiskfs.  These are used both by ldiskfs
 211 # and lvfs (which includes ldiskfs headers.)
 212 #
 213 AC_DEFUN([LB_DEFINE_LDISKFS_OPTIONS],
 214 [
 215         AC_DEFINE(CONFIG_LDISKFS_FS_MODULE, 1, [build ldiskfs as a module])
 216         AC_DEFINE(CONFIG_LDISKFS_FS_XATTR, 1, [enable extended attributes for ldiskfs])
 217         AC_DEFINE(CONFIG_LDISKFS_FS_POSIX_ACL, 1, [enable posix acls for ldiskfs])
 218         AC_DEFINE(CONFIG_LDISKFS_FS_SECURITY, 1, [enable fs security for ldiskfs])
 219 ])
 220
 221 #
 222 # LB_CONFIG_CRAY_XT3
 223 #
 224 # Enable Cray XT3 features
 225 #
 226 AC_DEFUN([LB_CONFIG_CRAY_XT3],
 227 [AC_MSG_CHECKING([whether to build Cray XT3 features])
 228 AC_ARG_ENABLE([cray_xt3],
 229         AC_HELP_STRING([--enable-cray-xt3],
 230                         [enable building of Cray XT3 features]),
 231         [enable_cray_xt3='yes'],[enable_cray_xt3='no'])
 232 AC_MSG_RESULT([$enable_cray_xt3])
 233 if test x$enable_cray_xt3 != xno; then
 234         AC_DEFINE(CRAY_XT3, 1, Enable Cray XT3 Features)
 235 fi
 236 ])
 237
 238 #
 239 # LB_CONFIG_BGL
 240 #
 241 # Enable BGL features
 242 #
 243 AC_DEFUN([LB_CONFIG_BGL],
 244 [AC_MSG_CHECKING([whether to build BGL features])
 245 AC_ARG_ENABLE([bgl],
 246         AC_HELP_STRING([--enable-bgl],
 247                         [enable building of BGL features]),
 248         [enable_bgl='yes'],[enable_bgl='no'])
 249 AC_MSG_RESULT([$enable_bgl])
 250 if test x$enable_bgl != xno; then
 251         AC_DEFINE(BGL_SUPPORT, 1, Enable BGL Features)
 252         enable_doc='no'
 253         enable_tests='no'
 254         enable_server='no'
 255         enable_liblustre='no'
 256         enable_libreadline='no'
 257 fi
 258 ])
 259
 260 #
 261 # Support for --enable-uoss
 262 #
 263 AC_DEFUN([LB_UOSS],
 264 [AC_MSG_CHECKING([whether to enable uoss])
 265 AC_ARG_ENABLE([uoss],
 266         AC_HELP_STRING([--enable-uoss],
 267                         [enable userspace OSS]),
 268         [enable_uoss='yes'],[enable_uoss='no'])
 269 AC_MSG_RESULT([$enable_uoss])
 270 if test x$enable_uoss = xyes; then
 271         AC_DEFINE(UOSS_SUPPORT, 1, Enable user-level OSS)
 272         AC_DEFINE(LUSTRE_ULEVEL_MT, 1, Multi-threaded user-level lustre port)
 273         enable_uoss='yes'
 274         enable_ulevel_mt='yes'
 275         enable_modules='no'
 276         enable_client='no'
 277         enable_tests='no'
 278         enable_liblustre='no'
 279         with_ldiskfs='no'
 280 fi
 281 AC_SUBST(enable_uoss)
 282 ])
 283
 284 #
 285 # Support for --enable-posix-osd
 286 #
 287 AC_DEFUN([LB_POSIX_OSD],
 288 [AC_MSG_CHECKING([whether to enable posix osd])
 289 AC_ARG_ENABLE([posix-osd],
 290         AC_HELP_STRING([--enable-posix-osd],
 291                         [enable using of posix osd]),
 292         [enable_posix_osd='yes'],[enable_posix_osd='no'])
 293 AC_MSG_RESULT([$enable_posix_osd])
 294 if test x$enable_uoss = xyes -a x$enable_posix_osd = xyes ; then
 295         AC_DEFINE(POSIX_OSD, 1, Enable POSIX OSD)
 296         posix_osd='yes'
 297 fi
 298 AM_CONDITIONAL(POSIX_OSD_ENABLED, test x$posix_osd = xyes)
 299 ])
 300
 301 #
 302 # LB_PATH_DMU
 303 # Support for --with-dmu
 304 #
 305 AC_DEFUN([LB_PATH_DMU],
 306 [AC_MSG_CHECKING([whether to enable DMU])
 307 AC_ARG_WITH([dmu],
 308         AC_HELP_STRING([--with-dmu=path],
 309                        [set path to a DMU tree (default is included zfs-lustre)]),
 310         [
 311                 DMU_SRC=$with_dmu
 312         ],
 313         [
 314                 DMU_SRC="$PWD/zfs-lustre"
 315         ])
 316 if test x$enable_uoss = xyes -a x$enable_posix_osd != xyes; then
 317         AC_DEFINE(DMU_OSD, 1, Enable DMU OSD)
 318         AC_MSG_RESULT([yes])
 319         LB_CHECK_FILE([$DMU_SRC/src/.patched],[],[
 320                 AC_MSG_ERROR([A complete (patched) DMU tree was not found.])
 321         ])
 322         AC_CONFIG_SUBDIRS(zfs-lustre)
 323         dmu_osd='yes'
 324 else
 325         AC_MSG_RESULT([no])
 326 fi
 327 AC_SUBST(DMU_SRC)
 328 AM_CONDITIONAL(DMU_OSD_ENABLED, test x$dmu_osd = xyes)
 329 ])
 330
 331 #
 332 # LB_PATH_SNMP
 333 #
 334 # check for in-tree snmp support
 335 #
 336 AC_DEFUN([LB_PATH_SNMP],
 337 [LB_CHECK_FILE([$srcdir/snmp/lustre-snmp.c],[SNMP_DIST_SUBDIR="snmp"])
 338 AC_SUBST(SNMP_DIST_SUBDIR)
 339 AC_SUBST(SNMP_SUBDIR)
 340 ])
 341
 342 #
 343 # LB_CONFIG_MODULES
 344 #
 345 # Build kernel modules?
 346 #
 347 AC_DEFUN([LB_CONFIG_MODULES],
 348 [AC_MSG_CHECKING([whether to build kernel modules])
 349 AC_ARG_ENABLE([modules],
 350         AC_HELP_STRING([--disable-modules],
 351                         [disable building of Lustre kernel modules]),
 352         [],[
 353                 LC_TARGET_SUPPORTED([
 354                         enable_modules='yes'
 355                 ],[
 356                         enable_modules='no'
 357                 ])
 358         ])
 359 AC_MSG_RESULT([$enable_modules ($target_os)])
 360
 361 if test x$enable_modules = xyes ; then
 362         case $target_os in
 363                 linux*)
 364                         LB_PROG_LINUX
 365                         LN_PROG_LINUX
 366                         LC_PROG_LINUX
 367                         ;;
 368                 darwin*)
 369                         LB_PROG_DARWIN
 370                         ;;
 371                 *)
 372                         # This is strange - Lustre supports a target we don't
 373                         AC_MSG_ERROR([Modules are not supported on $target_os])
 374                         ;;
 375         esac
 376 fi
 377 ])
 378
 379 #
 380 # LB_CONFIG_UTILS
 381 #
 382 # Build utils?
 383 #
 384 AC_DEFUN([LB_CONFIG_UTILS],
 385 [AC_MSG_CHECKING([whether to build utilities])
 386 AC_ARG_ENABLE([utils],
 387         AC_HELP_STRING([--disable-utils],
 388                         [disable building of Lustre utility programs]),
 389         [],[enable_utils='yes'])
 390 AC_MSG_RESULT([$enable_utils])
 391 if test x$enable_utils = xyes ; then
 392         LB_CONFIG_INIT_SCRIPTS
 393 fi
 394 ])
 395
 396 #
 397 # LB_CONFIG_TESTS
 398 #
 399 # Build tests?
 400 #
 401 AC_DEFUN([LB_CONFIG_TESTS],
 402 [AC_MSG_CHECKING([whether to build Lustre tests])
 403 AC_ARG_ENABLE([tests],
 404         AC_HELP_STRING([--disable-tests],
 405                         [disable building of Lustre tests]),
 406         [],
 407         [
 408                 enable_tests='yes'
 409         ])
 410 AC_MSG_RESULT([$enable_tests])
 411 ])
 412
 413 #
 414 # LB_CONFIG_DOCS
 415 #
 416 # Build docs?
 417 #
 418 AC_DEFUN([LB_CONFIG_DOCS],
 419 [AC_MSG_CHECKING([whether to build docs])
 420 AC_ARG_ENABLE(doc,
 421         AC_HELP_STRING([--disable-doc],
 422                         [skip creation of pdf documentation]),
 423         [
 424                 if test x$enable_doc = xyes ; then
 425                     ENABLE_DOC=1
 426                 else
 427                     ENABLE_DOC=0
 428                 fi
 429         ],[
 430                 ENABLE_DOC=0
 431                 enable_doc='no'
 432         ])
 433 AC_MSG_RESULT([$enable_doc])
 434 AC_SUBST(ENABLE_DOC)
 435 ])
 436
 437 #
 438 # LB_CONFIG_INIT_SCRIPTS
 439 #
 440 # our init scripts only work on red hat linux
 441 #
 442 AC_DEFUN([LB_CONFIG_INIT_SCRIPTS],
 443 [ENABLE_INIT_SCRIPTS=0
 444 if test x$enable_utils = xyes ; then
 445         AC_MSG_CHECKING([whether to install init scripts])
 446         # our scripts only work on red hat systems
 447         if test -f /etc/init.d/functions -a -f /etc/sysconfig/network ; then
 448                 ENABLE_INIT_SCRIPTS=1
 449                 AC_MSG_RESULT([yes])
 450         else
 451                 AC_MSG_RESULT([no])
 452         fi
 453 fi
 454 AC_SUBST(ENABLE_INIT_SCRIPTS)
 455 ])
 456
 457 #
 458 # LB_CONFIG_HEADERS
 459 #
 460 # add -include config.h
 461 #
 462 AC_DEFUN([LB_CONFIG_HEADERS],
 463 [AC_CONFIG_HEADERS([config.h])
 464 CPPFLAGS="-include \$(top_builddir)/config.h $CPPFLAGS"
 465 EXTRA_KCFLAGS="-include $PWD/config.h $EXTRA_KCFLAGS"
 466 AC_SUBST(EXTRA_KCFLAGS)
 467 ])
 468
 469 #
 470 # LB_INCLUDE_RULES
 471 #
 472 # defines for including the toplevel Rules
 473 #
 474 AC_DEFUN([LB_INCLUDE_RULES],
 475 [INCLUDE_RULES="include $PWD/Rules"
 476 AC_SUBST(INCLUDE_RULES)
 477 ])
 478
 479 #
 480 # LB_PATH_DEFAULTS
 481 #
 482 # 'fixup' default paths
 483 #
 484 AC_DEFUN([LB_PATH_DEFAULTS],
 485 [# directories for binaries
 486 AC_PREFIX_DEFAULT([/usr])
 487
 488 sysconfdir='/etc'
 489 AC_SUBST(sysconfdir)
 490
 491 # Directories for documentation and demos.
 492 docdir='${datadir}/doc/$(PACKAGE)'
 493 AC_SUBST(docdir)
 494
 495 LN_PATH_DEFAULTS
 496 LC_PATH_DEFAULTS
 497
 498 ])
 499
 500 #
 501 # LB_PROG_CC
 502 #
 503 # checks on the C compiler
 504 #
 505 AC_DEFUN([LB_PROG_CC],
 506 [AC_PROG_RANLIB
 507 AC_MSG_CHECKING([for buggy compiler])
 508 CC_VERSION=`$CC -v 2>&1 | grep "^gcc version"`
 509 bad_cc() {
 510         AC_MSG_RESULT([buggy compiler found!])
 511         echo
 512         echo "   '$CC_VERSION'"
 513         echo "  has been known to generate bad code, "
 514         echo "  please get an updated compiler."
 515         AC_MSG_ERROR([sorry])
 516 }
 517 case "$CC_VERSION" in
 518         "gcc version 2.95"*)
 519                 bad_cc
 520                 ;;
 521         # ost_pack_niobuf putting 64bit NTOH temporaries on the stack
 522         # without "sub    $0xc,%esp" to protect the stack from being
 523         # stomped on by interrupts (bug 606)
 524         "gcc version 2.96 20000731 (Red Hat Linux 7.1 2.96-98)")
 525                 bad_cc
 526                 ;;
 527         # mandrake's similar sub 0xc compiler bug
 528         # http://marc.theaimsgroup.com/?l=linux-kernel&m=104748366226348&w=2
 529         "gcc version 2.96 20000731 (Mandrake Linux 8.1 2.96-0.62mdk)")
 530                 bad_cc
 531                 ;;
 532         *)
 533                 AC_MSG_RESULT([no known problems])
 534                 ;;
 535 esac
 536
 537 # ---------  unsigned long long sane? -------
 538 AC_CHECK_SIZEOF(unsigned long long, 0)
 539 echo "---> size SIZEOF $SIZEOF_unsigned_long_long"
 540 echo "---> size SIZEOF $ac_cv_sizeof_unsigned_long_long"
 541 if test $ac_cv_sizeof_unsigned_long_long != 8 ; then
 542         AC_MSG_ERROR([** we assume that sizeof(long long) == 8.  Tell phil@clusterfs.com])
 543 fi
 544
 545 CPPFLAGS="-I\$(top_builddir)/lnet/include -I\$(top_srcdir)/lnet/include -I\$(top_builddir)/lustre/include -I\$(top_srcdir)/lustre/include $CPPFLAGS"
 546
 547 LLCPPFLAGS="-D__arch_lib__ -D_LARGEFILE64_SOURCE=1"
 548 AC_SUBST(LLCPPFLAGS)
 549
 550 LLCFLAGS="-g -Wall -fPIC"
 551 AC_SUBST(LLCFLAGS)
 552
 553 # everyone builds against lnet and lustre
 554 EXTRA_KCFLAGS="$EXTRA_KCFLAGS -g -I$PWD/lnet/include -I$PWD/lustre/include"
 555 AC_SUBST(EXTRA_KCFLAGS)
 556 ])
 557
 558 #
 559 # LB_CONTITIONALS
 560 #
 561 # AM_CONDITIONAL instances for everything
 562 # (so that portals/lustre can disable some if needed)
 563 AC_DEFUN([LB_CONDITIONALS],
 564 [AM_CONDITIONAL(MODULES, test x$enable_modules = xyes)
 565 AM_CONDITIONAL(UTILS, test x$enable_utils = xyes)
 566 AM_CONDITIONAL(TESTS, test x$enable_tests = xyes)
 567 AM_CONDITIONAL(DOC, test x$ENABLE_DOC = x1)
 568 AM_CONDITIONAL(INIT_SCRIPTS, test x$ENABLE_INIT_SCRIPTS = "x1")
 569 AM_CONDITIONAL(LINUX, test x$lb_target_os = "xlinux")
 570 AM_CONDITIONAL(DARWIN, test x$lb_target_os = "xdarwin")
 571 AM_CONDITIONAL(CRAY_XT3, test x$enable_cray_xt3 = "xyes")
 572 AM_CONDITIONAL(SUNOS, test x$lb_target_os = "xSunOS")
 573
 574 # this lets lustre cancel libsysio, per-branch or if liblustre is
 575 # disabled
 576 if test "x$LIBSYSIO_SUBDIR" = xlibsysio ; then
 577         if test "x$with_sysio" != xyes ; then
 578                 SYSIO=""
 579                 LIBSYSIO_SUBDIR=""
 580         fi
 581 fi
 582 AC_SUBST(LIBSYSIO_SUBDIR)
 583 AC_SUBST(SYSIO)
 584
 585 LB_LINUX_CONDITIONALS
 586 LB_DARWIN_CONDITIONALS
 587
 588 LN_CONDITIONALS
 589 LC_CONDITIONALS
 590 ])
 591
 592 #
 593 # LB_CONFIG_FILES
 594 #
 595 # build-specific config files
 596 #
 597 AC_DEFUN([LB_CONFIG_FILES],
 598 [
 599 AC_CONFIG_FILES(
 600 [Makefile
 601 autoMakefile
 602 ]
 603 [Rules:build/Rules.in]
 604 AC_PACKAGE_TARNAME[.spec]
 605 )
 606 ])
 607
 608 #
 609 # LB_CONFIGURE
 610 #
 611 # main configure steps
 612 #
 613 AC_DEFUN([LB_CONFIGURE],
 614 [LB_CANONICAL_SYSTEM
 615
 616 LB_INCLUDE_RULES
 617
 618 LB_CONFIG_CRAY_XT3
 619 LB_CONFIG_BGL
 620 LB_PATH_DEFAULTS
 621
 622 LB_PROG_CC
 623
 624 LB_UOSS
 625 LB_POSIX_OSD
 626 LB_PATH_DMU
 627
 628 LB_CONFIG_DOCS
 629 LB_CONFIG_UTILS
 630 LB_CONFIG_TESTS
 631 LC_CONFIG_CLIENT_SERVER
 632
 633 # three macros for cmd3
 634 LC_CONFIG_SPLIT
 635 LC_CONFIG_LDISKFS
 636 LN_CONFIG_CDEBUG
 637
 638 LB_CONFIG_MODULES
 639
 640 LB_PATH_LIBSYSIO
 641 LB_PATH_SNMP
 642 LB_PATH_LDISKFS
 643
 644 LC_CONFIG_LIBLUSTRE
 645 LN_CONFIGURE
 646
 647 LC_CONFIGURE
 648
 649 if test "$SNMP_DIST_SUBDIR" ; then
 650         LS_CONFIGURE
 651 fi
 652
 653 LB_CONDITIONALS
 654 LB_CONFIG_HEADERS
 655
 656 LB_CONFIG_FILES
 657 LN_CONFIG_FILES
 658 LC_CONFIG_FILES
 659 if test "$SNMP_DIST_SUBDIR" ; then
 660         LS_CONFIG_FILES
 661 fi
 662
 663 AC_SUBST(ac_configure_args)
 664
 665 MOSTLYCLEANFILES='.*.cmd .*.flags *.o *.ko *.mod.c .depend .*.1.* Modules.symvers Module.symvers'
 666 AC_SUBST(MOSTLYCLEANFILES)
 667
 668 AC_OUTPUT
 669
 670 cat <<_ACEOF
 671
 672 CC:            $CC
 673 LD:            $LD
 674 CPPFLAGS:      $CPPFLAGS
 675 LLCPPFLAGS:    $LLCPPFLAGS
 676 CFLAGS:        $CFLAGS
 677 EXTRA_KCFLAGS: $EXTRA_KCFLAGS
 678 LLCFLAGS:      $LLCFLAGS
 679
 680 Type 'make' to build Lustre.
 681 _ACEOF
 682 ])