build/autoconf/lustre-build.m4

   1 #
   2 # LB_CHECK_VERSION
   3 #
   4 # Verify that LUSTRE_VERSION was defined properly
   5 #
   6 AC_DEFUN([LB_CHECK_VERSION],
   7 [if test "LUSTRE_VERSION" = "LUSTRE""_VERSION" ; then
   8         AC_MSG_ERROR([This script was not built with a version number.])
   9 fi
  10 ])
  11
  12 #
  13 # LB_CANONICAL_SYSTEM
  14 #
  15 # fixup $target_os for use in other places
  16 #
  17 AC_DEFUN([LB_CANONICAL_SYSTEM],
  18 [case $target_os in
  19         linux*)
  20                 lb_target_os="linux"
  21                 ;;
  22         darwin*)
  23                 lb_target_os="darwin"
  24                 ;;
  25         solaris2.11*)
  26                 lb_target_os="SunOS"
  27                 ;;esac
  28 AC_SUBST(lb_target_os)
  29 ])
  30
  31 #
  32 # LB_CHECK_FILE
  33 #
  34 # Check for file existance even when cross compiling
  35 #
  36 AC_DEFUN([LB_CHECK_FILE],
  37 [AS_VAR_PUSHDEF([lb_File], [lb_cv_file_$1])dnl
  38 AC_CACHE_CHECK([for $1], lb_File,
  39 [if test -r "$1"; then
  40   AS_VAR_SET(lb_File, yes)
  41 else
  42   AS_VAR_SET(lb_File, no)
  43 fi])
  44 AS_IF([test AS_VAR_GET(lb_File) = yes], [$2], [$3])[]dnl
  45 AS_VAR_POPDEF([lb_File])dnl
  46 ])# LB_CHECK_FILE
  47
  48 #
  49 # LB_CHECK_FILES
  50 #
  51 # LB_CHECK_FILE over multiple files
  52 #
  53 AC_DEFUN([LB_CHECK_FILES],
  54 [AC_FOREACH([AC_FILE_NAME], [$1],
  55   [LB_CHECK_FILE(AC_FILE_NAME,
  56                  [AC_DEFINE_UNQUOTED(AS_TR_CPP(HAVE_[]AC_FILE_NAME), 1,
  57                                     [Define to 1 if you have the
  58                                      file `]AC_File['.])
  59 $2],
  60                  [$3])])])
  61
  62 #
  63 # LB_ARG_LIBS_INCLUDES
  64 #
  65 # support for --with-foo, --with-foo-includes, and --with-foo-libs in
  66 # a single magical macro
  67 #
  68 AC_DEFUN([LB_ARG_LIBS_INCLUDES],
  69 [lb_pathvar="m4_bpatsubst([$2], -, _)"
  70 AC_MSG_CHECKING([for $1])
  71 AC_ARG_WITH([$2],
  72         AC_HELP_STRING([--with-$2=path],
  73                 [path to $1]),
  74         [],[withval=$4])
  75
  76 if test x$withval = xyes ; then
  77         eval "$lb_pathvar='$3'"
  78 else
  79         eval "$lb_pathvar='$withval'"
  80 fi
  81 AC_MSG_RESULT([${!lb_pathvar:-no}])
  82
  83 if test x${!lb_pathvar} != x -a x${!lb_pathvar} != xno ; then
  84         AC_MSG_CHECKING([for $1 includes])
  85         AC_ARG_WITH([$2-includes],
  86                 AC_HELP_STRING([--with-$2-includes=path],
  87                         [path to $1 includes]),
  88                 [],[withval='yes'])
  89
  90         lb_includevar="${lb_pathvar}_includes"
  91         if test x$withval = xyes ; then
  92                 eval "${lb_includevar}='${!lb_pathvar}/include'"
  93         else
  94                 eval "${lb_includevar}='$withval'"
  95         fi
  96         AC_MSG_RESULT([${!lb_includevar}])
  97
  98         AC_MSG_CHECKING([for $1 libs])
  99         AC_ARG_WITH([$2-libs],
 100                 AC_HELP_STRING([--with-$2-libs=path],
 101                         [path to $1 libs]),
 102                 [],[withval='yes'])
 103
 104         lb_libvar="${lb_pathvar}_libs"
 105         if test x$withval = xyes ; then
 106                 eval "${lb_libvar}='${!lb_pathvar}/lib'"
 107         else
 108                 eval "${lb_libvar}='$withval'"
 109         fi
 110         AC_MSG_RESULT([${!lb_libvar}])
 111 fi
 112 ])
 113 ])
 114
 115 #
 116 # LB_PATH_LIBSYSIO
 117 #
 118 # Handle internal/external libsysio
 119 #
 120 AC_DEFUN([LB_PATH_LIBSYSIO],
 121 [AC_ARG_WITH([sysio],
 122         AC_HELP_STRING([--with-sysio=path],
 123                         [set path to libsysio source (default is included libsysio)]),
 124         [],[
 125                 case $lb_target_os in
 126                         linux)
 127                                 with_sysio='yes'
 128                                 ;;
 129                         *)
 130                                 with_sysio='no'
 131                                 ;;
 132                 esac
 133         ])
 134 AC_MSG_CHECKING([location of libsysio])
 135 enable_sysio="$with_sysio"
 136 case x$with_sysio in
 137         xyes)
 138                 AC_MSG_RESULT([internal])
 139                 LB_CHECK_FILE([$srcdir/libsysio/src/rmdir.c],[],[
 140                         AC_MSG_ERROR([A complete internal libsysio was not found.])
 141                 ])
 142                 LIBSYSIO_SUBDIR="libsysio"
 143                 SYSIO="$PWD/libsysio"
 144                 ;;
 145         xno)
 146                 AC_MSG_RESULT([disabled])
 147                 ;;
 148         *)
 149                 AC_MSG_RESULT([$with_sysio])
 150                 LB_CHECK_FILE([$with_sysio/lib/libsysio.a],[],[
 151                         AC_MSG_ERROR([A complete (built) external libsysio was not found.])
 152                 ])
 153                 SYSIO=$with_sysio
 154                 with_sysio="yes"
 155                 ;;
 156 esac
 157
 158 # We have to configure even if we don't build here for make dist to work
 159 AC_CONFIG_SUBDIRS(libsysio)
 160 ])
 161
 162 #
 163 # LB_PATH_LDISKFS
 164 #
 165 # Handle internal/external ldiskfs
 166 #
 167 AC_DEFUN([LB_PATH_LDISKFS],
 168 [AC_ARG_WITH([ldiskfs],
 169         AC_HELP_STRING([--with-ldiskfs=path],
 170                         [set path to ldiskfs source (default is included ldiskfs)]),
 171         [],[
 172                 if test x$linux25$enable_server = xyesyes ; then
 173                         with_ldiskfs=yes
 174                 else
 175                         with_ldiskfs=no
 176                 fi
 177         ])
 178 AC_MSG_CHECKING([location of ldiskfs])
 179 case x$with_ldiskfs in
 180         xyes)
 181                 AC_MSG_RESULT([internal])
 182                 LB_CHECK_FILE([$srcdir/ldiskfs/lustre-ldiskfs.spec.in],[],[
 183                         AC_MSG_ERROR([A complete internal ldiskfs was not found.])
 184                 ])
 185                 LDISKFS_SUBDIR="ldiskfs"
 186                 LDISKFS_DIR="$PWD/ldiskfs"
 187                 ;;
 188         xno)
 189                 AC_MSG_RESULT([disabled])
 190                 ;;
 191         *)
 192                 AC_MSG_RESULT([$with_ldiskfs])
 193                 LB_CHECK_FILE([$with_ldiskfs/ldiskfs/linux/ldiskfs_fs.h],[],[
 194                         AC_MSG_ERROR([A complete (built) external ldiskfs was not found.])
 195                 ])
 196                 LDISKFS_DIR=$with_ldiskfs
 197                 ;;
 198 esac
 199 AC_SUBST(LDISKFS_DIR)
 200 AC_SUBST(LDISKFS_SUBDIR)
 201
 202 # We have to configure even if we don't build here for make dist to work
 203 AC_CONFIG_SUBDIRS(ldiskfs)
 204 ])
 205
 206 #
 207 # LB_DEFINE_LDISKFS_OPTIONS
 208 #
 209 # Enable config options related to ldiskfs.  These are used both by ldiskfs
 210 # and lvfs (which includes ldiskfs headers.)
 211 #
 212 AC_DEFUN([LB_DEFINE_LDISKFS_OPTIONS],
 213 [
 214         AC_DEFINE(CONFIG_LDISKFS_FS_MODULE, 1, [build ldiskfs as a module])
 215         AC_DEFINE(CONFIG_LDISKFS_FS_XATTR, 1, [enable extended attributes for ldiskfs])
 216         AC_DEFINE(CONFIG_LDISKFS_FS_POSIX_ACL, 1, [enable posix acls for ldiskfs])
 217         AC_DEFINE(CONFIG_LDISKFS_FS_SECURITY, 1, [enable fs security for ldiskfs])
 218 ])
 219
 220 #
 221 # LB_CONFIG_CRAY_XT3
 222 #
 223 # Enable Cray XT3 features
 224 #
 225 AC_DEFUN([LB_CONFIG_CRAY_XT3],
 226 [AC_MSG_CHECKING([whether to build Cray XT3 features])
 227 AC_ARG_ENABLE([cray_xt3],
 228         AC_HELP_STRING([--enable-cray-xt3],
 229                         [enable building of Cray XT3 features]),
 230         [enable_cray_xt3='yes'],[enable_cray_xt3='no'])
 231 AC_MSG_RESULT([$enable_cray_xt3])
 232 if test x$enable_cray_xt3 != xno; then
 233         AC_DEFINE(CRAY_XT3, 1, Enable Cray XT3 Features)
 234 fi
 235 ])
 236
 237 #
 238 # LB_CONFIG_BGL
 239 #
 240 # Enable BGL features
 241 #
 242 AC_DEFUN([LB_CONFIG_BGL],
 243 [AC_MSG_CHECKING([whether to build BGL features])
 244 AC_ARG_ENABLE([bgl],
 245         AC_HELP_STRING([--enable-bgl],
 246                         [enable building of BGL features]),
 247         [enable_bgl='yes'],[enable_bgl='no'])
 248 AC_MSG_RESULT([$enable_bgl])
 249 if test x$enable_bgl != xno; then
 250         AC_DEFINE(BGL_SUPPORT, 1, Enable BGL Features)
 251         enable_doc='no'
 252         enable_tests='no'
 253         enable_server='no'
 254         enable_liblustre='no'
 255         enable_libreadline='no'
 256 fi
 257 ])
 258
 259
 260 #
 261 # LB_CONFIG_UOSS
 262 #
 263 #
 264 AC_DEFUN([LB_CONFIG_UOSS],
 265 [AC_MSG_CHECKING([whether to build user-level oss])
 266 AC_ARG_ENABLE([uoss],
 267         AC_HELP_STRING([--enable-uoss],
 268                         [enable building of user-level oss]),
 269         [enable_uoss='yes'],[enable_uoss='no'])
 270 AC_MSG_RESULT([$enable_uoss])
 271 if test x$enable_uoss != xno; then
 272         AC_DEFINE(UOSS_SUPPORT, 1, Enable user-level OSS)
 273         AC_DEFINE(LUSTRE_ULEVEL_MT, 1, Multi-threaded user-level lustre port)
 274         enable_ulevel_mt='yes'
 275         enable_modules='no'
 276         enable_client='no'
 277         enable_tests='no'
 278         enable_liblustre='no'
 279         with_ldiskfs=no
 280 fi
 281 ])
 282
 283 #
 284 # LB_PATH_DMU
 285 # Support for --with-dmu
 286 #
 287 AC_DEFUN([LB_PATH_DMU],
 288 [AC_ARG_WITH([dmu],
 289         AC_HELP_STRING([--with-dmu=path],
 290                        [set path to a built dmu]),
 291         [
 292                 DMU_SRC=$with_dmu
 293                 dmu=true
 294         ],
 295         [
 296                 dmu=false
 297                 DMU_SRC=""
 298         ])
 299 AM_CONDITIONAL([ENABLE_DMU], [test x$dmu = xtrue])
 300 AC_SUBST(DMU_SRC)
 301 AC_DEFINE(DMU_OSD, 1, Enable DMU OSD)
 302 ])
 303
 304 #
 305 # Support for --enable-posix-dmu
 306 #
 307 AC_DEFUN([LB_POSIX_OSD],
 308 [AC_MSG_CHECKING([whether to posix osd])
 309 AC_ARG_ENABLE([posix-osd],
 310         AC_HELP_STRING([--enable-posix-osd],
 311                         [enable using of posix osd]),
 312         [enable_posix_osd='yes'],[enable_posix_osd='no'])
 313 AC_MSG_RESULT([$enable_posix_osd])
 314 if test x$enable_posix_osd != xno; then
 315         AC_DEFINE(POSIX_OSD, 1, Enable POSIX OSD)
 316         AC_DEFINE(LUSTRE_ULEVEL_MT, 1, Multi-threaded user-level lustre port)
 317         enable_ulevel_mt='yes'
 318         enable_modules='no'
 319         enable_client='no'
 320         enable_tests='no'
 321         enable_liblustre='no'
 322         with_ldiskfs=no
 323 fi
 324 ])
 325
 326 #
 327 # LB_PATH_SNMP
 328 #
 329 # check for in-tree snmp support
 330 #
 331 AC_DEFUN([LB_PATH_SNMP],
 332 [LB_CHECK_FILE([$srcdir/snmp/lustre-snmp.c],[SNMP_DIST_SUBDIR="snmp"])
 333 AC_SUBST(SNMP_DIST_SUBDIR)
 334 AC_SUBST(SNMP_SUBDIR)
 335 ])
 336
 337 #
 338 # LB_CONFIG_MODULES
 339 #
 340 # Build kernel modules?
 341 #
 342 AC_DEFUN([LB_CONFIG_MODULES],
 343 [AC_MSG_CHECKING([whether to build kernel modules])
 344 AC_ARG_ENABLE([modules],
 345         AC_HELP_STRING([--disable-modules],
 346                         [disable building of Lustre kernel modules]),
 347         [],[
 348                 LC_TARGET_SUPPORTED([
 349                         enable_modules='yes'
 350                 ],[
 351                         enable_modules='no'
 352                 ])
 353         ])
 354 AC_MSG_RESULT([$enable_modules ($target_os)])
 355
 356 if test x$enable_modules = xyes ; then
 357         case $target_os in
 358                 linux*)
 359                         LB_PROG_LINUX
 360                         LN_PROG_LINUX
 361                         LC_PROG_LINUX
 362                         ;;
 363                 darwin*)
 364                         LB_PROG_DARWIN
 365                         ;;
 366                 *)
 367                         # This is strange - Lustre supports a target we don't
 368                         AC_MSG_ERROR([Modules are not supported on $target_os])
 369                         ;;
 370         esac
 371 fi
 372 ])
 373
 374 #
 375 # LB_CONFIG_UTILS
 376 #
 377 # Build utils?
 378 #
 379 AC_DEFUN([LB_CONFIG_UTILS],
 380 [AC_MSG_CHECKING([whether to build utilities])
 381 AC_ARG_ENABLE([utils],
 382         AC_HELP_STRING([--disable-utils],
 383                         [disable building of Lustre utility programs]),
 384         [],[enable_utils='yes'])
 385 AC_MSG_RESULT([$enable_utils])
 386 if test x$enable_utils = xyes ; then
 387         LB_CONFIG_INIT_SCRIPTS
 388 fi
 389 ])
 390
 391 #
 392 # LB_CONFIG_TESTS
 393 #
 394 # Build tests?
 395 #
 396 AC_DEFUN([LB_CONFIG_TESTS],
 397 [AC_MSG_CHECKING([whether to build Lustre tests])
 398 AC_ARG_ENABLE([tests],
 399         AC_HELP_STRING([--disable-tests],
 400                         [disable building of Lustre tests]),
 401         [],
 402         [
 403                 enable_tests='yes'
 404         ])
 405 AC_MSG_RESULT([$enable_tests])
 406 ])
 407
 408 #
 409 # LB_CONFIG_DOCS
 410 #
 411 # Build docs?
 412 #
 413 AC_DEFUN([LB_CONFIG_DOCS],
 414 [AC_MSG_CHECKING([whether to build docs])
 415 AC_ARG_ENABLE(doc,
 416         AC_HELP_STRING([--disable-doc],
 417                         [skip creation of pdf documentation]),
 418         [
 419                 if test x$enable_doc = xyes ; then
 420                     ENABLE_DOC=1
 421                 else
 422                     ENABLE_DOC=0
 423                 fi
 424         ],[
 425                 ENABLE_DOC=0
 426                 enable_doc='no'
 427         ])
 428 AC_MSG_RESULT([$enable_doc])
 429 AC_SUBST(ENABLE_DOC)
 430 ])
 431
 432 #
 433 # LB_CONFIG_INIT_SCRIPTS
 434 #
 435 # our init scripts only work on red hat linux
 436 #
 437 AC_DEFUN([LB_CONFIG_INIT_SCRIPTS],
 438 [ENABLE_INIT_SCRIPTS=0
 439 if test x$enable_utils = xyes ; then
 440         AC_MSG_CHECKING([whether to install init scripts])
 441         # our scripts only work on red hat systems
 442         if test -f /etc/init.d/functions -a -f /etc/sysconfig/network ; then
 443                 ENABLE_INIT_SCRIPTS=1
 444                 AC_MSG_RESULT([yes])
 445         else
 446                 AC_MSG_RESULT([no])
 447         fi
 448 fi
 449 AC_SUBST(ENABLE_INIT_SCRIPTS)
 450 ])
 451
 452 #
 453 # LB_CONFIG_HEADERS
 454 #
 455 # add -include config.h
 456 #
 457 AC_DEFUN([LB_CONFIG_HEADERS],
 458 [AC_CONFIG_HEADERS([config.h])
 459 CPPFLAGS="-include \$(top_builddir)/config.h $CPPFLAGS"
 460 EXTRA_KCFLAGS="-include $PWD/config.h $EXTRA_KCFLAGS"
 461 AC_SUBST(EXTRA_KCFLAGS)
 462 ])
 463
 464 #
 465 # LB_INCLUDE_RULES
 466 #
 467 # defines for including the toplevel Rules
 468 #
 469 AC_DEFUN([LB_INCLUDE_RULES],
 470 [INCLUDE_RULES="include $PWD/Rules"
 471 AC_SUBST(INCLUDE_RULES)
 472 ])
 473
 474 #
 475 # LB_PATH_DEFAULTS
 476 #
 477 # 'fixup' default paths
 478 #
 479 AC_DEFUN([LB_PATH_DEFAULTS],
 480 [# directories for binaries
 481 AC_PREFIX_DEFAULT([/usr])
 482
 483 sysconfdir='/etc'
 484 AC_SUBST(sysconfdir)
 485
 486 # Directories for documentation and demos.
 487 docdir='${datadir}/doc/$(PACKAGE)'
 488 AC_SUBST(docdir)
 489
 490 LN_PATH_DEFAULTS
 491 LC_PATH_DEFAULTS
 492
 493 ])
 494
 495 #
 496 # LB_PROG_CC
 497 #
 498 # checks on the C compiler
 499 #
 500 AC_DEFUN([LB_PROG_CC],
 501 [AC_PROG_RANLIB
 502 AC_MSG_CHECKING([for buggy compiler])
 503 CC_VERSION=`$CC -v 2>&1 | grep "^gcc version"`
 504 bad_cc() {
 505         AC_MSG_RESULT([buggy compiler found!])
 506         echo
 507         echo "   '$CC_VERSION'"
 508         echo "  has been known to generate bad code, "
 509         echo "  please get an updated compiler."
 510         AC_MSG_ERROR([sorry])
 511 }
 512 case "$CC_VERSION" in
 513         "gcc version 2.95"*)
 514                 bad_cc
 515                 ;;
 516         # ost_pack_niobuf putting 64bit NTOH temporaries on the stack
 517         # without "sub    $0xc,%esp" to protect the stack from being
 518         # stomped on by interrupts (bug 606)
 519         "gcc version 2.96 20000731 (Red Hat Linux 7.1 2.96-98)")
 520                 bad_cc
 521                 ;;
 522         # mandrake's similar sub 0xc compiler bug
 523         # http://marc.theaimsgroup.com/?l=linux-kernel&m=104748366226348&w=2
 524         "gcc version 2.96 20000731 (Mandrake Linux 8.1 2.96-0.62mdk)")
 525                 bad_cc
 526                 ;;
 527         *)
 528                 AC_MSG_RESULT([no known problems])
 529                 ;;
 530 esac
 531
 532 # ---------  unsigned long long sane? -------
 533 AC_CHECK_SIZEOF(unsigned long long, 0)
 534 echo "---> size SIZEOF $SIZEOF_unsigned_long_long"
 535 echo "---> size SIZEOF $ac_cv_sizeof_unsigned_long_long"
 536 if test $ac_cv_sizeof_unsigned_long_long != 8 ; then
 537         AC_MSG_ERROR([** we assume that sizeof(long long) == 8.  Tell phil@clusterfs.com])
 538 fi
 539
 540 # FIXME
 541 AC_CHECK_DECL([__i386__], [], [
 542
 543 if test x$enable_bgl != xyes; then
 544 AC_MSG_CHECKING([if $CC accepts -m64])
 545 CC_save="$CC"
 546 CC="$CC -m64"
 547 AC_TRY_COMPILE([],[],[
 548         AC_MSG_RESULT([yes])
 549 ],[
 550         AC_MSG_RESULT([no])
 551         CC="$CC_save"
 552 ])
 553 fi
 554
 555 ])
 556
 557 CPPFLAGS="-I\$(top_builddir)/lnet/include -I\$(top_srcdir)/lnet/include -I\$(top_builddir)/lustre/include -I\$(top_srcdir)/lustre/include $CPPFLAGS"
 558
 559 LLCPPFLAGS="-D__arch_lib__ -D_LARGEFILE64_SOURCE=1"
 560 AC_SUBST(LLCPPFLAGS)
 561
 562 LLCFLAGS="-g -Wall -fPIC"
 563 AC_SUBST(LLCFLAGS)
 564
 565 # everyone builds against lnet and lustre
 566 EXTRA_KCFLAGS="$EXTRA_KCFLAGS -g -I$PWD/lnet/include -I$PWD/lustre/include"
 567 AC_SUBST(EXTRA_KCFLAGS)
 568 ])
 569
 570 #
 571 # LB_CONTITIONALS
 572 #
 573 # AM_CONDITIONAL instances for everything
 574 # (so that portals/lustre can disable some if needed)
 575 AC_DEFUN([LB_CONDITIONALS],
 576 [AM_CONDITIONAL(MODULES, test x$enable_modules = xyes)
 577 AM_CONDITIONAL(UTILS, test x$enable_utils = xyes)
 578 AM_CONDITIONAL(TESTS, test x$enable_tests = xyes)
 579 AM_CONDITIONAL(DOC, test x$ENABLE_DOC = x1)
 580 AM_CONDITIONAL(INIT_SCRIPTS, test x$ENABLE_INIT_SCRIPTS = "x1")
 581 AM_CONDITIONAL(LINUX, test x$lb_target_os = "xlinux")
 582 AM_CONDITIONAL(DARWIN, test x$lb_target_os = "xdarwin")
 583 AM_CONDITIONAL(CRAY_XT3, test x$enable_cray_xt3 = "xyes")
 584 AM_CONDITIONAL(SUNOS, test x$lb_target_os = "xSunOS")
 585
 586 # this lets lustre cancel libsysio, per-branch or if liblustre is
 587 # disabled
 588 if test "x$LIBSYSIO_SUBDIR" = xlibsysio ; then
 589         if test "x$with_sysio" != xyes ; then
 590                 SYSIO=""
 591                 LIBSYSIO_SUBDIR=""
 592         fi
 593 fi
 594 AC_SUBST(LIBSYSIO_SUBDIR)
 595 AC_SUBST(SYSIO)
 596
 597 LB_LINUX_CONDITIONALS
 598 LB_DARWIN_CONDITIONALS
 599
 600 LN_CONDITIONALS
 601 LC_CONDITIONALS
 602 ])
 603
 604 #
 605 # LB_CONFIG_FILES
 606 #
 607 # build-specific config files
 608 #
 609 AC_DEFUN([LB_CONFIG_FILES],
 610 [
 611 AC_CONFIG_FILES(
 612 [Makefile
 613 autoMakefile
 614 ]
 615 [Rules:build/Rules.in]
 616 AC_PACKAGE_TARNAME[.spec]
 617 )
 618 ])
 619
 620 #
 621 # LB_CONFIGURE
 622 #
 623 # main configure steps
 624 #
 625 AC_DEFUN([LB_CONFIGURE],
 626 [LB_CANONICAL_SYSTEM
 627
 628 LB_INCLUDE_RULES
 629
 630 LB_CONFIG_CRAY_XT3
 631 LB_CONFIG_BGL
 632 LB_PATH_DEFAULTS
 633
 634 LB_PROG_CC
 635
 636 LB_PATH_DMU
 637 LB_CONFIG_UOSS
 638 LB_POSIX_OSD
 639
 640 LB_CONFIG_DOCS
 641 LB_CONFIG_UTILS
 642 LB_CONFIG_TESTS
 643 LC_CONFIG_CLIENT_SERVER
 644
 645 # three macros for cmd3
 646 LC_CONFIG_SPLIT
 647 LC_CONFIG_LDISKFS
 648 LN_CONFIG_CDEBUG
 649
 650 LB_CONFIG_MODULES
 651
 652 LB_PATH_LIBSYSIO
 653 LB_PATH_SNMP
 654 LB_PATH_LDISKFS
 655
 656 LC_CONFIG_LIBLUSTRE
 657 LN_CONFIGURE
 658
 659 LC_CONFIGURE
 660
 661 if test "$SNMP_DIST_SUBDIR" ; then
 662         LS_CONFIGURE
 663 fi
 664
 665 LB_CONDITIONALS
 666 LB_CONFIG_HEADERS
 667
 668 LB_CONFIG_FILES
 669 LN_CONFIG_FILES
 670 LC_CONFIG_FILES
 671 if test "$SNMP_DIST_SUBDIR" ; then
 672         LS_CONFIG_FILES
 673 fi
 674
 675 AC_SUBST(ac_configure_args)
 676
 677 MOSTLYCLEANFILES='.*.cmd .*.flags *.o *.ko *.mod.c .depend .*.1.*'
 678 AC_SUBST(MOSTLYCLEANFILES)
 679
 680 AC_OUTPUT
 681
 682 cat <<_ACEOF
 683
 684 CC:            $CC
 685 LD:            $LD
 686 CPPFLAGS:      $CPPFLAGS
 687 LLCPPFLAGS:    $LLCPPFLAGS
 688 CFLAGS:        $CFLAGS
 689 EXTRA_KCFLAGS: $EXTRA_KCFLAGS
 690 LLCFLAGS:      $LLCFLAGS
 691
 692 Type 'make' to build Lustre.
 693 _ACEOF
 694 ])